src/Pure/display.ML
author wenzelm
Wed Jan 21 23:21:44 2009 +0100 (2009-01-21)
changeset 29606 fedb8be05f24
parent 29091 b81fe045e799
child 29858 c8cee17d7e50
permissions -rw-r--r--
removed Ids;
     1 (*  Title:      Pure/display.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1993  University of Cambridge
     4 
     5 Printing of theorems, goals, results etc.
     6 *)
     7 
     8 signature BASIC_DISPLAY =
     9 sig
    10   val goals_limit: int ref
    11   val show_hyps: bool ref
    12   val show_tags: bool ref
    13   val show_consts: bool ref
    14 end;
    15 
    16 signature DISPLAY =
    17 sig
    18   include BASIC_DISPLAY
    19   val pretty_flexpair: Pretty.pp -> term * term -> Pretty.T
    20   val pretty_thm_aux: Pretty.pp -> bool -> bool -> term list -> thm -> Pretty.T
    21   val pretty_thm: thm -> Pretty.T
    22   val string_of_thm: thm -> string
    23   val pretty_thms: thm list -> Pretty.T
    24   val pretty_thm_sg: theory -> thm -> Pretty.T
    25   val pretty_thms_sg: theory -> thm list -> Pretty.T
    26   val print_thm: thm -> unit
    27   val print_thms: thm list -> unit
    28   val prth: thm -> thm
    29   val prthq: thm Seq.seq -> thm Seq.seq
    30   val prths: thm list -> thm list
    31   val pretty_ctyp: ctyp -> Pretty.T
    32   val string_of_ctyp: ctyp -> string
    33   val print_ctyp: ctyp -> unit
    34   val pretty_cterm: cterm -> Pretty.T
    35   val string_of_cterm: cterm -> string
    36   val print_cterm: cterm -> unit
    37   val print_syntax: theory -> unit
    38   val pretty_full_theory: bool -> theory -> Pretty.T list
    39   val pretty_goals_aux: Pretty.pp -> Markup.T -> bool * bool -> int -> thm -> Pretty.T list
    40   val pretty_goals: int -> thm -> Pretty.T list
    41   val print_goals: int -> thm -> unit
    42 end;
    43 
    44 structure Display: DISPLAY =
    45 struct
    46 
    47 
    48 (** print thm **)
    49 
    50 val goals_limit = ref 10;       (*max number of goals to print*)
    51 val show_hyps = ref false;      (*false: print meta-hypotheses as dots*)
    52 val show_tags = ref false;      (*false: suppress tags*)
    53 
    54 fun pretty_tag (name, arg) = Pretty.strs [name, quote arg];
    55 val pretty_tags = Pretty.list "[" "]" o map pretty_tag;
    56 
    57 fun pretty_flexpair pp (t, u) = Pretty.block
    58   [Pretty.term pp t, Pretty.str " =?=", Pretty.brk 1, Pretty.term pp u];
    59 
    60 fun pretty_thm_aux pp quote show_hyps' asms raw_th =
    61   let
    62     val th = Thm.strip_shyps raw_th;
    63     val {hyps, tpairs, prop, ...} = Thm.rep_thm th;
    64     val xshyps = Thm.extra_shyps th;
    65     val tags = Thm.get_tags th;
    66 
    67     val q = if quote then Pretty.quote else I;
    68     val prt_term = q o Pretty.term pp;
    69 
    70     val hyps' = if ! show_hyps then hyps else subtract (op aconv) asms hyps;
    71 (* FIXME
    72     val ora' = Thm.oracle_of th andalso (! show_hyps orelse not (! quick_and_dirty)); *)
    73     val ora' = false;
    74 
    75     val hlen = length xshyps + length hyps' + length tpairs;
    76     val hsymbs =
    77       if hlen = 0 andalso not ora' then []
    78       else if ! show_hyps orelse show_hyps' then
    79         [Pretty.brk 2, Pretty.list "[" "]"
    80           (map (q o pretty_flexpair pp) tpairs @ map prt_term hyps' @
    81            map (Pretty.sort pp) xshyps @
    82             (if ora' then [Pretty.str "!"] else []))]
    83       else [Pretty.brk 2, Pretty.str ("[" ^ implode (replicate hlen ".") ^
    84         (if ora' then "!" else "") ^ "]")];
    85     val tsymbs =
    86       if null tags orelse not (! show_tags) then []
    87       else [Pretty.brk 1, pretty_tags tags];
    88   in Pretty.block (prt_term prop :: (hsymbs @ tsymbs)) end;
    89 
    90 fun pretty_thm th =
    91   pretty_thm_aux (Syntax.pp_global (Thm.theory_of_thm th)) true false [] th;
    92 
    93 val string_of_thm = Pretty.string_of o pretty_thm;
    94 
    95 fun pretty_thms [th] = pretty_thm th
    96   | pretty_thms ths = Pretty.block (Pretty.fbreaks (map pretty_thm ths));
    97 
    98 val pretty_thm_sg = pretty_thm oo Thm.transfer;
    99 val pretty_thms_sg = pretty_thms oo (map o Thm.transfer);
   100 
   101 
   102 (* top-level commands for printing theorems *)
   103 
   104 val print_thm = Pretty.writeln o pretty_thm;
   105 val print_thms = Pretty.writeln o pretty_thms;
   106 
   107 fun prth th = (print_thm th; th);
   108 fun prthq thq = (Seq.print (K print_thm) 100000 thq; thq);
   109 fun prths ths = (prthq (Seq.of_list ths); ths);
   110 
   111 
   112 (* other printing commands *)
   113 
   114 fun pretty_ctyp cT = Syntax.pretty_typ_global (Thm.theory_of_ctyp cT) (Thm.typ_of cT);
   115 fun string_of_ctyp cT = Syntax.string_of_typ_global (Thm.theory_of_ctyp cT) (Thm.typ_of cT);
   116 val print_ctyp = writeln o string_of_ctyp;
   117 
   118 fun pretty_cterm ct = Syntax.pretty_term_global (Thm.theory_of_cterm ct) (Thm.term_of ct);
   119 fun string_of_cterm ct = Syntax.string_of_term_global (Thm.theory_of_cterm ct) (Thm.term_of ct);
   120 val print_cterm = writeln o string_of_cterm;
   121 
   122 
   123 
   124 (** print theory **)
   125 
   126 val print_syntax = Syntax.print_syntax o Sign.syn_of;
   127 
   128 
   129 (* pretty_full_theory *)
   130 
   131 fun pretty_full_theory verbose thy =
   132   let
   133     val ctxt = ProofContext.init thy;
   134 
   135     fun prt_cls c = Syntax.pretty_sort ctxt [c];
   136     fun prt_sort S = Syntax.pretty_sort ctxt S;
   137     fun prt_arity t (c, (_, Ss)) = Syntax.pretty_arity ctxt (t, Ss, [c]);
   138     fun prt_typ ty = Pretty.quote (Syntax.pretty_typ ctxt ty);
   139     val prt_typ_no_tvars = prt_typ o Logic.unvarifyT;
   140     fun prt_term t = Pretty.quote (Syntax.pretty_term ctxt t);
   141     val prt_term_no_vars = prt_term o Logic.unvarify;
   142     fun prt_const (c, ty) = [Pretty.str c, Pretty.str " ::", Pretty.brk 1, prt_typ_no_tvars ty];
   143     val prt_const' = Defs.pretty_const (Syntax.pp ctxt);
   144 
   145     fun pretty_classrel (c, []) = prt_cls c
   146       | pretty_classrel (c, cs) = Pretty.block
   147           (prt_cls c :: Pretty.str " <" :: Pretty.brk 1 ::
   148             Pretty.commas (map prt_cls cs));
   149 
   150     fun pretty_default S = Pretty.block
   151       [Pretty.str "default sort:", Pretty.brk 1, prt_sort S];
   152 
   153     val tfrees = map (fn v => TFree (v, []));
   154     fun pretty_type syn (t, ((Type.LogicalType n, _), _)) =
   155           if syn then NONE
   156           else SOME (prt_typ (Type (t, tfrees (Name.invents Name.context Name.aT n))))
   157       | pretty_type syn (t, ((Type.Abbreviation (vs, U, syn'), _), _)) =
   158           if syn <> syn' then NONE
   159           else SOME (Pretty.block
   160             [prt_typ (Type (t, tfrees vs)), Pretty.str " =", Pretty.brk 1, prt_typ U])
   161       | pretty_type syn (t, ((Type.Nonterminal, _), _)) =
   162           if not syn then NONE
   163           else SOME (prt_typ (Type (t, [])));
   164 
   165     val pretty_arities = maps (fn (t, ars) => map (prt_arity t) ars);
   166 
   167     fun pretty_abbrev (c, (ty, t)) = Pretty.block
   168       (prt_const (c, ty) @ [Pretty.str " ==", Pretty.brk 1, prt_term_no_vars t]);
   169 
   170     fun pretty_axm (a, t) = Pretty.block [Pretty.str (a ^ ":"), Pretty.brk 1, prt_term_no_vars t];
   171 
   172     fun pretty_finals reds = Pretty.block
   173       (Pretty.str "final:" :: Pretty.brk 1 :: Pretty.commas (map (prt_const' o fst) reds));
   174 
   175     fun pretty_reduct (lhs, rhs) = Pretty.block
   176       ([prt_const' lhs, Pretty.str "  ->", Pretty.brk 2] @
   177         Pretty.commas (map prt_const' (sort_wrt #1 rhs)));
   178 
   179     fun pretty_restrict (const, name) =
   180       Pretty.block ([prt_const' const, Pretty.brk 2, Pretty.str ("(from " ^ quote name ^ ")")]);
   181 
   182     val axioms = (Theory.axiom_space thy, Theory.axiom_table thy);
   183     val defs = Theory.defs_of thy;
   184     val {restricts, reducts} = Defs.dest defs;
   185     val {naming, syn = _, tsig, consts} = Sign.rep_sg thy;
   186     val {constants, constraints} = Consts.dest consts;
   187     val extern_const = NameSpace.extern (#1 constants);
   188     val {classes, default, types, ...} = Type.rep_tsig tsig;
   189     val (class_space, class_algebra) = classes;
   190     val {classes, arities} = Sorts.rep_algebra class_algebra;
   191 
   192     val clsses = NameSpace.dest_table (class_space, Symtab.make (Graph.dest classes));
   193     val tdecls = NameSpace.dest_table types;
   194     val arties = NameSpace.dest_table (Sign.type_space thy, arities);
   195 
   196     fun prune_const c = not verbose andalso
   197       member (op =) (Consts.the_tags consts c) Markup.property_internal;
   198     val cnsts = NameSpace.extern_table (#1 constants,
   199       Symtab.make (filter_out (prune_const o fst) (Symtab.dest (#2 constants))));
   200 
   201     val log_cnsts = map_filter (fn (c, (ty, NONE)) => SOME (c, ty) | _ => NONE) cnsts;
   202     val abbrevs = map_filter (fn (c, (ty, SOME t)) => SOME (c, (ty, t)) | _ => NONE) cnsts;
   203     val cnstrs = NameSpace.extern_table constraints;
   204 
   205     val axms = NameSpace.extern_table axioms;
   206 
   207     val (reds0, (reds1, reds2)) = filter_out (prune_const o fst o fst) reducts
   208       |> map (fn (lhs, rhs) =>
   209         (apfst extern_const lhs, map (apfst extern_const) (filter_out (prune_const o fst) rhs)))
   210       |> sort_wrt (#1 o #1)
   211       |> List.partition (null o #2)
   212       ||> List.partition (Defs.plain_args o #2 o #1);
   213     val rests = restricts |> map (apfst (apfst extern_const)) |> sort_wrt (#1 o #1);
   214   in
   215     [Pretty.strs ("names:" :: Context.display_names thy)] @
   216     [Pretty.strs ["name prefix:", NameSpace.path_of naming],
   217       Pretty.big_list "classes:" (map pretty_classrel clsses),
   218       pretty_default default,
   219       Pretty.big_list "syntactic types:" (map_filter (pretty_type true) tdecls),
   220       Pretty.big_list "logical types:" (map_filter (pretty_type false) tdecls),
   221       Pretty.big_list "type arities:" (pretty_arities arties),
   222       Pretty.big_list "logical consts:" (map (Pretty.block o prt_const) log_cnsts),
   223       Pretty.big_list "abbreviations:" (map pretty_abbrev abbrevs),
   224       Pretty.big_list "constraints:" (map (Pretty.block o prt_const) cnstrs),
   225       Pretty.big_list "axioms:" (map pretty_axm axms),
   226       Pretty.strs ("oracles:" :: Thm.extern_oracles thy),
   227       Pretty.big_list "definitions:"
   228         [pretty_finals reds0,
   229          Pretty.big_list "non-overloaded:" (map pretty_reduct reds1),
   230          Pretty.big_list "overloaded:" (map pretty_reduct reds2),
   231          Pretty.big_list "pattern restrictions:" (map pretty_restrict rests)]]
   232   end;
   233 
   234 
   235 
   236 (** print_goals **)
   237 
   238 (* print_goals etc. *)
   239 
   240 val show_consts = ref false;  (*true: show consts with types in proof state output*)
   241 
   242 
   243 (*print thm A1,...,An/B in "goal style" -- premises as numbered subgoals*)
   244 
   245 local
   246 
   247 fun ins_entry (x, y) =
   248   AList.default (op =) (x, []) #>
   249   AList.map_entry (op =) x (insert (op =) y);
   250 
   251 val add_consts = Term.fold_aterms
   252   (fn Const (c, T) => ins_entry (T, (c, T))
   253     | _ => I);
   254 
   255 val add_vars = Term.fold_aterms
   256   (fn Free (x, T) => ins_entry (T, (x, ~1))
   257     | Var (xi, T) => ins_entry (T, xi)
   258     | _ => I);
   259 
   260 val add_varsT = Term.fold_atyps
   261   (fn TFree (x, S) => ins_entry (S, (x, ~1))
   262     | TVar (xi, S) => ins_entry (S, xi)
   263     | _ => I);
   264 
   265 fun sort_idxs vs = map (apsnd (sort (prod_ord string_ord int_ord))) vs;
   266 fun sort_cnsts cs = map (apsnd (sort_wrt fst)) cs;
   267 
   268 fun consts_of t = sort_cnsts (add_consts t []);
   269 fun vars_of t = sort_idxs (add_vars t []);
   270 fun varsT_of t = rev (sort_idxs (Term.fold_types add_varsT t []));
   271 
   272 in
   273 
   274 fun pretty_goals_aux pp markup (msg, main) maxgoals state =
   275   let
   276     fun prt_atoms prt prtT (X, xs) = Pretty.block
   277       [Pretty.block (Pretty.commas (map prt xs)), Pretty.str " ::",
   278         Pretty.brk 1, prtT X];
   279 
   280     fun prt_var (x, ~1) = Pretty.term pp (Syntax.free x)
   281       | prt_var xi = Pretty.term pp (Syntax.var xi);
   282 
   283     fun prt_varT (x, ~1) = Pretty.typ pp (TFree (x, []))
   284       | prt_varT xi = Pretty.typ pp (TVar (xi, []));
   285 
   286     val prt_consts = prt_atoms (Pretty.term pp o Const) (Pretty.typ pp);
   287     val prt_vars = prt_atoms prt_var (Pretty.typ pp);
   288     val prt_varsT = prt_atoms prt_varT (Pretty.sort pp);
   289 
   290 
   291     fun pretty_list _ _ [] = []
   292       | pretty_list name prt lst = [Pretty.big_list name (map prt lst)];
   293 
   294     fun pretty_subgoal (n, A) = Pretty.markup markup
   295       [Pretty.str (" " ^ string_of_int n ^ ". "), Pretty.term pp A];
   296     fun pretty_subgoals As = map pretty_subgoal (1 upto length As ~~ As);
   297 
   298     val pretty_ffpairs = pretty_list "flex-flex pairs:" (pretty_flexpair pp);
   299 
   300     val pretty_consts = pretty_list "constants:" prt_consts o consts_of;
   301     val pretty_vars = pretty_list "variables:" prt_vars o vars_of;
   302     val pretty_varsT = pretty_list "type variables:" prt_varsT o varsT_of;
   303 
   304 
   305     val {prop, tpairs, ...} = Thm.rep_thm state;
   306     val (As, B) = Logic.strip_horn prop;
   307     val ngoals = length As;
   308 
   309     fun pretty_gs (types, sorts) =
   310       (if main then [Pretty.term pp B] else []) @
   311        (if ngoals = 0 then [Pretty.str "No subgoals!"]
   312         else if ngoals > maxgoals then
   313           pretty_subgoals (Library.take (maxgoals, As)) @
   314           (if msg then [Pretty.str ("A total of " ^ string_of_int ngoals ^ " subgoals...")]
   315            else [])
   316         else pretty_subgoals As) @
   317       pretty_ffpairs tpairs @
   318       (if ! show_consts then pretty_consts prop else []) @
   319       (if types then pretty_vars prop else []) @
   320       (if sorts then pretty_varsT prop else []);
   321   in
   322     setmp show_no_free_types true
   323       (setmp show_types (! show_types orelse ! show_sorts orelse ! show_all_types)
   324         (setmp show_sorts false pretty_gs))
   325    (! show_types orelse ! show_sorts orelse ! show_all_types, ! show_sorts)
   326   end;
   327 
   328 fun pretty_goals n th =
   329   pretty_goals_aux (Syntax.pp_global (Thm.theory_of_thm th)) Markup.none (true, true) n th;
   330 
   331 val print_goals = (Pretty.writeln o Pretty.chunks) oo pretty_goals;
   332 
   333 end;
   334 
   335 
   336 end;
   337 
   338 structure BasicDisplay: BASIC_DISPLAY = Display;
   339 open BasicDisplay;