src/HOL/Analysis/Linear_Algebra.thy
author Manuel Eberl <eberlm@in.tum.de>
Tue Aug 22 21:36:48 2017 +0200 (21 months ago)
changeset 66486 ffaaa83543b2
parent 66453 cc19f7ca2ed6
child 66503 7685861f337d
permissions -rw-r--r--
Lemmas about analysis and permutations
     1 (*  Title:      HOL/Analysis/Linear_Algebra.thy
     2     Author:     Amine Chaieb, University of Cambridge
     3 *)
     4 
     5 section \<open>Elementary linear algebra on Euclidean spaces\<close>
     6 
     7 theory Linear_Algebra
     8 imports
     9   Euclidean_Space
    10   "HOL-Library.Infinite_Set"
    11 begin
    12 
    13 lemma linear_simps:
    14   assumes "bounded_linear f"
    15   shows
    16     "f (a + b) = f a + f b"
    17     "f (a - b) = f a - f b"
    18     "f 0 = 0"
    19     "f (- a) = - f a"
    20     "f (s *\<^sub>R v) = s *\<^sub>R (f v)"
    21 proof -
    22   interpret f: bounded_linear f by fact
    23   show "f (a + b) = f a + f b" by (rule f.add)
    24   show "f (a - b) = f a - f b" by (rule f.diff)
    25   show "f 0 = 0" by (rule f.zero)
    26   show "f (- a) = - f a" by (rule f.minus)
    27   show "f (s *\<^sub>R v) = s *\<^sub>R (f v)" by (rule f.scaleR)
    28 qed
    29 
    30 lemma bounded_linearI:
    31   assumes "\<And>x y. f (x + y) = f x + f y"
    32     and "\<And>r x. f (r *\<^sub>R x) = r *\<^sub>R f x"
    33     and "\<And>x. norm (f x) \<le> norm x * K"
    34   shows "bounded_linear f"
    35   using assms by (rule bounded_linear_intro) (* FIXME: duplicate *)
    36 
    37 subsection \<open>A generic notion of "hull" (convex, affine, conic hull and closure).\<close>
    38 
    39 definition hull :: "('a set \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> 'a set"  (infixl "hull" 75)
    40   where "S hull s = \<Inter>{t. S t \<and> s \<subseteq> t}"
    41 
    42 lemma hull_same: "S s \<Longrightarrow> S hull s = s"
    43   unfolding hull_def by auto
    44 
    45 lemma hull_in: "(\<And>T. Ball T S \<Longrightarrow> S (\<Inter>T)) \<Longrightarrow> S (S hull s)"
    46   unfolding hull_def Ball_def by auto
    47 
    48 lemma hull_eq: "(\<And>T. Ball T S \<Longrightarrow> S (\<Inter>T)) \<Longrightarrow> (S hull s) = s \<longleftrightarrow> S s"
    49   using hull_same[of S s] hull_in[of S s] by metis
    50 
    51 lemma hull_hull [simp]: "S hull (S hull s) = S hull s"
    52   unfolding hull_def by blast
    53 
    54 lemma hull_subset[intro]: "s \<subseteq> (S hull s)"
    55   unfolding hull_def by blast
    56 
    57 lemma hull_mono: "s \<subseteq> t \<Longrightarrow> (S hull s) \<subseteq> (S hull t)"
    58   unfolding hull_def by blast
    59 
    60 lemma hull_antimono: "\<forall>x. S x \<longrightarrow> T x \<Longrightarrow> (T hull s) \<subseteq> (S hull s)"
    61   unfolding hull_def by blast
    62 
    63 lemma hull_minimal: "s \<subseteq> t \<Longrightarrow> S t \<Longrightarrow> (S hull s) \<subseteq> t"
    64   unfolding hull_def by blast
    65 
    66 lemma subset_hull: "S t \<Longrightarrow> S hull s \<subseteq> t \<longleftrightarrow> s \<subseteq> t"
    67   unfolding hull_def by blast
    68 
    69 lemma hull_UNIV [simp]: "S hull UNIV = UNIV"
    70   unfolding hull_def by auto
    71 
    72 lemma hull_unique: "s \<subseteq> t \<Longrightarrow> S t \<Longrightarrow> (\<And>t'. s \<subseteq> t' \<Longrightarrow> S t' \<Longrightarrow> t \<subseteq> t') \<Longrightarrow> (S hull s = t)"
    73   unfolding hull_def by auto
    74 
    75 lemma hull_induct: "(\<And>x. x\<in> S \<Longrightarrow> P x) \<Longrightarrow> Q {x. P x} \<Longrightarrow> \<forall>x\<in> Q hull S. P x"
    76   using hull_minimal[of S "{x. P x}" Q]
    77   by (auto simp add: subset_eq)
    78 
    79 lemma hull_inc: "x \<in> S \<Longrightarrow> x \<in> P hull S"
    80   by (metis hull_subset subset_eq)
    81 
    82 lemma hull_Un_subset: "(S hull s) \<union> (S hull t) \<subseteq> (S hull (s \<union> t))"
    83   unfolding Un_subset_iff by (metis hull_mono Un_upper1 Un_upper2)
    84 
    85 lemma hull_Un:
    86   assumes T: "\<And>T. Ball T S \<Longrightarrow> S (\<Inter>T)"
    87   shows "S hull (s \<union> t) = S hull (S hull s \<union> S hull t)"
    88   apply (rule equalityI)
    89   apply (meson hull_mono hull_subset sup.mono)
    90   by (metis hull_Un_subset hull_hull hull_mono)
    91 
    92 lemma hull_Un_left: "P hull (S \<union> T) = P hull (P hull S \<union> T)"
    93   apply (rule equalityI)
    94    apply (simp add: Un_commute hull_mono hull_subset sup.coboundedI2)
    95   by (metis Un_subset_iff hull_hull hull_mono hull_subset)
    96 
    97 lemma hull_Un_right: "P hull (S \<union> T) = P hull (S \<union> P hull T)"
    98   by (metis hull_Un_left sup.commute)
    99 
   100 lemma hull_insert:
   101    "P hull (insert a S) = P hull (insert a (P hull S))"
   102   by (metis hull_Un_right insert_is_Un)
   103 
   104 lemma hull_redundant_eq: "a \<in> (S hull s) \<longleftrightarrow> S hull (insert a s) = S hull s"
   105   unfolding hull_def by blast
   106 
   107 lemma hull_redundant: "a \<in> (S hull s) \<Longrightarrow> S hull (insert a s) = S hull s"
   108   by (metis hull_redundant_eq)
   109 
   110 subsection \<open>Linear functions.\<close>
   111 
   112 lemma linear_iff:
   113   "linear f \<longleftrightarrow> (\<forall>x y. f (x + y) = f x + f y) \<and> (\<forall>c x. f (c *\<^sub>R x) = c *\<^sub>R f x)"
   114   (is "linear f \<longleftrightarrow> ?rhs")
   115 proof
   116   assume "linear f"
   117   then interpret f: linear f .
   118   show "?rhs" by (simp add: f.add f.scaleR)
   119 next
   120   assume "?rhs"
   121   then show "linear f" by unfold_locales simp_all
   122 qed
   123 
   124 lemma linear_compose_cmul: "linear f \<Longrightarrow> linear (\<lambda>x. c *\<^sub>R f x)"
   125   by (simp add: linear_iff algebra_simps)
   126 
   127 lemma linear_compose_scaleR: "linear f \<Longrightarrow> linear (\<lambda>x. f x *\<^sub>R c)"
   128   by (simp add: linear_iff scaleR_add_left)
   129 
   130 lemma linear_compose_neg: "linear f \<Longrightarrow> linear (\<lambda>x. - f x)"
   131   by (simp add: linear_iff)
   132 
   133 lemma linear_compose_add: "linear f \<Longrightarrow> linear g \<Longrightarrow> linear (\<lambda>x. f x + g x)"
   134   by (simp add: linear_iff algebra_simps)
   135 
   136 lemma linear_compose_sub: "linear f \<Longrightarrow> linear g \<Longrightarrow> linear (\<lambda>x. f x - g x)"
   137   by (simp add: linear_iff algebra_simps)
   138 
   139 lemma linear_compose: "linear f \<Longrightarrow> linear g \<Longrightarrow> linear (g \<circ> f)"
   140   by (simp add: linear_iff)
   141 
   142 lemma linear_id: "linear id"
   143   by (simp add: linear_iff id_def)
   144 
   145 lemma linear_zero: "linear (\<lambda>x. 0)"
   146   by (simp add: linear_iff)
   147 
   148 lemma linear_uminus: "linear uminus"
   149 by (simp add: linear_iff)
   150 
   151 lemma linear_compose_sum:
   152   assumes lS: "\<forall>a \<in> S. linear (f a)"
   153   shows "linear (\<lambda>x. sum (\<lambda>a. f a x) S)"
   154 proof (cases "finite S")
   155   case True
   156   then show ?thesis
   157     using lS by induct (simp_all add: linear_zero linear_compose_add)
   158 next
   159   case False
   160   then show ?thesis
   161     by (simp add: linear_zero)
   162 qed
   163 
   164 lemma linear_0: "linear f \<Longrightarrow> f 0 = 0"
   165   unfolding linear_iff
   166   apply clarsimp
   167   apply (erule allE[where x="0::'a"])
   168   apply simp
   169   done
   170 
   171 lemma linear_cmul: "linear f \<Longrightarrow> f (c *\<^sub>R x) = c *\<^sub>R f x"
   172   by (rule linear.scaleR)
   173 
   174 lemma linear_neg: "linear f \<Longrightarrow> f (- x) = - f x"
   175   using linear_cmul [where c="-1"] by simp
   176 
   177 lemma linear_add: "linear f \<Longrightarrow> f (x + y) = f x + f y"
   178   by (metis linear_iff)
   179 
   180 lemma linear_diff: "linear f \<Longrightarrow> f (x - y) = f x - f y"
   181   using linear_add [of f x "- y"] by (simp add: linear_neg)
   182 
   183 lemma linear_sum:
   184   assumes f: "linear f"
   185   shows "f (sum g S) = sum (f \<circ> g) S"
   186 proof (cases "finite S")
   187   case True
   188   then show ?thesis
   189     by induct (simp_all add: linear_0 [OF f] linear_add [OF f])
   190 next
   191   case False
   192   then show ?thesis
   193     by (simp add: linear_0 [OF f])
   194 qed
   195 
   196 lemma linear_sum_mul:
   197   assumes lin: "linear f"
   198   shows "f (sum (\<lambda>i. c i *\<^sub>R v i) S) = sum (\<lambda>i. c i *\<^sub>R f (v i)) S"
   199   using linear_sum[OF lin, of "\<lambda>i. c i *\<^sub>R v i" , unfolded o_def] linear_cmul[OF lin]
   200   by simp
   201 
   202 lemma linear_injective_0:
   203   assumes lin: "linear f"
   204   shows "inj f \<longleftrightarrow> (\<forall>x. f x = 0 \<longrightarrow> x = 0)"
   205 proof -
   206   have "inj f \<longleftrightarrow> (\<forall> x y. f x = f y \<longrightarrow> x = y)"
   207     by (simp add: inj_on_def)
   208   also have "\<dots> \<longleftrightarrow> (\<forall> x y. f x - f y = 0 \<longrightarrow> x - y = 0)"
   209     by simp
   210   also have "\<dots> \<longleftrightarrow> (\<forall> x y. f (x - y) = 0 \<longrightarrow> x - y = 0)"
   211     by (simp add: linear_diff[OF lin])
   212   also have "\<dots> \<longleftrightarrow> (\<forall> x. f x = 0 \<longrightarrow> x = 0)"
   213     by auto
   214   finally show ?thesis .
   215 qed
   216 
   217 lemma linear_scaleR  [simp]: "linear (\<lambda>x. scaleR c x)"
   218   by (simp add: linear_iff scaleR_add_right)
   219 
   220 lemma linear_scaleR_left [simp]: "linear (\<lambda>r. scaleR r x)"
   221   by (simp add: linear_iff scaleR_add_left)
   222 
   223 lemma injective_scaleR: "c \<noteq> 0 \<Longrightarrow> inj (\<lambda>x::'a::real_vector. scaleR c x)"
   224   by (simp add: inj_on_def)
   225 
   226 lemma linear_add_cmul:
   227   assumes "linear f"
   228   shows "f (a *\<^sub>R x + b *\<^sub>R y) = a *\<^sub>R f x +  b *\<^sub>R f y"
   229   using linear_add[of f] linear_cmul[of f] assms by simp
   230 
   231 subsection \<open>Subspaces of vector spaces\<close>
   232 
   233 definition (in real_vector) subspace :: "'a set \<Rightarrow> bool"
   234   where "subspace S \<longleftrightarrow> 0 \<in> S \<and> (\<forall>x \<in> S. \<forall>y \<in> S. x + y \<in> S) \<and> (\<forall>c. \<forall>x \<in> S. c *\<^sub>R x \<in> S)"
   235 
   236 definition (in real_vector) "span S = (subspace hull S)"
   237 definition (in real_vector) "dependent S \<longleftrightarrow> (\<exists>a \<in> S. a \<in> span (S - {a}))"
   238 abbreviation (in real_vector) "independent s \<equiv> \<not> dependent s"
   239 
   240 text \<open>Closure properties of subspaces.\<close>
   241 
   242 lemma subspace_UNIV[simp]: "subspace UNIV"
   243   by (simp add: subspace_def)
   244 
   245 lemma (in real_vector) subspace_0: "subspace S \<Longrightarrow> 0 \<in> S"
   246   by (metis subspace_def)
   247 
   248 lemma (in real_vector) subspace_add: "subspace S \<Longrightarrow> x \<in> S \<Longrightarrow> y \<in> S \<Longrightarrow> x + y \<in> S"
   249   by (metis subspace_def)
   250 
   251 lemma (in real_vector) subspace_mul: "subspace S \<Longrightarrow> x \<in> S \<Longrightarrow> c *\<^sub>R x \<in> S"
   252   by (metis subspace_def)
   253 
   254 lemma subspace_neg: "subspace S \<Longrightarrow> x \<in> S \<Longrightarrow> - x \<in> S"
   255   by (metis scaleR_minus1_left subspace_mul)
   256 
   257 lemma subspace_diff: "subspace S \<Longrightarrow> x \<in> S \<Longrightarrow> y \<in> S \<Longrightarrow> x - y \<in> S"
   258   using subspace_add [of S x "- y"] by (simp add: subspace_neg)
   259 
   260 lemma (in real_vector) subspace_sum:
   261   assumes sA: "subspace A"
   262     and f: "\<And>x. x \<in> B \<Longrightarrow> f x \<in> A"
   263   shows "sum f B \<in> A"
   264 proof (cases "finite B")
   265   case True
   266   then show ?thesis
   267     using f by induct (simp_all add: subspace_0 [OF sA] subspace_add [OF sA])
   268 qed (simp add: subspace_0 [OF sA])
   269 
   270 lemma subspace_trivial [iff]: "subspace {0}"
   271   by (simp add: subspace_def)
   272 
   273 lemma (in real_vector) subspace_inter: "subspace A \<Longrightarrow> subspace B \<Longrightarrow> subspace (A \<inter> B)"
   274   by (simp add: subspace_def)
   275 
   276 lemma subspace_Times: "subspace A \<Longrightarrow> subspace B \<Longrightarrow> subspace (A \<times> B)"
   277   unfolding subspace_def zero_prod_def by simp
   278 
   279 lemma subspace_sums: "\<lbrakk>subspace S; subspace T\<rbrakk> \<Longrightarrow> subspace {x + y|x y. x \<in> S \<and> y \<in> T}"
   280 apply (simp add: subspace_def)
   281 apply (intro conjI impI allI)
   282   using add.right_neutral apply blast
   283  apply clarify
   284  apply (metis add.assoc add.left_commute)
   285 using scaleR_add_right by blast
   286 
   287 subsection \<open>Properties of span\<close>
   288 
   289 lemma (in real_vector) span_mono: "A \<subseteq> B \<Longrightarrow> span A \<subseteq> span B"
   290   by (metis span_def hull_mono)
   291 
   292 lemma (in real_vector) subspace_span [iff]: "subspace (span S)"
   293   unfolding span_def
   294   apply (rule hull_in)
   295   apply (simp only: subspace_def Inter_iff Int_iff subset_eq)
   296   apply auto
   297   done
   298 
   299 lemma (in real_vector) span_clauses:
   300   "a \<in> S \<Longrightarrow> a \<in> span S"
   301   "0 \<in> span S"
   302   "x\<in> span S \<Longrightarrow> y \<in> span S \<Longrightarrow> x + y \<in> span S"
   303   "x \<in> span S \<Longrightarrow> c *\<^sub>R x \<in> span S"
   304   by (metis span_def hull_subset subset_eq) (metis subspace_span subspace_def)+
   305 
   306 lemma span_unique:
   307   "S \<subseteq> T \<Longrightarrow> subspace T \<Longrightarrow> (\<And>T'. S \<subseteq> T' \<Longrightarrow> subspace T' \<Longrightarrow> T \<subseteq> T') \<Longrightarrow> span S = T"
   308   unfolding span_def by (rule hull_unique)
   309 
   310 lemma span_minimal: "S \<subseteq> T \<Longrightarrow> subspace T \<Longrightarrow> span S \<subseteq> T"
   311   unfolding span_def by (rule hull_minimal)
   312 
   313 lemma span_UNIV: "span UNIV = UNIV"
   314   by (intro span_unique) auto
   315 
   316 lemma (in real_vector) span_induct:
   317   assumes x: "x \<in> span S"
   318     and P: "subspace (Collect P)"
   319     and SP: "\<And>x. x \<in> S \<Longrightarrow> P x"
   320   shows "P x"
   321 proof -
   322   from SP have SP': "S \<subseteq> Collect P"
   323     by (simp add: subset_eq)
   324   from x hull_minimal[where S=subspace, OF SP' P, unfolded span_def[symmetric]]
   325   show ?thesis
   326     using subset_eq by force
   327 qed
   328 
   329 lemma span_empty[simp]: "span {} = {0}"
   330   apply (simp add: span_def)
   331   apply (rule hull_unique)
   332   apply (auto simp add: subspace_def)
   333   done
   334 
   335 lemma (in real_vector) independent_empty [iff]: "independent {}"
   336   by (simp add: dependent_def)
   337 
   338 lemma dependent_single[simp]: "dependent {x} \<longleftrightarrow> x = 0"
   339   unfolding dependent_def by auto
   340 
   341 lemma (in real_vector) independent_mono: "independent A \<Longrightarrow> B \<subseteq> A \<Longrightarrow> independent B"
   342   apply (clarsimp simp add: dependent_def span_mono)
   343   apply (subgoal_tac "span (B - {a}) \<le> span (A - {a})")
   344   apply force
   345   apply (rule span_mono)
   346   apply auto
   347   done
   348 
   349 lemma (in real_vector) span_subspace: "A \<subseteq> B \<Longrightarrow> B \<le> span A \<Longrightarrow>  subspace B \<Longrightarrow> span A = B"
   350   by (metis order_antisym span_def hull_minimal)
   351 
   352 lemma (in real_vector) span_induct':
   353   "\<forall>x \<in> S. P x \<Longrightarrow> subspace {x. P x} \<Longrightarrow> \<forall>x \<in> span S. P x"
   354   unfolding span_def by (rule hull_induct) auto
   355 
   356 inductive_set (in real_vector) span_induct_alt_help for S :: "'a set"
   357 where
   358   span_induct_alt_help_0: "0 \<in> span_induct_alt_help S"
   359 | span_induct_alt_help_S:
   360     "x \<in> S \<Longrightarrow> z \<in> span_induct_alt_help S \<Longrightarrow>
   361       (c *\<^sub>R x + z) \<in> span_induct_alt_help S"
   362 
   363 lemma span_induct_alt':
   364   assumes h0: "h 0"
   365     and hS: "\<And>c x y. x \<in> S \<Longrightarrow> h y \<Longrightarrow> h (c *\<^sub>R x + y)"
   366   shows "\<forall>x \<in> span S. h x"
   367 proof -
   368   {
   369     fix x :: 'a
   370     assume x: "x \<in> span_induct_alt_help S"
   371     have "h x"
   372       apply (rule span_induct_alt_help.induct[OF x])
   373       apply (rule h0)
   374       apply (rule hS)
   375       apply assumption
   376       apply assumption
   377       done
   378   }
   379   note th0 = this
   380   {
   381     fix x
   382     assume x: "x \<in> span S"
   383     have "x \<in> span_induct_alt_help S"
   384     proof (rule span_induct[where x=x and S=S])
   385       show "x \<in> span S" by (rule x)
   386     next
   387       fix x
   388       assume xS: "x \<in> S"
   389       from span_induct_alt_help_S[OF xS span_induct_alt_help_0, of 1]
   390       show "x \<in> span_induct_alt_help S"
   391         by simp
   392     next
   393       have "0 \<in> span_induct_alt_help S" by (rule span_induct_alt_help_0)
   394       moreover
   395       {
   396         fix x y
   397         assume h: "x \<in> span_induct_alt_help S" "y \<in> span_induct_alt_help S"
   398         from h have "(x + y) \<in> span_induct_alt_help S"
   399           apply (induct rule: span_induct_alt_help.induct)
   400           apply simp
   401           unfolding add.assoc
   402           apply (rule span_induct_alt_help_S)
   403           apply assumption
   404           apply simp
   405           done
   406       }
   407       moreover
   408       {
   409         fix c x
   410         assume xt: "x \<in> span_induct_alt_help S"
   411         then have "(c *\<^sub>R x) \<in> span_induct_alt_help S"
   412           apply (induct rule: span_induct_alt_help.induct)
   413           apply (simp add: span_induct_alt_help_0)
   414           apply (simp add: scaleR_right_distrib)
   415           apply (rule span_induct_alt_help_S)
   416           apply assumption
   417           apply simp
   418           done }
   419       ultimately show "subspace {a. a \<in> span_induct_alt_help S}"
   420         unfolding subspace_def Ball_def by blast
   421     qed
   422   }
   423   with th0 show ?thesis by blast
   424 qed
   425 
   426 lemma span_induct_alt:
   427   assumes h0: "h 0"
   428     and hS: "\<And>c x y. x \<in> S \<Longrightarrow> h y \<Longrightarrow> h (c *\<^sub>R x + y)"
   429     and x: "x \<in> span S"
   430   shows "h x"
   431   using span_induct_alt'[of h S] h0 hS x by blast
   432 
   433 text \<open>Individual closure properties.\<close>
   434 
   435 lemma span_span: "span (span A) = span A"
   436   unfolding span_def hull_hull ..
   437 
   438 lemma (in real_vector) span_superset: "x \<in> S \<Longrightarrow> x \<in> span S"
   439   by (metis span_clauses(1))
   440 
   441 lemma (in real_vector) span_0 [simp]: "0 \<in> span S"
   442   by (metis subspace_span subspace_0)
   443 
   444 lemma span_inc: "S \<subseteq> span S"
   445   by (metis subset_eq span_superset)
   446 
   447 lemma span_eq: "span S = span T \<longleftrightarrow> S \<subseteq> span T \<and> T \<subseteq> span S"
   448   using span_inc[unfolded subset_eq] using span_mono[of T "span S"] span_mono[of S "span T"]
   449   by (auto simp add: span_span)
   450 
   451 lemma (in real_vector) dependent_0:
   452   assumes "0 \<in> A"
   453   shows "dependent A"
   454   unfolding dependent_def
   455   using assms span_0
   456   by blast
   457 
   458 lemma (in real_vector) span_add: "x \<in> span S \<Longrightarrow> y \<in> span S \<Longrightarrow> x + y \<in> span S"
   459   by (metis subspace_add subspace_span)
   460 
   461 lemma (in real_vector) span_mul: "x \<in> span S \<Longrightarrow> c *\<^sub>R x \<in> span S"
   462   by (metis subspace_span subspace_mul)
   463 
   464 lemma span_neg: "x \<in> span S \<Longrightarrow> - x \<in> span S"
   465   by (metis subspace_neg subspace_span)
   466 
   467 lemma span_diff: "x \<in> span S \<Longrightarrow> y \<in> span S \<Longrightarrow> x - y \<in> span S"
   468   by (metis subspace_span subspace_diff)
   469 
   470 lemma (in real_vector) span_sum: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> span S) \<Longrightarrow> sum f A \<in> span S"
   471   by (rule subspace_sum [OF subspace_span])
   472 
   473 lemma span_add_eq: "x \<in> span S \<Longrightarrow> x + y \<in> span S \<longleftrightarrow> y \<in> span S"
   474   by (metis add_minus_cancel scaleR_minus1_left subspace_def subspace_span)
   475 
   476 text \<open>The key breakdown property.\<close>
   477 
   478 lemma span_singleton: "span {x} = range (\<lambda>k. k *\<^sub>R x)"
   479 proof (rule span_unique)
   480   show "{x} \<subseteq> range (\<lambda>k. k *\<^sub>R x)"
   481     by (fast intro: scaleR_one [symmetric])
   482   show "subspace (range (\<lambda>k. k *\<^sub>R x))"
   483     unfolding subspace_def
   484     by (auto intro: scaleR_add_left [symmetric])
   485 next
   486   fix T
   487   assume "{x} \<subseteq> T" and "subspace T"
   488   then show "range (\<lambda>k. k *\<^sub>R x) \<subseteq> T"
   489     unfolding subspace_def by auto
   490 qed
   491 
   492 text \<open>Mapping under linear image.\<close>
   493 
   494 lemma subspace_linear_image:
   495   assumes lf: "linear f"
   496     and sS: "subspace S"
   497   shows "subspace (f ` S)"
   498   using lf sS linear_0[OF lf]
   499   unfolding linear_iff subspace_def
   500   apply (auto simp add: image_iff)
   501   apply (rule_tac x="x + y" in bexI)
   502   apply auto
   503   apply (rule_tac x="c *\<^sub>R x" in bexI)
   504   apply auto
   505   done
   506 
   507 lemma subspace_linear_vimage: "linear f \<Longrightarrow> subspace S \<Longrightarrow> subspace (f -` S)"
   508   by (auto simp add: subspace_def linear_iff linear_0[of f])
   509 
   510 lemma subspace_linear_preimage: "linear f \<Longrightarrow> subspace S \<Longrightarrow> subspace {x. f x \<in> S}"
   511   by (auto simp add: subspace_def linear_iff linear_0[of f])
   512 
   513 lemma span_linear_image:
   514   assumes lf: "linear f"
   515   shows "span (f ` S) = f ` span S"
   516 proof (rule span_unique)
   517   show "f ` S \<subseteq> f ` span S"
   518     by (intro image_mono span_inc)
   519   show "subspace (f ` span S)"
   520     using lf subspace_span by (rule subspace_linear_image)
   521 next
   522   fix T
   523   assume "f ` S \<subseteq> T" and "subspace T"
   524   then show "f ` span S \<subseteq> T"
   525     unfolding image_subset_iff_subset_vimage
   526     by (intro span_minimal subspace_linear_vimage lf)
   527 qed
   528 
   529 lemma spans_image:
   530   assumes lf: "linear f"
   531     and VB: "V \<subseteq> span B"
   532   shows "f ` V \<subseteq> span (f ` B)"
   533   unfolding span_linear_image[OF lf] by (metis VB image_mono)
   534 
   535 lemma span_Un: "span (A \<union> B) = (\<lambda>(a, b). a + b) ` (span A \<times> span B)"
   536 proof (rule span_unique)
   537   show "A \<union> B \<subseteq> (\<lambda>(a, b). a + b) ` (span A \<times> span B)"
   538     by safe (force intro: span_clauses)+
   539 next
   540   have "linear (\<lambda>(a, b). a + b)"
   541     by (simp add: linear_iff scaleR_add_right)
   542   moreover have "subspace (span A \<times> span B)"
   543     by (intro subspace_Times subspace_span)
   544   ultimately show "subspace ((\<lambda>(a, b). a + b) ` (span A \<times> span B))"
   545     by (rule subspace_linear_image)
   546 next
   547   fix T
   548   assume "A \<union> B \<subseteq> T" and "subspace T"
   549   then show "(\<lambda>(a, b). a + b) ` (span A \<times> span B) \<subseteq> T"
   550     by (auto intro!: subspace_add elim: span_induct)
   551 qed
   552 
   553 lemma span_insert: "span (insert a S) = {x. \<exists>k. (x - k *\<^sub>R a) \<in> span S}"
   554 proof -
   555   have "span ({a} \<union> S) = {x. \<exists>k. (x - k *\<^sub>R a) \<in> span S}"
   556     unfolding span_Un span_singleton
   557     apply safe
   558     apply (rule_tac x=k in exI, simp)
   559     apply (erule rev_image_eqI [OF SigmaI [OF rangeI]])
   560     apply auto
   561     done
   562   then show ?thesis by simp
   563 qed
   564 
   565 lemma span_breakdown:
   566   assumes bS: "b \<in> S"
   567     and aS: "a \<in> span S"
   568   shows "\<exists>k. a - k *\<^sub>R b \<in> span (S - {b})"
   569   using assms span_insert [of b "S - {b}"]
   570   by (simp add: insert_absorb)
   571 
   572 lemma span_breakdown_eq: "x \<in> span (insert a S) \<longleftrightarrow> (\<exists>k. x - k *\<^sub>R a \<in> span S)"
   573   by (simp add: span_insert)
   574 
   575 text \<open>Hence some "reversal" results.\<close>
   576 
   577 lemma in_span_insert:
   578   assumes a: "a \<in> span (insert b S)"
   579     and na: "a \<notin> span S"
   580   shows "b \<in> span (insert a S)"
   581 proof -
   582   from a obtain k where k: "a - k *\<^sub>R b \<in> span S"
   583     unfolding span_insert by fast
   584   show ?thesis
   585   proof (cases "k = 0")
   586     case True
   587     with k have "a \<in> span S" by simp
   588     with na show ?thesis by simp
   589   next
   590     case False
   591     from k have "(- inverse k) *\<^sub>R (a - k *\<^sub>R b) \<in> span S"
   592       by (rule span_mul)
   593     then have "b - inverse k *\<^sub>R a \<in> span S"
   594       using \<open>k \<noteq> 0\<close> by (simp add: scaleR_diff_right)
   595     then show ?thesis
   596       unfolding span_insert by fast
   597   qed
   598 qed
   599 
   600 lemma in_span_delete:
   601   assumes a: "a \<in> span S"
   602     and na: "a \<notin> span (S - {b})"
   603   shows "b \<in> span (insert a (S - {b}))"
   604   apply (rule in_span_insert)
   605   apply (rule set_rev_mp)
   606   apply (rule a)
   607   apply (rule span_mono)
   608   apply blast
   609   apply (rule na)
   610   done
   611 
   612 text \<open>Transitivity property.\<close>
   613 
   614 lemma span_redundant: "x \<in> span S \<Longrightarrow> span (insert x S) = span S"
   615   unfolding span_def by (rule hull_redundant)
   616 
   617 lemma span_trans:
   618   assumes x: "x \<in> span S"
   619     and y: "y \<in> span (insert x S)"
   620   shows "y \<in> span S"
   621   using assms by (simp only: span_redundant)
   622 
   623 lemma span_insert_0[simp]: "span (insert 0 S) = span S"
   624   by (simp only: span_redundant span_0)
   625 
   626 text \<open>An explicit expansion is sometimes needed.\<close>
   627 
   628 lemma span_explicit:
   629   "span P = {y. \<exists>S u. finite S \<and> S \<subseteq> P \<and> sum (\<lambda>v. u v *\<^sub>R v) S = y}"
   630   (is "_ = ?E" is "_ = {y. ?h y}" is "_ = {y. \<exists>S u. ?Q S u y}")
   631 proof -
   632   {
   633     fix x
   634     assume "?h x"
   635     then obtain S u where "finite S" and "S \<subseteq> P" and "sum (\<lambda>v. u v *\<^sub>R v) S = x"
   636       by blast
   637     then have "x \<in> span P"
   638       by (auto intro: span_sum span_mul span_superset)
   639   }
   640   moreover
   641   have "\<forall>x \<in> span P. ?h x"
   642   proof (rule span_induct_alt')
   643     show "?h 0"
   644       by (rule exI[where x="{}"], simp)
   645   next
   646     fix c x y
   647     assume x: "x \<in> P"
   648     assume hy: "?h y"
   649     from hy obtain S u where fS: "finite S" and SP: "S\<subseteq>P"
   650       and u: "sum (\<lambda>v. u v *\<^sub>R v) S = y" by blast
   651     let ?S = "insert x S"
   652     let ?u = "\<lambda>y. if y = x then (if x \<in> S then u y + c else c) else u y"
   653     from fS SP x have th0: "finite (insert x S)" "insert x S \<subseteq> P"
   654       by blast+
   655     have "?Q ?S ?u (c*\<^sub>R x + y)"
   656     proof cases
   657       assume xS: "x \<in> S"
   658       have "sum (\<lambda>v. ?u v *\<^sub>R v) ?S = (\<Sum>v\<in>S - {x}. u v *\<^sub>R v) + (u x + c) *\<^sub>R x"
   659         using xS by (simp add: sum.remove [OF fS xS] insert_absorb)
   660       also have "\<dots> = (\<Sum>v\<in>S. u v *\<^sub>R v) + c *\<^sub>R x"
   661         by (simp add: sum.remove [OF fS xS] algebra_simps)
   662       also have "\<dots> = c*\<^sub>R x + y"
   663         by (simp add: add.commute u)
   664       finally have "sum (\<lambda>v. ?u v *\<^sub>R v) ?S = c*\<^sub>R x + y" .
   665       then show ?thesis using th0 by blast
   666     next
   667       assume xS: "x \<notin> S"
   668       have th00: "(\<Sum>v\<in>S. (if v = x then c else u v) *\<^sub>R v) = y"
   669         unfolding u[symmetric]
   670         apply (rule sum.cong)
   671         using xS
   672         apply auto
   673         done
   674       show ?thesis using fS xS th0
   675         by (simp add: th00 add.commute cong del: if_weak_cong)
   676     qed
   677     then show "?h (c*\<^sub>R x + y)"
   678       by fast
   679   qed
   680   ultimately show ?thesis by blast
   681 qed
   682 
   683 lemma dependent_explicit:
   684   "dependent P \<longleftrightarrow> (\<exists>S u. finite S \<and> S \<subseteq> P \<and> (\<exists>v\<in>S. u v \<noteq> 0 \<and> sum (\<lambda>v. u v *\<^sub>R v) S = 0))"
   685   (is "?lhs = ?rhs")
   686 proof -
   687   {
   688     assume dP: "dependent P"
   689     then obtain a S u where aP: "a \<in> P" and fS: "finite S"
   690       and SP: "S \<subseteq> P - {a}" and ua: "sum (\<lambda>v. u v *\<^sub>R v) S = a"
   691       unfolding dependent_def span_explicit by blast
   692     let ?S = "insert a S"
   693     let ?u = "\<lambda>y. if y = a then - 1 else u y"
   694     let ?v = a
   695     from aP SP have aS: "a \<notin> S"
   696       by blast
   697     from fS SP aP have th0: "finite ?S" "?S \<subseteq> P" "?v \<in> ?S" "?u ?v \<noteq> 0"
   698       by auto
   699     have s0: "sum (\<lambda>v. ?u v *\<^sub>R v) ?S = 0"
   700       using fS aS
   701       apply simp
   702       apply (subst (2) ua[symmetric])
   703       apply (rule sum.cong)
   704       apply auto
   705       done
   706     with th0 have ?rhs by fast
   707   }
   708   moreover
   709   {
   710     fix S u v
   711     assume fS: "finite S"
   712       and SP: "S \<subseteq> P"
   713       and vS: "v \<in> S"
   714       and uv: "u v \<noteq> 0"
   715       and u: "sum (\<lambda>v. u v *\<^sub>R v) S = 0"
   716     let ?a = v
   717     let ?S = "S - {v}"
   718     let ?u = "\<lambda>i. (- u i) / u v"
   719     have th0: "?a \<in> P" "finite ?S" "?S \<subseteq> P"
   720       using fS SP vS by auto
   721     have "sum (\<lambda>v. ?u v *\<^sub>R v) ?S =
   722       sum (\<lambda>v. (- (inverse (u ?a))) *\<^sub>R (u v *\<^sub>R v)) S - ?u v *\<^sub>R v"
   723       using fS vS uv by (simp add: sum_diff1 field_simps)
   724     also have "\<dots> = ?a"
   725       unfolding scaleR_right.sum [symmetric] u using uv by simp
   726     finally have "sum (\<lambda>v. ?u v *\<^sub>R v) ?S = ?a" .
   727     with th0 have ?lhs
   728       unfolding dependent_def span_explicit
   729       apply -
   730       apply (rule bexI[where x= "?a"])
   731       apply (simp_all del: scaleR_minus_left)
   732       apply (rule exI[where x= "?S"])
   733       apply (auto simp del: scaleR_minus_left)
   734       done
   735   }
   736   ultimately show ?thesis by blast
   737 qed
   738 
   739 lemma dependent_finite:
   740   assumes "finite S"
   741     shows "dependent S \<longleftrightarrow> (\<exists>u. (\<exists>v \<in> S. u v \<noteq> 0) \<and> (\<Sum>v\<in>S. u v *\<^sub>R v) = 0)"
   742            (is "?lhs = ?rhs")
   743 proof
   744   assume ?lhs
   745   then obtain T u v
   746          where "finite T" "T \<subseteq> S" "v\<in>T" "u v \<noteq> 0" "(\<Sum>v\<in>T. u v *\<^sub>R v) = 0"
   747     by (force simp: dependent_explicit)
   748   with assms show ?rhs
   749     apply (rule_tac x="\<lambda>v. if v \<in> T then u v else 0" in exI)
   750     apply (auto simp: sum.mono_neutral_right)
   751     done
   752 next
   753   assume ?rhs  with assms show ?lhs
   754     by (fastforce simp add: dependent_explicit)
   755 qed
   756 
   757 lemma span_alt:
   758   "span B = {(\<Sum>x | f x \<noteq> 0. f x *\<^sub>R x) | f. {x. f x \<noteq> 0} \<subseteq> B \<and> finite {x. f x \<noteq> 0}}"
   759   unfolding span_explicit
   760   apply safe
   761   subgoal for x S u
   762     by (intro exI[of _ "\<lambda>x. if x \<in> S then u x else 0"])
   763         (auto intro!: sum.mono_neutral_cong_right)
   764   apply auto
   765   done
   766 
   767 lemma dependent_alt:
   768   "dependent B \<longleftrightarrow>
   769     (\<exists>X. finite {x. X x \<noteq> 0} \<and> {x. X x \<noteq> 0} \<subseteq> B \<and> (\<Sum>x|X x \<noteq> 0. X x *\<^sub>R x) = 0 \<and> (\<exists>x. X x \<noteq> 0))"
   770   unfolding dependent_explicit
   771   apply safe
   772   subgoal for S u v
   773     apply (intro exI[of _ "\<lambda>x. if x \<in> S then u x else 0"])
   774     apply (subst sum.mono_neutral_cong_left[where T=S])
   775     apply (auto intro!: sum.mono_neutral_cong_right cong: rev_conj_cong)
   776     done
   777   apply auto
   778   done
   779 
   780 lemma independent_alt:
   781   "independent B \<longleftrightarrow>
   782     (\<forall>X. finite {x. X x \<noteq> 0} \<longrightarrow> {x. X x \<noteq> 0} \<subseteq> B \<longrightarrow> (\<Sum>x|X x \<noteq> 0. X x *\<^sub>R x) = 0 \<longrightarrow> (\<forall>x. X x = 0))"
   783   unfolding dependent_alt by auto
   784 
   785 lemma independentD_alt:
   786   "independent B \<Longrightarrow> finite {x. X x \<noteq> 0} \<Longrightarrow> {x. X x \<noteq> 0} \<subseteq> B \<Longrightarrow> (\<Sum>x|X x \<noteq> 0. X x *\<^sub>R x) = 0 \<Longrightarrow> X x = 0"
   787   unfolding independent_alt by blast
   788 
   789 lemma independentD_unique:
   790   assumes B: "independent B"
   791     and X: "finite {x. X x \<noteq> 0}" "{x. X x \<noteq> 0} \<subseteq> B"
   792     and Y: "finite {x. Y x \<noteq> 0}" "{x. Y x \<noteq> 0} \<subseteq> B"
   793     and "(\<Sum>x | X x \<noteq> 0. X x *\<^sub>R x) = (\<Sum>x| Y x \<noteq> 0. Y x *\<^sub>R x)"
   794   shows "X = Y"
   795 proof -
   796   have "X x - Y x = 0" for x
   797     using B
   798   proof (rule independentD_alt)
   799     have "{x. X x - Y x \<noteq> 0} \<subseteq> {x. X x \<noteq> 0} \<union> {x. Y x \<noteq> 0}"
   800       by auto
   801     then show "finite {x. X x - Y x \<noteq> 0}" "{x. X x - Y x \<noteq> 0} \<subseteq> B"
   802       using X Y by (auto dest: finite_subset)
   803     then have "(\<Sum>x | X x - Y x \<noteq> 0. (X x - Y x) *\<^sub>R x) = (\<Sum>v\<in>{S. X S \<noteq> 0} \<union> {S. Y S \<noteq> 0}. (X v - Y v) *\<^sub>R v)"
   804       using X Y by (intro sum.mono_neutral_cong_left) auto
   805     also have "\<dots> = (\<Sum>v\<in>{S. X S \<noteq> 0} \<union> {S. Y S \<noteq> 0}. X v *\<^sub>R v) - (\<Sum>v\<in>{S. X S \<noteq> 0} \<union> {S. Y S \<noteq> 0}. Y v *\<^sub>R v)"
   806       by (simp add: scaleR_diff_left sum_subtractf assms)
   807     also have "(\<Sum>v\<in>{S. X S \<noteq> 0} \<union> {S. Y S \<noteq> 0}. X v *\<^sub>R v) = (\<Sum>v\<in>{S. X S \<noteq> 0}. X v *\<^sub>R v)"
   808       using X Y by (intro sum.mono_neutral_cong_right) auto
   809     also have "(\<Sum>v\<in>{S. X S \<noteq> 0} \<union> {S. Y S \<noteq> 0}. Y v *\<^sub>R v) = (\<Sum>v\<in>{S. Y S \<noteq> 0}. Y v *\<^sub>R v)"
   810       using X Y by (intro sum.mono_neutral_cong_right) auto
   811     finally show "(\<Sum>x | X x - Y x \<noteq> 0. (X x - Y x) *\<^sub>R x) = 0"
   812       using assms by simp
   813   qed
   814   then show ?thesis
   815     by auto
   816 qed
   817 
   818 text \<open>This is useful for building a basis step-by-step.\<close>
   819 
   820 lemma independent_insert:
   821   "independent (insert a S) \<longleftrightarrow>
   822     (if a \<in> S then independent S else independent S \<and> a \<notin> span S)"
   823   (is "?lhs \<longleftrightarrow> ?rhs")
   824 proof (cases "a \<in> S")
   825   case True
   826   then show ?thesis
   827     using insert_absorb[OF True] by simp
   828 next
   829   case False
   830   show ?thesis
   831   proof
   832     assume i: ?lhs
   833     then show ?rhs
   834       using False
   835       apply simp
   836       apply (rule conjI)
   837       apply (rule independent_mono)
   838       apply assumption
   839       apply blast
   840       apply (simp add: dependent_def)
   841       done
   842   next
   843     assume i: ?rhs
   844     show ?lhs
   845       using i False
   846       apply (auto simp add: dependent_def)
   847       by (metis in_span_insert insert_Diff_if insert_Diff_single insert_absorb)
   848   qed
   849 qed
   850 
   851 lemma independent_Union_directed:
   852   assumes directed: "\<And>c d. c \<in> C \<Longrightarrow> d \<in> C \<Longrightarrow> c \<subseteq> d \<or> d \<subseteq> c"
   853   assumes indep: "\<And>c. c \<in> C \<Longrightarrow> independent c"
   854   shows "independent (\<Union>C)"
   855 proof
   856   assume "dependent (\<Union>C)"
   857   then obtain u v S where S: "finite S" "S \<subseteq> \<Union>C" "v \<in> S" "u v \<noteq> 0" "(\<Sum>v\<in>S. u v *\<^sub>R v) = 0"
   858     by (auto simp: dependent_explicit)
   859 
   860   have "S \<noteq> {}"
   861     using \<open>v \<in> S\<close> by auto
   862   have "\<exists>c\<in>C. S \<subseteq> c"
   863     using \<open>finite S\<close> \<open>S \<noteq> {}\<close> \<open>S \<subseteq> \<Union>C\<close>
   864   proof (induction rule: finite_ne_induct)
   865     case (insert i I)
   866     then obtain c d where cd: "c \<in> C" "d \<in> C" and iI: "I \<subseteq> c" "i \<in> d"
   867       by blast
   868     from directed[OF cd] cd have "c \<union> d \<in> C"
   869       by (auto simp: sup.absorb1 sup.absorb2)
   870     with iI show ?case
   871       by (intro bexI[of _ "c \<union> d"]) auto
   872   qed auto
   873   then obtain c where "c \<in> C" "S \<subseteq> c"
   874     by auto
   875   have "dependent c"
   876     unfolding dependent_explicit
   877     by (intro exI[of _ S] exI[of _ u] bexI[of _ v] conjI) fact+
   878   with indep[OF \<open>c \<in> C\<close>] show False
   879     by auto
   880 qed
   881 
   882 text \<open>Hence we can create a maximal independent subset.\<close>
   883 
   884 lemma maximal_independent_subset_extend:
   885   assumes "S \<subseteq> V" "independent S"
   886   shows "\<exists>B. S \<subseteq> B \<and> B \<subseteq> V \<and> independent B \<and> V \<subseteq> span B"
   887 proof -
   888   let ?C = "{B. S \<subseteq> B \<and> independent B \<and> B \<subseteq> V}"
   889   have "\<exists>M\<in>?C. \<forall>X\<in>?C. M \<subseteq> X \<longrightarrow> X = M"
   890   proof (rule subset_Zorn)
   891     fix C :: "'a set set" assume "subset.chain ?C C"
   892     then have C: "\<And>c. c \<in> C \<Longrightarrow> c \<subseteq> V" "\<And>c. c \<in> C \<Longrightarrow> S \<subseteq> c" "\<And>c. c \<in> C \<Longrightarrow> independent c"
   893       "\<And>c d. c \<in> C \<Longrightarrow> d \<in> C \<Longrightarrow> c \<subseteq> d \<or> d \<subseteq> c"
   894       unfolding subset.chain_def by blast+
   895 
   896     show "\<exists>U\<in>?C. \<forall>X\<in>C. X \<subseteq> U"
   897     proof cases
   898       assume "C = {}" with assms show ?thesis
   899         by (auto intro!: exI[of _ S])
   900     next
   901       assume "C \<noteq> {}"
   902       with C(2) have "S \<subseteq> \<Union>C"
   903         by auto
   904       moreover have "independent (\<Union>C)"
   905         by (intro independent_Union_directed C)
   906       moreover have "\<Union>C \<subseteq> V"
   907         using C by auto
   908       ultimately show ?thesis
   909         by auto
   910     qed
   911   qed
   912   then obtain B where B: "independent B" "B \<subseteq> V" "S \<subseteq> B"
   913     and max: "\<And>S. independent S \<Longrightarrow> S \<subseteq> V \<Longrightarrow> B \<subseteq> S \<Longrightarrow> S = B"
   914     by auto
   915   moreover
   916   { assume "\<not> V \<subseteq> span B"
   917     then obtain v where "v \<in> V" "v \<notin> span B"
   918       by auto
   919     with B have "independent (insert v B)"
   920       unfolding independent_insert by auto
   921     from max[OF this] \<open>v \<in> V\<close> \<open>B \<subseteq> V\<close>
   922     have "v \<in> B"
   923       by auto
   924     with \<open>v \<notin> span B\<close> have False
   925       by (auto intro: span_superset) }
   926   ultimately show ?thesis
   927     by (auto intro!: exI[of _ B])
   928 qed
   929 
   930 
   931 lemma maximal_independent_subset:
   932   "\<exists>B. B \<subseteq> V \<and> independent B \<and> V \<subseteq> span B"
   933   by (metis maximal_independent_subset_extend[of "{}"] empty_subsetI independent_empty)
   934 
   935 lemma span_finite:
   936   assumes fS: "finite S"
   937   shows "span S = {y. \<exists>u. sum (\<lambda>v. u v *\<^sub>R v) S = y}"
   938   (is "_ = ?rhs")
   939 proof -
   940   {
   941     fix y
   942     assume y: "y \<in> span S"
   943     from y obtain S' u where fS': "finite S'"
   944       and SS': "S' \<subseteq> S"
   945       and u: "sum (\<lambda>v. u v *\<^sub>R v) S' = y"
   946       unfolding span_explicit by blast
   947     let ?u = "\<lambda>x. if x \<in> S' then u x else 0"
   948     have "sum (\<lambda>v. ?u v *\<^sub>R v) S = sum (\<lambda>v. u v *\<^sub>R v) S'"
   949       using SS' fS by (auto intro!: sum.mono_neutral_cong_right)
   950     then have "sum (\<lambda>v. ?u v *\<^sub>R v) S = y" by (metis u)
   951     then have "y \<in> ?rhs" by auto
   952   }
   953   moreover
   954   {
   955     fix y u
   956     assume u: "sum (\<lambda>v. u v *\<^sub>R v) S = y"
   957     then have "y \<in> span S" using fS unfolding span_explicit by auto
   958   }
   959   ultimately show ?thesis by blast
   960 qed
   961 
   962 lemma linear_independent_extend_subspace:
   963   assumes "independent B"
   964   shows "\<exists>g. linear g \<and> (\<forall>x\<in>B. g x = f x) \<and> range g = span (f`B)"
   965 proof -
   966   from maximal_independent_subset_extend[OF _ \<open>independent B\<close>, of UNIV]
   967   obtain B' where "B \<subseteq> B'" "independent B'" "span B' = UNIV"
   968     by (auto simp: top_unique)
   969   have "\<forall>y. \<exists>X. {x. X x \<noteq> 0} \<subseteq> B' \<and> finite {x. X x \<noteq> 0} \<and> y = (\<Sum>x|X x \<noteq> 0. X x *\<^sub>R x)"
   970     using \<open>span B' = UNIV\<close> unfolding span_alt by auto
   971   then obtain X where X: "\<And>y. {x. X y x \<noteq> 0} \<subseteq> B'" "\<And>y. finite {x. X y x \<noteq> 0}"
   972     "\<And>y. y = (\<Sum>x|X y x \<noteq> 0. X y x *\<^sub>R x)"
   973     unfolding choice_iff by auto
   974 
   975   have X_add: "X (x + y) = (\<lambda>z. X x z + X y z)" for x y
   976     using \<open>independent B'\<close>
   977   proof (rule independentD_unique)
   978     have "(\<Sum>z | X x z + X y z \<noteq> 0. (X x z + X y z) *\<^sub>R z)
   979       = (\<Sum>z\<in>{z. X x z \<noteq> 0} \<union> {z. X y z \<noteq> 0}. (X x z + X y z) *\<^sub>R z)"
   980       by (intro sum.mono_neutral_cong_left) (auto intro: X)
   981     also have "\<dots> = (\<Sum>z\<in>{z. X x z \<noteq> 0}. X x z *\<^sub>R z) + (\<Sum>z\<in>{z. X y z \<noteq> 0}. X y z *\<^sub>R z)"
   982       by (auto simp add: scaleR_add_left sum.distrib
   983                intro!: arg_cong2[where f="op +"]  sum.mono_neutral_cong_right X)
   984     also have "\<dots> = x + y"
   985       by (simp add: X(3)[symmetric])
   986     also have "\<dots> = (\<Sum>z | X (x + y) z \<noteq> 0. X (x + y) z *\<^sub>R z)"
   987       by (rule X(3))
   988     finally show "(\<Sum>z | X (x + y) z \<noteq> 0. X (x + y) z *\<^sub>R z) = (\<Sum>z | X x z + X y z \<noteq> 0. (X x z + X y z) *\<^sub>R z)"
   989       ..
   990     have "{z. X x z + X y z \<noteq> 0} \<subseteq> {z. X x z \<noteq> 0} \<union> {z. X y z \<noteq> 0}"
   991       by auto
   992     then show "finite {z. X x z + X y z \<noteq> 0}" "{xa. X x xa + X y xa \<noteq> 0} \<subseteq> B'"
   993         "finite {xa. X (x + y) xa \<noteq> 0}" "{xa. X (x + y) xa \<noteq> 0} \<subseteq> B'"
   994       using X(1) by (auto dest: finite_subset intro: X)
   995   qed
   996 
   997   have X_cmult: "X (c *\<^sub>R x) = (\<lambda>z. c * X x z)" for x c
   998     using \<open>independent B'\<close>
   999   proof (rule independentD_unique)
  1000     show "finite {z. X (c *\<^sub>R x) z \<noteq> 0}" "{z. X (c *\<^sub>R x) z \<noteq> 0} \<subseteq> B'"
  1001       "finite {z. c * X x z \<noteq> 0}" "{z. c * X x z \<noteq> 0} \<subseteq> B' "
  1002       using X(1,2) by auto
  1003     show "(\<Sum>z | X (c *\<^sub>R x) z \<noteq> 0. X (c *\<^sub>R x) z *\<^sub>R z) = (\<Sum>z | c * X x z \<noteq> 0. (c * X x z) *\<^sub>R z)"
  1004       unfolding scaleR_scaleR[symmetric] scaleR_sum_right[symmetric]
  1005       by (cases "c = 0") (auto simp: X(3)[symmetric])
  1006   qed
  1007 
  1008   have X_B': "x \<in> B' \<Longrightarrow> X x = (\<lambda>z. if z = x then 1 else 0)" for x
  1009     using \<open>independent B'\<close>
  1010     by (rule independentD_unique[OF _ X(2) X(1)]) (auto intro: X simp: X(3)[symmetric])
  1011 
  1012   define f' where "f' y = (if y \<in> B then f y else 0)" for y
  1013   define g where "g y = (\<Sum>x|X y x \<noteq> 0. X y x *\<^sub>R f' x)" for y
  1014 
  1015   have g_f': "x \<in> B' \<Longrightarrow> g x = f' x" for x
  1016     by (auto simp: g_def X_B')
  1017 
  1018   have "linear g"
  1019   proof
  1020     fix x y
  1021     have *: "(\<Sum>z | X x z + X y z \<noteq> 0. (X x z + X y z) *\<^sub>R f' z)
  1022       = (\<Sum>z\<in>{z. X x z \<noteq> 0} \<union> {z. X y z \<noteq> 0}. (X x z + X y z) *\<^sub>R f' z)"
  1023       by (intro sum.mono_neutral_cong_left) (auto intro: X)
  1024     show "g (x + y) = g x + g y"
  1025       unfolding g_def X_add *
  1026       by (auto simp add: scaleR_add_left sum.distrib
  1027                intro!: arg_cong2[where f="op +"]  sum.mono_neutral_cong_right X)
  1028   next
  1029     show "g (r *\<^sub>R x) = r *\<^sub>R g x" for r x
  1030       by (auto simp add: g_def X_cmult scaleR_sum_right intro!: sum.mono_neutral_cong_left X)
  1031   qed
  1032   moreover have "\<forall>x\<in>B. g x = f x"
  1033     using \<open>B \<subseteq> B'\<close> by (auto simp: g_f' f'_def)
  1034   moreover have "range g = span (f`B)"
  1035     unfolding \<open>span B' = UNIV\<close>[symmetric] span_linear_image[OF \<open>linear g\<close>, symmetric]
  1036   proof (rule span_subspace)
  1037     have "g ` B' \<subseteq> f`B \<union> {0}"
  1038       by (auto simp: g_f' f'_def)
  1039     also have "\<dots> \<subseteq> span (f`B)"
  1040       by (auto intro: span_superset span_0)
  1041     finally show "g ` B' \<subseteq> span (f`B)"
  1042       by auto
  1043     have "x \<in> B \<Longrightarrow> f x = g x" for x
  1044       using \<open>B \<subseteq> B'\<close> by (auto simp add: g_f' f'_def)
  1045     then show "span (f ` B) \<subseteq> span (g ` B')"
  1046       using \<open>B \<subseteq> B'\<close> by (intro span_mono) auto
  1047   qed (rule subspace_span)
  1048   ultimately show ?thesis
  1049     by auto
  1050 qed
  1051 
  1052 lemma linear_independent_extend:
  1053   "independent B \<Longrightarrow> \<exists>g. linear g \<and> (\<forall>x\<in>B. g x = f x)"
  1054   using linear_independent_extend_subspace[of B f] by auto
  1055 
  1056 text \<open>Linear functions are equal on a subspace if they are on a spanning set.\<close>
  1057 
  1058 lemma subspace_kernel:
  1059   assumes lf: "linear f"
  1060   shows "subspace {x. f x = 0}"
  1061   apply (simp add: subspace_def)
  1062   apply (simp add: linear_add[OF lf] linear_cmul[OF lf] linear_0[OF lf])
  1063   done
  1064 
  1065 lemma linear_eq_0_span:
  1066   assumes lf: "linear f" and f0: "\<forall>x\<in>B. f x = 0"
  1067   shows "\<forall>x \<in> span B. f x = 0"
  1068   using f0 subspace_kernel[OF lf]
  1069   by (rule span_induct')
  1070 
  1071 lemma linear_eq_0: "linear f \<Longrightarrow> S \<subseteq> span B \<Longrightarrow> \<forall>x\<in>B. f x = 0 \<Longrightarrow> \<forall>x\<in>S. f x = 0"
  1072   using linear_eq_0_span[of f B] by auto
  1073 
  1074 lemma linear_eq_span:  "linear f \<Longrightarrow> linear g \<Longrightarrow> \<forall>x\<in>B. f x = g x \<Longrightarrow> \<forall>x \<in> span B. f x = g x"
  1075   using linear_eq_0_span[of "\<lambda>x. f x - g x" B] by (auto simp: linear_compose_sub)
  1076 
  1077 lemma linear_eq: "linear f \<Longrightarrow> linear g \<Longrightarrow> S \<subseteq> span B \<Longrightarrow> \<forall>x\<in>B. f x = g x \<Longrightarrow> \<forall>x\<in>S. f x = g x"
  1078   using linear_eq_span[of f g B] by auto
  1079 
  1080 text \<open>The degenerate case of the Exchange Lemma.\<close>
  1081 
  1082 lemma spanning_subset_independent:
  1083   assumes BA: "B \<subseteq> A"
  1084     and iA: "independent A"
  1085     and AsB: "A \<subseteq> span B"
  1086   shows "A = B"
  1087 proof
  1088   show "B \<subseteq> A" by (rule BA)
  1089 
  1090   from span_mono[OF BA] span_mono[OF AsB]
  1091   have sAB: "span A = span B" unfolding span_span by blast
  1092 
  1093   {
  1094     fix x
  1095     assume x: "x \<in> A"
  1096     from iA have th0: "x \<notin> span (A - {x})"
  1097       unfolding dependent_def using x by blast
  1098     from x have xsA: "x \<in> span A"
  1099       by (blast intro: span_superset)
  1100     have "A - {x} \<subseteq> A" by blast
  1101     then have th1: "span (A - {x}) \<subseteq> span A"
  1102       by (metis span_mono)
  1103     {
  1104       assume xB: "x \<notin> B"
  1105       from xB BA have "B \<subseteq> A - {x}"
  1106         by blast
  1107       then have "span B \<subseteq> span (A - {x})"
  1108         by (metis span_mono)
  1109       with th1 th0 sAB have "x \<notin> span A"
  1110         by blast
  1111       with x have False
  1112         by (metis span_superset)
  1113     }
  1114     then have "x \<in> B" by blast
  1115   }
  1116   then show "A \<subseteq> B" by blast
  1117 qed
  1118 
  1119 text \<open>Relation between bases and injectivity/surjectivity of map.\<close>
  1120 
  1121 lemma spanning_surjective_image:
  1122   assumes us: "UNIV \<subseteq> span S"
  1123     and lf: "linear f"
  1124     and sf: "surj f"
  1125   shows "UNIV \<subseteq> span (f ` S)"
  1126 proof -
  1127   have "UNIV \<subseteq> f ` UNIV"
  1128     using sf by (auto simp add: surj_def)
  1129   also have " \<dots> \<subseteq> span (f ` S)"
  1130     using spans_image[OF lf us] .
  1131   finally show ?thesis .
  1132 qed
  1133 
  1134 lemma independent_inj_on_image:
  1135   assumes iS: "independent S"
  1136     and lf: "linear f"
  1137     and fi: "inj_on f (span S)"
  1138   shows "independent (f ` S)"
  1139 proof -
  1140   {
  1141     fix a
  1142     assume a: "a \<in> S" "f a \<in> span (f ` S - {f a})"
  1143     have eq: "f ` S - {f a} = f ` (S - {a})"
  1144       using fi \<open>a\<in>S\<close> by (auto simp add: inj_on_def span_superset)
  1145     from a have "f a \<in> f ` span (S - {a})"
  1146       unfolding eq span_linear_image[OF lf, of "S - {a}"] by blast
  1147     then have "a \<in> span (S - {a})"
  1148       by (rule inj_on_image_mem_iff_alt[OF fi, rotated])
  1149          (insert span_mono[of "S - {a}" S], auto intro: span_superset \<open>a\<in>S\<close>)
  1150     with a(1) iS have False
  1151       by (simp add: dependent_def)
  1152   }
  1153   then show ?thesis
  1154     unfolding dependent_def by blast
  1155 qed
  1156 
  1157 lemma independent_injective_image:
  1158   "independent S \<Longrightarrow> linear f \<Longrightarrow> inj f \<Longrightarrow> independent (f ` S)"
  1159   using independent_inj_on_image[of S f] by (auto simp: subset_inj_on)
  1160 
  1161 text \<open>Detailed theorems about left and right invertibility in general case.\<close>
  1162 
  1163 lemma linear_inj_on_left_inverse:
  1164   assumes lf: "linear f" and fi: "inj_on f (span S)"
  1165   shows "\<exists>g. range g \<subseteq> span S \<and> linear g \<and> (\<forall>x\<in>span S. g (f x) = x)"
  1166 proof -
  1167   obtain B where "independent B" "B \<subseteq> S" "S \<subseteq> span B"
  1168     using maximal_independent_subset[of S] by auto
  1169   then have "span S = span B"
  1170     unfolding span_eq by (auto simp: span_superset)
  1171   with linear_independent_extend_subspace[OF independent_inj_on_image, OF \<open>independent B\<close> lf] fi
  1172   obtain g where g: "linear g" "\<forall>x\<in>f ` B. g x = inv_into B f x" "range g = span (inv_into B f ` f ` B)"
  1173     by fastforce
  1174   have fB: "inj_on f B"
  1175     using fi by (auto simp: \<open>span S = span B\<close> intro: subset_inj_on span_superset)
  1176 
  1177   have "\<forall>x\<in>span B. g (f x) = x"
  1178   proof (intro linear_eq_span)
  1179     show "linear (\<lambda>x. x)" "linear (\<lambda>x. g (f x))"
  1180       using linear_id linear_compose[OF \<open>linear f\<close> \<open>linear g\<close>] by (auto simp: id_def comp_def)
  1181     show "\<forall>x \<in> B. g (f x) = x"
  1182       using g fi \<open>span S = span B\<close> by (auto simp: fB)
  1183   qed
  1184   moreover
  1185   have "inv_into B f ` f ` B \<subseteq> B"
  1186     by (auto simp: fB)
  1187   then have "range g \<subseteq> span S"
  1188     unfolding g \<open>span S = span B\<close> by (intro span_mono)
  1189   ultimately show ?thesis
  1190     using \<open>span S = span B\<close> \<open>linear g\<close> by auto
  1191 qed
  1192 
  1193 lemma linear_injective_left_inverse: "linear f \<Longrightarrow> inj f \<Longrightarrow> \<exists>g. linear g \<and> g \<circ> f = id"
  1194   using linear_inj_on_left_inverse[of f UNIV] by (auto simp: fun_eq_iff span_UNIV)
  1195 
  1196 lemma linear_surj_right_inverse:
  1197   assumes lf: "linear f" and sf: "span T \<subseteq> f`span S"
  1198   shows "\<exists>g. range g \<subseteq> span S \<and> linear g \<and> (\<forall>x\<in>span T. f (g x) = x)"
  1199 proof -
  1200   obtain B where "independent B" "B \<subseteq> T" "T \<subseteq> span B"
  1201     using maximal_independent_subset[of T] by auto
  1202   then have "span T = span B"
  1203     unfolding span_eq by (auto simp: span_superset)
  1204 
  1205   from linear_independent_extend_subspace[OF \<open>independent B\<close>, of "inv_into (span S) f"]
  1206   obtain g where g: "linear g" "\<forall>x\<in>B. g x = inv_into (span S) f x" "range g = span (inv_into (span S) f`B)"
  1207     by auto
  1208   moreover have "x \<in> B \<Longrightarrow> f (inv_into (span S) f x) = x" for x
  1209     using \<open>B \<subseteq> T\<close> \<open>span T \<subseteq> f`span S\<close> by (intro f_inv_into_f) (auto intro: span_superset)
  1210   ultimately have "\<forall>x\<in>B. f (g x) = x"
  1211     by auto
  1212   then have "\<forall>x\<in>span B. f (g x) = x"
  1213     using linear_id linear_compose[OF \<open>linear g\<close> \<open>linear f\<close>]
  1214     by (intro linear_eq_span) (auto simp: id_def comp_def)
  1215   moreover have "inv_into (span S) f ` B \<subseteq> span S"
  1216     using \<open>B \<subseteq> T\<close> \<open>span T \<subseteq> f`span S\<close> by (auto intro: inv_into_into span_superset)
  1217   then have "range g \<subseteq> span S"
  1218     unfolding g by (intro span_minimal subspace_span) auto
  1219   ultimately show ?thesis
  1220     using \<open>linear g\<close> \<open>span T = span B\<close> by auto
  1221 qed
  1222 
  1223 lemma linear_surjective_right_inverse: "linear f \<Longrightarrow> surj f \<Longrightarrow> \<exists>g. linear g \<and> f \<circ> g = id"
  1224   using linear_surj_right_inverse[of f UNIV UNIV]
  1225   by (auto simp: span_UNIV fun_eq_iff)
  1226 
  1227 text \<open>The general case of the Exchange Lemma, the key to what follows.\<close>
  1228 
  1229 lemma exchange_lemma:
  1230   assumes f:"finite t"
  1231     and i: "independent s"
  1232     and sp: "s \<subseteq> span t"
  1233   shows "\<exists>t'. card t' = card t \<and> finite t' \<and> s \<subseteq> t' \<and> t' \<subseteq> s \<union> t \<and> s \<subseteq> span t'"
  1234   using f i sp
  1235 proof (induct "card (t - s)" arbitrary: s t rule: less_induct)
  1236   case less
  1237   note ft = \<open>finite t\<close> and s = \<open>independent s\<close> and sp = \<open>s \<subseteq> span t\<close>
  1238   let ?P = "\<lambda>t'. card t' = card t \<and> finite t' \<and> s \<subseteq> t' \<and> t' \<subseteq> s \<union> t \<and> s \<subseteq> span t'"
  1239   let ?ths = "\<exists>t'. ?P t'"
  1240   {
  1241     assume "s \<subseteq> t"
  1242     then have ?ths
  1243       by (metis ft Un_commute sp sup_ge1)
  1244   }
  1245   moreover
  1246   {
  1247     assume st: "t \<subseteq> s"
  1248     from spanning_subset_independent[OF st s sp] st ft span_mono[OF st]
  1249     have ?ths
  1250       by (metis Un_absorb sp)
  1251   }
  1252   moreover
  1253   {
  1254     assume st: "\<not> s \<subseteq> t" "\<not> t \<subseteq> s"
  1255     from st(2) obtain b where b: "b \<in> t" "b \<notin> s"
  1256       by blast
  1257     from b have "t - {b} - s \<subset> t - s"
  1258       by blast
  1259     then have cardlt: "card (t - {b} - s) < card (t - s)"
  1260       using ft by (auto intro: psubset_card_mono)
  1261     from b ft have ct0: "card t \<noteq> 0"
  1262       by auto
  1263     have ?ths
  1264     proof cases
  1265       assume stb: "s \<subseteq> span (t - {b})"
  1266       from ft have ftb: "finite (t - {b})"
  1267         by auto
  1268       from less(1)[OF cardlt ftb s stb]
  1269       obtain u where u: "card u = card (t - {b})" "s \<subseteq> u" "u \<subseteq> s \<union> (t - {b})" "s \<subseteq> span u"
  1270         and fu: "finite u" by blast
  1271       let ?w = "insert b u"
  1272       have th0: "s \<subseteq> insert b u"
  1273         using u by blast
  1274       from u(3) b have "u \<subseteq> s \<union> t"
  1275         by blast
  1276       then have th1: "insert b u \<subseteq> s \<union> t"
  1277         using u b by blast
  1278       have bu: "b \<notin> u"
  1279         using b u by blast
  1280       from u(1) ft b have "card u = (card t - 1)"
  1281         by auto
  1282       then have th2: "card (insert b u) = card t"
  1283         using card_insert_disjoint[OF fu bu] ct0 by auto
  1284       from u(4) have "s \<subseteq> span u" .
  1285       also have "\<dots> \<subseteq> span (insert b u)"
  1286         by (rule span_mono) blast
  1287       finally have th3: "s \<subseteq> span (insert b u)" .
  1288       from th0 th1 th2 th3 fu have th: "?P ?w"
  1289         by blast
  1290       from th show ?thesis by blast
  1291     next
  1292       assume stb: "\<not> s \<subseteq> span (t - {b})"
  1293       from stb obtain a where a: "a \<in> s" "a \<notin> span (t - {b})"
  1294         by blast
  1295       have ab: "a \<noteq> b"
  1296         using a b by blast
  1297       have at: "a \<notin> t"
  1298         using a ab span_superset[of a "t- {b}"] by auto
  1299       have mlt: "card ((insert a (t - {b})) - s) < card (t - s)"
  1300         using cardlt ft a b by auto
  1301       have ft': "finite (insert a (t - {b}))"
  1302         using ft by auto
  1303       {
  1304         fix x
  1305         assume xs: "x \<in> s"
  1306         have t: "t \<subseteq> insert b (insert a (t - {b}))"
  1307           using b by auto
  1308         from b(1) have "b \<in> span t"
  1309           by (simp add: span_superset)
  1310         have bs: "b \<in> span (insert a (t - {b}))"
  1311           apply (rule in_span_delete)
  1312           using a sp unfolding subset_eq
  1313           apply auto
  1314           done
  1315         from xs sp have "x \<in> span t"
  1316           by blast
  1317         with span_mono[OF t] have x: "x \<in> span (insert b (insert a (t - {b})))" ..
  1318         from span_trans[OF bs x] have "x \<in> span (insert a (t - {b}))" .
  1319       }
  1320       then have sp': "s \<subseteq> span (insert a (t - {b}))"
  1321         by blast
  1322       from less(1)[OF mlt ft' s sp'] obtain u where u:
  1323         "card u = card (insert a (t - {b}))"
  1324         "finite u" "s \<subseteq> u" "u \<subseteq> s \<union> insert a (t - {b})"
  1325         "s \<subseteq> span u" by blast
  1326       from u a b ft at ct0 have "?P u"
  1327         by auto
  1328       then show ?thesis by blast
  1329     qed
  1330   }
  1331   ultimately show ?ths by blast
  1332 qed
  1333 
  1334 text \<open>This implies corresponding size bounds.\<close>
  1335 
  1336 lemma independent_span_bound:
  1337   assumes f: "finite t"
  1338     and i: "independent s"
  1339     and sp: "s \<subseteq> span t"
  1340   shows "finite s \<and> card s \<le> card t"
  1341   by (metis exchange_lemma[OF f i sp] finite_subset card_mono)
  1342 
  1343 lemma finite_Atleast_Atmost_nat[simp]: "finite {f x |x. x\<in> (UNIV::'a::finite set)}"
  1344 proof -
  1345   have eq: "{f x |x. x\<in> UNIV} = f ` UNIV"
  1346     by auto
  1347   show ?thesis unfolding eq
  1348     apply (rule finite_imageI)
  1349     apply (rule finite)
  1350     done
  1351 qed
  1352 
  1353 
  1354 subsection \<open>More interesting properties of the norm.\<close>
  1355 
  1356 lemma cond_application_beta: "(if b then f else g) x = (if b then f x else g x)"
  1357   by auto
  1358 
  1359 notation inner (infix "\<bullet>" 70)
  1360 
  1361 lemma square_bound_lemma:
  1362   fixes x :: real
  1363   shows "x < (1 + x) * (1 + x)"
  1364 proof -
  1365   have "(x + 1/2)\<^sup>2 + 3/4 > 0"
  1366     using zero_le_power2[of "x+1/2"] by arith
  1367   then show ?thesis
  1368     by (simp add: field_simps power2_eq_square)
  1369 qed
  1370 
  1371 lemma square_continuous:
  1372   fixes e :: real
  1373   shows "e > 0 \<Longrightarrow> \<exists>d. 0 < d \<and> (\<forall>y. \<bar>y - x\<bar> < d \<longrightarrow> \<bar>y * y - x * x\<bar> < e)"
  1374   using isCont_power[OF continuous_ident, of x, unfolded isCont_def LIM_eq, rule_format, of e 2]
  1375   by (force simp add: power2_eq_square)
  1376 
  1377 
  1378 lemma norm_eq_0_dot: "norm x = 0 \<longleftrightarrow> x \<bullet> x = (0::real)"
  1379   by simp (* TODO: delete *)
  1380 
  1381 lemma norm_triangle_sub:
  1382   fixes x y :: "'a::real_normed_vector"
  1383   shows "norm x \<le> norm y + norm (x - y)"
  1384   using norm_triangle_ineq[of "y" "x - y"] by (simp add: field_simps)
  1385 
  1386 lemma norm_le: "norm x \<le> norm y \<longleftrightarrow> x \<bullet> x \<le> y \<bullet> y"
  1387   by (simp add: norm_eq_sqrt_inner)
  1388 
  1389 lemma norm_lt: "norm x < norm y \<longleftrightarrow> x \<bullet> x < y \<bullet> y"
  1390   by (simp add: norm_eq_sqrt_inner)
  1391 
  1392 lemma norm_eq: "norm x = norm y \<longleftrightarrow> x \<bullet> x = y \<bullet> y"
  1393   apply (subst order_eq_iff)
  1394   apply (auto simp: norm_le)
  1395   done
  1396 
  1397 lemma norm_eq_1: "norm x = 1 \<longleftrightarrow> x \<bullet> x = 1"
  1398   by (simp add: norm_eq_sqrt_inner)
  1399 
  1400 
  1401 text\<open>Equality of vectors in terms of @{term "op \<bullet>"} products.\<close>
  1402 
  1403 lemma linear_componentwise:
  1404   fixes f:: "'a::euclidean_space \<Rightarrow> 'b::real_inner"
  1405   assumes lf: "linear f"
  1406   shows "(f x) \<bullet> j = (\<Sum>i\<in>Basis. (x\<bullet>i) * (f i\<bullet>j))" (is "?lhs = ?rhs")
  1407 proof -
  1408   have "?rhs = (\<Sum>i\<in>Basis. (x\<bullet>i) *\<^sub>R (f i))\<bullet>j"
  1409     by (simp add: inner_sum_left)
  1410   then show ?thesis
  1411     unfolding linear_sum_mul[OF lf, symmetric]
  1412     unfolding euclidean_representation ..
  1413 qed
  1414 
  1415 lemma vector_eq: "x = y \<longleftrightarrow> x \<bullet> x = x \<bullet> y \<and> y \<bullet> y = x \<bullet> x"
  1416   (is "?lhs \<longleftrightarrow> ?rhs")
  1417 proof
  1418   assume ?lhs
  1419   then show ?rhs by simp
  1420 next
  1421   assume ?rhs
  1422   then have "x \<bullet> x - x \<bullet> y = 0 \<and> x \<bullet> y - y \<bullet> y = 0"
  1423     by simp
  1424   then have "x \<bullet> (x - y) = 0 \<and> y \<bullet> (x - y) = 0"
  1425     by (simp add: inner_diff inner_commute)
  1426   then have "(x - y) \<bullet> (x - y) = 0"
  1427     by (simp add: field_simps inner_diff inner_commute)
  1428   then show "x = y" by simp
  1429 qed
  1430 
  1431 lemma norm_triangle_half_r:
  1432   "norm (y - x1) < e / 2 \<Longrightarrow> norm (y - x2) < e / 2 \<Longrightarrow> norm (x1 - x2) < e"
  1433   using dist_triangle_half_r unfolding dist_norm[symmetric] by auto
  1434 
  1435 lemma norm_triangle_half_l:
  1436   assumes "norm (x - y) < e / 2"
  1437     and "norm (x' - y) < e / 2"
  1438   shows "norm (x - x') < e"
  1439   using dist_triangle_half_l[OF assms[unfolded dist_norm[symmetric]]]
  1440   unfolding dist_norm[symmetric] .
  1441 
  1442 lemma norm_triangle_le: "norm x + norm y \<le> e \<Longrightarrow> norm (x + y) \<le> e"
  1443   by (rule norm_triangle_ineq [THEN order_trans])
  1444 
  1445 lemma norm_triangle_lt: "norm x + norm y < e \<Longrightarrow> norm (x + y) < e"
  1446   by (rule norm_triangle_ineq [THEN le_less_trans])
  1447 
  1448 lemma abs_triangle_half_r:
  1449   fixes y :: "'a::linordered_field"
  1450   shows "abs (y - x1) < e / 2 \<Longrightarrow> abs (y - x2) < e / 2 \<Longrightarrow> abs (x1 - x2) < e"
  1451   by linarith
  1452 
  1453 lemma abs_triangle_half_l:
  1454   fixes y :: "'a::linordered_field"
  1455   assumes "abs (x - y) < e / 2"
  1456     and "abs (x' - y) < e / 2"
  1457   shows "abs (x - x') < e"
  1458   using assms by linarith
  1459 
  1460 lemma eps_leI: 
  1461   assumes "(\<And>e::'a::linordered_idom. 0 < e \<Longrightarrow> x < y + e)" shows "x \<le> y"
  1462   by (metis add_diff_eq assms diff_diff_add diff_gt_0_iff_gt linorder_not_less order_less_irrefl)
  1463 
  1464 lemma sum_clauses:
  1465   shows "sum f {} = 0"
  1466     and "finite S \<Longrightarrow> sum f (insert x S) = (if x \<in> S then sum f S else f x + sum f S)"
  1467   by (auto simp add: insert_absorb)
  1468 
  1469 lemma sum_norm_bound:
  1470   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1471   assumes K: "\<And>x. x \<in> S \<Longrightarrow> norm (f x) \<le> K"
  1472   shows "norm (sum f S) \<le> of_nat (card S)*K"
  1473   using sum_norm_le[OF K] sum_constant[symmetric]
  1474   by simp
  1475 
  1476 lemma sum_group:
  1477   assumes fS: "finite S" and fT: "finite T" and fST: "f ` S \<subseteq> T"
  1478   shows "sum (\<lambda>y. sum g {x. x \<in> S \<and> f x = y}) T = sum g S"
  1479   apply (subst sum_image_gen[OF fS, of g f])
  1480   apply (rule sum.mono_neutral_right[OF fT fST])
  1481   apply (auto intro: sum.neutral)
  1482   done
  1483 
  1484 lemma vector_eq_ldot: "(\<forall>x. x \<bullet> y = x \<bullet> z) \<longleftrightarrow> y = z"
  1485 proof
  1486   assume "\<forall>x. x \<bullet> y = x \<bullet> z"
  1487   then have "\<forall>x. x \<bullet> (y - z) = 0"
  1488     by (simp add: inner_diff)
  1489   then have "(y - z) \<bullet> (y - z) = 0" ..
  1490   then show "y = z" by simp
  1491 qed simp
  1492 
  1493 lemma vector_eq_rdot: "(\<forall>z. x \<bullet> z = y \<bullet> z) \<longleftrightarrow> x = y"
  1494 proof
  1495   assume "\<forall>z. x \<bullet> z = y \<bullet> z"
  1496   then have "\<forall>z. (x - y) \<bullet> z = 0"
  1497     by (simp add: inner_diff)
  1498   then have "(x - y) \<bullet> (x - y) = 0" ..
  1499   then show "x = y" by simp
  1500 qed simp
  1501 
  1502 
  1503 subsection \<open>Orthogonality.\<close>
  1504 
  1505 context real_inner
  1506 begin
  1507 
  1508 definition "orthogonal x y \<longleftrightarrow> x \<bullet> y = 0"
  1509 
  1510 lemma orthogonal_self: "orthogonal x x \<longleftrightarrow> x = 0"
  1511   by (simp add: orthogonal_def)
  1512 
  1513 lemma orthogonal_clauses:
  1514   "orthogonal a 0"
  1515   "orthogonal a x \<Longrightarrow> orthogonal a (c *\<^sub>R x)"
  1516   "orthogonal a x \<Longrightarrow> orthogonal a (- x)"
  1517   "orthogonal a x \<Longrightarrow> orthogonal a y \<Longrightarrow> orthogonal a (x + y)"
  1518   "orthogonal a x \<Longrightarrow> orthogonal a y \<Longrightarrow> orthogonal a (x - y)"
  1519   "orthogonal 0 a"
  1520   "orthogonal x a \<Longrightarrow> orthogonal (c *\<^sub>R x) a"
  1521   "orthogonal x a \<Longrightarrow> orthogonal (- x) a"
  1522   "orthogonal x a \<Longrightarrow> orthogonal y a \<Longrightarrow> orthogonal (x + y) a"
  1523   "orthogonal x a \<Longrightarrow> orthogonal y a \<Longrightarrow> orthogonal (x - y) a"
  1524   unfolding orthogonal_def inner_add inner_diff by auto
  1525 
  1526 end
  1527 
  1528 lemma orthogonal_commute: "orthogonal x y \<longleftrightarrow> orthogonal y x"
  1529   by (simp add: orthogonal_def inner_commute)
  1530 
  1531 lemma orthogonal_scaleR [simp]: "c \<noteq> 0 \<Longrightarrow> orthogonal (c *\<^sub>R x) = orthogonal x"
  1532   by (rule ext) (simp add: orthogonal_def)
  1533 
  1534 lemma pairwise_ortho_scaleR:
  1535     "pairwise (\<lambda>i j. orthogonal (f i) (g j)) B
  1536     \<Longrightarrow> pairwise (\<lambda>i j. orthogonal (a i *\<^sub>R f i) (a j *\<^sub>R g j)) B"
  1537   by (auto simp: pairwise_def orthogonal_clauses)
  1538 
  1539 lemma orthogonal_rvsum:
  1540     "\<lbrakk>finite s; \<And>y. y \<in> s \<Longrightarrow> orthogonal x (f y)\<rbrakk> \<Longrightarrow> orthogonal x (sum f s)"
  1541   by (induction s rule: finite_induct) (auto simp: orthogonal_clauses)
  1542 
  1543 lemma orthogonal_lvsum:
  1544     "\<lbrakk>finite s; \<And>x. x \<in> s \<Longrightarrow> orthogonal (f x) y\<rbrakk> \<Longrightarrow> orthogonal (sum f s) y"
  1545   by (induction s rule: finite_induct) (auto simp: orthogonal_clauses)
  1546 
  1547 lemma norm_add_Pythagorean:
  1548   assumes "orthogonal a b"
  1549     shows "norm(a + b) ^ 2 = norm a ^ 2 + norm b ^ 2"
  1550 proof -
  1551   from assms have "(a - (0 - b)) \<bullet> (a - (0 - b)) = a \<bullet> a - (0 - b \<bullet> b)"
  1552     by (simp add: algebra_simps orthogonal_def inner_commute)
  1553   then show ?thesis
  1554     by (simp add: power2_norm_eq_inner)
  1555 qed
  1556 
  1557 lemma norm_sum_Pythagorean:
  1558   assumes "finite I" "pairwise (\<lambda>i j. orthogonal (f i) (f j)) I"
  1559     shows "(norm (sum f I))\<^sup>2 = (\<Sum>i\<in>I. (norm (f i))\<^sup>2)"
  1560 using assms
  1561 proof (induction I rule: finite_induct)
  1562   case empty then show ?case by simp
  1563 next
  1564   case (insert x I)
  1565   then have "orthogonal (f x) (sum f I)"
  1566     by (metis pairwise_insert orthogonal_rvsum)
  1567   with insert show ?case
  1568     by (simp add: pairwise_insert norm_add_Pythagorean)
  1569 qed
  1570 
  1571 
  1572 subsection \<open>Bilinear functions.\<close>
  1573 
  1574 definition "bilinear f \<longleftrightarrow> (\<forall>x. linear (\<lambda>y. f x y)) \<and> (\<forall>y. linear (\<lambda>x. f x y))"
  1575 
  1576 lemma bilinear_ladd: "bilinear h \<Longrightarrow> h (x + y) z = h x z + h y z"
  1577   by (simp add: bilinear_def linear_iff)
  1578 
  1579 lemma bilinear_radd: "bilinear h \<Longrightarrow> h x (y + z) = h x y + h x z"
  1580   by (simp add: bilinear_def linear_iff)
  1581 
  1582 lemma bilinear_lmul: "bilinear h \<Longrightarrow> h (c *\<^sub>R x) y = c *\<^sub>R h x y"
  1583   by (simp add: bilinear_def linear_iff)
  1584 
  1585 lemma bilinear_rmul: "bilinear h \<Longrightarrow> h x (c *\<^sub>R y) = c *\<^sub>R h x y"
  1586   by (simp add: bilinear_def linear_iff)
  1587 
  1588 lemma bilinear_lneg: "bilinear h \<Longrightarrow> h (- x) y = - h x y"
  1589   by (drule bilinear_lmul [of _ "- 1"]) simp
  1590 
  1591 lemma bilinear_rneg: "bilinear h \<Longrightarrow> h x (- y) = - h x y"
  1592   by (drule bilinear_rmul [of _ _ "- 1"]) simp
  1593 
  1594 lemma (in ab_group_add) eq_add_iff: "x = x + y \<longleftrightarrow> y = 0"
  1595   using add_left_imp_eq[of x y 0] by auto
  1596 
  1597 lemma bilinear_lzero:
  1598   assumes "bilinear h"
  1599   shows "h 0 x = 0"
  1600   using bilinear_ladd [OF assms, of 0 0 x] by (simp add: eq_add_iff field_simps)
  1601 
  1602 lemma bilinear_rzero:
  1603   assumes "bilinear h"
  1604   shows "h x 0 = 0"
  1605   using bilinear_radd [OF assms, of x 0 0 ] by (simp add: eq_add_iff field_simps)
  1606 
  1607 lemma bilinear_lsub: "bilinear h \<Longrightarrow> h (x - y) z = h x z - h y z"
  1608   using bilinear_ladd [of h x "- y"] by (simp add: bilinear_lneg)
  1609 
  1610 lemma bilinear_rsub: "bilinear h \<Longrightarrow> h z (x - y) = h z x - h z y"
  1611   using bilinear_radd [of h _ x "- y"] by (simp add: bilinear_rneg)
  1612 
  1613 lemma bilinear_sum:
  1614   assumes bh: "bilinear h"
  1615     and fS: "finite S"
  1616     and fT: "finite T"
  1617   shows "h (sum f S) (sum g T) = sum (\<lambda>(i,j). h (f i) (g j)) (S \<times> T) "
  1618 proof -
  1619   have "h (sum f S) (sum g T) = sum (\<lambda>x. h (f x) (sum g T)) S"
  1620     apply (rule linear_sum[unfolded o_def])
  1621     using bh fS
  1622     apply (auto simp add: bilinear_def)
  1623     done
  1624   also have "\<dots> = sum (\<lambda>x. sum (\<lambda>y. h (f x) (g y)) T) S"
  1625     apply (rule sum.cong, simp)
  1626     apply (rule linear_sum[unfolded o_def])
  1627     using bh fT
  1628     apply (auto simp add: bilinear_def)
  1629     done
  1630   finally show ?thesis
  1631     unfolding sum.cartesian_product .
  1632 qed
  1633 
  1634 
  1635 subsection \<open>Adjoints.\<close>
  1636 
  1637 definition "adjoint f = (SOME f'. \<forall>x y. f x \<bullet> y = x \<bullet> f' y)"
  1638 
  1639 lemma adjoint_unique:
  1640   assumes "\<forall>x y. inner (f x) y = inner x (g y)"
  1641   shows "adjoint f = g"
  1642   unfolding adjoint_def
  1643 proof (rule some_equality)
  1644   show "\<forall>x y. inner (f x) y = inner x (g y)"
  1645     by (rule assms)
  1646 next
  1647   fix h
  1648   assume "\<forall>x y. inner (f x) y = inner x (h y)"
  1649   then have "\<forall>x y. inner x (g y) = inner x (h y)"
  1650     using assms by simp
  1651   then have "\<forall>x y. inner x (g y - h y) = 0"
  1652     by (simp add: inner_diff_right)
  1653   then have "\<forall>y. inner (g y - h y) (g y - h y) = 0"
  1654     by simp
  1655   then have "\<forall>y. h y = g y"
  1656     by simp
  1657   then show "h = g" by (simp add: ext)
  1658 qed
  1659 
  1660 text \<open>TODO: The following lemmas about adjoints should hold for any
  1661   Hilbert space (i.e. complete inner product space).
  1662   (see \<^url>\<open>http://en.wikipedia.org/wiki/Hermitian_adjoint\<close>)
  1663 \<close>
  1664 
  1665 lemma adjoint_works:
  1666   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
  1667   assumes lf: "linear f"
  1668   shows "x \<bullet> adjoint f y = f x \<bullet> y"
  1669 proof -
  1670   have "\<forall>y. \<exists>w. \<forall>x. f x \<bullet> y = x \<bullet> w"
  1671   proof (intro allI exI)
  1672     fix y :: "'m" and x
  1673     let ?w = "(\<Sum>i\<in>Basis. (f i \<bullet> y) *\<^sub>R i) :: 'n"
  1674     have "f x \<bullet> y = f (\<Sum>i\<in>Basis. (x \<bullet> i) *\<^sub>R i) \<bullet> y"
  1675       by (simp add: euclidean_representation)
  1676     also have "\<dots> = (\<Sum>i\<in>Basis. (x \<bullet> i) *\<^sub>R f i) \<bullet> y"
  1677       unfolding linear_sum[OF lf]
  1678       by (simp add: linear_cmul[OF lf])
  1679     finally show "f x \<bullet> y = x \<bullet> ?w"
  1680       by (simp add: inner_sum_left inner_sum_right mult.commute)
  1681   qed
  1682   then show ?thesis
  1683     unfolding adjoint_def choice_iff
  1684     by (intro someI2_ex[where Q="\<lambda>f'. x \<bullet> f' y = f x \<bullet> y"]) auto
  1685 qed
  1686 
  1687 lemma adjoint_clauses:
  1688   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
  1689   assumes lf: "linear f"
  1690   shows "x \<bullet> adjoint f y = f x \<bullet> y"
  1691     and "adjoint f y \<bullet> x = y \<bullet> f x"
  1692   by (simp_all add: adjoint_works[OF lf] inner_commute)
  1693 
  1694 lemma adjoint_linear:
  1695   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
  1696   assumes lf: "linear f"
  1697   shows "linear (adjoint f)"
  1698   by (simp add: lf linear_iff euclidean_eq_iff[where 'a='n] euclidean_eq_iff[where 'a='m]
  1699     adjoint_clauses[OF lf] inner_distrib)
  1700 
  1701 lemma adjoint_adjoint:
  1702   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
  1703   assumes lf: "linear f"
  1704   shows "adjoint (adjoint f) = f"
  1705   by (rule adjoint_unique, simp add: adjoint_clauses [OF lf])
  1706 
  1707 
  1708 subsection \<open>Interlude: Some properties of real sets\<close>
  1709 
  1710 lemma seq_mono_lemma:
  1711   assumes "\<forall>(n::nat) \<ge> m. (d n :: real) < e n"
  1712     and "\<forall>n \<ge> m. e n \<le> e m"
  1713   shows "\<forall>n \<ge> m. d n < e m"
  1714   using assms
  1715   apply auto
  1716   apply (erule_tac x="n" in allE)
  1717   apply (erule_tac x="n" in allE)
  1718   apply auto
  1719   done
  1720 
  1721 lemma infinite_enumerate:
  1722   assumes fS: "infinite S"
  1723   shows "\<exists>r::nat\<Rightarrow>nat. strict_mono r \<and> (\<forall>n. r n \<in> S)"
  1724   unfolding strict_mono_def
  1725   using enumerate_in_set[OF fS] enumerate_mono[of _ _ S] fS by auto
  1726 
  1727 lemma approachable_lt_le: "(\<exists>(d::real) > 0. \<forall>x. f x < d \<longrightarrow> P x) \<longleftrightarrow> (\<exists>d>0. \<forall>x. f x \<le> d \<longrightarrow> P x)"
  1728   apply auto
  1729   apply (rule_tac x="d/2" in exI)
  1730   apply auto
  1731   done
  1732 
  1733 lemma approachable_lt_le2:  \<comment>\<open>like the above, but pushes aside an extra formula\<close>
  1734     "(\<exists>(d::real) > 0. \<forall>x. Q x \<longrightarrow> f x < d \<longrightarrow> P x) \<longleftrightarrow> (\<exists>d>0. \<forall>x. f x \<le> d \<longrightarrow> Q x \<longrightarrow> P x)"
  1735   apply auto
  1736   apply (rule_tac x="d/2" in exI, auto)
  1737   done
  1738 
  1739 lemma triangle_lemma:
  1740   fixes x y z :: real
  1741   assumes x: "0 \<le> x"
  1742     and y: "0 \<le> y"
  1743     and z: "0 \<le> z"
  1744     and xy: "x\<^sup>2 \<le> y\<^sup>2 + z\<^sup>2"
  1745   shows "x \<le> y + z"
  1746 proof -
  1747   have "y\<^sup>2 + z\<^sup>2 \<le> y\<^sup>2 + 2 * y * z + z\<^sup>2"
  1748     using z y by simp
  1749   with xy have th: "x\<^sup>2 \<le> (y + z)\<^sup>2"
  1750     by (simp add: power2_eq_square field_simps)
  1751   from y z have yz: "y + z \<ge> 0"
  1752     by arith
  1753   from power2_le_imp_le[OF th yz] show ?thesis .
  1754 qed
  1755 
  1756 
  1757 
  1758 subsection \<open>Archimedean properties and useful consequences\<close>
  1759 
  1760 text\<open>Bernoulli's inequality\<close>
  1761 proposition Bernoulli_inequality:
  1762   fixes x :: real
  1763   assumes "-1 \<le> x"
  1764     shows "1 + n * x \<le> (1 + x) ^ n"
  1765 proof (induct n)
  1766   case 0
  1767   then show ?case by simp
  1768 next
  1769   case (Suc n)
  1770   have "1 + Suc n * x \<le> 1 + (Suc n)*x + n * x^2"
  1771     by (simp add: algebra_simps)
  1772   also have "... = (1 + x) * (1 + n*x)"
  1773     by (auto simp: power2_eq_square algebra_simps  of_nat_Suc)
  1774   also have "... \<le> (1 + x) ^ Suc n"
  1775     using Suc.hyps assms mult_left_mono by fastforce
  1776   finally show ?case .
  1777 qed
  1778 
  1779 corollary Bernoulli_inequality_even:
  1780   fixes x :: real
  1781   assumes "even n"
  1782     shows "1 + n * x \<le> (1 + x) ^ n"
  1783 proof (cases "-1 \<le> x \<or> n=0")
  1784   case True
  1785   then show ?thesis
  1786     by (auto simp: Bernoulli_inequality)
  1787 next
  1788   case False
  1789   then have "real n \<ge> 1"
  1790     by simp
  1791   with False have "n * x \<le> -1"
  1792     by (metis linear minus_zero mult.commute mult.left_neutral mult_left_mono_neg neg_le_iff_le order_trans zero_le_one)
  1793   then have "1 + n * x \<le> 0"
  1794     by auto
  1795   also have "... \<le> (1 + x) ^ n"
  1796     using assms
  1797     using zero_le_even_power by blast
  1798   finally show ?thesis .
  1799 qed
  1800 
  1801 corollary real_arch_pow:
  1802   fixes x :: real
  1803   assumes x: "1 < x"
  1804   shows "\<exists>n. y < x^n"
  1805 proof -
  1806   from x have x0: "x - 1 > 0"
  1807     by arith
  1808   from reals_Archimedean3[OF x0, rule_format, of y]
  1809   obtain n :: nat where n: "y < real n * (x - 1)" by metis
  1810   from x0 have x00: "x- 1 \<ge> -1" by arith
  1811   from Bernoulli_inequality[OF x00, of n] n
  1812   have "y < x^n" by auto
  1813   then show ?thesis by metis
  1814 qed
  1815 
  1816 corollary real_arch_pow_inv:
  1817   fixes x y :: real
  1818   assumes y: "y > 0"
  1819     and x1: "x < 1"
  1820   shows "\<exists>n. x^n < y"
  1821 proof (cases "x > 0")
  1822   case True
  1823   with x1 have ix: "1 < 1/x" by (simp add: field_simps)
  1824   from real_arch_pow[OF ix, of "1/y"]
  1825   obtain n where n: "1/y < (1/x)^n" by blast
  1826   then show ?thesis using y \<open>x > 0\<close>
  1827     by (auto simp add: field_simps)
  1828 next
  1829   case False
  1830   with y x1 show ?thesis
  1831     apply auto
  1832     apply (rule exI[where x=1])
  1833     apply auto
  1834     done
  1835 qed
  1836 
  1837 lemma forall_pos_mono:
  1838   "(\<And>d e::real. d < e \<Longrightarrow> P d \<Longrightarrow> P e) \<Longrightarrow>
  1839     (\<And>n::nat. n \<noteq> 0 \<Longrightarrow> P (inverse (real n))) \<Longrightarrow> (\<And>e. 0 < e \<Longrightarrow> P e)"
  1840   by (metis real_arch_inverse)
  1841 
  1842 lemma forall_pos_mono_1:
  1843   "(\<And>d e::real. d < e \<Longrightarrow> P d \<Longrightarrow> P e) \<Longrightarrow>
  1844     (\<And>n. P (inverse (real (Suc n)))) \<Longrightarrow> 0 < e \<Longrightarrow> P e"
  1845   apply (rule forall_pos_mono)
  1846   apply auto
  1847   apply (metis Suc_pred of_nat_Suc)
  1848   done
  1849 
  1850 
  1851 subsection \<open>Euclidean Spaces as Typeclass\<close>
  1852 
  1853 lemma independent_Basis: "independent Basis"
  1854   unfolding dependent_def
  1855   apply (subst span_finite)
  1856   apply simp
  1857   apply clarify
  1858   apply (drule_tac f="inner a" in arg_cong)
  1859   apply (simp add: inner_Basis inner_sum_right eq_commute)
  1860   done
  1861 
  1862 lemma span_Basis [simp]: "span Basis = UNIV"
  1863   unfolding span_finite [OF finite_Basis]
  1864   by (fast intro: euclidean_representation)
  1865 
  1866 lemma in_span_Basis: "x \<in> span Basis"
  1867   unfolding span_Basis ..
  1868 
  1869 lemma Basis_le_norm: "b \<in> Basis \<Longrightarrow> \<bar>x \<bullet> b\<bar> \<le> norm x"
  1870   by (rule order_trans [OF Cauchy_Schwarz_ineq2]) simp
  1871 
  1872 lemma norm_bound_Basis_le: "b \<in> Basis \<Longrightarrow> norm x \<le> e \<Longrightarrow> \<bar>x \<bullet> b\<bar> \<le> e"
  1873   by (metis Basis_le_norm order_trans)
  1874 
  1875 lemma norm_bound_Basis_lt: "b \<in> Basis \<Longrightarrow> norm x < e \<Longrightarrow> \<bar>x \<bullet> b\<bar> < e"
  1876   by (metis Basis_le_norm le_less_trans)
  1877 
  1878 lemma norm_le_l1: "norm x \<le> (\<Sum>b\<in>Basis. \<bar>x \<bullet> b\<bar>)"
  1879   apply (subst euclidean_representation[of x, symmetric])
  1880   apply (rule order_trans[OF norm_sum])
  1881   apply (auto intro!: sum_mono)
  1882   done
  1883 
  1884 lemma sum_norm_allsubsets_bound:
  1885   fixes f :: "'a \<Rightarrow> 'n::euclidean_space"
  1886   assumes fP: "finite P"
  1887     and fPs: "\<And>Q. Q \<subseteq> P \<Longrightarrow> norm (sum f Q) \<le> e"
  1888   shows "(\<Sum>x\<in>P. norm (f x)) \<le> 2 * real DIM('n) * e"
  1889 proof -
  1890   have "(\<Sum>x\<in>P. norm (f x)) \<le> (\<Sum>x\<in>P. \<Sum>b\<in>Basis. \<bar>f x \<bullet> b\<bar>)"
  1891     by (rule sum_mono) (rule norm_le_l1)
  1892   also have "(\<Sum>x\<in>P. \<Sum>b\<in>Basis. \<bar>f x \<bullet> b\<bar>) = (\<Sum>b\<in>Basis. \<Sum>x\<in>P. \<bar>f x \<bullet> b\<bar>)"
  1893     by (rule sum.commute)
  1894   also have "\<dots> \<le> of_nat (card (Basis :: 'n set)) * (2 * e)"
  1895   proof (rule sum_bounded_above)
  1896     fix i :: 'n
  1897     assume i: "i \<in> Basis"
  1898     have "norm (\<Sum>x\<in>P. \<bar>f x \<bullet> i\<bar>) \<le>
  1899       norm ((\<Sum>x\<in>P \<inter> - {x. f x \<bullet> i < 0}. f x) \<bullet> i) + norm ((\<Sum>x\<in>P \<inter> {x. f x \<bullet> i < 0}. f x) \<bullet> i)"
  1900       by (simp add: abs_real_def sum.If_cases[OF fP] sum_negf norm_triangle_ineq4 inner_sum_left
  1901         del: real_norm_def)
  1902     also have "\<dots> \<le> e + e"
  1903       unfolding real_norm_def
  1904       by (intro add_mono norm_bound_Basis_le i fPs) auto
  1905     finally show "(\<Sum>x\<in>P. \<bar>f x \<bullet> i\<bar>) \<le> 2*e" by simp
  1906   qed
  1907   also have "\<dots> = 2 * real DIM('n) * e" by simp
  1908   finally show ?thesis .
  1909 qed
  1910 
  1911 
  1912 subsection \<open>Linearity and Bilinearity continued\<close>
  1913 
  1914 lemma linear_bounded:
  1915   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
  1916   assumes lf: "linear f"
  1917   shows "\<exists>B. \<forall>x. norm (f x) \<le> B * norm x"
  1918 proof
  1919   let ?B = "\<Sum>b\<in>Basis. norm (f b)"
  1920   show "\<forall>x. norm (f x) \<le> ?B * norm x"
  1921   proof
  1922     fix x :: 'a
  1923     let ?g = "\<lambda>b. (x \<bullet> b) *\<^sub>R f b"
  1924     have "norm (f x) = norm (f (\<Sum>b\<in>Basis. (x \<bullet> b) *\<^sub>R b))"
  1925       unfolding euclidean_representation ..
  1926     also have "\<dots> = norm (sum ?g Basis)"
  1927       by (simp add: linear_sum [OF lf] linear_cmul [OF lf])
  1928     finally have th0: "norm (f x) = norm (sum ?g Basis)" .
  1929     have th: "norm (?g i) \<le> norm (f i) * norm x" if "i \<in> Basis" for i
  1930     proof -
  1931       from Basis_le_norm[OF that, of x]
  1932       show "norm (?g i) \<le> norm (f i) * norm x"
  1933         unfolding norm_scaleR
  1934         apply (subst mult.commute)
  1935         apply (rule mult_mono)
  1936         apply (auto simp add: field_simps)
  1937         done
  1938     qed
  1939     from sum_norm_le[of _ ?g, OF th]
  1940     show "norm (f x) \<le> ?B * norm x"
  1941       unfolding th0 sum_distrib_right by metis
  1942   qed
  1943 qed
  1944 
  1945 lemma linear_conv_bounded_linear:
  1946   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
  1947   shows "linear f \<longleftrightarrow> bounded_linear f"
  1948 proof
  1949   assume "linear f"
  1950   then interpret f: linear f .
  1951   show "bounded_linear f"
  1952   proof
  1953     have "\<exists>B. \<forall>x. norm (f x) \<le> B * norm x"
  1954       using \<open>linear f\<close> by (rule linear_bounded)
  1955     then show "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
  1956       by (simp add: mult.commute)
  1957   qed
  1958 next
  1959   assume "bounded_linear f"
  1960   then interpret f: bounded_linear f .
  1961   show "linear f" ..
  1962 qed
  1963 
  1964 lemmas linear_linear = linear_conv_bounded_linear[symmetric]
  1965 
  1966 lemma linear_bounded_pos:
  1967   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
  1968   assumes lf: "linear f"
  1969   shows "\<exists>B > 0. \<forall>x. norm (f x) \<le> B * norm x"
  1970 proof -
  1971   have "\<exists>B > 0. \<forall>x. norm (f x) \<le> norm x * B"
  1972     using lf unfolding linear_conv_bounded_linear
  1973     by (rule bounded_linear.pos_bounded)
  1974   then show ?thesis
  1975     by (simp only: mult.commute)
  1976 qed
  1977 
  1978 lemma bounded_linearI':
  1979   fixes f ::"'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
  1980   assumes "\<And>x y. f (x + y) = f x + f y"
  1981     and "\<And>c x. f (c *\<^sub>R x) = c *\<^sub>R f x"
  1982   shows "bounded_linear f"
  1983   unfolding linear_conv_bounded_linear[symmetric]
  1984   by (rule linearI[OF assms])
  1985 
  1986 lemma bilinear_bounded:
  1987   fixes h :: "'m::euclidean_space \<Rightarrow> 'n::euclidean_space \<Rightarrow> 'k::real_normed_vector"
  1988   assumes bh: "bilinear h"
  1989   shows "\<exists>B. \<forall>x y. norm (h x y) \<le> B * norm x * norm y"
  1990 proof (clarify intro!: exI[of _ "\<Sum>i\<in>Basis. \<Sum>j\<in>Basis. norm (h i j)"])
  1991   fix x :: 'm
  1992   fix y :: 'n
  1993   have "norm (h x y) = norm (h (sum (\<lambda>i. (x \<bullet> i) *\<^sub>R i) Basis) (sum (\<lambda>i. (y \<bullet> i) *\<^sub>R i) Basis))"
  1994     apply (subst euclidean_representation[where 'a='m])
  1995     apply (subst euclidean_representation[where 'a='n])
  1996     apply rule
  1997     done
  1998   also have "\<dots> = norm (sum (\<lambda> (i,j). h ((x \<bullet> i) *\<^sub>R i) ((y \<bullet> j) *\<^sub>R j)) (Basis \<times> Basis))"
  1999     unfolding bilinear_sum[OF bh finite_Basis finite_Basis] ..
  2000   finally have th: "norm (h x y) = \<dots>" .
  2001   show "norm (h x y) \<le> (\<Sum>i\<in>Basis. \<Sum>j\<in>Basis. norm (h i j)) * norm x * norm y"
  2002     apply (auto simp add: sum_distrib_right th sum.cartesian_product)
  2003     apply (rule sum_norm_le)
  2004     apply (auto simp add: bilinear_rmul[OF bh] bilinear_lmul[OF bh]
  2005       field_simps simp del: scaleR_scaleR)
  2006     apply (rule mult_mono)
  2007     apply (auto simp add: zero_le_mult_iff Basis_le_norm)
  2008     apply (rule mult_mono)
  2009     apply (auto simp add: zero_le_mult_iff Basis_le_norm)
  2010     done
  2011 qed
  2012 
  2013 lemma bilinear_conv_bounded_bilinear:
  2014   fixes h :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space \<Rightarrow> 'c::real_normed_vector"
  2015   shows "bilinear h \<longleftrightarrow> bounded_bilinear h"
  2016 proof
  2017   assume "bilinear h"
  2018   show "bounded_bilinear h"
  2019   proof
  2020     fix x y z
  2021     show "h (x + y) z = h x z + h y z"
  2022       using \<open>bilinear h\<close> unfolding bilinear_def linear_iff by simp
  2023   next
  2024     fix x y z
  2025     show "h x (y + z) = h x y + h x z"
  2026       using \<open>bilinear h\<close> unfolding bilinear_def linear_iff by simp
  2027   next
  2028     fix r x y
  2029     show "h (scaleR r x) y = scaleR r (h x y)"
  2030       using \<open>bilinear h\<close> unfolding bilinear_def linear_iff
  2031       by simp
  2032   next
  2033     fix r x y
  2034     show "h x (scaleR r y) = scaleR r (h x y)"
  2035       using \<open>bilinear h\<close> unfolding bilinear_def linear_iff
  2036       by simp
  2037   next
  2038     have "\<exists>B. \<forall>x y. norm (h x y) \<le> B * norm x * norm y"
  2039       using \<open>bilinear h\<close> by (rule bilinear_bounded)
  2040     then show "\<exists>K. \<forall>x y. norm (h x y) \<le> norm x * norm y * K"
  2041       by (simp add: ac_simps)
  2042   qed
  2043 next
  2044   assume "bounded_bilinear h"
  2045   then interpret h: bounded_bilinear h .
  2046   show "bilinear h"
  2047     unfolding bilinear_def linear_conv_bounded_linear
  2048     using h.bounded_linear_left h.bounded_linear_right by simp
  2049 qed
  2050 
  2051 lemma bilinear_bounded_pos:
  2052   fixes h :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space \<Rightarrow> 'c::real_normed_vector"
  2053   assumes bh: "bilinear h"
  2054   shows "\<exists>B > 0. \<forall>x y. norm (h x y) \<le> B * norm x * norm y"
  2055 proof -
  2056   have "\<exists>B > 0. \<forall>x y. norm (h x y) \<le> norm x * norm y * B"
  2057     using bh [unfolded bilinear_conv_bounded_bilinear]
  2058     by (rule bounded_bilinear.pos_bounded)
  2059   then show ?thesis
  2060     by (simp only: ac_simps)
  2061 qed
  2062 
  2063 lemma bounded_linear_imp_has_derivative:
  2064      "bounded_linear f \<Longrightarrow> (f has_derivative f) net"
  2065   by (simp add: has_derivative_def bounded_linear.linear linear_diff)
  2066 
  2067 lemma linear_imp_has_derivative:
  2068   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
  2069   shows "linear f \<Longrightarrow> (f has_derivative f) net"
  2070 by (simp add: has_derivative_def linear_conv_bounded_linear linear_diff)
  2071 
  2072 lemma bounded_linear_imp_differentiable: "bounded_linear f \<Longrightarrow> f differentiable net"
  2073   using bounded_linear_imp_has_derivative differentiable_def by blast
  2074 
  2075 lemma linear_imp_differentiable:
  2076   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
  2077   shows "linear f \<Longrightarrow> f differentiable net"
  2078 by (metis linear_imp_has_derivative differentiable_def)
  2079 
  2080 
  2081 subsection \<open>We continue.\<close>
  2082 
  2083 lemma independent_bound:
  2084   fixes S :: "'a::euclidean_space set"
  2085   shows "independent S \<Longrightarrow> finite S \<and> card S \<le> DIM('a)"
  2086   using independent_span_bound[OF finite_Basis, of S] by auto
  2087 
  2088 corollary
  2089   fixes S :: "'a::euclidean_space set"
  2090   assumes "independent S"
  2091   shows independent_imp_finite: "finite S" and independent_card_le:"card S \<le> DIM('a)"
  2092 using assms independent_bound by auto
  2093 
  2094 lemma independent_explicit:
  2095   fixes B :: "'a::euclidean_space set"
  2096   shows "independent B \<longleftrightarrow>
  2097          finite B \<and> (\<forall>c. (\<Sum>v\<in>B. c v *\<^sub>R v) = 0 \<longrightarrow> (\<forall>v \<in> B. c v = 0))"
  2098 apply (cases "finite B")
  2099  apply (force simp: dependent_finite)
  2100 using independent_bound
  2101 apply auto
  2102 done
  2103 
  2104 lemma dependent_biggerset:
  2105   fixes S :: "'a::euclidean_space set"
  2106   shows "(finite S \<Longrightarrow> card S > DIM('a)) \<Longrightarrow> dependent S"
  2107   by (metis independent_bound not_less)
  2108 
  2109 text \<open>Notion of dimension.\<close>
  2110 
  2111 definition "dim V = (SOME n. \<exists>B. B \<subseteq> V \<and> independent B \<and> V \<subseteq> span B \<and> card B = n)"
  2112 
  2113 lemma basis_exists:
  2114   "\<exists>B. (B :: ('a::euclidean_space) set) \<subseteq> V \<and> independent B \<and> V \<subseteq> span B \<and> (card B = dim V)"
  2115   unfolding dim_def some_eq_ex[of "\<lambda>n. \<exists>B. B \<subseteq> V \<and> independent B \<and> V \<subseteq> span B \<and> (card B = n)"]
  2116   using maximal_independent_subset[of V] independent_bound
  2117   by auto
  2118 
  2119 corollary dim_le_card:
  2120   fixes s :: "'a::euclidean_space set"
  2121   shows "finite s \<Longrightarrow> dim s \<le> card s"
  2122 by (metis basis_exists card_mono)
  2123 
  2124 text \<open>Consequences of independence or spanning for cardinality.\<close>
  2125 
  2126 lemma independent_card_le_dim:
  2127   fixes B :: "'a::euclidean_space set"
  2128   assumes "B \<subseteq> V"
  2129     and "independent B"
  2130   shows "card B \<le> dim V"
  2131 proof -
  2132   from basis_exists[of V] \<open>B \<subseteq> V\<close>
  2133   obtain B' where "independent B'"
  2134     and "B \<subseteq> span B'"
  2135     and "card B' = dim V"
  2136     by blast
  2137   with independent_span_bound[OF _ \<open>independent B\<close> \<open>B \<subseteq> span B'\<close>] independent_bound[of B']
  2138   show ?thesis by auto
  2139 qed
  2140 
  2141 lemma span_card_ge_dim:
  2142   fixes B :: "'a::euclidean_space set"
  2143   shows "B \<subseteq> V \<Longrightarrow> V \<subseteq> span B \<Longrightarrow> finite B \<Longrightarrow> dim V \<le> card B"
  2144   by (metis basis_exists[of V] independent_span_bound subset_trans)
  2145 
  2146 lemma basis_card_eq_dim:
  2147   fixes V :: "'a::euclidean_space set"
  2148   shows "B \<subseteq> V \<Longrightarrow> V \<subseteq> span B \<Longrightarrow> independent B \<Longrightarrow> finite B \<and> card B = dim V"
  2149   by (metis order_eq_iff independent_card_le_dim span_card_ge_dim independent_bound)
  2150 
  2151 lemma dim_unique:
  2152   fixes B :: "'a::euclidean_space set"
  2153   shows "B \<subseteq> V \<Longrightarrow> V \<subseteq> span B \<Longrightarrow> independent B \<Longrightarrow> card B = n \<Longrightarrow> dim V = n"
  2154   by (metis basis_card_eq_dim)
  2155 
  2156 text \<open>More lemmas about dimension.\<close>
  2157 
  2158 lemma dim_UNIV [simp]: "dim (UNIV :: 'a::euclidean_space set) = DIM('a)"
  2159   using independent_Basis
  2160   by (intro dim_unique[of Basis]) auto
  2161 
  2162 lemma dim_subset:
  2163   fixes S :: "'a::euclidean_space set"
  2164   shows "S \<subseteq> T \<Longrightarrow> dim S \<le> dim T"
  2165   using basis_exists[of T] basis_exists[of S]
  2166   by (metis independent_card_le_dim subset_trans)
  2167 
  2168 lemma dim_subset_UNIV:
  2169   fixes S :: "'a::euclidean_space set"
  2170   shows "dim S \<le> DIM('a)"
  2171   by (metis dim_subset subset_UNIV dim_UNIV)
  2172 
  2173 text \<open>Converses to those.\<close>
  2174 
  2175 lemma card_ge_dim_independent:
  2176   fixes B :: "'a::euclidean_space set"
  2177   assumes BV: "B \<subseteq> V"
  2178     and iB: "independent B"
  2179     and dVB: "dim V \<le> card B"
  2180   shows "V \<subseteq> span B"
  2181 proof
  2182   fix a
  2183   assume aV: "a \<in> V"
  2184   {
  2185     assume aB: "a \<notin> span B"
  2186     then have iaB: "independent (insert a B)"
  2187       using iB aV BV by (simp add: independent_insert)
  2188     from aV BV have th0: "insert a B \<subseteq> V"
  2189       by blast
  2190     from aB have "a \<notin>B"
  2191       by (auto simp add: span_superset)
  2192     with independent_card_le_dim[OF th0 iaB] dVB independent_bound[OF iB]
  2193     have False by auto
  2194   }
  2195   then show "a \<in> span B" by blast
  2196 qed
  2197 
  2198 lemma card_le_dim_spanning:
  2199   assumes BV: "(B:: ('a::euclidean_space) set) \<subseteq> V"
  2200     and VB: "V \<subseteq> span B"
  2201     and fB: "finite B"
  2202     and dVB: "dim V \<ge> card B"
  2203   shows "independent B"
  2204 proof -
  2205   {
  2206     fix a
  2207     assume a: "a \<in> B" "a \<in> span (B - {a})"
  2208     from a fB have c0: "card B \<noteq> 0"
  2209       by auto
  2210     from a fB have cb: "card (B - {a}) = card B - 1"
  2211       by auto
  2212     from BV a have th0: "B - {a} \<subseteq> V"
  2213       by blast
  2214     {
  2215       fix x
  2216       assume x: "x \<in> V"
  2217       from a have eq: "insert a (B - {a}) = B"
  2218         by blast
  2219       from x VB have x': "x \<in> span B"
  2220         by blast
  2221       from span_trans[OF a(2), unfolded eq, OF x']
  2222       have "x \<in> span (B - {a})" .
  2223     }
  2224     then have th1: "V \<subseteq> span (B - {a})"
  2225       by blast
  2226     have th2: "finite (B - {a})"
  2227       using fB by auto
  2228     from span_card_ge_dim[OF th0 th1 th2]
  2229     have c: "dim V \<le> card (B - {a})" .
  2230     from c c0 dVB cb have False by simp
  2231   }
  2232   then show ?thesis
  2233     unfolding dependent_def by blast
  2234 qed
  2235 
  2236 lemma card_eq_dim:
  2237   fixes B :: "'a::euclidean_space set"
  2238   shows "B \<subseteq> V \<Longrightarrow> card B = dim V \<Longrightarrow> finite B \<Longrightarrow> independent B \<longleftrightarrow> V \<subseteq> span B"
  2239   by (metis order_eq_iff card_le_dim_spanning card_ge_dim_independent)
  2240 
  2241 text \<open>More general size bound lemmas.\<close>
  2242 
  2243 lemma independent_bound_general:
  2244   fixes S :: "'a::euclidean_space set"
  2245   shows "independent S \<Longrightarrow> finite S \<and> card S \<le> dim S"
  2246   by (metis independent_card_le_dim independent_bound subset_refl)
  2247 
  2248 lemma dependent_biggerset_general:
  2249   fixes S :: "'a::euclidean_space set"
  2250   shows "(finite S \<Longrightarrow> card S > dim S) \<Longrightarrow> dependent S"
  2251   using independent_bound_general[of S] by (metis linorder_not_le)
  2252 
  2253 lemma dim_span [simp]:
  2254   fixes S :: "'a::euclidean_space set"
  2255   shows "dim (span S) = dim S"
  2256 proof -
  2257   have th0: "dim S \<le> dim (span S)"
  2258     by (auto simp add: subset_eq intro: dim_subset span_superset)
  2259   from basis_exists[of S]
  2260   obtain B where B: "B \<subseteq> S" "independent B" "S \<subseteq> span B" "card B = dim S"
  2261     by blast
  2262   from B have fB: "finite B" "card B = dim S"
  2263     using independent_bound by blast+
  2264   have bSS: "B \<subseteq> span S"
  2265     using B(1) by (metis subset_eq span_inc)
  2266   have sssB: "span S \<subseteq> span B"
  2267     using span_mono[OF B(3)] by (simp add: span_span)
  2268   from span_card_ge_dim[OF bSS sssB fB(1)] th0 show ?thesis
  2269     using fB(2) by arith
  2270 qed
  2271 
  2272 lemma subset_le_dim:
  2273   fixes S :: "'a::euclidean_space set"
  2274   shows "S \<subseteq> span T \<Longrightarrow> dim S \<le> dim T"
  2275   by (metis dim_span dim_subset)
  2276 
  2277 lemma span_eq_dim:
  2278   fixes S :: "'a::euclidean_space set"
  2279   shows "span S = span T \<Longrightarrow> dim S = dim T"
  2280   by (metis dim_span)
  2281 
  2282 lemma dim_image_le:
  2283   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  2284   assumes lf: "linear f"
  2285   shows "dim (f ` S) \<le> dim (S)"
  2286 proof -
  2287   from basis_exists[of S] obtain B where
  2288     B: "B \<subseteq> S" "independent B" "S \<subseteq> span B" "card B = dim S" by blast
  2289   from B have fB: "finite B" "card B = dim S"
  2290     using independent_bound by blast+
  2291   have "dim (f ` S) \<le> card (f ` B)"
  2292     apply (rule span_card_ge_dim)
  2293     using lf B fB
  2294     apply (auto simp add: span_linear_image spans_image subset_image_iff)
  2295     done
  2296   also have "\<dots> \<le> dim S"
  2297     using card_image_le[OF fB(1)] fB by simp
  2298   finally show ?thesis .
  2299 qed
  2300 
  2301 text \<open>Picking an orthogonal replacement for a spanning set.\<close>
  2302 
  2303 lemma vector_sub_project_orthogonal:
  2304   fixes b x :: "'a::euclidean_space"
  2305   shows "b \<bullet> (x - ((b \<bullet> x) / (b \<bullet> b)) *\<^sub>R b) = 0"
  2306   unfolding inner_simps by auto
  2307 
  2308 lemma pairwise_orthogonal_insert:
  2309   assumes "pairwise orthogonal S"
  2310     and "\<And>y. y \<in> S \<Longrightarrow> orthogonal x y"
  2311   shows "pairwise orthogonal (insert x S)"
  2312   using assms unfolding pairwise_def
  2313   by (auto simp add: orthogonal_commute)
  2314 
  2315 lemma basis_orthogonal:
  2316   fixes B :: "'a::real_inner set"
  2317   assumes fB: "finite B"
  2318   shows "\<exists>C. finite C \<and> card C \<le> card B \<and> span C = span B \<and> pairwise orthogonal C"
  2319   (is " \<exists>C. ?P B C")
  2320   using fB
  2321 proof (induct rule: finite_induct)
  2322   case empty
  2323   then show ?case
  2324     apply (rule exI[where x="{}"])
  2325     apply (auto simp add: pairwise_def)
  2326     done
  2327 next
  2328   case (insert a B)
  2329   note fB = \<open>finite B\<close> and aB = \<open>a \<notin> B\<close>
  2330   from \<open>\<exists>C. finite C \<and> card C \<le> card B \<and> span C = span B \<and> pairwise orthogonal C\<close>
  2331   obtain C where C: "finite C" "card C \<le> card B"
  2332     "span C = span B" "pairwise orthogonal C" by blast
  2333   let ?a = "a - sum (\<lambda>x. (x \<bullet> a / (x \<bullet> x)) *\<^sub>R x) C"
  2334   let ?C = "insert ?a C"
  2335   from C(1) have fC: "finite ?C"
  2336     by simp
  2337   from fB aB C(1,2) have cC: "card ?C \<le> card (insert a B)"
  2338     by (simp add: card_insert_if)
  2339   {
  2340     fix x k
  2341     have th0: "\<And>(a::'a) b c. a - (b - c) = c + (a - b)"
  2342       by (simp add: field_simps)
  2343     have "x - k *\<^sub>R (a - (\<Sum>x\<in>C. (x \<bullet> a / (x \<bullet> x)) *\<^sub>R x)) \<in> span C \<longleftrightarrow> x - k *\<^sub>R a \<in> span C"
  2344       apply (simp only: scaleR_right_diff_distrib th0)
  2345       apply (rule span_add_eq)
  2346       apply (rule span_mul)
  2347       apply (rule span_sum)
  2348       apply (rule span_mul)
  2349       apply (rule span_superset)
  2350       apply assumption
  2351       done
  2352   }
  2353   then have SC: "span ?C = span (insert a B)"
  2354     unfolding set_eq_iff span_breakdown_eq C(3)[symmetric] by auto
  2355   {
  2356     fix y
  2357     assume yC: "y \<in> C"
  2358     then have Cy: "C = insert y (C - {y})"
  2359       by blast
  2360     have fth: "finite (C - {y})"
  2361       using C by simp
  2362     have "orthogonal ?a y"
  2363       unfolding orthogonal_def
  2364       unfolding inner_diff inner_sum_left right_minus_eq
  2365       unfolding sum.remove [OF \<open>finite C\<close> \<open>y \<in> C\<close>]
  2366       apply (clarsimp simp add: inner_commute[of y a])
  2367       apply (rule sum.neutral)
  2368       apply clarsimp
  2369       apply (rule C(4)[unfolded pairwise_def orthogonal_def, rule_format])
  2370       using \<open>y \<in> C\<close> by auto
  2371   }
  2372   with \<open>pairwise orthogonal C\<close> have CPO: "pairwise orthogonal ?C"
  2373     by (rule pairwise_orthogonal_insert)
  2374   from fC cC SC CPO have "?P (insert a B) ?C"
  2375     by blast
  2376   then show ?case by blast
  2377 qed
  2378 
  2379 lemma orthogonal_basis_exists:
  2380   fixes V :: "('a::euclidean_space) set"
  2381   shows "\<exists>B. independent B \<and> B \<subseteq> span V \<and> V \<subseteq> span B \<and> (card B = dim V) \<and> pairwise orthogonal B"
  2382 proof -
  2383   from basis_exists[of V] obtain B where
  2384     B: "B \<subseteq> V" "independent B" "V \<subseteq> span B" "card B = dim V"
  2385     by blast
  2386   from B have fB: "finite B" "card B = dim V"
  2387     using independent_bound by auto
  2388   from basis_orthogonal[OF fB(1)] obtain C where
  2389     C: "finite C" "card C \<le> card B" "span C = span B" "pairwise orthogonal C"
  2390     by blast
  2391   from C B have CSV: "C \<subseteq> span V"
  2392     by (metis span_inc span_mono subset_trans)
  2393   from span_mono[OF B(3)] C have SVC: "span V \<subseteq> span C"
  2394     by (simp add: span_span)
  2395   from card_le_dim_spanning[OF CSV SVC C(1)] C(2,3) fB
  2396   have iC: "independent C"
  2397     by (simp add: dim_span)
  2398   from C fB have "card C \<le> dim V"
  2399     by simp
  2400   moreover have "dim V \<le> card C"
  2401     using span_card_ge_dim[OF CSV SVC C(1)]
  2402     by (simp add: dim_span)
  2403   ultimately have CdV: "card C = dim V"
  2404     using C(1) by simp
  2405   from C B CSV CdV iC show ?thesis
  2406     by auto
  2407 qed
  2408 
  2409 text \<open>Low-dimensional subset is in a hyperplane (weak orthogonal complement).\<close>
  2410 
  2411 lemma span_not_univ_orthogonal:
  2412   fixes S :: "'a::euclidean_space set"
  2413   assumes sU: "span S \<noteq> UNIV"
  2414   shows "\<exists>a::'a. a \<noteq> 0 \<and> (\<forall>x \<in> span S. a \<bullet> x = 0)"
  2415 proof -
  2416   from sU obtain a where a: "a \<notin> span S"
  2417     by blast
  2418   from orthogonal_basis_exists obtain B where
  2419     B: "independent B" "B \<subseteq> span S" "S \<subseteq> span B" "card B = dim S" "pairwise orthogonal B"
  2420     by blast
  2421   from B have fB: "finite B" "card B = dim S"
  2422     using independent_bound by auto
  2423   from span_mono[OF B(2)] span_mono[OF B(3)]
  2424   have sSB: "span S = span B"
  2425     by (simp add: span_span)
  2426   let ?a = "a - sum (\<lambda>b. (a \<bullet> b / (b \<bullet> b)) *\<^sub>R b) B"
  2427   have "sum (\<lambda>b. (a \<bullet> b / (b \<bullet> b)) *\<^sub>R b) B \<in> span S"
  2428     unfolding sSB
  2429     apply (rule span_sum)
  2430     apply (rule span_mul)
  2431     apply (rule span_superset)
  2432     apply assumption
  2433     done
  2434   with a have a0:"?a  \<noteq> 0"
  2435     by auto
  2436   have "\<forall>x\<in>span B. ?a \<bullet> x = 0"
  2437   proof (rule span_induct')
  2438     show "subspace {x. ?a \<bullet> x = 0}"
  2439       by (auto simp add: subspace_def inner_add)
  2440   next
  2441     {
  2442       fix x
  2443       assume x: "x \<in> B"
  2444       from x have B': "B = insert x (B - {x})"
  2445         by blast
  2446       have fth: "finite (B - {x})"
  2447         using fB by simp
  2448       have "?a \<bullet> x = 0"
  2449         apply (subst B')
  2450         using fB fth
  2451         unfolding sum_clauses(2)[OF fth]
  2452         apply simp unfolding inner_simps
  2453         apply (clarsimp simp add: inner_add inner_sum_left)
  2454         apply (rule sum.neutral, rule ballI)
  2455         apply (simp only: inner_commute)
  2456         apply (auto simp add: x field_simps
  2457           intro: B(5)[unfolded pairwise_def orthogonal_def, rule_format])
  2458         done
  2459     }
  2460     then show "\<forall>x \<in> B. ?a \<bullet> x = 0"
  2461       by blast
  2462   qed
  2463   with a0 show ?thesis
  2464     unfolding sSB by (auto intro: exI[where x="?a"])
  2465 qed
  2466 
  2467 lemma span_not_univ_subset_hyperplane:
  2468   fixes S :: "'a::euclidean_space set"
  2469   assumes SU: "span S \<noteq> UNIV"
  2470   shows "\<exists> a. a \<noteq>0 \<and> span S \<subseteq> {x. a \<bullet> x = 0}"
  2471   using span_not_univ_orthogonal[OF SU] by auto
  2472 
  2473 lemma lowdim_subset_hyperplane:
  2474   fixes S :: "'a::euclidean_space set"
  2475   assumes d: "dim S < DIM('a)"
  2476   shows "\<exists>a::'a. a \<noteq> 0 \<and> span S \<subseteq> {x. a \<bullet> x = 0}"
  2477 proof -
  2478   {
  2479     assume "span S = UNIV"
  2480     then have "dim (span S) = dim (UNIV :: ('a) set)"
  2481       by simp
  2482     then have "dim S = DIM('a)"
  2483       by (simp add: dim_span dim_UNIV)
  2484     with d have False by arith
  2485   }
  2486   then have th: "span S \<noteq> UNIV"
  2487     by blast
  2488   from span_not_univ_subset_hyperplane[OF th] show ?thesis .
  2489 qed
  2490 
  2491 text \<open>We can extend a linear basis-basis injection to the whole set.\<close>
  2492 
  2493 lemma linear_indep_image_lemma:
  2494   assumes lf: "linear f"
  2495     and fB: "finite B"
  2496     and ifB: "independent (f ` B)"
  2497     and fi: "inj_on f B"
  2498     and xsB: "x \<in> span B"
  2499     and fx: "f x = 0"
  2500   shows "x = 0"
  2501   using fB ifB fi xsB fx
  2502 proof (induct arbitrary: x rule: finite_induct[OF fB])
  2503   case 1
  2504   then show ?case by auto
  2505 next
  2506   case (2 a b x)
  2507   have fb: "finite b" using "2.prems" by simp
  2508   have th0: "f ` b \<subseteq> f ` (insert a b)"
  2509     apply (rule image_mono)
  2510     apply blast
  2511     done
  2512   from independent_mono[ OF "2.prems"(2) th0]
  2513   have ifb: "independent (f ` b)"  .
  2514   have fib: "inj_on f b"
  2515     apply (rule subset_inj_on [OF "2.prems"(3)])
  2516     apply blast
  2517     done
  2518   from span_breakdown[of a "insert a b", simplified, OF "2.prems"(4)]
  2519   obtain k where k: "x - k*\<^sub>R a \<in> span (b - {a})"
  2520     by blast
  2521   have "f (x - k*\<^sub>R a) \<in> span (f ` b)"
  2522     unfolding span_linear_image[OF lf]
  2523     apply (rule imageI)
  2524     using k span_mono[of "b - {a}" b]
  2525     apply blast
  2526     done
  2527   then have "f x - k*\<^sub>R f a \<in> span (f ` b)"
  2528     by (simp add: linear_diff[OF lf] linear_cmul[OF lf])
  2529   then have th: "-k *\<^sub>R f a \<in> span (f ` b)"
  2530     using "2.prems"(5) by simp
  2531   have xsb: "x \<in> span b"
  2532   proof (cases "k = 0")
  2533     case True
  2534     with k have "x \<in> span (b - {a})" by simp
  2535     then show ?thesis using span_mono[of "b - {a}" b]
  2536       by blast
  2537   next
  2538     case False
  2539     with span_mul[OF th, of "- 1/ k"]
  2540     have th1: "f a \<in> span (f ` b)"
  2541       by auto
  2542     from inj_on_image_set_diff[OF "2.prems"(3), of "insert a b " "{a}", symmetric]
  2543     have tha: "f ` insert a b - f ` {a} = f ` (insert a b - {a})" by blast
  2544     from "2.prems"(2) [unfolded dependent_def bex_simps(8), rule_format, of "f a"]
  2545     have "f a \<notin> span (f ` b)" using tha
  2546       using "2.hyps"(2)
  2547       "2.prems"(3) by auto
  2548     with th1 have False by blast
  2549     then show ?thesis by blast
  2550   qed
  2551   from "2.hyps"(3)[OF fb ifb fib xsb "2.prems"(5)] show "x = 0" .
  2552 qed
  2553 
  2554 text \<open>Can construct an isomorphism between spaces of same dimension.\<close>
  2555 
  2556 lemma subspace_isomorphism:
  2557   fixes S :: "'a::euclidean_space set"
  2558     and T :: "'b::euclidean_space set"
  2559   assumes s: "subspace S"
  2560     and t: "subspace T"
  2561     and d: "dim S = dim T"
  2562   shows "\<exists>f. linear f \<and> f ` S = T \<and> inj_on f S"
  2563 proof -
  2564   from basis_exists[of S] independent_bound
  2565   obtain B where B: "B \<subseteq> S" "independent B" "S \<subseteq> span B" "card B = dim S" and fB: "finite B"
  2566     by blast
  2567   from basis_exists[of T] independent_bound
  2568   obtain C where C: "C \<subseteq> T" "independent C" "T \<subseteq> span C" "card C = dim T" and fC: "finite C"
  2569     by blast
  2570   from B(4) C(4) card_le_inj[of B C] d
  2571   obtain f where f: "f ` B \<subseteq> C" "inj_on f B" using \<open>finite B\<close> \<open>finite C\<close>
  2572     by auto
  2573   from linear_independent_extend[OF B(2)]
  2574   obtain g where g: "linear g" "\<forall>x\<in> B. g x = f x"
  2575     by blast
  2576   from inj_on_iff_eq_card[OF fB, of f] f(2) have "card (f ` B) = card B"
  2577     by simp
  2578   with B(4) C(4) have ceq: "card (f ` B) = card C"
  2579     using d by simp
  2580   have "g ` B = f ` B"
  2581     using g(2) by (auto simp add: image_iff)
  2582   also have "\<dots> = C" using card_subset_eq[OF fC f(1) ceq] .
  2583   finally have gBC: "g ` B = C" .
  2584   have gi: "inj_on g B"
  2585     using f(2) g(2) by (auto simp add: inj_on_def)
  2586   note g0 = linear_indep_image_lemma[OF g(1) fB, unfolded gBC, OF C(2) gi]
  2587   {
  2588     fix x y
  2589     assume x: "x \<in> S" and y: "y \<in> S" and gxy: "g x = g y"
  2590     from B(3) x y have x': "x \<in> span B" and y': "y \<in> span B"
  2591       by blast+
  2592     from gxy have th0: "g (x - y) = 0"
  2593       by (simp add: linear_diff[OF g(1)])
  2594     have th1: "x - y \<in> span B"
  2595       using x' y' by (metis span_diff)
  2596     have "x = y"
  2597       using g0[OF th1 th0] by simp
  2598   }
  2599   then have giS: "inj_on g S"
  2600     unfolding inj_on_def by blast
  2601   from span_subspace[OF B(1,3) s] have "g ` S = span (g ` B)"
  2602     by (simp add: span_linear_image[OF g(1)])
  2603   also have "\<dots> = span C" unfolding gBC ..
  2604   also have "\<dots> = T" using span_subspace[OF C(1,3) t] .
  2605   finally have gS: "g ` S = T" .
  2606   from g(1) gS giS show ?thesis
  2607     by blast
  2608 qed
  2609 
  2610 lemma linear_eq_stdbasis:
  2611   fixes f :: "'a::euclidean_space \<Rightarrow> _"
  2612   assumes lf: "linear f"
  2613     and lg: "linear g"
  2614     and fg: "\<forall>b\<in>Basis. f b = g b"
  2615   shows "f = g"
  2616   using linear_eq[OF lf lg, of _ Basis] fg by auto
  2617 
  2618 text \<open>Similar results for bilinear functions.\<close>
  2619 
  2620 lemma bilinear_eq:
  2621   assumes bf: "bilinear f"
  2622     and bg: "bilinear g"
  2623     and SB: "S \<subseteq> span B"
  2624     and TC: "T \<subseteq> span C"
  2625     and fg: "\<forall>x\<in> B. \<forall>y\<in> C. f x y = g x y"
  2626   shows "\<forall>x\<in>S. \<forall>y\<in>T. f x y = g x y "
  2627 proof -
  2628   let ?P = "{x. \<forall>y\<in> span C. f x y = g x y}"
  2629   from bf bg have sp: "subspace ?P"
  2630     unfolding bilinear_def linear_iff subspace_def bf bg
  2631     by (auto simp add: span_0 bilinear_lzero[OF bf] bilinear_lzero[OF bg] span_add Ball_def
  2632       intro: bilinear_ladd[OF bf])
  2633 
  2634   have "\<forall>x \<in> span B. \<forall>y\<in> span C. f x y = g x y"
  2635     apply (rule span_induct' [OF _ sp])
  2636     apply (rule ballI)
  2637     apply (rule span_induct')
  2638     apply (simp add: fg)
  2639     apply (auto simp add: subspace_def)
  2640     using bf bg unfolding bilinear_def linear_iff
  2641     apply (auto simp add: span_0 bilinear_rzero[OF bf] bilinear_rzero[OF bg] span_add Ball_def
  2642       intro: bilinear_ladd[OF bf])
  2643     done
  2644   then show ?thesis
  2645     using SB TC by auto
  2646 qed
  2647 
  2648 lemma bilinear_eq_stdbasis:
  2649   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space \<Rightarrow> _"
  2650   assumes bf: "bilinear f"
  2651     and bg: "bilinear g"
  2652     and fg: "\<forall>i\<in>Basis. \<forall>j\<in>Basis. f i j = g i j"
  2653   shows "f = g"
  2654   using bilinear_eq[OF bf bg equalityD2[OF span_Basis] equalityD2[OF span_Basis] fg] by blast
  2655 
  2656 text \<open>An injective map @{typ "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"} is also surjective.\<close>
  2657 
  2658 lemma linear_injective_imp_surjective:
  2659   fixes f :: "'a::euclidean_space \<Rightarrow> 'a::euclidean_space"
  2660   assumes lf: "linear f"
  2661     and fi: "inj f"
  2662   shows "surj f"
  2663 proof -
  2664   let ?U = "UNIV :: 'a set"
  2665   from basis_exists[of ?U] obtain B
  2666     where B: "B \<subseteq> ?U" "independent B" "?U \<subseteq> span B" "card B = dim ?U"
  2667     by blast
  2668   from B(4) have d: "dim ?U = card B"
  2669     by simp
  2670   have th: "?U \<subseteq> span (f ` B)"
  2671     apply (rule card_ge_dim_independent)
  2672     apply blast
  2673     apply (rule independent_injective_image[OF B(2) lf fi])
  2674     apply (rule order_eq_refl)
  2675     apply (rule sym)
  2676     unfolding d
  2677     apply (rule card_image)
  2678     apply (rule subset_inj_on[OF fi])
  2679     apply blast
  2680     done
  2681   from th show ?thesis
  2682     unfolding span_linear_image[OF lf] surj_def
  2683     using B(3) by blast
  2684 qed
  2685 
  2686 text \<open>And vice versa.\<close>
  2687 
  2688 lemma surjective_iff_injective_gen:
  2689   assumes fS: "finite S"
  2690     and fT: "finite T"
  2691     and c: "card S = card T"
  2692     and ST: "f ` S \<subseteq> T"
  2693   shows "(\<forall>y \<in> T. \<exists>x \<in> S. f x = y) \<longleftrightarrow> inj_on f S"
  2694   (is "?lhs \<longleftrightarrow> ?rhs")
  2695 proof
  2696   assume h: "?lhs"
  2697   {
  2698     fix x y
  2699     assume x: "x \<in> S"
  2700     assume y: "y \<in> S"
  2701     assume f: "f x = f y"
  2702     from x fS have S0: "card S \<noteq> 0"
  2703       by auto
  2704     have "x = y"
  2705     proof (rule ccontr)
  2706       assume xy: "\<not> ?thesis"
  2707       have th: "card S \<le> card (f ` (S - {y}))"
  2708         unfolding c
  2709         apply (rule card_mono)
  2710         apply (rule finite_imageI)
  2711         using fS apply simp
  2712         using h xy x y f unfolding subset_eq image_iff
  2713         apply auto
  2714         apply (case_tac "xa = f x")
  2715         apply (rule bexI[where x=x])
  2716         apply auto
  2717         done
  2718       also have " \<dots> \<le> card (S - {y})"
  2719         apply (rule card_image_le)
  2720         using fS by simp
  2721       also have "\<dots> \<le> card S - 1" using y fS by simp
  2722       finally show False using S0 by arith
  2723     qed
  2724   }
  2725   then show ?rhs
  2726     unfolding inj_on_def by blast
  2727 next
  2728   assume h: ?rhs
  2729   have "f ` S = T"
  2730     apply (rule card_subset_eq[OF fT ST])
  2731     unfolding card_image[OF h]
  2732     apply (rule c)
  2733     done
  2734   then show ?lhs by blast
  2735 qed
  2736 
  2737 lemma linear_surjective_imp_injective:
  2738   fixes f :: "'a::euclidean_space \<Rightarrow> 'a::euclidean_space"
  2739   assumes lf: "linear f"
  2740     and sf: "surj f"
  2741   shows "inj f"
  2742 proof -
  2743   let ?U = "UNIV :: 'a set"
  2744   from basis_exists[of ?U] obtain B
  2745     where B: "B \<subseteq> ?U" "independent B" "?U \<subseteq> span B" and d: "card B = dim ?U"
  2746     by blast
  2747   {
  2748     fix x
  2749     assume x: "x \<in> span B"
  2750     assume fx: "f x = 0"
  2751     from B(2) have fB: "finite B"
  2752       using independent_bound by auto
  2753     have fBi: "independent (f ` B)"
  2754       apply (rule card_le_dim_spanning[of "f ` B" ?U])
  2755       apply blast
  2756       using sf B(3)
  2757       unfolding span_linear_image[OF lf] surj_def subset_eq image_iff
  2758       apply blast
  2759       using fB apply blast
  2760       unfolding d[symmetric]
  2761       apply (rule card_image_le)
  2762       apply (rule fB)
  2763       done
  2764     have th0: "dim ?U \<le> card (f ` B)"
  2765       apply (rule span_card_ge_dim)
  2766       apply blast
  2767       unfolding span_linear_image[OF lf]
  2768       apply (rule subset_trans[where B = "f ` UNIV"])
  2769       using sf unfolding surj_def
  2770       apply blast
  2771       apply (rule image_mono)
  2772       apply (rule B(3))
  2773       apply (metis finite_imageI fB)
  2774       done
  2775     moreover have "card (f ` B) \<le> card B"
  2776       by (rule card_image_le, rule fB)
  2777     ultimately have th1: "card B = card (f ` B)"
  2778       unfolding d by arith
  2779     have fiB: "inj_on f B"
  2780       unfolding surjective_iff_injective_gen[OF fB finite_imageI[OF fB] th1 subset_refl, symmetric]
  2781       by blast
  2782     from linear_indep_image_lemma[OF lf fB fBi fiB x] fx
  2783     have "x = 0" by blast
  2784   }
  2785   then show ?thesis
  2786     unfolding linear_injective_0[OF lf]
  2787     using B(3)
  2788     by blast
  2789 qed
  2790 
  2791 text \<open>Hence either is enough for isomorphism.\<close>
  2792 
  2793 lemma left_right_inverse_eq:
  2794   assumes fg: "f \<circ> g = id"
  2795     and gh: "g \<circ> h = id"
  2796   shows "f = h"
  2797 proof -
  2798   have "f = f \<circ> (g \<circ> h)"
  2799     unfolding gh by simp
  2800   also have "\<dots> = (f \<circ> g) \<circ> h"
  2801     by (simp add: o_assoc)
  2802   finally show "f = h"
  2803     unfolding fg by simp
  2804 qed
  2805 
  2806 lemma isomorphism_expand:
  2807   "f \<circ> g = id \<and> g \<circ> f = id \<longleftrightarrow> (\<forall>x. f (g x) = x) \<and> (\<forall>x. g (f x) = x)"
  2808   by (simp add: fun_eq_iff o_def id_def)
  2809 
  2810 lemma linear_injective_isomorphism:
  2811   fixes f :: "'a::euclidean_space \<Rightarrow> 'a::euclidean_space"
  2812   assumes lf: "linear f"
  2813     and fi: "inj f"
  2814   shows "\<exists>f'. linear f' \<and> (\<forall>x. f' (f x) = x) \<and> (\<forall>x. f (f' x) = x)"
  2815   unfolding isomorphism_expand[symmetric]
  2816   using linear_surjective_right_inverse[OF lf linear_injective_imp_surjective[OF lf fi]]
  2817     linear_injective_left_inverse[OF lf fi]
  2818   by (metis left_right_inverse_eq)
  2819 
  2820 lemma linear_surjective_isomorphism:
  2821   fixes f :: "'a::euclidean_space \<Rightarrow> 'a::euclidean_space"
  2822   assumes lf: "linear f"
  2823     and sf: "surj f"
  2824   shows "\<exists>f'. linear f' \<and> (\<forall>x. f' (f x) = x) \<and> (\<forall>x. f (f' x) = x)"
  2825   unfolding isomorphism_expand[symmetric]
  2826   using linear_surjective_right_inverse[OF lf sf]
  2827     linear_injective_left_inverse[OF lf linear_surjective_imp_injective[OF lf sf]]
  2828   by (metis left_right_inverse_eq)
  2829 
  2830 text \<open>Left and right inverses are the same for
  2831   @{typ "'a::euclidean_space \<Rightarrow> 'a::euclidean_space"}.\<close>
  2832 
  2833 lemma linear_inverse_left:
  2834   fixes f :: "'a::euclidean_space \<Rightarrow> 'a::euclidean_space"
  2835   assumes lf: "linear f"
  2836     and lf': "linear f'"
  2837   shows "f \<circ> f' = id \<longleftrightarrow> f' \<circ> f = id"
  2838 proof -
  2839   {
  2840     fix f f':: "'a \<Rightarrow> 'a"
  2841     assume lf: "linear f" "linear f'"
  2842     assume f: "f \<circ> f' = id"
  2843     from f have sf: "surj f"
  2844       apply (auto simp add: o_def id_def surj_def)
  2845       apply metis
  2846       done
  2847     from linear_surjective_isomorphism[OF lf(1) sf] lf f
  2848     have "f' \<circ> f = id"
  2849       unfolding fun_eq_iff o_def id_def by metis
  2850   }
  2851   then show ?thesis
  2852     using lf lf' by metis
  2853 qed
  2854 
  2855 text \<open>Moreover, a one-sided inverse is automatically linear.\<close>
  2856 
  2857 lemma left_inverse_linear:
  2858   fixes f :: "'a::euclidean_space \<Rightarrow> 'a::euclidean_space"
  2859   assumes lf: "linear f"
  2860     and gf: "g \<circ> f = id"
  2861   shows "linear g"
  2862 proof -
  2863   from gf have fi: "inj f"
  2864     apply (auto simp add: inj_on_def o_def id_def fun_eq_iff)
  2865     apply metis
  2866     done
  2867   from linear_injective_isomorphism[OF lf fi]
  2868   obtain h :: "'a \<Rightarrow> 'a" where h: "linear h" "\<forall>x. h (f x) = x" "\<forall>x. f (h x) = x"
  2869     by blast
  2870   have "h = g"
  2871     apply (rule ext) using gf h(2,3)
  2872     apply (simp add: o_def id_def fun_eq_iff)
  2873     apply metis
  2874     done
  2875   with h(1) show ?thesis by blast
  2876 qed
  2877 
  2878 lemma inj_linear_imp_inv_linear:
  2879   fixes f :: "'a::euclidean_space \<Rightarrow> 'a::euclidean_space"
  2880   assumes "linear f" "inj f" shows "linear (inv f)"
  2881 using assms inj_iff left_inverse_linear by blast
  2882 
  2883 
  2884 subsection \<open>Infinity norm\<close>
  2885 
  2886 definition "infnorm (x::'a::euclidean_space) = Sup {\<bar>x \<bullet> b\<bar> |b. b \<in> Basis}"
  2887 
  2888 lemma infnorm_set_image:
  2889   fixes x :: "'a::euclidean_space"
  2890   shows "{\<bar>x \<bullet> i\<bar> |i. i \<in> Basis} = (\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis"
  2891   by blast
  2892 
  2893 lemma infnorm_Max:
  2894   fixes x :: "'a::euclidean_space"
  2895   shows "infnorm x = Max ((\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis)"
  2896   by (simp add: infnorm_def infnorm_set_image cSup_eq_Max)
  2897 
  2898 lemma infnorm_set_lemma:
  2899   fixes x :: "'a::euclidean_space"
  2900   shows "finite {\<bar>x \<bullet> i\<bar> |i. i \<in> Basis}"
  2901     and "{\<bar>x \<bullet> i\<bar> |i. i \<in> Basis} \<noteq> {}"
  2902   unfolding infnorm_set_image
  2903   by auto
  2904 
  2905 lemma infnorm_pos_le:
  2906   fixes x :: "'a::euclidean_space"
  2907   shows "0 \<le> infnorm x"
  2908   by (simp add: infnorm_Max Max_ge_iff ex_in_conv)
  2909 
  2910 lemma infnorm_triangle:
  2911   fixes x :: "'a::euclidean_space"
  2912   shows "infnorm (x + y) \<le> infnorm x + infnorm y"
  2913 proof -
  2914   have *: "\<And>a b c d :: real. \<bar>a\<bar> \<le> c \<Longrightarrow> \<bar>b\<bar> \<le> d \<Longrightarrow> \<bar>a + b\<bar> \<le> c + d"
  2915     by simp
  2916   show ?thesis
  2917     by (auto simp: infnorm_Max inner_add_left intro!: *)
  2918 qed
  2919 
  2920 lemma infnorm_eq_0:
  2921   fixes x :: "'a::euclidean_space"
  2922   shows "infnorm x = 0 \<longleftrightarrow> x = 0"
  2923 proof -
  2924   have "infnorm x \<le> 0 \<longleftrightarrow> x = 0"
  2925     unfolding infnorm_Max by (simp add: euclidean_all_zero_iff)
  2926   then show ?thesis
  2927     using infnorm_pos_le[of x] by simp
  2928 qed
  2929 
  2930 lemma infnorm_0: "infnorm 0 = 0"
  2931   by (simp add: infnorm_eq_0)
  2932 
  2933 lemma infnorm_neg: "infnorm (- x) = infnorm x"
  2934   unfolding infnorm_def
  2935   apply (rule cong[of "Sup" "Sup"])
  2936   apply blast
  2937   apply auto
  2938   done
  2939 
  2940 lemma infnorm_sub: "infnorm (x - y) = infnorm (y - x)"
  2941 proof -
  2942   have "y - x = - (x - y)" by simp
  2943   then show ?thesis
  2944     by (metis infnorm_neg)
  2945 qed
  2946 
  2947 lemma real_abs_sub_infnorm: "\<bar>infnorm x - infnorm y\<bar> \<le> infnorm (x - y)"
  2948 proof -
  2949   have th: "\<And>(nx::real) n ny. nx \<le> n + ny \<Longrightarrow> ny \<le> n + nx \<Longrightarrow> \<bar>nx - ny\<bar> \<le> n"
  2950     by arith
  2951   from infnorm_triangle[of "x - y" " y"] infnorm_triangle[of "x - y" "-x"]
  2952   have ths: "infnorm x \<le> infnorm (x - y) + infnorm y"
  2953     "infnorm y \<le> infnorm (x - y) + infnorm x"
  2954     by (simp_all add: field_simps infnorm_neg)
  2955   from th[OF ths] show ?thesis .
  2956 qed
  2957 
  2958 lemma real_abs_infnorm: "\<bar>infnorm x\<bar> = infnorm x"
  2959   using infnorm_pos_le[of x] by arith
  2960 
  2961 lemma Basis_le_infnorm:
  2962   fixes x :: "'a::euclidean_space"
  2963   shows "b \<in> Basis \<Longrightarrow> \<bar>x \<bullet> b\<bar> \<le> infnorm x"
  2964   by (simp add: infnorm_Max)
  2965 
  2966 lemma infnorm_mul: "infnorm (a *\<^sub>R x) = \<bar>a\<bar> * infnorm x"
  2967   unfolding infnorm_Max
  2968 proof (safe intro!: Max_eqI)
  2969   let ?B = "(\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis"
  2970   {
  2971     fix b :: 'a
  2972     assume "b \<in> Basis"
  2973     then show "\<bar>a *\<^sub>R x \<bullet> b\<bar> \<le> \<bar>a\<bar> * Max ?B"
  2974       by (simp add: abs_mult mult_left_mono)
  2975   next
  2976     from Max_in[of ?B] obtain b where "b \<in> Basis" "Max ?B = \<bar>x \<bullet> b\<bar>"
  2977       by (auto simp del: Max_in)
  2978     then show "\<bar>a\<bar> * Max ((\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis) \<in> (\<lambda>i. \<bar>a *\<^sub>R x \<bullet> i\<bar>) ` Basis"
  2979       by (intro image_eqI[where x=b]) (auto simp: abs_mult)
  2980   }
  2981 qed simp
  2982 
  2983 lemma infnorm_mul_lemma: "infnorm (a *\<^sub>R x) \<le> \<bar>a\<bar> * infnorm x"
  2984   unfolding infnorm_mul ..
  2985 
  2986 lemma infnorm_pos_lt: "infnorm x > 0 \<longleftrightarrow> x \<noteq> 0"
  2987   using infnorm_pos_le[of x] infnorm_eq_0[of x] by arith
  2988 
  2989 text \<open>Prove that it differs only up to a bound from Euclidean norm.\<close>
  2990 
  2991 lemma infnorm_le_norm: "infnorm x \<le> norm x"
  2992   by (simp add: Basis_le_norm infnorm_Max)
  2993 
  2994 lemma (in euclidean_space) euclidean_inner: "inner x y = (\<Sum>b\<in>Basis. (x \<bullet> b) * (y \<bullet> b))"
  2995   by (subst (1 2) euclidean_representation [symmetric])
  2996     (simp add: inner_sum_right inner_Basis ac_simps)
  2997 
  2998 lemma norm_le_infnorm:
  2999   fixes x :: "'a::euclidean_space"
  3000   shows "norm x \<le> sqrt DIM('a) * infnorm x"
  3001 proof -
  3002   let ?d = "DIM('a)"
  3003   have "real ?d \<ge> 0"
  3004     by simp
  3005   then have d2: "(sqrt (real ?d))\<^sup>2 = real ?d"
  3006     by (auto intro: real_sqrt_pow2)
  3007   have th: "sqrt (real ?d) * infnorm x \<ge> 0"
  3008     by (simp add: zero_le_mult_iff infnorm_pos_le)
  3009   have th1: "x \<bullet> x \<le> (sqrt (real ?d) * infnorm x)\<^sup>2"
  3010     unfolding power_mult_distrib d2
  3011     apply (subst euclidean_inner)
  3012     apply (subst power2_abs[symmetric])
  3013     apply (rule order_trans[OF sum_bounded_above[where K="\<bar>infnorm x\<bar>\<^sup>2"]])
  3014     apply (auto simp add: power2_eq_square[symmetric])
  3015     apply (subst power2_abs[symmetric])
  3016     apply (rule power_mono)
  3017     apply (auto simp: infnorm_Max)
  3018     done
  3019   from real_le_lsqrt[OF inner_ge_zero th th1]
  3020   show ?thesis
  3021     unfolding norm_eq_sqrt_inner id_def .
  3022 qed
  3023 
  3024 lemma tendsto_infnorm [tendsto_intros]:
  3025   assumes "(f \<longlongrightarrow> a) F"
  3026   shows "((\<lambda>x. infnorm (f x)) \<longlongrightarrow> infnorm a) F"
  3027 proof (rule tendsto_compose [OF LIM_I assms])
  3028   fix r :: real
  3029   assume "r > 0"
  3030   then show "\<exists>s>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (infnorm x - infnorm a) < r"
  3031     by (metis real_norm_def le_less_trans real_abs_sub_infnorm infnorm_le_norm)
  3032 qed
  3033 
  3034 text \<open>Equality in Cauchy-Schwarz and triangle inequalities.\<close>
  3035 
  3036 lemma norm_cauchy_schwarz_eq: "x \<bullet> y = norm x * norm y \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x"
  3037   (is "?lhs \<longleftrightarrow> ?rhs")
  3038 proof -
  3039   {
  3040     assume h: "x = 0"
  3041     then have ?thesis by simp
  3042   }
  3043   moreover
  3044   {
  3045     assume h: "y = 0"
  3046     then have ?thesis by simp
  3047   }
  3048   moreover
  3049   {
  3050     assume x: "x \<noteq> 0" and y: "y \<noteq> 0"
  3051     from inner_eq_zero_iff[of "norm y *\<^sub>R x - norm x *\<^sub>R y"]
  3052     have "?rhs \<longleftrightarrow>
  3053       (norm y * (norm y * norm x * norm x - norm x * (x \<bullet> y)) -
  3054         norm x * (norm y * (y \<bullet> x) - norm x * norm y * norm y) =  0)"
  3055       using x y
  3056       unfolding inner_simps
  3057       unfolding power2_norm_eq_inner[symmetric] power2_eq_square right_minus_eq
  3058       apply (simp add: inner_commute)
  3059       apply (simp add: field_simps)
  3060       apply metis
  3061       done
  3062     also have "\<dots> \<longleftrightarrow> (2 * norm x * norm y * (norm x * norm y - x \<bullet> y) = 0)" using x y
  3063       by (simp add: field_simps inner_commute)
  3064     also have "\<dots> \<longleftrightarrow> ?lhs" using x y
  3065       apply simp
  3066       apply metis
  3067       done
  3068     finally have ?thesis by blast
  3069   }
  3070   ultimately show ?thesis by blast
  3071 qed
  3072 
  3073 lemma norm_cauchy_schwarz_abs_eq:
  3074   "\<bar>x \<bullet> y\<bar> = norm x * norm y \<longleftrightarrow>
  3075     norm x *\<^sub>R y = norm y *\<^sub>R x \<or> norm x *\<^sub>R y = - norm y *\<^sub>R x"
  3076   (is "?lhs \<longleftrightarrow> ?rhs")
  3077 proof -
  3078   have th: "\<And>(x::real) a. a \<ge> 0 \<Longrightarrow> \<bar>x\<bar> = a \<longleftrightarrow> x = a \<or> x = - a"
  3079     by arith
  3080   have "?rhs \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x \<or> norm (- x) *\<^sub>R y = norm y *\<^sub>R (- x)"
  3081     by simp
  3082   also have "\<dots> \<longleftrightarrow>(x \<bullet> y = norm x * norm y \<or> (- x) \<bullet> y = norm x * norm y)"
  3083     unfolding norm_cauchy_schwarz_eq[symmetric]
  3084     unfolding norm_minus_cancel norm_scaleR ..
  3085   also have "\<dots> \<longleftrightarrow> ?lhs"
  3086     unfolding th[OF mult_nonneg_nonneg, OF norm_ge_zero[of x] norm_ge_zero[of y]] inner_simps
  3087     by auto
  3088   finally show ?thesis ..
  3089 qed
  3090 
  3091 lemma norm_triangle_eq:
  3092   fixes x y :: "'a::real_inner"
  3093   shows "norm (x + y) = norm x + norm y \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x"
  3094 proof -
  3095   {
  3096     assume x: "x = 0 \<or> y = 0"
  3097     then have ?thesis
  3098       by (cases "x = 0") simp_all
  3099   }
  3100   moreover
  3101   {
  3102     assume x: "x \<noteq> 0" and y: "y \<noteq> 0"
  3103     then have "norm x \<noteq> 0" "norm y \<noteq> 0"
  3104       by simp_all
  3105     then have n: "norm x > 0" "norm y > 0"
  3106       using norm_ge_zero[of x] norm_ge_zero[of y] by arith+
  3107     have th: "\<And>(a::real) b c. a + b + c \<noteq> 0 \<Longrightarrow> a = b + c \<longleftrightarrow> a\<^sup>2 = (b + c)\<^sup>2"
  3108       by algebra
  3109     have "norm (x + y) = norm x + norm y \<longleftrightarrow> (norm (x + y))\<^sup>2 = (norm x + norm y)\<^sup>2"
  3110       apply (rule th)
  3111       using n norm_ge_zero[of "x + y"]
  3112       apply arith
  3113       done
  3114     also have "\<dots> \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x"
  3115       unfolding norm_cauchy_schwarz_eq[symmetric]
  3116       unfolding power2_norm_eq_inner inner_simps
  3117       by (simp add: power2_norm_eq_inner[symmetric] power2_eq_square inner_commute field_simps)
  3118     finally have ?thesis .
  3119   }
  3120   ultimately show ?thesis by blast
  3121 qed
  3122 
  3123 
  3124 subsection \<open>Collinearity\<close>
  3125 
  3126 definition collinear :: "'a::real_vector set \<Rightarrow> bool"
  3127   where "collinear S \<longleftrightarrow> (\<exists>u. \<forall>x \<in> S. \<forall> y \<in> S. \<exists>c. x - y = c *\<^sub>R u)"
  3128 
  3129 lemma collinear_alt:
  3130      "collinear S \<longleftrightarrow> (\<exists>u v. \<forall>x \<in> S. \<exists>c. x = u + c *\<^sub>R v)" (is "?lhs = ?rhs")
  3131 proof
  3132   assume ?lhs
  3133   then show ?rhs
  3134     unfolding collinear_def by (metis Groups.add_ac(2) diff_add_cancel)
  3135 next
  3136   assume ?rhs
  3137   then obtain u v where *: "\<And>x. x \<in> S \<Longrightarrow> \<exists>c. x = u + c *\<^sub>R v"
  3138     by (auto simp: )
  3139   have "\<exists>c. x - y = c *\<^sub>R v" if "x \<in> S" "y \<in> S" for x y
  3140         by (metis *[OF \<open>x \<in> S\<close>] *[OF \<open>y \<in> S\<close>] scaleR_left.diff add_diff_cancel_left)
  3141   then show ?lhs
  3142     using collinear_def by blast
  3143 qed
  3144 
  3145 lemma collinear:
  3146   fixes S :: "'a::{perfect_space,real_vector} set"
  3147   shows "collinear S \<longleftrightarrow> (\<exists>u. u \<noteq> 0 \<and> (\<forall>x \<in> S. \<forall> y \<in> S. \<exists>c. x - y = c *\<^sub>R u))"
  3148 proof -
  3149   have "\<exists>v. v \<noteq> 0 \<and> (\<forall>x\<in>S. \<forall>y\<in>S. \<exists>c. x - y = c *\<^sub>R v)"
  3150     if "\<forall>x\<in>S. \<forall>y\<in>S. \<exists>c. x - y = c *\<^sub>R u" "u=0" for u
  3151   proof -
  3152     have "\<forall>x\<in>S. \<forall>y\<in>S. x = y"
  3153       using that by auto
  3154     moreover
  3155     obtain v::'a where "v \<noteq> 0"
  3156       using UNIV_not_singleton [of 0] by auto
  3157     ultimately have "\<forall>x\<in>S. \<forall>y\<in>S. \<exists>c. x - y = c *\<^sub>R v"
  3158       by auto
  3159     then show ?thesis
  3160       using \<open>v \<noteq> 0\<close> by blast
  3161   qed
  3162   then show ?thesis
  3163     apply (clarsimp simp: collinear_def)
  3164     by (metis real_vector.scale_zero_right vector_fraction_eq_iff)
  3165 qed
  3166 
  3167 lemma collinear_subset: "\<lbrakk>collinear T; S \<subseteq> T\<rbrakk> \<Longrightarrow> collinear S"
  3168   by (meson collinear_def subsetCE)
  3169 
  3170 lemma collinear_empty [iff]: "collinear {}"
  3171   by (simp add: collinear_def)
  3172 
  3173 lemma collinear_sing [iff]: "collinear {x}"
  3174   by (simp add: collinear_def)
  3175 
  3176 lemma collinear_2 [iff]: "collinear {x, y}"
  3177   apply (simp add: collinear_def)
  3178   apply (rule exI[where x="x - y"])
  3179   apply auto
  3180   apply (rule exI[where x=1], simp)
  3181   apply (rule exI[where x="- 1"], simp)
  3182   done
  3183 
  3184 lemma collinear_lemma: "collinear {0, x, y} \<longleftrightarrow> x = 0 \<or> y = 0 \<or> (\<exists>c. y = c *\<^sub>R x)"
  3185   (is "?lhs \<longleftrightarrow> ?rhs")
  3186 proof -
  3187   {
  3188     assume "x = 0 \<or> y = 0"
  3189     then have ?thesis
  3190       by (cases "x = 0") (simp_all add: collinear_2 insert_commute)
  3191   }
  3192   moreover
  3193   {
  3194     assume x: "x \<noteq> 0" and y: "y \<noteq> 0"
  3195     have ?thesis
  3196     proof
  3197       assume h: "?lhs"
  3198       then obtain u where u: "\<forall> x\<in> {0,x,y}. \<forall>y\<in> {0,x,y}. \<exists>c. x - y = c *\<^sub>R u"
  3199         unfolding collinear_def by blast
  3200       from u[rule_format, of x 0] u[rule_format, of y 0]
  3201       obtain cx and cy where
  3202         cx: "x = cx *\<^sub>R u" and cy: "y = cy *\<^sub>R u"
  3203         by auto
  3204       from cx x have cx0: "cx \<noteq> 0" by auto
  3205       from cy y have cy0: "cy \<noteq> 0" by auto
  3206       let ?d = "cy / cx"
  3207       from cx cy cx0 have "y = ?d *\<^sub>R x"
  3208         by simp
  3209       then show ?rhs using x y by blast
  3210     next
  3211       assume h: "?rhs"
  3212       then obtain c where c: "y = c *\<^sub>R x"
  3213         using x y by blast
  3214       show ?lhs
  3215         unfolding collinear_def c
  3216         apply (rule exI[where x=x])
  3217         apply auto
  3218         apply (rule exI[where x="- 1"], simp)
  3219         apply (rule exI[where x= "-c"], simp)
  3220         apply (rule exI[where x=1], simp)
  3221         apply (rule exI[where x="1 - c"], simp add: scaleR_left_diff_distrib)
  3222         apply (rule exI[where x="c - 1"], simp add: scaleR_left_diff_distrib)
  3223         done
  3224     qed
  3225   }
  3226   ultimately show ?thesis by blast
  3227 qed
  3228 
  3229 lemma norm_cauchy_schwarz_equal: "\<bar>x \<bullet> y\<bar> = norm x * norm y \<longleftrightarrow> collinear {0, x, y}"
  3230   unfolding norm_cauchy_schwarz_abs_eq
  3231   apply (cases "x=0", simp_all)
  3232   apply (cases "y=0", simp_all add: insert_commute)
  3233   unfolding collinear_lemma
  3234   apply simp
  3235   apply (subgoal_tac "norm x \<noteq> 0")
  3236   apply (subgoal_tac "norm y \<noteq> 0")
  3237   apply (rule iffI)
  3238   apply (cases "norm x *\<^sub>R y = norm y *\<^sub>R x")
  3239   apply (rule exI[where x="(1/norm x) * norm y"])
  3240   apply (drule sym)
  3241   unfolding scaleR_scaleR[symmetric]
  3242   apply (simp add: field_simps)
  3243   apply (rule exI[where x="(1/norm x) * - norm y"])
  3244   apply clarify
  3245   apply (drule sym)
  3246   unfolding scaleR_scaleR[symmetric]
  3247   apply (simp add: field_simps)
  3248   apply (erule exE)
  3249   apply (erule ssubst)
  3250   unfolding scaleR_scaleR
  3251   unfolding norm_scaleR
  3252   apply (subgoal_tac "norm x * c = \<bar>c\<bar> * norm x \<or> norm x * c = - \<bar>c\<bar> * norm x")
  3253   apply (auto simp add: field_simps)
  3254   done
  3255 
  3256 end