src/HOL/Product_Type.thy
author blanchet
Mon Feb 21 10:44:19 2011 +0100 (2011-02-21)
changeset 41792 ff3cb0c418b7
parent 41505 6d19301074cf
child 42059 83f3dc509068
permissions -rw-r--r--
renamed "nitpick\_def" to "nitpick_unfold" to reflect its new semantics
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 uses
    11   ("Tools/split_rule.ML")
    12   ("Tools/inductive_codegen.ML")
    13   ("Tools/inductive_set.ML")
    14 begin
    15 
    16 subsection {* @{typ bool} is a datatype *}
    17 
    18 rep_datatype True False by (auto intro: bool_induct)
    19 
    20 declare case_split [cases type: bool]
    21   -- "prefer plain propositional version"
    22 
    23 lemma
    24   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    25     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    26     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P" 
    27     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    28     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    29   by (simp_all add: equal)
    30 
    31 code_const "HOL.equal \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    32   (Haskell infix 4 "==")
    33 
    34 code_instance bool :: equal
    35   (Haskell -)
    36 
    37 
    38 subsection {* The @{text unit} type *}
    39 
    40 typedef (open) unit = "{True}"
    41 proof
    42   show "True : ?unit" ..
    43 qed
    44 
    45 definition
    46   Unity :: unit    ("'(')")
    47 where
    48   "() = Abs_unit True"
    49 
    50 lemma unit_eq [no_atp]: "u = ()"
    51   by (induct u) (simp add: Unity_def)
    52 
    53 text {*
    54   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    55   this rule directly --- it loops!
    56 *}
    57 
    58 ML {*
    59   val unit_eq_proc =
    60     let val unit_meta_eq = mk_meta_eq @{thm unit_eq} in
    61       Simplifier.simproc_global @{theory} "unit_eq" ["x::unit"]
    62       (fn _ => fn _ => fn t => if HOLogic.is_unit t then NONE else SOME unit_meta_eq)
    63     end;
    64 
    65   Addsimprocs [unit_eq_proc];
    66 *}
    67 
    68 rep_datatype "()" by simp
    69 
    70 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    71   by simp
    72 
    73 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    74   by (rule triv_forall_equality)
    75 
    76 text {*
    77   This rewrite counters the effect of @{text unit_eq_proc} on @{term
    78   [source] "%u::unit. f u"}, replacing it by @{term [source]
    79   f} rather than by @{term [source] "%u. f ()"}.
    80 *}
    81 
    82 lemma unit_abs_eta_conv [simp,no_atp]: "(%u::unit. f ()) = f"
    83   by (rule ext) simp
    84 
    85 instantiation unit :: default
    86 begin
    87 
    88 definition "default = ()"
    89 
    90 instance ..
    91 
    92 end
    93 
    94 lemma [code]:
    95   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
    96 
    97 code_type unit
    98   (SML "unit")
    99   (OCaml "unit")
   100   (Haskell "()")
   101   (Scala "Unit")
   102 
   103 code_const Unity
   104   (SML "()")
   105   (OCaml "()")
   106   (Haskell "()")
   107   (Scala "()")
   108 
   109 code_instance unit :: equal
   110   (Haskell -)
   111 
   112 code_const "HOL.equal \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   113   (Haskell infix 4 "==")
   114 
   115 code_reserved SML
   116   unit
   117 
   118 code_reserved OCaml
   119   unit
   120 
   121 code_reserved Scala
   122   Unit
   123 
   124 
   125 subsection {* The product type *}
   126 
   127 subsubsection {* Type definition *}
   128 
   129 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   130   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   131 
   132 typedef ('a, 'b) prod (infixr "*" 20)
   133   = "{f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   134 proof
   135   fix a b show "Pair_Rep a b \<in> ?prod"
   136     by rule+
   137 qed
   138 
   139 type_notation (xsymbols)
   140   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   141 type_notation (HTML output)
   142   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   143 
   144 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   145   "Pair a b = Abs_prod (Pair_Rep a b)"
   146 
   147 rep_datatype Pair proof -
   148   fix P :: "'a \<times> 'b \<Rightarrow> bool" and p
   149   assume "\<And>a b. P (Pair a b)"
   150   then show "P p" by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   151 next
   152   fix a c :: 'a and b d :: 'b
   153   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   154     by (auto simp add: Pair_Rep_def fun_eq_iff)
   155   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   156     by (auto simp add: prod_def)
   157   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   158     by (simp add: Pair_def Abs_prod_inject)
   159 qed
   160 
   161 declare prod.simps(2) [nitpick_simp del]
   162 
   163 declare prod.weak_case_cong [cong del]
   164 
   165 
   166 subsubsection {* Tuple syntax *}
   167 
   168 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   169   "split \<equiv> prod_case"
   170 
   171 text {*
   172   Patterns -- extends pre-defined type @{typ pttrn} used in
   173   abstractions.
   174 *}
   175 
   176 nonterminal tuple_args and patterns
   177 
   178 syntax
   179   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   180   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   181   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   182   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   183   ""            :: "pttrn => patterns"                  ("_")
   184   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   185 
   186 translations
   187   "(x, y)" == "CONST Pair x y"
   188   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   189   "%(x, y, zs). b" == "CONST prod_case (%x (y, zs). b)"
   190   "%(x, y). b" == "CONST prod_case (%x y. b)"
   191   "_abs (CONST Pair x y) t" => "%(x, y). t"
   192   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   193      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   194 
   195 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   196   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   197 print_translation {*
   198 let
   199   fun split_tr' [Abs (x, T, t as (Abs abs))] =
   200         (* split (%x y. t) => %(x,y) t *)
   201         let
   202           val (y, t') = atomic_abs_tr' abs;
   203           val (x', t'') = atomic_abs_tr' (x, T, t');
   204         in
   205           Syntax.const @{syntax_const "_abs"} $
   206             (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   207         end
   208     | split_tr' [Abs (x, T, (s as Const (@{const_syntax prod_case}, _) $ t))] =
   209         (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   210         let
   211           val Const (@{syntax_const "_abs"}, _) $
   212             (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   213           val (x', t'') = atomic_abs_tr' (x, T, t');
   214         in
   215           Syntax.const @{syntax_const "_abs"} $
   216             (Syntax.const @{syntax_const "_pattern"} $ x' $
   217               (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   218         end
   219     | split_tr' [Const (@{const_syntax prod_case}, _) $ t] =
   220         (* split (split (%x y z. t)) => %((x, y), z). t *)
   221         split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   222     | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   223         (* split (%pttrn z. t) => %(pttrn,z). t *)
   224         let val (z, t) = atomic_abs_tr' abs in
   225           Syntax.const @{syntax_const "_abs"} $
   226             (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   227         end
   228     | split_tr' _ = raise Match;
   229 in [(@{const_syntax prod_case}, split_tr')] end
   230 *}
   231 
   232 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   233 typed_print_translation {*
   234 let
   235   fun split_guess_names_tr' _ T [Abs (x, _, Abs _)] = raise Match
   236     | split_guess_names_tr' _ T [Abs (x, xT, t)] =
   237         (case (head_of t) of
   238           Const (@{const_syntax prod_case}, _) => raise Match
   239         | _ =>
   240           let 
   241             val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   242             val (y, t') = atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   243             val (x', t'') = atomic_abs_tr' (x, xT, t');
   244           in
   245             Syntax.const @{syntax_const "_abs"} $
   246               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   247           end)
   248     | split_guess_names_tr' _ T [t] =
   249         (case head_of t of
   250           Const (@{const_syntax prod_case}, _) => raise Match
   251         | _ =>
   252           let
   253             val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   254             val (y, t') = atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   255             val (x', t'') = atomic_abs_tr' ("x", xT, t');
   256           in
   257             Syntax.const @{syntax_const "_abs"} $
   258               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   259           end)
   260     | split_guess_names_tr' _ _ _ = raise Match;
   261 in [(@{const_syntax prod_case}, split_guess_names_tr')] end
   262 *}
   263 
   264 
   265 subsubsection {* Code generator setup *}
   266 
   267 code_type prod
   268   (SML infix 2 "*")
   269   (OCaml infix 2 "*")
   270   (Haskell "!((_),/ (_))")
   271   (Scala "((_),/ (_))")
   272 
   273 code_const Pair
   274   (SML "!((_),/ (_))")
   275   (OCaml "!((_),/ (_))")
   276   (Haskell "!((_),/ (_))")
   277   (Scala "!((_),/ (_))")
   278 
   279 code_instance prod :: equal
   280   (Haskell -)
   281 
   282 code_const "HOL.equal \<Colon> 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   283   (Haskell infix 4 "==")
   284 
   285 types_code
   286   "prod"     ("(_ */ _)")
   287 attach (term_of) {*
   288 fun term_of_prod aF aT bF bT (x, y) = HOLogic.pair_const aT bT $ aF x $ bF y;
   289 *}
   290 attach (test) {*
   291 fun gen_prod aG aT bG bT i =
   292   let
   293     val (x, t) = aG i;
   294     val (y, u) = bG i
   295   in ((x, y), fn () => HOLogic.pair_const aT bT $ t () $ u ()) end;
   296 *}
   297 
   298 consts_code
   299   "Pair"    ("(_,/ _)")
   300 
   301 setup {*
   302 let
   303 
   304 fun strip_abs_split 0 t = ([], t)
   305   | strip_abs_split i (Abs (s, T, t)) =
   306       let
   307         val s' = Codegen.new_name t s;
   308         val v = Free (s', T)
   309       in apfst (cons v) (strip_abs_split (i-1) (subst_bound (v, t))) end
   310   | strip_abs_split i (u as Const (@{const_name prod_case}, _) $ t) =
   311       (case strip_abs_split (i+1) t of
   312         (v :: v' :: vs, u) => (HOLogic.mk_prod (v, v') :: vs, u)
   313       | _ => ([], u))
   314   | strip_abs_split i t =
   315       strip_abs_split i (Abs ("x", hd (binder_types (fastype_of t)), t $ Bound 0));
   316 
   317 fun let_codegen thy defs dep thyname brack t gr =
   318   (case strip_comb t of
   319     (t1 as Const (@{const_name Let}, _), t2 :: t3 :: ts) =>
   320     let
   321       fun dest_let (l as Const (@{const_name Let}, _) $ t $ u) =
   322           (case strip_abs_split 1 u of
   323              ([p], u') => apfst (cons (p, t)) (dest_let u')
   324            | _ => ([], l))
   325         | dest_let t = ([], t);
   326       fun mk_code (l, r) gr =
   327         let
   328           val (pl, gr1) = Codegen.invoke_codegen thy defs dep thyname false l gr;
   329           val (pr, gr2) = Codegen.invoke_codegen thy defs dep thyname false r gr1;
   330         in ((pl, pr), gr2) end
   331     in case dest_let (t1 $ t2 $ t3) of
   332         ([], _) => NONE
   333       | (ps, u) =>
   334           let
   335             val (qs, gr1) = fold_map mk_code ps gr;
   336             val (pu, gr2) = Codegen.invoke_codegen thy defs dep thyname false u gr1;
   337             val (pargs, gr3) = fold_map
   338               (Codegen.invoke_codegen thy defs dep thyname true) ts gr2
   339           in
   340             SOME (Codegen.mk_app brack
   341               (Pretty.blk (0, [Codegen.str "let ", Pretty.blk (0, flat
   342                   (separate [Codegen.str ";", Pretty.brk 1] (map (fn (pl, pr) =>
   343                     [Pretty.block [Codegen.str "val ", pl, Codegen.str " =",
   344                        Pretty.brk 1, pr]]) qs))),
   345                 Pretty.brk 1, Codegen.str "in ", pu,
   346                 Pretty.brk 1, Codegen.str "end"])) pargs, gr3)
   347           end
   348     end
   349   | _ => NONE);
   350 
   351 fun split_codegen thy defs dep thyname brack t gr = (case strip_comb t of
   352     (t1 as Const (@{const_name prod_case}, _), t2 :: ts) =>
   353       let
   354         val ([p], u) = strip_abs_split 1 (t1 $ t2);
   355         val (q, gr1) = Codegen.invoke_codegen thy defs dep thyname false p gr;
   356         val (pu, gr2) = Codegen.invoke_codegen thy defs dep thyname false u gr1;
   357         val (pargs, gr3) = fold_map
   358           (Codegen.invoke_codegen thy defs dep thyname true) ts gr2
   359       in
   360         SOME (Codegen.mk_app brack
   361           (Pretty.block [Codegen.str "(fn ", q, Codegen.str " =>",
   362             Pretty.brk 1, pu, Codegen.str ")"]) pargs, gr2)
   363       end
   364   | _ => NONE);
   365 
   366 in
   367 
   368   Codegen.add_codegen "let_codegen" let_codegen
   369   #> Codegen.add_codegen "split_codegen" split_codegen
   370 
   371 end
   372 *}
   373 
   374 
   375 subsubsection {* Fundamental operations and properties *}
   376 
   377 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   378   by (cases p) simp
   379 
   380 definition fst :: "'a \<times> 'b \<Rightarrow> 'a" where
   381   "fst p = (case p of (a, b) \<Rightarrow> a)"
   382 
   383 definition snd :: "'a \<times> 'b \<Rightarrow> 'b" where
   384   "snd p = (case p of (a, b) \<Rightarrow> b)"
   385 
   386 lemma fst_conv [simp, code]: "fst (a, b) = a"
   387   unfolding fst_def by simp
   388 
   389 lemma snd_conv [simp, code]: "snd (a, b) = b"
   390   unfolding snd_def by simp
   391 
   392 code_const fst and snd
   393   (Haskell "fst" and "snd")
   394 
   395 lemma prod_case_unfold [nitpick_unfold]: "prod_case = (%c p. c (fst p) (snd p))"
   396   by (simp add: fun_eq_iff split: prod.split)
   397 
   398 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   399   by simp
   400 
   401 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   402   by simp
   403 
   404 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   405   by (cases p) simp
   406 
   407 lemmas surjective_pairing = pair_collapse [symmetric]
   408 
   409 lemma Pair_fst_snd_eq: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   410   by (cases s, cases t) simp
   411 
   412 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   413   by (simp add: Pair_fst_snd_eq)
   414 
   415 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   416   by (fact prod.cases)
   417 
   418 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   419   by (rule split_conv [THEN iffD2])
   420 
   421 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   422   by (rule split_conv [THEN iffD1])
   423 
   424 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   425   by (simp add: fun_eq_iff split: prod.split)
   426 
   427 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   428   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   429   by (simp add: fun_eq_iff split: prod.split)
   430 
   431 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   432   by (cases x) simp
   433 
   434 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   435   by (cases p) simp
   436 
   437 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   438   by (simp add: prod_case_unfold)
   439 
   440 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   441   -- {* Prevents simplification of @{term c}: much faster *}
   442   by (fact prod.weak_case_cong)
   443 
   444 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   445   by (simp add: split_eta)
   446 
   447 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   448 proof
   449   fix a b
   450   assume "!!x. PROP P x"
   451   then show "PROP P (a, b)" .
   452 next
   453   fix x
   454   assume "!!a b. PROP P (a, b)"
   455   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   456 qed
   457 
   458 text {*
   459   The rule @{thm [source] split_paired_all} does not work with the
   460   Simplifier because it also affects premises in congrence rules,
   461   where this can lead to premises of the form @{text "!!a b. ... =
   462   ?P(a, b)"} which cannot be solved by reflexivity.
   463 *}
   464 
   465 lemmas split_tupled_all = split_paired_all unit_all_eq2
   466 
   467 ML {*
   468   (* replace parameters of product type by individual component parameters *)
   469   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   470   local (* filtering with exists_paired_all is an essential optimization *)
   471     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   472           can HOLogic.dest_prodT T orelse exists_paired_all t
   473       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   474       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   475       | exists_paired_all _ = false;
   476     val ss = HOL_basic_ss
   477       addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   478       addsimprocs [unit_eq_proc];
   479   in
   480     val split_all_tac = SUBGOAL (fn (t, i) =>
   481       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   482     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   483       if exists_paired_all t then full_simp_tac ss i else no_tac);
   484     fun split_all th =
   485    if exists_paired_all (Thm.prop_of th) then full_simplify ss th else th;
   486   end;
   487 *}
   488 
   489 declaration {* fn _ =>
   490   Classical.map_cs (fn cs => cs addSbefore ("split_all_tac", split_all_tac))
   491 *}
   492 
   493 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   494   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   495   by fast
   496 
   497 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   498   by fast
   499 
   500 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   501   -- {* Can't be added to simpset: loops! *}
   502   by (simp add: split_eta)
   503 
   504 text {*
   505   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   506   @{thm [source] split_eta} as a rewrite rule is not general enough,
   507   and using @{thm [source] cond_split_eta} directly would render some
   508   existing proofs very inefficient; similarly for @{text
   509   split_beta}.
   510 *}
   511 
   512 ML {*
   513 local
   514   val cond_split_eta_ss = HOL_basic_ss addsimps @{thms cond_split_eta};
   515   fun Pair_pat k 0 (Bound m) = (m = k)
   516     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   517         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   518     | Pair_pat _ _ _ = false;
   519   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   520     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   521     | no_args k i (Bound m) = m < k orelse m > k + i
   522     | no_args _ _ _ = true;
   523   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   524     | split_pat tp i (Const (@{const_name prod_case}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   525     | split_pat tp i _ = NONE;
   526   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   527         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   528         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   529 
   530   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   531     | beta_term_pat k i (t $ u) =
   532         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   533     | beta_term_pat k i t = no_args k i t;
   534   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   535     | eta_term_pat _ _ _ = false;
   536   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   537     | subst arg k i (t $ u) =
   538         if Pair_pat k i (t $ u) then incr_boundvars k arg
   539         else (subst arg k i t $ subst arg k i u)
   540     | subst arg k i t = t;
   541   fun beta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t) $ arg) =
   542         (case split_pat beta_term_pat 1 t of
   543           SOME (i, f) => SOME (metaeq ss s (subst arg 0 i f))
   544         | NONE => NONE)
   545     | beta_proc _ _ = NONE;
   546   fun eta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t)) =
   547         (case split_pat eta_term_pat 1 t of
   548           SOME (_, ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   549         | NONE => NONE)
   550     | eta_proc _ _ = NONE;
   551 in
   552   val split_beta_proc = Simplifier.simproc_global @{theory} "split_beta" ["split f z"] (K beta_proc);
   553   val split_eta_proc = Simplifier.simproc_global @{theory} "split_eta" ["split f"] (K eta_proc);
   554 end;
   555 
   556 Addsimprocs [split_beta_proc, split_eta_proc];
   557 *}
   558 
   559 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   560   by (subst surjective_pairing, rule split_conv)
   561 
   562 lemma split_split [no_atp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   563   -- {* For use with @{text split} and the Simplifier. *}
   564   by (insert surj_pair [of p], clarify, simp)
   565 
   566 text {*
   567   @{thm [source] split_split} could be declared as @{text "[split]"}
   568   done after the Splitter has been speeded up significantly;
   569   precompute the constants involved and don't do anything unless the
   570   current goal contains one of those constants.
   571 *}
   572 
   573 lemma split_split_asm [no_atp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   574 by (subst split_split, simp)
   575 
   576 text {*
   577   \medskip @{term split} used as a logical connective or set former.
   578 
   579   \medskip These rules are for use with @{text blast}; could instead
   580   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   581 
   582 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   583   apply (simp only: split_tupled_all)
   584   apply (simp (no_asm_simp))
   585   done
   586 
   587 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   588   apply (simp only: split_tupled_all)
   589   apply (simp (no_asm_simp))
   590   done
   591 
   592 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   593   by (induct p) auto
   594 
   595 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   596   by (induct p) auto
   597 
   598 lemma splitE2:
   599   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   600 proof -
   601   assume q: "Q (split P z)"
   602   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   603   show R
   604     apply (rule r surjective_pairing)+
   605     apply (rule split_beta [THEN subst], rule q)
   606     done
   607 qed
   608 
   609 lemma splitD': "split R (a,b) c ==> R a b c"
   610   by simp
   611 
   612 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   613   by simp
   614 
   615 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   616 by (simp only: split_tupled_all, simp)
   617 
   618 lemma mem_splitE:
   619   assumes major: "z \<in> split c p"
   620     and cases: "\<And>x y. p = (x, y) \<Longrightarrow> z \<in> c x y \<Longrightarrow> Q"
   621   shows Q
   622   by (rule major [unfolded prod_case_unfold] cases surjective_pairing)+
   623 
   624 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   625 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   626 
   627 ML {*
   628 local (* filtering with exists_p_split is an essential optimization *)
   629   fun exists_p_split (Const (@{const_name prod_case},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   630     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   631     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   632     | exists_p_split _ = false;
   633   val ss = HOL_basic_ss addsimps @{thms split_conv};
   634 in
   635 val split_conv_tac = SUBGOAL (fn (t, i) =>
   636     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   637 end;
   638 *}
   639 
   640 (* This prevents applications of splitE for already splitted arguments leading
   641    to quite time-consuming computations (in particular for nested tuples) *)
   642 declaration {* fn _ =>
   643   Classical.map_cs (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac))
   644 *}
   645 
   646 lemma split_eta_SetCompr [simp,no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   647   by (rule ext) fast
   648 
   649 lemma split_eta_SetCompr2 [simp,no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   650   by (rule ext) fast
   651 
   652 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   653   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   654   by (rule ext) blast
   655 
   656 (* Do NOT make this a simp rule as it
   657    a) only helps in special situations
   658    b) can lead to nontermination in the presence of split_def
   659 *)
   660 lemma split_comp_eq: 
   661   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   662   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   663   by (rule ext) auto
   664 
   665 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   666   apply (rule_tac x = "(a, b)" in image_eqI)
   667    apply auto
   668   done
   669 
   670 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   671   by blast
   672 
   673 (*
   674 the following  would be slightly more general,
   675 but cannot be used as rewrite rule:
   676 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   677 ### ?y = .x
   678 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   679 by (rtac some_equality 1)
   680 by ( Simp_tac 1)
   681 by (split_all_tac 1)
   682 by (Asm_full_simp_tac 1)
   683 qed "The_split_eq";
   684 *)
   685 
   686 text {*
   687   Setup of internal @{text split_rule}.
   688 *}
   689 
   690 lemmas prod_caseI = prod.cases [THEN iffD2, standard]
   691 
   692 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   693   by (fact splitI2)
   694 
   695 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   696   by (fact splitI2')
   697 
   698 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   699   by (fact splitE)
   700 
   701 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   702   by (fact splitE')
   703 
   704 declare prod_caseI [intro!]
   705 
   706 lemma prod_case_beta:
   707   "prod_case f p = f (fst p) (snd p)"
   708   by (fact split_beta)
   709 
   710 lemma prod_cases3 [cases type]:
   711   obtains (fields) a b c where "y = (a, b, c)"
   712   by (cases y, case_tac b) blast
   713 
   714 lemma prod_induct3 [case_names fields, induct type]:
   715     "(!!a b c. P (a, b, c)) ==> P x"
   716   by (cases x) blast
   717 
   718 lemma prod_cases4 [cases type]:
   719   obtains (fields) a b c d where "y = (a, b, c, d)"
   720   by (cases y, case_tac c) blast
   721 
   722 lemma prod_induct4 [case_names fields, induct type]:
   723     "(!!a b c d. P (a, b, c, d)) ==> P x"
   724   by (cases x) blast
   725 
   726 lemma prod_cases5 [cases type]:
   727   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   728   by (cases y, case_tac d) blast
   729 
   730 lemma prod_induct5 [case_names fields, induct type]:
   731     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   732   by (cases x) blast
   733 
   734 lemma prod_cases6 [cases type]:
   735   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   736   by (cases y, case_tac e) blast
   737 
   738 lemma prod_induct6 [case_names fields, induct type]:
   739     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   740   by (cases x) blast
   741 
   742 lemma prod_cases7 [cases type]:
   743   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   744   by (cases y, case_tac f) blast
   745 
   746 lemma prod_induct7 [case_names fields, induct type]:
   747     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   748   by (cases x) blast
   749 
   750 lemma split_def:
   751   "split = (\<lambda>c p. c (fst p) (snd p))"
   752   by (fact prod_case_unfold)
   753 
   754 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   755   "internal_split == split"
   756 
   757 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   758   by (simp only: internal_split_def split_conv)
   759 
   760 use "Tools/split_rule.ML"
   761 setup Split_Rule.setup
   762 
   763 hide_const internal_split
   764 
   765 
   766 subsubsection {* Derived operations *}
   767 
   768 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   769   "curry = (\<lambda>c x y. c (x, y))"
   770 
   771 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   772   by (simp add: curry_def)
   773 
   774 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   775   by (simp add: curry_def)
   776 
   777 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   778   by (simp add: curry_def)
   779 
   780 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   781   by (simp add: curry_def)
   782 
   783 lemma curry_split [simp]: "curry (split f) = f"
   784   by (simp add: curry_def split_def)
   785 
   786 lemma split_curry [simp]: "split (curry f) = f"
   787   by (simp add: curry_def split_def)
   788 
   789 text {*
   790   The composition-uncurry combinator.
   791 *}
   792 
   793 notation fcomp (infixl "\<circ>>" 60)
   794 
   795 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   796   "f \<circ>\<rightarrow> g = (\<lambda>x. prod_case g (f x))"
   797 
   798 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   799   by (simp add: fun_eq_iff scomp_def prod_case_unfold)
   800 
   801 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = prod_case g (f x)"
   802   by (simp add: scomp_unfold prod_case_unfold)
   803 
   804 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   805   by (simp add: fun_eq_iff scomp_apply)
   806 
   807 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   808   by (simp add: fun_eq_iff scomp_apply)
   809 
   810 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   811   by (simp add: fun_eq_iff scomp_unfold)
   812 
   813 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   814   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   815 
   816 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   817   by (simp add: fun_eq_iff scomp_unfold fcomp_apply)
   818 
   819 code_const scomp
   820   (Eval infixl 3 "#->")
   821 
   822 no_notation fcomp (infixl "\<circ>>" 60)
   823 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   824 
   825 text {*
   826   @{term map_pair} --- action of the product functor upon
   827   functions.
   828 *}
   829 
   830 definition map_pair :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   831   "map_pair f g = (\<lambda>(x, y). (f x, g y))"
   832 
   833 lemma map_pair_simp [simp, code]:
   834   "map_pair f g (a, b) = (f a, g b)"
   835   by (simp add: map_pair_def)
   836 
   837 enriched_type map_pair: map_pair
   838   by (auto simp add: split_paired_all intro: ext)
   839 
   840 lemma fst_map_pair [simp]:
   841   "fst (map_pair f g x) = f (fst x)"
   842   by (cases x) simp_all
   843 
   844 lemma snd_prod_fun [simp]:
   845   "snd (map_pair f g x) = g (snd x)"
   846   by (cases x) simp_all
   847 
   848 lemma fst_comp_map_pair [simp]:
   849   "fst \<circ> map_pair f g = f \<circ> fst"
   850   by (rule ext) simp_all
   851 
   852 lemma snd_comp_map_pair [simp]:
   853   "snd \<circ> map_pair f g = g \<circ> snd"
   854   by (rule ext) simp_all
   855 
   856 lemma map_pair_compose:
   857   "map_pair (f1 o f2) (g1 o g2) = (map_pair f1 g1 o map_pair f2 g2)"
   858   by (rule ext) (simp add: map_pair.compositionality comp_def)
   859 
   860 lemma map_pair_ident [simp]:
   861   "map_pair (%x. x) (%y. y) = (%z. z)"
   862   by (rule ext) (simp add: map_pair.identity)
   863 
   864 lemma map_pair_imageI [intro]:
   865   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_pair f g ` R"
   866   by (rule image_eqI) simp_all
   867 
   868 lemma prod_fun_imageE [elim!]:
   869   assumes major: "c \<in> map_pair f g ` R"
   870     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   871   shows P
   872   apply (rule major [THEN imageE])
   873   apply (case_tac x)
   874   apply (rule cases)
   875   apply simp_all
   876   done
   877 
   878 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   879   "apfst f = map_pair f id"
   880 
   881 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   882   "apsnd f = map_pair id f"
   883 
   884 lemma apfst_conv [simp, code]:
   885   "apfst f (x, y) = (f x, y)" 
   886   by (simp add: apfst_def)
   887 
   888 lemma apsnd_conv [simp, code]:
   889   "apsnd f (x, y) = (x, f y)" 
   890   by (simp add: apsnd_def)
   891 
   892 lemma fst_apfst [simp]:
   893   "fst (apfst f x) = f (fst x)"
   894   by (cases x) simp
   895 
   896 lemma fst_apsnd [simp]:
   897   "fst (apsnd f x) = fst x"
   898   by (cases x) simp
   899 
   900 lemma snd_apfst [simp]:
   901   "snd (apfst f x) = snd x"
   902   by (cases x) simp
   903 
   904 lemma snd_apsnd [simp]:
   905   "snd (apsnd f x) = f (snd x)"
   906   by (cases x) simp
   907 
   908 lemma apfst_compose:
   909   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   910   by (cases x) simp
   911 
   912 lemma apsnd_compose:
   913   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   914   by (cases x) simp
   915 
   916 lemma apfst_apsnd [simp]:
   917   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   918   by (cases x) simp
   919 
   920 lemma apsnd_apfst [simp]:
   921   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   922   by (cases x) simp
   923 
   924 lemma apfst_id [simp] :
   925   "apfst id = id"
   926   by (simp add: fun_eq_iff)
   927 
   928 lemma apsnd_id [simp] :
   929   "apsnd id = id"
   930   by (simp add: fun_eq_iff)
   931 
   932 lemma apfst_eq_conv [simp]:
   933   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   934   by (cases x) simp
   935 
   936 lemma apsnd_eq_conv [simp]:
   937   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   938   by (cases x) simp
   939 
   940 lemma apsnd_apfst_commute:
   941   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   942   by simp
   943 
   944 text {*
   945   Disjoint union of a family of sets -- Sigma.
   946 *}
   947 
   948 definition Sigma :: "['a set, 'a => 'b set] => ('a \<times> 'b) set" where
   949   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   950 
   951 abbreviation
   952   Times :: "['a set, 'b set] => ('a * 'b) set"
   953     (infixr "<*>" 80) where
   954   "A <*> B == Sigma A (%_. B)"
   955 
   956 notation (xsymbols)
   957   Times  (infixr "\<times>" 80)
   958 
   959 notation (HTML output)
   960   Times  (infixr "\<times>" 80)
   961 
   962 syntax
   963   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   964 translations
   965   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
   966 
   967 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   968   by (unfold Sigma_def) blast
   969 
   970 lemma SigmaE [elim!]:
   971     "[| c: Sigma A B;
   972         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   973      |] ==> P"
   974   -- {* The general elimination rule. *}
   975   by (unfold Sigma_def) blast
   976 
   977 text {*
   978   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   979   eigenvariables.
   980 *}
   981 
   982 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
   983   by blast
   984 
   985 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
   986   by blast
   987 
   988 lemma SigmaE2:
   989     "[| (a, b) : Sigma A B;
   990         [| a:A;  b:B(a) |] ==> P
   991      |] ==> P"
   992   by blast
   993 
   994 lemma Sigma_cong:
   995      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
   996       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
   997   by auto
   998 
   999 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
  1000   by blast
  1001 
  1002 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
  1003   by blast
  1004 
  1005 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
  1006   by blast
  1007 
  1008 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
  1009   by auto
  1010 
  1011 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
  1012   by auto
  1013 
  1014 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
  1015   by auto
  1016 
  1017 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
  1018   by blast
  1019 
  1020 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
  1021   by blast
  1022 
  1023 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
  1024   by (blast elim: equalityE)
  1025 
  1026 lemma SetCompr_Sigma_eq:
  1027     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
  1028   by blast
  1029 
  1030 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
  1031   by blast
  1032 
  1033 lemma UN_Times_distrib:
  1034   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
  1035   -- {* Suggested by Pierre Chartier *}
  1036   by blast
  1037 
  1038 lemma split_paired_Ball_Sigma [simp,no_atp]:
  1039     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
  1040   by blast
  1041 
  1042 lemma split_paired_Bex_Sigma [simp,no_atp]:
  1043     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
  1044   by blast
  1045 
  1046 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
  1047   by blast
  1048 
  1049 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
  1050   by blast
  1051 
  1052 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
  1053   by blast
  1054 
  1055 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
  1056   by blast
  1057 
  1058 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
  1059   by blast
  1060 
  1061 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1062   by blast
  1063 
  1064 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1065   by blast
  1066 
  1067 text {*
  1068   Non-dependent versions are needed to avoid the need for higher-order
  1069   matching, especially when the rules are re-oriented.
  1070 *}
  1071 
  1072 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1073 by blast
  1074 
  1075 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1076 by blast
  1077 
  1078 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1079 by blast
  1080 
  1081 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1082   by auto
  1083 
  1084 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1085   by (auto intro!: image_eqI)
  1086 
  1087 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1088   by (auto intro!: image_eqI)
  1089 
  1090 lemma insert_times_insert[simp]:
  1091   "insert a A \<times> insert b B =
  1092    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1093 by blast
  1094 
  1095 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1096   by (auto, case_tac "f x", auto)
  1097 
  1098 lemma swap_inj_on:
  1099   "inj_on (\<lambda>(i, j). (j, i)) A"
  1100   by (auto intro!: inj_onI)
  1101 
  1102 lemma swap_product:
  1103   "(%(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1104   by (simp add: split_def image_def) blast
  1105 
  1106 lemma image_split_eq_Sigma:
  1107   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1108 proof (safe intro!: imageI vimageI)
  1109   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1110   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1111     using * eq[symmetric] by auto
  1112 qed simp_all
  1113 
  1114 text {* The following @{const map_pair} lemmas are due to Joachim Breitner: *}
  1115 
  1116 lemma map_pair_inj_on:
  1117   assumes "inj_on f A" and "inj_on g B"
  1118   shows "inj_on (map_pair f g) (A \<times> B)"
  1119 proof (rule inj_onI)
  1120   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1121   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1122   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1123   assume "map_pair f g x = map_pair f g y"
  1124   hence "fst (map_pair f g x) = fst (map_pair f g y)" by (auto)
  1125   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1126   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1127   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1128   moreover from `map_pair f g x = map_pair f g y`
  1129   have "snd (map_pair f g x) = snd (map_pair f g y)" by (auto)
  1130   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1131   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1132   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1133   ultimately show "x = y" by(rule prod_eqI)
  1134 qed
  1135 
  1136 lemma map_pair_surj:
  1137   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1138   assumes "surj f" and "surj g"
  1139   shows "surj (map_pair f g)"
  1140 unfolding surj_def
  1141 proof
  1142   fix y :: "'b \<times> 'd"
  1143   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1144   moreover
  1145   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1146   ultimately have "(fst y, snd y) = map_pair f g (a,b)" by auto
  1147   thus "\<exists>x. y = map_pair f g x" by auto
  1148 qed
  1149 
  1150 lemma map_pair_surj_on:
  1151   assumes "f ` A = A'" and "g ` B = B'"
  1152   shows "map_pair f g ` (A \<times> B) = A' \<times> B'"
  1153 unfolding image_def
  1154 proof(rule set_eqI,rule iffI)
  1155   fix x :: "'a \<times> 'c"
  1156   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_pair f g x}"
  1157   then obtain y where "y \<in> A \<times> B" and "x = map_pair f g y" by blast
  1158   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1159   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1160   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1161   with `x = map_pair f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1162 next
  1163   fix x :: "'a \<times> 'c"
  1164   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1165   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1166   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1167   moreover from `image g B = B'` and `snd x \<in> B'`
  1168   obtain b where "b \<in> B" and "snd x = g b" by auto
  1169   ultimately have "(fst x, snd x) = map_pair f g (a,b)" by auto
  1170   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1171   ultimately have "\<exists>y \<in> A \<times> B. x = map_pair f g y" by auto
  1172   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_pair f g y}" by auto
  1173 qed
  1174 
  1175 
  1176 subsection {* Inductively defined sets *}
  1177 
  1178 use "Tools/inductive_codegen.ML"
  1179 setup Inductive_Codegen.setup
  1180 
  1181 use "Tools/inductive_set.ML"
  1182 setup Inductive_Set.setup
  1183 
  1184 
  1185 subsection {* Legacy theorem bindings and duplicates *}
  1186 
  1187 lemma PairE:
  1188   obtains x y where "p = (x, y)"
  1189   by (fact prod.exhaust)
  1190 
  1191 lemma Pair_inject:
  1192   assumes "(a, b) = (a', b')"
  1193     and "a = a' ==> b = b' ==> R"
  1194   shows R
  1195   using assms by simp
  1196 
  1197 lemmas Pair_eq = prod.inject
  1198 
  1199 lemmas split = split_conv  -- {* for backwards compatibility *}
  1200 
  1201 end