src/HOL/Auth/Event.thy
author paulson
Wed Jan 04 16:13:53 2006 +0100 (2006-01-04)
changeset 18570 ffce25f9aa7f
parent 17990 86d462f305e0
child 20768 1d478c2d621f
permissions -rw-r--r--
a few more named lemmas
     1 (*  Title:      HOL/Auth/Event
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1996  University of Cambridge
     5 
     6 Datatype of events; function "spies"; freshness
     7 
     8 "bad" agents have been broken by the Spy; their private keys and internal
     9     stores are visible to him
    10 *)
    11 
    12 header{*Theory of Events for Security Protocols*}
    13 
    14 theory Event imports Message begin
    15 
    16 consts  (*Initial states of agents -- parameter of the construction*)
    17   initState :: "agent => msg set"
    18 
    19 datatype
    20   event = Says  agent agent msg
    21         | Gets  agent       msg
    22         | Notes agent       msg
    23        
    24 consts 
    25   bad    :: "agent set"				(*compromised agents*)
    26   knows  :: "agent => event list => msg set"
    27 
    28 
    29 text{*The constant "spies" is retained for compatibility's sake*}
    30 syntax
    31   spies  :: "event list => msg set"
    32 
    33 translations
    34   "spies"   => "knows Spy"
    35 
    36 text{*Spy has access to his own key for spoof messages, but Server is secure*}
    37 specification (bad)
    38   Spy_in_bad     [iff]: "Spy \<in> bad"
    39   Server_not_bad [iff]: "Server \<notin> bad"
    40     by (rule exI [of _ "{Spy}"], simp)
    41 
    42 primrec
    43   knows_Nil:   "knows A [] = initState A"
    44   knows_Cons:
    45     "knows A (ev # evs) =
    46        (if A = Spy then 
    47 	(case ev of
    48 	   Says A' B X => insert X (knows Spy evs)
    49 	 | Gets A' X => knows Spy evs
    50 	 | Notes A' X  => 
    51 	     if A' \<in> bad then insert X (knows Spy evs) else knows Spy evs)
    52 	else
    53 	(case ev of
    54 	   Says A' B X => 
    55 	     if A'=A then insert X (knows A evs) else knows A evs
    56 	 | Gets A' X    => 
    57 	     if A'=A then insert X (knows A evs) else knows A evs
    58 	 | Notes A' X    => 
    59 	     if A'=A then insert X (knows A evs) else knows A evs))"
    60 
    61 (*
    62   Case A=Spy on the Gets event
    63   enforces the fact that if a message is received then it must have been sent,
    64   therefore the oops case must use Notes
    65 *)
    66 
    67 consts
    68   (*Set of items that might be visible to somebody:
    69     complement of the set of fresh items*)
    70   used :: "event list => msg set"
    71 
    72 primrec
    73   used_Nil:   "used []         = (UN B. parts (initState B))"
    74   used_Cons:  "used (ev # evs) =
    75 		     (case ev of
    76 			Says A B X => parts {X} \<union> used evs
    77 		      | Gets A X   => used evs
    78 		      | Notes A X  => parts {X} \<union> used evs)"
    79     --{*The case for @{term Gets} seems anomalous, but @{term Gets} always
    80         follows @{term Says} in real protocols.  Seems difficult to change.
    81         See @{text Gets_correct} in theory @{text "Guard/Extensions.thy"}. *}
    82 
    83 lemma Notes_imp_used [rule_format]: "Notes A X \<in> set evs --> X \<in> used evs"
    84 apply (induct_tac evs)
    85 apply (auto split: event.split) 
    86 done
    87 
    88 lemma Says_imp_used [rule_format]: "Says A B X \<in> set evs --> X \<in> used evs"
    89 apply (induct_tac evs)
    90 apply (auto split: event.split) 
    91 done
    92 
    93 
    94 subsection{*Function @{term knows}*}
    95 
    96 (*Simplifying   
    97  parts(insert X (knows Spy evs)) = parts{X} \<union> parts(knows Spy evs).
    98   This version won't loop with the simplifier.*)
    99 lemmas parts_insert_knows_A = parts_insert [of _ "knows A evs", standard]
   100 
   101 lemma knows_Spy_Says [simp]:
   102      "knows Spy (Says A B X # evs) = insert X (knows Spy evs)"
   103 by simp
   104 
   105 text{*Letting the Spy see "bad" agents' notes avoids redundant case-splits
   106       on whether @{term "A=Spy"} and whether @{term "A\<in>bad"}*}
   107 lemma knows_Spy_Notes [simp]:
   108      "knows Spy (Notes A X # evs) =  
   109           (if A:bad then insert X (knows Spy evs) else knows Spy evs)"
   110 by simp
   111 
   112 lemma knows_Spy_Gets [simp]: "knows Spy (Gets A X # evs) = knows Spy evs"
   113 by simp
   114 
   115 lemma knows_Spy_subset_knows_Spy_Says:
   116      "knows Spy evs \<subseteq> knows Spy (Says A B X # evs)"
   117 by (simp add: subset_insertI)
   118 
   119 lemma knows_Spy_subset_knows_Spy_Notes:
   120      "knows Spy evs \<subseteq> knows Spy (Notes A X # evs)"
   121 by force
   122 
   123 lemma knows_Spy_subset_knows_Spy_Gets:
   124      "knows Spy evs \<subseteq> knows Spy (Gets A X # evs)"
   125 by (simp add: subset_insertI)
   126 
   127 text{*Spy sees what is sent on the traffic*}
   128 lemma Says_imp_knows_Spy [rule_format]:
   129      "Says A B X \<in> set evs --> X \<in> knows Spy evs"
   130 apply (induct_tac "evs")
   131 apply (simp_all (no_asm_simp) split add: event.split)
   132 done
   133 
   134 lemma Notes_imp_knows_Spy [rule_format]:
   135      "Notes A X \<in> set evs --> A: bad --> X \<in> knows Spy evs"
   136 apply (induct_tac "evs")
   137 apply (simp_all (no_asm_simp) split add: event.split)
   138 done
   139 
   140 
   141 text{*Elimination rules: derive contradictions from old Says events containing
   142   items known to be fresh*}
   143 lemmas knows_Spy_partsEs =
   144      Says_imp_knows_Spy [THEN parts.Inj, THEN revcut_rl, standard] 
   145      parts.Body [THEN revcut_rl, standard]
   146 
   147 lemmas Says_imp_analz_Spy = Says_imp_knows_Spy [THEN analz.Inj]
   148 
   149 text{*Compatibility for the old "spies" function*}
   150 lemmas spies_partsEs = knows_Spy_partsEs
   151 lemmas Says_imp_spies = Says_imp_knows_Spy
   152 lemmas parts_insert_spies = parts_insert_knows_A [of _ Spy]
   153 
   154 
   155 subsection{*Knowledge of Agents*}
   156 
   157 lemma knows_Says: "knows A (Says A B X # evs) = insert X (knows A evs)"
   158 by simp
   159 
   160 lemma knows_Notes: "knows A (Notes A X # evs) = insert X (knows A evs)"
   161 by simp
   162 
   163 lemma knows_Gets:
   164      "A \<noteq> Spy --> knows A (Gets A X # evs) = insert X (knows A evs)"
   165 by simp
   166 
   167 
   168 lemma knows_subset_knows_Says: "knows A evs \<subseteq> knows A (Says A' B X # evs)"
   169 by (simp add: subset_insertI)
   170 
   171 lemma knows_subset_knows_Notes: "knows A evs \<subseteq> knows A (Notes A' X # evs)"
   172 by (simp add: subset_insertI)
   173 
   174 lemma knows_subset_knows_Gets: "knows A evs \<subseteq> knows A (Gets A' X # evs)"
   175 by (simp add: subset_insertI)
   176 
   177 text{*Agents know what they say*}
   178 lemma Says_imp_knows [rule_format]: "Says A B X \<in> set evs --> X \<in> knows A evs"
   179 apply (induct_tac "evs")
   180 apply (simp_all (no_asm_simp) split add: event.split)
   181 apply blast
   182 done
   183 
   184 text{*Agents know what they note*}
   185 lemma Notes_imp_knows [rule_format]: "Notes A X \<in> set evs --> X \<in> knows A evs"
   186 apply (induct_tac "evs")
   187 apply (simp_all (no_asm_simp) split add: event.split)
   188 apply blast
   189 done
   190 
   191 text{*Agents know what they receive*}
   192 lemma Gets_imp_knows_agents [rule_format]:
   193      "A \<noteq> Spy --> Gets A X \<in> set evs --> X \<in> knows A evs"
   194 apply (induct_tac "evs")
   195 apply (simp_all (no_asm_simp) split add: event.split)
   196 done
   197 
   198 
   199 text{*What agents DIFFERENT FROM Spy know 
   200   was either said, or noted, or got, or known initially*}
   201 lemma knows_imp_Says_Gets_Notes_initState [rule_format]:
   202      "[| X \<in> knows A evs; A \<noteq> Spy |] ==> EX B.  
   203   Says A B X \<in> set evs | Gets A X \<in> set evs | Notes A X \<in> set evs | X \<in> initState A"
   204 apply (erule rev_mp)
   205 apply (induct_tac "evs")
   206 apply (simp_all (no_asm_simp) split add: event.split)
   207 apply blast
   208 done
   209 
   210 text{*What the Spy knows -- for the time being --
   211   was either said or noted, or known initially*}
   212 lemma knows_Spy_imp_Says_Notes_initState [rule_format]:
   213      "[| X \<in> knows Spy evs |] ==> EX A B.  
   214   Says A B X \<in> set evs | Notes A X \<in> set evs | X \<in> initState Spy"
   215 apply (erule rev_mp)
   216 apply (induct_tac "evs")
   217 apply (simp_all (no_asm_simp) split add: event.split)
   218 apply blast
   219 done
   220 
   221 lemma parts_knows_Spy_subset_used: "parts (knows Spy evs) \<subseteq> used evs"
   222 apply (induct_tac "evs", force)  
   223 apply (simp add: parts_insert_knows_A knows_Cons add: event.split, blast) 
   224 done
   225 
   226 lemmas usedI = parts_knows_Spy_subset_used [THEN subsetD, intro]
   227 
   228 lemma initState_into_used: "X \<in> parts (initState B) ==> X \<in> used evs"
   229 apply (induct_tac "evs")
   230 apply (simp_all add: parts_insert_knows_A split add: event.split, blast)
   231 done
   232 
   233 lemma used_Says [simp]: "used (Says A B X # evs) = parts{X} \<union> used evs"
   234 by simp
   235 
   236 lemma used_Notes [simp]: "used (Notes A X # evs) = parts{X} \<union> used evs"
   237 by simp
   238 
   239 lemma used_Gets [simp]: "used (Gets A X # evs) = used evs"
   240 by simp
   241 
   242 lemma used_nil_subset: "used [] \<subseteq> used evs"
   243 apply simp
   244 apply (blast intro: initState_into_used)
   245 done
   246 
   247 text{*NOTE REMOVAL--laws above are cleaner, as they don't involve "case"*}
   248 declare knows_Cons [simp del]
   249         used_Nil [simp del] used_Cons [simp del]
   250 
   251 
   252 text{*For proving theorems of the form @{term "X \<notin> analz (knows Spy evs) --> P"}
   253   New events added by induction to "evs" are discarded.  Provided 
   254   this information isn't needed, the proof will be much shorter, since
   255   it will omit complicated reasoning about @{term analz}.*}
   256 
   257 lemmas analz_mono_contra =
   258        knows_Spy_subset_knows_Spy_Says [THEN analz_mono, THEN contra_subsetD]
   259        knows_Spy_subset_knows_Spy_Notes [THEN analz_mono, THEN contra_subsetD]
   260        knows_Spy_subset_knows_Spy_Gets [THEN analz_mono, THEN contra_subsetD]
   261 
   262 ML
   263 {*
   264 val analz_mono_contra_tac = 
   265   let val analz_impI = inst "P" "?Y \<notin> analz (knows Spy ?evs)" impI
   266   in
   267     rtac analz_impI THEN' 
   268     REPEAT1 o 
   269       (dresolve_tac (thms"analz_mono_contra"))
   270     THEN' mp_tac
   271   end
   272 *}
   273 
   274 
   275 lemma knows_subset_knows_Cons: "knows A evs \<subseteq> knows A (e # evs)"
   276 by (induct e, auto simp: knows_Cons)
   277 
   278 lemma initState_subset_knows: "initState A \<subseteq> knows A evs"
   279 apply (induct_tac evs, simp) 
   280 apply (blast intro: knows_subset_knows_Cons [THEN subsetD])
   281 done
   282 
   283 
   284 text{*For proving @{text new_keys_not_used}*}
   285 lemma keysFor_parts_insert:
   286      "[| K \<in> keysFor (parts (insert X G));  X \<in> synth (analz H) |] 
   287       ==> K \<in> keysFor (parts (G \<union> H)) | Key (invKey K) \<in> parts H"; 
   288 by (force 
   289     dest!: parts_insert_subset_Un [THEN keysFor_mono, THEN [2] rev_subsetD]
   290            analz_subset_parts [THEN keysFor_mono, THEN [2] rev_subsetD]
   291     intro: analz_subset_parts [THEN subsetD] parts_mono [THEN [2] rev_subsetD])
   292 
   293 method_setup analz_mono_contra = {*
   294     Method.no_args
   295       (Method.METHOD (fn facts => REPEAT_FIRST analz_mono_contra_tac)) *}
   296     "for proving theorems of the form X \<notin> analz (knows Spy evs) --> P"
   297 
   298 subsubsection{*Useful for case analysis on whether a hash is a spoof or not*}
   299 
   300 ML
   301 {*
   302 val knows_Cons     = thm "knows_Cons"
   303 val used_Nil       = thm "used_Nil"
   304 val used_Cons      = thm "used_Cons"
   305 
   306 val Notes_imp_used = thm "Notes_imp_used";
   307 val Says_imp_used = thm "Says_imp_used";
   308 val Says_imp_knows_Spy = thm "Says_imp_knows_Spy";
   309 val Notes_imp_knows_Spy = thm "Notes_imp_knows_Spy";
   310 val knows_Spy_partsEs = thms "knows_Spy_partsEs";
   311 val spies_partsEs = thms "spies_partsEs";
   312 val Says_imp_spies = thm "Says_imp_spies";
   313 val parts_insert_spies = thm "parts_insert_spies";
   314 val Says_imp_knows = thm "Says_imp_knows";
   315 val Notes_imp_knows = thm "Notes_imp_knows";
   316 val Gets_imp_knows_agents = thm "Gets_imp_knows_agents";
   317 val knows_imp_Says_Gets_Notes_initState = thm "knows_imp_Says_Gets_Notes_initState";
   318 val knows_Spy_imp_Says_Notes_initState = thm "knows_Spy_imp_Says_Notes_initState";
   319 val usedI = thm "usedI";
   320 val initState_into_used = thm "initState_into_used";
   321 val used_Says = thm "used_Says";
   322 val used_Notes = thm "used_Notes";
   323 val used_Gets = thm "used_Gets";
   324 val used_nil_subset = thm "used_nil_subset";
   325 val analz_mono_contra = thms "analz_mono_contra";
   326 val knows_subset_knows_Cons = thm "knows_subset_knows_Cons";
   327 val initState_subset_knows = thm "initState_subset_knows";
   328 val keysFor_parts_insert = thm "keysFor_parts_insert";
   329 
   330 
   331 val synth_analz_mono = thm "synth_analz_mono";
   332 
   333 val knows_Spy_subset_knows_Spy_Says = thm "knows_Spy_subset_knows_Spy_Says";
   334 val knows_Spy_subset_knows_Spy_Notes = thm "knows_Spy_subset_knows_Spy_Notes";
   335 val knows_Spy_subset_knows_Spy_Gets = thm "knows_Spy_subset_knows_Spy_Gets";
   336 
   337 
   338 val synth_analz_mono_contra_tac = 
   339   let val syan_impI = inst "P" "?Y \<notin> synth (analz (knows Spy ?evs))" impI
   340   in
   341     rtac syan_impI THEN' 
   342     REPEAT1 o 
   343       (dresolve_tac 
   344        [knows_Spy_subset_knows_Spy_Says RS synth_analz_mono RS contra_subsetD,
   345         knows_Spy_subset_knows_Spy_Notes RS synth_analz_mono RS contra_subsetD,
   346 	knows_Spy_subset_knows_Spy_Gets RS synth_analz_mono RS contra_subsetD])
   347     THEN'
   348     mp_tac
   349   end;
   350 *}
   351 
   352 method_setup synth_analz_mono_contra = {*
   353     Method.no_args
   354       (Method.METHOD (fn facts => REPEAT_FIRST synth_analz_mono_contra_tac)) *}
   355     "for proving theorems of the form X \<notin> synth (analz (knows Spy evs)) --> P"
   356 
   357 end