src/HOL/Nitpick.thy
author blanchet
Mon Feb 21 10:44:19 2011 +0100 (2011-02-21)
changeset 41792 ff3cb0c418b7
parent 41052 3db267a01c1d
child 41797 0c6093d596d6
permissions -rw-r--r--
renamed "nitpick\_def" to "nitpick_unfold" to reflect its new semantics
     1 (*  Title:      HOL/Nitpick.thy
     2     Author:     Jasmin Blanchette, TU Muenchen
     3     Copyright   2008, 2009, 2010
     4 
     5 Nitpick: Yet another counterexample generator for Isabelle/HOL.
     6 *)
     7 
     8 header {* Nitpick: Yet Another Counterexample Generator for Isabelle/HOL *}
     9 
    10 theory Nitpick
    11 imports Map Quotient SAT Record
    12 uses ("Tools/Nitpick/kodkod.ML")
    13      ("Tools/Nitpick/kodkod_sat.ML")
    14      ("Tools/Nitpick/nitpick_util.ML")
    15      ("Tools/Nitpick/nitpick_hol.ML")
    16      ("Tools/Nitpick/nitpick_preproc.ML")
    17      ("Tools/Nitpick/nitpick_mono.ML")
    18      ("Tools/Nitpick/nitpick_scope.ML")
    19      ("Tools/Nitpick/nitpick_peephole.ML")
    20      ("Tools/Nitpick/nitpick_rep.ML")
    21      ("Tools/Nitpick/nitpick_nut.ML")
    22      ("Tools/Nitpick/nitpick_kodkod.ML")
    23      ("Tools/Nitpick/nitpick_model.ML")
    24      ("Tools/Nitpick/nitpick.ML")
    25      ("Tools/Nitpick/nitpick_isar.ML")
    26      ("Tools/Nitpick/nitpick_tests.ML")
    27 begin
    28 
    29 typedecl bisim_iterator
    30 
    31 axiomatization unknown :: 'a
    32            and is_unknown :: "'a \<Rightarrow> bool"
    33            and bisim :: "bisim_iterator \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
    34            and bisim_iterator_max :: bisim_iterator
    35            and Quot :: "'a \<Rightarrow> 'b"
    36            and safe_The :: "('a \<Rightarrow> bool) \<Rightarrow> 'a"
    37 
    38 datatype ('a, 'b) fun_box = FunBox "('a \<Rightarrow> 'b)"
    39 datatype ('a, 'b) pair_box = PairBox 'a 'b
    40 
    41 typedecl unsigned_bit
    42 typedecl signed_bit
    43 
    44 datatype 'a word = Word "('a set)"
    45 
    46 text {*
    47 Alternative definitions.
    48 *}
    49 
    50 lemma Ex1_def [nitpick_unfold, no_atp]:
    51 "Ex1 P \<equiv> \<exists>x. P = {x}"
    52 apply (rule eq_reflection)
    53 apply (simp add: Ex1_def set_eq_iff)
    54 apply (rule iffI)
    55  apply (erule exE)
    56  apply (erule conjE)
    57  apply (rule_tac x = x in exI)
    58  apply (rule allI)
    59  apply (rename_tac y)
    60  apply (erule_tac x = y in allE)
    61 by (auto simp: mem_def)
    62 
    63 lemma rtrancl_def [nitpick_unfold, no_atp]: "r\<^sup>* \<equiv> (r\<^sup>+)\<^sup>="
    64 by simp
    65 
    66 lemma rtranclp_def [nitpick_unfold, no_atp]:
    67 "rtranclp r a b \<equiv> (a = b \<or> tranclp r a b)"
    68 by (rule eq_reflection) (auto dest: rtranclpD)
    69 
    70 lemma tranclp_def [nitpick_unfold, no_atp]:
    71 "tranclp r a b \<equiv> trancl (split r) (a, b)"
    72 by (simp add: trancl_def Collect_def mem_def)
    73 
    74 definition prod :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set" where
    75 "prod A B = {(a, b). a \<in> A \<and> b \<in> B}"
    76 
    77 definition refl' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> bool" where
    78 "refl' r \<equiv> \<forall>x. (x, x) \<in> r"
    79 
    80 definition wf' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> bool" where
    81 "wf' r \<equiv> acyclic r \<and> (finite r \<or> unknown)"
    82 
    83 axiomatization wf_wfrec :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b"
    84 
    85 definition wf_wfrec' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b" where
    86 [nitpick_simp]: "wf_wfrec' R F x = F (Recdef.cut (wf_wfrec R F) R x) x"
    87 
    88 definition wfrec' ::  "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b" where
    89 "wfrec' R F x \<equiv> if wf R then wf_wfrec' R F x
    90                 else THE y. wfrec_rel R (%f x. F (Recdef.cut f R x) x) x y"
    91 
    92 definition card' :: "('a \<Rightarrow> bool) \<Rightarrow> nat" where
    93 "card' A \<equiv> if finite A then length (SOME xs. set xs = A \<and> distinct xs) else 0"
    94 
    95 definition setsum' :: "('a \<Rightarrow> 'b\<Colon>comm_monoid_add) \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'b" where
    96 "setsum' f A \<equiv> if finite A then listsum (map f (SOME xs. set xs = A \<and> distinct xs)) else 0"
    97 
    98 inductive fold_graph' :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'b \<Rightarrow> bool" where
    99 "fold_graph' f z {} z" |
   100 "\<lbrakk>x \<in> A; fold_graph' f z (A - {x}) y\<rbrakk> \<Longrightarrow> fold_graph' f z A (f x y)"
   101 
   102 text {*
   103 The following lemmas are not strictly necessary but they help the
   104 \textit{special\_level} optimization.
   105 *}
   106 
   107 lemma The_psimp [nitpick_psimp, no_atp]:
   108 "P = {x} \<Longrightarrow> The P = x"
   109 by (subgoal_tac "{x} = (\<lambda>y. y = x)") (auto simp: mem_def)
   110 
   111 lemma Eps_psimp [nitpick_psimp, no_atp]:
   112 "\<lbrakk>P x; \<not> P y; Eps P = y\<rbrakk> \<Longrightarrow> Eps P = x"
   113 apply (case_tac "P (Eps P)")
   114  apply auto
   115 apply (erule contrapos_np)
   116 by (rule someI)
   117 
   118 lemma unit_case_def [nitpick_unfold, no_atp]:
   119 "unit_case x u \<equiv> x"
   120 apply (subgoal_tac "u = ()")
   121  apply (simp only: unit.cases)
   122 by simp
   123 
   124 declare unit.cases [nitpick_simp del]
   125 
   126 lemma nat_case_def [nitpick_unfold, no_atp]:
   127 "nat_case x f n \<equiv> if n = 0 then x else f (n - 1)"
   128 apply (rule eq_reflection)
   129 by (case_tac n) auto
   130 
   131 declare nat.cases [nitpick_simp del]
   132 
   133 lemma list_size_simp [nitpick_simp, no_atp]:
   134 "list_size f xs = (if xs = [] then 0
   135                    else Suc (f (hd xs) + list_size f (tl xs)))"
   136 "size xs = (if xs = [] then 0 else Suc (size (tl xs)))"
   137 by (case_tac xs) auto
   138 
   139 text {*
   140 Auxiliary definitions used to provide an alternative representation for
   141 @{text rat} and @{text real}.
   142 *}
   143 
   144 function nat_gcd :: "nat \<Rightarrow> nat \<Rightarrow> nat" where
   145 [simp del]: "nat_gcd x y = (if y = 0 then x else nat_gcd y (x mod y))"
   146 by auto
   147 termination
   148 apply (relation "measure (\<lambda>(x, y). x + y + (if y > x then 1 else 0))")
   149  apply auto
   150  apply (metis mod_less_divisor xt1(9))
   151 by (metis mod_mod_trivial mod_self nat_neq_iff xt1(10))
   152 
   153 definition nat_lcm :: "nat \<Rightarrow> nat \<Rightarrow> nat" where
   154 "nat_lcm x y = x * y div (nat_gcd x y)"
   155 
   156 definition int_gcd :: "int \<Rightarrow> int \<Rightarrow> int" where
   157 "int_gcd x y = int (nat_gcd (nat (abs x)) (nat (abs y)))"
   158 
   159 definition int_lcm :: "int \<Rightarrow> int \<Rightarrow> int" where
   160 "int_lcm x y = int (nat_lcm (nat (abs x)) (nat (abs y)))"
   161 
   162 definition Frac :: "int \<times> int \<Rightarrow> bool" where
   163 "Frac \<equiv> \<lambda>(a, b). b > 0 \<and> int_gcd a b = 1"
   164 
   165 axiomatization Abs_Frac :: "int \<times> int \<Rightarrow> 'a"
   166            and Rep_Frac :: "'a \<Rightarrow> int \<times> int"
   167 
   168 definition zero_frac :: 'a where
   169 "zero_frac \<equiv> Abs_Frac (0, 1)"
   170 
   171 definition one_frac :: 'a where
   172 "one_frac \<equiv> Abs_Frac (1, 1)"
   173 
   174 definition num :: "'a \<Rightarrow> int" where
   175 "num \<equiv> fst o Rep_Frac"
   176 
   177 definition denom :: "'a \<Rightarrow> int" where
   178 "denom \<equiv> snd o Rep_Frac"
   179 
   180 function norm_frac :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
   181 [simp del]: "norm_frac a b = (if b < 0 then norm_frac (- a) (- b)
   182                               else if a = 0 \<or> b = 0 then (0, 1)
   183                               else let c = int_gcd a b in (a div c, b div c))"
   184 by pat_completeness auto
   185 termination by (relation "measure (\<lambda>(_, b). if b < 0 then 1 else 0)") auto
   186 
   187 definition frac :: "int \<Rightarrow> int \<Rightarrow> 'a" where
   188 "frac a b \<equiv> Abs_Frac (norm_frac a b)"
   189 
   190 definition plus_frac :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   191 [nitpick_simp]:
   192 "plus_frac q r = (let d = int_lcm (denom q) (denom r) in
   193                     frac (num q * (d div denom q) + num r * (d div denom r)) d)"
   194 
   195 definition times_frac :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   196 [nitpick_simp]:
   197 "times_frac q r = frac (num q * num r) (denom q * denom r)"
   198 
   199 definition uminus_frac :: "'a \<Rightarrow> 'a" where
   200 "uminus_frac q \<equiv> Abs_Frac (- num q, denom q)"
   201 
   202 definition number_of_frac :: "int \<Rightarrow> 'a" where
   203 "number_of_frac n \<equiv> Abs_Frac (n, 1)"
   204 
   205 definition inverse_frac :: "'a \<Rightarrow> 'a" where
   206 "inverse_frac q \<equiv> frac (denom q) (num q)"
   207 
   208 definition less_frac :: "'a \<Rightarrow> 'a \<Rightarrow> bool" where
   209 [nitpick_simp]:
   210 "less_frac q r \<longleftrightarrow> num (plus_frac q (uminus_frac r)) < 0"
   211 
   212 definition less_eq_frac :: "'a \<Rightarrow> 'a \<Rightarrow> bool" where
   213 [nitpick_simp]:
   214 "less_eq_frac q r \<longleftrightarrow> num (plus_frac q (uminus_frac r)) \<le> 0"
   215 
   216 definition of_frac :: "'a \<Rightarrow> 'b\<Colon>{inverse,ring_1}" where
   217 "of_frac q \<equiv> of_int (num q) / of_int (denom q)"
   218 
   219 use "Tools/Nitpick/kodkod.ML"
   220 use "Tools/Nitpick/kodkod_sat.ML"
   221 use "Tools/Nitpick/nitpick_util.ML"
   222 use "Tools/Nitpick/nitpick_hol.ML"
   223 use "Tools/Nitpick/nitpick_mono.ML"
   224 use "Tools/Nitpick/nitpick_preproc.ML"
   225 use "Tools/Nitpick/nitpick_scope.ML"
   226 use "Tools/Nitpick/nitpick_peephole.ML"
   227 use "Tools/Nitpick/nitpick_rep.ML"
   228 use "Tools/Nitpick/nitpick_nut.ML"
   229 use "Tools/Nitpick/nitpick_kodkod.ML"
   230 use "Tools/Nitpick/nitpick_model.ML"
   231 use "Tools/Nitpick/nitpick.ML"
   232 use "Tools/Nitpick/nitpick_isar.ML"
   233 use "Tools/Nitpick/nitpick_tests.ML"
   234 
   235 setup {* Nitpick_Isar.setup *}
   236 
   237 hide_const (open) unknown is_unknown bisim bisim_iterator_max Quot safe_The
   238     FunBox PairBox Word prod refl' wf' wf_wfrec wf_wfrec' wfrec' card' setsum'
   239     fold_graph' nat_gcd nat_lcm int_gcd int_lcm Frac Abs_Frac Rep_Frac zero_frac
   240     one_frac num denom norm_frac frac plus_frac times_frac uminus_frac
   241     number_of_frac inverse_frac less_frac less_eq_frac of_frac
   242 hide_type (open) bisim_iterator fun_box pair_box unsigned_bit signed_bit word
   243 hide_fact (open) If_def Ex1_def rtrancl_def rtranclp_def tranclp_def prod_def
   244     refl'_def wf'_def wf_wfrec'_def wfrec'_def card'_def setsum'_def
   245     fold_graph'_def The_psimp Eps_psimp unit_case_def nat_case_def
   246     list_size_simp nat_gcd_def nat_lcm_def int_gcd_def int_lcm_def Frac_def
   247     zero_frac_def one_frac_def num_def denom_def norm_frac_def frac_def
   248     plus_frac_def times_frac_def uminus_frac_def number_of_frac_def
   249     inverse_frac_def less_frac_def less_eq_frac_def of_frac_def
   250 
   251 end