src/Pure/envir.ML
author haftmann
Fri Jun 19 21:08:07 2009 +0200 (2009-06-19)
changeset 31726 ffd2dc631d88
parent 30146 a77fc0209723
child 32018 3370cea95387
permissions -rw-r--r--
merged
     1 (*  Title:      Pure/envir.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3 
     4 Environments.  The type of a term variable / sort of a type variable is
     5 part of its name. The lookup function must apply type substitutions,
     6 since they may change the identity of a variable.
     7 *)
     8 
     9 signature ENVIR =
    10 sig
    11   type tenv
    12   datatype env = Envir of {asol: tenv, iTs: Type.tyenv, maxidx: int}
    13   val type_env: env -> Type.tyenv
    14   val insert_sorts: env -> sort list -> sort list
    15   exception SAME
    16   val genvars: string -> env * typ list -> env * term list
    17   val genvar: string -> env * typ -> env * term
    18   val lookup: env * (indexname * typ) -> term option
    19   val lookup': tenv * (indexname * typ) -> term option
    20   val update: ((indexname * typ) * term) * env -> env
    21   val empty: int -> env
    22   val is_empty: env -> bool
    23   val above: env -> int -> bool
    24   val vupdate: ((indexname * typ) * term) * env -> env
    25   val alist_of: env -> (indexname * (typ * term)) list
    26   val norm_term: env -> term -> term
    27   val norm_term_same: env -> term -> term
    28   val norm_type: Type.tyenv -> typ -> typ
    29   val norm_type_same: Type.tyenv -> typ -> typ
    30   val norm_types_same: Type.tyenv -> typ list -> typ list
    31   val beta_norm: term -> term
    32   val head_norm: env -> term -> term
    33   val eta_contract: term -> term
    34   val beta_eta_contract: term -> term
    35   val fastype: env -> typ list -> term -> typ
    36   val typ_subst_TVars: Type.tyenv -> typ -> typ
    37   val subst_TVars: Type.tyenv -> term -> term
    38   val subst_Vars: tenv -> term -> term
    39   val subst_vars: Type.tyenv * tenv -> term -> term
    40   val expand_atom: typ -> typ * term -> term
    41   val expand_term: (term -> (typ * term) option) -> term -> term
    42   val expand_term_frees: ((string * typ) * term) list -> term -> term
    43 end;
    44 
    45 structure Envir : ENVIR =
    46 struct
    47 
    48 (*updating can destroy environment in 2 ways!!
    49    (1) variables out of range   (2) circular assignments
    50 *)
    51 type tenv = (typ * term) Vartab.table
    52 
    53 datatype env = Envir of
    54     {maxidx: int,      (*maximum index of vars*)
    55      asol: tenv,       (*table of assignments to Vars*)
    56      iTs: Type.tyenv}  (*table of assignments to TVars*)
    57 
    58 fun type_env (Envir {iTs, ...}) = iTs;
    59 
    60 (*NB: type unification may invent new sorts*)
    61 val insert_sorts = Vartab.fold (fn (_, (_, T)) => Sorts.insert_typ T) o type_env;
    62 
    63 (*Generate a list of distinct variables.
    64   Increments index to make them distinct from ALL present variables. *)
    65 fun genvars name (Envir{maxidx, asol, iTs}, Ts) : env * term list =
    66   let fun genvs (_, [] : typ list) : term list = []
    67         | genvs (n, [T]) = [ Var((name, maxidx+1), T) ]
    68         | genvs (n, T::Ts) =
    69             Var((name ^ radixstring(26,"a",n), maxidx+1), T)
    70             :: genvs(n+1,Ts)
    71   in  (Envir{maxidx=maxidx+1, asol=asol, iTs=iTs}, genvs (0,Ts))  end;
    72 
    73 (*Generate a variable.*)
    74 fun genvar name (env,T) : env * term =
    75   let val (env',[v]) = genvars name (env,[T])
    76   in  (env',v)  end;
    77 
    78 fun var_clash ixn T T' = raise TYPE ("Variable " ^
    79   quote (Term.string_of_vname ixn) ^ " has two distinct types",
    80   [T', T], []);
    81 
    82 fun gen_lookup f asol (xname, T) =
    83   (case Vartab.lookup asol xname of
    84      NONE => NONE
    85    | SOME (U, t) => if f (T, U) then SOME t
    86        else var_clash xname T U);
    87 
    88 (* When dealing with environments produced by matching instead *)
    89 (* of unification, there is no need to chase assigned TVars.   *)
    90 (* In this case, we can simply ignore the type substitution    *)
    91 (* and use = instead of eq_type.                               *)
    92 
    93 fun lookup' (asol, p) = gen_lookup op = asol p;
    94 
    95 fun lookup2 (iTs, asol) p =
    96   if Vartab.is_empty iTs then lookup' (asol, p)
    97   else gen_lookup (Type.eq_type iTs) asol p;
    98 
    99 fun lookup (Envir {asol, iTs, ...}, p) = lookup2 (iTs, asol) p;
   100 
   101 fun update (((xname, T), t), Envir {maxidx, asol, iTs}) =
   102   Envir{maxidx=maxidx, asol=Vartab.update_new (xname, (T, t)) asol, iTs=iTs};
   103 
   104 (*The empty environment.  New variables will start with the given index+1.*)
   105 fun empty m = Envir{maxidx=m, asol=Vartab.empty, iTs=Vartab.empty};
   106 
   107 (*Test for empty environment*)
   108 fun is_empty (Envir {asol, iTs, ...}) = Vartab.is_empty asol andalso Vartab.is_empty iTs;
   109 
   110 (*Determine if the least index updated exceeds lim*)
   111 fun above (Envir {asol, iTs, ...}) lim =
   112   (case Vartab.min_key asol of SOME (_, i) => i > lim | NONE => true) andalso
   113   (case Vartab.min_key iTs of SOME (_, i) => i > lim | NONE => true);
   114 
   115 (*Update, checking Var-Var assignments: try to suppress higher indexes*)
   116 fun vupdate ((aU as (a, U), t), env as Envir {iTs, ...}) = case t of
   117       Var (nT as (name', T)) =>
   118         if a = name' then env     (*cycle!*)
   119         else if TermOrd.indexname_ord (a, name') = LESS then
   120            (case lookup (env, nT) of  (*if already assigned, chase*)
   121                 NONE => update ((nT, Var (a, T)), env)
   122               | SOME u => vupdate ((aU, u), env))
   123         else update ((aU, t), env)
   124     | _ => update ((aU, t), env);
   125 
   126 
   127 (*Convert environment to alist*)
   128 fun alist_of (Envir{asol,...}) = Vartab.dest asol;
   129 
   130 
   131 (*** Beta normal form for terms (not eta normal form).
   132      Chases variables in env;  Does not exploit sharing of variable bindings
   133      Does not check types, so could loop. ***)
   134 
   135 (*raised when norm has no effect on a term, to do sharing instead of copying*)
   136 exception SAME;
   137 
   138 fun norm_term1 same (asol,t) : term =
   139   let fun norm (Var wT) =
   140             (case lookup' (asol, wT) of
   141                 SOME u => (norm u handle SAME => u)
   142               | NONE   => raise SAME)
   143         | norm (Abs(a,T,body)) =  Abs(a, T, norm body)
   144         | norm (Abs(_,_,body) $ t) = normh(subst_bound (t, body))
   145         | norm (f $ t) =
   146             ((case norm f of
   147                Abs(_,_,body) => normh(subst_bound (t, body))
   148              | nf => nf $ (norm t handle SAME => t))
   149             handle SAME => f $ norm t)
   150         | norm _ =  raise SAME
   151       and normh t = norm t handle SAME => t
   152   in (if same then norm else normh) t end
   153 
   154 fun normT iTs (Type (a, Ts)) = Type (a, normTs iTs Ts)
   155   | normT iTs (TFree _) = raise SAME
   156   | normT iTs (TVar vS) = (case Type.lookup iTs vS of
   157           SOME U => normTh iTs U
   158         | NONE => raise SAME)
   159 and normTh iTs T = ((normT iTs T) handle SAME => T)
   160 and normTs iTs [] = raise SAME
   161   | normTs iTs (T :: Ts) =
   162       ((normT iTs T :: (normTs iTs Ts handle SAME => Ts))
   163        handle SAME => T :: normTs iTs Ts);
   164 
   165 fun norm_term2 same (asol, iTs, t) : term =
   166   let fun norm (Const (a, T)) = Const(a, normT iTs T)
   167         | norm (Free (a, T)) = Free(a, normT iTs T)
   168         | norm (Var (w, T)) =
   169             (case lookup2 (iTs, asol) (w, T) of
   170                 SOME u => normh u
   171               | NONE   => Var(w, normT iTs T))
   172         | norm (Abs (a, T, body)) =
   173                (Abs (a, normT iTs T, normh body) handle SAME => Abs (a, T, norm body))
   174         | norm (Abs(_, _, body) $ t) = normh (subst_bound (t, body))
   175         | norm (f $ t) =
   176             ((case norm f of
   177                Abs(_, _, body) => normh (subst_bound (t, body))
   178              | nf => nf $ normh t)
   179             handle SAME => f $ norm t)
   180         | norm _ =  raise SAME
   181       and normh t = (norm t) handle SAME => t
   182   in (if same then norm else normh) t end;
   183 
   184 fun gen_norm_term same (env as Envir{asol,iTs,...}) t : term =
   185   if Vartab.is_empty iTs then norm_term1 same (asol, t)
   186   else norm_term2 same (asol, iTs, t);
   187 
   188 val norm_term = gen_norm_term false;
   189 val norm_term_same = gen_norm_term true;
   190 
   191 fun beta_norm t = if Term.has_abs t then norm_term (empty 0) t else t;
   192 
   193 fun norm_type iTs = normTh iTs;
   194 fun norm_type_same iTs =
   195   if Vartab.is_empty iTs then raise SAME else normT iTs;
   196 
   197 fun norm_types_same iTs =
   198   if Vartab.is_empty iTs then raise SAME else normTs iTs;
   199 
   200 
   201 (*Put a term into head normal form for unification.*)
   202 
   203 fun head_norm env t =
   204   let
   205     fun hnorm (Var vT) = (case lookup (env, vT) of
   206           SOME u => head_norm env u
   207         | NONE => raise SAME)
   208       | hnorm (Abs (a, T, body)) =  Abs (a, T, hnorm body)
   209       | hnorm (Abs (_, _, body) $ t) =
   210           head_norm env (subst_bound (t, body))
   211       | hnorm (f $ t) = (case hnorm f of
   212           Abs (_, _, body) => head_norm env (subst_bound (t, body))
   213         | nf => nf $ t)
   214           | hnorm _ =  raise SAME
   215   in hnorm t handle SAME => t end;
   216 
   217 
   218 (*Eta-contract a term (fully)*)
   219 
   220 local
   221 
   222 fun decr lev (Bound i) = if i >= lev then Bound (i - 1) else raise SAME
   223   | decr lev (Abs (a, T, body)) = Abs (a, T, decr (lev + 1) body)
   224   | decr lev (t $ u) = (decr lev t $ decrh lev u handle SAME => t $ decr lev u)
   225   | decr _ _ = raise SAME
   226 and decrh lev t = (decr lev t handle SAME => t);
   227 
   228 fun eta (Abs (a, T, body)) =
   229     ((case eta body of
   230         body' as (f $ Bound 0) =>
   231           if loose_bvar1 (f, 0) then Abs (a, T, body')
   232           else decrh 0 f
   233      | body' => Abs (a, T, body')) handle SAME =>
   234         (case body of
   235           f $ Bound 0 =>
   236             if loose_bvar1 (f, 0) then raise SAME
   237             else decrh 0 f
   238         | _ => raise SAME))
   239   | eta (t $ u) = (eta t $ etah u handle SAME => t $ eta u)
   240   | eta _ = raise SAME
   241 and etah t = (eta t handle SAME => t);
   242 
   243 in
   244 
   245 fun eta_contract t =
   246   if Term.has_abs t then etah t else t;
   247 
   248 val beta_eta_contract = eta_contract o beta_norm;
   249 
   250 end;
   251 
   252 
   253 (*finds type of term without checking that combinations are consistent
   254   Ts holds types of bound variables*)
   255 fun fastype (Envir {iTs, ...}) =
   256 let val funerr = "fastype: expected function type";
   257     fun fast Ts (f $ u) =
   258         (case fast Ts f of
   259            Type ("fun", [_, T]) => T
   260          | TVar ixnS =>
   261                 (case Type.lookup iTs ixnS of
   262                    SOME (Type ("fun", [_, T])) => T
   263                  | _ => raise TERM (funerr, [f $ u]))
   264          | _ => raise TERM (funerr, [f $ u]))
   265       | fast Ts (Const (_, T)) = T
   266       | fast Ts (Free (_, T)) = T
   267       | fast Ts (Bound i) =
   268         (nth Ts i
   269          handle Subscript => raise TERM ("fastype: Bound", [Bound i]))
   270       | fast Ts (Var (_, T)) = T
   271       | fast Ts (Abs (_, T, u)) = T --> fast (T :: Ts) u
   272 in fast end;
   273 
   274 
   275 (*Substitute for type Vars in a type*)
   276 fun typ_subst_TVars iTs T = if Vartab.is_empty iTs then T else
   277   let fun subst(Type(a, Ts)) = Type(a, map subst Ts)
   278         | subst(T as TFree _) = T
   279         | subst(T as TVar ixnS) =
   280             (case Type.lookup iTs ixnS of NONE => T | SOME(U) => U)
   281   in subst T end;
   282 
   283 (*Substitute for type Vars in a term*)
   284 val subst_TVars = map_types o typ_subst_TVars;
   285 
   286 (*Substitute for Vars in a term *)
   287 fun subst_Vars itms t = if Vartab.is_empty itms then t else
   288   let fun subst (v as Var ixnT) = the_default v (lookup' (itms, ixnT))
   289         | subst (Abs (a, T, t)) = Abs (a, T, subst t)
   290         | subst (f $ t) = subst f $ subst t
   291         | subst t = t
   292   in subst t end;
   293 
   294 (*Substitute for type/term Vars in a term *)
   295 fun subst_vars (iTs, itms) =
   296   if Vartab.is_empty iTs then subst_Vars itms else
   297   let fun subst (Const (a, T)) = Const(a, typ_subst_TVars iTs T)
   298         | subst (Free (a, T)) = Free (a, typ_subst_TVars iTs T)
   299         | subst (Var (ixn, T)) = (case lookup' (itms, (ixn, T)) of
   300             NONE   => Var (ixn, typ_subst_TVars iTs T)
   301           | SOME t => t)
   302         | subst (b as Bound _) = b
   303         | subst (Abs (a, T, t)) = Abs(a, typ_subst_TVars iTs T, subst t)
   304         | subst (f $ t) = subst f $ subst t
   305   in subst end;
   306 
   307 
   308 (* expand defined atoms -- with local beta reduction *)
   309 
   310 fun expand_atom T (U, u) =
   311   subst_TVars (Type.raw_match (U, T) Vartab.empty) u
   312   handle Type.TYPE_MATCH => raise TYPE ("expand_atom: ill-typed replacement", [T, U], [u]);
   313 
   314 fun expand_term get =
   315   let
   316     fun expand tm =
   317       let
   318         val (head, args) = Term.strip_comb tm;
   319         val args' = map expand args;
   320         fun comb head' = Term.list_comb (head', args');
   321       in
   322         (case head of
   323           Abs (x, T, t) => comb (Abs (x, T, expand t))
   324         | _ =>
   325             (case get head of
   326               SOME def => Term.betapplys (expand_atom (Term.fastype_of head) def, args')
   327             | NONE => comb head)
   328         | _ => comb head)
   329       end;
   330   in expand end;
   331 
   332 fun expand_term_frees defs =
   333   let
   334     val eqs = map (fn ((x, U), u) => (x, (U, u))) defs;
   335     val get = fn Free (x, _) => AList.lookup (op =) eqs x | _ => NONE;
   336   in expand_term get end;
   337 
   338 end;