src/HOL/Library/Euclidean_Space.thy
author haftmann
Wed Apr 22 19:09:21 2009 +0200 (2009-04-22)
changeset 30960 fec1a04b7220
parent 30665 4cf38ea4fad2
child 31021 53642251a04f
permissions -rw-r--r--
power operation defined generic
     1 (* Title:      Library/Euclidean_Space
     2    Author:     Amine Chaieb, University of Cambridge
     3 *)
     4 
     5 header {* (Real) Vectors in Euclidean space, and elementary linear algebra.*}
     6 
     7 theory Euclidean_Space
     8 imports
     9   Complex_Main "~~/src/HOL/Decision_Procs/Dense_Linear_Order"
    10   Finite_Cartesian_Product Glbs Infinite_Set Numeral_Type
    11   Inner_Product
    12 uses ("normarith.ML")
    13 begin
    14 
    15 text{* Some common special cases.*}
    16 
    17 lemma forall_1: "(\<forall>i::1. P i) \<longleftrightarrow> P 1"
    18   by (metis num1_eq_iff)
    19 
    20 lemma exhaust_2:
    21   fixes x :: 2 shows "x = 1 \<or> x = 2"
    22 proof (induct x)
    23   case (of_int z)
    24   then have "0 <= z" and "z < 2" by simp_all
    25   then have "z = 0 | z = 1" by arith
    26   then show ?case by auto
    27 qed
    28 
    29 lemma forall_2: "(\<forall>i::2. P i) \<longleftrightarrow> P 1 \<and> P 2"
    30   by (metis exhaust_2)
    31 
    32 lemma exhaust_3:
    33   fixes x :: 3 shows "x = 1 \<or> x = 2 \<or> x = 3"
    34 proof (induct x)
    35   case (of_int z)
    36   then have "0 <= z" and "z < 3" by simp_all
    37   then have "z = 0 \<or> z = 1 \<or> z = 2" by arith
    38   then show ?case by auto
    39 qed
    40 
    41 lemma forall_3: "(\<forall>i::3. P i) \<longleftrightarrow> P 1 \<and> P 2 \<and> P 3"
    42   by (metis exhaust_3)
    43 
    44 lemma UNIV_1: "UNIV = {1::1}"
    45   by (auto simp add: num1_eq_iff)
    46 
    47 lemma UNIV_2: "UNIV = {1::2, 2::2}"
    48   using exhaust_2 by auto
    49 
    50 lemma UNIV_3: "UNIV = {1::3, 2::3, 3::3}"
    51   using exhaust_3 by auto
    52 
    53 lemma setsum_1: "setsum f (UNIV::1 set) = f 1"
    54   unfolding UNIV_1 by simp
    55 
    56 lemma setsum_2: "setsum f (UNIV::2 set) = f 1 + f 2"
    57   unfolding UNIV_2 by simp
    58 
    59 lemma setsum_3: "setsum f (UNIV::3 set) = f 1 + f 2 + f 3"
    60   unfolding UNIV_3 by (simp add: add_ac)
    61 
    62 subsection{* Basic componentwise operations on vectors. *}
    63 
    64 instantiation "^" :: (plus,type) plus
    65 begin
    66 definition  vector_add_def : "op + \<equiv> (\<lambda> x y.  (\<chi> i. (x$i) + (y$i)))"
    67 instance ..
    68 end
    69 
    70 instantiation "^" :: (times,type) times
    71 begin
    72   definition vector_mult_def : "op * \<equiv> (\<lambda> x y.  (\<chi> i. (x$i) * (y$i)))"
    73   instance ..
    74 end
    75 
    76 instantiation "^" :: (minus,type) minus begin
    77   definition vector_minus_def : "op - \<equiv> (\<lambda> x y.  (\<chi> i. (x$i) - (y$i)))"
    78 instance ..
    79 end
    80 
    81 instantiation "^" :: (uminus,type) uminus begin
    82   definition vector_uminus_def : "uminus \<equiv> (\<lambda> x.  (\<chi> i. - (x$i)))"
    83 instance ..
    84 end
    85 instantiation "^" :: (zero,type) zero begin
    86   definition vector_zero_def : "0 \<equiv> (\<chi> i. 0)"
    87 instance ..
    88 end
    89 
    90 instantiation "^" :: (one,type) one begin
    91   definition vector_one_def : "1 \<equiv> (\<chi> i. 1)"
    92 instance ..
    93 end
    94 
    95 instantiation "^" :: (ord,type) ord
    96  begin
    97 definition vector_less_eq_def:
    98   "less_eq (x :: 'a ^'b) y = (ALL i. x$i <= y$i)"
    99 definition vector_less_def: "less (x :: 'a ^'b) y = (ALL i. x$i < y$i)"
   100 
   101 instance by (intro_classes)
   102 end
   103 
   104 instantiation "^" :: (scaleR, type) scaleR
   105 begin
   106 definition vector_scaleR_def: "scaleR = (\<lambda> r x.  (\<chi> i. scaleR r (x$i)))"
   107 instance ..
   108 end
   109 
   110 text{* Also the scalar-vector multiplication. *}
   111 
   112 definition vector_scalar_mult:: "'a::times \<Rightarrow> 'a ^'n \<Rightarrow> 'a ^ 'n" (infixr "*s" 75)
   113   where "c *s x = (\<chi> i. c * (x$i))"
   114 
   115 text{* Constant Vectors *}
   116 
   117 definition "vec x = (\<chi> i. x)"
   118 
   119 text{* Dot products. *}
   120 
   121 definition dot :: "'a::{comm_monoid_add, times} ^ 'n \<Rightarrow> 'a ^ 'n \<Rightarrow> 'a" (infix "\<bullet>" 70) where
   122   "x \<bullet> y = setsum (\<lambda>i. x$i * y$i) UNIV"
   123 
   124 lemma dot_1[simp]: "(x::'a::{comm_monoid_add, times}^1) \<bullet> y = (x$1) * (y$1)"
   125   by (simp add: dot_def setsum_1)
   126 
   127 lemma dot_2[simp]: "(x::'a::{comm_monoid_add, times}^2) \<bullet> y = (x$1) * (y$1) + (x$2) * (y$2)"
   128   by (simp add: dot_def setsum_2)
   129 
   130 lemma dot_3[simp]: "(x::'a::{comm_monoid_add, times}^3) \<bullet> y = (x$1) * (y$1) + (x$2) * (y$2) + (x$3) * (y$3)"
   131   by (simp add: dot_def setsum_3)
   132 
   133 subsection {* A naive proof procedure to lift really trivial arithmetic stuff from the basis of the vector space. *}
   134 
   135 method_setup vector = {*
   136 let
   137   val ss1 = HOL_basic_ss addsimps [@{thm dot_def}, @{thm setsum_addf} RS sym,
   138   @{thm setsum_subtractf} RS sym, @{thm setsum_right_distrib},
   139   @{thm setsum_left_distrib}, @{thm setsum_negf} RS sym]
   140   val ss2 = @{simpset} addsimps
   141              [@{thm vector_add_def}, @{thm vector_mult_def},
   142               @{thm vector_minus_def}, @{thm vector_uminus_def},
   143               @{thm vector_one_def}, @{thm vector_zero_def}, @{thm vec_def},
   144               @{thm vector_scaleR_def},
   145               @{thm Cart_lambda_beta}, @{thm vector_scalar_mult_def}]
   146  fun vector_arith_tac ths =
   147    simp_tac ss1
   148    THEN' (fn i => rtac @{thm setsum_cong2} i
   149          ORELSE rtac @{thm setsum_0'} i
   150          ORELSE simp_tac (HOL_basic_ss addsimps [@{thm "Cart_eq"}]) i)
   151    (* THEN' TRY o clarify_tac HOL_cs  THEN' (TRY o rtac @{thm iffI}) *)
   152    THEN' asm_full_simp_tac (ss2 addsimps ths)
   153  in
   154   Attrib.thms >> (fn ths => K (SIMPLE_METHOD' (vector_arith_tac ths)))
   155  end
   156 *} "Lifts trivial vector statements to real arith statements"
   157 
   158 lemma vec_0[simp]: "vec 0 = 0" by (vector vector_zero_def)
   159 lemma vec_1[simp]: "vec 1 = 1" by (vector vector_one_def)
   160 
   161 
   162 
   163 text{* Obvious "component-pushing". *}
   164 
   165 lemma vec_component [simp]: "(vec x :: 'a ^ 'n)$i = x"
   166   by (vector vec_def)
   167 
   168 lemma vector_add_component [simp]:
   169   fixes x y :: "'a::{plus} ^ 'n"
   170   shows "(x + y)$i = x$i + y$i"
   171   by vector
   172 
   173 lemma vector_minus_component [simp]:
   174   fixes x y :: "'a::{minus} ^ 'n"
   175   shows "(x - y)$i = x$i - y$i"
   176   by vector
   177 
   178 lemma vector_mult_component [simp]:
   179   fixes x y :: "'a::{times} ^ 'n"
   180   shows "(x * y)$i = x$i * y$i"
   181   by vector
   182 
   183 lemma vector_smult_component [simp]:
   184   fixes y :: "'a::{times} ^ 'n"
   185   shows "(c *s y)$i = c * (y$i)"
   186   by vector
   187 
   188 lemma vector_uminus_component [simp]:
   189   fixes x :: "'a::{uminus} ^ 'n"
   190   shows "(- x)$i = - (x$i)"
   191   by vector
   192 
   193 lemma vector_scaleR_component [simp]:
   194   fixes x :: "'a::scaleR ^ 'n"
   195   shows "(scaleR r x)$i = scaleR r (x$i)"
   196   by vector
   197 
   198 lemma cond_component: "(if b then x else y)$i = (if b then x$i else y$i)" by vector
   199 
   200 lemmas vector_component =
   201   vec_component vector_add_component vector_mult_component
   202   vector_smult_component vector_minus_component vector_uminus_component
   203   vector_scaleR_component cond_component
   204 
   205 subsection {* Some frequently useful arithmetic lemmas over vectors. *}
   206 
   207 instance "^" :: (semigroup_add,type) semigroup_add
   208   apply (intro_classes) by (vector add_assoc)
   209 
   210 
   211 instance "^" :: (monoid_add,type) monoid_add
   212   apply (intro_classes) by vector+
   213 
   214 instance "^" :: (group_add,type) group_add
   215   apply (intro_classes) by (vector algebra_simps)+
   216 
   217 instance "^" :: (ab_semigroup_add,type) ab_semigroup_add
   218   apply (intro_classes) by (vector add_commute)
   219 
   220 instance "^" :: (comm_monoid_add,type) comm_monoid_add
   221   apply (intro_classes) by vector
   222 
   223 instance "^" :: (ab_group_add,type) ab_group_add
   224   apply (intro_classes) by vector+
   225 
   226 instance "^" :: (cancel_semigroup_add,type) cancel_semigroup_add
   227   apply (intro_classes)
   228   by (vector Cart_eq)+
   229 
   230 instance "^" :: (cancel_ab_semigroup_add,type) cancel_ab_semigroup_add
   231   apply (intro_classes)
   232   by (vector Cart_eq)
   233 
   234 instance "^" :: (real_vector, type) real_vector
   235   by default (vector scaleR_left_distrib scaleR_right_distrib)+
   236 
   237 instance "^" :: (semigroup_mult,type) semigroup_mult
   238   apply (intro_classes) by (vector mult_assoc)
   239 
   240 instance "^" :: (monoid_mult,type) monoid_mult
   241   apply (intro_classes) by vector+
   242 
   243 instance "^" :: (ab_semigroup_mult,type) ab_semigroup_mult
   244   apply (intro_classes) by (vector mult_commute)
   245 
   246 instance "^" :: (ab_semigroup_idem_mult,type) ab_semigroup_idem_mult
   247   apply (intro_classes) by (vector mult_idem)
   248 
   249 instance "^" :: (comm_monoid_mult,type) comm_monoid_mult
   250   apply (intro_classes) by vector
   251 
   252 fun vector_power :: "('a::{one,times} ^'n) \<Rightarrow> nat \<Rightarrow> 'a^'n" where
   253   "vector_power x 0 = 1"
   254   | "vector_power x (Suc n) = x * vector_power x n"
   255 
   256 instance "^" :: (recpower,type) recpower ..
   257 
   258 instance "^" :: (semiring,type) semiring
   259   apply (intro_classes) by (vector ring_simps)+
   260 
   261 instance "^" :: (semiring_0,type) semiring_0
   262   apply (intro_classes) by (vector ring_simps)+
   263 instance "^" :: (semiring_1,type) semiring_1
   264   apply (intro_classes) by vector
   265 instance "^" :: (comm_semiring,type) comm_semiring
   266   apply (intro_classes) by (vector ring_simps)+
   267 
   268 instance "^" :: (comm_semiring_0,type) comm_semiring_0 by (intro_classes)
   269 instance "^" :: (cancel_comm_monoid_add, type) cancel_comm_monoid_add ..
   270 instance "^" :: (semiring_0_cancel,type) semiring_0_cancel by (intro_classes)
   271 instance "^" :: (comm_semiring_0_cancel,type) comm_semiring_0_cancel by (intro_classes)
   272 instance "^" :: (ring,type) ring by (intro_classes)
   273 instance "^" :: (semiring_1_cancel,type) semiring_1_cancel by (intro_classes)
   274 instance "^" :: (comm_semiring_1,type) comm_semiring_1 by (intro_classes)
   275 
   276 instance "^" :: (ring_1,type) ring_1 ..
   277 
   278 instance "^" :: (real_algebra,type) real_algebra
   279   apply intro_classes
   280   apply (simp_all add: vector_scaleR_def ring_simps)
   281   apply vector
   282   apply vector
   283   done
   284 
   285 instance "^" :: (real_algebra_1,type) real_algebra_1 ..
   286 
   287 lemma of_nat_index:
   288   "(of_nat n :: 'a::semiring_1 ^'n)$i = of_nat n"
   289   apply (induct n)
   290   apply vector
   291   apply vector
   292   done
   293 lemma zero_index[simp]:
   294   "(0 :: 'a::zero ^'n)$i = 0" by vector
   295 
   296 lemma one_index[simp]:
   297   "(1 :: 'a::one ^'n)$i = 1" by vector
   298 
   299 lemma one_plus_of_nat_neq_0: "(1::'a::semiring_char_0) + of_nat n \<noteq> 0"
   300 proof-
   301   have "(1::'a) + of_nat n = 0 \<longleftrightarrow> of_nat 1 + of_nat n = (of_nat 0 :: 'a)" by simp
   302   also have "\<dots> \<longleftrightarrow> 1 + n = 0" by (simp only: of_nat_add[symmetric] of_nat_eq_iff)
   303   finally show ?thesis by simp
   304 qed
   305 
   306 instance "^" :: (semiring_char_0,type) semiring_char_0
   307 proof (intro_classes)
   308   fix m n ::nat
   309   show "(of_nat m :: 'a^'b) = of_nat n \<longleftrightarrow> m = n"
   310     by (simp add: Cart_eq of_nat_index)
   311 qed
   312 
   313 instance "^" :: (comm_ring_1,type) comm_ring_1 by intro_classes
   314 instance "^" :: (ring_char_0,type) ring_char_0 by intro_classes
   315 
   316 lemma vector_smult_assoc: "a *s (b *s x) = ((a::'a::semigroup_mult) * b) *s x"
   317   by (vector mult_assoc)
   318 lemma vector_sadd_rdistrib: "((a::'a::semiring) + b) *s x = a *s x + b *s x"
   319   by (vector ring_simps)
   320 lemma vector_add_ldistrib: "(c::'a::semiring) *s (x + y) = c *s x + c *s y"
   321   by (vector ring_simps)
   322 lemma vector_smult_lzero[simp]: "(0::'a::mult_zero) *s x = 0" by vector
   323 lemma vector_smult_lid[simp]: "(1::'a::monoid_mult) *s x = x" by vector
   324 lemma vector_ssub_ldistrib: "(c::'a::ring) *s (x - y) = c *s x - c *s y"
   325   by (vector ring_simps)
   326 lemma vector_smult_rneg: "(c::'a::ring) *s -x = -(c *s x)" by vector
   327 lemma vector_smult_lneg: "- (c::'a::ring) *s x = -(c *s x)" by vector
   328 lemma vector_sneg_minus1: "-x = (- (1::'a::ring_1)) *s x" by vector
   329 lemma vector_smult_rzero[simp]: "c *s 0 = (0::'a::mult_zero ^ 'n)" by vector
   330 lemma vector_sub_rdistrib: "((a::'a::ring) - b) *s x = a *s x - b *s x"
   331   by (vector ring_simps)
   332 
   333 lemma vec_eq[simp]: "(vec m = vec n) \<longleftrightarrow> (m = n)"
   334   by (simp add: Cart_eq)
   335 
   336 subsection {* Square root of sum of squares *}
   337 
   338 definition
   339   "setL2 f A = sqrt (\<Sum>i\<in>A. (f i)\<twosuperior>)"
   340 
   341 lemma setL2_cong:
   342   "\<lbrakk>A = B; \<And>x. x \<in> B \<Longrightarrow> f x = g x\<rbrakk> \<Longrightarrow> setL2 f A = setL2 g B"
   343   unfolding setL2_def by simp
   344 
   345 lemma strong_setL2_cong:
   346   "\<lbrakk>A = B; \<And>x. x \<in> B =simp=> f x = g x\<rbrakk> \<Longrightarrow> setL2 f A = setL2 g B"
   347   unfolding setL2_def simp_implies_def by simp
   348 
   349 lemma setL2_infinite [simp]: "\<not> finite A \<Longrightarrow> setL2 f A = 0"
   350   unfolding setL2_def by simp
   351 
   352 lemma setL2_empty [simp]: "setL2 f {} = 0"
   353   unfolding setL2_def by simp
   354 
   355 lemma setL2_insert [simp]:
   356   "\<lbrakk>finite F; a \<notin> F\<rbrakk> \<Longrightarrow>
   357     setL2 f (insert a F) = sqrt ((f a)\<twosuperior> + (setL2 f F)\<twosuperior>)"
   358   unfolding setL2_def by (simp add: setsum_nonneg)
   359 
   360 lemma setL2_nonneg [simp]: "0 \<le> setL2 f A"
   361   unfolding setL2_def by (simp add: setsum_nonneg)
   362 
   363 lemma setL2_0': "\<forall>a\<in>A. f a = 0 \<Longrightarrow> setL2 f A = 0"
   364   unfolding setL2_def by simp
   365 
   366 lemma setL2_mono:
   367   assumes "\<And>i. i \<in> K \<Longrightarrow> f i \<le> g i"
   368   assumes "\<And>i. i \<in> K \<Longrightarrow> 0 \<le> f i"
   369   shows "setL2 f K \<le> setL2 g K"
   370   unfolding setL2_def
   371   by (simp add: setsum_nonneg setsum_mono power_mono prems)
   372 
   373 lemma setL2_right_distrib:
   374   "0 \<le> r \<Longrightarrow> r * setL2 f A = setL2 (\<lambda>x. r * f x) A"
   375   unfolding setL2_def
   376   apply (simp add: power_mult_distrib)
   377   apply (simp add: setsum_right_distrib [symmetric])
   378   apply (simp add: real_sqrt_mult setsum_nonneg)
   379   done
   380 
   381 lemma setL2_left_distrib:
   382   "0 \<le> r \<Longrightarrow> setL2 f A * r = setL2 (\<lambda>x. f x * r) A"
   383   unfolding setL2_def
   384   apply (simp add: power_mult_distrib)
   385   apply (simp add: setsum_left_distrib [symmetric])
   386   apply (simp add: real_sqrt_mult setsum_nonneg)
   387   done
   388 
   389 lemma setsum_nonneg_eq_0_iff:
   390   fixes f :: "'a \<Rightarrow> 'b::pordered_ab_group_add"
   391   shows "\<lbrakk>finite A; \<forall>x\<in>A. 0 \<le> f x\<rbrakk> \<Longrightarrow> setsum f A = 0 \<longleftrightarrow> (\<forall>x\<in>A. f x = 0)"
   392   apply (induct set: finite, simp)
   393   apply (simp add: add_nonneg_eq_0_iff setsum_nonneg)
   394   done
   395 
   396 lemma setL2_eq_0_iff: "finite A \<Longrightarrow> setL2 f A = 0 \<longleftrightarrow> (\<forall>x\<in>A. f x = 0)"
   397   unfolding setL2_def
   398   by (simp add: setsum_nonneg setsum_nonneg_eq_0_iff)
   399 
   400 lemma setL2_triangle_ineq:
   401   shows "setL2 (\<lambda>i. f i + g i) A \<le> setL2 f A + setL2 g A"
   402 proof (cases "finite A")
   403   case False
   404   thus ?thesis by simp
   405 next
   406   case True
   407   thus ?thesis
   408   proof (induct set: finite)
   409     case empty
   410     show ?case by simp
   411   next
   412     case (insert x F)
   413     hence "sqrt ((f x + g x)\<twosuperior> + (setL2 (\<lambda>i. f i + g i) F)\<twosuperior>) \<le>
   414            sqrt ((f x + g x)\<twosuperior> + (setL2 f F + setL2 g F)\<twosuperior>)"
   415       by (intro real_sqrt_le_mono add_left_mono power_mono insert
   416                 setL2_nonneg add_increasing zero_le_power2)
   417     also have
   418       "\<dots> \<le> sqrt ((f x)\<twosuperior> + (setL2 f F)\<twosuperior>) + sqrt ((g x)\<twosuperior> + (setL2 g F)\<twosuperior>)"
   419       by (rule real_sqrt_sum_squares_triangle_ineq)
   420     finally show ?case
   421       using insert by simp
   422   qed
   423 qed
   424 
   425 lemma sqrt_sum_squares_le_sum:
   426   "\<lbrakk>0 \<le> x; 0 \<le> y\<rbrakk> \<Longrightarrow> sqrt (x\<twosuperior> + y\<twosuperior>) \<le> x + y"
   427   apply (rule power2_le_imp_le)
   428   apply (simp add: power2_sum)
   429   apply (simp add: mult_nonneg_nonneg)
   430   apply (simp add: add_nonneg_nonneg)
   431   done
   432 
   433 lemma setL2_le_setsum [rule_format]:
   434   "(\<forall>i\<in>A. 0 \<le> f i) \<longrightarrow> setL2 f A \<le> setsum f A"
   435   apply (cases "finite A")
   436   apply (induct set: finite)
   437   apply simp
   438   apply clarsimp
   439   apply (erule order_trans [OF sqrt_sum_squares_le_sum])
   440   apply simp
   441   apply simp
   442   apply simp
   443   done
   444 
   445 lemma sqrt_sum_squares_le_sum_abs: "sqrt (x\<twosuperior> + y\<twosuperior>) \<le> \<bar>x\<bar> + \<bar>y\<bar>"
   446   apply (rule power2_le_imp_le)
   447   apply (simp add: power2_sum)
   448   apply (simp add: mult_nonneg_nonneg)
   449   apply (simp add: add_nonneg_nonneg)
   450   done
   451 
   452 lemma setL2_le_setsum_abs: "setL2 f A \<le> (\<Sum>i\<in>A. \<bar>f i\<bar>)"
   453   apply (cases "finite A")
   454   apply (induct set: finite)
   455   apply simp
   456   apply simp
   457   apply (rule order_trans [OF sqrt_sum_squares_le_sum_abs])
   458   apply simp
   459   apply simp
   460   done
   461 
   462 lemma setL2_mult_ineq_lemma:
   463   fixes a b c d :: real
   464   shows "2 * (a * c) * (b * d) \<le> a\<twosuperior> * d\<twosuperior> + b\<twosuperior> * c\<twosuperior>"
   465 proof -
   466   have "0 \<le> (a * d - b * c)\<twosuperior>" by simp
   467   also have "\<dots> = a\<twosuperior> * d\<twosuperior> + b\<twosuperior> * c\<twosuperior> - 2 * (a * d) * (b * c)"
   468     by (simp only: power2_diff power_mult_distrib)
   469   also have "\<dots> = a\<twosuperior> * d\<twosuperior> + b\<twosuperior> * c\<twosuperior> - 2 * (a * c) * (b * d)"
   470     by simp
   471   finally show "2 * (a * c) * (b * d) \<le> a\<twosuperior> * d\<twosuperior> + b\<twosuperior> * c\<twosuperior>"
   472     by simp
   473 qed
   474 
   475 lemma setL2_mult_ineq: "(\<Sum>i\<in>A. \<bar>f i\<bar> * \<bar>g i\<bar>) \<le> setL2 f A * setL2 g A"
   476   apply (cases "finite A")
   477   apply (induct set: finite)
   478   apply simp
   479   apply (rule power2_le_imp_le, simp)
   480   apply (rule order_trans)
   481   apply (rule power_mono)
   482   apply (erule add_left_mono)
   483   apply (simp add: add_nonneg_nonneg mult_nonneg_nonneg setsum_nonneg)
   484   apply (simp add: power2_sum)
   485   apply (simp add: power_mult_distrib)
   486   apply (simp add: right_distrib left_distrib)
   487   apply (rule ord_le_eq_trans)
   488   apply (rule setL2_mult_ineq_lemma)
   489   apply simp
   490   apply (intro mult_nonneg_nonneg setL2_nonneg)
   491   apply simp
   492   done
   493 
   494 lemma member_le_setL2: "\<lbrakk>finite A; i \<in> A\<rbrakk> \<Longrightarrow> f i \<le> setL2 f A"
   495   apply (rule_tac s="insert i (A - {i})" and t="A" in subst)
   496   apply fast
   497   apply (subst setL2_insert)
   498   apply simp
   499   apply simp
   500   apply simp
   501   done
   502 
   503 subsection {* Norms *}
   504 
   505 instantiation "^" :: (real_normed_vector, finite) real_normed_vector
   506 begin
   507 
   508 definition vector_norm_def:
   509   "norm (x::'a^'b) = setL2 (\<lambda>i. norm (x$i)) UNIV"
   510 
   511 definition vector_sgn_def:
   512   "sgn (x::'a^'b) = scaleR (inverse (norm x)) x"
   513 
   514 instance proof
   515   fix a :: real and x y :: "'a ^ 'b"
   516   show "0 \<le> norm x"
   517     unfolding vector_norm_def
   518     by (rule setL2_nonneg)
   519   show "norm x = 0 \<longleftrightarrow> x = 0"
   520     unfolding vector_norm_def
   521     by (simp add: setL2_eq_0_iff Cart_eq)
   522   show "norm (x + y) \<le> norm x + norm y"
   523     unfolding vector_norm_def
   524     apply (rule order_trans [OF _ setL2_triangle_ineq])
   525     apply (simp add: setL2_mono norm_triangle_ineq)
   526     done
   527   show "norm (scaleR a x) = \<bar>a\<bar> * norm x"
   528     unfolding vector_norm_def
   529     by (simp add: norm_scaleR setL2_right_distrib)
   530   show "sgn x = scaleR (inverse (norm x)) x"
   531     by (rule vector_sgn_def)
   532 qed
   533 
   534 end
   535 
   536 subsection {* Inner products *}
   537 
   538 instantiation "^" :: (real_inner, finite) real_inner
   539 begin
   540 
   541 definition vector_inner_def:
   542   "inner x y = setsum (\<lambda>i. inner (x$i) (y$i)) UNIV"
   543 
   544 instance proof
   545   fix r :: real and x y z :: "'a ^ 'b"
   546   show "inner x y = inner y x"
   547     unfolding vector_inner_def
   548     by (simp add: inner_commute)
   549   show "inner (x + y) z = inner x z + inner y z"
   550     unfolding vector_inner_def
   551     by (simp add: inner_left_distrib setsum_addf)
   552   show "inner (scaleR r x) y = r * inner x y"
   553     unfolding vector_inner_def
   554     by (simp add: inner_scaleR_left setsum_right_distrib)
   555   show "0 \<le> inner x x"
   556     unfolding vector_inner_def
   557     by (simp add: setsum_nonneg)
   558   show "inner x x = 0 \<longleftrightarrow> x = 0"
   559     unfolding vector_inner_def
   560     by (simp add: Cart_eq setsum_nonneg_eq_0_iff)
   561   show "norm x = sqrt (inner x x)"
   562     unfolding vector_inner_def vector_norm_def setL2_def
   563     by (simp add: power2_norm_eq_inner)
   564 qed
   565 
   566 end
   567 
   568 subsection{* Properties of the dot product.  *}
   569 
   570 lemma dot_sym: "(x::'a:: {comm_monoid_add, ab_semigroup_mult} ^ 'n) \<bullet> y = y \<bullet> x"
   571   by (vector mult_commute)
   572 lemma dot_ladd: "((x::'a::ring ^ 'n) + y) \<bullet> z = (x \<bullet> z) + (y \<bullet> z)"
   573   by (vector ring_simps)
   574 lemma dot_radd: "x \<bullet> (y + (z::'a::ring ^ 'n)) = (x \<bullet> y) + (x \<bullet> z)"
   575   by (vector ring_simps)
   576 lemma dot_lsub: "((x::'a::ring ^ 'n) - y) \<bullet> z = (x \<bullet> z) - (y \<bullet> z)"
   577   by (vector ring_simps)
   578 lemma dot_rsub: "(x::'a::ring ^ 'n) \<bullet> (y - z) = (x \<bullet> y) - (x \<bullet> z)"
   579   by (vector ring_simps)
   580 lemma dot_lmult: "(c *s x) \<bullet> y = (c::'a::ring) * (x \<bullet> y)" by (vector ring_simps)
   581 lemma dot_rmult: "x \<bullet> (c *s y) = (c::'a::comm_ring) * (x \<bullet> y)" by (vector ring_simps)
   582 lemma dot_lneg: "(-x) \<bullet> (y::'a::ring ^ 'n) = -(x \<bullet> y)" by vector
   583 lemma dot_rneg: "(x::'a::ring ^ 'n) \<bullet> (-y) = -(x \<bullet> y)" by vector
   584 lemma dot_lzero[simp]: "0 \<bullet> x = (0::'a::{comm_monoid_add, mult_zero})" by vector
   585 lemma dot_rzero[simp]: "x \<bullet> 0 = (0::'a::{comm_monoid_add, mult_zero})" by vector
   586 lemma dot_pos_le[simp]: "(0::'a\<Colon>ordered_ring_strict) <= x \<bullet> x"
   587   by (simp add: dot_def setsum_nonneg)
   588 
   589 lemma setsum_squares_eq_0_iff: assumes fS: "finite F" and fp: "\<forall>x \<in> F. f x \<ge> (0 ::'a::pordered_ab_group_add)" shows "setsum f F = 0 \<longleftrightarrow> (ALL x:F. f x = 0)"
   590 using fS fp setsum_nonneg[OF fp]
   591 proof (induct set: finite)
   592   case empty thus ?case by simp
   593 next
   594   case (insert x F)
   595   from insert.prems have Fx: "f x \<ge> 0" and Fp: "\<forall> a \<in> F. f a \<ge> 0" by simp_all
   596   from insert.hyps Fp setsum_nonneg[OF Fp]
   597   have h: "setsum f F = 0 \<longleftrightarrow> (\<forall>a \<in>F. f a = 0)" by metis
   598   from sum_nonneg_eq_zero_iff[OF Fx  setsum_nonneg[OF Fp]] insert.hyps(1,2)
   599   show ?case by (simp add: h)
   600 qed
   601 
   602 lemma dot_eq_0: "x \<bullet> x = 0 \<longleftrightarrow> (x::'a::{ordered_ring_strict,ring_no_zero_divisors} ^ 'n::finite) = 0"
   603   by (simp add: dot_def setsum_squares_eq_0_iff Cart_eq)
   604 
   605 lemma dot_pos_lt[simp]: "(0 < x \<bullet> x) \<longleftrightarrow> (x::'a::{ordered_ring_strict,ring_no_zero_divisors} ^ 'n::finite) \<noteq> 0" using dot_eq_0[of x] dot_pos_le[of x]
   606   by (auto simp add: le_less)
   607 
   608 subsection{* The collapse of the general concepts to dimension one. *}
   609 
   610 lemma vector_one: "(x::'a ^1) = (\<chi> i. (x$1))"
   611   by (simp add: Cart_eq forall_1)
   612 
   613 lemma forall_one: "(\<forall>(x::'a ^1). P x) \<longleftrightarrow> (\<forall>x. P(\<chi> i. x))"
   614   apply auto
   615   apply (erule_tac x= "x$1" in allE)
   616   apply (simp only: vector_one[symmetric])
   617   done
   618 
   619 lemma norm_vector_1: "norm (x :: _^1) = norm (x$1)"
   620   by (simp add: vector_norm_def UNIV_1)
   621 
   622 lemma norm_real: "norm(x::real ^ 1) = abs(x$1)"
   623   by (simp add: norm_vector_1)
   624 
   625 text{* Metric *}
   626 
   627 text {* FIXME: generalize to arbitrary @{text real_normed_vector} types *}
   628 definition dist:: "real ^ 'n::finite \<Rightarrow> real ^ 'n \<Rightarrow> real" where
   629   "dist x y = norm (x - y)"
   630 
   631 lemma dist_real: "dist(x::real ^ 1) y = abs((x$1) - (y$1))"
   632   by (auto simp add: norm_real dist_def)
   633 
   634 subsection {* A connectedness or intermediate value lemma with several applications. *}
   635 
   636 lemma connected_real_lemma:
   637   fixes f :: "real \<Rightarrow> real ^ 'n::finite"
   638   assumes ab: "a \<le> b" and fa: "f a \<in> e1" and fb: "f b \<in> e2"
   639   and dst: "\<And>e x. a <= x \<Longrightarrow> x <= b \<Longrightarrow> 0 < e ==> \<exists>d > 0. \<forall>y. abs(y - x) < d \<longrightarrow> dist(f y) (f x) < e"
   640   and e1: "\<forall>y \<in> e1. \<exists>e > 0. \<forall>y'. dist y' y < e \<longrightarrow> y' \<in> e1"
   641   and e2: "\<forall>y \<in> e2. \<exists>e > 0. \<forall>y'. dist y' y < e \<longrightarrow> y' \<in> e2"
   642   and e12: "~(\<exists>x \<ge> a. x <= b \<and> f x \<in> e1 \<and> f x \<in> e2)"
   643   shows "\<exists>x \<ge> a. x <= b \<and> f x \<notin> e1 \<and> f x \<notin> e2" (is "\<exists> x. ?P x")
   644 proof-
   645   let ?S = "{c. \<forall>x \<ge> a. x <= c \<longrightarrow> f x \<in> e1}"
   646   have Se: " \<exists>x. x \<in> ?S" apply (rule exI[where x=a]) by (auto simp add: fa)
   647   have Sub: "\<exists>y. isUb UNIV ?S y"
   648     apply (rule exI[where x= b])
   649     using ab fb e12 by (auto simp add: isUb_def setle_def)
   650   from reals_complete[OF Se Sub] obtain l where
   651     l: "isLub UNIV ?S l"by blast
   652   have alb: "a \<le> l" "l \<le> b" using l ab fa fb e12
   653     apply (auto simp add: isLub_def leastP_def isUb_def setle_def setge_def)
   654     by (metis linorder_linear)
   655   have ale1: "\<forall>z \<ge> a. z < l \<longrightarrow> f z \<in> e1" using l
   656     apply (auto simp add: isLub_def leastP_def isUb_def setle_def setge_def)
   657     by (metis linorder_linear not_le)
   658     have th1: "\<And>z x e d :: real. z <= x + e \<Longrightarrow> e < d ==> z < x \<or> abs(z - x) < d" by arith
   659     have th2: "\<And>e x:: real. 0 < e ==> ~(x + e <= x)" by arith
   660     have th3: "\<And>d::real. d > 0 \<Longrightarrow> \<exists>e > 0. e < d" by dlo
   661     {assume le2: "f l \<in> e2"
   662       from le2 fa fb e12 alb have la: "l \<noteq> a" by metis
   663       hence lap: "l - a > 0" using alb by arith
   664       from e2[rule_format, OF le2] obtain e where
   665 	e: "e > 0" "\<forall>y. dist y (f l) < e \<longrightarrow> y \<in> e2" by metis
   666       from dst[OF alb e(1)] obtain d where
   667 	d: "d > 0" "\<forall>y. \<bar>y - l\<bar> < d \<longrightarrow> dist (f y) (f l) < e" by metis
   668       have "\<exists>d'. d' < d \<and> d' >0 \<and> l - d' > a" using lap d(1)
   669 	apply ferrack by arith
   670       then obtain d' where d': "d' > 0" "d' < d" "l - d' > a" by metis
   671       from d e have th0: "\<forall>y. \<bar>y - l\<bar> < d \<longrightarrow> f y \<in> e2" by metis
   672       from th0[rule_format, of "l - d'"] d' have "f (l - d') \<in> e2" by auto
   673       moreover
   674       have "f (l - d') \<in> e1" using ale1[rule_format, of "l -d'"] d' by auto
   675       ultimately have False using e12 alb d' by auto}
   676     moreover
   677     {assume le1: "f l \<in> e1"
   678     from le1 fa fb e12 alb have lb: "l \<noteq> b" by metis
   679       hence blp: "b - l > 0" using alb by arith
   680       from e1[rule_format, OF le1] obtain e where
   681 	e: "e > 0" "\<forall>y. dist y (f l) < e \<longrightarrow> y \<in> e1" by metis
   682       from dst[OF alb e(1)] obtain d where
   683 	d: "d > 0" "\<forall>y. \<bar>y - l\<bar> < d \<longrightarrow> dist (f y) (f l) < e" by metis
   684       have "\<exists>d'. d' < d \<and> d' >0" using d(1) by dlo
   685       then obtain d' where d': "d' > 0" "d' < d" by metis
   686       from d e have th0: "\<forall>y. \<bar>y - l\<bar> < d \<longrightarrow> f y \<in> e1" by auto
   687       hence "\<forall>y. l \<le> y \<and> y \<le> l + d' \<longrightarrow> f y \<in> e1" using d' by auto
   688       with ale1 have "\<forall>y. a \<le> y \<and> y \<le> l + d' \<longrightarrow> f y \<in> e1" by auto
   689       with l d' have False
   690 	by (auto simp add: isLub_def isUb_def setle_def setge_def leastP_def) }
   691     ultimately show ?thesis using alb by metis
   692 qed
   693 
   694 text{* One immediately useful corollary is the existence of square roots! --- Should help to get rid of all the development of square-root for reals as a special case @{typ "real^1"} *}
   695 
   696 lemma square_bound_lemma: "(x::real) < (1 + x) * (1 + x)"
   697 proof-
   698   have "(x + 1/2)^2 + 3/4 > 0" using zero_le_power2[of "x+1/2"] by arith
   699   thus ?thesis by (simp add: ring_simps power2_eq_square)
   700 qed
   701 
   702 lemma square_continuous: "0 < (e::real) ==> \<exists>d. 0 < d \<and> (\<forall>y. abs(y - x) < d \<longrightarrow> abs(y * y - x * x) < e)"
   703   using isCont_power[OF isCont_ident, of 2, unfolded isCont_def LIM_def, rule_format, of e x] apply (auto simp add: power2_eq_square)
   704   apply (rule_tac x="s" in exI)
   705   apply auto
   706   apply (erule_tac x=y in allE)
   707   apply auto
   708   done
   709 
   710 lemma real_le_lsqrt: "0 <= x \<Longrightarrow> 0 <= y \<Longrightarrow> x <= y^2 ==> sqrt x <= y"
   711   using real_sqrt_le_iff[of x "y^2"] by simp
   712 
   713 lemma real_le_rsqrt: "x^2 \<le> y \<Longrightarrow> x \<le> sqrt y"
   714   using real_sqrt_le_mono[of "x^2" y] by simp
   715 
   716 lemma real_less_rsqrt: "x^2 < y \<Longrightarrow> x < sqrt y"
   717   using real_sqrt_less_mono[of "x^2" y] by simp
   718 
   719 lemma sqrt_even_pow2: assumes n: "even n"
   720   shows "sqrt(2 ^ n) = 2 ^ (n div 2)"
   721 proof-
   722   from n obtain m where m: "n = 2*m" unfolding even_nat_equiv_def2
   723     by (auto simp add: nat_number)
   724   from m  have "sqrt(2 ^ n) = sqrt ((2 ^ m) ^ 2)"
   725     by (simp only: power_mult[symmetric] mult_commute)
   726   then show ?thesis  using m by simp
   727 qed
   728 
   729 lemma real_div_sqrt: "0 <= x ==> x / sqrt(x) = sqrt(x)"
   730   apply (cases "x = 0", simp_all)
   731   using sqrt_divide_self_eq[of x]
   732   apply (simp add: inverse_eq_divide real_sqrt_ge_0_iff field_simps)
   733   done
   734 
   735 text{* Hence derive more interesting properties of the norm. *}
   736 
   737 text {*
   738   This type-specific version is only here
   739   to make @{text normarith.ML} happy.
   740 *}
   741 lemma norm_0: "norm (0::real ^ _) = 0"
   742   by (rule norm_zero)
   743 
   744 lemma norm_mul[simp]: "norm(a *s x) = abs(a) * norm x"
   745   by (simp add: vector_norm_def vector_component setL2_right_distrib
   746            abs_mult cong: strong_setL2_cong)
   747 lemma norm_eq_0_dot: "(norm x = 0) \<longleftrightarrow> (x \<bullet> x = (0::real))"
   748   by (simp add: vector_norm_def dot_def setL2_def power2_eq_square)
   749 lemma real_vector_norm_def: "norm x = sqrt (x \<bullet> x)"
   750   by (simp add: vector_norm_def setL2_def dot_def power2_eq_square)
   751 lemma norm_pow_2: "norm x ^ 2 = x \<bullet> x"
   752   by (simp add: real_vector_norm_def)
   753 lemma norm_eq_0_imp: "norm x = 0 ==> x = (0::real ^'n::finite)" by (metis norm_eq_zero)
   754 lemma vector_mul_eq_0[simp]: "(a *s x = 0) \<longleftrightarrow> a = (0::'a::idom) \<or> x = 0"
   755   by vector
   756 lemma vector_mul_lcancel[simp]: "a *s x = a *s y \<longleftrightarrow> a = (0::real) \<or> x = y"
   757   by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_ssub_ldistrib)
   758 lemma vector_mul_rcancel[simp]: "a *s x = b *s x \<longleftrightarrow> (a::real) = b \<or> x = 0"
   759   by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_sub_rdistrib)
   760 lemma vector_mul_lcancel_imp: "a \<noteq> (0::real) ==>  a *s x = a *s y ==> (x = y)"
   761   by (metis vector_mul_lcancel)
   762 lemma vector_mul_rcancel_imp: "x \<noteq> 0 \<Longrightarrow> (a::real) *s x = b *s x ==> a = b"
   763   by (metis vector_mul_rcancel)
   764 lemma norm_cauchy_schwarz:
   765   fixes x y :: "real ^ 'n::finite"
   766   shows "x \<bullet> y <= norm x * norm y"
   767 proof-
   768   {assume "norm x = 0"
   769     hence ?thesis by (simp add: dot_lzero dot_rzero)}
   770   moreover
   771   {assume "norm y = 0"
   772     hence ?thesis by (simp add: dot_lzero dot_rzero)}
   773   moreover
   774   {assume h: "norm x \<noteq> 0" "norm y \<noteq> 0"
   775     let ?z = "norm y *s x - norm x *s y"
   776     from h have p: "norm x * norm y > 0" by (metis norm_ge_zero le_less zero_compare_simps)
   777     from dot_pos_le[of ?z]
   778     have "(norm x * norm y) * (x \<bullet> y) \<le> norm x ^2 * norm y ^2"
   779       apply (simp add: dot_rsub dot_lsub dot_lmult dot_rmult ring_simps)
   780       by (simp add: norm_pow_2[symmetric] power2_eq_square dot_sym)
   781     hence "x\<bullet>y \<le> (norm x ^2 * norm y ^2) / (norm x * norm y)" using p
   782       by (simp add: field_simps)
   783     hence ?thesis using h by (simp add: power2_eq_square)}
   784   ultimately show ?thesis by metis
   785 qed
   786 
   787 lemma norm_cauchy_schwarz_abs:
   788   fixes x y :: "real ^ 'n::finite"
   789   shows "\<bar>x \<bullet> y\<bar> \<le> norm x * norm y"
   790   using norm_cauchy_schwarz[of x y] norm_cauchy_schwarz[of x "-y"]
   791   by (simp add: real_abs_def dot_rneg)
   792 
   793 lemma norm_triangle_sub: "norm (x::real ^'n::finite) <= norm(y) + norm(x - y)"
   794   using norm_triangle_ineq[of "y" "x - y"] by (simp add: ring_simps)
   795 lemma norm_triangle_le: "norm(x::real ^'n::finite) + norm y <= e ==> norm(x + y) <= e"
   796   by (metis order_trans norm_triangle_ineq)
   797 lemma norm_triangle_lt: "norm(x::real ^'n::finite) + norm(y) < e ==> norm(x + y) < e"
   798   by (metis basic_trans_rules(21) norm_triangle_ineq)
   799 
   800 lemma setsum_delta:
   801   assumes fS: "finite S"
   802   shows "setsum (\<lambda>k. if k=a then b k else 0) S = (if a \<in> S then b a else 0)"
   803 proof-
   804   let ?f = "(\<lambda>k. if k=a then b k else 0)"
   805   {assume a: "a \<notin> S"
   806     hence "\<forall> k\<in> S. ?f k = 0" by simp
   807     hence ?thesis  using a by simp}
   808   moreover
   809   {assume a: "a \<in> S"
   810     let ?A = "S - {a}"
   811     let ?B = "{a}"
   812     have eq: "S = ?A \<union> ?B" using a by blast
   813     have dj: "?A \<inter> ?B = {}" by simp
   814     from fS have fAB: "finite ?A" "finite ?B" by auto
   815     have "setsum ?f S = setsum ?f ?A + setsum ?f ?B"
   816       using setsum_Un_disjoint[OF fAB dj, of ?f, unfolded eq[symmetric]]
   817       by simp
   818     then have ?thesis  using a by simp}
   819   ultimately show ?thesis by blast
   820 qed
   821 
   822 lemma component_le_norm: "\<bar>x$i\<bar> <= norm (x::real ^ 'n::finite)"
   823   apply (simp add: vector_norm_def)
   824   apply (rule member_le_setL2, simp_all)
   825   done
   826 
   827 lemma norm_bound_component_le: "norm(x::real ^ 'n::finite) <= e
   828                 ==> \<bar>x$i\<bar> <= e"
   829   by (metis component_le_norm order_trans)
   830 
   831 lemma norm_bound_component_lt: "norm(x::real ^ 'n::finite) < e
   832                 ==> \<bar>x$i\<bar> < e"
   833   by (metis component_le_norm basic_trans_rules(21))
   834 
   835 lemma norm_le_l1: "norm (x:: real ^'n::finite) <= setsum(\<lambda>i. \<bar>x$i\<bar>) UNIV"
   836   by (simp add: vector_norm_def setL2_le_setsum)
   837 
   838 lemma real_abs_norm: "\<bar>norm x\<bar> = norm (x :: real ^ _)"
   839   by (rule abs_norm_cancel)
   840 lemma real_abs_sub_norm: "\<bar>norm(x::real ^'n::finite) - norm y\<bar> <= norm(x - y)"
   841   by (rule norm_triangle_ineq3)
   842 lemma norm_le: "norm(x::real ^ _) <= norm(y) \<longleftrightarrow> x \<bullet> x <= y \<bullet> y"
   843   by (simp add: real_vector_norm_def)
   844 lemma norm_lt: "norm(x::real ^ _) < norm(y) \<longleftrightarrow> x \<bullet> x < y \<bullet> y"
   845   by (simp add: real_vector_norm_def)
   846 lemma norm_eq: "norm (x::real ^ _) = norm y \<longleftrightarrow> x \<bullet> x = y \<bullet> y"
   847   by (simp add: order_eq_iff norm_le)
   848 lemma norm_eq_1: "norm(x::real ^ _) = 1 \<longleftrightarrow> x \<bullet> x = 1"
   849   by (simp add: real_vector_norm_def)
   850 
   851 text{* Squaring equations and inequalities involving norms.  *}
   852 
   853 lemma dot_square_norm: "x \<bullet> x = norm(x)^2"
   854   by (simp add: real_vector_norm_def)
   855 
   856 lemma norm_eq_square: "norm(x) = a \<longleftrightarrow> 0 <= a \<and> x \<bullet> x = a^2"
   857   by (auto simp add: real_vector_norm_def)
   858 
   859 lemma real_abs_le_square_iff: "\<bar>x\<bar> \<le> \<bar>y\<bar> \<longleftrightarrow> (x::real)^2 \<le> y^2"
   860 proof-
   861   have "x^2 \<le> y^2 \<longleftrightarrow> (x -y) * (y + x) \<le> 0" by (simp add: ring_simps power2_eq_square)
   862   also have "\<dots> \<longleftrightarrow> \<bar>x\<bar> \<le> \<bar>y\<bar>" apply (simp add: zero_compare_simps real_abs_def not_less) by arith
   863 finally show ?thesis ..
   864 qed
   865 
   866 lemma norm_le_square: "norm(x) <= a \<longleftrightarrow> 0 <= a \<and> x \<bullet> x <= a^2"
   867   apply (simp add: dot_square_norm real_abs_le_square_iff[symmetric])
   868   using norm_ge_zero[of x]
   869   apply arith
   870   done
   871 
   872 lemma norm_ge_square: "norm(x) >= a \<longleftrightarrow> a <= 0 \<or> x \<bullet> x >= a ^ 2"
   873   apply (simp add: dot_square_norm real_abs_le_square_iff[symmetric])
   874   using norm_ge_zero[of x]
   875   apply arith
   876   done
   877 
   878 lemma norm_lt_square: "norm(x) < a \<longleftrightarrow> 0 < a \<and> x \<bullet> x < a^2"
   879   by (metis not_le norm_ge_square)
   880 lemma norm_gt_square: "norm(x) > a \<longleftrightarrow> a < 0 \<or> x \<bullet> x > a^2"
   881   by (metis norm_le_square not_less)
   882 
   883 text{* Dot product in terms of the norm rather than conversely. *}
   884 
   885 lemma dot_norm: "x \<bullet> y = (norm(x + y) ^2 - norm x ^ 2 - norm y ^ 2) / 2"
   886   by (simp add: norm_pow_2 dot_ladd dot_radd dot_sym)
   887 
   888 lemma dot_norm_neg: "x \<bullet> y = ((norm x ^ 2 + norm y ^ 2) - norm(x - y) ^ 2) / 2"
   889   by (simp add: norm_pow_2 dot_ladd dot_radd dot_lsub dot_rsub dot_sym)
   890 
   891 
   892 text{* Equality of vectors in terms of @{term "op \<bullet>"} products.    *}
   893 
   894 lemma vector_eq: "(x:: real ^ 'n::finite) = y \<longleftrightarrow> x \<bullet> x = x \<bullet> y\<and> y \<bullet> y = x \<bullet> x" (is "?lhs \<longleftrightarrow> ?rhs")
   895 proof
   896   assume "?lhs" then show ?rhs by simp
   897 next
   898   assume ?rhs
   899   then have "x \<bullet> x - x \<bullet> y = 0 \<and> x \<bullet> y - y\<bullet> y = 0" by simp
   900   hence "x \<bullet> (x - y) = 0 \<and> y \<bullet> (x - y) = 0"
   901     by (simp add: dot_rsub dot_lsub dot_sym)
   902   then have "(x - y) \<bullet> (x - y) = 0" by (simp add: ring_simps dot_lsub dot_rsub)
   903   then show "x = y" by (simp add: dot_eq_0)
   904 qed
   905 
   906 
   907 subsection{* General linear decision procedure for normed spaces. *}
   908 
   909 lemma norm_cmul_rule_thm: "b >= norm(x) ==> \<bar>c\<bar> * b >= norm(c *s x)"
   910   apply (clarsimp simp add: norm_mul)
   911   apply (rule mult_mono1)
   912   apply simp_all
   913   done
   914 
   915   (* FIXME: Move all these theorems into the ML code using lemma antiquotation *)
   916 lemma norm_add_rule_thm: "b1 >= norm(x1 :: real ^'n::finite) \<Longrightarrow> b2 >= norm(x2) ==> b1 + b2 >= norm(x1 + x2)"
   917   apply (rule norm_triangle_le) by simp
   918 
   919 lemma ge_iff_diff_ge_0: "(a::'a::ordered_ring) \<ge> b == a - b \<ge> 0"
   920   by (simp add: ring_simps)
   921 
   922 lemma pth_1: "(x::real^'n) == 1 *s x" by (simp only: vector_smult_lid)
   923 lemma pth_2: "x - (y::real^'n) == x + -y" by (atomize (full)) simp
   924 lemma pth_3: "(-x::real^'n) == -1 *s x" by vector
   925 lemma pth_4: "0 *s (x::real^'n) == 0" "c *s 0 = (0::real ^ 'n)" by vector+
   926 lemma pth_5: "c *s (d *s x) == (c * d) *s (x::real ^ 'n)" by (atomize (full)) vector
   927 lemma pth_6: "(c::real) *s (x + y) == c *s x + c *s y" by (atomize (full)) (vector ring_simps)
   928 lemma pth_7: "0 + x == (x::real^'n)" "x + 0 == x" by simp_all
   929 lemma pth_8: "(c::real) *s x + d *s x == (c + d) *s x" by (atomize (full)) (vector ring_simps)
   930 lemma pth_9: "((c::real) *s x + z) + d *s x == (c + d) *s x + z"
   931   "c *s x + (d *s x + z) == (c + d) *s x + z"
   932   "(c *s x + w) + (d *s x + z) == (c + d) *s x + (w + z)" by ((atomize (full)), vector ring_simps)+
   933 lemma pth_a: "(0::real) *s x + y == y" by (atomize (full)) vector
   934 lemma pth_b: "(c::real) *s x + d *s y == c *s x + d *s y"
   935   "(c *s x + z) + d *s y == c *s x + (z + d *s y)"
   936   "c *s x + (d *s y + z) == c *s x + (d *s y + z)"
   937   "(c *s x + w) + (d *s y + z) == c *s x + (w + (d *s y + z))"
   938   by ((atomize (full)), vector)+
   939 lemma pth_c: "(c::real) *s x + d *s y == d *s y + c *s x"
   940   "(c *s x + z) + d *s y == d *s y + (c *s x + z)"
   941   "c *s x + (d *s y + z) == d *s y + (c *s x + z)"
   942   "(c *s x + w) + (d *s y + z) == d *s y + ((c *s x + w) + z)" by ((atomize (full)), vector)+
   943 lemma pth_d: "x + (0::real ^'n) == x" by (atomize (full)) vector
   944 
   945 lemma norm_imp_pos_and_ge: "norm (x::real ^ _) == n \<Longrightarrow> norm x \<ge> 0 \<and> n \<ge> norm x"
   946   by (atomize) (auto simp add: norm_ge_zero)
   947 
   948 lemma real_eq_0_iff_le_ge_0: "(x::real) = 0 == x \<ge> 0 \<and> -x \<ge> 0" by arith
   949 
   950 lemma norm_pths:
   951   "(x::real ^'n::finite) = y \<longleftrightarrow> norm (x - y) \<le> 0"
   952   "x \<noteq> y \<longleftrightarrow> \<not> (norm (x - y) \<le> 0)"
   953   using norm_ge_zero[of "x - y"] by auto
   954 
   955 use "normarith.ML"
   956 
   957 method_setup norm = {* Scan.succeed (SIMPLE_METHOD' o NormArith.norm_arith_tac)
   958 *} "Proves simple linear statements about vector norms"
   959 
   960 
   961 
   962 text{* Hence more metric properties. *}
   963 
   964 lemma dist_refl[simp]: "dist x x = 0" by norm
   965 
   966 lemma dist_sym: "dist x y = dist y x"by norm
   967 
   968 lemma dist_pos_le[simp]: "0 <= dist x y" by norm
   969 
   970 lemma dist_triangle: "dist x z <= dist x y + dist y z" by norm
   971 
   972 lemma dist_triangle_alt: "dist y z <= dist x y + dist x z" by norm
   973 
   974 lemma dist_eq_0[simp]: "dist x y = 0 \<longleftrightarrow> x = y" by norm
   975 
   976 lemma dist_pos_lt: "x \<noteq> y ==> 0 < dist x y" by norm
   977 lemma dist_nz:  "x \<noteq> y \<longleftrightarrow> 0 < dist x y" by norm
   978 
   979 lemma dist_triangle_le: "dist x z + dist y z <= e \<Longrightarrow> dist x y <= e" by norm
   980 
   981 lemma dist_triangle_lt: "dist x z + dist y z < e ==> dist x y < e" by norm
   982 
   983 lemma dist_triangle_half_l: "dist x1 y < e / 2 \<Longrightarrow> dist x2 y < e / 2 ==> dist x1 x2 < e" by norm
   984 
   985 lemma dist_triangle_half_r: "dist y x1 < e / 2 \<Longrightarrow> dist y x2 < e / 2 ==> dist x1 x2 < e" by norm
   986 
   987 lemma dist_triangle_add: "dist (x + y) (x' + y') <= dist x x' + dist y y'"
   988   by norm
   989 
   990 lemma dist_mul[simp]: "dist (c *s x) (c *s y) = \<bar>c\<bar> * dist x y"
   991   unfolding dist_def vector_ssub_ldistrib[symmetric] norm_mul ..
   992 
   993 lemma dist_triangle_add_half: " dist x x' < e / 2 \<Longrightarrow> dist y y' < e / 2 ==> dist(x + y) (x' + y') < e" by norm
   994 
   995 lemma dist_le_0[simp]: "dist x y <= 0 \<longleftrightarrow> x = y" by norm
   996 
   997 lemma setsum_component [simp]:
   998   fixes f:: " 'a \<Rightarrow> ('b::comm_monoid_add) ^'n"
   999   shows "(setsum f S)$i = setsum (\<lambda>x. (f x)$i) S"
  1000   by (cases "finite S", induct S set: finite, simp_all)
  1001 
  1002 lemma setsum_eq: "setsum f S = (\<chi> i. setsum (\<lambda>x. (f x)$i ) S)"
  1003   by (simp add: Cart_eq)
  1004 
  1005 lemma setsum_clauses:
  1006   shows "setsum f {} = 0"
  1007   and "finite S \<Longrightarrow> setsum f (insert x S) =
  1008                  (if x \<in> S then setsum f S else f x + setsum f S)"
  1009   by (auto simp add: insert_absorb)
  1010 
  1011 lemma setsum_cmul:
  1012   fixes f:: "'c \<Rightarrow> ('a::semiring_1)^'n"
  1013   shows "setsum (\<lambda>x. c *s f x) S = c *s setsum f S"
  1014   by (simp add: Cart_eq setsum_right_distrib)
  1015 
  1016 lemma setsum_norm:
  1017   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1018   assumes fS: "finite S"
  1019   shows "norm (setsum f S) <= setsum (\<lambda>x. norm(f x)) S"
  1020 proof(induct rule: finite_induct[OF fS])
  1021   case 1 thus ?case by simp
  1022 next
  1023   case (2 x S)
  1024   from "2.hyps" have "norm (setsum f (insert x S)) \<le> norm (f x) + norm (setsum f S)" by (simp add: norm_triangle_ineq)
  1025   also have "\<dots> \<le> norm (f x) + setsum (\<lambda>x. norm(f x)) S"
  1026     using "2.hyps" by simp
  1027   finally  show ?case  using "2.hyps" by simp
  1028 qed
  1029 
  1030 lemma real_setsum_norm:
  1031   fixes f :: "'a \<Rightarrow> real ^'n::finite"
  1032   assumes fS: "finite S"
  1033   shows "norm (setsum f S) <= setsum (\<lambda>x. norm(f x)) S"
  1034 proof(induct rule: finite_induct[OF fS])
  1035   case 1 thus ?case by simp
  1036 next
  1037   case (2 x S)
  1038   from "2.hyps" have "norm (setsum f (insert x S)) \<le> norm (f x) + norm (setsum f S)" by (simp add: norm_triangle_ineq)
  1039   also have "\<dots> \<le> norm (f x) + setsum (\<lambda>x. norm(f x)) S"
  1040     using "2.hyps" by simp
  1041   finally  show ?case  using "2.hyps" by simp
  1042 qed
  1043 
  1044 lemma setsum_norm_le:
  1045   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1046   assumes fS: "finite S"
  1047   and fg: "\<forall>x \<in> S. norm (f x) \<le> g x"
  1048   shows "norm (setsum f S) \<le> setsum g S"
  1049 proof-
  1050   from fg have "setsum (\<lambda>x. norm(f x)) S <= setsum g S"
  1051     by - (rule setsum_mono, simp)
  1052   then show ?thesis using setsum_norm[OF fS, of f] fg
  1053     by arith
  1054 qed
  1055 
  1056 lemma real_setsum_norm_le:
  1057   fixes f :: "'a \<Rightarrow> real ^ 'n::finite"
  1058   assumes fS: "finite S"
  1059   and fg: "\<forall>x \<in> S. norm (f x) \<le> g x"
  1060   shows "norm (setsum f S) \<le> setsum g S"
  1061 proof-
  1062   from fg have "setsum (\<lambda>x. norm(f x)) S <= setsum g S"
  1063     by - (rule setsum_mono, simp)
  1064   then show ?thesis using real_setsum_norm[OF fS, of f] fg
  1065     by arith
  1066 qed
  1067 
  1068 lemma setsum_norm_bound:
  1069   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1070   assumes fS: "finite S"
  1071   and K: "\<forall>x \<in> S. norm (f x) \<le> K"
  1072   shows "norm (setsum f S) \<le> of_nat (card S) * K"
  1073   using setsum_norm_le[OF fS K] setsum_constant[symmetric]
  1074   by simp
  1075 
  1076 lemma real_setsum_norm_bound:
  1077   fixes f :: "'a \<Rightarrow> real ^ 'n::finite"
  1078   assumes fS: "finite S"
  1079   and K: "\<forall>x \<in> S. norm (f x) \<le> K"
  1080   shows "norm (setsum f S) \<le> of_nat (card S) * K"
  1081   using real_setsum_norm_le[OF fS K] setsum_constant[symmetric]
  1082   by simp
  1083 
  1084 lemma setsum_vmul:
  1085   fixes f :: "'a \<Rightarrow> 'b::{real_normed_vector,semiring, mult_zero}"
  1086   assumes fS: "finite S"
  1087   shows "setsum f S *s v = setsum (\<lambda>x. f x *s v) S"
  1088 proof(induct rule: finite_induct[OF fS])
  1089   case 1 then show ?case by (simp add: vector_smult_lzero)
  1090 next
  1091   case (2 x F)
  1092   from "2.hyps" have "setsum f (insert x F) *s v = (f x + setsum f F) *s v"
  1093     by simp
  1094   also have "\<dots> = f x *s v + setsum f F *s v"
  1095     by (simp add: vector_sadd_rdistrib)
  1096   also have "\<dots> = setsum (\<lambda>x. f x *s v) (insert x F)" using "2.hyps" by simp
  1097   finally show ?case .
  1098 qed
  1099 
  1100 (* FIXME : Problem thm setsum_vmul[of _ "f:: 'a \<Rightarrow> real ^'n"]  ---
  1101  Get rid of *s and use real_vector instead! Also prove that ^ creates a real_vector !! *)
  1102 
  1103 lemma setsum_add_split: assumes mn: "(m::nat) \<le> n + 1"
  1104   shows "setsum f {m..n + p} = setsum f {m..n} + setsum f {n + 1..n + p}"
  1105 proof-
  1106   let ?A = "{m .. n}"
  1107   let ?B = "{n + 1 .. n + p}"
  1108   have eq: "{m .. n+p} = ?A \<union> ?B" using mn by auto
  1109   have d: "?A \<inter> ?B = {}" by auto
  1110   from setsum_Un_disjoint[of "?A" "?B" f] eq d show ?thesis by auto
  1111 qed
  1112 
  1113 lemma setsum_natinterval_left:
  1114   assumes mn: "(m::nat) <= n"
  1115   shows "setsum f {m..n} = f m + setsum f {m + 1..n}"
  1116 proof-
  1117   from mn have "{m .. n} = insert m {m+1 .. n}" by auto
  1118   then show ?thesis by auto
  1119 qed
  1120 
  1121 lemma setsum_natinterval_difff:
  1122   fixes f:: "nat \<Rightarrow> ('a::ab_group_add)"
  1123   shows  "setsum (\<lambda>k. f k - f(k + 1)) {(m::nat) .. n} =
  1124           (if m <= n then f m - f(n + 1) else 0)"
  1125 by (induct n, auto simp add: ring_simps not_le le_Suc_eq)
  1126 
  1127 lemmas setsum_restrict_set' = setsum_restrict_set[unfolded Int_def]
  1128 
  1129 lemma setsum_setsum_restrict:
  1130   "finite S \<Longrightarrow> finite T \<Longrightarrow> setsum (\<lambda>x. setsum (\<lambda>y. f x y) {y. y\<in> T \<and> R x y}) S = setsum (\<lambda>y. setsum (\<lambda>x. f x y) {x. x \<in> S \<and> R x y}) T"
  1131   apply (simp add: setsum_restrict_set'[unfolded mem_def] mem_def)
  1132   by (rule setsum_commute)
  1133 
  1134 lemma setsum_image_gen: assumes fS: "finite S"
  1135   shows "setsum g S = setsum (\<lambda>y. setsum g {x. x \<in> S \<and> f x = y}) (f ` S)"
  1136 proof-
  1137   {fix x assume "x \<in> S" then have "{y. y\<in> f`S \<and> f x = y} = {f x}" by auto}
  1138   note th0 = this
  1139   have "setsum g S = setsum (\<lambda>x. setsum (\<lambda>y. g x) {y. y\<in> f`S \<and> f x = y}) S"
  1140     apply (rule setsum_cong2)
  1141     by (simp add: th0)
  1142   also have "\<dots> = setsum (\<lambda>y. setsum g {x. x \<in> S \<and> f x = y}) (f ` S)"
  1143     apply (rule setsum_setsum_restrict[OF fS])
  1144     by (rule finite_imageI[OF fS])
  1145   finally show ?thesis .
  1146 qed
  1147 
  1148     (* FIXME: Here too need stupid finiteness assumption on T!!! *)
  1149 lemma setsum_group:
  1150   assumes fS: "finite S" and fT: "finite T" and fST: "f ` S \<subseteq> T"
  1151   shows "setsum (\<lambda>y. setsum g {x. x\<in> S \<and> f x = y}) T = setsum g S"
  1152 
  1153 apply (subst setsum_image_gen[OF fS, of g f])
  1154 apply (rule setsum_mono_zero_right[OF fT fST])
  1155 by (auto intro: setsum_0')
  1156 
  1157 lemma vsum_norm_allsubsets_bound:
  1158   fixes f:: "'a \<Rightarrow> real ^'n::finite"
  1159   assumes fP: "finite P" and fPs: "\<And>Q. Q \<subseteq> P \<Longrightarrow> norm (setsum f Q) \<le> e"
  1160   shows "setsum (\<lambda>x. norm (f x)) P \<le> 2 * real CARD('n) *  e"
  1161 proof-
  1162   let ?d = "real CARD('n)"
  1163   let ?nf = "\<lambda>x. norm (f x)"
  1164   let ?U = "UNIV :: 'n set"
  1165   have th0: "setsum (\<lambda>x. setsum (\<lambda>i. \<bar>f x $ i\<bar>) ?U) P = setsum (\<lambda>i. setsum (\<lambda>x. \<bar>f x $ i\<bar>) P) ?U"
  1166     by (rule setsum_commute)
  1167   have th1: "2 * ?d * e = of_nat (card ?U) * (2 * e)" by (simp add: real_of_nat_def)
  1168   have "setsum ?nf P \<le> setsum (\<lambda>x. setsum (\<lambda>i. \<bar>f x $ i\<bar>) ?U) P"
  1169     apply (rule setsum_mono)
  1170     by (rule norm_le_l1)
  1171   also have "\<dots> \<le> 2 * ?d * e"
  1172     unfolding th0 th1
  1173   proof(rule setsum_bounded)
  1174     fix i assume i: "i \<in> ?U"
  1175     let ?Pp = "{x. x\<in> P \<and> f x $ i \<ge> 0}"
  1176     let ?Pn = "{x. x \<in> P \<and> f x $ i < 0}"
  1177     have thp: "P = ?Pp \<union> ?Pn" by auto
  1178     have thp0: "?Pp \<inter> ?Pn ={}" by auto
  1179     have PpP: "?Pp \<subseteq> P" and PnP: "?Pn \<subseteq> P" by blast+
  1180     have Ppe:"setsum (\<lambda>x. \<bar>f x $ i\<bar>) ?Pp \<le> e"
  1181       using component_le_norm[of "setsum (\<lambda>x. f x) ?Pp" i]  fPs[OF PpP]
  1182       by (auto intro: abs_le_D1)
  1183     have Pne: "setsum (\<lambda>x. \<bar>f x $ i\<bar>) ?Pn \<le> e"
  1184       using component_le_norm[of "setsum (\<lambda>x. - f x) ?Pn" i]  fPs[OF PnP]
  1185       by (auto simp add: setsum_negf intro: abs_le_D1)
  1186     have "setsum (\<lambda>x. \<bar>f x $ i\<bar>) P = setsum (\<lambda>x. \<bar>f x $ i\<bar>) ?Pp + setsum (\<lambda>x. \<bar>f x $ i\<bar>) ?Pn"
  1187       apply (subst thp)
  1188       apply (rule setsum_Un_zero)
  1189       using fP thp0 by auto
  1190     also have "\<dots> \<le> 2*e" using Pne Ppe by arith
  1191     finally show "setsum (\<lambda>x. \<bar>f x $ i\<bar>) P \<le> 2*e" .
  1192   qed
  1193   finally show ?thesis .
  1194 qed
  1195 
  1196 lemma dot_lsum: "finite S \<Longrightarrow> setsum f S \<bullet> (y::'a::{comm_ring}^'n) = setsum (\<lambda>x. f x \<bullet> y) S "
  1197   by (induct rule: finite_induct, auto simp add: dot_lzero dot_ladd dot_radd)
  1198 
  1199 lemma dot_rsum: "finite S \<Longrightarrow> (y::'a::{comm_ring}^'n) \<bullet> setsum f S = setsum (\<lambda>x. y \<bullet> f x) S "
  1200   by (induct rule: finite_induct, auto simp add: dot_rzero dot_radd)
  1201 
  1202 subsection{* Basis vectors in coordinate directions. *}
  1203 
  1204 
  1205 definition "basis k = (\<chi> i. if i = k then 1 else 0)"
  1206 
  1207 lemma basis_component [simp]: "basis k $ i = (if k=i then 1 else 0)"
  1208   unfolding basis_def by simp
  1209 
  1210 lemma delta_mult_idempotent:
  1211   "(if k=a then 1 else (0::'a::semiring_1)) * (if k=a then 1 else 0) = (if k=a then 1 else 0)" by (cases "k=a", auto)
  1212 
  1213 lemma norm_basis:
  1214   shows "norm (basis k :: real ^'n::finite) = 1"
  1215   apply (simp add: basis_def real_vector_norm_def dot_def)
  1216   apply (vector delta_mult_idempotent)
  1217   using setsum_delta[of "UNIV :: 'n set" "k" "\<lambda>k. 1::real"]
  1218   apply auto
  1219   done
  1220 
  1221 lemma norm_basis_1: "norm(basis 1 :: real ^'n::{finite,one}) = 1"
  1222   by (rule norm_basis)
  1223 
  1224 lemma vector_choose_size: "0 <= c ==> \<exists>(x::real^'n::finite). norm x = c"
  1225   apply (rule exI[where x="c *s basis arbitrary"])
  1226   by (simp only: norm_mul norm_basis)
  1227 
  1228 lemma vector_choose_dist: assumes e: "0 <= e"
  1229   shows "\<exists>(y::real^'n::finite). dist x y = e"
  1230 proof-
  1231   from vector_choose_size[OF e] obtain c:: "real ^'n"  where "norm c = e"
  1232     by blast
  1233   then have "dist x (x - c) = e" by (simp add: dist_def)
  1234   then show ?thesis by blast
  1235 qed
  1236 
  1237 lemma basis_inj: "inj (basis :: 'n \<Rightarrow> real ^'n::finite)"
  1238   by (simp add: inj_on_def Cart_eq)
  1239 
  1240 lemma cond_value_iff: "f (if b then x else y) = (if b then f x else f y)"
  1241   by auto
  1242 
  1243 lemma basis_expansion:
  1244   "setsum (\<lambda>i. (x$i) *s basis i) UNIV = (x::('a::ring_1) ^'n::finite)" (is "?lhs = ?rhs" is "setsum ?f ?S = _")
  1245   by (auto simp add: Cart_eq cond_value_iff setsum_delta[of "?S", where ?'b = "'a", simplified] cong del: if_weak_cong)
  1246 
  1247 lemma basis_expansion_unique:
  1248   "setsum (\<lambda>i. f i *s basis i) UNIV = (x::('a::comm_ring_1) ^'n::finite) \<longleftrightarrow> (\<forall>i. f i = x$i)"
  1249   by (simp add: Cart_eq setsum_delta cond_value_iff cong del: if_weak_cong)
  1250 
  1251 lemma cond_application_beta: "(if b then f else g) x = (if b then f x else g x)"
  1252   by auto
  1253 
  1254 lemma dot_basis:
  1255   shows "basis i \<bullet> x = x$i" "x \<bullet> (basis i :: 'a^'n::finite) = (x$i :: 'a::semiring_1)"
  1256   by (auto simp add: dot_def basis_def cond_application_beta  cond_value_iff setsum_delta cong del: if_weak_cong)
  1257 
  1258 lemma basis_eq_0: "basis i = (0::'a::semiring_1^'n) \<longleftrightarrow> False"
  1259   by (auto simp add: Cart_eq)
  1260 
  1261 lemma basis_nonzero:
  1262   shows "basis k \<noteq> (0:: 'a::semiring_1 ^'n)"
  1263   by (simp add: basis_eq_0)
  1264 
  1265 lemma vector_eq_ldot: "(\<forall>x. x \<bullet> y = x \<bullet> z) \<longleftrightarrow> y = (z::'a::semiring_1^'n::finite)"
  1266   apply (auto simp add: Cart_eq dot_basis)
  1267   apply (erule_tac x="basis i" in allE)
  1268   apply (simp add: dot_basis)
  1269   apply (subgoal_tac "y = z")
  1270   apply simp
  1271   apply (simp add: Cart_eq)
  1272   done
  1273 
  1274 lemma vector_eq_rdot: "(\<forall>z. x \<bullet> z = y \<bullet> z) \<longleftrightarrow> x = (y::'a::semiring_1^'n::finite)"
  1275   apply (auto simp add: Cart_eq dot_basis)
  1276   apply (erule_tac x="basis i" in allE)
  1277   apply (simp add: dot_basis)
  1278   apply (subgoal_tac "x = y")
  1279   apply simp
  1280   apply (simp add: Cart_eq)
  1281   done
  1282 
  1283 subsection{* Orthogonality. *}
  1284 
  1285 definition "orthogonal x y \<longleftrightarrow> (x \<bullet> y = 0)"
  1286 
  1287 lemma orthogonal_basis:
  1288   shows "orthogonal (basis i :: 'a^'n::finite) x \<longleftrightarrow> x$i = (0::'a::ring_1)"
  1289   by (auto simp add: orthogonal_def dot_def basis_def cond_value_iff cond_application_beta setsum_delta cong del: if_weak_cong)
  1290 
  1291 lemma orthogonal_basis_basis:
  1292   shows "orthogonal (basis i :: 'a::ring_1^'n::finite) (basis j) \<longleftrightarrow> i \<noteq> j"
  1293   unfolding orthogonal_basis[of i] basis_component[of j] by simp
  1294 
  1295   (* FIXME : Maybe some of these require less than comm_ring, but not all*)
  1296 lemma orthogonal_clauses:
  1297   "orthogonal a (0::'a::comm_ring ^'n)"
  1298   "orthogonal a x ==> orthogonal a (c *s x)"
  1299   "orthogonal a x ==> orthogonal a (-x)"
  1300   "orthogonal a x \<Longrightarrow> orthogonal a y ==> orthogonal a (x + y)"
  1301   "orthogonal a x \<Longrightarrow> orthogonal a y ==> orthogonal a (x - y)"
  1302   "orthogonal 0 a"
  1303   "orthogonal x a ==> orthogonal (c *s x) a"
  1304   "orthogonal x a ==> orthogonal (-x) a"
  1305   "orthogonal x a \<Longrightarrow> orthogonal y a ==> orthogonal (x + y) a"
  1306   "orthogonal x a \<Longrightarrow> orthogonal y a ==> orthogonal (x - y) a"
  1307   unfolding orthogonal_def dot_rneg dot_rmult dot_radd dot_rsub
  1308   dot_lzero dot_rzero dot_lneg dot_lmult dot_ladd dot_lsub
  1309   by simp_all
  1310 
  1311 lemma orthogonal_commute: "orthogonal (x::'a::{ab_semigroup_mult,comm_monoid_add} ^'n)y \<longleftrightarrow> orthogonal y x"
  1312   by (simp add: orthogonal_def dot_sym)
  1313 
  1314 subsection{* Explicit vector construction from lists. *}
  1315 
  1316 primrec from_nat :: "nat \<Rightarrow> 'a::{monoid_add,one}"
  1317 where "from_nat 0 = 0" | "from_nat (Suc n) = 1 + from_nat n"
  1318 
  1319 lemma from_nat [simp]: "from_nat = of_nat"
  1320 by (rule ext, induct_tac x, simp_all)
  1321 
  1322 primrec
  1323   list_fun :: "nat \<Rightarrow> _ list \<Rightarrow> _ \<Rightarrow> _"
  1324 where
  1325   "list_fun n [] = (\<lambda>x. 0)"
  1326 | "list_fun n (x # xs) = fun_upd (list_fun (Suc n) xs) (from_nat n) x"
  1327 
  1328 definition "vector l = (\<chi> i. list_fun 1 l i)"
  1329 (*definition "vector l = (\<chi> i. if i <= length l then l ! (i - 1) else 0)"*)
  1330 
  1331 lemma vector_1: "(vector[x]) $1 = x"
  1332   unfolding vector_def by simp
  1333 
  1334 lemma vector_2:
  1335  "(vector[x,y]) $1 = x"
  1336  "(vector[x,y] :: 'a^2)$2 = (y::'a::zero)"
  1337   unfolding vector_def by simp_all
  1338 
  1339 lemma vector_3:
  1340  "(vector [x,y,z] ::('a::zero)^3)$1 = x"
  1341  "(vector [x,y,z] ::('a::zero)^3)$2 = y"
  1342  "(vector [x,y,z] ::('a::zero)^3)$3 = z"
  1343   unfolding vector_def by simp_all
  1344 
  1345 lemma forall_vector_1: "(\<forall>v::'a::zero^1. P v) \<longleftrightarrow> (\<forall>x. P(vector[x]))"
  1346   apply auto
  1347   apply (erule_tac x="v$1" in allE)
  1348   apply (subgoal_tac "vector [v$1] = v")
  1349   apply simp
  1350   apply (vector vector_def)
  1351   apply (simp add: forall_1)
  1352   done
  1353 
  1354 lemma forall_vector_2: "(\<forall>v::'a::zero^2. P v) \<longleftrightarrow> (\<forall>x y. P(vector[x, y]))"
  1355   apply auto
  1356   apply (erule_tac x="v$1" in allE)
  1357   apply (erule_tac x="v$2" in allE)
  1358   apply (subgoal_tac "vector [v$1, v$2] = v")
  1359   apply simp
  1360   apply (vector vector_def)
  1361   apply (simp add: forall_2)
  1362   done
  1363 
  1364 lemma forall_vector_3: "(\<forall>v::'a::zero^3. P v) \<longleftrightarrow> (\<forall>x y z. P(vector[x, y, z]))"
  1365   apply auto
  1366   apply (erule_tac x="v$1" in allE)
  1367   apply (erule_tac x="v$2" in allE)
  1368   apply (erule_tac x="v$3" in allE)
  1369   apply (subgoal_tac "vector [v$1, v$2, v$3] = v")
  1370   apply simp
  1371   apply (vector vector_def)
  1372   apply (simp add: forall_3)
  1373   done
  1374 
  1375 subsection{* Linear functions. *}
  1376 
  1377 definition "linear f \<longleftrightarrow> (\<forall>x y. f(x + y) = f x + f y) \<and> (\<forall>c x. f(c *s x) = c *s f x)"
  1378 
  1379 lemma linear_compose_cmul: "linear f ==> linear (\<lambda>x. (c::'a::comm_semiring) *s f x)"
  1380   by (vector linear_def Cart_eq ring_simps)
  1381 
  1382 lemma linear_compose_neg: "linear (f :: 'a ^'n \<Rightarrow> 'a::comm_ring ^'m) ==> linear (\<lambda>x. -(f(x)))" by (vector linear_def Cart_eq)
  1383 
  1384 lemma linear_compose_add: "linear (f :: 'a ^'n \<Rightarrow> 'a::semiring_1 ^'m) \<Longrightarrow> linear g ==> linear (\<lambda>x. f(x) + g(x))"
  1385   by (vector linear_def Cart_eq ring_simps)
  1386 
  1387 lemma linear_compose_sub: "linear (f :: 'a ^'n \<Rightarrow> 'a::ring_1 ^'m) \<Longrightarrow> linear g ==> linear (\<lambda>x. f x - g x)"
  1388   by (vector linear_def Cart_eq ring_simps)
  1389 
  1390 lemma linear_compose: "linear f \<Longrightarrow> linear g ==> linear (g o f)"
  1391   by (simp add: linear_def)
  1392 
  1393 lemma linear_id: "linear id" by (simp add: linear_def id_def)
  1394 
  1395 lemma linear_zero: "linear (\<lambda>x. 0::'a::semiring_1 ^ 'n)" by (simp add: linear_def)
  1396 
  1397 lemma linear_compose_setsum:
  1398   assumes fS: "finite S" and lS: "\<forall>a \<in> S. linear (f a :: 'a::semiring_1 ^ 'n \<Rightarrow> 'a ^ 'm)"
  1399   shows "linear(\<lambda>x. setsum (\<lambda>a. f a x :: 'a::semiring_1 ^'m) S)"
  1400   using lS
  1401   apply (induct rule: finite_induct[OF fS])
  1402   by (auto simp add: linear_zero intro: linear_compose_add)
  1403 
  1404 lemma linear_vmul_component:
  1405   fixes f:: "'a::semiring_1^'m \<Rightarrow> 'a^'n"
  1406   assumes lf: "linear f"
  1407   shows "linear (\<lambda>x. f x $ k *s v)"
  1408   using lf
  1409   apply (auto simp add: linear_def )
  1410   by (vector ring_simps)+
  1411 
  1412 lemma linear_0: "linear f ==> f 0 = (0::'a::semiring_1 ^'n)"
  1413   unfolding linear_def
  1414   apply clarsimp
  1415   apply (erule allE[where x="0::'a"])
  1416   apply simp
  1417   done
  1418 
  1419 lemma linear_cmul: "linear f ==> f(c*s x) = c *s f x" by (simp add: linear_def)
  1420 
  1421 lemma linear_neg: "linear (f :: 'a::ring_1 ^'n \<Rightarrow> _) ==> f (-x) = - f x"
  1422   unfolding vector_sneg_minus1
  1423   using linear_cmul[of f] by auto
  1424 
  1425 lemma linear_add: "linear f ==> f(x + y) = f x + f y" by (metis linear_def)
  1426 
  1427 lemma linear_sub: "linear (f::'a::ring_1 ^'n \<Rightarrow> _) ==> f(x - y) = f x - f y"
  1428   by (simp add: diff_def linear_add linear_neg)
  1429 
  1430 lemma linear_setsum:
  1431   fixes f:: "'a::semiring_1^'n \<Rightarrow> _"
  1432   assumes lf: "linear f" and fS: "finite S"
  1433   shows "f (setsum g S) = setsum (f o g) S"
  1434 proof (induct rule: finite_induct[OF fS])
  1435   case 1 thus ?case by (simp add: linear_0[OF lf])
  1436 next
  1437   case (2 x F)
  1438   have "f (setsum g (insert x F)) = f (g x + setsum g F)" using "2.hyps"
  1439     by simp
  1440   also have "\<dots> = f (g x) + f (setsum g F)" using linear_add[OF lf] by simp
  1441   also have "\<dots> = setsum (f o g) (insert x F)" using "2.hyps" by simp
  1442   finally show ?case .
  1443 qed
  1444 
  1445 lemma linear_setsum_mul:
  1446   fixes f:: "'a ^'n \<Rightarrow> 'a::semiring_1^'m"
  1447   assumes lf: "linear f" and fS: "finite S"
  1448   shows "f (setsum (\<lambda>i. c i *s v i) S) = setsum (\<lambda>i. c i *s f (v i)) S"
  1449   using linear_setsum[OF lf fS, of "\<lambda>i. c i *s v i" , unfolded o_def]
  1450   linear_cmul[OF lf] by simp
  1451 
  1452 lemma linear_injective_0:
  1453   assumes lf: "linear (f:: 'a::ring_1 ^ 'n \<Rightarrow> _)"
  1454   shows "inj f \<longleftrightarrow> (\<forall>x. f x = 0 \<longrightarrow> x = 0)"
  1455 proof-
  1456   have "inj f \<longleftrightarrow> (\<forall> x y. f x = f y \<longrightarrow> x = y)" by (simp add: inj_on_def)
  1457   also have "\<dots> \<longleftrightarrow> (\<forall> x y. f x - f y = 0 \<longrightarrow> x - y = 0)" by simp
  1458   also have "\<dots> \<longleftrightarrow> (\<forall> x y. f (x - y) = 0 \<longrightarrow> x - y = 0)"
  1459     by (simp add: linear_sub[OF lf])
  1460   also have "\<dots> \<longleftrightarrow> (\<forall> x. f x = 0 \<longrightarrow> x = 0)" by auto
  1461   finally show ?thesis .
  1462 qed
  1463 
  1464 lemma linear_bounded:
  1465   fixes f:: "real ^'m::finite \<Rightarrow> real ^'n::finite"
  1466   assumes lf: "linear f"
  1467   shows "\<exists>B. \<forall>x. norm (f x) \<le> B * norm x"
  1468 proof-
  1469   let ?S = "UNIV:: 'm set"
  1470   let ?B = "setsum (\<lambda>i. norm(f(basis i))) ?S"
  1471   have fS: "finite ?S" by simp
  1472   {fix x:: "real ^ 'm"
  1473     let ?g = "(\<lambda>i. (x$i) *s (basis i) :: real ^ 'm)"
  1474     have "norm (f x) = norm (f (setsum (\<lambda>i. (x$i) *s (basis i)) ?S))"
  1475       by (simp only:  basis_expansion)
  1476     also have "\<dots> = norm (setsum (\<lambda>i. (x$i) *s f (basis i))?S)"
  1477       using linear_setsum[OF lf fS, of ?g, unfolded o_def] linear_cmul[OF lf]
  1478       by auto
  1479     finally have th0: "norm (f x) = norm (setsum (\<lambda>i. (x$i) *s f (basis i))?S)" .
  1480     {fix i assume i: "i \<in> ?S"
  1481       from component_le_norm[of x i]
  1482       have "norm ((x$i) *s f (basis i :: real ^'m)) \<le> norm (f (basis i)) * norm x"
  1483       unfolding norm_mul
  1484       apply (simp only: mult_commute)
  1485       apply (rule mult_mono)
  1486       by (auto simp add: ring_simps norm_ge_zero) }
  1487     then have th: "\<forall>i\<in> ?S. norm ((x$i) *s f (basis i :: real ^'m)) \<le> norm (f (basis i)) * norm x" by metis
  1488     from real_setsum_norm_le[OF fS, of "\<lambda>i. (x$i) *s (f (basis i))", OF th]
  1489     have "norm (f x) \<le> ?B * norm x" unfolding th0 setsum_left_distrib by metis}
  1490   then show ?thesis by blast
  1491 qed
  1492 
  1493 lemma linear_bounded_pos:
  1494   fixes f:: "real ^'n::finite \<Rightarrow> real ^ 'm::finite"
  1495   assumes lf: "linear f"
  1496   shows "\<exists>B > 0. \<forall>x. norm (f x) \<le> B * norm x"
  1497 proof-
  1498   from linear_bounded[OF lf] obtain B where
  1499     B: "\<forall>x. norm (f x) \<le> B * norm x" by blast
  1500   let ?K = "\<bar>B\<bar> + 1"
  1501   have Kp: "?K > 0" by arith
  1502     {assume C: "B < 0"
  1503       have "norm (1::real ^ 'n) > 0" by (simp add: zero_less_norm_iff)
  1504       with C have "B * norm (1:: real ^ 'n) < 0"
  1505 	by (simp add: zero_compare_simps)
  1506       with B[rule_format, of 1] norm_ge_zero[of "f 1"] have False by simp
  1507     }
  1508     then have Bp: "B \<ge> 0" by ferrack
  1509     {fix x::"real ^ 'n"
  1510       have "norm (f x) \<le> ?K *  norm x"
  1511       using B[rule_format, of x] norm_ge_zero[of x] norm_ge_zero[of "f x"] Bp
  1512       apply (auto simp add: ring_simps split add: abs_split)
  1513       apply (erule order_trans, simp)
  1514       done
  1515   }
  1516   then show ?thesis using Kp by blast
  1517 qed
  1518 
  1519 subsection{* Bilinear functions. *}
  1520 
  1521 definition "bilinear f \<longleftrightarrow> (\<forall>x. linear(\<lambda>y. f x y)) \<and> (\<forall>y. linear(\<lambda>x. f x y))"
  1522 
  1523 lemma bilinear_ladd: "bilinear h ==> h (x + y) z = (h x z) + (h y z)"
  1524   by (simp add: bilinear_def linear_def)
  1525 lemma bilinear_radd: "bilinear h ==> h x (y + z) = (h x y) + (h x z)"
  1526   by (simp add: bilinear_def linear_def)
  1527 
  1528 lemma bilinear_lmul: "bilinear h ==> h (c *s x) y = c *s (h x y)"
  1529   by (simp add: bilinear_def linear_def)
  1530 
  1531 lemma bilinear_rmul: "bilinear h ==> h x (c *s y) = c *s (h x y)"
  1532   by (simp add: bilinear_def linear_def)
  1533 
  1534 lemma bilinear_lneg: "bilinear h ==> h (- (x:: 'a::ring_1 ^ 'n)) y = -(h x y)"
  1535   by (simp only: vector_sneg_minus1 bilinear_lmul)
  1536 
  1537 lemma bilinear_rneg: "bilinear h ==> h x (- (y:: 'a::ring_1 ^ 'n)) = - h x y"
  1538   by (simp only: vector_sneg_minus1 bilinear_rmul)
  1539 
  1540 lemma  (in ab_group_add) eq_add_iff: "x = x + y \<longleftrightarrow> y = 0"
  1541   using add_imp_eq[of x y 0] by auto
  1542 
  1543 lemma bilinear_lzero:
  1544   fixes h :: "'a::ring^'n \<Rightarrow> _" assumes bh: "bilinear h" shows "h 0 x = 0"
  1545   using bilinear_ladd[OF bh, of 0 0 x]
  1546     by (simp add: eq_add_iff ring_simps)
  1547 
  1548 lemma bilinear_rzero:
  1549   fixes h :: "'a::ring^'n \<Rightarrow> _" assumes bh: "bilinear h" shows "h x 0 = 0"
  1550   using bilinear_radd[OF bh, of x 0 0 ]
  1551     by (simp add: eq_add_iff ring_simps)
  1552 
  1553 lemma bilinear_lsub: "bilinear h ==> h (x - (y:: 'a::ring_1 ^ 'n)) z = h x z - h y z"
  1554   by (simp  add: diff_def bilinear_ladd bilinear_lneg)
  1555 
  1556 lemma bilinear_rsub: "bilinear h ==> h z (x - (y:: 'a::ring_1 ^ 'n)) = h z x - h z y"
  1557   by (simp  add: diff_def bilinear_radd bilinear_rneg)
  1558 
  1559 lemma bilinear_setsum:
  1560   fixes h:: "'a ^'n \<Rightarrow> 'a::semiring_1^'m \<Rightarrow> 'a ^ 'k"
  1561   assumes bh: "bilinear h" and fS: "finite S" and fT: "finite T"
  1562   shows "h (setsum f S) (setsum g T) = setsum (\<lambda>(i,j). h (f i) (g j)) (S \<times> T) "
  1563 proof-
  1564   have "h (setsum f S) (setsum g T) = setsum (\<lambda>x. h (f x) (setsum g T)) S"
  1565     apply (rule linear_setsum[unfolded o_def])
  1566     using bh fS by (auto simp add: bilinear_def)
  1567   also have "\<dots> = setsum (\<lambda>x. setsum (\<lambda>y. h (f x) (g y)) T) S"
  1568     apply (rule setsum_cong, simp)
  1569     apply (rule linear_setsum[unfolded o_def])
  1570     using bh fT by (auto simp add: bilinear_def)
  1571   finally show ?thesis unfolding setsum_cartesian_product .
  1572 qed
  1573 
  1574 lemma bilinear_bounded:
  1575   fixes h:: "real ^'m::finite \<Rightarrow> real^'n::finite \<Rightarrow> real ^ 'k::finite"
  1576   assumes bh: "bilinear h"
  1577   shows "\<exists>B. \<forall>x y. norm (h x y) \<le> B * norm x * norm y"
  1578 proof-
  1579   let ?M = "UNIV :: 'm set"
  1580   let ?N = "UNIV :: 'n set"
  1581   let ?B = "setsum (\<lambda>(i,j). norm (h (basis i) (basis j))) (?M \<times> ?N)"
  1582   have fM: "finite ?M" and fN: "finite ?N" by simp_all
  1583   {fix x:: "real ^ 'm" and  y :: "real^'n"
  1584     have "norm (h x y) = norm (h (setsum (\<lambda>i. (x$i) *s basis i) ?M) (setsum (\<lambda>i. (y$i) *s basis i) ?N))" unfolding basis_expansion ..
  1585     also have "\<dots> = norm (setsum (\<lambda> (i,j). h ((x$i) *s basis i) ((y$j) *s basis j)) (?M \<times> ?N))"  unfolding bilinear_setsum[OF bh fM fN] ..
  1586     finally have th: "norm (h x y) = \<dots>" .
  1587     have "norm (h x y) \<le> ?B * norm x * norm y"
  1588       apply (simp add: setsum_left_distrib th)
  1589       apply (rule real_setsum_norm_le)
  1590       using fN fM
  1591       apply simp
  1592       apply (auto simp add: bilinear_rmul[OF bh] bilinear_lmul[OF bh] norm_mul ring_simps)
  1593       apply (rule mult_mono)
  1594       apply (auto simp add: norm_ge_zero zero_le_mult_iff component_le_norm)
  1595       apply (rule mult_mono)
  1596       apply (auto simp add: norm_ge_zero zero_le_mult_iff component_le_norm)
  1597       done}
  1598   then show ?thesis by metis
  1599 qed
  1600 
  1601 lemma bilinear_bounded_pos:
  1602   fixes h:: "real ^'m::finite \<Rightarrow> real^'n::finite \<Rightarrow> real ^ 'k::finite"
  1603   assumes bh: "bilinear h"
  1604   shows "\<exists>B > 0. \<forall>x y. norm (h x y) \<le> B * norm x * norm y"
  1605 proof-
  1606   from bilinear_bounded[OF bh] obtain B where
  1607     B: "\<forall>x y. norm (h x y) \<le> B * norm x * norm y" by blast
  1608   let ?K = "\<bar>B\<bar> + 1"
  1609   have Kp: "?K > 0" by arith
  1610   have KB: "B < ?K" by arith
  1611   {fix x::"real ^'m" and y :: "real ^'n"
  1612     from KB Kp
  1613     have "B * norm x * norm y \<le> ?K * norm x * norm y"
  1614       apply -
  1615       apply (rule mult_right_mono, rule mult_right_mono)
  1616       by (auto simp add: norm_ge_zero)
  1617     then have "norm (h x y) \<le> ?K * norm x * norm y"
  1618       using B[rule_format, of x y] by simp}
  1619   with Kp show ?thesis by blast
  1620 qed
  1621 
  1622 subsection{* Adjoints. *}
  1623 
  1624 definition "adjoint f = (SOME f'. \<forall>x y. f x \<bullet> y = x \<bullet> f' y)"
  1625 
  1626 lemma choice_iff: "(\<forall>x. \<exists>y. P x y) \<longleftrightarrow> (\<exists>f. \<forall>x. P x (f x))" by metis
  1627 
  1628 lemma adjoint_works_lemma:
  1629   fixes f:: "'a::ring_1 ^'n::finite \<Rightarrow> 'a ^ 'm::finite"
  1630   assumes lf: "linear f"
  1631   shows "\<forall>x y. f x \<bullet> y = x \<bullet> adjoint f y"
  1632 proof-
  1633   let ?N = "UNIV :: 'n set"
  1634   let ?M = "UNIV :: 'm set"
  1635   have fN: "finite ?N" by simp
  1636   have fM: "finite ?M" by simp
  1637   {fix y:: "'a ^ 'm"
  1638     let ?w = "(\<chi> i. (f (basis i) \<bullet> y)) :: 'a ^ 'n"
  1639     {fix x
  1640       have "f x \<bullet> y = f (setsum (\<lambda>i. (x$i) *s basis i) ?N) \<bullet> y"
  1641 	by (simp only: basis_expansion)
  1642       also have "\<dots> = (setsum (\<lambda>i. (x$i) *s f (basis i)) ?N) \<bullet> y"
  1643 	unfolding linear_setsum[OF lf fN]
  1644 	by (simp add: linear_cmul[OF lf])
  1645       finally have "f x \<bullet> y = x \<bullet> ?w"
  1646 	apply (simp only: )
  1647 	apply (simp add: dot_def setsum_left_distrib setsum_right_distrib setsum_commute[of _ ?M ?N] ring_simps)
  1648 	done}
  1649   }
  1650   then show ?thesis unfolding adjoint_def
  1651     some_eq_ex[of "\<lambda>f'. \<forall>x y. f x \<bullet> y = x \<bullet> f' y"]
  1652     using choice_iff[of "\<lambda>a b. \<forall>x. f x \<bullet> a = x \<bullet> b "]
  1653     by metis
  1654 qed
  1655 
  1656 lemma adjoint_works:
  1657   fixes f:: "'a::ring_1 ^'n::finite \<Rightarrow> 'a ^ 'm::finite"
  1658   assumes lf: "linear f"
  1659   shows "x \<bullet> adjoint f y = f x \<bullet> y"
  1660   using adjoint_works_lemma[OF lf] by metis
  1661 
  1662 
  1663 lemma adjoint_linear:
  1664   fixes f :: "'a::comm_ring_1 ^'n::finite \<Rightarrow> 'a ^ 'm::finite"
  1665   assumes lf: "linear f"
  1666   shows "linear (adjoint f)"
  1667   by (simp add: linear_def vector_eq_ldot[symmetric] dot_radd dot_rmult adjoint_works[OF lf])
  1668 
  1669 lemma adjoint_clauses:
  1670   fixes f:: "'a::comm_ring_1 ^'n::finite \<Rightarrow> 'a ^ 'm::finite"
  1671   assumes lf: "linear f"
  1672   shows "x \<bullet> adjoint f y = f x \<bullet> y"
  1673   and "adjoint f y \<bullet> x = y \<bullet> f x"
  1674   by (simp_all add: adjoint_works[OF lf] dot_sym )
  1675 
  1676 lemma adjoint_adjoint:
  1677   fixes f:: "'a::comm_ring_1 ^ 'n::finite \<Rightarrow> 'a ^ 'm::finite"
  1678   assumes lf: "linear f"
  1679   shows "adjoint (adjoint f) = f"
  1680   apply (rule ext)
  1681   by (simp add: vector_eq_ldot[symmetric] adjoint_clauses[OF adjoint_linear[OF lf]] adjoint_clauses[OF lf])
  1682 
  1683 lemma adjoint_unique:
  1684   fixes f:: "'a::comm_ring_1 ^ 'n::finite \<Rightarrow> 'a ^ 'm::finite"
  1685   assumes lf: "linear f" and u: "\<forall>x y. f' x \<bullet> y = x \<bullet> f y"
  1686   shows "f' = adjoint f"
  1687   apply (rule ext)
  1688   using u
  1689   by (simp add: vector_eq_rdot[symmetric] adjoint_clauses[OF lf])
  1690 
  1691 text{* Matrix notation. NB: an MxN matrix is of type @{typ "'a^'n^'m"}, not @{typ "'a^'m^'n"} *}
  1692 
  1693 consts generic_mult :: "'a \<Rightarrow> 'b \<Rightarrow> 'c" (infixr "\<star>" 75)
  1694 
  1695 defs (overloaded)
  1696 matrix_matrix_mult_def: "(m:: ('a::semiring_1) ^'n^'m) \<star> (m' :: 'a ^'p^'n) \<equiv> (\<chi> i j. setsum (\<lambda>k. ((m$i)$k) * ((m'$k)$j)) (UNIV :: 'n set)) ::'a ^ 'p ^'m"
  1697 
  1698 abbreviation
  1699   matrix_matrix_mult' :: "('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'p^'n \<Rightarrow> 'a ^ 'p ^'m"  (infixl "**" 70)
  1700   where "m ** m' == m\<star> m'"
  1701 
  1702 defs (overloaded)
  1703   matrix_vector_mult_def: "(m::('a::semiring_1) ^'n^'m) \<star> (x::'a ^'n) \<equiv> (\<chi> i. setsum (\<lambda>j. ((m$i)$j) * (x$j)) (UNIV ::'n set)) :: 'a^'m"
  1704 
  1705 abbreviation
  1706   matrix_vector_mult' :: "('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'n \<Rightarrow> 'a ^ 'm"  (infixl "*v" 70)
  1707   where
  1708   "m *v v == m \<star> v"
  1709 
  1710 defs (overloaded)
  1711   vector_matrix_mult_def: "(x::'a^'m) \<star> (m::('a::semiring_1) ^'n^'m) \<equiv> (\<chi> j. setsum (\<lambda>i. ((m$i)$j) * (x$i)) (UNIV :: 'm set)) :: 'a^'n"
  1712 
  1713 abbreviation
  1714   vactor_matrix_mult' :: "'a ^ 'm \<Rightarrow> ('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'n "  (infixl "v*" 70)
  1715   where
  1716   "v v* m == v \<star> m"
  1717 
  1718 definition "(mat::'a::zero => 'a ^'n^'n) k = (\<chi> i j. if i = j then k else 0)"
  1719 definition "(transp::'a^'n^'m \<Rightarrow> 'a^'m^'n) A = (\<chi> i j. ((A$j)$i))"
  1720 definition "(row::'m => 'a ^'n^'m \<Rightarrow> 'a ^'n) i A = (\<chi> j. ((A$i)$j))"
  1721 definition "(column::'n =>'a^'n^'m =>'a^'m) j A = (\<chi> i. ((A$i)$j))"
  1722 definition "rows(A::'a^'n^'m) = { row i A | i. i \<in> (UNIV :: 'm set)}"
  1723 definition "columns(A::'a^'n^'m) = { column i A | i. i \<in> (UNIV :: 'n set)}"
  1724 
  1725 lemma mat_0[simp]: "mat 0 = 0" by (vector mat_def)
  1726 lemma matrix_add_ldistrib: "(A ** (B + C)) = (A \<star> B) + (A \<star> C)"
  1727   by (vector matrix_matrix_mult_def setsum_addf[symmetric] ring_simps)
  1728 
  1729 lemma setsum_delta':
  1730   assumes fS: "finite S" shows
  1731   "setsum (\<lambda>k. if a = k then b k else 0) S =
  1732      (if a\<in> S then b a else 0)"
  1733   using setsum_delta[OF fS, of a b, symmetric]
  1734   by (auto intro: setsum_cong)
  1735 
  1736 lemma matrix_mul_lid:
  1737   fixes A :: "'a::semiring_1 ^ 'm ^ 'n::finite"
  1738   shows "mat 1 ** A = A"
  1739   apply (simp add: matrix_matrix_mult_def mat_def)
  1740   apply vector
  1741   by (auto simp only: cond_value_iff cond_application_beta setsum_delta'[OF finite]  mult_1_left mult_zero_left if_True UNIV_I)
  1742 
  1743 
  1744 lemma matrix_mul_rid:
  1745   fixes A :: "'a::semiring_1 ^ 'm::finite ^ 'n"
  1746   shows "A ** mat 1 = A"
  1747   apply (simp add: matrix_matrix_mult_def mat_def)
  1748   apply vector
  1749   by (auto simp only: cond_value_iff cond_application_beta setsum_delta[OF finite]  mult_1_right mult_zero_right if_True UNIV_I cong: if_cong)
  1750 
  1751 lemma matrix_mul_assoc: "A ** (B ** C) = (A ** B) ** C"
  1752   apply (vector matrix_matrix_mult_def setsum_right_distrib setsum_left_distrib mult_assoc)
  1753   apply (subst setsum_commute)
  1754   apply simp
  1755   done
  1756 
  1757 lemma matrix_vector_mul_assoc: "A *v (B *v x) = (A ** B) *v x"
  1758   apply (vector matrix_matrix_mult_def matrix_vector_mult_def setsum_right_distrib setsum_left_distrib mult_assoc)
  1759   apply (subst setsum_commute)
  1760   apply simp
  1761   done
  1762 
  1763 lemma matrix_vector_mul_lid: "mat 1 *v x = (x::'a::semiring_1 ^ 'n::finite)"
  1764   apply (vector matrix_vector_mult_def mat_def)
  1765   by (simp add: cond_value_iff cond_application_beta
  1766     setsum_delta' cong del: if_weak_cong)
  1767 
  1768 lemma matrix_transp_mul: "transp(A ** B) = transp B ** transp (A::'a::comm_semiring_1^'m^'n)"
  1769   by (simp add: matrix_matrix_mult_def transp_def Cart_eq mult_commute)
  1770 
  1771 lemma matrix_eq:
  1772   fixes A B :: "'a::semiring_1 ^ 'n::finite ^ 'm"
  1773   shows "A = B \<longleftrightarrow>  (\<forall>x. A *v x = B *v x)" (is "?lhs \<longleftrightarrow> ?rhs")
  1774   apply auto
  1775   apply (subst Cart_eq)
  1776   apply clarify
  1777   apply (clarsimp simp add: matrix_vector_mult_def basis_def cond_value_iff cond_application_beta Cart_eq cong del: if_weak_cong)
  1778   apply (erule_tac x="basis ia" in allE)
  1779   apply (erule_tac x="i" in allE)
  1780   by (auto simp add: basis_def cond_value_iff cond_application_beta setsum_delta[OF finite] cong del: if_weak_cong)
  1781 
  1782 lemma matrix_vector_mul_component:
  1783   shows "((A::'a::semiring_1^'n'^'m) *v x)$k = (A$k) \<bullet> x"
  1784   by (simp add: matrix_vector_mult_def dot_def)
  1785 
  1786 lemma dot_lmul_matrix: "((x::'a::comm_semiring_1 ^'n) v* A) \<bullet> y = x \<bullet> (A *v y)"
  1787   apply (simp add: dot_def matrix_vector_mult_def vector_matrix_mult_def setsum_left_distrib setsum_right_distrib mult_ac)
  1788   apply (subst setsum_commute)
  1789   by simp
  1790 
  1791 lemma transp_mat: "transp (mat n) = mat n"
  1792   by (vector transp_def mat_def)
  1793 
  1794 lemma transp_transp: "transp(transp A) = A"
  1795   by (vector transp_def)
  1796 
  1797 lemma row_transp:
  1798   fixes A:: "'a::semiring_1^'n^'m"
  1799   shows "row i (transp A) = column i A"
  1800   by (simp add: row_def column_def transp_def Cart_eq)
  1801 
  1802 lemma column_transp:
  1803   fixes A:: "'a::semiring_1^'n^'m"
  1804   shows "column i (transp A) = row i A"
  1805   by (simp add: row_def column_def transp_def Cart_eq)
  1806 
  1807 lemma rows_transp: "rows(transp (A::'a::semiring_1^'n^'m)) = columns A"
  1808 by (auto simp add: rows_def columns_def row_transp intro: set_ext)
  1809 
  1810 lemma columns_transp: "columns(transp (A::'a::semiring_1^'n^'m)) = rows A" by (metis transp_transp rows_transp)
  1811 
  1812 text{* Two sometimes fruitful ways of looking at matrix-vector multiplication. *}
  1813 
  1814 lemma matrix_mult_dot: "A *v x = (\<chi> i. A$i \<bullet> x)"
  1815   by (simp add: matrix_vector_mult_def dot_def)
  1816 
  1817 lemma matrix_mult_vsum: "(A::'a::comm_semiring_1^'n^'m) *v x = setsum (\<lambda>i. (x$i) *s column i A) (UNIV:: 'n set)"
  1818   by (simp add: matrix_vector_mult_def Cart_eq column_def mult_commute)
  1819 
  1820 lemma vector_componentwise:
  1821   "(x::'a::ring_1^'n::finite) = (\<chi> j. setsum (\<lambda>i. (x$i) * (basis i :: 'a^'n)$j) (UNIV :: 'n set))"
  1822   apply (subst basis_expansion[symmetric])
  1823   by (vector Cart_eq setsum_component)
  1824 
  1825 lemma linear_componentwise:
  1826   fixes f:: "'a::ring_1 ^ 'm::finite \<Rightarrow> 'a ^ 'n"
  1827   assumes lf: "linear f"
  1828   shows "(f x)$j = setsum (\<lambda>i. (x$i) * (f (basis i)$j)) (UNIV :: 'm set)" (is "?lhs = ?rhs")
  1829 proof-
  1830   let ?M = "(UNIV :: 'm set)"
  1831   let ?N = "(UNIV :: 'n set)"
  1832   have fM: "finite ?M" by simp
  1833   have "?rhs = (setsum (\<lambda>i.(x$i) *s f (basis i) ) ?M)$j"
  1834     unfolding vector_smult_component[symmetric]
  1835     unfolding setsum_component[of "(\<lambda>i.(x$i) *s f (basis i :: 'a^'m))" ?M]
  1836     ..
  1837   then show ?thesis unfolding linear_setsum_mul[OF lf fM, symmetric] basis_expansion ..
  1838 qed
  1839 
  1840 text{* Inverse matrices  (not necessarily square) *}
  1841 
  1842 definition "invertible(A::'a::semiring_1^'n^'m) \<longleftrightarrow> (\<exists>A'::'a^'m^'n. A ** A' = mat 1 \<and> A' ** A = mat 1)"
  1843 
  1844 definition "matrix_inv(A:: 'a::semiring_1^'n^'m) =
  1845         (SOME A'::'a^'m^'n. A ** A' = mat 1 \<and> A' ** A = mat 1)"
  1846 
  1847 text{* Correspondence between matrices and linear operators. *}
  1848 
  1849 definition matrix:: "('a::{plus,times, one, zero}^'m \<Rightarrow> 'a ^ 'n) \<Rightarrow> 'a^'m^'n"
  1850 where "matrix f = (\<chi> i j. (f(basis j))$i)"
  1851 
  1852 lemma matrix_vector_mul_linear: "linear(\<lambda>x. A *v (x::'a::comm_semiring_1 ^ 'n))"
  1853   by (simp add: linear_def matrix_vector_mult_def Cart_eq ring_simps setsum_right_distrib setsum_addf)
  1854 
  1855 lemma matrix_works: assumes lf: "linear f" shows "matrix f *v x = f (x::'a::comm_ring_1 ^ 'n::finite)"
  1856 apply (simp add: matrix_def matrix_vector_mult_def Cart_eq mult_commute)
  1857 apply clarify
  1858 apply (rule linear_componentwise[OF lf, symmetric])
  1859 done
  1860 
  1861 lemma matrix_vector_mul: "linear f ==> f = (\<lambda>x. matrix f *v (x::'a::comm_ring_1 ^ 'n::finite))" by (simp add: ext matrix_works)
  1862 
  1863 lemma matrix_of_matrix_vector_mul: "matrix(\<lambda>x. A *v (x :: 'a:: comm_ring_1 ^ 'n::finite)) = A"
  1864   by (simp add: matrix_eq matrix_vector_mul_linear matrix_works)
  1865 
  1866 lemma matrix_compose:
  1867   assumes lf: "linear (f::'a::comm_ring_1^'n::finite \<Rightarrow> 'a^'m::finite)"
  1868   and lg: "linear (g::'a::comm_ring_1^'m::finite \<Rightarrow> 'a^'k)"
  1869   shows "matrix (g o f) = matrix g ** matrix f"
  1870   using lf lg linear_compose[OF lf lg] matrix_works[OF linear_compose[OF lf lg]]
  1871   by (simp  add: matrix_eq matrix_works matrix_vector_mul_assoc[symmetric] o_def)
  1872 
  1873 lemma matrix_vector_column:"(A::'a::comm_semiring_1^'n^'m) *v x = setsum (\<lambda>i. (x$i) *s ((transp A)$i)) (UNIV:: 'n set)"
  1874   by (simp add: matrix_vector_mult_def transp_def Cart_eq mult_commute)
  1875 
  1876 lemma adjoint_matrix: "adjoint(\<lambda>x. (A::'a::comm_ring_1^'n::finite^'m::finite) *v x) = (\<lambda>x. transp A *v x)"
  1877   apply (rule adjoint_unique[symmetric])
  1878   apply (rule matrix_vector_mul_linear)
  1879   apply (simp add: transp_def dot_def matrix_vector_mult_def setsum_left_distrib setsum_right_distrib)
  1880   apply (subst setsum_commute)
  1881   apply (auto simp add: mult_ac)
  1882   done
  1883 
  1884 lemma matrix_adjoint: assumes lf: "linear (f :: 'a::comm_ring_1^'n::finite \<Rightarrow> 'a ^ 'm::finite)"
  1885   shows "matrix(adjoint f) = transp(matrix f)"
  1886   apply (subst matrix_vector_mul[OF lf])
  1887   unfolding adjoint_matrix matrix_of_matrix_vector_mul ..
  1888 
  1889 subsection{* Interlude: Some properties of real sets *}
  1890 
  1891 lemma seq_mono_lemma: assumes "\<forall>(n::nat) \<ge> m. (d n :: real) < e n" and "\<forall>n \<ge> m. e n <= e m"
  1892   shows "\<forall>n \<ge> m. d n < e m"
  1893   using prems apply auto
  1894   apply (erule_tac x="n" in allE)
  1895   apply (erule_tac x="n" in allE)
  1896   apply auto
  1897   done
  1898 
  1899 
  1900 lemma real_convex_bound_lt:
  1901   assumes xa: "(x::real) < a" and ya: "y < a" and u: "0 <= u" and v: "0 <= v"
  1902   and uv: "u + v = 1"
  1903   shows "u * x + v * y < a"
  1904 proof-
  1905   have uv': "u = 0 \<longrightarrow> v \<noteq> 0" using u v uv by arith
  1906   have "a = a * (u + v)" unfolding uv  by simp
  1907   hence th: "u * a + v * a = a" by (simp add: ring_simps)
  1908   from xa u have "u \<noteq> 0 \<Longrightarrow> u*x < u*a" by (simp add: mult_compare_simps)
  1909   from ya v have "v \<noteq> 0 \<Longrightarrow> v * y < v * a" by (simp add: mult_compare_simps)
  1910   from xa ya u v have "u * x + v * y < u * a + v * a"
  1911     apply (cases "u = 0", simp_all add: uv')
  1912     apply(rule mult_strict_left_mono)
  1913     using uv' apply simp_all
  1914 
  1915     apply (rule add_less_le_mono)
  1916     apply(rule mult_strict_left_mono)
  1917     apply simp_all
  1918     apply (rule mult_left_mono)
  1919     apply simp_all
  1920     done
  1921   thus ?thesis unfolding th .
  1922 qed
  1923 
  1924 lemma real_convex_bound_le:
  1925   assumes xa: "(x::real) \<le> a" and ya: "y \<le> a" and u: "0 <= u" and v: "0 <= v"
  1926   and uv: "u + v = 1"
  1927   shows "u * x + v * y \<le> a"
  1928 proof-
  1929   from xa ya u v have "u * x + v * y \<le> u * a + v * a" by (simp add: add_mono mult_left_mono)
  1930   also have "\<dots> \<le> (u + v) * a" by (simp add: ring_simps)
  1931   finally show ?thesis unfolding uv by simp
  1932 qed
  1933 
  1934 lemma infinite_enumerate: assumes fS: "infinite S"
  1935   shows "\<exists>r. subseq r \<and> (\<forall>n. r n \<in> S)"
  1936 unfolding subseq_def
  1937 using enumerate_in_set[OF fS] enumerate_mono[of _ _ S] fS by auto
  1938 
  1939 lemma approachable_lt_le: "(\<exists>(d::real)>0. \<forall>x. f x < d \<longrightarrow> P x) \<longleftrightarrow> (\<exists>d>0. \<forall>x. f x \<le> d \<longrightarrow> P x)"
  1940 apply auto
  1941 apply (rule_tac x="d/2" in exI)
  1942 apply auto
  1943 done
  1944 
  1945 
  1946 lemma triangle_lemma:
  1947   assumes x: "0 <= (x::real)" and y:"0 <= y" and z: "0 <= z" and xy: "x^2 <= y^2 + z^2"
  1948   shows "x <= y + z"
  1949 proof-
  1950   have "y^2 + z^2 \<le> y^2 + 2*y*z + z^2" using z y  by (simp add: zero_compare_simps)
  1951   with xy have th: "x ^2 \<le> (y+z)^2" by (simp add: power2_eq_square ring_simps)
  1952   from y z have yz: "y + z \<ge> 0" by arith
  1953   from power2_le_imp_le[OF th yz] show ?thesis .
  1954 qed
  1955 
  1956 
  1957 lemma lambda_skolem: "(\<forall>i. \<exists>x. P i x) \<longleftrightarrow>
  1958    (\<exists>x::'a ^ 'n. \<forall>i. P i (x$i))" (is "?lhs \<longleftrightarrow> ?rhs")
  1959 proof-
  1960   let ?S = "(UNIV :: 'n set)"
  1961   {assume H: "?rhs"
  1962     then have ?lhs by auto}
  1963   moreover
  1964   {assume H: "?lhs"
  1965     then obtain f where f:"\<forall>i. P i (f i)" unfolding choice_iff by metis
  1966     let ?x = "(\<chi> i. (f i)) :: 'a ^ 'n"
  1967     {fix i
  1968       from f have "P i (f i)" by metis
  1969       then have "P i (?x$i)" by auto
  1970     }
  1971     hence "\<forall>i. P i (?x$i)" by metis
  1972     hence ?rhs by metis }
  1973   ultimately show ?thesis by metis
  1974 qed
  1975 
  1976 (* Supremum and infimum of real sets *)
  1977 
  1978 
  1979 definition rsup:: "real set \<Rightarrow> real" where
  1980   "rsup S = (SOME a. isLub UNIV S a)"
  1981 
  1982 lemma rsup_alt: "rsup S = (SOME a. (\<forall>x \<in> S. x \<le> a) \<and> (\<forall>b. (\<forall>x \<in> S. x \<le> b) \<longrightarrow> a \<le> b))"  by (auto simp  add: isLub_def rsup_def leastP_def isUb_def setle_def setge_def)
  1983 
  1984 lemma rsup: assumes Se: "S \<noteq> {}" and b: "\<exists>b. S *<= b"
  1985   shows "isLub UNIV S (rsup S)"
  1986 using Se b
  1987 unfolding rsup_def
  1988 apply clarify
  1989 apply (rule someI_ex)
  1990 apply (rule reals_complete)
  1991 by (auto simp add: isUb_def setle_def)
  1992 
  1993 lemma rsup_le: assumes Se: "S \<noteq> {}" and Sb: "S *<= b" shows "rsup S \<le> b"
  1994 proof-
  1995   from Sb have bu: "isUb UNIV S b" by (simp add: isUb_def setle_def)
  1996   from rsup[OF Se] Sb have "isLub UNIV S (rsup S)"  by blast
  1997   then show ?thesis using bu by (auto simp add: isLub_def leastP_def setle_def setge_def)
  1998 qed
  1999 
  2000 lemma rsup_finite_Max: assumes fS: "finite S" and Se: "S \<noteq> {}"
  2001   shows "rsup S = Max S"
  2002 using fS Se
  2003 proof-
  2004   let ?m = "Max S"
  2005   from Max_ge[OF fS] have Sm: "\<forall> x\<in> S. x \<le> ?m" by metis
  2006   with rsup[OF Se] have lub: "isLub UNIV S (rsup S)" by (metis setle_def)
  2007   from Max_in[OF fS Se] lub have mrS: "?m \<le> rsup S"
  2008     by (auto simp add: isLub_def leastP_def setle_def setge_def isUb_def)
  2009   moreover
  2010   have "rsup S \<le> ?m" using Sm lub
  2011     by (auto simp add: isLub_def leastP_def isUb_def setle_def setge_def)
  2012   ultimately  show ?thesis by arith
  2013 qed
  2014 
  2015 lemma rsup_finite_in: assumes fS: "finite S" and Se: "S \<noteq> {}"
  2016   shows "rsup S \<in> S"
  2017   using rsup_finite_Max[OF fS Se] Max_in[OF fS Se] by metis
  2018 
  2019 lemma rsup_finite_Ub: assumes fS: "finite S" and Se: "S \<noteq> {}"
  2020   shows "isUb S S (rsup S)"
  2021   using rsup_finite_Max[OF fS Se] rsup_finite_in[OF fS Se] Max_ge[OF fS]
  2022   unfolding isUb_def setle_def by metis
  2023 
  2024 lemma rsup_finite_ge_iff: assumes fS: "finite S" and Se: "S \<noteq> {}"
  2025   shows "a \<le> rsup S \<longleftrightarrow> (\<exists> x \<in> S. a \<le> x)"
  2026 using rsup_finite_Ub[OF fS Se] by (auto simp add: isUb_def setle_def)
  2027 
  2028 lemma rsup_finite_le_iff: assumes fS: "finite S" and Se: "S \<noteq> {}"
  2029   shows "a \<ge> rsup S \<longleftrightarrow> (\<forall> x \<in> S. a \<ge> x)"
  2030 using rsup_finite_Ub[OF fS Se] by (auto simp add: isUb_def setle_def)
  2031 
  2032 lemma rsup_finite_gt_iff: assumes fS: "finite S" and Se: "S \<noteq> {}"
  2033   shows "a < rsup S \<longleftrightarrow> (\<exists> x \<in> S. a < x)"
  2034 using rsup_finite_Ub[OF fS Se] by (auto simp add: isUb_def setle_def)
  2035 
  2036 lemma rsup_finite_lt_iff: assumes fS: "finite S" and Se: "S \<noteq> {}"
  2037   shows "a > rsup S \<longleftrightarrow> (\<forall> x \<in> S. a > x)"
  2038 using rsup_finite_Ub[OF fS Se] by (auto simp add: isUb_def setle_def)
  2039 
  2040 lemma rsup_unique: assumes b: "S *<= b" and S: "\<forall>b' < b. \<exists>x \<in> S. b' < x"
  2041   shows "rsup S = b"
  2042 using b S
  2043 unfolding setle_def rsup_alt
  2044 apply -
  2045 apply (rule some_equality)
  2046 apply (metis  linorder_not_le order_eq_iff[symmetric])+
  2047 done
  2048 
  2049 lemma rsup_le_subset: "S\<noteq>{} \<Longrightarrow> S \<subseteq> T \<Longrightarrow> (\<exists>b. T *<= b) \<Longrightarrow> rsup S \<le> rsup T"
  2050   apply (rule rsup_le)
  2051   apply simp
  2052   using rsup[of T] by (auto simp add: isLub_def leastP_def setge_def setle_def isUb_def)
  2053 
  2054 lemma isUb_def': "isUb R S = (\<lambda>x. S *<= x \<and> x \<in> R)"
  2055   apply (rule ext)
  2056   by (metis isUb_def)
  2057 
  2058 lemma UNIV_trivial: "UNIV x" using UNIV_I[of x] by (metis mem_def)
  2059 lemma rsup_bounds: assumes Se: "S \<noteq> {}" and l: "a <=* S" and u: "S *<= b"
  2060   shows "a \<le> rsup S \<and> rsup S \<le> b"
  2061 proof-
  2062   from rsup[OF Se] u have lub: "isLub UNIV S (rsup S)" by blast
  2063   hence b: "rsup S \<le> b" using u by (auto simp add: isLub_def leastP_def setle_def setge_def isUb_def')
  2064   from Se obtain y where y: "y \<in> S" by blast
  2065   from lub l have "a \<le> rsup S" apply (auto simp add: isLub_def leastP_def setle_def setge_def isUb_def')
  2066     apply (erule ballE[where x=y])
  2067     apply (erule ballE[where x=y])
  2068     apply arith
  2069     using y apply auto
  2070     done
  2071   with b show ?thesis by blast
  2072 qed
  2073 
  2074 lemma rsup_abs_le: "S \<noteq> {} \<Longrightarrow> (\<forall>x\<in>S. \<bar>x\<bar> \<le> a) \<Longrightarrow> \<bar>rsup S\<bar> \<le> a"
  2075   unfolding abs_le_interval_iff  using rsup_bounds[of S "-a" a]
  2076   by (auto simp add: setge_def setle_def)
  2077 
  2078 lemma rsup_asclose: assumes S:"S \<noteq> {}" and b: "\<forall>x\<in>S. \<bar>x - l\<bar> \<le> e" shows "\<bar>rsup S - l\<bar> \<le> e"
  2079 proof-
  2080   have th: "\<And>(x::real) l e. \<bar>x - l\<bar> \<le> e \<longleftrightarrow> l - e \<le> x \<and> x \<le> l + e" by arith
  2081   show ?thesis using S b rsup_bounds[of S "l - e" "l+e"] unfolding th
  2082     by  (auto simp add: setge_def setle_def)
  2083 qed
  2084 
  2085 definition rinf:: "real set \<Rightarrow> real" where
  2086   "rinf S = (SOME a. isGlb UNIV S a)"
  2087 
  2088 lemma rinf_alt: "rinf S = (SOME a. (\<forall>x \<in> S. x \<ge> a) \<and> (\<forall>b. (\<forall>x \<in> S. x \<ge> b) \<longrightarrow> a \<ge> b))"  by (auto simp  add: isGlb_def rinf_def greatestP_def isLb_def setle_def setge_def)
  2089 
  2090 lemma reals_complete_Glb: assumes Se: "\<exists>x. x \<in> S" and lb: "\<exists> y. isLb UNIV S y"
  2091   shows "\<exists>(t::real). isGlb UNIV S t"
  2092 proof-
  2093   let ?M = "uminus ` S"
  2094   from lb have th: "\<exists>y. isUb UNIV ?M y" apply (auto simp add: isUb_def isLb_def setle_def setge_def)
  2095     by (rule_tac x="-y" in exI, auto)
  2096   from Se have Me: "\<exists>x. x \<in> ?M" by blast
  2097   from reals_complete[OF Me th] obtain t where t: "isLub UNIV ?M t" by blast
  2098   have "isGlb UNIV S (- t)" using t
  2099     apply (auto simp add: isLub_def isGlb_def leastP_def greatestP_def setle_def setge_def isUb_def isLb_def)
  2100     apply (erule_tac x="-y" in allE)
  2101     apply auto
  2102     done
  2103   then show ?thesis by metis
  2104 qed
  2105 
  2106 lemma rinf: assumes Se: "S \<noteq> {}" and b: "\<exists>b. b <=* S"
  2107   shows "isGlb UNIV S (rinf S)"
  2108 using Se b
  2109 unfolding rinf_def
  2110 apply clarify
  2111 apply (rule someI_ex)
  2112 apply (rule reals_complete_Glb)
  2113 apply (auto simp add: isLb_def setle_def setge_def)
  2114 done
  2115 
  2116 lemma rinf_ge: assumes Se: "S \<noteq> {}" and Sb: "b <=* S" shows "rinf S \<ge> b"
  2117 proof-
  2118   from Sb have bu: "isLb UNIV S b" by (simp add: isLb_def setge_def)
  2119   from rinf[OF Se] Sb have "isGlb UNIV S (rinf S)"  by blast
  2120   then show ?thesis using bu by (auto simp add: isGlb_def greatestP_def setle_def setge_def)
  2121 qed
  2122 
  2123 lemma rinf_finite_Min: assumes fS: "finite S" and Se: "S \<noteq> {}"
  2124   shows "rinf S = Min S"
  2125 using fS Se
  2126 proof-
  2127   let ?m = "Min S"
  2128   from Min_le[OF fS] have Sm: "\<forall> x\<in> S. x \<ge> ?m" by metis
  2129   with rinf[OF Se] have glb: "isGlb UNIV S (rinf S)" by (metis setge_def)
  2130   from Min_in[OF fS Se] glb have mrS: "?m \<ge> rinf S"
  2131     by (auto simp add: isGlb_def greatestP_def setle_def setge_def isLb_def)
  2132   moreover
  2133   have "rinf S \<ge> ?m" using Sm glb
  2134     by (auto simp add: isGlb_def greatestP_def isLb_def setle_def setge_def)
  2135   ultimately  show ?thesis by arith
  2136 qed
  2137 
  2138 lemma rinf_finite_in: assumes fS: "finite S" and Se: "S \<noteq> {}"
  2139   shows "rinf S \<in> S"
  2140   using rinf_finite_Min[OF fS Se] Min_in[OF fS Se] by metis
  2141 
  2142 lemma rinf_finite_Lb: assumes fS: "finite S" and Se: "S \<noteq> {}"
  2143   shows "isLb S S (rinf S)"
  2144   using rinf_finite_Min[OF fS Se] rinf_finite_in[OF fS Se] Min_le[OF fS]
  2145   unfolding isLb_def setge_def by metis
  2146 
  2147 lemma rinf_finite_ge_iff: assumes fS: "finite S" and Se: "S \<noteq> {}"
  2148   shows "a \<le> rinf S \<longleftrightarrow> (\<forall> x \<in> S. a \<le> x)"
  2149 using rinf_finite_Lb[OF fS Se] by (auto simp add: isLb_def setge_def)
  2150 
  2151 lemma rinf_finite_le_iff: assumes fS: "finite S" and Se: "S \<noteq> {}"
  2152   shows "a \<ge> rinf S \<longleftrightarrow> (\<exists> x \<in> S. a \<ge> x)"
  2153 using rinf_finite_Lb[OF fS Se] by (auto simp add: isLb_def setge_def)
  2154 
  2155 lemma rinf_finite_gt_iff: assumes fS: "finite S" and Se: "S \<noteq> {}"
  2156   shows "a < rinf S \<longleftrightarrow> (\<forall> x \<in> S. a < x)"
  2157 using rinf_finite_Lb[OF fS Se] by (auto simp add: isLb_def setge_def)
  2158 
  2159 lemma rinf_finite_lt_iff: assumes fS: "finite S" and Se: "S \<noteq> {}"
  2160   shows "a > rinf S \<longleftrightarrow> (\<exists> x \<in> S. a > x)"
  2161 using rinf_finite_Lb[OF fS Se] by (auto simp add: isLb_def setge_def)
  2162 
  2163 lemma rinf_unique: assumes b: "b <=* S" and S: "\<forall>b' > b. \<exists>x \<in> S. b' > x"
  2164   shows "rinf S = b"
  2165 using b S
  2166 unfolding setge_def rinf_alt
  2167 apply -
  2168 apply (rule some_equality)
  2169 apply (metis  linorder_not_le order_eq_iff[symmetric])+
  2170 done
  2171 
  2172 lemma rinf_ge_subset: "S\<noteq>{} \<Longrightarrow> S \<subseteq> T \<Longrightarrow> (\<exists>b. b <=* T) \<Longrightarrow> rinf S >= rinf T"
  2173   apply (rule rinf_ge)
  2174   apply simp
  2175   using rinf[of T] by (auto simp add: isGlb_def greatestP_def setge_def setle_def isLb_def)
  2176 
  2177 lemma isLb_def': "isLb R S = (\<lambda>x. x <=* S \<and> x \<in> R)"
  2178   apply (rule ext)
  2179   by (metis isLb_def)
  2180 
  2181 lemma rinf_bounds: assumes Se: "S \<noteq> {}" and l: "a <=* S" and u: "S *<= b"
  2182   shows "a \<le> rinf S \<and> rinf S \<le> b"
  2183 proof-
  2184   from rinf[OF Se] l have lub: "isGlb UNIV S (rinf S)" by blast
  2185   hence b: "a \<le> rinf S" using l by (auto simp add: isGlb_def greatestP_def setle_def setge_def isLb_def')
  2186   from Se obtain y where y: "y \<in> S" by blast
  2187   from lub u have "b \<ge> rinf S" apply (auto simp add: isGlb_def greatestP_def setle_def setge_def isLb_def')
  2188     apply (erule ballE[where x=y])
  2189     apply (erule ballE[where x=y])
  2190     apply arith
  2191     using y apply auto
  2192     done
  2193   with b show ?thesis by blast
  2194 qed
  2195 
  2196 lemma rinf_abs_ge: "S \<noteq> {} \<Longrightarrow> (\<forall>x\<in>S. \<bar>x\<bar> \<le> a) \<Longrightarrow> \<bar>rinf S\<bar> \<le> a"
  2197   unfolding abs_le_interval_iff  using rinf_bounds[of S "-a" a]
  2198   by (auto simp add: setge_def setle_def)
  2199 
  2200 lemma rinf_asclose: assumes S:"S \<noteq> {}" and b: "\<forall>x\<in>S. \<bar>x - l\<bar> \<le> e" shows "\<bar>rinf S - l\<bar> \<le> e"
  2201 proof-
  2202   have th: "\<And>(x::real) l e. \<bar>x - l\<bar> \<le> e \<longleftrightarrow> l - e \<le> x \<and> x \<le> l + e" by arith
  2203   show ?thesis using S b rinf_bounds[of S "l - e" "l+e"] unfolding th
  2204     by  (auto simp add: setge_def setle_def)
  2205 qed
  2206 
  2207 
  2208 
  2209 subsection{* Operator norm. *}
  2210 
  2211 definition "onorm f = rsup {norm (f x)| x. norm x = 1}"
  2212 
  2213 lemma norm_bound_generalize:
  2214   fixes f:: "real ^'n::finite \<Rightarrow> real^'m::finite"
  2215   assumes lf: "linear f"
  2216   shows "(\<forall>x. norm x = 1 \<longrightarrow> norm (f x) \<le> b) \<longleftrightarrow> (\<forall>x. norm (f x) \<le> b * norm x)" (is "?lhs \<longleftrightarrow> ?rhs")
  2217 proof-
  2218   {assume H: ?rhs
  2219     {fix x :: "real^'n" assume x: "norm x = 1"
  2220       from H[rule_format, of x] x have "norm (f x) \<le> b" by simp}
  2221     then have ?lhs by blast }
  2222 
  2223   moreover
  2224   {assume H: ?lhs
  2225     from H[rule_format, of "basis arbitrary"]
  2226     have bp: "b \<ge> 0" using norm_ge_zero[of "f (basis arbitrary)"]
  2227       by (auto simp add: norm_basis elim: order_trans [OF norm_ge_zero])
  2228     {fix x :: "real ^'n"
  2229       {assume "x = 0"
  2230 	then have "norm (f x) \<le> b * norm x" by (simp add: linear_0[OF lf] bp)}
  2231       moreover
  2232       {assume x0: "x \<noteq> 0"
  2233 	hence n0: "norm x \<noteq> 0" by (metis norm_eq_zero)
  2234 	let ?c = "1/ norm x"
  2235 	have "norm (?c*s x) = 1" using x0 by (simp add: n0 norm_mul)
  2236 	with H have "norm (f(?c*s x)) \<le> b" by blast
  2237 	hence "?c * norm (f x) \<le> b"
  2238 	  by (simp add: linear_cmul[OF lf] norm_mul)
  2239 	hence "norm (f x) \<le> b * norm x"
  2240 	  using n0 norm_ge_zero[of x] by (auto simp add: field_simps)}
  2241       ultimately have "norm (f x) \<le> b * norm x" by blast}
  2242     then have ?rhs by blast}
  2243   ultimately show ?thesis by blast
  2244 qed
  2245 
  2246 lemma onorm:
  2247   fixes f:: "real ^'n::finite \<Rightarrow> real ^'m::finite"
  2248   assumes lf: "linear f"
  2249   shows "norm (f x) <= onorm f * norm x"
  2250   and "\<forall>x. norm (f x) <= b * norm x \<Longrightarrow> onorm f <= b"
  2251 proof-
  2252   {
  2253     let ?S = "{norm (f x) |x. norm x = 1}"
  2254     have Se: "?S \<noteq> {}" using  norm_basis by auto
  2255     from linear_bounded[OF lf] have b: "\<exists> b. ?S *<= b"
  2256       unfolding norm_bound_generalize[OF lf, symmetric] by (auto simp add: setle_def)
  2257     {from rsup[OF Se b, unfolded onorm_def[symmetric]]
  2258       show "norm (f x) <= onorm f * norm x"
  2259 	apply -
  2260 	apply (rule spec[where x = x])
  2261 	unfolding norm_bound_generalize[OF lf, symmetric]
  2262 	by (auto simp add: isLub_def isUb_def leastP_def setge_def setle_def)}
  2263     {
  2264       show "\<forall>x. norm (f x) <= b * norm x \<Longrightarrow> onorm f <= b"
  2265 	using rsup[OF Se b, unfolded onorm_def[symmetric]]
  2266 	unfolding norm_bound_generalize[OF lf, symmetric]
  2267 	by (auto simp add: isLub_def isUb_def leastP_def setge_def setle_def)}
  2268   }
  2269 qed
  2270 
  2271 lemma onorm_pos_le: assumes lf: "linear (f::real ^'n::finite \<Rightarrow> real ^'m::finite)" shows "0 <= onorm f"
  2272   using order_trans[OF norm_ge_zero onorm(1)[OF lf, of "basis arbitrary"], unfolded norm_basis] by simp
  2273 
  2274 lemma onorm_eq_0: assumes lf: "linear (f::real ^'n::finite \<Rightarrow> real ^'m::finite)"
  2275   shows "onorm f = 0 \<longleftrightarrow> (\<forall>x. f x = 0)"
  2276   using onorm[OF lf]
  2277   apply (auto simp add: onorm_pos_le)
  2278   apply atomize
  2279   apply (erule allE[where x="0::real"])
  2280   using onorm_pos_le[OF lf]
  2281   apply arith
  2282   done
  2283 
  2284 lemma onorm_const: "onorm(\<lambda>x::real^'n::finite. (y::real ^ 'm::finite)) = norm y"
  2285 proof-
  2286   let ?f = "\<lambda>x::real^'n. (y::real ^ 'm)"
  2287   have th: "{norm (?f x)| x. norm x = 1} = {norm y}"
  2288     by(auto intro: vector_choose_size set_ext)
  2289   show ?thesis
  2290     unfolding onorm_def th
  2291     apply (rule rsup_unique) by (simp_all  add: setle_def)
  2292 qed
  2293 
  2294 lemma onorm_pos_lt: assumes lf: "linear (f::real ^ 'n::finite \<Rightarrow> real ^'m::finite)"
  2295   shows "0 < onorm f \<longleftrightarrow> ~(\<forall>x. f x = 0)"
  2296   unfolding onorm_eq_0[OF lf, symmetric]
  2297   using onorm_pos_le[OF lf] by arith
  2298 
  2299 lemma onorm_compose:
  2300   assumes lf: "linear (f::real ^'n::finite \<Rightarrow> real ^'m::finite)"
  2301   and lg: "linear (g::real^'k::finite \<Rightarrow> real^'n::finite)"
  2302   shows "onorm (f o g) <= onorm f * onorm g"
  2303   apply (rule onorm(2)[OF linear_compose[OF lg lf], rule_format])
  2304   unfolding o_def
  2305   apply (subst mult_assoc)
  2306   apply (rule order_trans)
  2307   apply (rule onorm(1)[OF lf])
  2308   apply (rule mult_mono1)
  2309   apply (rule onorm(1)[OF lg])
  2310   apply (rule onorm_pos_le[OF lf])
  2311   done
  2312 
  2313 lemma onorm_neg_lemma: assumes lf: "linear (f::real ^'n::finite \<Rightarrow> real^'m::finite)"
  2314   shows "onorm (\<lambda>x. - f x) \<le> onorm f"
  2315   using onorm[OF linear_compose_neg[OF lf]] onorm[OF lf]
  2316   unfolding norm_minus_cancel by metis
  2317 
  2318 lemma onorm_neg: assumes lf: "linear (f::real ^'n::finite \<Rightarrow> real^'m::finite)"
  2319   shows "onorm (\<lambda>x. - f x) = onorm f"
  2320   using onorm_neg_lemma[OF lf] onorm_neg_lemma[OF linear_compose_neg[OF lf]]
  2321   by simp
  2322 
  2323 lemma onorm_triangle:
  2324   assumes lf: "linear (f::real ^'n::finite \<Rightarrow> real ^'m::finite)" and lg: "linear g"
  2325   shows "onorm (\<lambda>x. f x + g x) <= onorm f + onorm g"
  2326   apply(rule onorm(2)[OF linear_compose_add[OF lf lg], rule_format])
  2327   apply (rule order_trans)
  2328   apply (rule norm_triangle_ineq)
  2329   apply (simp add: distrib)
  2330   apply (rule add_mono)
  2331   apply (rule onorm(1)[OF lf])
  2332   apply (rule onorm(1)[OF lg])
  2333   done
  2334 
  2335 lemma onorm_triangle_le: "linear (f::real ^'n::finite \<Rightarrow> real ^'m::finite) \<Longrightarrow> linear g \<Longrightarrow> onorm(f) + onorm(g) <= e
  2336   \<Longrightarrow> onorm(\<lambda>x. f x + g x) <= e"
  2337   apply (rule order_trans)
  2338   apply (rule onorm_triangle)
  2339   apply assumption+
  2340   done
  2341 
  2342 lemma onorm_triangle_lt: "linear (f::real ^'n::finite \<Rightarrow> real ^'m::finite) \<Longrightarrow> linear g \<Longrightarrow> onorm(f) + onorm(g) < e
  2343   ==> onorm(\<lambda>x. f x + g x) < e"
  2344   apply (rule order_le_less_trans)
  2345   apply (rule onorm_triangle)
  2346   by assumption+
  2347 
  2348 (* "lift" from 'a to 'a^1 and "drop" from 'a^1 to 'a -- FIXME: potential use of transfer *)
  2349 
  2350 definition vec1:: "'a \<Rightarrow> 'a ^ 1" where "vec1 x = (\<chi> i. x)"
  2351 
  2352 definition dest_vec1:: "'a ^1 \<Rightarrow> 'a"
  2353   where "dest_vec1 x = (x$1)"
  2354 
  2355 lemma vec1_component[simp]: "(vec1 x)$1 = x"
  2356   by (simp add: vec1_def)
  2357 
  2358 lemma vec1_dest_vec1[simp]: "vec1(dest_vec1 x) = x" "dest_vec1(vec1 y) = y"
  2359   by (simp_all add: vec1_def dest_vec1_def Cart_eq forall_1)
  2360 
  2361 lemma forall_vec1: "(\<forall>x. P x) \<longleftrightarrow> (\<forall>x. P (vec1 x))" by (metis vec1_dest_vec1)
  2362 
  2363 lemma exists_vec1: "(\<exists>x. P x) \<longleftrightarrow> (\<exists>x. P(vec1 x))" by (metis vec1_dest_vec1)
  2364 
  2365 lemma forall_dest_vec1: "(\<forall>x. P x) \<longleftrightarrow> (\<forall>x. P(dest_vec1 x))"  by (metis vec1_dest_vec1)
  2366 
  2367 lemma exists_dest_vec1: "(\<exists>x. P x) \<longleftrightarrow> (\<exists>x. P(dest_vec1 x))"by (metis vec1_dest_vec1)
  2368 
  2369 lemma vec1_eq[simp]:  "vec1 x = vec1 y \<longleftrightarrow> x = y" by (metis vec1_dest_vec1)
  2370 
  2371 lemma dest_vec1_eq[simp]: "dest_vec1 x = dest_vec1 y \<longleftrightarrow> x = y" by (metis vec1_dest_vec1)
  2372 
  2373 lemma vec1_in_image_vec1: "vec1 x \<in> (vec1 ` S) \<longleftrightarrow> x \<in> S" by auto
  2374 
  2375 lemma vec1_vec: "vec1 x = vec x" by (vector vec1_def)
  2376 
  2377 lemma vec1_add: "vec1(x + y) = vec1 x + vec1 y" by (vector vec1_def)
  2378 lemma vec1_sub: "vec1(x - y) = vec1 x - vec1 y" by (vector vec1_def)
  2379 lemma vec1_cmul: "vec1(c* x) = c *s vec1 x " by (vector vec1_def)
  2380 lemma vec1_neg: "vec1(- x) = - vec1 x " by (vector vec1_def)
  2381 
  2382 lemma vec1_setsum: assumes fS: "finite S"
  2383   shows "vec1(setsum f S) = setsum (vec1 o f) S"
  2384   apply (induct rule: finite_induct[OF fS])
  2385   apply (simp add: vec1_vec)
  2386   apply (auto simp add: vec1_add)
  2387   done
  2388 
  2389 lemma dest_vec1_lambda: "dest_vec1(\<chi> i. x i) = x 1"
  2390   by (simp add: dest_vec1_def)
  2391 
  2392 lemma dest_vec1_vec: "dest_vec1(vec x) = x"
  2393   by (simp add: vec1_vec[symmetric])
  2394 
  2395 lemma dest_vec1_add: "dest_vec1(x + y) = dest_vec1 x + dest_vec1 y"
  2396  by (metis vec1_dest_vec1 vec1_add)
  2397 
  2398 lemma dest_vec1_sub: "dest_vec1(x - y) = dest_vec1 x - dest_vec1 y"
  2399  by (metis vec1_dest_vec1 vec1_sub)
  2400 
  2401 lemma dest_vec1_cmul: "dest_vec1(c*sx) = c * dest_vec1 x"
  2402  by (metis vec1_dest_vec1 vec1_cmul)
  2403 
  2404 lemma dest_vec1_neg: "dest_vec1(- x) = - dest_vec1 x"
  2405  by (metis vec1_dest_vec1 vec1_neg)
  2406 
  2407 lemma dest_vec1_0[simp]: "dest_vec1 0 = 0" by (metis vec_0 dest_vec1_vec)
  2408 
  2409 lemma dest_vec1_sum: assumes fS: "finite S"
  2410   shows "dest_vec1(setsum f S) = setsum (dest_vec1 o f) S"
  2411   apply (induct rule: finite_induct[OF fS])
  2412   apply (simp add: dest_vec1_vec)
  2413   apply (auto simp add: dest_vec1_add)
  2414   done
  2415 
  2416 lemma norm_vec1: "norm(vec1 x) = abs(x)"
  2417   by (simp add: vec1_def norm_real)
  2418 
  2419 lemma dist_vec1: "dist(vec1 x) (vec1 y) = abs(x - y)"
  2420   by (simp only: dist_real vec1_component)
  2421 lemma abs_dest_vec1: "norm x = \<bar>dest_vec1 x\<bar>"
  2422   by (metis vec1_dest_vec1 norm_vec1)
  2423 
  2424 lemma linear_vmul_dest_vec1:
  2425   fixes f:: "'a::semiring_1^'n \<Rightarrow> 'a^1"
  2426   shows "linear f \<Longrightarrow> linear (\<lambda>x. dest_vec1(f x) *s v)"
  2427   unfolding dest_vec1_def
  2428   apply (rule linear_vmul_component)
  2429   by auto
  2430 
  2431 lemma linear_from_scalars:
  2432   assumes lf: "linear (f::'a::comm_ring_1 ^1 \<Rightarrow> 'a^'n)"
  2433   shows "f = (\<lambda>x. dest_vec1 x *s column 1 (matrix f))"
  2434   apply (rule ext)
  2435   apply (subst matrix_works[OF lf, symmetric])
  2436   apply (auto simp add: Cart_eq matrix_vector_mult_def dest_vec1_def column_def  mult_commute UNIV_1)
  2437   done
  2438 
  2439 lemma linear_to_scalars: assumes lf: "linear (f::'a::comm_ring_1 ^'n::finite \<Rightarrow> 'a^1)"
  2440   shows "f = (\<lambda>x. vec1(row 1 (matrix f) \<bullet> x))"
  2441   apply (rule ext)
  2442   apply (subst matrix_works[OF lf, symmetric])
  2443   apply (simp add: Cart_eq matrix_vector_mult_def vec1_def row_def dot_def mult_commute forall_1)
  2444   done
  2445 
  2446 lemma dest_vec1_eq_0: "dest_vec1 x = 0 \<longleftrightarrow> x = 0"
  2447   by (simp add: dest_vec1_eq[symmetric])
  2448 
  2449 lemma setsum_scalars: assumes fS: "finite S"
  2450   shows "setsum f S = vec1 (setsum (dest_vec1 o f) S)"
  2451   unfolding vec1_setsum[OF fS] by simp
  2452 
  2453 lemma dest_vec1_wlog_le: "(\<And>(x::'a::linorder ^ 1) y. P x y \<longleftrightarrow> P y x)  \<Longrightarrow> (\<And>x y. dest_vec1 x <= dest_vec1 y ==> P x y) \<Longrightarrow> P x y"
  2454   apply (cases "dest_vec1 x \<le> dest_vec1 y")
  2455   apply simp
  2456   apply (subgoal_tac "dest_vec1 y \<le> dest_vec1 x")
  2457   apply (auto)
  2458   done
  2459 
  2460 text{* Pasting vectors. *}
  2461 
  2462 lemma linear_fstcart: "linear fstcart"
  2463   by (auto simp add: linear_def Cart_eq)
  2464 
  2465 lemma linear_sndcart: "linear sndcart"
  2466   by (auto simp add: linear_def Cart_eq)
  2467 
  2468 lemma fstcart_vec[simp]: "fstcart(vec x) = vec x"
  2469   by (simp add: Cart_eq)
  2470 
  2471 lemma fstcart_add[simp]:"fstcart(x + y) = fstcart (x::'a::{plus,times}^('b + 'c)) + fstcart y"
  2472   by (simp add: Cart_eq)
  2473 
  2474 lemma fstcart_cmul[simp]:"fstcart(c*s x) = c*s fstcart (x::'a::{plus,times}^('b + 'c))"
  2475   by (simp add: Cart_eq)
  2476 
  2477 lemma fstcart_neg[simp]:"fstcart(- x) = - fstcart (x::'a::ring_1^('b + 'c))"
  2478   by (simp add: Cart_eq)
  2479 
  2480 lemma fstcart_sub[simp]:"fstcart(x - y) = fstcart (x::'a::ring_1^('b + 'c)) - fstcart y"
  2481   by (simp add: Cart_eq)
  2482 
  2483 lemma fstcart_setsum:
  2484   fixes f:: "'d \<Rightarrow> 'a::semiring_1^_"
  2485   assumes fS: "finite S"
  2486   shows "fstcart (setsum f S) = setsum (\<lambda>i. fstcart (f i)) S"
  2487   by (induct rule: finite_induct[OF fS], simp_all add: vec_0[symmetric] del: vec_0)
  2488 
  2489 lemma sndcart_vec[simp]: "sndcart(vec x) = vec x"
  2490   by (simp add: Cart_eq)
  2491 
  2492 lemma sndcart_add[simp]:"sndcart(x + y) = sndcart (x::'a::{plus,times}^('b + 'c)) + sndcart y"
  2493   by (simp add: Cart_eq)
  2494 
  2495 lemma sndcart_cmul[simp]:"sndcart(c*s x) = c*s sndcart (x::'a::{plus,times}^('b + 'c))"
  2496   by (simp add: Cart_eq)
  2497 
  2498 lemma sndcart_neg[simp]:"sndcart(- x) = - sndcart (x::'a::ring_1^('b + 'c))"
  2499   by (simp add: Cart_eq)
  2500 
  2501 lemma sndcart_sub[simp]:"sndcart(x - y) = sndcart (x::'a::ring_1^('b + 'c)) - sndcart y"
  2502   by (simp add: Cart_eq)
  2503 
  2504 lemma sndcart_setsum:
  2505   fixes f:: "'d \<Rightarrow> 'a::semiring_1^_"
  2506   assumes fS: "finite S"
  2507   shows "sndcart (setsum f S) = setsum (\<lambda>i. sndcart (f i)) S"
  2508   by (induct rule: finite_induct[OF fS], simp_all add: vec_0[symmetric] del: vec_0)
  2509 
  2510 lemma pastecart_vec[simp]: "pastecart (vec x) (vec x) = vec x"
  2511   by (simp add: pastecart_eq fstcart_pastecart sndcart_pastecart)
  2512 
  2513 lemma pastecart_add[simp]:"pastecart (x1::'a::{plus,times}^_) y1 + pastecart x2 y2 = pastecart (x1 + x2) (y1 + y2)"
  2514   by (simp add: pastecart_eq fstcart_pastecart sndcart_pastecart)
  2515 
  2516 lemma pastecart_cmul[simp]: "pastecart (c *s (x1::'a::{plus,times}^_)) (c *s y1) = c *s pastecart x1 y1"
  2517   by (simp add: pastecart_eq fstcart_pastecart sndcart_pastecart)
  2518 
  2519 lemma pastecart_neg[simp]: "pastecart (- (x::'a::ring_1^_)) (- y) = - pastecart x y"
  2520   unfolding vector_sneg_minus1 pastecart_cmul ..
  2521 
  2522 lemma pastecart_sub: "pastecart (x1::'a::ring_1^_) y1 - pastecart x2 y2 = pastecart (x1 - x2) (y1 - y2)"
  2523   by (simp add: diff_def pastecart_neg[symmetric] del: pastecart_neg)
  2524 
  2525 lemma pastecart_setsum:
  2526   fixes f:: "'d \<Rightarrow> 'a::semiring_1^_"
  2527   assumes fS: "finite S"
  2528   shows "pastecart (setsum f S) (setsum g S) = setsum (\<lambda>i. pastecart (f i) (g i)) S"
  2529   by (simp  add: pastecart_eq fstcart_setsum[OF fS] sndcart_setsum[OF fS] fstcart_pastecart sndcart_pastecart)
  2530 
  2531 lemma setsum_Plus:
  2532   "\<lbrakk>finite A; finite B\<rbrakk> \<Longrightarrow>
  2533     (\<Sum>x\<in>A <+> B. g x) = (\<Sum>x\<in>A. g (Inl x)) + (\<Sum>x\<in>B. g (Inr x))"
  2534   unfolding Plus_def
  2535   by (subst setsum_Un_disjoint, auto simp add: setsum_reindex)
  2536 
  2537 lemma setsum_UNIV_sum:
  2538   fixes g :: "'a::finite + 'b::finite \<Rightarrow> _"
  2539   shows "(\<Sum>x\<in>UNIV. g x) = (\<Sum>x\<in>UNIV. g (Inl x)) + (\<Sum>x\<in>UNIV. g (Inr x))"
  2540   apply (subst UNIV_Plus_UNIV [symmetric])
  2541   apply (rule setsum_Plus [OF finite finite])
  2542   done
  2543 
  2544 lemma norm_fstcart: "norm(fstcart x) <= norm (x::real ^('n::finite + 'm::finite))"
  2545 proof-
  2546   have th0: "norm x = norm (pastecart (fstcart x) (sndcart x))"
  2547     by (simp add: pastecart_fst_snd)
  2548   have th1: "fstcart x \<bullet> fstcart x \<le> pastecart (fstcart x) (sndcart x) \<bullet> pastecart (fstcart x) (sndcart x)"
  2549     by (simp add: dot_def setsum_UNIV_sum pastecart_def setsum_nonneg)
  2550   then show ?thesis
  2551     unfolding th0
  2552     unfolding real_vector_norm_def real_sqrt_le_iff id_def
  2553     by (simp add: dot_def)
  2554 qed
  2555 
  2556 lemma dist_fstcart: "dist(fstcart (x::real^_)) (fstcart y) <= dist x y"
  2557   by (metis dist_def fstcart_sub[symmetric] norm_fstcart)
  2558 
  2559 lemma norm_sndcart: "norm(sndcart x) <= norm (x::real ^('n::finite + 'm::finite))"
  2560 proof-
  2561   have th0: "norm x = norm (pastecart (fstcart x) (sndcart x))"
  2562     by (simp add: pastecart_fst_snd)
  2563   have th1: "sndcart x \<bullet> sndcart x \<le> pastecart (fstcart x) (sndcart x) \<bullet> pastecart (fstcart x) (sndcart x)"
  2564     by (simp add: dot_def setsum_UNIV_sum pastecart_def setsum_nonneg)
  2565   then show ?thesis
  2566     unfolding th0
  2567     unfolding real_vector_norm_def real_sqrt_le_iff id_def
  2568     by (simp add: dot_def)
  2569 qed
  2570 
  2571 lemma dist_sndcart: "dist(sndcart (x::real^_)) (sndcart y) <= dist x y"
  2572   by (metis dist_def sndcart_sub[symmetric] norm_sndcart)
  2573 
  2574 lemma dot_pastecart: "(pastecart (x1::'a::{times,comm_monoid_add}^'n::finite) (x2::'a::{times,comm_monoid_add}^'m::finite)) \<bullet> (pastecart y1 y2) =  x1 \<bullet> y1 + x2 \<bullet> y2"
  2575   by (simp add: dot_def setsum_UNIV_sum pastecart_def)
  2576 
  2577 lemma norm_pastecart: "norm(pastecart x y) <= norm(x :: real ^ 'm::finite) + norm(y::real^'n::finite)"
  2578   unfolding real_vector_norm_def dot_pastecart real_sqrt_le_iff id_def
  2579   apply (rule power2_le_imp_le)
  2580   apply (simp add: real_sqrt_pow2[OF add_nonneg_nonneg[OF dot_pos_le[of x] dot_pos_le[of y]]])
  2581   apply (auto simp add: power2_eq_square ring_simps)
  2582   apply (simp add: power2_eq_square[symmetric])
  2583   apply (rule mult_nonneg_nonneg)
  2584   apply (simp_all add: real_sqrt_pow2[OF dot_pos_le])
  2585   apply (rule add_nonneg_nonneg)
  2586   apply (simp_all add: real_sqrt_pow2[OF dot_pos_le])
  2587   done
  2588 
  2589 subsection {* A generic notion of "hull" (convex, affine, conic hull and closure). *}
  2590 
  2591 definition hull :: "'a set set \<Rightarrow> 'a set \<Rightarrow> 'a set" (infixl "hull" 75) where
  2592   "S hull s = Inter {t. t \<in> S \<and> s \<subseteq> t}"
  2593 
  2594 lemma hull_same: "s \<in> S \<Longrightarrow> S hull s = s"
  2595   unfolding hull_def by auto
  2596 
  2597 lemma hull_in: "(\<And>T. T \<subseteq> S ==> Inter T \<in> S) ==> (S hull s) \<in> S"
  2598 unfolding hull_def subset_iff by auto
  2599 
  2600 lemma hull_eq: "(\<And>T. T \<subseteq> S ==> Inter T \<in> S) ==> (S hull s) = s \<longleftrightarrow> s \<in> S"
  2601 using hull_same[of s S] hull_in[of S s] by metis
  2602 
  2603 
  2604 lemma hull_hull: "S hull (S hull s) = S hull s"
  2605   unfolding hull_def by blast
  2606 
  2607 lemma hull_subset: "s \<subseteq> (S hull s)"
  2608   unfolding hull_def by blast
  2609 
  2610 lemma hull_mono: " s \<subseteq> t ==> (S hull s) \<subseteq> (S hull t)"
  2611   unfolding hull_def by blast
  2612 
  2613 lemma hull_antimono: "S \<subseteq> T ==> (T hull s) \<subseteq> (S hull s)"
  2614   unfolding hull_def by blast
  2615 
  2616 lemma hull_minimal: "s \<subseteq> t \<Longrightarrow> t \<in> S ==> (S hull s) \<subseteq> t"
  2617   unfolding hull_def by blast
  2618 
  2619 lemma subset_hull: "t \<in> S ==> S hull s \<subseteq> t \<longleftrightarrow>  s \<subseteq> t"
  2620   unfolding hull_def by blast
  2621 
  2622 lemma hull_unique: "s \<subseteq> t \<Longrightarrow> t \<in> S \<Longrightarrow> (\<And>t'. s \<subseteq> t' \<Longrightarrow> t' \<in> S ==> t \<subseteq> t')
  2623            ==> (S hull s = t)"
  2624 unfolding hull_def by auto
  2625 
  2626 lemma hull_induct: "(\<And>x. x\<in> S \<Longrightarrow> P x) \<Longrightarrow> Q {x. P x} \<Longrightarrow> \<forall>x\<in> Q hull S. P x"
  2627   using hull_minimal[of S "{x. P x}" Q]
  2628   by (auto simp add: subset_eq Collect_def mem_def)
  2629 
  2630 lemma hull_inc: "x \<in> S \<Longrightarrow> x \<in> P hull S" by (metis hull_subset subset_eq)
  2631 
  2632 lemma hull_union_subset: "(S hull s) \<union> (S hull t) \<subseteq> (S hull (s \<union> t))"
  2633 unfolding Un_subset_iff by (metis hull_mono Un_upper1 Un_upper2)
  2634 
  2635 lemma hull_union: assumes T: "\<And>T. T \<subseteq> S ==> Inter T \<in> S"
  2636   shows "S hull (s \<union> t) = S hull (S hull s \<union> S hull t)"
  2637 apply rule
  2638 apply (rule hull_mono)
  2639 unfolding Un_subset_iff
  2640 apply (metis hull_subset Un_upper1 Un_upper2 subset_trans)
  2641 apply (rule hull_minimal)
  2642 apply (metis hull_union_subset)
  2643 apply (metis hull_in T)
  2644 done
  2645 
  2646 lemma hull_redundant_eq: "a \<in> (S hull s) \<longleftrightarrow> (S hull (insert a s) = S hull s)"
  2647   unfolding hull_def by blast
  2648 
  2649 lemma hull_redundant: "a \<in> (S hull s) ==> (S hull (insert a s) = S hull s)"
  2650 by (metis hull_redundant_eq)
  2651 
  2652 text{* Archimedian properties and useful consequences. *}
  2653 
  2654 lemma real_arch_simple: "\<exists>n. x <= real (n::nat)"
  2655   using reals_Archimedean2[of x] apply auto by (rule_tac x="Suc n" in exI, auto)
  2656 lemmas real_arch_lt = reals_Archimedean2
  2657 
  2658 lemmas real_arch = reals_Archimedean3
  2659 
  2660 lemma real_arch_inv: "0 < e \<longleftrightarrow> (\<exists>n::nat. n \<noteq> 0 \<and> 0 < inverse (real n) \<and> inverse (real n) < e)"
  2661   using reals_Archimedean
  2662   apply (auto simp add: field_simps inverse_positive_iff_positive)
  2663   apply (subgoal_tac "inverse (real n) > 0")
  2664   apply arith
  2665   apply simp
  2666   done
  2667 
  2668 lemma real_pow_lbound: "0 <= x ==> 1 + real n * x <= (1 + x) ^ n"
  2669 proof(induct n)
  2670   case 0 thus ?case by simp
  2671 next
  2672   case (Suc n)
  2673   hence h: "1 + real n * x \<le> (1 + x) ^ n" by simp
  2674   from h have p: "1 \<le> (1 + x) ^ n" using Suc.prems by simp
  2675   from h have "1 + real n * x + x \<le> (1 + x) ^ n + x" by simp
  2676   also have "\<dots> \<le> (1 + x) ^ Suc n" apply (subst diff_le_0_iff_le[symmetric])
  2677     apply (simp add: ring_simps)
  2678     using mult_left_mono[OF p Suc.prems] by simp
  2679   finally show ?case  by (simp add: real_of_nat_Suc ring_simps)
  2680 qed
  2681 
  2682 lemma real_arch_pow: assumes x: "1 < (x::real)" shows "\<exists>n. y < x^n"
  2683 proof-
  2684   from x have x0: "x - 1 > 0" by arith
  2685   from real_arch[OF x0, rule_format, of y]
  2686   obtain n::nat where n:"y < real n * (x - 1)" by metis
  2687   from x0 have x00: "x- 1 \<ge> 0" by arith
  2688   from real_pow_lbound[OF x00, of n] n
  2689   have "y < x^n" by auto
  2690   then show ?thesis by metis
  2691 qed
  2692 
  2693 lemma real_arch_pow2: "\<exists>n. (x::real) < 2^ n"
  2694   using real_arch_pow[of 2 x] by simp
  2695 
  2696 lemma real_arch_pow_inv: assumes y: "(y::real) > 0" and x1: "x < 1"
  2697   shows "\<exists>n. x^n < y"
  2698 proof-
  2699   {assume x0: "x > 0"
  2700     from x0 x1 have ix: "1 < 1/x" by (simp add: field_simps)
  2701     from real_arch_pow[OF ix, of "1/y"]
  2702     obtain n where n: "1/y < (1/x)^n" by blast
  2703     then
  2704     have ?thesis using y x0 by (auto simp add: field_simps power_divide) }
  2705   moreover
  2706   {assume "\<not> x > 0" with y x1 have ?thesis apply auto by (rule exI[where x=1], auto)}
  2707   ultimately show ?thesis by metis
  2708 qed
  2709 
  2710 lemma forall_pos_mono: "(\<And>d e::real. d < e \<Longrightarrow> P d ==> P e) \<Longrightarrow> (\<And>n::nat. n \<noteq> 0 ==> P(inverse(real n))) \<Longrightarrow> (\<And>e. 0 < e ==> P e)"
  2711   by (metis real_arch_inv)
  2712 
  2713 lemma forall_pos_mono_1: "(\<And>d e::real. d < e \<Longrightarrow> P d ==> P e) \<Longrightarrow> (\<And>n. P(inverse(real (Suc n)))) ==> 0 < e ==> P e"
  2714   apply (rule forall_pos_mono)
  2715   apply auto
  2716   apply (atomize)
  2717   apply (erule_tac x="n - 1" in allE)
  2718   apply auto
  2719   done
  2720 
  2721 lemma real_archimedian_rdiv_eq_0: assumes x0: "x \<ge> 0" and c: "c \<ge> 0" and xc: "\<forall>(m::nat)>0. real m * x \<le> c"
  2722   shows "x = 0"
  2723 proof-
  2724   {assume "x \<noteq> 0" with x0 have xp: "x > 0" by arith
  2725     from real_arch[OF xp, rule_format, of c] obtain n::nat where n: "c < real n * x"  by blast
  2726     with xc[rule_format, of n] have "n = 0" by arith
  2727     with n c have False by simp}
  2728   then show ?thesis by blast
  2729 qed
  2730 
  2731 (* ------------------------------------------------------------------------- *)
  2732 (* Relate max and min to sup and inf.                                        *)
  2733 (* ------------------------------------------------------------------------- *)
  2734 
  2735 lemma real_max_rsup: "max x y = rsup {x,y}"
  2736 proof-
  2737   have f: "finite {x, y}" "{x,y} \<noteq> {}"  by simp_all
  2738   from rsup_finite_le_iff[OF f, of "max x y"] have "rsup {x,y} \<le> max x y" by simp
  2739   moreover
  2740   have "max x y \<le> rsup {x,y}" using rsup_finite_ge_iff[OF f, of "max x y"]
  2741     by (simp add: linorder_linear)
  2742   ultimately show ?thesis by arith
  2743 qed
  2744 
  2745 lemma real_min_rinf: "min x y = rinf {x,y}"
  2746 proof-
  2747   have f: "finite {x, y}" "{x,y} \<noteq> {}"  by simp_all
  2748   from rinf_finite_le_iff[OF f, of "min x y"] have "rinf {x,y} \<le> min x y"
  2749     by (simp add: linorder_linear)
  2750   moreover
  2751   have "min x y \<le> rinf {x,y}" using rinf_finite_ge_iff[OF f, of "min x y"]
  2752     by simp
  2753   ultimately show ?thesis by arith
  2754 qed
  2755 
  2756 (* ------------------------------------------------------------------------- *)
  2757 (* Geometric progression.                                                    *)
  2758 (* ------------------------------------------------------------------------- *)
  2759 
  2760 lemma sum_gp_basic: "((1::'a::{field, recpower}) - x) * setsum (\<lambda>i. x^i) {0 .. n} = (1 - x^(Suc n))"
  2761   (is "?lhs = ?rhs")
  2762 proof-
  2763   {assume x1: "x = 1" hence ?thesis by simp}
  2764   moreover
  2765   {assume x1: "x\<noteq>1"
  2766     hence x1': "x - 1 \<noteq> 0" "1 - x \<noteq> 0" "x - 1 = - (1 - x)" "- (1 - x) \<noteq> 0" by auto
  2767     from geometric_sum[OF x1, of "Suc n", unfolded x1']
  2768     have "(- (1 - x)) * setsum (\<lambda>i. x^i) {0 .. n} = - (1 - x^(Suc n))"
  2769       unfolding atLeastLessThanSuc_atLeastAtMost
  2770       using x1' apply (auto simp only: field_simps)
  2771       apply (simp add: ring_simps)
  2772       done
  2773     then have ?thesis by (simp add: ring_simps) }
  2774   ultimately show ?thesis by metis
  2775 qed
  2776 
  2777 lemma sum_gp_multiplied: assumes mn: "m <= n"
  2778   shows "((1::'a::{field, recpower}) - x) * setsum (op ^ x) {m..n} = x^m - x^ Suc n"
  2779   (is "?lhs = ?rhs")
  2780 proof-
  2781   let ?S = "{0..(n - m)}"
  2782   from mn have mn': "n - m \<ge> 0" by arith
  2783   let ?f = "op + m"
  2784   have i: "inj_on ?f ?S" unfolding inj_on_def by auto
  2785   have f: "?f ` ?S = {m..n}"
  2786     using mn apply (auto simp add: image_iff Bex_def) by arith
  2787   have th: "op ^ x o op + m = (\<lambda>i. x^m * x^i)"
  2788     by (rule ext, simp add: power_add power_mult)
  2789   from setsum_reindex[OF i, of "op ^ x", unfolded f th setsum_right_distrib[symmetric]]
  2790   have "?lhs = x^m * ((1 - x) * setsum (op ^ x) {0..n - m})" by simp
  2791   then show ?thesis unfolding sum_gp_basic using mn
  2792     by (simp add: ring_simps power_add[symmetric])
  2793 qed
  2794 
  2795 lemma sum_gp: "setsum (op ^ (x::'a::{field, recpower})) {m .. n} =
  2796    (if n < m then 0 else if x = 1 then of_nat ((n + 1) - m)
  2797                     else (x^ m - x^ (Suc n)) / (1 - x))"
  2798 proof-
  2799   {assume nm: "n < m" hence ?thesis by simp}
  2800   moreover
  2801   {assume "\<not> n < m" hence nm: "m \<le> n" by arith
  2802     {assume x: "x = 1"  hence ?thesis by simp}
  2803     moreover
  2804     {assume x: "x \<noteq> 1" hence nz: "1 - x \<noteq> 0" by simp
  2805       from sum_gp_multiplied[OF nm, of x] nz have ?thesis by (simp add: field_simps)}
  2806     ultimately have ?thesis by metis
  2807   }
  2808   ultimately show ?thesis by metis
  2809 qed
  2810 
  2811 lemma sum_gp_offset: "setsum (op ^ (x::'a::{field,recpower})) {m .. m+n} =
  2812   (if x = 1 then of_nat n + 1 else x^m * (1 - x^Suc n) / (1 - x))"
  2813   unfolding sum_gp[of x m "m + n"] power_Suc
  2814   by (simp add: ring_simps power_add)
  2815 
  2816 
  2817 subsection{* A bit of linear algebra. *}
  2818 
  2819 definition "subspace S \<longleftrightarrow> 0 \<in> S \<and> (\<forall>x\<in> S. \<forall>y \<in>S. x + y \<in> S) \<and> (\<forall>c. \<forall>x \<in>S. c *s x \<in>S )"
  2820 definition "span S = (subspace hull S)"
  2821 definition "dependent S \<longleftrightarrow> (\<exists>a \<in> S. a \<in> span(S - {a}))"
  2822 abbreviation "independent s == ~(dependent s)"
  2823 
  2824 (* Closure properties of subspaces.                                          *)
  2825 
  2826 lemma subspace_UNIV[simp]: "subspace(UNIV)" by (simp add: subspace_def)
  2827 
  2828 lemma subspace_0: "subspace S ==> 0 \<in> S" by (metis subspace_def)
  2829 
  2830 lemma subspace_add: "subspace S \<Longrightarrow> x \<in> S \<Longrightarrow> y \<in> S ==> x + y \<in> S"
  2831   by (metis subspace_def)
  2832 
  2833 lemma subspace_mul: "subspace S \<Longrightarrow> x \<in> S \<Longrightarrow> c *s x \<in> S"
  2834   by (metis subspace_def)
  2835 
  2836 lemma subspace_neg: "subspace S \<Longrightarrow> (x::'a::ring_1^'n) \<in> S \<Longrightarrow> - x \<in> S"
  2837   by (metis vector_sneg_minus1 subspace_mul)
  2838 
  2839 lemma subspace_sub: "subspace S \<Longrightarrow> (x::'a::ring_1^'n) \<in> S \<Longrightarrow> y \<in> S \<Longrightarrow> x - y \<in> S"
  2840   by (metis diff_def subspace_add subspace_neg)
  2841 
  2842 lemma subspace_setsum:
  2843   assumes sA: "subspace A" and fB: "finite B"
  2844   and f: "\<forall>x\<in> B. f x \<in> A"
  2845   shows "setsum f B \<in> A"
  2846   using  fB f sA
  2847   apply(induct rule: finite_induct[OF fB])
  2848   by (simp add: subspace_def sA, auto simp add: sA subspace_add)
  2849 
  2850 lemma subspace_linear_image:
  2851   assumes lf: "linear (f::'a::semiring_1^'n \<Rightarrow> _)" and sS: "subspace S"
  2852   shows "subspace(f ` S)"
  2853   using lf sS linear_0[OF lf]
  2854   unfolding linear_def subspace_def
  2855   apply (auto simp add: image_iff)
  2856   apply (rule_tac x="x + y" in bexI, auto)
  2857   apply (rule_tac x="c*s x" in bexI, auto)
  2858   done
  2859 
  2860 lemma subspace_linear_preimage: "linear (f::'a::semiring_1^'n \<Rightarrow> _) ==> subspace S ==> subspace {x. f x \<in> S}"
  2861   by (auto simp add: subspace_def linear_def linear_0[of f])
  2862 
  2863 lemma subspace_trivial: "subspace {0::'a::semiring_1 ^_}"
  2864   by (simp add: subspace_def)
  2865 
  2866 lemma subspace_inter: "subspace A \<Longrightarrow> subspace B ==> subspace (A \<inter> B)"
  2867   by (simp add: subspace_def)
  2868 
  2869 
  2870 lemma span_mono: "A \<subseteq> B ==> span A \<subseteq> span B"
  2871   by (metis span_def hull_mono)
  2872 
  2873 lemma subspace_span: "subspace(span S)"
  2874   unfolding span_def
  2875   apply (rule hull_in[unfolded mem_def])
  2876   apply (simp only: subspace_def Inter_iff Int_iff subset_eq)
  2877   apply auto
  2878   apply (erule_tac x="X" in ballE)
  2879   apply (simp add: mem_def)
  2880   apply blast
  2881   apply (erule_tac x="X" in ballE)
  2882   apply (erule_tac x="X" in ballE)
  2883   apply (erule_tac x="X" in ballE)
  2884   apply (clarsimp simp add: mem_def)
  2885   apply simp
  2886   apply simp
  2887   apply simp
  2888   apply (erule_tac x="X" in ballE)
  2889   apply (erule_tac x="X" in ballE)
  2890   apply (simp add: mem_def)
  2891   apply simp
  2892   apply simp
  2893   done
  2894 
  2895 lemma span_clauses:
  2896   "a \<in> S ==> a \<in> span S"
  2897   "0 \<in> span S"
  2898   "x\<in> span S \<Longrightarrow> y \<in> span S ==> x + y \<in> span S"
  2899   "x \<in> span S \<Longrightarrow> c *s x \<in> span S"
  2900   by (metis span_def hull_subset subset_eq subspace_span subspace_def)+
  2901 
  2902 lemma span_induct: assumes SP: "\<And>x. x \<in> S ==> P x"
  2903   and P: "subspace P" and x: "x \<in> span S" shows "P x"
  2904 proof-
  2905   from SP have SP': "S \<subseteq> P" by (simp add: mem_def subset_eq)
  2906   from P have P': "P \<in> subspace" by (simp add: mem_def)
  2907   from x hull_minimal[OF SP' P', unfolded span_def[symmetric]]
  2908   show "P x" by (metis mem_def subset_eq)
  2909 qed
  2910 
  2911 lemma span_empty: "span {} = {(0::'a::semiring_0 ^ 'n)}"
  2912   apply (simp add: span_def)
  2913   apply (rule hull_unique)
  2914   apply (auto simp add: mem_def subspace_def)
  2915   unfolding mem_def[of "0::'a^'n", symmetric]
  2916   apply simp
  2917   done
  2918 
  2919 lemma independent_empty: "independent {}"
  2920   by (simp add: dependent_def)
  2921 
  2922 lemma independent_mono: "independent A \<Longrightarrow> B \<subseteq> A ==> independent B"
  2923   apply (clarsimp simp add: dependent_def span_mono)
  2924   apply (subgoal_tac "span (B - {a}) \<le> span (A - {a})")
  2925   apply force
  2926   apply (rule span_mono)
  2927   apply auto
  2928   done
  2929 
  2930 lemma span_subspace: "A \<subseteq> B \<Longrightarrow> B \<le> span A \<Longrightarrow>  subspace B \<Longrightarrow> span A = B"
  2931   by (metis order_antisym span_def hull_minimal mem_def)
  2932 
  2933 lemma span_induct': assumes SP: "\<forall>x \<in> S. P x"
  2934   and P: "subspace P" shows "\<forall>x \<in> span S. P x"
  2935   using span_induct SP P by blast
  2936 
  2937 inductive span_induct_alt_help for S:: "'a::semiring_1^'n \<Rightarrow> bool"
  2938   where
  2939   span_induct_alt_help_0: "span_induct_alt_help S 0"
  2940   | span_induct_alt_help_S: "x \<in> S \<Longrightarrow> span_induct_alt_help S z \<Longrightarrow> span_induct_alt_help S (c *s x + z)"
  2941 
  2942 lemma span_induct_alt':
  2943   assumes h0: "h (0::'a::semiring_1^'n)" and hS: "\<And>c x y. x \<in> S \<Longrightarrow> h y \<Longrightarrow> h (c*s x + y)" shows "\<forall>x \<in> span S. h x"
  2944 proof-
  2945   {fix x:: "'a^'n" assume x: "span_induct_alt_help S x"
  2946     have "h x"
  2947       apply (rule span_induct_alt_help.induct[OF x])
  2948       apply (rule h0)
  2949       apply (rule hS, assumption, assumption)
  2950       done}
  2951   note th0 = this
  2952   {fix x assume x: "x \<in> span S"
  2953 
  2954     have "span_induct_alt_help S x"
  2955       proof(rule span_induct[where x=x and S=S])
  2956 	show "x \<in> span S" using x .
  2957       next
  2958 	fix x assume xS : "x \<in> S"
  2959 	  from span_induct_alt_help_S[OF xS span_induct_alt_help_0, of 1]
  2960 	  show "span_induct_alt_help S x" by simp
  2961 	next
  2962 	have "span_induct_alt_help S 0" by (rule span_induct_alt_help_0)
  2963 	moreover
  2964 	{fix x y assume h: "span_induct_alt_help S x" "span_induct_alt_help S y"
  2965 	  from h
  2966 	  have "span_induct_alt_help S (x + y)"
  2967 	    apply (induct rule: span_induct_alt_help.induct)
  2968 	    apply simp
  2969 	    unfolding add_assoc
  2970 	    apply (rule span_induct_alt_help_S)
  2971 	    apply assumption
  2972 	    apply simp
  2973 	    done}
  2974 	moreover
  2975 	{fix c x assume xt: "span_induct_alt_help S x"
  2976 	  then have "span_induct_alt_help S (c*s x)"
  2977 	    apply (induct rule: span_induct_alt_help.induct)
  2978 	    apply (simp add: span_induct_alt_help_0)
  2979 	    apply (simp add: vector_smult_assoc vector_add_ldistrib)
  2980 	    apply (rule span_induct_alt_help_S)
  2981 	    apply assumption
  2982 	    apply simp
  2983 	    done
  2984 	}
  2985 	ultimately show "subspace (span_induct_alt_help S)"
  2986 	  unfolding subspace_def mem_def Ball_def by blast
  2987       qed}
  2988   with th0 show ?thesis by blast
  2989 qed
  2990 
  2991 lemma span_induct_alt:
  2992   assumes h0: "h (0::'a::semiring_1^'n)" and hS: "\<And>c x y. x \<in> S \<Longrightarrow> h y \<Longrightarrow> h (c*s x + y)" and x: "x \<in> span S"
  2993   shows "h x"
  2994 using span_induct_alt'[of h S] h0 hS x by blast
  2995 
  2996 (* Individual closure properties. *)
  2997 
  2998 lemma span_superset: "x \<in> S ==> x \<in> span S" by (metis span_clauses)
  2999 
  3000 lemma span_0: "0 \<in> span S" by (metis subspace_span subspace_0)
  3001 
  3002 lemma span_add: "x \<in> span S \<Longrightarrow> y \<in> span S ==> x + y \<in> span S"
  3003   by (metis subspace_add subspace_span)
  3004 
  3005 lemma span_mul: "x \<in> span S ==> (c *s x) \<in> span S"
  3006   by (metis subspace_span subspace_mul)
  3007 
  3008 lemma span_neg: "x \<in> span S ==> - (x::'a::ring_1^'n) \<in> span S"
  3009   by (metis subspace_neg subspace_span)
  3010 
  3011 lemma span_sub: "(x::'a::ring_1^'n) \<in> span S \<Longrightarrow> y \<in> span S ==> x - y \<in> span S"
  3012   by (metis subspace_span subspace_sub)
  3013 
  3014 lemma span_setsum: "finite A \<Longrightarrow> \<forall>x \<in> A. f x \<in> span S ==> setsum f A \<in> span S"
  3015   apply (rule subspace_setsum)
  3016   by (metis subspace_span subspace_setsum)+
  3017 
  3018 lemma span_add_eq: "(x::'a::ring_1^'n) \<in> span S \<Longrightarrow> x + y \<in> span S \<longleftrightarrow> y \<in> span S"
  3019   apply (auto simp only: span_add span_sub)
  3020   apply (subgoal_tac "(x + y) - x \<in> span S", simp)
  3021   by (simp only: span_add span_sub)
  3022 
  3023 (* Mapping under linear image. *)
  3024 
  3025 lemma span_linear_image: assumes lf: "linear (f::'a::semiring_1 ^ 'n => _)"
  3026   shows "span (f ` S) = f ` (span S)"
  3027 proof-
  3028   {fix x
  3029     assume x: "x \<in> span (f ` S)"
  3030     have "x \<in> f ` span S"
  3031       apply (rule span_induct[where x=x and S = "f ` S"])
  3032       apply (clarsimp simp add: image_iff)
  3033       apply (frule span_superset)
  3034       apply blast
  3035       apply (simp only: mem_def)
  3036       apply (rule subspace_linear_image[OF lf])
  3037       apply (rule subspace_span)
  3038       apply (rule x)
  3039       done}
  3040   moreover
  3041   {fix x assume x: "x \<in> span S"
  3042     have th0:"(\<lambda>a. f a \<in> span (f ` S)) = {x. f x \<in> span (f ` S)}" apply (rule set_ext)
  3043       unfolding mem_def Collect_def ..
  3044     have "f x \<in> span (f ` S)"
  3045       apply (rule span_induct[where S=S])
  3046       apply (rule span_superset)
  3047       apply simp
  3048       apply (subst th0)
  3049       apply (rule subspace_linear_preimage[OF lf subspace_span, of "f ` S"])
  3050       apply (rule x)
  3051       done}
  3052   ultimately show ?thesis by blast
  3053 qed
  3054 
  3055 (* The key breakdown property. *)
  3056 
  3057 lemma span_breakdown:
  3058   assumes bS: "(b::'a::ring_1 ^ 'n) \<in> S" and aS: "a \<in> span S"
  3059   shows "\<exists>k. a - k*s b \<in> span (S - {b})" (is "?P a")
  3060 proof-
  3061   {fix x assume xS: "x \<in> S"
  3062     {assume ab: "x = b"
  3063       then have "?P x"
  3064 	apply simp
  3065 	apply (rule exI[where x="1"], simp)
  3066 	by (rule span_0)}
  3067     moreover
  3068     {assume ab: "x \<noteq> b"
  3069       then have "?P x"  using xS
  3070 	apply -
  3071 	apply (rule exI[where x=0])
  3072 	apply (rule span_superset)
  3073 	by simp}
  3074     ultimately have "?P x" by blast}
  3075   moreover have "subspace ?P"
  3076     unfolding subspace_def
  3077     apply auto
  3078     apply (simp add: mem_def)
  3079     apply (rule exI[where x=0])
  3080     using span_0[of "S - {b}"]
  3081     apply (simp add: mem_def)
  3082     apply (clarsimp simp add: mem_def)
  3083     apply (rule_tac x="k + ka" in exI)
  3084     apply (subgoal_tac "x + y - (k + ka) *s b = (x - k*s b) + (y - ka *s b)")
  3085     apply (simp only: )
  3086     apply (rule span_add[unfolded mem_def])
  3087     apply assumption+
  3088     apply (vector ring_simps)
  3089     apply (clarsimp simp add: mem_def)
  3090     apply (rule_tac x= "c*k" in exI)
  3091     apply (subgoal_tac "c *s x - (c * k) *s b = c*s (x - k*s b)")
  3092     apply (simp only: )
  3093     apply (rule span_mul[unfolded mem_def])
  3094     apply assumption
  3095     by (vector ring_simps)
  3096   ultimately show "?P a" using aS span_induct[where S=S and P= "?P"] by metis
  3097 qed
  3098 
  3099 lemma span_breakdown_eq:
  3100   "(x::'a::ring_1^'n) \<in> span (insert a S) \<longleftrightarrow> (\<exists>k. (x - k *s a) \<in> span S)" (is "?lhs \<longleftrightarrow> ?rhs")
  3101 proof-
  3102   {assume x: "x \<in> span (insert a S)"
  3103     from x span_breakdown[of "a" "insert a S" "x"]
  3104     have ?rhs apply clarsimp
  3105       apply (rule_tac x= "k" in exI)
  3106       apply (rule set_rev_mp[of _ "span (S - {a})" _])
  3107       apply assumption
  3108       apply (rule span_mono)
  3109       apply blast
  3110       done}
  3111   moreover
  3112   { fix k assume k: "x - k *s a \<in> span S"
  3113     have eq: "x = (x - k *s a) + k *s a" by vector
  3114     have "(x - k *s a) + k *s a \<in> span (insert a S)"
  3115       apply (rule span_add)
  3116       apply (rule set_rev_mp[of _ "span S" _])
  3117       apply (rule k)
  3118       apply (rule span_mono)
  3119       apply blast
  3120       apply (rule span_mul)
  3121       apply (rule span_superset)
  3122       apply blast
  3123       done
  3124     then have ?lhs using eq by metis}
  3125   ultimately show ?thesis by blast
  3126 qed
  3127 
  3128 (* Hence some "reversal" results.*)
  3129 
  3130 lemma in_span_insert:
  3131   assumes a: "(a::'a::field^'n) \<in> span (insert b S)" and na: "a \<notin> span S"
  3132   shows "b \<in> span (insert a S)"
  3133 proof-
  3134   from span_breakdown[of b "insert b S" a, OF insertI1 a]
  3135   obtain k where k: "a - k*s b \<in> span (S - {b})" by auto
  3136   {assume k0: "k = 0"
  3137     with k have "a \<in> span S"
  3138       apply (simp)
  3139       apply (rule set_rev_mp)
  3140       apply assumption
  3141       apply (rule span_mono)
  3142       apply blast
  3143       done
  3144     with na  have ?thesis by blast}
  3145   moreover
  3146   {assume k0: "k \<noteq> 0"
  3147     have eq: "b = (1/k) *s a - ((1/k) *s a - b)" by vector
  3148     from k0 have eq': "(1/k) *s (a - k*s b) = (1/k) *s a - b"
  3149       by (vector field_simps)
  3150     from k have "(1/k) *s (a - k*s b) \<in> span (S - {b})"
  3151       by (rule span_mul)
  3152     hence th: "(1/k) *s a - b \<in> span (S - {b})"
  3153       unfolding eq' .
  3154 
  3155     from k
  3156     have ?thesis
  3157       apply (subst eq)
  3158       apply (rule span_sub)
  3159       apply (rule span_mul)
  3160       apply (rule span_superset)
  3161       apply blast
  3162       apply (rule set_rev_mp)
  3163       apply (rule th)
  3164       apply (rule span_mono)
  3165       using na by blast}
  3166   ultimately show ?thesis by blast
  3167 qed
  3168 
  3169 lemma in_span_delete:
  3170   assumes a: "(a::'a::field^'n) \<in> span S"
  3171   and na: "a \<notin> span (S-{b})"
  3172   shows "b \<in> span (insert a (S - {b}))"
  3173   apply (rule in_span_insert)
  3174   apply (rule set_rev_mp)
  3175   apply (rule a)
  3176   apply (rule span_mono)
  3177   apply blast
  3178   apply (rule na)
  3179   done
  3180 
  3181 (* Transitivity property. *)
  3182 
  3183 lemma span_trans:
  3184   assumes x: "(x::'a::ring_1^'n) \<in> span S" and y: "y \<in> span (insert x S)"
  3185   shows "y \<in> span S"
  3186 proof-
  3187   from span_breakdown[of x "insert x S" y, OF insertI1 y]
  3188   obtain k where k: "y -k*s x \<in> span (S - {x})" by auto
  3189   have eq: "y = (y - k *s x) + k *s x" by vector
  3190   show ?thesis
  3191     apply (subst eq)
  3192     apply (rule span_add)
  3193     apply (rule set_rev_mp)
  3194     apply (rule k)
  3195     apply (rule span_mono)
  3196     apply blast
  3197     apply (rule span_mul)
  3198     by (rule x)
  3199 qed
  3200 
  3201 (* ------------------------------------------------------------------------- *)
  3202 (* An explicit expansion is sometimes needed.                                *)
  3203 (* ------------------------------------------------------------------------- *)
  3204 
  3205 lemma span_explicit:
  3206   "span P = {y::'a::semiring_1^'n. \<exists>S u. finite S \<and> S \<subseteq> P \<and> setsum (\<lambda>v. u v *s v) S = y}"
  3207   (is "_ = ?E" is "_ = {y. ?h y}" is "_ = {y. \<exists>S u. ?Q S u y}")
  3208 proof-
  3209   {fix x assume x: "x \<in> ?E"
  3210     then obtain S u where fS: "finite S" and SP: "S\<subseteq>P" and u: "setsum (\<lambda>v. u v *s v) S = x"
  3211       by blast
  3212     have "x \<in> span P"
  3213       unfolding u[symmetric]
  3214       apply (rule span_setsum[OF fS])
  3215       using span_mono[OF SP]
  3216       by (auto intro: span_superset span_mul)}
  3217   moreover
  3218   have "\<forall>x \<in> span P. x \<in> ?E"
  3219     unfolding mem_def Collect_def
  3220   proof(rule span_induct_alt')
  3221     show "?h 0"
  3222       apply (rule exI[where x="{}"]) by simp
  3223   next
  3224     fix c x y
  3225     assume x: "x \<in> P" and hy: "?h y"
  3226     from hy obtain S u where fS: "finite S" and SP: "S\<subseteq>P"
  3227       and u: "setsum (\<lambda>v. u v *s v) S = y" by blast
  3228     let ?S = "insert x S"
  3229     let ?u = "\<lambda>y. if y = x then (if x \<in> S then u y + c else c)
  3230                   else u y"
  3231     from fS SP x have th0: "finite (insert x S)" "insert x S \<subseteq> P" by blast+
  3232     {assume xS: "x \<in> S"
  3233       have S1: "S = (S - {x}) \<union> {x}"
  3234 	and Sss:"finite (S - {x})" "finite {x}" "(S -{x}) \<inter> {x} = {}" using xS fS by auto
  3235       have "setsum (\<lambda>v. ?u v *s v) ?S =(\<Sum>v\<in>S - {x}. u v *s v) + (u x + c) *s x"
  3236 	using xS
  3237 	by (simp add: setsum_Un_disjoint[OF Sss, unfolded S1[symmetric]]
  3238 	  setsum_clauses(2)[OF fS] cong del: if_weak_cong)
  3239       also have "\<dots> = (\<Sum>v\<in>S. u v *s v) + c *s x"
  3240 	apply (simp add: setsum_Un_disjoint[OF Sss, unfolded S1[symmetric]])
  3241 	by (vector ring_simps)
  3242       also have "\<dots> = c*s x + y"
  3243 	by (simp add: add_commute u)
  3244       finally have "setsum (\<lambda>v. ?u v *s v) ?S = c*s x + y" .
  3245     then have "?Q ?S ?u (c*s x + y)" using th0 by blast}
  3246   moreover
  3247   {assume xS: "x \<notin> S"
  3248     have th00: "(\<Sum>v\<in>S. (if v = x then c else u v) *s v) = y"
  3249       unfolding u[symmetric]
  3250       apply (rule setsum_cong2)
  3251       using xS by auto
  3252     have "?Q ?S ?u (c*s x + y)" using fS xS th0
  3253       by (simp add: th00 setsum_clauses add_commute cong del: if_weak_cong)}
  3254   ultimately have "?Q ?S ?u (c*s x + y)"
  3255     by (cases "x \<in> S", simp, simp)
  3256     then show "?h (c*s x + y)"
  3257       apply -
  3258       apply (rule exI[where x="?S"])
  3259       apply (rule exI[where x="?u"]) by metis
  3260   qed
  3261   ultimately show ?thesis by blast
  3262 qed
  3263 
  3264 lemma dependent_explicit:
  3265   "dependent P \<longleftrightarrow> (\<exists>S u. finite S \<and> S \<subseteq> P \<and> (\<exists>(v::'a::{idom,field}^'n) \<in>S. u v \<noteq> 0 \<and> setsum (\<lambda>v. u v *s v) S = 0))" (is "?lhs = ?rhs")
  3266 proof-
  3267   {assume dP: "dependent P"
  3268     then obtain a S u where aP: "a \<in> P" and fS: "finite S"
  3269       and SP: "S \<subseteq> P - {a}" and ua: "setsum (\<lambda>v. u v *s v) S = a"
  3270       unfolding dependent_def span_explicit by blast
  3271     let ?S = "insert a S"
  3272     let ?u = "\<lambda>y. if y = a then - 1 else u y"
  3273     let ?v = a
  3274     from aP SP have aS: "a \<notin> S" by blast
  3275     from fS SP aP have th0: "finite ?S" "?S \<subseteq> P" "?v \<in> ?S" "?u ?v \<noteq> 0" by auto
  3276     have s0: "setsum (\<lambda>v. ?u v *s v) ?S = 0"
  3277       using fS aS
  3278       apply (simp add: vector_smult_lneg vector_smult_lid setsum_clauses ring_simps )
  3279       apply (subst (2) ua[symmetric])
  3280       apply (rule setsum_cong2)
  3281       by auto
  3282     with th0 have ?rhs
  3283       apply -
  3284       apply (rule exI[where x= "?S"])
  3285       apply (rule exI[where x= "?u"])
  3286       by clarsimp}
  3287   moreover
  3288   {fix S u v assume fS: "finite S"
  3289       and SP: "S \<subseteq> P" and vS: "v \<in> S" and uv: "u v \<noteq> 0"
  3290     and u: "setsum (\<lambda>v. u v *s v) S = 0"
  3291     let ?a = v
  3292     let ?S = "S - {v}"
  3293     let ?u = "\<lambda>i. (- u i) / u v"
  3294     have th0: "?a \<in> P" "finite ?S" "?S \<subseteq> P"       using fS SP vS by auto
  3295     have "setsum (\<lambda>v. ?u v *s v) ?S = setsum (\<lambda>v. (- (inverse (u ?a))) *s (u v *s v)) S - ?u v *s v"
  3296       using fS vS uv
  3297       by (simp add: setsum_diff1 vector_smult_lneg divide_inverse
  3298 	vector_smult_assoc field_simps)
  3299     also have "\<dots> = ?a"
  3300       unfolding setsum_cmul u
  3301       using uv by (simp add: vector_smult_lneg)
  3302     finally  have "setsum (\<lambda>v. ?u v *s v) ?S = ?a" .
  3303     with th0 have ?lhs
  3304       unfolding dependent_def span_explicit
  3305       apply -
  3306       apply (rule bexI[where x= "?a"])
  3307       apply simp_all
  3308       apply (rule exI[where x= "?S"])
  3309       by auto}
  3310   ultimately show ?thesis by blast
  3311 qed
  3312 
  3313 
  3314 lemma span_finite:
  3315   assumes fS: "finite S"
  3316   shows "span S = {(y::'a::semiring_1^'n). \<exists>u. setsum (\<lambda>v. u v *s v) S = y}"
  3317   (is "_ = ?rhs")
  3318 proof-
  3319   {fix y assume y: "y \<in> span S"
  3320     from y obtain S' u where fS': "finite S'" and SS': "S' \<subseteq> S" and
  3321       u: "setsum (\<lambda>v. u v *s v) S' = y" unfolding span_explicit by blast
  3322     let ?u = "\<lambda>x. if x \<in> S' then u x else 0"
  3323     from setsum_restrict_set[OF fS, of "\<lambda>v. u v *s v" S', symmetric] SS'
  3324     have "setsum (\<lambda>v. ?u v *s v) S = setsum (\<lambda>v. u v *s v) S'"
  3325       unfolding cond_value_iff cond_application_beta
  3326       apply (simp add: cond_value_iff cong del: if_weak_cong)
  3327       apply (rule setsum_cong)
  3328       apply auto
  3329       done
  3330     hence "setsum (\<lambda>v. ?u v *s v) S = y" by (metis u)
  3331     hence "y \<in> ?rhs" by auto}
  3332   moreover
  3333   {fix y u assume u: "setsum (\<lambda>v. u v *s v) S = y"
  3334     then have "y \<in> span S" using fS unfolding span_explicit by auto}
  3335   ultimately show ?thesis by blast
  3336 qed
  3337 
  3338 
  3339 (* Standard bases are a spanning set, and obviously finite.                  *)
  3340 
  3341 lemma span_stdbasis:"span {basis i :: 'a::ring_1^'n::finite | i. i \<in> (UNIV :: 'n set)} = UNIV"
  3342 apply (rule set_ext)
  3343 apply auto
  3344 apply (subst basis_expansion[symmetric])
  3345 apply (rule span_setsum)
  3346 apply simp
  3347 apply auto
  3348 apply (rule span_mul)
  3349 apply (rule span_superset)
  3350 apply (auto simp add: Collect_def mem_def)
  3351 done
  3352 
  3353 lemma has_size_stdbasis: "{basis i ::real ^'n::finite | i. i \<in> (UNIV :: 'n set)} hassize CARD('n)" (is "?S hassize ?n")
  3354 proof-
  3355   have eq: "?S = basis ` UNIV" by blast
  3356   show ?thesis unfolding eq
  3357     apply (rule hassize_image_inj[OF basis_inj])
  3358     by (simp add: hassize_def)
  3359 qed
  3360 
  3361 lemma finite_stdbasis: "finite {basis i ::real^'n::finite |i. i\<in> (UNIV:: 'n set)}"
  3362   using has_size_stdbasis[unfolded hassize_def]
  3363   ..
  3364 
  3365 lemma card_stdbasis: "card {basis i ::real^'n::finite |i. i\<in> (UNIV :: 'n set)} = CARD('n)"
  3366   using has_size_stdbasis[unfolded hassize_def]
  3367   ..
  3368 
  3369 lemma independent_stdbasis_lemma:
  3370   assumes x: "(x::'a::semiring_1 ^ 'n) \<in> span (basis ` S)"
  3371   and iS: "i \<notin> S"
  3372   shows "(x$i) = 0"
  3373 proof-
  3374   let ?U = "UNIV :: 'n set"
  3375   let ?B = "basis ` S"
  3376   let ?P = "\<lambda>(x::'a^'n). \<forall>i\<in> ?U. i \<notin> S \<longrightarrow> x$i =0"
  3377  {fix x::"'a^'n" assume xS: "x\<in> ?B"
  3378    from xS have "?P x" by auto}
  3379  moreover
  3380  have "subspace ?P"
  3381    by (auto simp add: subspace_def Collect_def mem_def)
  3382  ultimately show ?thesis
  3383    using x span_induct[of ?B ?P x] iS by blast
  3384 qed
  3385 
  3386 lemma independent_stdbasis: "independent {basis i ::real^'n::finite |i. i\<in> (UNIV :: 'n set)}"
  3387 proof-
  3388   let ?I = "UNIV :: 'n set"
  3389   let ?b = "basis :: _ \<Rightarrow> real ^'n"
  3390   let ?B = "?b ` ?I"
  3391   have eq: "{?b i|i. i \<in> ?I} = ?B"
  3392     by auto
  3393   {assume d: "dependent ?B"
  3394     then obtain k where k: "k \<in> ?I" "?b k \<in> span (?B - {?b k})"
  3395       unfolding dependent_def by auto
  3396     have eq1: "?B - {?b k} = ?B - ?b ` {k}"  by simp
  3397     have eq2: "?B - {?b k} = ?b ` (?I - {k})"
  3398       unfolding eq1
  3399       apply (rule inj_on_image_set_diff[symmetric])
  3400       apply (rule basis_inj) using k(1) by auto
  3401     from k(2) have th0: "?b k \<in> span (?b ` (?I - {k}))" unfolding eq2 .
  3402     from independent_stdbasis_lemma[OF th0, of k, simplified]
  3403     have False by simp}
  3404   then show ?thesis unfolding eq dependent_def ..
  3405 qed
  3406 
  3407 (* This is useful for building a basis step-by-step.                         *)
  3408 
  3409 lemma independent_insert:
  3410   "independent(insert (a::'a::field ^'n) S) \<longleftrightarrow>
  3411       (if a \<in> S then independent S
  3412                 else independent S \<and> a \<notin> span S)" (is "?lhs \<longleftrightarrow> ?rhs")
  3413 proof-
  3414   {assume aS: "a \<in> S"
  3415     hence ?thesis using insert_absorb[OF aS] by simp}
  3416   moreover
  3417   {assume aS: "a \<notin> S"
  3418     {assume i: ?lhs
  3419       then have ?rhs using aS
  3420 	apply simp
  3421 	apply (rule conjI)
  3422 	apply (rule independent_mono)
  3423 	apply assumption
  3424 	apply blast
  3425 	by (simp add: dependent_def)}
  3426     moreover
  3427     {assume i: ?rhs
  3428       have ?lhs using i aS
  3429 	apply simp
  3430 	apply (auto simp add: dependent_def)
  3431 	apply (case_tac "aa = a", auto)
  3432 	apply (subgoal_tac "insert a S - {aa} = insert a (S - {aa})")
  3433 	apply simp
  3434 	apply (subgoal_tac "a \<in> span (insert aa (S - {aa}))")
  3435 	apply (subgoal_tac "insert aa (S - {aa}) = S")
  3436 	apply simp
  3437 	apply blast
  3438 	apply (rule in_span_insert)
  3439 	apply assumption
  3440 	apply blast
  3441 	apply blast
  3442 	done}
  3443     ultimately have ?thesis by blast}
  3444   ultimately show ?thesis by blast
  3445 qed
  3446 
  3447 (* The degenerate case of the Exchange Lemma.  *)
  3448 
  3449 lemma mem_delete: "x \<in> (A - {a}) \<longleftrightarrow> x \<noteq> a \<and> x \<in> A"
  3450   by blast
  3451 
  3452 lemma span_span: "span (span A) = span A"
  3453   unfolding span_def hull_hull ..
  3454 
  3455 lemma span_inc: "S \<subseteq> span S"
  3456   by (metis subset_eq span_superset)
  3457 
  3458 lemma spanning_subset_independent:
  3459   assumes BA: "B \<subseteq> A" and iA: "independent (A::('a::field ^'n) set)"
  3460   and AsB: "A \<subseteq> span B"
  3461   shows "A = B"
  3462 proof
  3463   from BA show "B \<subseteq> A" .
  3464 next
  3465   from span_mono[OF BA] span_mono[OF AsB]
  3466   have sAB: "span A = span B" unfolding span_span by blast
  3467 
  3468   {fix x assume x: "x \<in> A"
  3469     from iA have th0: "x \<notin> span (A - {x})"
  3470       unfolding dependent_def using x by blast
  3471     from x have xsA: "x \<in> span A" by (blast intro: span_superset)
  3472     have "A - {x} \<subseteq> A" by blast
  3473     hence th1:"span (A - {x}) \<subseteq> span A" by (metis span_mono)
  3474     {assume xB: "x \<notin> B"
  3475       from xB BA have "B \<subseteq> A -{x}" by blast
  3476       hence "span B \<subseteq> span (A - {x})" by (metis span_mono)
  3477       with th1 th0 sAB have "x \<notin> span A" by blast
  3478       with x have False by (metis span_superset)}
  3479     then have "x \<in> B" by blast}
  3480   then show "A \<subseteq> B" by blast
  3481 qed
  3482 
  3483 (* The general case of the Exchange Lemma, the key to what follows.  *)
  3484 
  3485 lemma exchange_lemma:
  3486   assumes f:"finite (t:: ('a::field^'n) set)" and i: "independent s"
  3487   and sp:"s \<subseteq> span t"
  3488   shows "\<exists>t'. (t' hassize card t) \<and> s \<subseteq> t' \<and> t' \<subseteq> s \<union> t \<and> s \<subseteq> span t'"
  3489 using f i sp
  3490 proof(induct c\<equiv>"card(t - s)" arbitrary: s t rule: nat_less_induct)
  3491   fix n:: nat and s t :: "('a ^'n) set"
  3492   assume H: " \<forall>m<n. \<forall>(x:: ('a ^'n) set) xa.
  3493                 finite xa \<longrightarrow>
  3494                 independent x \<longrightarrow>
  3495                 x \<subseteq> span xa \<longrightarrow>
  3496                 m = card (xa - x) \<longrightarrow>
  3497                 (\<exists>t'. (t' hassize card xa) \<and>
  3498                       x \<subseteq> t' \<and> t' \<subseteq> x \<union> xa \<and> x \<subseteq> span t')"
  3499     and ft: "finite t" and s: "independent s" and sp: "s \<subseteq> span t"
  3500     and n: "n = card (t - s)"
  3501   let ?P = "\<lambda>t'. (t' hassize card t) \<and> s \<subseteq> t' \<and> t' \<subseteq> s \<union> t \<and> s \<subseteq> span t'"
  3502   let ?ths = "\<exists>t'. ?P t'"
  3503   {assume st: "s \<subseteq> t"
  3504     from st ft span_mono[OF st] have ?ths apply - apply (rule exI[where x=t])
  3505       by (auto simp add: hassize_def intro: span_superset)}
  3506   moreover
  3507   {assume st: "t \<subseteq> s"
  3508 
  3509     from spanning_subset_independent[OF st s sp]
  3510       st ft span_mono[OF st] have ?ths apply - apply (rule exI[where x=t])
  3511       by (auto simp add: hassize_def intro: span_superset)}
  3512   moreover
  3513   {assume st: "\<not> s \<subseteq> t" "\<not> t \<subseteq> s"
  3514     from st(2) obtain b where b: "b \<in> t" "b \<notin> s" by blast
  3515       from b have "t - {b} - s \<subset> t - s" by blast
  3516       then have cardlt: "card (t - {b} - s) < n" using n ft
  3517  	by (auto intro: psubset_card_mono)
  3518       from b ft have ct0: "card t \<noteq> 0" by auto
  3519     {assume stb: "s \<subseteq> span(t -{b})"
  3520       from ft have ftb: "finite (t -{b})" by auto
  3521       from H[rule_format, OF cardlt ftb s stb]
  3522       obtain u where u: "u hassize card (t-{b})" "s \<subseteq> u" "u \<subseteq> s \<union> (t - {b})" "s \<subseteq> span u" by blast
  3523       let ?w = "insert b u"
  3524       have th0: "s \<subseteq> insert b u" using u by blast
  3525       from u(3) b have "u \<subseteq> s \<union> t" by blast
  3526       then have th1: "insert b u \<subseteq> s \<union> t" using u b by blast
  3527       have bu: "b \<notin> u" using b u by blast
  3528       from u(1) have fu: "finite u" by (simp add: hassize_def)
  3529       from u(1) ft b have "u hassize (card t - 1)" by auto
  3530       then
  3531       have th2: "insert b u hassize card t"
  3532 	using  card_insert_disjoint[OF fu bu] ct0 by (auto simp add: hassize_def)
  3533       from u(4) have "s \<subseteq> span u" .
  3534       also have "\<dots> \<subseteq> span (insert b u)" apply (rule span_mono) by blast
  3535       finally have th3: "s \<subseteq> span (insert b u)" .      from th0 th1 th2 th3 have th: "?P ?w"  by blast
  3536       from th have ?ths by blast}
  3537     moreover
  3538     {assume stb: "\<not> s \<subseteq> span(t -{b})"
  3539       from stb obtain a where a: "a \<in> s" "a \<notin> span (t - {b})" by blast
  3540       have ab: "a \<noteq> b" using a b by blast
  3541       have at: "a \<notin> t" using a ab span_superset[of a "t- {b}"] by auto
  3542       have mlt: "card ((insert a (t - {b})) - s) < n"
  3543 	using cardlt ft n  a b by auto
  3544       have ft': "finite (insert a (t - {b}))" using ft by auto
  3545       {fix x assume xs: "x \<in> s"
  3546 	have t: "t \<subseteq> (insert b (insert a (t -{b})))" using b by auto
  3547 	from b(1) have "b \<in> span t" by (simp add: span_superset)
  3548 	have bs: "b \<in> span (insert a (t - {b}))"
  3549 	  by (metis in_span_delete a sp mem_def subset_eq)
  3550 	from xs sp have "x \<in> span t" by blast
  3551 	with span_mono[OF t]
  3552 	have x: "x \<in> span (insert b (insert a (t - {b})))" ..
  3553 	from span_trans[OF bs x] have "x \<in> span (insert a (t - {b}))"  .}
  3554       then have sp': "s \<subseteq> span (insert a (t - {b}))" by blast
  3555 
  3556       from H[rule_format, OF mlt ft' s sp' refl] obtain u where
  3557 	u: "u hassize card (insert a (t -{b}))" "s \<subseteq> u" "u \<subseteq> s \<union> insert a (t -{b})"
  3558 	"s \<subseteq> span u" by blast
  3559       from u a b ft at ct0 have "?P u" by (auto simp add: hassize_def)
  3560       then have ?ths by blast }
  3561     ultimately have ?ths by blast
  3562   }
  3563   ultimately
  3564   show ?ths  by blast
  3565 qed
  3566 
  3567 (* This implies corresponding size bounds.                                   *)
  3568 
  3569 lemma independent_span_bound:
  3570   assumes f: "finite t" and i: "independent (s::('a::field^'n) set)" and sp:"s \<subseteq> span t"
  3571   shows "finite s \<and> card s \<le> card t"
  3572   by (metis exchange_lemma[OF f i sp] hassize_def finite_subset card_mono)
  3573 
  3574 lemma finite_Atleast_Atmost[simp]: "finite {f x |x. x\<in> {(i::'a::finite_intvl_succ) .. j}}"
  3575 proof-
  3576   have eq: "{f x |x. x\<in> {i .. j}} = f ` {i .. j}" by auto
  3577   show ?thesis unfolding eq
  3578     apply (rule finite_imageI)
  3579     apply (rule finite_intvl)
  3580     done
  3581 qed
  3582 
  3583 lemma finite_Atleast_Atmost_nat[simp]: "finite {f x |x. x\<in> (UNIV::'a::finite set)}"
  3584 proof-
  3585   have eq: "{f x |x. x\<in> UNIV} = f ` UNIV" by auto
  3586   show ?thesis unfolding eq
  3587     apply (rule finite_imageI)
  3588     apply (rule finite)
  3589     done
  3590 qed
  3591 
  3592 
  3593 lemma independent_bound:
  3594   fixes S:: "(real^'n::finite) set"
  3595   shows "independent S \<Longrightarrow> finite S \<and> card S <= CARD('n)"
  3596   apply (subst card_stdbasis[symmetric])
  3597   apply (rule independent_span_bound)
  3598   apply (rule finite_Atleast_Atmost_nat)
  3599   apply assumption
  3600   unfolding span_stdbasis
  3601   apply (rule subset_UNIV)
  3602   done
  3603 
  3604 lemma dependent_biggerset: "(finite (S::(real ^'n::finite) set) ==> card S > CARD('n)) ==> dependent S"
  3605   by (metis independent_bound not_less)
  3606 
  3607 (* Hence we can create a maximal independent subset.                         *)
  3608 
  3609 lemma maximal_independent_subset_extend:
  3610   assumes sv: "(S::(real^'n::finite) set) \<subseteq> V" and iS: "independent S"
  3611   shows "\<exists>B. S \<subseteq> B \<and> B \<subseteq> V \<and> independent B \<and> V \<subseteq> span B"
  3612   using sv iS
  3613 proof(induct d\<equiv> "CARD('n) - card S" arbitrary: S rule: nat_less_induct)
  3614   fix n and S:: "(real^'n) set"
  3615   assume H: "\<forall>m<n. \<forall>S \<subseteq> V. independent S \<longrightarrow> m = CARD('n) - card S \<longrightarrow>
  3616               (\<exists>B. S \<subseteq> B \<and> B \<subseteq> V \<and> independent B \<and> V \<subseteq> span B)"
  3617     and sv: "S \<subseteq> V" and i: "independent S" and n: "n = CARD('n) - card S"
  3618   let ?P = "\<lambda>B. S \<subseteq> B \<and> B \<subseteq> V \<and> independent B \<and> V \<subseteq> span B"
  3619   let ?ths = "\<exists>x. ?P x"
  3620   let ?d = "CARD('n)"
  3621   {assume "V \<subseteq> span S"
  3622     then have ?ths  using sv i by blast }
  3623   moreover
  3624   {assume VS: "\<not> V \<subseteq> span S"
  3625     from VS obtain a where a: "a \<in> V" "a \<notin> span S" by blast
  3626     from a have aS: "a \<notin> S" by (auto simp add: span_superset)
  3627     have th0: "insert a S \<subseteq> V" using a sv by blast
  3628     from independent_insert[of a S]  i a
  3629     have th1: "independent (insert a S)" by auto
  3630     have mlt: "?d - card (insert a S) < n"
  3631       using aS a n independent_bound[OF th1]
  3632       by auto
  3633 
  3634     from H[rule_format, OF mlt th0 th1 refl]
  3635     obtain B where B: "insert a S \<subseteq> B" "B \<subseteq> V" "independent B" " V \<subseteq> span B"
  3636       by blast
  3637     from B have "?P B" by auto
  3638     then have ?ths by blast}
  3639   ultimately show ?ths by blast
  3640 qed
  3641 
  3642 lemma maximal_independent_subset:
  3643   "\<exists>(B:: (real ^'n::finite) set). B\<subseteq> V \<and> independent B \<and> V \<subseteq> span B"
  3644   by (metis maximal_independent_subset_extend[of "{}:: (real ^'n) set"] empty_subsetI independent_empty)
  3645 
  3646 (* Notion of dimension.                                                      *)
  3647 
  3648 definition "dim V = (SOME n. \<exists>B. B \<subseteq> V \<and> independent B \<and> V \<subseteq> span B \<and> (B hassize n))"
  3649 
  3650 lemma basis_exists:  "\<exists>B. (B :: (real ^'n::finite) set) \<subseteq> V \<and> independent B \<and> V \<subseteq> span B \<and> (B hassize dim V)"
  3651 unfolding dim_def some_eq_ex[of "\<lambda>n. \<exists>B. B \<subseteq> V \<and> independent B \<and> V \<subseteq> span B \<and> (B hassize n)"]
  3652 unfolding hassize_def
  3653 using maximal_independent_subset[of V] independent_bound
  3654 by auto
  3655 
  3656 (* Consequences of independence or spanning for cardinality.                 *)
  3657 
  3658 lemma independent_card_le_dim: "(B::(real ^'n::finite) set) \<subseteq> V \<Longrightarrow> independent B \<Longrightarrow> finite B \<and> card B \<le> dim V"
  3659 by (metis basis_exists[of V] independent_span_bound[where ?'a=real] hassize_def subset_trans)
  3660 
  3661 lemma span_card_ge_dim:  "(B::(real ^'n::finite) set) \<subseteq> V \<Longrightarrow> V \<subseteq> span B \<Longrightarrow> finite B \<Longrightarrow> dim V \<le> card B"
  3662   by (metis basis_exists[of V] independent_span_bound hassize_def subset_trans)
  3663 
  3664 lemma basis_card_eq_dim:
  3665   "B \<subseteq> (V:: (real ^'n::finite) set) \<Longrightarrow> V \<subseteq> span B \<Longrightarrow> independent B \<Longrightarrow> finite B \<and> card B = dim V"
  3666   by (metis order_eq_iff independent_card_le_dim span_card_ge_dim independent_mono)
  3667 
  3668 lemma dim_unique: "(B::(real ^'n::finite) set) \<subseteq> V \<Longrightarrow> V \<subseteq> span B \<Longrightarrow> independent B \<Longrightarrow> B hassize n \<Longrightarrow> dim V = n"
  3669   by (metis basis_card_eq_dim hassize_def)
  3670 
  3671 (* More lemmas about dimension.                                              *)
  3672 
  3673 lemma dim_univ: "dim (UNIV :: (real^'n::finite) set) = CARD('n)"
  3674   apply (rule dim_unique[of "{basis i |i. i\<in> (UNIV :: 'n set)}"])
  3675   by (auto simp only: span_stdbasis has_size_stdbasis independent_stdbasis)
  3676 
  3677 lemma dim_subset:
  3678   "(S:: (real ^'n::finite) set) \<subseteq> T \<Longrightarrow> dim S \<le> dim T"
  3679   using basis_exists[of T] basis_exists[of S]
  3680   by (metis independent_span_bound[where ?'a = real and ?'n = 'n] subset_eq hassize_def)
  3681 
  3682 lemma dim_subset_univ: "dim (S:: (real^'n::finite) set) \<le> CARD('n)"
  3683   by (metis dim_subset subset_UNIV dim_univ)
  3684 
  3685 (* Converses to those.                                                       *)
  3686 
  3687 lemma card_ge_dim_independent:
  3688   assumes BV:"(B::(real ^'n::finite) set) \<subseteq> V" and iB:"independent B" and dVB:"dim V \<le> card B"
  3689   shows "V \<subseteq> span B"
  3690 proof-
  3691   {fix a assume aV: "a \<in> V"
  3692     {assume aB: "a \<notin> span B"
  3693       then have iaB: "independent (insert a B)" using iB aV  BV by (simp add: independent_insert)
  3694       from aV BV have th0: "insert a B \<subseteq> V" by blast
  3695       from aB have "a \<notin>B" by (auto simp add: span_superset)
  3696       with independent_card_le_dim[OF th0 iaB] dVB  have False by auto}
  3697     then have "a \<in> span B"  by blast}
  3698   then show ?thesis by blast
  3699 qed
  3700 
  3701 lemma card_le_dim_spanning:
  3702   assumes BV: "(B:: (real ^'n::finite) set) \<subseteq> V" and VB: "V \<subseteq> span B"
  3703   and fB: "finite B" and dVB: "dim V \<ge> card B"
  3704   shows "independent B"
  3705 proof-
  3706   {fix a assume a: "a \<in> B" "a \<in> span (B -{a})"
  3707     from a fB have c0: "card B \<noteq> 0" by auto
  3708     from a fB have cb: "card (B -{a}) = card B - 1" by auto
  3709     from BV a have th0: "B -{a} \<subseteq> V" by blast
  3710     {fix x assume x: "x \<in> V"
  3711       from a have eq: "insert a (B -{a}) = B" by blast
  3712       from x VB have x': "x \<in> span B" by blast
  3713       from span_trans[OF a(2), unfolded eq, OF x']
  3714       have "x \<in> span (B -{a})" . }
  3715     then have th1: "V \<subseteq> span (B -{a})" by blast
  3716     have th2: "finite (B -{a})" using fB by auto
  3717     from span_card_ge_dim[OF th0 th1 th2]
  3718     have c: "dim V \<le> card (B -{a})" .
  3719     from c c0 dVB cb have False by simp}
  3720   then show ?thesis unfolding dependent_def by blast
  3721 qed
  3722 
  3723 lemma card_eq_dim: "(B:: (real ^'n::finite) set) \<subseteq> V \<Longrightarrow> B hassize dim V \<Longrightarrow> independent B \<longleftrightarrow> V \<subseteq> span B"
  3724   by (metis hassize_def order_eq_iff card_le_dim_spanning
  3725     card_ge_dim_independent)
  3726 
  3727 (* ------------------------------------------------------------------------- *)
  3728 (* More general size bound lemmas.                                           *)
  3729 (* ------------------------------------------------------------------------- *)
  3730 
  3731 lemma independent_bound_general:
  3732   "independent (S:: (real^'n::finite) set) \<Longrightarrow> finite S \<and> card S \<le> dim S"
  3733   by (metis independent_card_le_dim independent_bound subset_refl)
  3734 
  3735 lemma dependent_biggerset_general: "(finite (S:: (real^'n::finite) set) \<Longrightarrow> card S > dim S) \<Longrightarrow> dependent S"
  3736   using independent_bound_general[of S] by (metis linorder_not_le)
  3737 
  3738 lemma dim_span: "dim (span (S:: (real ^'n::finite) set)) = dim S"
  3739 proof-
  3740   have th0: "dim S \<le> dim (span S)"
  3741     by (auto simp add: subset_eq intro: dim_subset span_superset)
  3742   from basis_exists[of S]
  3743   obtain B where B: "B \<subseteq> S" "independent B" "S \<subseteq> span B" "B hassize dim S" by blast
  3744   from B have fB: "finite B" "card B = dim S" unfolding hassize_def by blast+
  3745   have bSS: "B \<subseteq> span S" using B(1) by (metis subset_eq span_inc)
  3746   have sssB: "span S \<subseteq> span B" using span_mono[OF B(3)] by (simp add: span_span)
  3747   from span_card_ge_dim[OF bSS sssB fB(1)] th0 show ?thesis
  3748     using fB(2)  by arith
  3749 qed
  3750 
  3751 lemma subset_le_dim: "(S:: (real ^'n::finite) set) \<subseteq> span T \<Longrightarrow> dim S \<le> dim T"
  3752   by (metis dim_span dim_subset)
  3753 
  3754 lemma span_eq_dim: "span (S:: (real ^'n::finite) set) = span T ==> dim S = dim T"
  3755   by (metis dim_span)
  3756 
  3757 lemma spans_image:
  3758   assumes lf: "linear (f::'a::semiring_1^'n \<Rightarrow> _)" and VB: "V \<subseteq> span B"
  3759   shows "f ` V \<subseteq> span (f ` B)"
  3760   unfolding span_linear_image[OF lf]
  3761   by (metis VB image_mono)
  3762 
  3763 lemma dim_image_le:
  3764   fixes f :: "real^'n::finite \<Rightarrow> real^'m::finite"
  3765   assumes lf: "linear f" shows "dim (f ` S) \<le> dim (S:: (real ^'n::finite) set)"
  3766 proof-
  3767   from basis_exists[of S] obtain B where
  3768     B: "B \<subseteq> S" "independent B" "S \<subseteq> span B" "B hassize dim S" by blast
  3769   from B have fB: "finite B" "card B = dim S" unfolding hassize_def by blast+
  3770   have "dim (f ` S) \<le> card (f ` B)"
  3771     apply (rule span_card_ge_dim)
  3772     using lf B fB by (auto simp add: span_linear_image spans_image subset_image_iff)
  3773   also have "\<dots> \<le> dim S" using card_image_le[OF fB(1)] fB by simp
  3774   finally show ?thesis .
  3775 qed
  3776 
  3777 (* Relation between bases and injectivity/surjectivity of map.               *)
  3778 
  3779 lemma spanning_surjective_image:
  3780   assumes us: "UNIV \<subseteq> span (S:: ('a::semiring_1 ^'n) set)"
  3781   and lf: "linear f" and sf: "surj f"
  3782   shows "UNIV \<subseteq> span (f ` S)"
  3783 proof-
  3784   have "UNIV \<subseteq> f ` UNIV" using sf by (auto simp add: surj_def)
  3785   also have " \<dots> \<subseteq> span (f ` S)" using spans_image[OF lf us] .
  3786 finally show ?thesis .
  3787 qed
  3788 
  3789 lemma independent_injective_image:
  3790   assumes iS: "independent (S::('a::semiring_1^'n) set)" and lf: "linear f" and fi: "inj f"
  3791   shows "independent (f ` S)"
  3792 proof-
  3793   {fix a assume a: "a \<in> S" "f a \<in> span (f ` S - {f a})"
  3794     have eq: "f ` S - {f a} = f ` (S - {a})" using fi
  3795       by (auto simp add: inj_on_def)
  3796     from a have "f a \<in> f ` span (S -{a})"
  3797       unfolding eq span_linear_image[OF lf, of "S - {a}"]  by blast
  3798     hence "a \<in> span (S -{a})" using fi by (auto simp add: inj_on_def)
  3799     with a(1) iS  have False by (simp add: dependent_def) }
  3800   then show ?thesis unfolding dependent_def by blast
  3801 qed
  3802 
  3803 (* ------------------------------------------------------------------------- *)
  3804 (* Picking an orthogonal replacement for a spanning set.                     *)
  3805 (* ------------------------------------------------------------------------- *)
  3806     (* FIXME : Move to some general theory ?*)
  3807 definition "pairwise R S \<longleftrightarrow> (\<forall>x \<in> S. \<forall>y\<in> S. x\<noteq>y \<longrightarrow> R x y)"
  3808 
  3809 lemma vector_sub_project_orthogonal: "(b::'a::ordered_field^'n::finite) \<bullet> (x - ((b \<bullet> x) / (b\<bullet>b)) *s b) = 0"
  3810   apply (cases "b = 0", simp)
  3811   apply (simp add: dot_rsub dot_rmult)
  3812   unfolding times_divide_eq_right[symmetric]
  3813   by (simp add: field_simps dot_eq_0)
  3814 
  3815 lemma basis_orthogonal:
  3816   fixes B :: "(real ^'n::finite) set"
  3817   assumes fB: "finite B"
  3818   shows "\<exists>C. finite C \<and> card C \<le> card B \<and> span C = span B \<and> pairwise orthogonal C"
  3819   (is " \<exists>C. ?P B C")
  3820 proof(induct rule: finite_induct[OF fB])
  3821   case 1 thus ?case apply (rule exI[where x="{}"]) by (auto simp add: pairwise_def)
  3822 next
  3823   case (2 a B)
  3824   note fB = `finite B` and aB = `a \<notin> B`
  3825   from `\<exists>C. finite C \<and> card C \<le> card B \<and> span C = span B \<and> pairwise orthogonal C`
  3826   obtain C where C: "finite C" "card C \<le> card B"
  3827     "span C = span B" "pairwise orthogonal C" by blast
  3828   let ?a = "a - setsum (\<lambda>x. (x\<bullet>a / (x\<bullet>x)) *s x) C"
  3829   let ?C = "insert ?a C"
  3830   from C(1) have fC: "finite ?C" by simp
  3831   from fB aB C(1,2) have cC: "card ?C \<le> card (insert a B)" by (simp add: card_insert_if)
  3832   {fix x k
  3833     have th0: "\<And>(a::'b::comm_ring) b c. a - (b - c) = c + (a - b)" by (simp add: ring_simps)
  3834     have "x - k *s (a - (\<Sum>x\<in>C. (x \<bullet> a / (x \<bullet> x)) *s x)) \<in> span C \<longleftrightarrow> x - k *s a \<in> span C"
  3835       apply (simp only: vector_ssub_ldistrib th0)
  3836       apply (rule span_add_eq)
  3837       apply (rule span_mul)
  3838       apply (rule span_setsum[OF C(1)])
  3839       apply clarify
  3840       apply (rule span_mul)
  3841       by (rule span_superset)}
  3842   then have SC: "span ?C = span (insert a B)"
  3843     unfolding expand_set_eq span_breakdown_eq C(3)[symmetric] by auto
  3844   thm pairwise_def
  3845   {fix x y assume xC: "x \<in> ?C" and yC: "y \<in> ?C" and xy: "x \<noteq> y"
  3846     {assume xa: "x = ?a" and ya: "y = ?a"
  3847       have "orthogonal x y" using xa ya xy by blast}
  3848     moreover
  3849     {assume xa: "x = ?a" and ya: "y \<noteq> ?a" "y \<in> C"
  3850       from ya have Cy: "C = insert y (C - {y})" by blast
  3851       have fth: "finite (C - {y})" using C by simp
  3852       have "orthogonal x y"
  3853 	using xa ya
  3854 	unfolding orthogonal_def xa dot_lsub dot_rsub diff_eq_0_iff_eq
  3855 	apply simp
  3856 	apply (subst Cy)
  3857 	using C(1) fth
  3858 	apply (simp only: setsum_clauses)
  3859 	thm dot_ladd
  3860 	apply (auto simp add: dot_ladd dot_radd dot_lmult dot_rmult dot_eq_0 dot_sym[of y a] dot_lsum[OF fth])
  3861 	apply (rule setsum_0')
  3862 	apply clarsimp
  3863 	apply (rule C(4)[unfolded pairwise_def orthogonal_def, rule_format])
  3864 	by auto}
  3865     moreover
  3866     {assume xa: "x \<noteq> ?a" "x \<in> C" and ya: "y = ?a"
  3867       from xa have Cx: "C = insert x (C - {x})" by blast
  3868       have fth: "finite (C - {x})" using C by simp
  3869       have "orthogonal x y"
  3870 	using xa ya
  3871 	unfolding orthogonal_def ya dot_rsub dot_lsub diff_eq_0_iff_eq
  3872 	apply simp
  3873 	apply (subst Cx)
  3874 	using C(1) fth
  3875 	apply (simp only: setsum_clauses)
  3876 	apply (subst dot_sym[of x])
  3877 	apply (auto simp add: dot_radd dot_rmult dot_eq_0 dot_sym[of x a] dot_rsum[OF fth])
  3878 	apply (rule setsum_0')
  3879 	apply clarsimp
  3880 	apply (rule C(4)[unfolded pairwise_def orthogonal_def, rule_format])
  3881 	by auto}
  3882     moreover
  3883     {assume xa: "x \<in> C" and ya: "y \<in> C"
  3884       have "orthogonal x y" using xa ya xy C(4) unfolding pairwise_def by blast}
  3885     ultimately have "orthogonal x y" using xC yC by blast}
  3886   then have CPO: "pairwise orthogonal ?C" unfolding pairwise_def by blast
  3887   from fC cC SC CPO have "?P (insert a B) ?C" by blast
  3888   then show ?case by blast
  3889 qed
  3890 
  3891 lemma orthogonal_basis_exists:
  3892   fixes V :: "(real ^'n::finite) set"
  3893   shows "\<exists>B. independent B \<and> B \<subseteq> span V \<and> V \<subseteq> span B \<and> (B hassize dim V) \<and> pairwise orthogonal B"
  3894 proof-
  3895   from basis_exists[of V] obtain B where B: "B \<subseteq> V" "independent B" "V \<subseteq> span B" "B hassize dim V" by blast
  3896   from B have fB: "finite B" "card B = dim V" by (simp_all add: hassize_def)
  3897   from basis_orthogonal[OF fB(1)] obtain C where
  3898     C: "finite C" "card C \<le> card B" "span C = span B" "pairwise orthogonal C" by blast
  3899   from C B
  3900   have CSV: "C \<subseteq> span V" by (metis span_inc span_mono subset_trans)
  3901   from span_mono[OF B(3)]  C have SVC: "span V \<subseteq> span C" by (simp add: span_span)
  3902   from card_le_dim_spanning[OF CSV SVC C(1)] C(2,3) fB
  3903   have iC: "independent C" by (simp add: dim_span)
  3904   from C fB have "card C \<le> dim V" by simp
  3905   moreover have "dim V \<le> card C" using span_card_ge_dim[OF CSV SVC C(1)]
  3906     by (simp add: dim_span)
  3907   ultimately have CdV: "C hassize dim V" unfolding hassize_def using C(1) by simp
  3908   from C B CSV CdV iC show ?thesis by auto
  3909 qed
  3910 
  3911 lemma span_eq: "span S = span T \<longleftrightarrow> S \<subseteq> span T \<and> T \<subseteq> span S"
  3912   by (metis set_eq_subset span_mono span_span span_inc)
  3913 
  3914 (* ------------------------------------------------------------------------- *)
  3915 (* Low-dimensional subset is in a hyperplane (weak orthogonal complement).   *)
  3916 (* ------------------------------------------------------------------------- *)
  3917 
  3918 lemma span_not_univ_orthogonal:
  3919   assumes sU: "span S \<noteq> UNIV"
  3920   shows "\<exists>(a:: real ^'n::finite). a \<noteq>0 \<and> (\<forall>x \<in> span S. a \<bullet> x = 0)"
  3921 proof-
  3922   from sU obtain a where a: "a \<notin> span S" by blast
  3923   from orthogonal_basis_exists obtain B where
  3924     B: "independent B" "B \<subseteq> span S" "S \<subseteq> span B" "B hassize dim S" "pairwise orthogonal B"
  3925     by blast
  3926   from B have fB: "finite B" "card B = dim S" by (simp_all add: hassize_def)
  3927   from span_mono[OF B(2)] span_mono[OF B(3)]
  3928   have sSB: "span S = span B" by (simp add: span_span)
  3929   let ?a = "a - setsum (\<lambda>b. (a\<bullet>b / (b\<bullet>b)) *s b) B"
  3930   have "setsum (\<lambda>b. (a\<bullet>b / (b\<bullet>b)) *s b) B \<in> span S"
  3931     unfolding sSB
  3932     apply (rule span_setsum[OF fB(1)])
  3933     apply clarsimp
  3934     apply (rule span_mul)
  3935     by (rule span_superset)
  3936   with a have a0:"?a  \<noteq> 0" by auto
  3937   have "\<forall>x\<in>span B. ?a \<bullet> x = 0"
  3938   proof(rule span_induct')
  3939     show "subspace (\<lambda>x. ?a \<bullet> x = 0)"
  3940       by (auto simp add: subspace_def mem_def dot_radd dot_rmult)
  3941   next
  3942     {fix x assume x: "x \<in> B"
  3943       from x have B': "B = insert x (B - {x})" by blast
  3944       have fth: "finite (B - {x})" using fB by simp
  3945       have "?a \<bullet> x = 0"
  3946 	apply (subst B') using fB fth
  3947 	unfolding setsum_clauses(2)[OF fth]
  3948 	apply simp
  3949 	apply (clarsimp simp add: dot_lsub dot_ladd dot_lmult dot_lsum dot_eq_0)
  3950 	apply (rule setsum_0', rule ballI)
  3951 	unfolding dot_sym
  3952 	by (auto simp add: x field_simps dot_eq_0 intro: B(5)[unfolded pairwise_def orthogonal_def, rule_format])}
  3953     then show "\<forall>x \<in> B. ?a \<bullet> x = 0" by blast
  3954   qed
  3955   with a0 show ?thesis unfolding sSB by (auto intro: exI[where x="?a"])
  3956 qed
  3957 
  3958 lemma span_not_univ_subset_hyperplane:
  3959   assumes SU: "span S \<noteq> (UNIV ::(real^'n::finite) set)"
  3960   shows "\<exists> a. a \<noteq>0 \<and> span S \<subseteq> {x. a \<bullet> x = 0}"
  3961   using span_not_univ_orthogonal[OF SU] by auto
  3962 
  3963 lemma lowdim_subset_hyperplane:
  3964   assumes d: "dim S < CARD('n::finite)"
  3965   shows "\<exists>(a::real ^'n::finite). a  \<noteq> 0 \<and> span S \<subseteq> {x. a \<bullet> x = 0}"
  3966 proof-
  3967   {assume "span S = UNIV"
  3968     hence "dim (span S) = dim (UNIV :: (real ^'n) set)" by simp
  3969     hence "dim S = CARD('n)" by (simp add: dim_span dim_univ)
  3970     with d have False by arith}
  3971   hence th: "span S \<noteq> UNIV" by blast
  3972   from span_not_univ_subset_hyperplane[OF th] show ?thesis .
  3973 qed
  3974 
  3975 (* We can extend a linear basis-basis injection to the whole set.            *)
  3976 
  3977 lemma linear_indep_image_lemma:
  3978   assumes lf: "linear f" and fB: "finite B"
  3979   and ifB: "independent (f ` B)"
  3980   and fi: "inj_on f B" and xsB: "x \<in> span B"
  3981   and fx: "f (x::'a::field^'n) = 0"
  3982   shows "x = 0"
  3983   using fB ifB fi xsB fx
  3984 proof(induct arbitrary: x rule: finite_induct[OF fB])
  3985   case 1 thus ?case by (auto simp add:  span_empty)
  3986 next
  3987   case (2 a b x)
  3988   have fb: "finite b" using "2.prems" by simp
  3989   have th0: "f ` b \<subseteq> f ` (insert a b)"
  3990     apply (rule image_mono) by blast
  3991   from independent_mono[ OF "2.prems"(2) th0]
  3992   have ifb: "independent (f ` b)"  .
  3993   have fib: "inj_on f b"
  3994     apply (rule subset_inj_on [OF "2.prems"(3)])
  3995     by blast
  3996   from span_breakdown[of a "insert a b", simplified, OF "2.prems"(4)]
  3997   obtain k where k: "x - k*s a \<in> span (b -{a})" by blast
  3998   have "f (x - k*s a) \<in> span (f ` b)"
  3999     unfolding span_linear_image[OF lf]
  4000     apply (rule imageI)
  4001     using k span_mono[of "b-{a}" b] by blast
  4002   hence "f x - k*s f a \<in> span (f ` b)"
  4003     by (simp add: linear_sub[OF lf] linear_cmul[OF lf])
  4004   hence th: "-k *s f a \<in> span (f ` b)"
  4005     using "2.prems"(5) by (simp add: vector_smult_lneg)
  4006   {assume k0: "k = 0"
  4007     from k0 k have "x \<in> span (b -{a})" by simp
  4008     then have "x \<in> span b" using span_mono[of "b-{a}" b]
  4009       by blast}
  4010   moreover
  4011   {assume k0: "k \<noteq> 0"
  4012     from span_mul[OF th, of "- 1/ k"] k0
  4013     have th1: "f a \<in> span (f ` b)"
  4014       by (auto simp add: vector_smult_assoc)
  4015     from inj_on_image_set_diff[OF "2.prems"(3), of "insert a b " "{a}", symmetric]
  4016     have tha: "f ` insert a b - f ` {a} = f ` (insert a b - {a})" by blast
  4017     from "2.prems"(2)[unfolded dependent_def bex_simps(10), rule_format, of "f a"]
  4018     have "f a \<notin> span (f ` b)" using tha
  4019       using "2.hyps"(2)
  4020       "2.prems"(3) by auto
  4021     with th1 have False by blast
  4022     then have "x \<in> span b" by blast}
  4023   ultimately have xsb: "x \<in> span b" by blast
  4024   from "2.hyps"(3)[OF fb ifb fib xsb "2.prems"(5)]
  4025   show "x = 0" .
  4026 qed
  4027 
  4028 (* We can extend a linear mapping from basis.                                *)
  4029 
  4030 lemma linear_independent_extend_lemma:
  4031   assumes fi: "finite B" and ib: "independent B"
  4032   shows "\<exists>g. (\<forall>x\<in> span B. \<forall>y\<in> span B. g ((x::'a::field^'n) + y) = g x + g y)
  4033            \<and> (\<forall>x\<in> span B. \<forall>c. g (c*s x) = c *s g x)
  4034            \<and> (\<forall>x\<in> B. g x = f x)"
  4035 using ib fi
  4036 proof(induct rule: finite_induct[OF fi])
  4037   case 1 thus ?case by (auto simp add: span_empty)
  4038 next
  4039   case (2 a b)
  4040   from "2.prems" "2.hyps" have ibf: "independent b" "finite b"
  4041     by (simp_all add: independent_insert)
  4042   from "2.hyps"(3)[OF ibf] obtain g where
  4043     g: "\<forall>x\<in>span b. \<forall>y\<in>span b. g (x + y) = g x + g y"
  4044     "\<forall>x\<in>span b. \<forall>c. g (c *s x) = c *s g x" "\<forall>x\<in>b. g x = f x" by blast
  4045   let ?h = "\<lambda>z. SOME k. (z - k *s a) \<in> span b"
  4046   {fix z assume z: "z \<in> span (insert a b)"
  4047     have th0: "z - ?h z *s a \<in> span b"
  4048       apply (rule someI_ex)
  4049       unfolding span_breakdown_eq[symmetric]
  4050       using z .
  4051     {fix k assume k: "z - k *s a \<in> span b"
  4052       have eq: "z - ?h z *s a - (z - k*s a) = (k - ?h z) *s a"
  4053 	by (simp add: ring_simps vector_sadd_rdistrib[symmetric])
  4054       from span_sub[OF th0 k]
  4055       have khz: "(k - ?h z) *s a \<in> span b" by (simp add: eq)
  4056       {assume "k \<noteq> ?h z" hence k0: "k - ?h z \<noteq> 0" by simp
  4057 	from k0 span_mul[OF khz, of "1 /(k - ?h z)"]
  4058 	have "a \<in> span b" by (simp add: vector_smult_assoc)
  4059 	with "2.prems"(1) "2.hyps"(2) have False
  4060 	  by (auto simp add: dependent_def)}
  4061       then have "k = ?h z" by blast}
  4062     with th0 have "z - ?h z *s a \<in> span b \<and> (\<forall>k. z - k *s a \<in> span b \<longrightarrow> k = ?h z)" by blast}
  4063   note h = this
  4064   let ?g = "\<lambda>z. ?h z *s f a + g (z - ?h z *s a)"
  4065   {fix x y assume x: "x \<in> span (insert a b)" and y: "y \<in> span (insert a b)"
  4066     have tha: "\<And>(x::'a^'n) y a k l. (x + y) - (k + l) *s a = (x - k *s a) + (y - l *s a)"
  4067       by (vector ring_simps)
  4068     have addh: "?h (x + y) = ?h x + ?h y"
  4069       apply (rule conjunct2[OF h, rule_format, symmetric])
  4070       apply (rule span_add[OF x y])
  4071       unfolding tha
  4072       by (metis span_add x y conjunct1[OF h, rule_format])
  4073     have "?g (x + y) = ?g x + ?g y"
  4074       unfolding addh tha
  4075       g(1)[rule_format,OF conjunct1[OF h, OF x] conjunct1[OF h, OF y]]
  4076       by (simp add: vector_sadd_rdistrib)}
  4077   moreover
  4078   {fix x:: "'a^'n" and c:: 'a  assume x: "x \<in> span (insert a b)"
  4079     have tha: "\<And>(x::'a^'n) c k a. c *s x - (c * k) *s a = c *s (x - k *s a)"
  4080       by (vector ring_simps)
  4081     have hc: "?h (c *s x) = c * ?h x"
  4082       apply (rule conjunct2[OF h, rule_format, symmetric])
  4083       apply (metis span_mul x)
  4084       by (metis tha span_mul x conjunct1[OF h])
  4085     have "?g (c *s x) = c*s ?g x"
  4086       unfolding hc tha g(2)[rule_format, OF conjunct1[OF h, OF x]]
  4087       by (vector ring_simps)}
  4088   moreover
  4089   {fix x assume x: "x \<in> (insert a b)"
  4090     {assume xa: "x = a"
  4091       have ha1: "1 = ?h a"
  4092 	apply (rule conjunct2[OF h, rule_format])
  4093 	apply (metis span_superset insertI1)
  4094 	using conjunct1[OF h, OF span_superset, OF insertI1]
  4095 	by (auto simp add: span_0)
  4096 
  4097       from xa ha1[symmetric] have "?g x = f x"
  4098 	apply simp
  4099 	using g(2)[rule_format, OF span_0, of 0]
  4100 	by simp}
  4101     moreover
  4102     {assume xb: "x \<in> b"
  4103       have h0: "0 = ?h x"
  4104 	apply (rule conjunct2[OF h, rule_format])
  4105 	apply (metis  span_superset insertI1 xb x)
  4106 	apply simp
  4107 	apply (metis span_superset xb)
  4108 	done
  4109       have "?g x = f x"
  4110 	by (simp add: h0[symmetric] g(3)[rule_format, OF xb])}
  4111     ultimately have "?g x = f x" using x by blast }
  4112   ultimately show ?case apply - apply (rule exI[where x="?g"]) by blast
  4113 qed
  4114 
  4115 lemma linear_independent_extend:
  4116   assumes iB: "independent (B:: (real ^'n::finite) set)"
  4117   shows "\<exists>g. linear g \<and> (\<forall>x\<in>B. g x = f x)"
  4118 proof-
  4119   from maximal_independent_subset_extend[of B UNIV] iB
  4120   obtain C where C: "B \<subseteq> C" "independent C" "\<And>x. x \<in> span C" by auto
  4121 
  4122   from C(2) independent_bound[of C] linear_independent_extend_lemma[of C f]
  4123   obtain g where g: "(\<forall>x\<in> span C. \<forall>y\<in> span C. g (x + y) = g x + g y)
  4124            \<and> (\<forall>x\<in> span C. \<forall>c. g (c*s x) = c *s g x)
  4125            \<and> (\<forall>x\<in> C. g x = f x)" by blast
  4126   from g show ?thesis unfolding linear_def using C
  4127     apply clarsimp by blast
  4128 qed
  4129 
  4130 (* Can construct an isomorphism between spaces of same dimension.            *)
  4131 
  4132 lemma card_le_inj: assumes fA: "finite A" and fB: "finite B"
  4133   and c: "card A \<le> card B" shows "(\<exists>f. f ` A \<subseteq> B \<and> inj_on f A)"
  4134 using fB c
  4135 proof(induct arbitrary: B rule: finite_induct[OF fA])
  4136   case 1 thus ?case by simp
  4137 next
  4138   case (2 x s t)
  4139   thus ?case
  4140   proof(induct rule: finite_induct[OF "2.prems"(1)])
  4141     case 1    then show ?case by simp
  4142   next
  4143     case (2 y t)
  4144     from "2.prems"(1,2,5) "2.hyps"(1,2) have cst:"card s \<le> card t" by simp
  4145     from "2.prems"(3) [OF "2.hyps"(1) cst] obtain f where
  4146       f: "f ` s \<subseteq> t \<and> inj_on f s" by blast
  4147     from f "2.prems"(2) "2.hyps"(2) show ?case
  4148       apply -
  4149       apply (rule exI[where x = "\<lambda>z. if z = x then y else f z"])
  4150       by (auto simp add: inj_on_def)
  4151   qed
  4152 qed
  4153 
  4154 lemma card_subset_eq: assumes fB: "finite B" and AB: "A \<subseteq> B" and
  4155   c: "card A = card B"
  4156   shows "A = B"
  4157 proof-
  4158   from fB AB have fA: "finite A" by (auto intro: finite_subset)
  4159   from fA fB have fBA: "finite (B - A)" by auto
  4160   have e: "A \<inter> (B - A) = {}" by blast
  4161   have eq: "A \<union> (B - A) = B" using AB by blast
  4162   from card_Un_disjoint[OF fA fBA e, unfolded eq c]
  4163   have "card (B - A) = 0" by arith
  4164   hence "B - A = {}" unfolding card_eq_0_iff using fA fB by simp
  4165   with AB show "A = B" by blast
  4166 qed
  4167 
  4168 lemma subspace_isomorphism:
  4169   assumes s: "subspace (S:: (real ^'n::finite) set)"
  4170   and t: "subspace (T :: (real ^ 'm::finite) set)"
  4171   and d: "dim S = dim T"
  4172   shows "\<exists>f. linear f \<and> f ` S = T \<and> inj_on f S"
  4173 proof-
  4174   from basis_exists[of S] obtain B where
  4175     B: "B \<subseteq> S" "independent B" "S \<subseteq> span B" "B hassize dim S" by blast
  4176   from basis_exists[of T] obtain C where
  4177     C: "C \<subseteq> T" "independent C" "T \<subseteq> span C" "C hassize dim T" by blast
  4178   from B(4) C(4) card_le_inj[of B C] d obtain f where
  4179     f: "f ` B \<subseteq> C" "inj_on f B" unfolding hassize_def by auto
  4180   from linear_independent_extend[OF B(2)] obtain g where
  4181     g: "linear g" "\<forall>x\<in> B. g x = f x" by blast
  4182   from B(4) have fB: "finite B" by (simp add: hassize_def)
  4183   from C(4) have fC: "finite C" by (simp add: hassize_def)
  4184   from inj_on_iff_eq_card[OF fB, of f] f(2)
  4185   have "card (f ` B) = card B" by simp
  4186   with B(4) C(4) have ceq: "card (f ` B) = card C" using d
  4187     by (simp add: hassize_def)
  4188   have "g ` B = f ` B" using g(2)
  4189     by (auto simp add: image_iff)
  4190   also have "\<dots> = C" using card_subset_eq[OF fC f(1) ceq] .
  4191   finally have gBC: "g ` B = C" .
  4192   have gi: "inj_on g B" using f(2) g(2)
  4193     by (auto simp add: inj_on_def)
  4194   note g0 = linear_indep_image_lemma[OF g(1) fB, unfolded gBC, OF C(2) gi]
  4195   {fix x y assume x: "x \<in> S" and y: "y \<in> S" and gxy:"g x = g y"
  4196     from B(3) x y have x': "x \<in> span B" and y': "y \<in> span B" by blast+
  4197     from gxy have th0: "g (x - y) = 0" by (simp add: linear_sub[OF g(1)])
  4198     have th1: "x - y \<in> span B" using x' y' by (metis span_sub)
  4199     have "x=y" using g0[OF th1 th0] by simp }
  4200   then have giS: "inj_on g S"
  4201     unfolding inj_on_def by blast
  4202   from span_subspace[OF B(1,3) s]
  4203   have "g ` S = span (g ` B)" by (simp add: span_linear_image[OF g(1)])
  4204   also have "\<dots> = span C" unfolding gBC ..
  4205   also have "\<dots> = T" using span_subspace[OF C(1,3) t] .
  4206   finally have gS: "g ` S = T" .
  4207   from g(1) gS giS show ?thesis by blast
  4208 qed
  4209 
  4210 (* linear functions are equal on a subspace if they are on a spanning set.   *)
  4211 
  4212 lemma subspace_kernel:
  4213   assumes lf: "linear (f::'a::semiring_1 ^'n \<Rightarrow> _)"
  4214   shows "subspace {x. f x = 0}"
  4215 apply (simp add: subspace_def)
  4216 by (simp add: linear_add[OF lf] linear_cmul[OF lf] linear_0[OF lf])
  4217 
  4218 lemma linear_eq_0_span:
  4219   assumes lf: "linear f" and f0: "\<forall>x\<in>B. f x = 0"
  4220   shows "\<forall>x \<in> span B. f x = (0::'a::semiring_1 ^'n)"
  4221 proof
  4222   fix x assume x: "x \<in> span B"
  4223   let ?P = "\<lambda>x. f x = 0"
  4224   from subspace_kernel[OF lf] have "subspace ?P" unfolding Collect_def .
  4225   with x f0 span_induct[of B "?P" x] show "f x = 0" by blast
  4226 qed
  4227 
  4228 lemma linear_eq_0:
  4229   assumes lf: "linear f" and SB: "S \<subseteq> span B" and f0: "\<forall>x\<in>B. f x = 0"
  4230   shows "\<forall>x \<in> S. f x = (0::'a::semiring_1^'n)"
  4231   by (metis linear_eq_0_span[OF lf] subset_eq SB f0)
  4232 
  4233 lemma linear_eq:
  4234   assumes lf: "linear (f::'a::ring_1^'n \<Rightarrow> _)" and lg: "linear g" and S: "S \<subseteq> span B"
  4235   and fg: "\<forall> x\<in> B. f x = g x"
  4236   shows "\<forall>x\<in> S. f x = g x"
  4237 proof-
  4238   let ?h = "\<lambda>x. f x - g x"
  4239   from fg have fg': "\<forall>x\<in> B. ?h x = 0" by simp
  4240   from linear_eq_0[OF linear_compose_sub[OF lf lg] S fg']
  4241   show ?thesis by simp
  4242 qed
  4243 
  4244 lemma linear_eq_stdbasis:
  4245   assumes lf: "linear (f::'a::ring_1^'m::finite \<Rightarrow> 'a^'n::finite)" and lg: "linear g"
  4246   and fg: "\<forall>i. f (basis i) = g(basis i)"
  4247   shows "f = g"
  4248 proof-
  4249   let ?U = "UNIV :: 'm set"
  4250   let ?I = "{basis i:: 'a^'m|i. i \<in> ?U}"
  4251   {fix x assume x: "x \<in> (UNIV :: ('a^'m) set)"
  4252     from equalityD2[OF span_stdbasis]
  4253     have IU: " (UNIV :: ('a^'m) set) \<subseteq> span ?I" by blast
  4254     from linear_eq[OF lf lg IU] fg x
  4255     have "f x = g x" unfolding Collect_def  Ball_def mem_def by metis}
  4256   then show ?thesis by (auto intro: ext)
  4257 qed
  4258 
  4259 (* Similar results for bilinear functions.                                   *)
  4260 
  4261 lemma bilinear_eq:
  4262   assumes bf: "bilinear (f:: 'a::ring^'m \<Rightarrow> 'a^'n \<Rightarrow> 'a^'p)"
  4263   and bg: "bilinear g"
  4264   and SB: "S \<subseteq> span B" and TC: "T \<subseteq> span C"
  4265   and fg: "\<forall>x\<in> B. \<forall>y\<in> C. f x y = g x y"
  4266   shows "\<forall>x\<in>S. \<forall>y\<in>T. f x y = g x y "
  4267 proof-
  4268   let ?P = "\<lambda>x. \<forall>y\<in> span C. f x y = g x y"
  4269   from bf bg have sp: "subspace ?P"
  4270     unfolding bilinear_def linear_def subspace_def bf bg
  4271     by(auto simp add: span_0 mem_def bilinear_lzero[OF bf] bilinear_lzero[OF bg] span_add Ball_def intro:  bilinear_ladd[OF bf])
  4272 
  4273   have "\<forall>x \<in> span B. \<forall>y\<in> span C. f x y = g x y"
  4274     apply -
  4275     apply (rule ballI)
  4276     apply (rule span_induct[of B ?P])
  4277     defer
  4278     apply (rule sp)
  4279     apply assumption
  4280     apply (clarsimp simp add: Ball_def)
  4281     apply (rule_tac P="\<lambda>y. f xa y = g xa y" and S=C in span_induct)
  4282     using fg
  4283     apply (auto simp add: subspace_def)
  4284     using bf bg unfolding bilinear_def linear_def
  4285     by(auto simp add: span_0 mem_def bilinear_rzero[OF bf] bilinear_rzero[OF bg] span_add Ball_def intro:  bilinear_ladd[OF bf])
  4286   then show ?thesis using SB TC by (auto intro: ext)
  4287 qed
  4288 
  4289 lemma bilinear_eq_stdbasis:
  4290   assumes bf: "bilinear (f:: 'a::ring_1^'m::finite \<Rightarrow> 'a^'n::finite \<Rightarrow> 'a^'p)"
  4291   and bg: "bilinear g"
  4292   and fg: "\<forall>i j. f (basis i) (basis j) = g (basis i) (basis j)"
  4293   shows "f = g"
  4294 proof-
  4295   from fg have th: "\<forall>x \<in> {basis i| i. i\<in> (UNIV :: 'm set)}. \<forall>y\<in>  {basis j |j. j \<in> (UNIV :: 'n set)}. f x y = g x y" by blast
  4296   from bilinear_eq[OF bf bg equalityD2[OF span_stdbasis] equalityD2[OF span_stdbasis] th] show ?thesis by (blast intro: ext)
  4297 qed
  4298 
  4299 (* Detailed theorems about left and right invertibility in general case.     *)
  4300 
  4301 lemma left_invertible_transp:
  4302   "(\<exists>(B::'a^'n^'m). B ** transp (A::'a^'n^'m) = mat (1::'a::comm_semiring_1)) \<longleftrightarrow> (\<exists>(B::'a^'m^'n). A ** B = mat 1)"
  4303   by (metis matrix_transp_mul transp_mat transp_transp)
  4304 
  4305 lemma right_invertible_transp:
  4306   "(\<exists>(B::'a^'n^'m). transp (A::'a^'n^'m) ** B = mat (1::'a::comm_semiring_1)) \<longleftrightarrow> (\<exists>(B::'a^'m^'n). B ** A = mat 1)"
  4307   by (metis matrix_transp_mul transp_mat transp_transp)
  4308 
  4309 lemma linear_injective_left_inverse:
  4310   assumes lf: "linear (f::real ^'n::finite \<Rightarrow> real ^'m::finite)" and fi: "inj f"
  4311   shows "\<exists>g. linear g \<and> g o f = id"
  4312 proof-
  4313   from linear_independent_extend[OF independent_injective_image, OF independent_stdbasis, OF lf fi]
  4314   obtain h:: "real ^'m \<Rightarrow> real ^'n" where h: "linear h" " \<forall>x \<in> f ` {basis i|i. i \<in> (UNIV::'n set)}. h x = inv f x" by blast
  4315   from h(2)
  4316   have th: "\<forall>i. (h \<circ> f) (basis i) = id (basis i)"
  4317     using inv_o_cancel[OF fi, unfolded stupid_ext[symmetric] id_def o_def]
  4318     by auto
  4319 
  4320   from linear_eq_stdbasis[OF linear_compose[OF lf h(1)] linear_id th]
  4321   have "h o f = id" .
  4322   then show ?thesis using h(1) by blast
  4323 qed
  4324 
  4325 lemma linear_surjective_right_inverse:
  4326   assumes lf: "linear (f:: real ^'m::finite \<Rightarrow> real ^'n::finite)" and sf: "surj f"
  4327   shows "\<exists>g. linear g \<and> f o g = id"
  4328 proof-
  4329   from linear_independent_extend[OF independent_stdbasis]
  4330   obtain h:: "real ^'n \<Rightarrow> real ^'m" where
  4331     h: "linear h" "\<forall> x\<in> {basis i| i. i\<in> (UNIV :: 'n set)}. h x = inv f x" by blast
  4332   from h(2)
  4333   have th: "\<forall>i. (f o h) (basis i) = id (basis i)"
  4334     using sf
  4335     apply (auto simp add: surj_iff o_def stupid_ext[symmetric])
  4336     apply (erule_tac x="basis i" in allE)
  4337     by auto
  4338 
  4339   from linear_eq_stdbasis[OF linear_compose[OF h(1) lf] linear_id th]
  4340   have "f o h = id" .
  4341   then show ?thesis using h(1) by blast
  4342 qed
  4343 
  4344 lemma matrix_left_invertible_injective:
  4345 "(\<exists>B. (B::real^'m^'n) ** (A::real^'n::finite^'m::finite) = mat 1) \<longleftrightarrow> (\<forall>x y. A *v x = A *v y \<longrightarrow> x = y)"
  4346 proof-
  4347   {fix B:: "real^'m^'n" and x y assume B: "B ** A = mat 1" and xy: "A *v x = A*v y"
  4348     from xy have "B*v (A *v x) = B *v (A*v y)" by simp
  4349     hence "x = y"
  4350       unfolding matrix_vector_mul_assoc B matrix_vector_mul_lid .}
  4351   moreover
  4352   {assume A: "\<forall>x y. A *v x = A *v y \<longrightarrow> x = y"
  4353     hence i: "inj (op *v A)" unfolding inj_on_def by auto
  4354     from linear_injective_left_inverse[OF matrix_vector_mul_linear i]
  4355     obtain g where g: "linear g" "g o op *v A = id" by blast
  4356     have "matrix g ** A = mat 1"
  4357       unfolding matrix_eq matrix_vector_mul_lid matrix_vector_mul_assoc[symmetric] matrix_works[OF g(1)]
  4358       using g(2) by (simp add: o_def id_def stupid_ext)
  4359     then have "\<exists>B. (B::real ^'m^'n) ** A = mat 1" by blast}
  4360   ultimately show ?thesis by blast
  4361 qed
  4362 
  4363 lemma matrix_left_invertible_ker:
  4364   "(\<exists>B. (B::real ^'m::finite^'n::finite) ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> (\<forall>x. A *v x = 0 \<longrightarrow> x = 0)"
  4365   unfolding matrix_left_invertible_injective
  4366   using linear_injective_0[OF matrix_vector_mul_linear, of A]
  4367   by (simp add: inj_on_def)
  4368 
  4369 lemma matrix_right_invertible_surjective:
  4370 "(\<exists>B. (A::real^'n::finite^'m::finite) ** (B::real^'m^'n) = mat 1) \<longleftrightarrow> surj (\<lambda>x. A *v x)"
  4371 proof-
  4372   {fix B :: "real ^'m^'n"  assume AB: "A ** B = mat 1"
  4373     {fix x :: "real ^ 'm"
  4374       have "A *v (B *v x) = x"
  4375 	by (simp add: matrix_vector_mul_lid matrix_vector_mul_assoc AB)}
  4376     hence "surj (op *v A)" unfolding surj_def by metis }
  4377   moreover
  4378   {assume sf: "surj (op *v A)"
  4379     from linear_surjective_right_inverse[OF matrix_vector_mul_linear sf]
  4380     obtain g:: "real ^'m \<Rightarrow> real ^'n" where g: "linear g" "op *v A o g = id"
  4381       by blast
  4382 
  4383     have "A ** (matrix g) = mat 1"
  4384       unfolding matrix_eq  matrix_vector_mul_lid
  4385 	matrix_vector_mul_assoc[symmetric] matrix_works[OF g(1)]
  4386       using g(2) unfolding o_def stupid_ext[symmetric] id_def
  4387       .
  4388     hence "\<exists>B. A ** (B::real^'m^'n) = mat 1" by blast
  4389   }
  4390   ultimately show ?thesis unfolding surj_def by blast
  4391 qed
  4392 
  4393 lemma matrix_left_invertible_independent_columns:
  4394   fixes A :: "real^'n::finite^'m::finite"
  4395   shows "(\<exists>(B::real ^'m^'n). B ** A = mat 1) \<longleftrightarrow> (\<forall>c. setsum (\<lambda>i. c i *s column i A) (UNIV :: 'n set) = 0 \<longrightarrow> (\<forall>i. c i = 0))"
  4396    (is "?lhs \<longleftrightarrow> ?rhs")
  4397 proof-
  4398   let ?U = "UNIV :: 'n set"
  4399   {assume k: "\<forall>x. A *v x = 0 \<longrightarrow> x = 0"
  4400     {fix c i assume c: "setsum (\<lambda>i. c i *s column i A) ?U = 0"
  4401       and i: "i \<in> ?U"
  4402       let ?x = "\<chi> i. c i"
  4403       have th0:"A *v ?x = 0"
  4404 	using c
  4405 	unfolding matrix_mult_vsum Cart_eq
  4406 	by auto
  4407       from k[rule_format, OF th0] i
  4408       have "c i = 0" by (vector Cart_eq)}
  4409     hence ?rhs by blast}
  4410   moreover
  4411   {assume H: ?rhs
  4412     {fix x assume x: "A *v x = 0"
  4413       let ?c = "\<lambda>i. ((x$i ):: real)"
  4414       from H[rule_format, of ?c, unfolded matrix_mult_vsum[symmetric], OF x]
  4415       have "x = 0" by vector}}
  4416   ultimately show ?thesis unfolding matrix_left_invertible_ker by blast
  4417 qed
  4418 
  4419 lemma matrix_right_invertible_independent_rows:
  4420   fixes A :: "real^'n::finite^'m::finite"
  4421   shows "(\<exists>(B::real^'m^'n). A ** B = mat 1) \<longleftrightarrow> (\<forall>c. setsum (\<lambda>i. c i *s row i A) (UNIV :: 'm set) = 0 \<longrightarrow> (\<forall>i. c i = 0))"
  4422   unfolding left_invertible_transp[symmetric]
  4423     matrix_left_invertible_independent_columns
  4424   by (simp add: column_transp)
  4425 
  4426 lemma matrix_right_invertible_span_columns:
  4427   "(\<exists>(B::real ^'n::finite^'m::finite). (A::real ^'m^'n) ** B = mat 1) \<longleftrightarrow> span (columns A) = UNIV" (is "?lhs = ?rhs")
  4428 proof-
  4429   let ?U = "UNIV :: 'm set"
  4430   have fU: "finite ?U" by simp
  4431   have lhseq: "?lhs \<longleftrightarrow> (\<forall>y. \<exists>(x::real^'m). setsum (\<lambda>i. (x$i) *s column i A) ?U = y)"
  4432     unfolding matrix_right_invertible_surjective matrix_mult_vsum surj_def
  4433     apply (subst eq_commute) ..
  4434   have rhseq: "?rhs \<longleftrightarrow> (\<forall>x. x \<in> span (columns A))" by blast
  4435   {assume h: ?lhs
  4436     {fix x:: "real ^'n"
  4437 	from h[unfolded lhseq, rule_format, of x] obtain y:: "real ^'m"
  4438 	  where y: "setsum (\<lambda>i. (y$i) *s column i A) ?U = x" by blast
  4439 	have "x \<in> span (columns A)"
  4440 	  unfolding y[symmetric]
  4441 	  apply (rule span_setsum[OF fU])
  4442 	  apply clarify
  4443 	  apply (rule span_mul)
  4444 	  apply (rule span_superset)
  4445 	  unfolding columns_def
  4446 	  by blast}
  4447     then have ?rhs unfolding rhseq by blast}
  4448   moreover
  4449   {assume h:?rhs
  4450     let ?P = "\<lambda>(y::real ^'n). \<exists>(x::real^'m). setsum (\<lambda>i. (x$i) *s column i A) ?U = y"
  4451     {fix y have "?P y"
  4452       proof(rule span_induct_alt[of ?P "columns A"])
  4453 	show "\<exists>x\<Colon>real ^ 'm. setsum (\<lambda>i. (x$i) *s column i A) ?U = 0"
  4454 	  apply (rule exI[where x=0])
  4455 	  by (simp add: zero_index vector_smult_lzero)
  4456       next
  4457 	fix c y1 y2 assume y1: "y1 \<in> columns A" and y2: "?P y2"
  4458 	from y1 obtain i where i: "i \<in> ?U" "y1 = column i A"
  4459 	  unfolding columns_def by blast
  4460 	from y2 obtain x:: "real ^'m" where
  4461 	  x: "setsum (\<lambda>i. (x$i) *s column i A) ?U = y2" by blast
  4462 	let ?x = "(\<chi> j. if j = i then c + (x$i) else (x$j))::real^'m"
  4463 	show "?P (c*s y1 + y2)"
  4464 	  proof(rule exI[where x= "?x"], vector, auto simp add: i x[symmetric] cond_value_iff right_distrib cond_application_beta cong del: if_weak_cong)
  4465 	    fix j
  4466 	    have th: "\<forall>xa \<in> ?U. (if xa = i then (c + (x$i)) * ((column xa A)$j)
  4467            else (x$xa) * ((column xa A$j))) = (if xa = i then c * ((column i A)$j) else 0) + ((x$xa) * ((column xa A)$j))" using i(1)
  4468 	      by (simp add: ring_simps)
  4469 	    have "setsum (\<lambda>xa. if xa = i then (c + (x$i)) * ((column xa A)$j)
  4470            else (x$xa) * ((column xa A$j))) ?U = setsum (\<lambda>xa. (if xa = i then c * ((column i A)$j) else 0) + ((x$xa) * ((column xa A)$j))) ?U"
  4471 	      apply (rule setsum_cong[OF refl])
  4472 	      using th by blast
  4473 	    also have "\<dots> = setsum (\<lambda>xa. if xa = i then c * ((column i A)$j) else 0) ?U + setsum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U"
  4474 	      by (simp add: setsum_addf)
  4475 	    also have "\<dots> = c * ((column i A)$j) + setsum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U"
  4476 	      unfolding setsum_delta[OF fU]
  4477 	      using i(1) by simp
  4478 	    finally show "setsum (\<lambda>xa. if xa = i then (c + (x$i)) * ((column xa A)$j)
  4479            else (x$xa) * ((column xa A$j))) ?U = c * ((column i A)$j) + setsum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U" .
  4480 	  qed
  4481 	next
  4482 	  show "y \<in> span (columns A)" unfolding h by blast
  4483 	qed}
  4484     then have ?lhs unfolding lhseq ..}
  4485   ultimately show ?thesis by blast
  4486 qed
  4487 
  4488 lemma matrix_left_invertible_span_rows:
  4489   "(\<exists>(B::real^'m::finite^'n::finite). B ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> span (rows A) = UNIV"
  4490   unfolding right_invertible_transp[symmetric]
  4491   unfolding columns_transp[symmetric]
  4492   unfolding matrix_right_invertible_span_columns
  4493  ..
  4494 
  4495 (* An injective map real^'n->real^'n is also surjective.                       *)
  4496 
  4497 lemma linear_injective_imp_surjective:
  4498   assumes lf: "linear (f:: real ^'n::finite \<Rightarrow> real ^'n)" and fi: "inj f"
  4499   shows "surj f"
  4500 proof-
  4501   let ?U = "UNIV :: (real ^'n) set"
  4502   from basis_exists[of ?U] obtain B
  4503     where B: "B \<subseteq> ?U" "independent B" "?U \<subseteq> span B" "B hassize dim ?U"
  4504     by blast
  4505   from B(4) have d: "dim ?U = card B" by (simp add: hassize_def)
  4506   have th: "?U \<subseteq> span (f ` B)"
  4507     apply (rule card_ge_dim_independent)
  4508     apply blast
  4509     apply (rule independent_injective_image[OF B(2) lf fi])
  4510     apply (rule order_eq_refl)
  4511     apply (rule sym)
  4512     unfolding d
  4513     apply (rule card_image)
  4514     apply (rule subset_inj_on[OF fi])
  4515     by blast
  4516   from th show ?thesis
  4517     unfolding span_linear_image[OF lf] surj_def
  4518     using B(3) by blast
  4519 qed
  4520 
  4521 (* And vice versa.                                                           *)
  4522 
  4523 lemma surjective_iff_injective_gen:
  4524   assumes fS: "finite S" and fT: "finite T" and c: "card S = card T"
  4525   and ST: "f ` S \<subseteq> T"
  4526   shows "(\<forall>y \<in> T. \<exists>x \<in> S. f x = y) \<longleftrightarrow> inj_on f S" (is "?lhs \<longleftrightarrow> ?rhs")
  4527 proof-
  4528   {assume h: "?lhs"
  4529     {fix x y assume x: "x \<in> S" and y: "y \<in> S" and f: "f x = f y"
  4530       from x fS have S0: "card S \<noteq> 0" by auto
  4531       {assume xy: "x \<noteq> y"
  4532 	have th: "card S \<le> card (f ` (S - {y}))"
  4533 	  unfolding c
  4534 	  apply (rule card_mono)
  4535 	  apply (rule finite_imageI)
  4536 	  using fS apply simp
  4537 	  using h xy x y f unfolding subset_eq image_iff
  4538 	  apply auto
  4539 	  apply (case_tac "xa = f x")
  4540 	  apply (rule bexI[where x=x])
  4541 	  apply auto
  4542 	  done
  4543 	also have " \<dots> \<le> card (S -{y})"
  4544 	  apply (rule card_image_le)
  4545 	  using fS by simp
  4546 	also have "\<dots> \<le> card S - 1" using y fS by simp
  4547 	finally have False  using S0 by arith }
  4548       then have "x = y" by blast}
  4549     then have ?rhs unfolding inj_on_def by blast}
  4550   moreover
  4551   {assume h: ?rhs
  4552     have "f ` S = T"
  4553       apply (rule card_subset_eq[OF fT ST])
  4554       unfolding card_image[OF h] using c .
  4555     then have ?lhs by blast}
  4556   ultimately show ?thesis by blast
  4557 qed
  4558 
  4559 lemma linear_surjective_imp_injective:
  4560   assumes lf: "linear (f::real ^'n::finite => real ^'n)" and sf: "surj f"
  4561   shows "inj f"
  4562 proof-
  4563   let ?U = "UNIV :: (real ^'n) set"
  4564   from basis_exists[of ?U] obtain B
  4565     where B: "B \<subseteq> ?U" "independent B" "?U \<subseteq> span B" "B hassize dim ?U"
  4566     by blast
  4567   {fix x assume x: "x \<in> span B" and fx: "f x = 0"
  4568     from B(4) have fB: "finite B" by (simp add: hassize_def)
  4569     from B(4) have d: "dim ?U = card B" by (simp add: hassize_def)
  4570     have fBi: "independent (f ` B)"
  4571       apply (rule card_le_dim_spanning[of "f ` B" ?U])
  4572       apply blast
  4573       using sf B(3)
  4574       unfolding span_linear_image[OF lf] surj_def subset_eq image_iff
  4575       apply blast
  4576       using fB apply (blast intro: finite_imageI)
  4577       unfolding d
  4578       apply (rule card_image_le)
  4579       apply (rule fB)
  4580       done
  4581     have th0: "dim ?U \<le> card (f ` B)"
  4582       apply (rule span_card_ge_dim)
  4583       apply blast
  4584       unfolding span_linear_image[OF lf]
  4585       apply (rule subset_trans[where B = "f ` UNIV"])
  4586       using sf unfolding surj_def apply blast
  4587       apply (rule image_mono)
  4588       apply (rule B(3))
  4589       apply (metis finite_imageI fB)
  4590       done
  4591 
  4592     moreover have "card (f ` B) \<le> card B"
  4593       by (rule card_image_le, rule fB)
  4594     ultimately have th1: "card B = card (f ` B)" unfolding d by arith
  4595     have fiB: "inj_on f B"
  4596       unfolding surjective_iff_injective_gen[OF fB finite_imageI[OF fB] th1 subset_refl, symmetric] by blast
  4597     from linear_indep_image_lemma[OF lf fB fBi fiB x] fx
  4598     have "x = 0" by blast}
  4599   note th = this
  4600   from th show ?thesis unfolding linear_injective_0[OF lf]
  4601     using B(3) by blast
  4602 qed
  4603 
  4604 (* Hence either is enough for isomorphism.                                   *)
  4605 
  4606 lemma left_right_inverse_eq:
  4607   assumes fg: "f o g = id" and gh: "g o h = id"
  4608   shows "f = h"
  4609 proof-
  4610   have "f = f o (g o h)" unfolding gh by simp
  4611   also have "\<dots> = (f o g) o h" by (simp add: o_assoc)
  4612   finally show "f = h" unfolding fg by simp
  4613 qed
  4614 
  4615 lemma isomorphism_expand:
  4616   "f o g = id \<and> g o f = id \<longleftrightarrow> (\<forall>x. f(g x) = x) \<and> (\<forall>x. g(f x) = x)"
  4617   by (simp add: expand_fun_eq o_def id_def)
  4618 
  4619 lemma linear_injective_isomorphism:
  4620   assumes lf: "linear (f :: real^'n::finite \<Rightarrow> real ^'n)" and fi: "inj f"
  4621   shows "\<exists>f'. linear f' \<and> (\<forall>x. f' (f x) = x) \<and> (\<forall>x. f (f' x) = x)"
  4622 unfolding isomorphism_expand[symmetric]
  4623 using linear_surjective_right_inverse[OF lf linear_injective_imp_surjective[OF lf fi]] linear_injective_left_inverse[OF lf fi]
  4624 by (metis left_right_inverse_eq)
  4625 
  4626 lemma linear_surjective_isomorphism:
  4627   assumes lf: "linear (f::real ^'n::finite \<Rightarrow> real ^'n)" and sf: "surj f"
  4628   shows "\<exists>f'. linear f' \<and> (\<forall>x. f' (f x) = x) \<and> (\<forall>x. f (f' x) = x)"
  4629 unfolding isomorphism_expand[symmetric]
  4630 using linear_surjective_right_inverse[OF lf sf] linear_injective_left_inverse[OF lf linear_surjective_imp_injective[OF lf sf]]
  4631 by (metis left_right_inverse_eq)
  4632 
  4633 (* Left and right inverses are the same for R^N->R^N.                        *)
  4634 
  4635 lemma linear_inverse_left:
  4636   assumes lf: "linear (f::real ^'n::finite \<Rightarrow> real ^'n)" and lf': "linear f'"
  4637   shows "f o f' = id \<longleftrightarrow> f' o f = id"
  4638 proof-
  4639   {fix f f':: "real ^'n \<Rightarrow> real ^'n"
  4640     assume lf: "linear f" "linear f'" and f: "f o f' = id"
  4641     from f have sf: "surj f"
  4642 
  4643       apply (auto simp add: o_def stupid_ext[symmetric] id_def surj_def)
  4644       by metis
  4645     from linear_surjective_isomorphism[OF lf(1) sf] lf f
  4646     have "f' o f = id" unfolding stupid_ext[symmetric] o_def id_def
  4647       by metis}
  4648   then show ?thesis using lf lf' by metis
  4649 qed
  4650 
  4651 (* Moreover, a one-sided inverse is automatically linear.                    *)
  4652 
  4653 lemma left_inverse_linear:
  4654   assumes lf: "linear (f::real ^'n::finite \<Rightarrow> real ^'n)" and gf: "g o f = id"
  4655   shows "linear g"
  4656 proof-
  4657   from gf have fi: "inj f" apply (auto simp add: inj_on_def o_def id_def stupid_ext[symmetric])
  4658     by metis
  4659   from linear_injective_isomorphism[OF lf fi]
  4660   obtain h:: "real ^'n \<Rightarrow> real ^'n" where
  4661     h: "linear h" "\<forall>x. h (f x) = x" "\<forall>x. f (h x) = x" by blast
  4662   have "h = g" apply (rule ext) using gf h(2,3)
  4663     apply (simp add: o_def id_def stupid_ext[symmetric])
  4664     by metis
  4665   with h(1) show ?thesis by blast
  4666 qed
  4667 
  4668 lemma right_inverse_linear:
  4669   assumes lf: "linear (f:: real ^'n::finite \<Rightarrow> real ^'n)" and gf: "f o g = id"
  4670   shows "linear g"
  4671 proof-
  4672   from gf have fi: "surj f" apply (auto simp add: surj_def o_def id_def stupid_ext[symmetric])
  4673     by metis
  4674   from linear_surjective_isomorphism[OF lf fi]
  4675   obtain h:: "real ^'n \<Rightarrow> real ^'n" where
  4676     h: "linear h" "\<forall>x. h (f x) = x" "\<forall>x. f (h x) = x" by blast
  4677   have "h = g" apply (rule ext) using gf h(2,3)
  4678     apply (simp add: o_def id_def stupid_ext[symmetric])
  4679     by metis
  4680   with h(1) show ?thesis by blast
  4681 qed
  4682 
  4683 (* The same result in terms of square matrices.                              *)
  4684 
  4685 lemma matrix_left_right_inverse:
  4686   fixes A A' :: "real ^'n::finite^'n"
  4687   shows "A ** A' = mat 1 \<longleftrightarrow> A' ** A = mat 1"
  4688 proof-
  4689   {fix A A' :: "real ^'n^'n" assume AA': "A ** A' = mat 1"
  4690     have sA: "surj (op *v A)"
  4691       unfolding surj_def
  4692       apply clarify
  4693       apply (rule_tac x="(A' *v y)" in exI)
  4694       by (simp add: matrix_vector_mul_assoc AA' matrix_vector_mul_lid)
  4695     from linear_surjective_isomorphism[OF matrix_vector_mul_linear sA]
  4696     obtain f' :: "real ^'n \<Rightarrow> real ^'n"
  4697       where f': "linear f'" "\<forall>x. f' (A *v x) = x" "\<forall>x. A *v f' x = x" by blast
  4698     have th: "matrix f' ** A = mat 1"
  4699       by (simp add: matrix_eq matrix_works[OF f'(1)] matrix_vector_mul_assoc[symmetric] matrix_vector_mul_lid f'(2)[rule_format])
  4700     hence "(matrix f' ** A) ** A' = mat 1 ** A'" by simp
  4701     hence "matrix f' = A'" by (simp add: matrix_mul_assoc[symmetric] AA' matrix_mul_rid matrix_mul_lid)
  4702     hence "matrix f' ** A = A' ** A" by simp
  4703     hence "A' ** A = mat 1" by (simp add: th)}
  4704   then show ?thesis by blast
  4705 qed
  4706 
  4707 (* Considering an n-element vector as an n-by-1 or 1-by-n matrix.            *)
  4708 
  4709 definition "rowvector v = (\<chi> i j. (v$j))"
  4710 
  4711 definition "columnvector v = (\<chi> i j. (v$i))"
  4712 
  4713 lemma transp_columnvector:
  4714  "transp(columnvector v) = rowvector v"
  4715   by (simp add: transp_def rowvector_def columnvector_def Cart_eq)
  4716 
  4717 lemma transp_rowvector: "transp(rowvector v) = columnvector v"
  4718   by (simp add: transp_def columnvector_def rowvector_def Cart_eq)
  4719 
  4720 lemma dot_rowvector_columnvector:
  4721   "columnvector (A *v v) = A ** columnvector v"
  4722   by (vector columnvector_def matrix_matrix_mult_def matrix_vector_mult_def)
  4723 
  4724 lemma dot_matrix_product: "(x::'a::semiring_1^'n::finite) \<bullet> y = (((rowvector x ::'a^'n^1) ** (columnvector y :: 'a^1^'n))$1)$1"
  4725   by (vector matrix_matrix_mult_def rowvector_def columnvector_def dot_def)
  4726 
  4727 lemma dot_matrix_vector_mul:
  4728   fixes A B :: "real ^'n::finite ^'n" and x y :: "real ^'n"
  4729   shows "(A *v x) \<bullet> (B *v y) =
  4730       (((rowvector x :: real^'n^1) ** ((transp A ** B) ** (columnvector y :: real ^1^'n)))$1)$1"
  4731 unfolding dot_matrix_product transp_columnvector[symmetric]
  4732   dot_rowvector_columnvector matrix_transp_mul matrix_mul_assoc ..
  4733 
  4734 (* Infinity norm.                                                            *)
  4735 
  4736 definition "infnorm (x::real^'n::finite) = rsup {abs(x$i) |i. i\<in> (UNIV :: 'n set)}"
  4737 
  4738 lemma numseg_dimindex_nonempty: "\<exists>i. i \<in> (UNIV :: 'n set)"
  4739   by auto
  4740 
  4741 lemma infnorm_set_image:
  4742   "{abs(x$i) |i. i\<in> (UNIV :: 'n set)} =
  4743   (\<lambda>i. abs(x$i)) ` (UNIV :: 'n set)" by blast
  4744 
  4745 lemma infnorm_set_lemma:
  4746   shows "finite {abs((x::'a::abs ^'n::finite)$i) |i. i\<in> (UNIV :: 'n set)}"
  4747   and "{abs(x$i) |i. i\<in> (UNIV :: 'n::finite set)} \<noteq> {}"
  4748   unfolding infnorm_set_image
  4749   by (auto intro: finite_imageI)
  4750 
  4751 lemma infnorm_pos_le: "0 \<le> infnorm (x::real^'n::finite)"
  4752   unfolding infnorm_def
  4753   unfolding rsup_finite_ge_iff[ OF infnorm_set_lemma]
  4754   unfolding infnorm_set_image
  4755   by auto
  4756 
  4757 lemma infnorm_triangle: "infnorm ((x::real^'n::finite) + y) \<le> infnorm x + infnorm y"
  4758 proof-
  4759   have th: "\<And>x y (z::real). x - y <= z \<longleftrightarrow> x - z <= y" by arith
  4760   have th1: "\<And>S f. f ` S = { f i| i. i \<in> S}" by blast
  4761   have th2: "\<And>x (y::real). abs(x + y) - abs(x) <= abs(y)" by arith
  4762   show ?thesis
  4763   unfolding infnorm_def
  4764   unfolding rsup_finite_le_iff[ OF infnorm_set_lemma]
  4765   apply (subst diff_le_eq[symmetric])
  4766   unfolding rsup_finite_ge_iff[ OF infnorm_set_lemma]
  4767   unfolding infnorm_set_image bex_simps
  4768   apply (subst th)
  4769   unfolding th1
  4770   unfolding rsup_finite_ge_iff[ OF infnorm_set_lemma]
  4771 
  4772   unfolding infnorm_set_image ball_simps bex_simps
  4773   apply simp
  4774   apply (metis th2)
  4775   done
  4776 qed
  4777 
  4778 lemma infnorm_eq_0: "infnorm x = 0 \<longleftrightarrow> (x::real ^'n::finite) = 0"
  4779 proof-
  4780   have "infnorm x <= 0 \<longleftrightarrow> x = 0"
  4781     unfolding infnorm_def
  4782     unfolding rsup_finite_le_iff[OF infnorm_set_lemma]
  4783     unfolding infnorm_set_image ball_simps
  4784     by vector
  4785   then show ?thesis using infnorm_pos_le[of x] by simp
  4786 qed
  4787 
  4788 lemma infnorm_0: "infnorm 0 = 0"
  4789   by (simp add: infnorm_eq_0)
  4790 
  4791 lemma infnorm_neg: "infnorm (- x) = infnorm x"
  4792   unfolding infnorm_def
  4793   apply (rule cong[of "rsup" "rsup"])
  4794   apply blast
  4795   apply (rule set_ext)
  4796   apply auto
  4797   done
  4798 
  4799 lemma infnorm_sub: "infnorm (x - y) = infnorm (y - x)"
  4800 proof-
  4801   have "y - x = - (x - y)" by simp
  4802   then show ?thesis  by (metis infnorm_neg)
  4803 qed
  4804 
  4805 lemma real_abs_sub_infnorm: "\<bar> infnorm x - infnorm y\<bar> \<le> infnorm (x - y)"
  4806 proof-
  4807   have th: "\<And>(nx::real) n ny. nx <= n + ny \<Longrightarrow> ny <= n + nx ==> \<bar>nx - ny\<bar> <= n"
  4808     by arith
  4809   from infnorm_triangle[of "x - y" " y"] infnorm_triangle[of "x - y" "-x"]
  4810   have ths: "infnorm x \<le> infnorm (x - y) + infnorm y"
  4811     "infnorm y \<le> infnorm (x - y) + infnorm x"
  4812     by (simp_all add: ring_simps infnorm_neg diff_def[symmetric])
  4813   from th[OF ths]  show ?thesis .
  4814 qed
  4815 
  4816 lemma real_abs_infnorm: " \<bar>infnorm x\<bar> = infnorm x"
  4817   using infnorm_pos_le[of x] by arith
  4818 
  4819 lemma component_le_infnorm:
  4820   shows "\<bar>x$i\<bar> \<le> infnorm (x::real^'n::finite)"
  4821 proof-
  4822   let ?U = "UNIV :: 'n set"
  4823   let ?S = "{\<bar>x$i\<bar> |i. i\<in> ?U}"
  4824   have fS: "finite ?S" unfolding image_Collect[symmetric]
  4825     apply (rule finite_imageI) unfolding Collect_def mem_def by simp
  4826   have S0: "?S \<noteq> {}" by blast
  4827   have th1: "\<And>S f. f ` S = { f i| i. i \<in> S}" by blast
  4828   from rsup_finite_in[OF fS S0] rsup_finite_Ub[OF fS S0]
  4829   show ?thesis unfolding infnorm_def isUb_def setle_def
  4830     unfolding infnorm_set_image ball_simps by auto
  4831 qed
  4832 
  4833 lemma infnorm_mul_lemma: "infnorm(a *s x) <= \<bar>a\<bar> * infnorm x"
  4834   apply (subst infnorm_def)
  4835   unfolding rsup_finite_le_iff[OF infnorm_set_lemma]
  4836   unfolding infnorm_set_image ball_simps
  4837   apply (simp add: abs_mult)
  4838   apply (rule allI)
  4839   apply (cut_tac component_le_infnorm[of x])
  4840   apply (rule mult_mono)
  4841   apply auto
  4842   done
  4843 
  4844 lemma infnorm_mul: "infnorm(a *s x) = abs a * infnorm x"
  4845 proof-
  4846   {assume a0: "a = 0" hence ?thesis by (simp add: infnorm_0) }
  4847   moreover
  4848   {assume a0: "a \<noteq> 0"
  4849     from a0 have th: "(1/a) *s (a *s x) = x"
  4850       by (simp add: vector_smult_assoc)
  4851     from a0 have ap: "\<bar>a\<bar> > 0" by arith
  4852     from infnorm_mul_lemma[of "1/a" "a *s x"]
  4853     have "infnorm x \<le> 1/\<bar>a\<bar> * infnorm (a*s x)"
  4854       unfolding th by simp
  4855     with ap have "\<bar>a\<bar> * infnorm x \<le> \<bar>a\<bar> * (1/\<bar>a\<bar> * infnorm (a *s x))" by (simp add: field_simps)
  4856     then have "\<bar>a\<bar> * infnorm x \<le> infnorm (a*s x)"
  4857       using ap by (simp add: field_simps)
  4858     with infnorm_mul_lemma[of a x] have ?thesis by arith }
  4859   ultimately show ?thesis by blast
  4860 qed
  4861 
  4862 lemma infnorm_pos_lt: "infnorm x > 0 \<longleftrightarrow> x \<noteq> 0"
  4863   using infnorm_pos_le[of x] infnorm_eq_0[of x] by arith
  4864 
  4865 (* Prove that it differs only up to a bound from Euclidean norm.             *)
  4866 
  4867 lemma infnorm_le_norm: "infnorm x \<le> norm x"
  4868   unfolding infnorm_def rsup_finite_le_iff[OF infnorm_set_lemma]
  4869   unfolding infnorm_set_image  ball_simps
  4870   by (metis component_le_norm)
  4871 lemma card_enum: "card {1 .. n} = n" by auto
  4872 lemma norm_le_infnorm: "norm(x) <= sqrt(real CARD('n)) * infnorm(x::real ^'n::finite)"
  4873 proof-
  4874   let ?d = "CARD('n)"
  4875   have "real ?d \<ge> 0" by simp
  4876   hence d2: "(sqrt (real ?d))^2 = real ?d"
  4877     by (auto intro: real_sqrt_pow2)
  4878   have th: "sqrt (real ?d) * infnorm x \<ge> 0"
  4879     by (simp add: zero_le_mult_iff real_sqrt_ge_0_iff infnorm_pos_le)
  4880   have th1: "x\<bullet>x \<le> (sqrt (real ?d) * infnorm x)^2"
  4881     unfolding power_mult_distrib d2
  4882     apply (subst power2_abs[symmetric])
  4883     unfolding real_of_nat_def dot_def power2_eq_square[symmetric]
  4884     apply (subst power2_abs[symmetric])
  4885     apply (rule setsum_bounded)
  4886     apply (rule power_mono)
  4887     unfolding abs_of_nonneg[OF infnorm_pos_le]
  4888     unfolding infnorm_def  rsup_finite_ge_iff[OF infnorm_set_lemma]
  4889     unfolding infnorm_set_image bex_simps
  4890     apply blast
  4891     by (rule abs_ge_zero)
  4892   from real_le_lsqrt[OF dot_pos_le th th1]
  4893   show ?thesis unfolding real_vector_norm_def id_def .
  4894 qed
  4895 
  4896 (* Equality in Cauchy-Schwarz and triangle inequalities.                     *)
  4897 
  4898 lemma norm_cauchy_schwarz_eq: "(x::real ^'n::finite) \<bullet> y = norm x * norm y \<longleftrightarrow> norm x *s y = norm y *s x" (is "?lhs \<longleftrightarrow> ?rhs")
  4899 proof-
  4900   {assume h: "x = 0"
  4901     hence ?thesis by simp}
  4902   moreover
  4903   {assume h: "y = 0"
  4904     hence ?thesis by simp}
  4905   moreover
  4906   {assume x: "x \<noteq> 0" and y: "y \<noteq> 0"
  4907     from dot_eq_0[of "norm y *s x - norm x *s y"]
  4908     have "?rhs \<longleftrightarrow> (norm y * (norm y * norm x * norm x - norm x * (x \<bullet> y)) - norm x * (norm y * (y \<bullet> x) - norm x * norm y * norm y) =  0)"
  4909       using x y
  4910       unfolding dot_rsub dot_lsub dot_lmult dot_rmult
  4911       unfolding norm_pow_2[symmetric] power2_eq_square diff_eq_0_iff_eq apply (simp add: dot_sym)
  4912       apply (simp add: ring_simps)
  4913       apply metis
  4914       done
  4915     also have "\<dots> \<longleftrightarrow> (2 * norm x * norm y * (norm x * norm y - x \<bullet> y) = 0)" using x y
  4916       by (simp add: ring_simps dot_sym)
  4917     also have "\<dots> \<longleftrightarrow> ?lhs" using x y
  4918       apply simp
  4919       by metis
  4920     finally have ?thesis by blast}
  4921   ultimately show ?thesis by blast
  4922 qed
  4923 
  4924 lemma norm_cauchy_schwarz_abs_eq:
  4925   fixes x y :: "real ^ 'n::finite"
  4926   shows "abs(x \<bullet> y) = norm x * norm y \<longleftrightarrow>
  4927                 norm x *s y = norm y *s x \<or> norm(x) *s y = - norm y *s x" (is "?lhs \<longleftrightarrow> ?rhs")
  4928 proof-
  4929   have th: "\<And>(x::real) a. a \<ge> 0 \<Longrightarrow> abs x = a \<longleftrightarrow> x = a \<or> x = - a" by arith
  4930   have "?rhs \<longleftrightarrow> norm x *s y = norm y *s x \<or> norm (- x) *s y = norm y *s (- x)"
  4931     apply simp by vector
  4932   also have "\<dots> \<longleftrightarrow>(x \<bullet> y = norm x * norm y \<or>
  4933      (-x) \<bullet> y = norm x * norm y)"
  4934     unfolding norm_cauchy_schwarz_eq[symmetric]
  4935     unfolding norm_minus_cancel
  4936       norm_mul by blast
  4937   also have "\<dots> \<longleftrightarrow> ?lhs"
  4938     unfolding th[OF mult_nonneg_nonneg, OF norm_ge_zero[of x] norm_ge_zero[of y]] dot_lneg
  4939     by arith
  4940   finally show ?thesis ..
  4941 qed
  4942 
  4943 lemma norm_triangle_eq:
  4944   fixes x y :: "real ^ 'n::finite"
  4945   shows "norm(x + y) = norm x + norm y \<longleftrightarrow> norm x *s y = norm y *s x"
  4946 proof-
  4947   {assume x: "x =0 \<or> y =0"
  4948     hence ?thesis by (cases "x=0", simp_all)}
  4949   moreover
  4950   {assume x: "x \<noteq> 0" and y: "y \<noteq> 0"
  4951     hence "norm x \<noteq> 0" "norm y \<noteq> 0"
  4952       by simp_all
  4953     hence n: "norm x > 0" "norm y > 0"
  4954       using norm_ge_zero[of x] norm_ge_zero[of y]
  4955       by arith+
  4956     have th: "\<And>(a::real) b c. a + b + c \<noteq> 0 ==> (a = b + c \<longleftrightarrow> a^2 = (b + c)^2)" by algebra
  4957     have "norm(x + y) = norm x + norm y \<longleftrightarrow> norm(x + y)^ 2 = (norm x + norm y) ^2"
  4958       apply (rule th) using n norm_ge_zero[of "x + y"]
  4959       by arith
  4960     also have "\<dots> \<longleftrightarrow> norm x *s y = norm y *s x"
  4961       unfolding norm_cauchy_schwarz_eq[symmetric]
  4962       unfolding norm_pow_2 dot_ladd dot_radd
  4963       by (simp add: norm_pow_2[symmetric] power2_eq_square dot_sym ring_simps)
  4964     finally have ?thesis .}
  4965   ultimately show ?thesis by blast
  4966 qed
  4967 
  4968 (* Collinearity.*)
  4969 
  4970 definition "collinear S \<longleftrightarrow> (\<exists>u. \<forall>x \<in> S. \<forall> y \<in> S. \<exists>c. x - y = c *s u)"
  4971 
  4972 lemma collinear_empty:  "collinear {}" by (simp add: collinear_def)
  4973 
  4974 lemma collinear_sing: "collinear {(x::'a::ring_1^'n)}"
  4975   apply (simp add: collinear_def)
  4976   apply (rule exI[where x=0])
  4977   by simp
  4978 
  4979 lemma collinear_2: "collinear {(x::'a::ring_1^'n),y}"
  4980   apply (simp add: collinear_def)
  4981   apply (rule exI[where x="x - y"])
  4982   apply auto
  4983   apply (rule exI[where x=0], simp)
  4984   apply (rule exI[where x=1], simp)
  4985   apply (rule exI[where x="- 1"], simp add: vector_sneg_minus1[symmetric])
  4986   apply (rule exI[where x=0], simp)
  4987   done
  4988 
  4989 lemma collinear_lemma: "collinear {(0::real^'n),x,y} \<longleftrightarrow> x = 0 \<or> y = 0 \<or> (\<exists>c. y = c *s x)" (is "?lhs \<longleftrightarrow> ?rhs")
  4990 proof-
  4991   {assume "x=0 \<or> y = 0" hence ?thesis
  4992       by (cases "x = 0", simp_all add: collinear_2 insert_commute)}
  4993   moreover
  4994   {assume x: "x \<noteq> 0" and y: "y \<noteq> 0"
  4995     {assume h: "?lhs"
  4996       then obtain u where u: "\<forall> x\<in> {0,x,y}. \<forall>y\<in> {0,x,y}. \<exists>c. x - y = c *s u" unfolding collinear_def by blast
  4997       from u[rule_format, of x 0] u[rule_format, of y 0]
  4998       obtain cx and cy where
  4999 	cx: "x = cx*s u" and cy: "y = cy*s u"
  5000 	by auto
  5001       from cx x have cx0: "cx \<noteq> 0" by auto
  5002       from cy y have cy0: "cy \<noteq> 0" by auto
  5003       let ?d = "cy / cx"
  5004       from cx cy cx0 have "y = ?d *s x"
  5005 	by (simp add: vector_smult_assoc)
  5006       hence ?rhs using x y by blast}
  5007     moreover
  5008     {assume h: "?rhs"
  5009       then obtain c where c: "y = c*s x" using x y by blast
  5010       have ?lhs unfolding collinear_def c
  5011 	apply (rule exI[where x=x])
  5012 	apply auto
  5013 	apply (rule exI[where x="- 1"], simp only: vector_smult_lneg vector_smult_lid)
  5014 	apply (rule exI[where x= "-c"], simp only: vector_smult_lneg)
  5015 	apply (rule exI[where x=1], simp)
  5016 	apply (rule exI[where x="1 - c"], simp add: vector_smult_lneg vector_sub_rdistrib)
  5017 	apply (rule exI[where x="c - 1"], simp add: vector_smult_lneg vector_sub_rdistrib)
  5018 	done}
  5019     ultimately have ?thesis by blast}
  5020   ultimately show ?thesis by blast
  5021 qed
  5022 
  5023 lemma norm_cauchy_schwarz_equal:
  5024   fixes x y :: "real ^ 'n::finite"
  5025   shows "abs(x \<bullet> y) = norm x * norm y \<longleftrightarrow> collinear {(0::real^'n),x,y}"
  5026 unfolding norm_cauchy_schwarz_abs_eq
  5027 apply (cases "x=0", simp_all add: collinear_2)
  5028 apply (cases "y=0", simp_all add: collinear_2 insert_commute)
  5029 unfolding collinear_lemma
  5030 apply simp
  5031 apply (subgoal_tac "norm x \<noteq> 0")
  5032 apply (subgoal_tac "norm y \<noteq> 0")
  5033 apply (rule iffI)
  5034 apply (cases "norm x *s y = norm y *s x")
  5035 apply (rule exI[where x="(1/norm x) * norm y"])
  5036 apply (drule sym)
  5037 unfolding vector_smult_assoc[symmetric]
  5038 apply (simp add: vector_smult_assoc field_simps)
  5039 apply (rule exI[where x="(1/norm x) * - norm y"])
  5040 apply clarify
  5041 apply (drule sym)
  5042 unfolding vector_smult_assoc[symmetric]
  5043 apply (simp add: vector_smult_assoc field_simps)
  5044 apply (erule exE)
  5045 apply (erule ssubst)
  5046 unfolding vector_smult_assoc
  5047 unfolding norm_mul
  5048 apply (subgoal_tac "norm x * c = \<bar>c\<bar> * norm x \<or> norm x * c = - \<bar>c\<bar> * norm x")
  5049 apply (case_tac "c <= 0", simp add: ring_simps)
  5050 apply (simp add: ring_simps)
  5051 apply (case_tac "c <= 0", simp add: ring_simps)
  5052 apply (simp add: ring_simps)
  5053 apply simp
  5054 apply simp
  5055 done
  5056 
  5057 end