src/Pure/Isar/isar_cmd.ML
author wenzelm
Wed Oct 17 13:20:08 2012 +0200 (2012-10-17 ago)
changeset 49889 00ea087e83d8
parent 49866 619acbd72664
child 50737 f310d1735d93
permissions -rw-r--r--
more method position information, notably finished_pos after end of previous text;
     1 (*  Title:      Pure/Isar/isar_cmd.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Miscellaneous Isar commands.
     5 *)
     6 
     7 signature ISAR_CMD =
     8 sig
     9   val global_setup: Symbol_Pos.text * Position.T -> theory -> theory
    10   val local_setup: Symbol_Pos.text * Position.T -> Proof.context -> Proof.context
    11   val parse_ast_translation: bool * (Symbol_Pos.text * Position.T) -> theory -> theory
    12   val parse_translation: bool * (Symbol_Pos.text * Position.T) -> theory -> theory
    13   val print_translation: bool * (Symbol_Pos.text * Position.T) -> theory -> theory
    14   val typed_print_translation: bool * (Symbol_Pos.text * Position.T) -> theory -> theory
    15   val print_ast_translation: bool * (Symbol_Pos.text * Position.T) -> theory -> theory
    16   val translations: (xstring * string) Syntax.trrule list -> theory -> theory
    17   val no_translations: (xstring * string) Syntax.trrule list -> theory -> theory
    18   val oracle: bstring * Position.T -> Symbol_Pos.text * Position.T -> theory -> theory
    19   val add_axioms: (Attrib.binding * string) list -> theory -> theory
    20   val add_defs: (bool * bool) * ((binding * string) * Attrib.src list) list -> theory -> theory
    21   val declaration: {syntax: bool, pervasive: bool} ->
    22     Symbol_Pos.text * Position.T -> local_theory -> local_theory
    23   val simproc_setup: string * Position.T -> string list -> Symbol_Pos.text * Position.T ->
    24     string list -> local_theory -> local_theory
    25   val hide_class: bool -> xstring list -> theory -> theory
    26   val hide_type: bool -> xstring list -> theory -> theory
    27   val hide_const: bool -> xstring list -> theory -> theory
    28   val hide_fact: bool -> xstring list -> theory -> theory
    29   val have: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    30   val hence: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    31   val show: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    32   val thus: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    33   val qed: Method.text_range option -> Toplevel.transition -> Toplevel.transition
    34   val terminal_proof: Method.text_range * Method.text_range option ->
    35     Toplevel.transition -> Toplevel.transition
    36   val default_proof: Toplevel.transition -> Toplevel.transition
    37   val immediate_proof: Toplevel.transition -> Toplevel.transition
    38   val done_proof: Toplevel.transition -> Toplevel.transition
    39   val skip_proof: Toplevel.transition -> Toplevel.transition
    40   val ml_diag: bool -> Symbol_Pos.text * Position.T -> Toplevel.transition -> Toplevel.transition
    41   val diag_state: Proof.context -> Toplevel.state
    42   val diag_goal: Proof.context -> {context: Proof.context, facts: thm list, goal: thm}
    43   val display_drafts: string list -> Toplevel.transition -> Toplevel.transition
    44   val print_drafts: string list -> Toplevel.transition -> Toplevel.transition
    45   val print_context: Toplevel.transition -> Toplevel.transition
    46   val print_theory: bool -> Toplevel.transition -> Toplevel.transition
    47   val print_syntax: Toplevel.transition -> Toplevel.transition
    48   val print_abbrevs: Toplevel.transition -> Toplevel.transition
    49   val print_facts: Toplevel.transition -> Toplevel.transition
    50   val print_configs: Toplevel.transition -> Toplevel.transition
    51   val print_theorems: bool -> Toplevel.transition -> Toplevel.transition
    52   val print_locales: Toplevel.transition -> Toplevel.transition
    53   val print_locale: bool * (xstring * Position.T) -> Toplevel.transition -> Toplevel.transition
    54   val print_registrations: xstring * Position.T -> Toplevel.transition -> Toplevel.transition
    55   val print_dependencies: bool * Expression.expression -> Toplevel.transition
    56     -> Toplevel.transition
    57   val print_attributes: Toplevel.transition -> Toplevel.transition
    58   val print_simpset: Toplevel.transition -> Toplevel.transition
    59   val print_rules: Toplevel.transition -> Toplevel.transition
    60   val print_trans_rules: Toplevel.transition -> Toplevel.transition
    61   val print_methods: Toplevel.transition -> Toplevel.transition
    62   val print_antiquotations: Toplevel.transition -> Toplevel.transition
    63   val thy_deps: Toplevel.transition -> Toplevel.transition
    64   val locale_deps: Toplevel.transition -> Toplevel.transition
    65   val class_deps: Toplevel.transition -> Toplevel.transition
    66   val thm_deps: (Facts.ref * Attrib.src list) list -> Toplevel.transition -> Toplevel.transition
    67   val unused_thms: (string list * string list option) option ->
    68     Toplevel.transition -> Toplevel.transition
    69   val print_binds: Toplevel.transition -> Toplevel.transition
    70   val print_cases: Toplevel.transition -> Toplevel.transition
    71   val print_stmts: string list * (Facts.ref * Attrib.src list) list
    72     -> Toplevel.transition -> Toplevel.transition
    73   val print_thms: string list * (Facts.ref * Attrib.src list) list
    74     -> Toplevel.transition -> Toplevel.transition
    75   val print_prfs: bool -> string list * (Facts.ref * Attrib.src list) list option
    76     -> Toplevel.transition -> Toplevel.transition
    77   val print_prop: (string list * string) -> Toplevel.transition -> Toplevel.transition
    78   val print_term: (string list * string) -> Toplevel.transition -> Toplevel.transition
    79   val print_type: (string list * (string * string option)) ->
    80     Toplevel.transition -> Toplevel.transition
    81   val header_markup: Symbol_Pos.text * Position.T -> Toplevel.transition -> Toplevel.transition
    82   val local_theory_markup: (xstring * Position.T) option * (Symbol_Pos.text * Position.T) ->
    83     Toplevel.transition -> Toplevel.transition
    84   val proof_markup: Symbol_Pos.text * Position.T -> Toplevel.transition -> Toplevel.transition
    85 end;
    86 
    87 structure Isar_Cmd: ISAR_CMD =
    88 struct
    89 
    90 
    91 (** theory declarations **)
    92 
    93 (* generic setup *)
    94 
    95 fun global_setup (txt, pos) =
    96   ML_Lex.read pos txt
    97   |> ML_Context.expression pos "val setup: theory -> theory" "Context.map_theory setup"
    98   |> Context.theory_map;
    99 
   100 fun local_setup (txt, pos) =
   101   ML_Lex.read pos txt
   102   |> ML_Context.expression pos "val setup: local_theory -> local_theory" "Context.map_proof setup"
   103   |> Context.proof_map;
   104 
   105 
   106 (* translation functions *)
   107 
   108 local
   109 
   110 fun advancedT false = ""
   111   | advancedT true = "Proof.context -> ";
   112 
   113 fun advancedN false = ""
   114   | advancedN true = "advanced_";
   115 
   116 in
   117 
   118 fun parse_ast_translation (a, (txt, pos)) =
   119   ML_Lex.read pos txt
   120   |> ML_Context.expression pos
   121     ("val parse_ast_translation: (string * (" ^ advancedT a ^
   122       "Ast.ast list -> Ast.ast)) list")
   123     ("Context.map_theory (Sign.add_" ^ advancedN a ^ "trfuns (parse_ast_translation, [], [], []))")
   124   |> Context.theory_map;
   125 
   126 fun parse_translation (a, (txt, pos)) =
   127   ML_Lex.read pos txt
   128   |> ML_Context.expression pos
   129     ("val parse_translation: (string * (" ^ advancedT a ^
   130       "term list -> term)) list")
   131     ("Context.map_theory (Sign.add_" ^ advancedN a ^ "trfuns ([], parse_translation, [], []))")
   132   |> Context.theory_map;
   133 
   134 fun print_translation (a, (txt, pos)) =
   135   ML_Lex.read pos txt
   136   |> ML_Context.expression pos
   137     ("val print_translation: (string * (" ^ advancedT a ^
   138       "term list -> term)) list")
   139     ("Context.map_theory (Sign.add_" ^ advancedN a ^ "trfuns ([], [], print_translation, []))")
   140   |> Context.theory_map;
   141 
   142 fun print_ast_translation (a, (txt, pos)) =
   143   ML_Lex.read pos txt
   144   |> ML_Context.expression pos
   145     ("val print_ast_translation: (string * (" ^ advancedT a ^
   146       "Ast.ast list -> Ast.ast)) list")
   147     ("Context.map_theory (Sign.add_" ^ advancedN a ^ "trfuns ([], [], [], print_ast_translation))")
   148   |> Context.theory_map;
   149 
   150 fun typed_print_translation (a, (txt, pos)) =
   151   ML_Lex.read pos txt
   152   |> ML_Context.expression pos
   153     ("val typed_print_translation: (string * (" ^ advancedT a ^ "typ -> term list -> term)) list")
   154     ("Context.map_theory (Sign.add_" ^ advancedN a ^ "trfunsT typed_print_translation)")
   155   |> Context.theory_map;
   156 
   157 end;
   158 
   159 
   160 (* translation rules *)
   161 
   162 fun read_trrules thy raw_rules =
   163   let
   164     val ctxt = Proof_Context.init_global thy;
   165   in
   166     raw_rules |> map (Syntax.map_trrule (fn (r, s) =>
   167       Syntax_Phases.parse_ast_pattern ctxt (Proof_Context.intern_type ctxt r, s)))
   168   end;
   169 
   170 fun translations args thy = Sign.add_trrules (read_trrules thy args) thy;
   171 fun no_translations args thy = Sign.del_trrules (read_trrules thy args) thy;
   172 
   173 
   174 (* oracles *)
   175 
   176 fun oracle (name, pos) (body_txt, body_pos) =
   177   let
   178     val body = ML_Lex.read body_pos body_txt;
   179     val ants =
   180       ML_Lex.read Position.none
   181        ("local\n\
   182         \  val binding = " ^ ML_Syntax.make_binding (name, pos) ^ ";\n\
   183         \  val body = ") @ body @ ML_Lex.read Position.none (";\n\
   184         \in\n\
   185         \  val " ^ name ^ " = snd (Context.>>> (Context.map_theory_result (Thm.add_oracle (binding, body))));\n\
   186         \end;\n");
   187   in Context.theory_map (ML_Context.exec (fn () => ML_Context.eval false body_pos ants)) end;
   188 
   189 
   190 (* old-style axioms *)
   191 
   192 val add_axioms = fold (snd oo Specification.axiom_cmd);
   193 
   194 fun add_defs ((unchecked, overloaded), args) thy =
   195   thy |>
   196     (if unchecked then Global_Theory.add_defs_unchecked_cmd else Global_Theory.add_defs_cmd)
   197       overloaded
   198       (map (fn ((b, ax), srcs) => ((b, ax), map (Attrib.attribute_cmd_global thy) srcs)) args)
   199   |> snd;
   200 
   201 
   202 (* declarations *)
   203 
   204 fun declaration {syntax, pervasive} (txt, pos) =
   205   ML_Lex.read pos txt
   206   |> ML_Context.expression pos
   207     "val declaration: Morphism.declaration"
   208     ("Context.map_proof (Local_Theory.declaration {syntax = " ^ Bool.toString syntax ^ ", \
   209       \pervasive = " ^ Bool.toString pervasive ^ "} declaration)")
   210   |> Context.proof_map;
   211 
   212 
   213 (* simprocs *)
   214 
   215 fun simproc_setup name lhss (txt, pos) identifier =
   216   ML_Lex.read pos txt
   217   |> ML_Context.expression pos
   218     "val proc: Morphism.morphism -> Simplifier.simpset -> cterm -> thm option"
   219     ("Context.map_proof (Simplifier.def_simproc_cmd {name = " ^ ML_Syntax.make_binding name ^ ", \
   220       \lhss = " ^ ML_Syntax.print_strings lhss ^ ", proc = proc, \
   221       \identifier = Library.maps ML_Context.thms " ^ ML_Syntax.print_strings identifier ^ "})")
   222   |> Context.proof_map;
   223 
   224 
   225 (* hide names *)
   226 
   227 fun hide_names intern check hide fully xnames thy =
   228   let
   229     val names = map (intern thy) xnames;
   230     val bads = filter_out (check thy) names;
   231   in
   232     if null bads then fold (hide fully) names thy
   233     else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   234   end;
   235 
   236 val hide_class = hide_names Sign.intern_class (can o Sign.certify_class) Sign.hide_class;
   237 val hide_type = hide_names Sign.intern_type Sign.declared_tyname Sign.hide_type;
   238 val hide_const = hide_names Sign.intern_const Sign.declared_const Sign.hide_const;
   239 val hide_fact =
   240   hide_names Global_Theory.intern_fact Global_Theory.defined_fact Global_Theory.hide_fact;
   241 
   242 
   243 (* goals *)
   244 
   245 fun goal opt_chain goal stmt int =
   246   opt_chain #> goal NONE (K I) stmt int;
   247 
   248 val have = goal I Proof.have_cmd;
   249 val hence = goal Proof.chain Proof.have_cmd;
   250 val show = goal I Proof.show_cmd;
   251 val thus = goal Proof.chain Proof.show_cmd;
   252 
   253 
   254 (* local endings *)
   255 
   256 fun local_qed m = Toplevel.proof (Proof.local_qed (m, true));
   257 val local_terminal_proof = Toplevel.proof' o Proof.local_future_terminal_proof;
   258 val local_default_proof = Toplevel.proof Proof.local_default_proof;
   259 val local_immediate_proof = Toplevel.proof Proof.local_immediate_proof;
   260 val local_done_proof = Toplevel.proof Proof.local_done_proof;
   261 val local_skip_proof = Toplevel.proof' Proof.local_skip_proof;
   262 
   263 val skip_local_qed = Toplevel.skip_proof (fn i => if i > 1 then i - 1 else raise Toplevel.UNDEF);
   264 
   265 
   266 (* global endings *)
   267 
   268 fun global_qed m = Toplevel.end_proof (K (Proof.global_qed (m, true)));
   269 val global_terminal_proof = Toplevel.end_proof o Proof.global_future_terminal_proof;
   270 val global_default_proof = Toplevel.end_proof (K Proof.global_default_proof);
   271 val global_immediate_proof = Toplevel.end_proof (K Proof.global_immediate_proof);
   272 val global_skip_proof = Toplevel.end_proof Proof.global_skip_proof;
   273 val global_done_proof = Toplevel.end_proof (K Proof.global_done_proof);
   274 
   275 val skip_global_qed = Toplevel.skip_proof_to_theory (fn n => n = 1);
   276 
   277 
   278 (* common endings *)
   279 
   280 fun qed m = local_qed m o global_qed m o skip_local_qed o skip_global_qed;
   281 fun terminal_proof m = local_terminal_proof m o global_terminal_proof m;
   282 val default_proof = local_default_proof o global_default_proof;
   283 val immediate_proof = local_immediate_proof o global_immediate_proof;
   284 val done_proof = local_done_proof o global_done_proof;
   285 val skip_proof = local_skip_proof o global_skip_proof;
   286 
   287 
   288 (* diagnostic ML evaluation *)
   289 
   290 structure Diag_State = Proof_Data
   291 (
   292   type T = Toplevel.state;
   293   fun init _ = Toplevel.toplevel;
   294 );
   295 
   296 fun ml_diag verbose (txt, pos) = Toplevel.keep (fn state =>
   297   let val opt_ctxt =
   298     try Toplevel.generic_theory_of state
   299     |> Option.map (Context.proof_of #> Diag_State.put state)
   300   in ML_Context.eval_text_in opt_ctxt verbose pos txt end);
   301 
   302 val diag_state = Diag_State.get;
   303 
   304 fun diag_goal ctxt =
   305   Proof.goal (Toplevel.proof_of (diag_state ctxt))
   306     handle Toplevel.UNDEF => error "No goal present";
   307 
   308 val _ =
   309   Context.>> (Context.map_theory
   310    (ML_Antiquote.value (Binding.qualify true "Isar" (Binding.name "state"))
   311       (Scan.succeed "Isar_Cmd.diag_state ML_context") #>
   312     ML_Antiquote.value (Binding.qualify true "Isar" (Binding.name "goal"))
   313       (Scan.succeed "Isar_Cmd.diag_goal ML_context")));
   314 
   315 
   316 (* present draft files *)
   317 
   318 fun display_drafts names = Toplevel.imperative (fn () =>
   319   let
   320     val paths = map Path.explode names;
   321     val outfile = File.shell_path (Present.drafts (getenv "ISABELLE_DOC_FORMAT") paths);
   322   in Isabelle_System.isabelle_tool "display" ("-c " ^ outfile ^ " &"); () end);
   323 
   324 fun print_drafts names = Toplevel.imperative (fn () =>
   325   let
   326     val paths = map Path.explode names;
   327     val outfile = File.shell_path (Present.drafts "ps" paths);
   328   in Isabelle_System.isabelle_tool "print" ("-c " ^ outfile); () end);
   329 
   330 
   331 (* print parts of theory and proof context *)
   332 
   333 val print_context = Toplevel.keep Toplevel.print_state_context;
   334 
   335 fun print_theory verbose = Toplevel.unknown_theory o
   336   Toplevel.keep (Pretty.writeln o Proof_Display.pretty_full_theory verbose o Toplevel.theory_of);
   337 
   338 val print_syntax = Toplevel.unknown_context o
   339   Toplevel.keep (Proof_Context.print_syntax o Toplevel.context_of);
   340 
   341 val print_abbrevs = Toplevel.unknown_context o
   342   Toplevel.keep (Proof_Context.print_abbrevs o Toplevel.context_of);
   343 
   344 val print_facts = Toplevel.unknown_context o
   345   Toplevel.keep (Proof_Context.print_lthms o Toplevel.context_of);
   346 
   347 val print_configs = Toplevel.unknown_context o
   348   Toplevel.keep (Attrib.print_configs o Toplevel.context_of);
   349 
   350 val print_theorems_proof =
   351   Toplevel.keep (Proof_Context.print_lthms o Proof.context_of o Toplevel.proof_of);
   352 
   353 fun print_theorems_theory verbose = Toplevel.keep (fn state =>
   354   Toplevel.theory_of state |>
   355   (case Toplevel.previous_context_of state of
   356     SOME prev => Proof_Display.print_theorems_diff verbose (Proof_Context.theory_of prev)
   357   | NONE => Proof_Display.print_theorems verbose));
   358 
   359 fun print_theorems verbose =
   360   Toplevel.unknown_context o print_theorems_theory verbose o print_theorems_proof;
   361 
   362 val print_locales = Toplevel.unknown_theory o
   363   Toplevel.keep (Locale.print_locales o Toplevel.theory_of);
   364 
   365 fun print_locale (verbose, name) = Toplevel.unknown_theory o
   366   Toplevel.keep (fn state => Locale.print_locale (Toplevel.theory_of state) verbose name);
   367 
   368 fun print_registrations name = Toplevel.unknown_context o
   369   Toplevel.keep (fn state =>
   370     Locale.print_registrations (Toplevel.context_of state) name);
   371 
   372 fun print_dependencies (clean, expression) = Toplevel.unknown_context o
   373   Toplevel.keep (fn state =>
   374     Expression.print_dependencies (Toplevel.context_of state) clean expression);
   375 
   376 val print_attributes = Toplevel.unknown_theory o
   377   Toplevel.keep (Attrib.print_attributes o Toplevel.theory_of);
   378 
   379 val print_simpset = Toplevel.unknown_context o
   380   Toplevel.keep (fn state =>
   381     let val ctxt = Toplevel.context_of state
   382     in Pretty.writeln (Simplifier.pretty_ss ctxt (simpset_of ctxt)) end);
   383 
   384 val print_rules = Toplevel.unknown_context o
   385   Toplevel.keep (Context_Rules.print_rules o Toplevel.context_of);
   386 
   387 val print_trans_rules = Toplevel.unknown_context o
   388   Toplevel.keep (Calculation.print_rules o Toplevel.context_of);
   389 
   390 val print_methods = Toplevel.unknown_theory o
   391   Toplevel.keep (Method.print_methods o Toplevel.theory_of);
   392 
   393 val print_antiquotations =
   394   Toplevel.keep (Thy_Output.print_antiquotations o Toplevel.context_of);
   395 
   396 val thy_deps = Toplevel.unknown_theory o Toplevel.keep (fn state =>
   397   let
   398     val thy = Toplevel.theory_of state;
   399     val thy_session = Present.session_name thy;
   400 
   401     val gr = rev (Theory.nodes_of thy) |> map (fn node =>
   402       let
   403         val name = Context.theory_name node;
   404         val parents = map Context.theory_name (Theory.parents_of node);
   405         val session = Present.session_name node;
   406         val unfold = (session = thy_session);
   407       in
   408        {name = name, ID = name, parents = parents, dir = session,
   409         unfold = unfold, path = "", content = []}
   410       end);
   411   in Graph_Display.display_graph gr end);
   412 
   413 val locale_deps = Toplevel.unknown_theory o Toplevel.keep (fn state =>
   414   let
   415     val thy = Toplevel.theory_of state;
   416     val gr = Locale.pretty_locale_deps thy |> map (fn {name, parents, body} =>
   417      {name = Locale.extern thy name, ID = name, parents = parents,
   418       dir = "", unfold = true, path = "", content = [body]});
   419   in Graph_Display.display_graph gr end);
   420 
   421 val class_deps = Toplevel.unknown_theory o Toplevel.keep (fn state =>
   422   let
   423     val ctxt = Toplevel.context_of state;
   424     val {classes = (space, algebra), ...} = Type.rep_tsig (Proof_Context.tsig_of ctxt);
   425     val classes = Sorts.classes_of algebra;
   426     fun entry (c, (i, (_, cs))) =
   427       (i, {name = Name_Space.extern ctxt space c, ID = c, parents = Graph.Keys.dest cs,
   428             dir = "", unfold = true, path = "", content = []});
   429     val gr =
   430       Graph.fold (cons o entry) classes []
   431       |> sort (int_ord o pairself #1) |> map #2;
   432   in Graph_Display.display_graph gr end);
   433 
   434 fun thm_deps args = Toplevel.unknown_theory o Toplevel.keep (fn state =>
   435   Thm_Deps.thm_deps (Toplevel.theory_of state)
   436     (Attrib.eval_thms (Toplevel.context_of state) args));
   437 
   438 
   439 (* find unused theorems *)
   440 
   441 fun unused_thms opt_range = Toplevel.keep (fn state =>
   442   let
   443     val thy = Toplevel.theory_of state;
   444     val ctxt = Toplevel.context_of state;
   445     fun pretty_thm (a, th) = Proof_Context.pretty_fact ctxt (a, [th]);
   446     val get_theory = Context.get_theory thy;
   447   in
   448     Thm_Deps.unused_thms
   449       (case opt_range of
   450         NONE => (Theory.parents_of thy, [thy])
   451       | SOME (xs, NONE) => (map get_theory xs, [thy])
   452       | SOME (xs, SOME ys) => (map get_theory xs, map get_theory ys))
   453     |> map pretty_thm |> Pretty.chunks |> Pretty.writeln
   454   end);
   455 
   456 
   457 (* print proof context contents *)
   458 
   459 val print_binds = Toplevel.unknown_context o
   460   Toplevel.keep (Proof_Context.print_binds o Toplevel.context_of);
   461 
   462 val print_cases = Toplevel.unknown_context o
   463   Toplevel.keep (Proof_Context.print_cases o Toplevel.context_of);
   464 
   465 
   466 (* print theorems, terms, types etc. *)
   467 
   468 local
   469 
   470 fun string_of_stmts ctxt args =
   471   Attrib.eval_thms ctxt args
   472   |> map (Element.pretty_statement ctxt Thm.theoremK)
   473   |> Pretty.chunks2 |> Pretty.string_of;
   474 
   475 fun string_of_thms ctxt args =
   476   Pretty.string_of (Display.pretty_thms ctxt (Attrib.eval_thms ctxt args));
   477 
   478 fun string_of_prfs full state arg =
   479   Pretty.string_of
   480     (case arg of
   481       NONE =>
   482         let
   483           val {context = ctxt, goal = thm} = Proof.simple_goal (Toplevel.proof_of state);
   484           val thy = Proof_Context.theory_of ctxt;
   485           val prf = Thm.proof_of thm;
   486           val prop = Thm.full_prop_of thm;
   487           val prf' = Proofterm.rewrite_proof_notypes ([], []) prf;
   488         in
   489           Proof_Syntax.pretty_proof ctxt
   490             (if full then Reconstruct.reconstruct_proof thy prop prf' else prf')
   491         end
   492     | SOME srcs =>
   493         let val ctxt = Toplevel.context_of state
   494         in map (Proof_Syntax.pretty_proof_of ctxt full) (Attrib.eval_thms ctxt srcs) end
   495         |> Pretty.chunks);
   496 
   497 fun string_of_prop ctxt s =
   498   let
   499     val prop = Syntax.read_prop ctxt s;
   500     val ctxt' = Variable.auto_fixes prop ctxt;
   501   in Pretty.string_of (Pretty.quote (Syntax.pretty_term ctxt' prop)) end;
   502 
   503 fun string_of_term ctxt s =
   504   let
   505     val t = Syntax.read_term ctxt s;
   506     val T = Term.type_of t;
   507     val ctxt' = Variable.auto_fixes t ctxt;
   508   in
   509     Pretty.string_of
   510       (Pretty.block [Pretty.quote (Syntax.pretty_term ctxt' t), Pretty.fbrk,
   511         Pretty.str "::", Pretty.brk 1, Pretty.quote (Syntax.pretty_typ ctxt' T)])
   512   end;
   513 
   514 fun string_of_type ctxt (s, NONE) =
   515       let val T = Syntax.read_typ ctxt s
   516       in Pretty.string_of (Pretty.quote (Syntax.pretty_typ ctxt T)) end
   517   | string_of_type ctxt (s1, SOME s2) =
   518       let
   519         val ctxt' = Config.put show_sorts true ctxt;
   520         val raw_T = Syntax.parse_typ ctxt' s1;
   521         val S = Syntax.read_sort ctxt' s2;
   522         val T =
   523           Syntax.check_term ctxt'
   524             (Logic.mk_type raw_T |> Type.constraint (Term.itselfT (Type_Infer.anyT S)))
   525           |> Logic.dest_type;
   526       in Pretty.string_of (Pretty.quote (Syntax.pretty_typ ctxt' T)) end;
   527 
   528 fun print_item string_of (modes, arg) = Toplevel.keep (fn state =>
   529   Print_Mode.with_modes modes (fn () => writeln (string_of state arg)) ());
   530 
   531 in
   532 
   533 val print_stmts = print_item (string_of_stmts o Toplevel.context_of);
   534 val print_thms = print_item (string_of_thms o Toplevel.context_of);
   535 val print_prfs = print_item o string_of_prfs;
   536 val print_prop = print_item (string_of_prop o Toplevel.context_of);
   537 val print_term = print_item (string_of_term o Toplevel.context_of);
   538 val print_type = print_item (string_of_type o Toplevel.context_of);
   539 
   540 end;
   541 
   542 
   543 (* markup commands *)
   544 
   545 fun header_markup txt = Toplevel.keep (fn state =>
   546   if Toplevel.is_toplevel state then Thy_Output.check_text txt state
   547   else raise Toplevel.UNDEF);
   548 
   549 fun local_theory_markup (loc, txt) = Toplevel.present_local_theory loc (Thy_Output.check_text txt);
   550 val proof_markup = Toplevel.present_proof o Thy_Output.check_text;
   551 
   552 end;