src/Pure/meta_simplifier.ML
author haftmann
Fri Oct 21 14:49:49 2005 +0200 (2005-10-21 ago)
changeset 17952 00eccd84608f
parent 17897 1733b4680fde
child 17966 34e420fa03ad
permissions -rw-r--r--
abandoned rational number functions in favor of General/rat.ML
     1 (*  Title:      Pure/meta_simplifier.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Stefan Berghofer
     4 
     5 Meta-level Simplification.
     6 *)
     7 
     8 infix 4
     9   addsimps delsimps addeqcongs deleqcongs addcongs delcongs addsimprocs delsimprocs
    10   setmksimps setmkcong setmksym setmkeqTrue settermless setsubgoaler
    11   setloop' setloop addloop addloop' delloop setSSolver addSSolver setSolver addSolver;
    12 
    13 signature BASIC_META_SIMPLIFIER =
    14 sig
    15   val debug_simp: bool ref
    16   val trace_simp: bool ref
    17   val simp_depth_limit: int ref
    18   val trace_simp_depth_limit: int ref
    19   type rrule
    20   val eq_rrule: rrule * rrule -> bool
    21   type cong
    22   type simpset
    23   type proc
    24   type solver
    25   val mk_solver': string -> (simpset -> int -> tactic) -> solver
    26   val mk_solver: string -> (thm list -> int -> tactic) -> solver
    27   val rep_ss: simpset ->
    28    {rules: rrule Net.net,
    29     prems: thm list,
    30     bounds: int * ((string * typ) * string) list,
    31     context: Context.proof option} *
    32    {congs: (string * cong) list * string list,
    33     procs: proc Net.net,
    34     mk_rews:
    35      {mk: thm -> thm list,
    36       mk_cong: thm -> thm,
    37       mk_sym: thm -> thm option,
    38       mk_eq_True: thm -> thm option},
    39     termless: term * term -> bool,
    40     subgoal_tac: simpset -> int -> tactic,
    41     loop_tacs: (string * (simpset -> int -> tactic)) list,
    42     solvers: solver list * solver list}
    43   val print_ss: simpset -> unit
    44   val empty_ss: simpset
    45   val merge_ss: simpset * simpset -> simpset
    46   type simproc
    47   val mk_simproc: string -> cterm list ->
    48     (theory -> simpset -> term -> thm option) -> simproc
    49   val add_prems: thm list -> simpset -> simpset
    50   val prems_of_ss: simpset -> thm list
    51   val addsimps: simpset * thm list -> simpset
    52   val delsimps: simpset * thm list -> simpset
    53   val addeqcongs: simpset * thm list -> simpset
    54   val deleqcongs: simpset * thm list -> simpset
    55   val addcongs: simpset * thm list -> simpset
    56   val delcongs: simpset * thm list -> simpset
    57   val addsimprocs: simpset * simproc list -> simpset
    58   val delsimprocs: simpset * simproc list -> simpset
    59   val setmksimps: simpset * (thm -> thm list) -> simpset
    60   val setmkcong: simpset * (thm -> thm) -> simpset
    61   val setmksym: simpset * (thm -> thm option) -> simpset
    62   val setmkeqTrue: simpset * (thm -> thm option) -> simpset
    63   val settermless: simpset * (term * term -> bool) -> simpset
    64   val setsubgoaler: simpset * (simpset -> int -> tactic) -> simpset
    65   val setloop': simpset * (simpset -> int -> tactic) -> simpset
    66   val setloop: simpset * (int -> tactic) -> simpset
    67   val addloop': simpset * (string * (simpset -> int -> tactic)) -> simpset
    68   val addloop: simpset * (string * (int -> tactic)) -> simpset
    69   val delloop: simpset * string -> simpset
    70   val setSSolver: simpset * solver -> simpset
    71   val addSSolver: simpset * solver -> simpset
    72   val setSolver: simpset * solver -> simpset
    73   val addSolver: simpset * solver -> simpset
    74   val generic_simp_tac: bool -> bool * bool * bool -> simpset -> int -> tactic
    75 end;
    76 
    77 signature META_SIMPLIFIER =
    78 sig
    79   include BASIC_META_SIMPLIFIER
    80   exception SIMPLIFIER of string * thm
    81   val clear_ss: simpset -> simpset
    82   exception SIMPROC_FAIL of string * exn
    83   val simproc_i: theory -> string -> term list
    84     -> (theory -> simpset -> term -> thm option) -> simproc
    85   val simproc: theory -> string -> string list
    86     -> (theory -> simpset -> term -> thm option) -> simproc
    87   val inherit_context: simpset -> simpset -> simpset
    88   val the_context: simpset -> Context.proof
    89   val context: Context.proof -> simpset -> simpset
    90   val theory_context: theory  -> simpset -> simpset
    91   val debug_bounds: bool ref
    92   val rewrite_cterm: bool * bool * bool ->
    93     (simpset -> thm -> thm option) -> simpset -> cterm -> thm
    94   val rewrite_aux: (simpset -> thm -> thm option) -> bool -> thm list -> cterm -> thm
    95   val simplify_aux: (simpset -> thm -> thm option) -> bool -> thm list -> thm -> thm
    96   val rewrite_term: theory -> thm list -> (term -> term option) list -> term -> term
    97   val rewrite_thm: bool * bool * bool ->
    98     (simpset -> thm -> thm option) -> simpset -> thm -> thm
    99   val rewrite_goals_rule_aux: (simpset -> thm -> thm option) -> thm list -> thm -> thm
   100   val rewrite_goal_rule: bool * bool * bool ->
   101     (simpset -> thm -> thm option) -> simpset -> int -> thm -> thm
   102   val asm_rewrite_goal_tac: bool * bool * bool ->
   103     (simpset -> tactic) -> simpset -> int -> tactic
   104   val simp_thm: bool * bool * bool -> simpset -> thm -> thm
   105   val simp_cterm: bool * bool * bool -> simpset -> cterm -> thm
   106 end;
   107 
   108 structure MetaSimplifier: META_SIMPLIFIER =
   109 struct
   110 
   111 
   112 (** datatype simpset **)
   113 
   114 (* rewrite rules *)
   115 
   116 type rrule = {thm: thm, name: string, lhs: term, elhs: cterm, fo: bool, perm: bool};
   117 
   118 (*thm: the rewrite rule;
   119   name: name of theorem from which rewrite rule was extracted;
   120   lhs: the left-hand side;
   121   elhs: the etac-contracted lhs;
   122   fo: use first-order matching;
   123   perm: the rewrite rule is permutative;
   124 
   125 Remarks:
   126   - elhs is used for matching,
   127     lhs only for preservation of bound variable names;
   128   - fo is set iff
   129     either elhs is first-order (no Var is applied),
   130       in which case fo-matching is complete,
   131     or elhs is not a pattern,
   132       in which case there is nothing better to do;*)
   133 
   134 fun eq_rrule ({thm = thm1, ...}: rrule, {thm = thm2, ...}: rrule) =
   135   Drule.eq_thm_prop (thm1, thm2);
   136 
   137 
   138 (* congruences *)
   139 
   140 type cong = {thm: thm, lhs: cterm};
   141 
   142 fun eq_cong ({thm = thm1, ...}: cong, {thm = thm2, ...}: cong) =
   143   Drule.eq_thm_prop (thm1, thm2);
   144 
   145 
   146 (* simplification sets, procedures, and solvers *)
   147 
   148 (*A simpset contains data required during conversion:
   149     rules: discrimination net of rewrite rules;
   150     prems: current premises;
   151     bounds: maximal index of bound variables already used
   152       (for generating new names when rewriting under lambda abstractions);
   153     congs: association list of congruence rules and
   154            a list of `weak' congruence constants.
   155            A congruence is `weak' if it avoids normalization of some argument.
   156     procs: discrimination net of simplification procedures
   157       (functions that prove rewrite rules on the fly);
   158     mk_rews:
   159       mk: turn simplification thms into rewrite rules;
   160       mk_cong: prepare congruence rules;
   161       mk_sym: turn == around;
   162       mk_eq_True: turn P into P == True;
   163     termless: relation for ordered rewriting;*)
   164 
   165 type mk_rews =
   166  {mk: thm -> thm list,
   167   mk_cong: thm -> thm,
   168   mk_sym: thm -> thm option,
   169   mk_eq_True: thm -> thm option};
   170 
   171 datatype simpset =
   172   Simpset of
   173    {rules: rrule Net.net,
   174     prems: thm list,
   175     bounds: int * ((string * typ) * string) list,
   176     context: Context.proof option} *
   177    {congs: (string * cong) list * string list,
   178     procs: proc Net.net,
   179     mk_rews: mk_rews,
   180     termless: term * term -> bool,
   181     subgoal_tac: simpset -> int -> tactic,
   182     loop_tacs: (string * (simpset -> int -> tactic)) list,
   183     solvers: solver list * solver list}
   184 and proc =
   185   Proc of
   186    {name: string,
   187     lhs: cterm,
   188     proc: theory -> simpset -> term -> thm option,
   189     id: stamp}
   190 and solver =
   191   Solver of
   192    {name: string,
   193     solver: simpset -> int -> tactic,
   194     id: stamp};
   195 
   196 
   197 fun rep_ss (Simpset args) = args;
   198 
   199 fun make_ss1 (rules, prems, bounds, context) =
   200   {rules = rules, prems = prems, bounds = bounds, context = context};
   201 
   202 fun map_ss1 f {rules, prems, bounds, context} =
   203   make_ss1 (f (rules, prems, bounds, context));
   204 
   205 fun make_ss2 (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =
   206   {congs = congs, procs = procs, mk_rews = mk_rews, termless = termless,
   207     subgoal_tac = subgoal_tac, loop_tacs = loop_tacs, solvers = solvers};
   208 
   209 fun map_ss2 f {congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers} =
   210   make_ss2 (f (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   211 
   212 fun make_simpset (args1, args2) = Simpset (make_ss1 args1, make_ss2 args2);
   213 
   214 fun map_simpset f (Simpset ({rules, prems, bounds, context},
   215     {congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers})) =
   216   make_simpset (f ((rules, prems, bounds, context),
   217     (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers)));
   218 
   219 fun map_simpset1 f (Simpset (r1, r2)) = Simpset (map_ss1 f r1, r2);
   220 fun map_simpset2 f (Simpset (r1, r2)) = Simpset (r1, map_ss2 f r2);
   221 
   222 fun prems_of_ss (Simpset ({prems, ...}, _)) = prems;
   223 
   224 
   225 fun eq_proc (Proc {id = id1, ...}, Proc {id = id2, ...}) = (id1 = id2);
   226 
   227 fun mk_solver' name solver = Solver {name = name, solver = solver, id = stamp ()};
   228 fun mk_solver name solver = mk_solver' name (solver o prems_of_ss);
   229 
   230 fun solver_name (Solver {name, ...}) = name;
   231 fun solver ths (Solver {solver = tacf, ...}) = tacf ths;
   232 fun eq_solver (Solver {id = id1, ...}, Solver {id = id2, ...}) = (id1 = id2);
   233 val merge_solvers = gen_merge_lists eq_solver;
   234 
   235 
   236 (* diagnostics *)
   237 
   238 exception SIMPLIFIER of string * thm;
   239 
   240 val debug_simp = ref false;
   241 val trace_simp = ref false;
   242 val simp_depth = ref 0;
   243 val simp_depth_limit = ref 100;
   244 val trace_simp_depth_limit = ref 100;
   245 
   246 local
   247 
   248 fun println a =
   249   if ! simp_depth > ! trace_simp_depth_limit then ()
   250   else tracing (enclose "[" "]" (string_of_int (! simp_depth)) ^ a);
   251 
   252 fun prnt warn a = if warn then warning a else println a;
   253 
   254 fun show_bounds (Simpset ({bounds = (_, bs), ...}, _)) t =
   255   let
   256     val used = Term.add_term_names (t, []);
   257     val xs = rev (Term.variantlist (rev (map #2 bs), used));
   258     fun subst (((b, T), _), x') = (Free (b, T), Syntax.mark_boundT (x', T));
   259   in Term.subst_atomic (ListPair.map subst (bs, xs)) t end;
   260 
   261 in
   262 
   263 fun print_term warn a ss thy t = prnt warn (a ^ "\n" ^
   264   Sign.string_of_term thy (if ! debug_simp then t else show_bounds ss t));
   265 
   266 fun debug warn a = if ! debug_simp then prnt warn a else ();
   267 fun trace warn a = if ! trace_simp then prnt warn a else ();
   268 
   269 fun debug_term warn a ss thy t = if ! debug_simp then print_term warn a ss thy t else ();
   270 fun trace_term warn a ss thy t = if ! trace_simp then print_term warn a ss thy t else ();
   271 
   272 fun trace_cterm warn a ss ct =
   273   if ! trace_simp then print_term warn a ss (Thm.theory_of_cterm ct) (Thm.term_of ct) else ();
   274 
   275 fun trace_thm a ss th =
   276   if ! trace_simp then print_term false a ss (Thm.theory_of_thm th) (Thm.full_prop_of th) else ();
   277 
   278 fun trace_named_thm a ss (th, name) =
   279   if ! trace_simp then
   280     print_term false (if name = "" then a else a ^ " " ^ quote name ^ ":") ss
   281       (Thm.theory_of_thm th) (Thm.full_prop_of th)
   282   else ();
   283 
   284 fun warn_thm a ss th = print_term true a ss (Thm.theory_of_thm th) (Thm.full_prop_of th);
   285 
   286 end;
   287 
   288 
   289 (* print simpsets *)
   290 
   291 fun print_ss ss =
   292   let
   293     val pretty_thms = map Display.pretty_thm;
   294 
   295     fun pretty_cong (name, th) =
   296       Pretty.block [Pretty.str (name ^ ":"), Pretty.brk 1, Display.pretty_thm th];
   297     fun pretty_proc (name, lhss) =
   298       Pretty.big_list (name ^ ":") (map Display.pretty_cterm lhss);
   299 
   300     val Simpset ({rules, ...}, {congs, procs, loop_tacs, solvers, ...}) = ss;
   301     val smps = map #thm (Net.entries rules);
   302     val cngs = map (fn (name, {thm, ...}) => (name, thm)) (#1 congs);
   303     val prcs = Net.entries procs |>
   304       map (fn Proc {name, lhs, id, ...} => ((name, lhs), id))
   305       |> partition_eq (eq_snd (op =))
   306       |> map (fn ps => (fst (fst (hd ps)), map (snd o fst) ps))
   307       |> Library.sort_wrt fst;
   308   in
   309     [Pretty.big_list "simplification rules:" (pretty_thms smps),
   310       Pretty.big_list "simplification procedures:" (map pretty_proc prcs),
   311       Pretty.big_list "congruences:" (map pretty_cong cngs),
   312       Pretty.strs ("loopers:" :: map (quote o #1) loop_tacs),
   313       Pretty.strs ("unsafe solvers:" :: map (quote o solver_name) (#1 solvers)),
   314       Pretty.strs ("safe solvers:" :: map (quote o solver_name) (#2 solvers))]
   315     |> Pretty.chunks |> Pretty.writeln
   316   end;
   317 
   318 
   319 (* empty simpsets *)
   320 
   321 fun init_ss mk_rews termless subgoal_tac solvers =
   322   make_simpset ((Net.empty, [], (0, []), NONE),
   323     (([], []), Net.empty, mk_rews, termless, subgoal_tac, [], solvers));
   324 
   325 val basic_mk_rews: mk_rews =
   326  {mk = fn th => if can Logic.dest_equals (Thm.concl_of th) then [th] else [],
   327   mk_cong = I,
   328   mk_sym = SOME o Drule.symmetric_fun,
   329   mk_eq_True = K NONE};
   330 
   331 val empty_ss = init_ss basic_mk_rews Term.termless (K (K no_tac)) ([], []);
   332 
   333 
   334 (* merge simpsets *)            (*NOTE: ignores some fields of 2nd simpset*)
   335 
   336 fun merge_ss (ss1, ss2) =
   337   let
   338     val Simpset ({rules = rules1, prems = prems1, bounds = bounds1, context = _},
   339      {congs = (congs1, weak1), procs = procs1, mk_rews, termless, subgoal_tac,
   340       loop_tacs = loop_tacs1, solvers = (unsafe_solvers1, solvers1)}) = ss1;
   341     val Simpset ({rules = rules2, prems = prems2, bounds = bounds2, context = _},
   342      {congs = (congs2, weak2), procs = procs2, mk_rews = _, termless = _, subgoal_tac = _,
   343       loop_tacs = loop_tacs2, solvers = (unsafe_solvers2, solvers2)}) = ss2;
   344 
   345     val rules' = Net.merge eq_rrule (rules1, rules2);
   346     val prems' = gen_merge_lists Drule.eq_thm_prop prems1 prems2;
   347     val bounds' = if #1 bounds1 < #1 bounds2 then bounds2 else bounds1;
   348     val congs' = gen_merge_lists (eq_cong o pairself #2) congs1 congs2;
   349     val weak' = merge_lists weak1 weak2;
   350     val procs' = Net.merge eq_proc (procs1, procs2);
   351     val loop_tacs' = merge_alists loop_tacs1 loop_tacs2;
   352     val unsafe_solvers' = merge_solvers unsafe_solvers1 unsafe_solvers2;
   353     val solvers' = merge_solvers solvers1 solvers2;
   354   in
   355     make_simpset ((rules', prems', bounds', NONE), ((congs', weak'), procs',
   356       mk_rews, termless, subgoal_tac, loop_tacs', (unsafe_solvers', solvers')))
   357   end;
   358 
   359 
   360 (* simprocs *)
   361 
   362 exception SIMPROC_FAIL of string * exn;
   363 
   364 datatype simproc = Simproc of proc list;
   365 
   366 fun mk_simproc name lhss proc =
   367   let val id = stamp () in
   368     Simproc (lhss |> map (fn lhs =>
   369       Proc {name = name, lhs = lhs, proc = proc, id = id}))
   370   end;
   371 
   372 fun simproc_i thy name = mk_simproc name o map (Thm.cterm_of thy o Logic.varify);
   373 fun simproc thy name = simproc_i thy name o map (Sign.read_term thy);
   374 
   375 
   376 
   377 (** simpset operations **)
   378 
   379 (* context *)
   380 
   381 fun eq_bound (x: string, (y, _)) = x = y;
   382 
   383 fun add_bound bound = map_simpset1 (fn (rules, prems, (count, bounds), context) =>
   384   (rules, prems, (count + 1, bound :: bounds), context));
   385 
   386 fun add_prems ths = map_simpset1 (fn (rules, prems, bounds, context) =>
   387   (rules, ths @ prems, bounds, context));
   388 
   389 fun inherit_context (Simpset ({bounds, context, ...}, _)) =
   390   map_simpset1 (fn (rules, prems, _, _) => (rules, prems, bounds, context));
   391 
   392 fun the_context (Simpset ({context = SOME ctxt, ...}, _)) = ctxt
   393   | the_context _ = raise Fail "Simplifier: no proof context in simpset";
   394 
   395 fun context ctxt =
   396   map_simpset1 (fn (rules, prems, bounds, _) => (rules, prems, bounds, SOME ctxt));
   397 
   398 val theory_context = context o Context.init_proof;
   399 
   400 fun fallback_context _ (ss as Simpset ({context = SOME _, ...}, _)) = ss
   401   | fallback_context thy ss =
   402      (warning "Simplifier: no proof context in simpset -- fallback to theory context!";
   403       theory_context thy ss);
   404 
   405 
   406 (* clear_ss *)
   407 
   408 fun clear_ss (ss as Simpset (_, {mk_rews, termless, subgoal_tac, solvers, ...})) =
   409   init_ss mk_rews termless subgoal_tac solvers
   410   |> inherit_context ss;
   411 
   412 
   413 (* addsimps *)
   414 
   415 fun mk_rrule2 {thm, name, lhs, elhs, perm} =
   416   let
   417     val fo = Pattern.first_order (term_of elhs) orelse not (Pattern.pattern (term_of elhs))
   418   in {thm = thm, name = name, lhs = lhs, elhs = elhs, fo = fo, perm = perm} end;
   419 
   420 fun insert_rrule quiet (ss, rrule as {thm, name, lhs, elhs, perm}) =
   421  (trace_named_thm "Adding rewrite rule" ss (thm, name);
   422   ss |> map_simpset1 (fn (rules, prems, bounds, context) =>
   423     let
   424       val rrule2 as {elhs, ...} = mk_rrule2 rrule;
   425       val rules' = Net.insert_term eq_rrule (term_of elhs, rrule2) rules;
   426     in (rules', prems, bounds, context) end)
   427   handle Net.INSERT =>
   428     (if quiet then () else warn_thm "Ignoring duplicate rewrite rule:" ss thm; ss));
   429 
   430 fun vperm (Var _, Var _) = true
   431   | vperm (Abs (_, _, s), Abs (_, _, t)) = vperm (s, t)
   432   | vperm (t1 $ t2, u1 $ u2) = vperm (t1, u1) andalso vperm (t2, u2)
   433   | vperm (t, u) = (t = u);
   434 
   435 fun var_perm (t, u) =
   436   vperm (t, u) andalso eq_set (term_varnames t, term_varnames u);
   437 
   438 (* FIXME: it seems that the conditions on extra variables are too liberal if
   439 prems are nonempty: does solving the prems really guarantee instantiation of
   440 all its Vars? Better: a dynamic check each time a rule is applied.
   441 *)
   442 fun rewrite_rule_extra_vars prems elhs erhs =
   443   not (term_varnames erhs subset fold add_term_varnames prems (term_varnames elhs))
   444   orelse
   445   not (term_tvars erhs subset (term_tvars elhs union List.concat (map term_tvars prems)));
   446 
   447 (*simple test for looping rewrite rules and stupid orientations*)
   448 fun reorient thy prems lhs rhs =
   449   rewrite_rule_extra_vars prems lhs rhs
   450     orelse
   451   is_Var (head_of lhs)
   452     orelse
   453 (* turns t = x around, which causes a headache if x is a local variable -
   454    usually it is very useful :-(
   455   is_Free rhs andalso not(is_Free lhs) andalso not(Logic.occs(rhs,lhs))
   456   andalso not(exists_subterm is_Var lhs)
   457     orelse
   458 *)
   459   exists (fn t => Logic.occs (lhs, t)) (rhs :: prems)
   460     orelse
   461   null prems andalso Pattern.matches thy (lhs, rhs)
   462     (*the condition "null prems" is necessary because conditional rewrites
   463       with extra variables in the conditions may terminate although
   464       the rhs is an instance of the lhs; example: ?m < ?n ==> f(?n) == f(?m)*)
   465     orelse
   466   is_Const lhs andalso not (is_Const rhs);
   467 
   468 fun decomp_simp thm =
   469   let
   470     val {thy, prop, ...} = Thm.rep_thm thm;
   471     val prems = Logic.strip_imp_prems prop;
   472     val concl = Drule.strip_imp_concl (Thm.cprop_of thm);
   473     val (lhs, rhs) = Drule.dest_equals concl handle TERM _ =>
   474       raise SIMPLIFIER ("Rewrite rule not a meta-equality", thm);
   475     val (_, elhs) = Drule.dest_equals (Thm.cprop_of (Thm.eta_conversion lhs));
   476     val elhs = if term_of elhs aconv term_of lhs then lhs else elhs;  (*share identical copies*)
   477     val erhs = Pattern.eta_contract (term_of rhs);
   478     val perm =
   479       var_perm (term_of elhs, erhs) andalso
   480       not (term_of elhs aconv erhs) andalso
   481       not (is_Var (term_of elhs));
   482   in (thy, prems, term_of lhs, elhs, term_of rhs, perm) end;
   483 
   484 fun decomp_simp' thm =
   485   let val (_, _, lhs, _, rhs, _) = decomp_simp thm in
   486     if Thm.nprems_of thm > 0 then raise SIMPLIFIER ("Bad conditional rewrite rule", thm)
   487     else (lhs, rhs)
   488   end;
   489 
   490 fun mk_eq_True (Simpset (_, {mk_rews = {mk_eq_True, ...}, ...})) (thm, name) =
   491   (case mk_eq_True thm of
   492     NONE => []
   493   | SOME eq_True =>
   494       let val (_, _, lhs, elhs, _, _) = decomp_simp eq_True
   495       in [{thm = eq_True, name = name, lhs = lhs, elhs = elhs, perm = false}] end);
   496 
   497 (*create the rewrite rule and possibly also the eq_True variant,
   498   in case there are extra vars on the rhs*)
   499 fun rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm2) =
   500   let val rrule = {thm = thm, name = name, lhs = lhs, elhs = elhs, perm = false} in
   501     if term_varnames rhs subset term_varnames lhs andalso
   502       term_tvars rhs subset term_tvars lhs then [rrule]
   503     else mk_eq_True ss (thm2, name) @ [rrule]
   504   end;
   505 
   506 fun mk_rrule ss (thm, name) =
   507   let val (_, prems, lhs, elhs, rhs, perm) = decomp_simp thm in
   508     if perm then [{thm = thm, name = name, lhs = lhs, elhs = elhs, perm = true}]
   509     else
   510       (*weak test for loops*)
   511       if rewrite_rule_extra_vars prems lhs rhs orelse is_Var (term_of elhs)
   512       then mk_eq_True ss (thm, name)
   513       else rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm)
   514   end;
   515 
   516 fun orient_rrule ss (thm, name) =
   517   let val (thy, prems, lhs, elhs, rhs, perm) = decomp_simp thm in
   518     if perm then [{thm = thm, name = name, lhs = lhs, elhs = elhs, perm = true}]
   519     else if reorient thy prems lhs rhs then
   520       if reorient thy prems rhs lhs
   521       then mk_eq_True ss (thm, name)
   522       else
   523         let val Simpset (_, {mk_rews = {mk_sym, ...}, ...}) = ss in
   524           (case mk_sym thm of
   525             NONE => []
   526           | SOME thm' =>
   527               let val (_, _, lhs', elhs', rhs', _) = decomp_simp thm'
   528               in rrule_eq_True (thm', name, lhs', elhs', rhs', ss, thm) end)
   529         end
   530     else rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm)
   531   end;
   532 
   533 fun extract_rews (Simpset (_, {mk_rews = {mk, ...}, ...}), thms) =
   534   List.concat (map (fn thm => map (rpair (Thm.name_of_thm thm)) (mk thm)) thms);
   535 
   536 fun orient_comb_simps comb mk_rrule (ss, thms) =
   537   let
   538     val rews = extract_rews (ss, thms);
   539     val rrules = List.concat (map mk_rrule rews);
   540   in Library.foldl comb (ss, rrules) end;
   541 
   542 fun extract_safe_rrules (ss, thm) =
   543   List.concat (map (orient_rrule ss) (extract_rews (ss, [thm])));
   544 
   545 (*add rewrite rules explicitly; do not reorient!*)
   546 fun ss addsimps thms =
   547   orient_comb_simps (insert_rrule false) (mk_rrule ss) (ss, thms);
   548 
   549 
   550 (* delsimps *)
   551 
   552 fun del_rrule (ss, rrule as {thm, elhs, ...}) =
   553   ss |> map_simpset1 (fn (rules, prems, bounds, context) =>
   554     (Net.delete_term eq_rrule (term_of elhs, rrule) rules, prems, bounds, context))
   555   handle Net.DELETE => (warn_thm "Rewrite rule not in simpset:" ss thm; ss);
   556 
   557 fun ss delsimps thms =
   558   orient_comb_simps del_rrule (map mk_rrule2 o mk_rrule ss) (ss, thms);
   559 
   560 
   561 (* congs *)
   562 
   563 fun cong_name (Const (a, _)) = SOME a
   564   | cong_name (Free (a, _)) = SOME ("Free: " ^ a)
   565   | cong_name _ = NONE;
   566 
   567 local
   568 
   569 fun is_full_cong_prems [] [] = true
   570   | is_full_cong_prems [] _ = false
   571   | is_full_cong_prems (p :: prems) varpairs =
   572       (case Logic.strip_assums_concl p of
   573         Const ("==", _) $ lhs $ rhs =>
   574           let val (x, xs) = strip_comb lhs and (y, ys) = strip_comb rhs in
   575             is_Var x andalso forall is_Bound xs andalso
   576             null (findrep xs) andalso xs = ys andalso
   577             (x, y) mem varpairs andalso
   578             is_full_cong_prems prems (varpairs \ (x, y))
   579           end
   580       | _ => false);
   581 
   582 fun is_full_cong thm =
   583   let
   584     val prems = prems_of thm and concl = concl_of thm;
   585     val (lhs, rhs) = Logic.dest_equals concl;
   586     val (f, xs) = strip_comb lhs and (g, ys) = strip_comb rhs;
   587   in
   588     f = g andalso null (findrep (xs @ ys)) andalso length xs = length ys andalso
   589     is_full_cong_prems prems (xs ~~ ys)
   590   end;
   591 
   592 fun add_cong (ss, thm) = ss |>
   593   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   594     let
   595       val (lhs, _) = Drule.dest_equals (Drule.strip_imp_concl (Thm.cprop_of thm))
   596         handle TERM _ => raise SIMPLIFIER ("Congruence not a meta-equality", thm);
   597     (*val lhs = Pattern.eta_contract lhs;*)
   598       val a = valOf (cong_name (head_of (term_of lhs))) handle Option =>
   599         raise SIMPLIFIER ("Congruence must start with a constant or free variable", thm);
   600       val (alist, weak) = congs;
   601       val alist2 = overwrite_warn (alist, (a, {lhs = lhs, thm = thm}))
   602         ("Overwriting congruence rule for " ^ quote a);
   603       val weak2 = if is_full_cong thm then weak else a :: weak;
   604     in ((alist2, weak2), procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) end);
   605 
   606 fun del_cong (ss, thm) = ss |>
   607   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   608     let
   609       val (lhs, _) = Logic.dest_equals (Thm.concl_of thm) handle TERM _ =>
   610         raise SIMPLIFIER ("Congruence not a meta-equality", thm);
   611     (*val lhs = Pattern.eta_contract lhs;*)
   612       val a = valOf (cong_name (head_of lhs)) handle Option =>
   613         raise SIMPLIFIER ("Congruence must start with a constant", thm);
   614       val (alist, _) = congs;
   615       val alist2 = List.filter (fn (x, _) => x <> a) alist;
   616       val weak2 = alist2 |> List.mapPartial (fn (a, {thm, ...}: cong) =>
   617         if is_full_cong thm then NONE else SOME a);
   618     in ((alist2, weak2), procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) end);
   619 
   620 fun mk_cong (Simpset (_, {mk_rews = {mk_cong = f, ...}, ...})) = f;
   621 
   622 in
   623 
   624 val (op addeqcongs) = Library.foldl add_cong;
   625 val (op deleqcongs) = Library.foldl del_cong;
   626 
   627 fun ss addcongs congs = ss addeqcongs map (mk_cong ss) congs;
   628 fun ss delcongs congs = ss deleqcongs map (mk_cong ss) congs;
   629 
   630 end;
   631 
   632 
   633 (* simprocs *)
   634 
   635 local
   636 
   637 fun add_proc (proc as Proc {name, lhs, ...}) ss =
   638  (trace_cterm false ("Adding simplification procedure " ^ quote name ^ " for") ss lhs;
   639   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   640     (congs, Net.insert_term eq_proc (term_of lhs, proc) procs,
   641       mk_rews, termless, subgoal_tac, loop_tacs, solvers)) ss
   642   handle Net.INSERT =>
   643     (warning ("Ignoring duplicate simplification procedure " ^ quote name); ss));
   644 
   645 fun del_proc (proc as Proc {name, lhs, ...}) ss =
   646   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   647     (congs, Net.delete_term eq_proc (term_of lhs, proc) procs,
   648       mk_rews, termless, subgoal_tac, loop_tacs, solvers)) ss
   649   handle Net.DELETE =>
   650     (warning ("Simplification procedure " ^ quote name ^ " not in simpset"); ss);
   651 
   652 in
   653 
   654 fun ss addsimprocs ps = fold (fn Simproc procs => fold add_proc procs) ps ss;
   655 fun ss delsimprocs ps = fold (fn Simproc procs => fold del_proc procs) ps ss;
   656 
   657 end;
   658 
   659 
   660 (* mk_rews *)
   661 
   662 local
   663 
   664 fun map_mk_rews f = map_simpset2 (fn (congs, procs, {mk, mk_cong, mk_sym, mk_eq_True},
   665       termless, subgoal_tac, loop_tacs, solvers) =>
   666   let val (mk', mk_cong', mk_sym', mk_eq_True') = f (mk, mk_cong, mk_sym, mk_eq_True) in
   667     (congs, procs, {mk = mk', mk_cong = mk_cong', mk_sym = mk_sym', mk_eq_True = mk_eq_True'},
   668       termless, subgoal_tac, loop_tacs, solvers)
   669   end);
   670 
   671 in
   672 
   673 fun ss setmksimps mk = ss |> map_mk_rews (fn (_, mk_cong, mk_sym, mk_eq_True) =>
   674   (mk, mk_cong, mk_sym, mk_eq_True));
   675 
   676 fun ss setmkcong mk_cong = ss |> map_mk_rews (fn (mk, _, mk_sym, mk_eq_True) =>
   677   (mk, mk_cong, mk_sym, mk_eq_True));
   678 
   679 fun ss setmksym mk_sym = ss |> map_mk_rews (fn (mk, mk_cong, _, mk_eq_True) =>
   680   (mk, mk_cong, mk_sym, mk_eq_True));
   681 
   682 fun ss setmkeqTrue mk_eq_True = ss |> map_mk_rews (fn (mk, mk_cong, mk_sym, _) =>
   683   (mk, mk_cong, mk_sym, mk_eq_True));
   684 
   685 end;
   686 
   687 
   688 (* termless *)
   689 
   690 fun ss settermless termless = ss |>
   691   map_simpset2 (fn (congs, procs, mk_rews, _, subgoal_tac, loop_tacs, solvers) =>
   692    (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   693 
   694 
   695 (* tactics *)
   696 
   697 fun ss setsubgoaler subgoal_tac = ss |>
   698   map_simpset2 (fn (congs, procs, mk_rews, termless, _, loop_tacs, solvers) =>
   699    (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   700 
   701 fun ss setloop' tac = ss |>
   702   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, _, solvers) =>
   703    (congs, procs, mk_rews, termless, subgoal_tac, [("", tac)], solvers));
   704 
   705 fun ss setloop tac = ss setloop' (K tac);
   706 
   707 fun ss addloop' (name, tac) = ss |>
   708   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   709     (congs, procs, mk_rews, termless, subgoal_tac,
   710       overwrite_warn (loop_tacs, (name, tac)) ("Overwriting looper " ^ quote name),
   711       solvers));
   712 
   713 fun ss addloop (name, tac) = ss addloop' (name, K tac);
   714 
   715 fun ss delloop name = ss |>
   716   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   717     let val loop_tacs' = filter_out (equal name o fst) loop_tacs in
   718       if length loop_tacs <> length loop_tacs' then ()
   719       else warning ("No such looper in simpset: " ^ quote name);
   720       (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs', solvers)
   721     end);
   722 
   723 fun ss setSSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   724   subgoal_tac, loop_tacs, (unsafe_solvers, _)) =>
   725     (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, (unsafe_solvers, [solver])));
   726 
   727 fun ss addSSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   728   subgoal_tac, loop_tacs, (unsafe_solvers, solvers)) => (congs, procs, mk_rews, termless,
   729     subgoal_tac, loop_tacs, (unsafe_solvers, merge_solvers solvers [solver])));
   730 
   731 fun ss setSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   732   subgoal_tac, loop_tacs, (_, solvers)) => (congs, procs, mk_rews, termless,
   733     subgoal_tac, loop_tacs, ([solver], solvers)));
   734 
   735 fun ss addSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   736   subgoal_tac, loop_tacs, (unsafe_solvers, solvers)) => (congs, procs, mk_rews, termless,
   737     subgoal_tac, loop_tacs, (merge_solvers unsafe_solvers [solver], solvers)));
   738 
   739 fun set_solvers solvers = map_simpset2 (fn (congs, procs, mk_rews, termless,
   740   subgoal_tac, loop_tacs, _) => (congs, procs, mk_rews, termless,
   741   subgoal_tac, loop_tacs, (solvers, solvers)));
   742 
   743 
   744 
   745 (** rewriting **)
   746 
   747 (*
   748   Uses conversions, see:
   749     L C Paulson, A higher-order implementation of rewriting,
   750     Science of Computer Programming 3 (1983), pages 119-149.
   751 *)
   752 
   753 val dest_eq = Drule.dest_equals o Thm.cprop_of;
   754 val lhs_of = #1 o dest_eq;
   755 val rhs_of = #2 o dest_eq;
   756 
   757 fun check_conv msg ss thm thm' =
   758   let
   759     val thm'' = transitive thm (transitive
   760       (symmetric (Drule.beta_eta_conversion (lhs_of thm'))) thm')
   761   in if msg then trace_thm "SUCCEEDED" ss thm' else (); SOME thm'' end
   762   handle THM _ =>
   763     let val {thy, prop = _ $ _ $ prop0, ...} = Thm.rep_thm thm in
   764       trace_thm "Proved wrong thm (Check subgoaler?)" ss thm';
   765       trace_term false "Should have proved:" ss thy prop0;
   766       NONE
   767     end;
   768 
   769 
   770 (* mk_procrule *)
   771 
   772 fun mk_procrule ss thm =
   773   let val (_, prems, lhs, elhs, rhs, _) = decomp_simp thm in
   774     if rewrite_rule_extra_vars prems lhs rhs
   775     then (warn_thm "Extra vars on rhs:" ss thm; [])
   776     else [mk_rrule2 {thm = thm, name = "", lhs = lhs, elhs = elhs, perm = false}]
   777   end;
   778 
   779 
   780 (* rewritec: conversion to apply the meta simpset to a term *)
   781 
   782 (*Since the rewriting strategy is bottom-up, we avoid re-normalizing already
   783   normalized terms by carrying around the rhs of the rewrite rule just
   784   applied. This is called the `skeleton'. It is decomposed in parallel
   785   with the term. Once a Var is encountered, the corresponding term is
   786   already in normal form.
   787   skel0 is a dummy skeleton that is to enforce complete normalization.*)
   788 
   789 val skel0 = Bound 0;
   790 
   791 (*Use rhs as skeleton only if the lhs does not contain unnormalized bits.
   792   The latter may happen iff there are weak congruence rules for constants
   793   in the lhs.*)
   794 
   795 fun uncond_skel ((_, weak), (lhs, rhs)) =
   796   if null weak then rhs  (*optimization*)
   797   else if exists_Const (fn (c, _) => c mem weak) lhs then skel0
   798   else rhs;
   799 
   800 (*Behaves like unconditional rule if rhs does not contain vars not in the lhs.
   801   Otherwise those vars may become instantiated with unnormalized terms
   802   while the premises are solved.*)
   803 
   804 fun cond_skel (args as (congs, (lhs, rhs))) =
   805   if term_varnames rhs subset term_varnames lhs then uncond_skel args
   806   else skel0;
   807 
   808 (*
   809   Rewriting -- we try in order:
   810     (1) beta reduction
   811     (2) unconditional rewrite rules
   812     (3) conditional rewrite rules
   813     (4) simplification procedures
   814 
   815   IMPORTANT: rewrite rules must not introduce new Vars or TVars!
   816 *)
   817 
   818 fun rewritec (prover, thyt, maxt) ss t =
   819   let
   820     val Simpset ({rules, ...}, {congs, procs, termless, ...}) = ss;
   821     val eta_thm = Thm.eta_conversion t;
   822     val eta_t' = rhs_of eta_thm;
   823     val eta_t = term_of eta_t';
   824     fun rew {thm, name, lhs, elhs, fo, perm} =
   825       let
   826         val {thy, prop, maxidx, ...} = rep_thm thm;
   827         val (rthm, elhs') = if maxt = ~1 then (thm, elhs)
   828           else (Thm.incr_indexes (maxt+1) thm, Thm.cterm_incr_indexes (maxt+1) elhs);
   829         val insts = if fo then Thm.cterm_first_order_match (elhs', eta_t')
   830                           else Thm.cterm_match (elhs', eta_t');
   831         val thm' = Thm.instantiate insts (Thm.rename_boundvars lhs eta_t rthm);
   832         val prop' = Thm.prop_of thm';
   833         val unconditional = (Logic.count_prems (prop',0) = 0);
   834         val (lhs', rhs') = Logic.dest_equals (Logic.strip_imp_concl prop')
   835       in
   836         if perm andalso not (termless (rhs', lhs'))
   837         then (trace_named_thm "Cannot apply permutative rewrite rule" ss (thm, name);
   838               trace_thm "Term does not become smaller:" ss thm'; NONE)
   839         else (trace_named_thm "Applying instance of rewrite rule" ss (thm, name);
   840            if unconditional
   841            then
   842              (trace_thm "Rewriting:" ss thm';
   843               let val lr = Logic.dest_equals prop;
   844                   val SOME thm'' = check_conv false ss eta_thm thm'
   845               in SOME (thm'', uncond_skel (congs, lr)) end)
   846            else
   847              (trace_thm "Trying to rewrite:" ss thm';
   848               if !simp_depth > !simp_depth_limit
   849               then let val s = "simp_depth_limit exceeded - giving up"
   850                    in trace false s; warning s; NONE end
   851               else
   852               case prover ss thm' of
   853                 NONE => (trace_thm "FAILED" ss thm'; NONE)
   854               | SOME thm2 =>
   855                   (case check_conv true ss eta_thm thm2 of
   856                      NONE => NONE |
   857                      SOME thm2' =>
   858                        let val concl = Logic.strip_imp_concl prop
   859                            val lr = Logic.dest_equals concl
   860                        in SOME (thm2', cond_skel (congs, lr)) end)))
   861       end
   862 
   863     fun rews [] = NONE
   864       | rews (rrule :: rrules) =
   865           let val opt = rew rrule handle Pattern.MATCH => NONE
   866           in case opt of NONE => rews rrules | some => some end;
   867 
   868     fun sort_rrules rrs = let
   869       fun is_simple({thm, ...}:rrule) = case Thm.prop_of thm of
   870                                       Const("==",_) $ _ $ _ => true
   871                                       | _                   => false
   872       fun sort []        (re1,re2) = re1 @ re2
   873         | sort (rr::rrs) (re1,re2) = if is_simple rr
   874                                      then sort rrs (rr::re1,re2)
   875                                      else sort rrs (re1,rr::re2)
   876     in sort rrs ([],[]) end
   877 
   878     fun proc_rews [] = NONE
   879       | proc_rews (Proc {name, proc, lhs, ...} :: ps) =
   880           if Pattern.matches thyt (Thm.term_of lhs, Thm.term_of t) then
   881             (debug_term false ("Trying procedure " ^ quote name ^ " on:") ss thyt eta_t;
   882              case transform_failure (curry SIMPROC_FAIL name)
   883                  (fn () => proc thyt ss eta_t) () of
   884                NONE => (debug false "FAILED"; proc_rews ps)
   885              | SOME raw_thm =>
   886                  (trace_thm ("Procedure " ^ quote name ^ " produced rewrite rule:") ss raw_thm;
   887                   (case rews (mk_procrule ss raw_thm) of
   888                     NONE => (trace_cterm true ("IGNORED result of simproc " ^ quote name ^
   889                       " -- does not match") ss t; proc_rews ps)
   890                   | some => some)))
   891           else proc_rews ps;
   892   in case eta_t of
   893        Abs _ $ _ => SOME (transitive eta_thm
   894          (beta_conversion false eta_t'), skel0)
   895      | _ => (case rews (sort_rrules (Net.match_term rules eta_t)) of
   896                NONE => proc_rews (Net.match_term procs eta_t)
   897              | some => some)
   898   end;
   899 
   900 
   901 (* conversion to apply a congruence rule to a term *)
   902 
   903 fun congc prover ss maxt {thm=cong,lhs=lhs} t =
   904   let val rthm = Thm.incr_indexes (maxt+1) cong;
   905       val rlhs = fst (Drule.dest_equals (Drule.strip_imp_concl (cprop_of rthm)));
   906       val insts = Thm.cterm_match (rlhs, t)
   907       (* Pattern.match can raise Pattern.MATCH;
   908          is handled when congc is called *)
   909       val thm' = Thm.instantiate insts (Thm.rename_boundvars (term_of rlhs) (term_of t) rthm);
   910       val unit = trace_thm "Applying congruence rule:" ss thm';
   911       fun err (msg, thm) = (trace_thm msg ss thm; NONE)
   912   in case prover thm' of
   913        NONE => err ("Congruence proof failed.  Could not prove", thm')
   914      | SOME thm2 => (case check_conv true ss (Drule.beta_eta_conversion t) thm2 of
   915           NONE => err ("Congruence proof failed.  Should not have proved", thm2)
   916         | SOME thm2' =>
   917             if op aconv (pairself term_of (dest_equals (cprop_of thm2')))
   918             then NONE else SOME thm2')
   919   end;
   920 
   921 val (cA, (cB, cC)) =
   922   apsnd dest_equals (dest_implies (hd (cprems_of Drule.imp_cong)));
   923 
   924 fun transitive1 NONE NONE = NONE
   925   | transitive1 (SOME thm1) NONE = SOME thm1
   926   | transitive1 NONE (SOME thm2) = SOME thm2
   927   | transitive1 (SOME thm1) (SOME thm2) = SOME (transitive thm1 thm2)
   928 
   929 fun transitive2 thm = transitive1 (SOME thm);
   930 fun transitive3 thm = transitive1 thm o SOME;
   931 
   932 fun bottomc ((simprem, useprem, mutsimp), prover, thy, maxidx) =
   933   let
   934     fun botc skel ss t =
   935           if is_Var skel then NONE
   936           else
   937           (case subc skel ss t of
   938              some as SOME thm1 =>
   939                (case rewritec (prover, thy, maxidx) ss (rhs_of thm1) of
   940                   SOME (thm2, skel2) =>
   941                     transitive2 (transitive thm1 thm2)
   942                       (botc skel2 ss (rhs_of thm2))
   943                 | NONE => some)
   944            | NONE =>
   945                (case rewritec (prover, thy, maxidx) ss t of
   946                   SOME (thm2, skel2) => transitive2 thm2
   947                     (botc skel2 ss (rhs_of thm2))
   948                 | NONE => NONE))
   949 
   950     and try_botc ss t =
   951           (case botc skel0 ss t of
   952              SOME trec1 => trec1 | NONE => (reflexive t))
   953 
   954     and subc skel (ss as Simpset ({bounds, ...}, {congs, ...})) t0 =
   955        (case term_of t0 of
   956            Abs (a, T, t) =>
   957              let
   958                  val b = Term.bound (#1 bounds);
   959                  val (v, t') = Thm.dest_abs (SOME b) t0;
   960                  val b' = #1 (Term.dest_Free (Thm.term_of v));
   961                  val _ = conditional (b <> b') (fn () =>
   962                    warning ("Simplifier: renamed bound variable " ^ quote b ^ " to " ^ quote b'));
   963                  val ss' = add_bound ((b', T), a) ss;
   964                  val skel' = case skel of Abs (_, _, sk) => sk | _ => skel0;
   965              in case botc skel' ss' t' of
   966                   SOME thm => SOME (abstract_rule a v thm)
   967                 | NONE => NONE
   968              end
   969          | t $ _ => (case t of
   970              Const ("==>", _) $ _  => impc t0 ss
   971            | Abs _ =>
   972                let val thm = beta_conversion false t0
   973                in case subc skel0 ss (rhs_of thm) of
   974                     NONE => SOME thm
   975                   | SOME thm' => SOME (transitive thm thm')
   976                end
   977            | _  =>
   978                let fun appc () =
   979                      let
   980                        val (tskel, uskel) = case skel of
   981                            tskel $ uskel => (tskel, uskel)
   982                          | _ => (skel0, skel0);
   983                        val (ct, cu) = Thm.dest_comb t0
   984                      in
   985                      (case botc tskel ss ct of
   986                         SOME thm1 =>
   987                           (case botc uskel ss cu of
   988                              SOME thm2 => SOME (combination thm1 thm2)
   989                            | NONE => SOME (combination thm1 (reflexive cu)))
   990                       | NONE =>
   991                           (case botc uskel ss cu of
   992                              SOME thm1 => SOME (combination (reflexive ct) thm1)
   993                            | NONE => NONE))
   994                      end
   995                    val (h, ts) = strip_comb t
   996                in case cong_name h of
   997                     SOME a =>
   998                       (case AList.lookup (op =) (fst congs) a of
   999                          NONE => appc ()
  1000                        | SOME cong =>
  1001   (*post processing: some partial applications h t1 ... tj, j <= length ts,
  1002     may be a redex. Example: map (%x. x) = (%xs. xs) wrt map_cong*)
  1003                           (let
  1004                              val thm = congc (prover ss) ss maxidx cong t0;
  1005                              val t = getOpt (Option.map rhs_of thm, t0);
  1006                              val (cl, cr) = Thm.dest_comb t
  1007                              val dVar = Var(("", 0), dummyT)
  1008                              val skel =
  1009                                list_comb (h, replicate (length ts) dVar)
  1010                            in case botc skel ss cl of
  1011                                 NONE => thm
  1012                               | SOME thm' => transitive3 thm
  1013                                   (combination thm' (reflexive cr))
  1014                            end handle TERM _ => error "congc result"
  1015                                     | Pattern.MATCH => appc ()))
  1016                   | _ => appc ()
  1017                end)
  1018          | _ => NONE)
  1019 
  1020     and impc ct ss =
  1021       if mutsimp then mut_impc0 [] ct [] [] ss else nonmut_impc ct ss
  1022 
  1023     and rules_of_prem ss prem =
  1024       if maxidx_of_term (term_of prem) <> ~1
  1025       then (trace_cterm true
  1026         "Cannot add premise as rewrite rule because it contains (type) unknowns:" ss prem; ([], NONE))
  1027       else
  1028         let val asm = assume prem
  1029         in (extract_safe_rrules (ss, asm), SOME asm) end
  1030 
  1031     and add_rrules (rrss, asms) ss =
  1032       Library.foldl (insert_rrule true) (ss, List.concat rrss) |> add_prems (List.mapPartial I asms)
  1033 
  1034     and disch r (prem, eq) =
  1035       let
  1036         val (lhs, rhs) = dest_eq eq;
  1037         val eq' = implies_elim (Thm.instantiate
  1038           ([], [(cA, prem), (cB, lhs), (cC, rhs)]) Drule.imp_cong)
  1039           (implies_intr prem eq)
  1040       in if not r then eq' else
  1041         let
  1042           val (prem', concl) = dest_implies lhs;
  1043           val (prem'', _) = dest_implies rhs
  1044         in transitive (transitive
  1045           (Thm.instantiate ([], [(cA, prem'), (cB, prem), (cC, concl)])
  1046              Drule.swap_prems_eq) eq')
  1047           (Thm.instantiate ([], [(cA, prem), (cB, prem''), (cC, concl)])
  1048              Drule.swap_prems_eq)
  1049         end
  1050       end
  1051 
  1052     and rebuild [] _ _ _ _ eq = eq
  1053       | rebuild (prem :: prems) concl (rrs :: rrss) (asm :: asms) ss eq =
  1054           let
  1055             val ss' = add_rrules (rev rrss, rev asms) ss;
  1056             val concl' =
  1057               Drule.mk_implies (prem, getOpt (Option.map rhs_of eq, concl));
  1058             val dprem = Option.map (curry (disch false) prem)
  1059           in case rewritec (prover, thy, maxidx) ss' concl' of
  1060               NONE => rebuild prems concl' rrss asms ss (dprem eq)
  1061             | SOME (eq', _) => transitive2 (Library.foldl (disch false o swap)
  1062                   (valOf (transitive3 (dprem eq) eq'), prems))
  1063                 (mut_impc0 (rev prems) (rhs_of eq') (rev rrss) (rev asms) ss)
  1064           end
  1065 
  1066     and mut_impc0 prems concl rrss asms ss =
  1067       let
  1068         val prems' = strip_imp_prems concl;
  1069         val (rrss', asms') = split_list (map (rules_of_prem ss) prems')
  1070       in mut_impc (prems @ prems') (strip_imp_concl concl) (rrss @ rrss')
  1071         (asms @ asms') [] [] [] [] ss ~1 ~1
  1072       end
  1073 
  1074     and mut_impc [] concl [] [] prems' rrss' asms' eqns ss changed k =
  1075         transitive1 (Library.foldl (fn (eq2, (eq1, prem)) => transitive1 eq1
  1076             (Option.map (curry (disch false) prem) eq2)) (NONE, eqns ~~ prems'))
  1077           (if changed > 0 then
  1078              mut_impc (rev prems') concl (rev rrss') (rev asms')
  1079                [] [] [] [] ss ~1 changed
  1080            else rebuild prems' concl rrss' asms' ss
  1081              (botc skel0 (add_rrules (rev rrss', rev asms') ss) concl))
  1082 
  1083       | mut_impc (prem :: prems) concl (rrs :: rrss) (asm :: asms)
  1084           prems' rrss' asms' eqns ss changed k =
  1085         case (if k = 0 then NONE else botc skel0 (add_rrules
  1086           (rev rrss' @ rrss, rev asms' @ asms) ss) prem) of
  1087             NONE => mut_impc prems concl rrss asms (prem :: prems')
  1088               (rrs :: rrss') (asm :: asms') (NONE :: eqns) ss changed
  1089               (if k = 0 then 0 else k - 1)
  1090           | SOME eqn =>
  1091             let
  1092               val prem' = rhs_of eqn;
  1093               val tprems = map term_of prems;
  1094               val i = 1 + Library.foldl Int.max (~1, map (fn p =>
  1095                 find_index_eq p tprems) (#hyps (rep_thm eqn)));
  1096               val (rrs', asm') = rules_of_prem ss prem'
  1097             in mut_impc prems concl rrss asms (prem' :: prems')
  1098               (rrs' :: rrss') (asm' :: asms') (SOME (foldr (disch true)
  1099                 (Drule.imp_cong' eqn (reflexive (Drule.list_implies
  1100                   (Library.drop (i, prems), concl)))) (Library.take (i, prems))) :: eqns) ss (length prems') ~1
  1101             end
  1102 
  1103      (*legacy code - only for backwards compatibility*)
  1104      and nonmut_impc ct ss =
  1105        let val (prem, conc) = dest_implies ct;
  1106            val thm1 = if simprem then botc skel0 ss prem else NONE;
  1107            val prem1 = getOpt (Option.map rhs_of thm1, prem);
  1108            val ss1 = if not useprem then ss else add_rrules
  1109              (apsnd single (apfst single (rules_of_prem ss prem1))) ss
  1110        in (case botc skel0 ss1 conc of
  1111            NONE => (case thm1 of
  1112                NONE => NONE
  1113              | SOME thm1' => SOME (Drule.imp_cong' thm1' (reflexive conc)))
  1114          | SOME thm2 =>
  1115            let val thm2' = disch false (prem1, thm2)
  1116            in (case thm1 of
  1117                NONE => SOME thm2'
  1118              | SOME thm1' =>
  1119                  SOME (transitive (Drule.imp_cong' thm1' (reflexive conc)) thm2'))
  1120            end)
  1121        end
  1122 
  1123  in try_botc end;
  1124 
  1125 
  1126 (* Meta-rewriting: rewrites t to u and returns the theorem t==u *)
  1127 
  1128 (*
  1129   Parameters:
  1130     mode = (simplify A,
  1131             use A in simplifying B,
  1132             use prems of B (if B is again a meta-impl.) to simplify A)
  1133            when simplifying A ==> B
  1134     prover: how to solve premises in conditional rewrites and congruences
  1135 *)
  1136 
  1137 val debug_bounds = ref false;
  1138 
  1139 fun check_bounds ss ct = conditional (! debug_bounds) (fn () =>
  1140   let
  1141     val Simpset ({bounds = (_, bounds), ...}, _) = ss;
  1142     val bs = fold_aterms (fn Free (x, _) =>
  1143         if Term.is_bound x andalso not (AList.defined eq_bound bounds x)
  1144         then insert (op =) x else I
  1145       | _ => I) (term_of ct) [];
  1146   in
  1147     if null bs then ()
  1148     else print_term true ("Simplifier: term contains loose bounds: " ^ commas_quote bs) ss
  1149       (Thm.theory_of_cterm ct) (Thm.term_of ct)
  1150   end);
  1151 
  1152 fun rewrite_cterm mode prover raw_ss ct =
  1153   let
  1154     val {thy, t, maxidx, ...} = Thm.rep_cterm ct;
  1155     val ss = fallback_context thy raw_ss;
  1156     val _ = inc simp_depth;
  1157     val _ = conditional (!simp_depth mod 20 = 0) (fn () =>
  1158       warning ("Simplification depth " ^ string_of_int (! simp_depth)));
  1159     val _ = trace_cterm false "SIMPLIFIER INVOKED ON THE FOLLOWING TERM:" ss ct;
  1160     val _ = check_bounds ss ct;
  1161     val res = bottomc (mode, Option.map Drule.flexflex_unique oo prover, thy, maxidx) ss ct
  1162   in dec simp_depth; res end
  1163   handle exn => (dec simp_depth; raise exn);
  1164 
  1165 (*Rewrite a cterm*)
  1166 fun rewrite_aux _ _ [] ct = Thm.reflexive ct
  1167   | rewrite_aux prover full thms ct =
  1168       rewrite_cterm (full, false, false) prover
  1169       (theory_context (Thm.theory_of_cterm ct) empty_ss addsimps thms) ct;
  1170 
  1171 (*Rewrite a theorem*)
  1172 fun simplify_aux _ _ [] th = th
  1173   | simplify_aux prover full thms th =
  1174       Drule.fconv_rule (rewrite_cterm (full, false, false) prover
  1175         (theory_context (Thm.theory_of_thm th) empty_ss addsimps thms)) th;
  1176 
  1177 (*simple term rewriting -- no proof*)
  1178 fun rewrite_term thy rules procs =
  1179   Pattern.rewrite_term thy (map decomp_simp' rules) procs;
  1180 
  1181 fun rewrite_thm mode prover ss = Drule.fconv_rule (rewrite_cterm mode prover ss);
  1182 
  1183 (*Rewrite the subgoals of a proof state (represented by a theorem) *)
  1184 fun rewrite_goals_rule_aux _ []   th = th
  1185   | rewrite_goals_rule_aux prover thms th =
  1186       Drule.fconv_rule (Drule.goals_conv (K true) (rewrite_cterm (true, true, false) prover
  1187         (theory_context (Thm.theory_of_thm th) empty_ss addsimps thms))) th;
  1188 
  1189 (*Rewrite the subgoal of a proof state (represented by a theorem)*)
  1190 fun rewrite_goal_rule mode prover ss i thm =
  1191   if 0 < i  andalso  i <= nprems_of thm
  1192   then Drule.fconv_rule (Drule.goals_conv (fn j => j=i) (rewrite_cterm mode prover ss)) thm
  1193   else raise THM("rewrite_goal_rule",i,[thm]);
  1194 
  1195 (*Rewrite subgoal i only.  SELECT_GOAL avoids inefficiencies in goals_conv.*)
  1196 fun asm_rewrite_goal_tac mode prover_tac ss =
  1197   SELECT_GOAL
  1198     (PRIMITIVE (rewrite_goal_rule mode (SINGLE o prover_tac) ss 1));
  1199 
  1200 
  1201 
  1202 (** simplification tactics and rules **)
  1203 
  1204 fun solve_all_tac solvers ss =
  1205   let
  1206     val Simpset (_, {subgoal_tac, ...}) = ss;
  1207     val solve_tac = subgoal_tac (set_solvers solvers ss) THEN_ALL_NEW (K no_tac);
  1208   in DEPTH_SOLVE (solve_tac 1) end;
  1209 
  1210 (*NOTE: may instantiate unknowns that appear also in other subgoals*)
  1211 fun generic_simp_tac safe mode ss =
  1212   let
  1213     val Simpset (_, {loop_tacs, solvers = (unsafe_solvers, solvers), ...}) = ss;
  1214     val loop_tac = FIRST' (map (fn (_, tac) => tac ss) loop_tacs);
  1215     val solve_tac = FIRST' (map (solver ss) (if safe then solvers else unsafe_solvers));
  1216 
  1217     fun simp_loop_tac i =
  1218       asm_rewrite_goal_tac mode (solve_all_tac unsafe_solvers) ss i THEN
  1219       (solve_tac i ORELSE TRY ((loop_tac THEN_ALL_NEW simp_loop_tac) i));
  1220   in simp_loop_tac end;
  1221 
  1222 fun simp rew mode ss thm =
  1223   let
  1224     val Simpset (_, {solvers = (unsafe_solvers, _), ...}) = ss;
  1225     val tacf = solve_all_tac unsafe_solvers;
  1226     fun prover s th = Option.map #1 (Seq.pull (tacf s th));
  1227   in rew mode prover ss thm end;
  1228 
  1229 val simp_thm = simp rewrite_thm;
  1230 val simp_cterm = simp rewrite_cterm;
  1231 
  1232 end;
  1233 
  1234 structure BasicMetaSimplifier: BASIC_META_SIMPLIFIER = MetaSimplifier;
  1235 open BasicMetaSimplifier;