src/Pure/logic.ML
author haftmann
Fri Oct 21 14:49:49 2005 +0200 (2005-10-21 ago)
changeset 17952 00eccd84608f
parent 17120 4ddeef83bd66
child 18029 19f1ad18bece
permissions -rw-r--r--
abandoned rational number functions in favor of General/rat.ML
wenzelm@9460
     1
(*  Title:      Pure/logic.ML
clasohm@0
     2
    ID:         $Id$
wenzelm@9460
     3
    Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
clasohm@0
     4
    Copyright   Cambridge University 1992
clasohm@0
     5
wenzelm@9460
     6
Abstract syntax operations of the Pure meta-logic.
clasohm@0
     7
*)
clasohm@0
     8
wenzelm@9460
     9
signature LOGIC =
wenzelm@4345
    10
sig
nipkow@5041
    11
  val is_all            : term -> bool
wenzelm@9460
    12
  val mk_equals         : term * term -> term
wenzelm@9460
    13
  val dest_equals       : term -> term * term
nipkow@3963
    14
  val is_equals         : term -> bool
wenzelm@9460
    15
  val mk_implies        : term * term -> term
wenzelm@9460
    16
  val dest_implies      : term -> term * term
nipkow@5041
    17
  val is_implies        : term -> bool
wenzelm@9460
    18
  val list_implies      : term list * term -> term
wenzelm@9460
    19
  val strip_imp_prems   : term -> term list
wenzelm@9460
    20
  val strip_imp_concl   : term -> term
wenzelm@9460
    21
  val strip_prems       : int * term list * term -> term list * term
wenzelm@9460
    22
  val count_prems       : term * int -> int
wenzelm@16879
    23
  val nth_prem          : int * term -> term
wenzelm@12137
    24
  val mk_conjunction    : term * term -> term
wenzelm@12757
    25
  val mk_conjunction_list: term list -> term
berghofe@13659
    26
  val strip_horn        : term -> term list * term
wenzelm@9460
    27
  val mk_cond_defpair   : term list -> term * term -> string * term
wenzelm@9460
    28
  val mk_defpair        : term * term -> string * term
wenzelm@9460
    29
  val mk_type           : typ -> term
wenzelm@9460
    30
  val dest_type         : term -> typ
wenzelm@9460
    31
  val mk_inclass        : typ * class -> term
wenzelm@9460
    32
  val dest_inclass      : term -> typ * class
wenzelm@9460
    33
  val goal_const        : term
wenzelm@9460
    34
  val mk_goal           : term -> term
wenzelm@9460
    35
  val dest_goal         : term -> term
wenzelm@9460
    36
  val occs              : term * term -> bool
wenzelm@9460
    37
  val close_form        : term -> term
wenzelm@9460
    38
  val incr_indexes      : typ list * int -> term -> term
wenzelm@16879
    39
  val incr_tvar         : int -> typ -> typ
wenzelm@9460
    40
  val lift_fns          : term * int -> (term -> term) * (term -> term)
wenzelm@9460
    41
  val strip_assums_hyp  : term -> term list
wenzelm@9460
    42
  val strip_assums_concl: term -> term
wenzelm@9460
    43
  val strip_params      : term -> (string * typ) list
wenzelm@9667
    44
  val has_meta_prems    : term -> int -> bool
wenzelm@9460
    45
  val flatten_params    : int -> term -> term
wenzelm@9460
    46
  val auto_rename       : bool ref
wenzelm@9460
    47
  val set_rename_prefix : string -> unit
clasohm@0
    48
  val list_rename_params: string list * term -> term
paulson@15454
    49
  val assum_pairs       : int * term -> (term*term)list
wenzelm@9460
    50
  val varify            : term -> term
wenzelm@9460
    51
  val unvarify          : term -> term
berghofe@13799
    52
  val get_goal          : term -> int -> term
berghofe@14107
    53
  val goal_params       : term -> int -> term * term list
berghofe@13799
    54
  val prems_of_goal     : term -> int -> term list
berghofe@13799
    55
  val concl_of_goal     : term -> int -> term
wenzelm@4345
    56
end;
clasohm@0
    57
paulson@1500
    58
structure Logic : LOGIC =
clasohm@0
    59
struct
wenzelm@398
    60
wenzelm@4345
    61
clasohm@0
    62
(*** Abstract syntax operations on the meta-connectives ***)
clasohm@0
    63
nipkow@5041
    64
(** all **)
nipkow@5041
    65
nipkow@5041
    66
fun is_all (Const ("all", _) $ _) = true
nipkow@5041
    67
  | is_all _ = false;
nipkow@5041
    68
nipkow@5041
    69
clasohm@0
    70
(** equality **)
clasohm@0
    71
paulson@1835
    72
(*Make an equality.  DOES NOT CHECK TYPE OF u*)
lcp@64
    73
fun mk_equals(t,u) = equals(fastype_of t) $ t $ u;
clasohm@0
    74
clasohm@0
    75
fun dest_equals (Const("==",_) $ t $ u)  =  (t,u)
clasohm@0
    76
  | dest_equals t = raise TERM("dest_equals", [t]);
clasohm@0
    77
wenzelm@637
    78
fun is_equals (Const ("==", _) $ _ $ _) = true
wenzelm@637
    79
  | is_equals _ = false;
wenzelm@637
    80
wenzelm@637
    81
clasohm@0
    82
(** implies **)
clasohm@0
    83
clasohm@0
    84
fun mk_implies(A,B) = implies $ A $ B;
clasohm@0
    85
clasohm@0
    86
fun dest_implies (Const("==>",_) $ A $ B)  =  (A,B)
clasohm@0
    87
  | dest_implies A = raise TERM("dest_implies", [A]);
clasohm@0
    88
nipkow@5041
    89
fun is_implies (Const ("==>", _) $ _ $ _) = true
nipkow@5041
    90
  | is_implies _ = false;
nipkow@5041
    91
wenzelm@4822
    92
clasohm@0
    93
(** nested implications **)
clasohm@0
    94
clasohm@0
    95
(* [A1,...,An], B  goes to  A1==>...An==>B  *)
clasohm@0
    96
fun list_implies ([], B) = B : term
clasohm@0
    97
  | list_implies (A::AS, B) = implies $ A $ list_implies(AS,B);
clasohm@0
    98
clasohm@0
    99
(* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
clasohm@0
   100
fun strip_imp_prems (Const("==>", _) $ A $ B) = A :: strip_imp_prems B
clasohm@0
   101
  | strip_imp_prems _ = [];
clasohm@0
   102
clasohm@0
   103
(* A1==>...An==>B  goes to B, where B is not an implication *)
clasohm@0
   104
fun strip_imp_concl (Const("==>", _) $ A $ B) = strip_imp_concl B
clasohm@0
   105
  | strip_imp_concl A = A : term;
clasohm@0
   106
clasohm@0
   107
(*Strip and return premises: (i, [], A1==>...Ai==>B)
wenzelm@9460
   108
    goes to   ([Ai, A(i-1),...,A1] , B)         (REVERSED)
clasohm@0
   109
  if  i<0 or else i too big then raises  TERM*)
wenzelm@9460
   110
fun strip_prems (0, As, B) = (As, B)
wenzelm@9460
   111
  | strip_prems (i, As, Const("==>", _) $ A $ B) =
wenzelm@9460
   112
        strip_prems (i-1, A::As, B)
clasohm@0
   113
  | strip_prems (_, As, A) = raise TERM("strip_prems", A::As);
clasohm@0
   114
wenzelm@16130
   115
(*Count premises -- quicker than (length o strip_prems) *)
clasohm@0
   116
fun count_prems (Const("==>", _) $ A $ B, n) = count_prems (B,n+1)
clasohm@0
   117
  | count_prems (_,n) = n;
clasohm@0
   118
wenzelm@16130
   119
(*Select Ai from A1 ==>...Ai==>B*)
wenzelm@16130
   120
fun nth_prem (1, Const ("==>", _) $ A $ _) = A
wenzelm@16130
   121
  | nth_prem (i, Const ("==>", _) $ _ $ B) = nth_prem (i - 1, B)
wenzelm@16130
   122
  | nth_prem (_, A) = raise TERM ("nth_prem", [A]);
wenzelm@16130
   123
berghofe@13659
   124
(*strip a proof state (Horn clause):
berghofe@13659
   125
  B1 ==> ... Bn ==> C   goes to   ([B1, ..., Bn], C)    *)
berghofe@13659
   126
fun strip_horn A = (strip_imp_prems A, strip_imp_concl A);
berghofe@13659
   127
wenzelm@4822
   128
wenzelm@12137
   129
(** conjunction **)
wenzelm@12137
   130
wenzelm@12137
   131
fun mk_conjunction (t, u) =
wenzelm@12137
   132
  Term.list_all ([("C", propT)], mk_implies (list_implies ([t, u], Bound 0), Bound 0));
wenzelm@12137
   133
wenzelm@12757
   134
fun mk_conjunction_list [] = Term.all propT $ Abs ("dummy", propT, mk_implies (Bound 0, Bound 0))
wenzelm@12757
   135
  | mk_conjunction_list ts = foldr1 mk_conjunction ts;
wenzelm@12137
   136
wenzelm@12137
   137
wenzelm@4822
   138
(** definitions **)
wenzelm@4822
   139
wenzelm@4822
   140
fun mk_cond_defpair As (lhs, rhs) =
wenzelm@4822
   141
  (case Term.head_of lhs of
wenzelm@4822
   142
    Const (name, _) =>
wenzelm@4822
   143
      (Sign.base_name name ^ "_def", list_implies (As, mk_equals (lhs, rhs)))
wenzelm@4822
   144
  | _ => raise TERM ("Malformed definition: head of lhs not a constant", [lhs, rhs]));
wenzelm@4822
   145
wenzelm@4822
   146
fun mk_defpair lhs_rhs = mk_cond_defpair [] lhs_rhs;
wenzelm@4822
   147
wenzelm@4822
   148
wenzelm@398
   149
(** types as terms **)
wenzelm@398
   150
wenzelm@398
   151
fun mk_type ty = Const ("TYPE", itselfT ty);
wenzelm@398
   152
wenzelm@398
   153
fun dest_type (Const ("TYPE", Type ("itself", [ty]))) = ty
wenzelm@398
   154
  | dest_type t = raise TERM ("dest_type", [t]);
wenzelm@398
   155
wenzelm@4822
   156
wenzelm@447
   157
(** class constraints **)
wenzelm@398
   158
wenzelm@398
   159
fun mk_inclass (ty, c) =
wenzelm@398
   160
  Const (Sign.const_of_class c, itselfT ty --> propT) $ mk_type ty;
wenzelm@398
   161
wenzelm@398
   162
fun dest_inclass (t as Const (c_class, _) $ ty) =
wenzelm@398
   163
      ((dest_type ty, Sign.class_of_const c_class)
wenzelm@398
   164
        handle TERM _ => raise TERM ("dest_inclass", [t]))
wenzelm@398
   165
  | dest_inclass t = raise TERM ("dest_inclass", [t]);
wenzelm@398
   166
clasohm@0
   167
wenzelm@9460
   168
(** atomic goals **)
wenzelm@9460
   169
wenzelm@9460
   170
val goal_const = Const ("Goal", propT --> propT);
wenzelm@9460
   171
fun mk_goal t = goal_const $ t;
wenzelm@9460
   172
wenzelm@9460
   173
fun dest_goal (Const ("Goal", _) $ t) = t
wenzelm@9460
   174
  | dest_goal t = raise TERM ("dest_goal", [t]);
wenzelm@9460
   175
wenzelm@9460
   176
clasohm@0
   177
(*** Low-level term operations ***)
clasohm@0
   178
clasohm@0
   179
(*Does t occur in u?  Or is alpha-convertible to u?
clasohm@0
   180
  The term t must contain no loose bound variables*)
wenzelm@16846
   181
fun occs (t, u) = exists_subterm (fn s => t aconv s) u;
clasohm@0
   182
clasohm@0
   183
(*Close up a formula over all free variables by quantification*)
clasohm@0
   184
fun close_form A =
wenzelm@4443
   185
  list_all_free (sort_wrt fst (map dest_Free (term_frees A)), A);
clasohm@0
   186
clasohm@0
   187
clasohm@0
   188
(*** Specialized operations for resolution... ***)
clasohm@0
   189
wenzelm@16879
   190
local exception SAME in
wenzelm@16879
   191
wenzelm@16879
   192
fun incrT k =
wenzelm@16879
   193
  let
wenzelm@16879
   194
    fun incr (TVar ((a, i), S)) = TVar ((a, i + k), S)
wenzelm@16879
   195
      | incr (Type (a, Ts)) = Type (a, incrs Ts)
wenzelm@16879
   196
      | incr _ = raise SAME
wenzelm@16879
   197
    and incrs (T :: Ts) =
wenzelm@16879
   198
        (incr T :: (incrs Ts handle SAME => Ts)
wenzelm@16879
   199
          handle SAME => T :: incrs Ts)
wenzelm@16879
   200
      | incrs [] = raise SAME;
wenzelm@16879
   201
  in incr end;
wenzelm@16879
   202
clasohm@0
   203
(*For all variables in the term, increment indexnames and lift over the Us
clasohm@0
   204
    result is ?Gidx(B.(lev+n-1),...,B.lev) where lev is abstraction level *)
paulson@17120
   205
fun incr_indexes ([], 0) t = t
paulson@17120
   206
  | incr_indexes (Us, k) t =
wenzelm@16879
   207
  let
wenzelm@16879
   208
    val n = length Us;
wenzelm@16879
   209
    val incrT = if k = 0 then I else incrT k;
wenzelm@16879
   210
wenzelm@16879
   211
    fun incr lev (Var ((x, i), T)) =
wenzelm@16879
   212
          Unify.combound (Var ((x, i + k), Us ---> (incrT T handle SAME => T)), lev, n)
wenzelm@16879
   213
      | incr lev (Abs (x, T, body)) =
wenzelm@16879
   214
          (Abs (x, incrT T, incr (lev + 1) body handle SAME => body)
wenzelm@16879
   215
            handle SAME => Abs (x, T, incr (lev + 1) body))
wenzelm@16879
   216
      | incr lev (t $ u) =
wenzelm@16879
   217
          (incr lev t $ (incr lev u handle SAME => u)
wenzelm@16879
   218
            handle SAME => t $ incr lev u)
wenzelm@16879
   219
      | incr _ (Const (c, T)) = Const (c, incrT T)
wenzelm@16879
   220
      | incr _ (Free (x, T)) = Free (x, incrT T)
wenzelm@16879
   221
      | incr _ (t as Bound _) = t;
wenzelm@16879
   222
  in incr 0 t handle SAME => t end;
wenzelm@16879
   223
wenzelm@16879
   224
fun incr_tvar 0 T = T
wenzelm@16879
   225
  | incr_tvar k T = incrT k T handle SAME => T;
wenzelm@16879
   226
wenzelm@16879
   227
end;
wenzelm@16879
   228
clasohm@0
   229
clasohm@0
   230
(*Make lifting functions from subgoal and increment.
clasohm@0
   231
    lift_abs operates on tpairs (unification constraints)
clasohm@0
   232
    lift_all operates on propositions     *)
clasohm@0
   233
fun lift_fns (B,inc) =
clasohm@0
   234
  let fun lift_abs (Us, Const("==>", _) $ _ $ B) u = lift_abs (Us,B) u
wenzelm@9460
   235
        | lift_abs (Us, Const("all",_)$Abs(a,T,t)) u =
wenzelm@9460
   236
              Abs(a, T, lift_abs (T::Us, t) u)
wenzelm@9460
   237
        | lift_abs (Us, _) u = incr_indexes(rev Us, inc) u
clasohm@0
   238
      fun lift_all (Us, Const("==>", _) $ A $ B) u =
wenzelm@9460
   239
              implies $ A $ lift_all (Us,B) u
wenzelm@9460
   240
        | lift_all (Us, Const("all",_)$Abs(a,T,t)) u =
wenzelm@9460
   241
              all T $ Abs(a, T, lift_all (T::Us,t) u)
wenzelm@9460
   242
        | lift_all (Us, _) u = incr_indexes(rev Us, inc) u;
clasohm@0
   243
  in  (lift_abs([],B), lift_all([],B))  end;
clasohm@0
   244
clasohm@0
   245
(*Strips assumptions in goal, yielding list of hypotheses.   *)
clasohm@0
   246
fun strip_assums_hyp (Const("==>", _) $ H $ B) = H :: strip_assums_hyp B
clasohm@0
   247
  | strip_assums_hyp (Const("all",_)$Abs(a,T,t)) = strip_assums_hyp t
clasohm@0
   248
  | strip_assums_hyp B = [];
clasohm@0
   249
clasohm@0
   250
(*Strips assumptions in goal, yielding conclusion.   *)
clasohm@0
   251
fun strip_assums_concl (Const("==>", _) $ H $ B) = strip_assums_concl B
clasohm@0
   252
  | strip_assums_concl (Const("all",_)$Abs(a,T,t)) = strip_assums_concl t
clasohm@0
   253
  | strip_assums_concl B = B;
clasohm@0
   254
clasohm@0
   255
(*Make a list of all the parameters in a subgoal, even if nested*)
clasohm@0
   256
fun strip_params (Const("==>", _) $ H $ B) = strip_params B
clasohm@0
   257
  | strip_params (Const("all",_)$Abs(a,T,t)) = (a,T) :: strip_params t
clasohm@0
   258
  | strip_params B = [];
clasohm@0
   259
wenzelm@9667
   260
(*test for meta connectives in prems of a 'subgoal'*)
wenzelm@9667
   261
fun has_meta_prems prop i =
wenzelm@9667
   262
  let
wenzelm@9667
   263
    fun is_meta (Const ("==>", _) $ _ $ _) = true
wenzelm@10442
   264
      | is_meta (Const ("==", _) $ _ $ _) = true
wenzelm@9667
   265
      | is_meta (Const ("all", _) $ _) = true
wenzelm@9667
   266
      | is_meta _ = false;
wenzelm@9667
   267
  in
berghofe@13659
   268
    (case strip_prems (i, [], prop) of
wenzelm@9667
   269
      (B :: _, _) => exists is_meta (strip_assums_hyp B)
wenzelm@9667
   270
    | _ => false) handle TERM _ => false
wenzelm@9667
   271
  end;
wenzelm@9483
   272
clasohm@0
   273
(*Removes the parameters from a subgoal and renumber bvars in hypotheses,
wenzelm@9460
   274
    where j is the total number of parameters (precomputed)
clasohm@0
   275
  If n>0 then deletes assumption n. *)
wenzelm@9460
   276
fun remove_params j n A =
clasohm@0
   277
    if j=0 andalso n<=0 then A  (*nothing left to do...*)
clasohm@0
   278
    else case A of
wenzelm@9460
   279
        Const("==>", _) $ H $ B =>
wenzelm@9460
   280
          if n=1 then                           (remove_params j (n-1) B)
wenzelm@9460
   281
          else implies $ (incr_boundvars j H) $ (remove_params j (n-1) B)
clasohm@0
   282
      | Const("all",_)$Abs(a,T,t) => remove_params (j-1) n t
clasohm@0
   283
      | _ => if n>0 then raise TERM("remove_params", [A])
clasohm@0
   284
             else A;
clasohm@0
   285
clasohm@0
   286
(** Auto-renaming of parameters in subgoals **)
clasohm@0
   287
clasohm@0
   288
val auto_rename = ref false
clasohm@0
   289
and rename_prefix = ref "ka";
clasohm@0
   290
clasohm@0
   291
(*rename_prefix is not exported; it is set by this function.*)
clasohm@0
   292
fun set_rename_prefix a =
wenzelm@4693
   293
    if a<>"" andalso forall Symbol.is_letter (Symbol.explode a)
clasohm@0
   294
    then  (rename_prefix := a;  auto_rename := true)
clasohm@0
   295
    else  error"rename prefix must be nonempty and consist of letters";
clasohm@0
   296
clasohm@0
   297
(*Makes parameters in a goal have distinctive names (not guaranteed unique!)
clasohm@0
   298
  A name clash could cause the printer to rename bound vars;
clasohm@0
   299
    then res_inst_tac would not work properly.*)
clasohm@0
   300
fun rename_vars (a, []) = []
clasohm@0
   301
  | rename_vars (a, (_,T)::vars) =
wenzelm@12902
   302
        (a,T) :: rename_vars (Symbol.bump_string a, vars);
clasohm@0
   303
clasohm@0
   304
(*Move all parameters to the front of the subgoal, renaming them apart;
clasohm@0
   305
  if n>0 then deletes assumption n. *)
clasohm@0
   306
fun flatten_params n A =
clasohm@0
   307
    let val params = strip_params A;
wenzelm@9460
   308
        val vars = if !auto_rename
wenzelm@9460
   309
                   then rename_vars (!rename_prefix, params)
wenzelm@9460
   310
                   else ListPair.zip (variantlist(map #1 params,[]),
wenzelm@9460
   311
                                      map #2 params)
clasohm@0
   312
    in  list_all (vars, remove_params (length vars) n A)
clasohm@0
   313
    end;
clasohm@0
   314
clasohm@0
   315
(*Makes parameters in a goal have the names supplied by the list cs.*)
clasohm@0
   316
fun list_rename_params (cs, Const("==>", _) $ A $ B) =
clasohm@0
   317
      implies $ A $ list_rename_params (cs, B)
wenzelm@9460
   318
  | list_rename_params (c::cs, Const("all",_)$Abs(_,T,t)) =
clasohm@0
   319
      all T $ Abs(c, T, list_rename_params (cs, t))
clasohm@0
   320
  | list_rename_params (cs, B) = B;
clasohm@0
   321
paulson@15451
   322
(*** Treatmsent of "assume", "erule", etc. ***)
clasohm@0
   323
wenzelm@16879
   324
(*Strips assumptions in goal yielding
paulson@15451
   325
   HS = [Hn,...,H1],   params = [xm,...,x1], and B,
wenzelm@16879
   326
  where x1...xm are the parameters. This version (21.1.2005) REQUIRES
wenzelm@16879
   327
  the the parameters to be flattened, but it allows erule to work on
paulson@15451
   328
  assumptions of the form !!x. phi. Any !! after the outermost string
paulson@15451
   329
  will be regarded as belonging to the conclusion, and left untouched.
paulson@15454
   330
  Used ONLY by assum_pairs.
paulson@15454
   331
      Unless nasms<0, it can terminate the recursion early; that allows
paulson@15454
   332
  erule to work on assumptions of the form P==>Q.*)
paulson@15454
   333
fun strip_assums_imp (0, Hs, B) = (Hs, B)  (*recursion terminated by nasms*)
wenzelm@16879
   334
  | strip_assums_imp (nasms, Hs, Const("==>", _) $ H $ B) =
paulson@15454
   335
      strip_assums_imp (nasms-1, H::Hs, B)
paulson@15454
   336
  | strip_assums_imp (_, Hs, B) = (Hs, B); (*recursion terminated by B*)
paulson@15454
   337
clasohm@0
   338
paulson@15451
   339
(*Strips OUTER parameters only, unlike similar legacy versions.*)
paulson@15451
   340
fun strip_assums_all (params, Const("all",_)$Abs(a,T,t)) =
paulson@15451
   341
      strip_assums_all ((a,T)::params, t)
paulson@15451
   342
  | strip_assums_all (params, B) = (params, B);
clasohm@0
   343
clasohm@0
   344
(*Produces disagreement pairs, one for each assumption proof, in order.
clasohm@0
   345
  A is the first premise of the lifted rule, and thus has the form
paulson@15454
   346
    H1 ==> ... Hk ==> B   and the pairs are (H1,B),...,(Hk,B).
paulson@15454
   347
  nasms is the number of assumptions in the original subgoal, needed when B
paulson@15454
   348
    has the form B1 ==> B2: it stops B1 from being taken as an assumption. *)
paulson@15454
   349
fun assum_pairs(nasms,A) =
paulson@15451
   350
  let val (params, A') = strip_assums_all ([],A)
paulson@15454
   351
      val (Hs,B) = strip_assums_imp (nasms,[],A')
paulson@15451
   352
      fun abspar t = Unify.rlist_abs(params, t)
paulson@15451
   353
      val D = abspar B
paulson@15451
   354
      fun pairrev ([], pairs) = pairs
paulson@15451
   355
        | pairrev (H::Hs, pairs) = pairrev(Hs,  (abspar H, D) :: pairs)
paulson@15451
   356
  in  pairrev (Hs,[])
clasohm@0
   357
  end;
clasohm@0
   358
clasohm@0
   359
(*Converts Frees to Vars and TFrees to TVars so that axioms can be written
clasohm@0
   360
  without (?) everywhere*)
wenzelm@16862
   361
fun varify (Const(a, T)) = Const (a, Type.varifyT T)
wenzelm@16862
   362
  | varify (Free (a, T)) = Var ((a, 0), Type.varifyT T)
wenzelm@16862
   363
  | varify (Var (ixn, T)) = Var (ixn, Type.varifyT T)
wenzelm@16862
   364
  | varify (t as Bound _) = t
wenzelm@16862
   365
  | varify (Abs (a, T, body)) = Abs (a, Type.varifyT T, varify body)
wenzelm@16862
   366
  | varify (f $ t) = varify f $ varify t;
clasohm@0
   367
lcp@546
   368
(*Inverse of varify.  Converts axioms back to their original form.*)
wenzelm@16862
   369
fun unvarify (Const (a, T)) = Const (a, Type.unvarifyT T)
wenzelm@16862
   370
  | unvarify (Free (a, T)) = Free (a, Type.unvarifyT T)
wenzelm@16862
   371
  | unvarify (Var ((a, 0), T)) = Free (a, Type.unvarifyT T)
wenzelm@16862
   372
  | unvarify (Var (ixn, T)) = Var (ixn, Type.unvarifyT T)  (*non-0 index!*)
wenzelm@16862
   373
  | unvarify (t as Bound _) = t
wenzelm@16862
   374
  | unvarify (Abs (a, T, body)) = Abs (a, Type.unvarifyT T, unvarify body)
wenzelm@16862
   375
  | unvarify (f $ t) = unvarify f $ unvarify t;
lcp@546
   376
berghofe@13799
   377
wenzelm@16862
   378
(* goal states *)
wenzelm@16862
   379
wenzelm@16862
   380
fun get_goal st i = nth_prem (i, st)
wenzelm@16862
   381
  handle TERM _ => error "Goal number out of range";
berghofe@13799
   382
berghofe@13799
   383
(*reverses parameters for substitution*)
berghofe@13799
   384
fun goal_params st i =
berghofe@13799
   385
  let val gi = get_goal st i
berghofe@14137
   386
      val rfrees = map Free (rename_wrt_term gi (strip_params gi))
berghofe@13799
   387
  in (gi, rfrees) end;
berghofe@13799
   388
berghofe@13799
   389
fun concl_of_goal st i =
berghofe@13799
   390
  let val (gi, rfrees) = goal_params st i
berghofe@13799
   391
      val B = strip_assums_concl gi
berghofe@13799
   392
  in subst_bounds (rfrees, B) end;
berghofe@13799
   393
berghofe@13799
   394
fun prems_of_goal st i =
berghofe@13799
   395
  let val (gi, rfrees) = goal_params st i
berghofe@13799
   396
      val As = strip_assums_hyp gi
berghofe@13799
   397
  in map (fn A => subst_bounds (rfrees, A)) As end;
berghofe@13799
   398
clasohm@0
   399
end;