src/Pure/tctical.ML
author haftmann
Fri Oct 21 14:49:49 2005 +0200 (2005-10-21 ago)
changeset 17952 00eccd84608f
parent 17344 8b2f56aff711
child 17969 7262f4a45190
permissions -rw-r--r--
abandoned rational number functions in favor of General/rat.ML
     1 (*  Title:      Pure/tctical.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Tacticals.
     7 *)
     8 
     9 infix 1 THEN THEN' THEN_ALL_NEW;
    10 infix 0 ORELSE APPEND INTLEAVE ORELSE' APPEND' INTLEAVE';
    11 infix 0 THEN_ELSE;
    12 
    13 
    14 signature TACTICAL =
    15 sig
    16   type tactic  (* = thm -> thm Seq.seq*)
    17   val all_tac           : tactic
    18   val ALLGOALS          : (int -> tactic) -> tactic
    19   val APPEND            : tactic * tactic -> tactic
    20   val APPEND'           : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    21   val CHANGED           : tactic -> tactic
    22   val CHANGED_PROP      : tactic -> tactic
    23   val CHANGED_GOAL      : (int -> tactic) -> int -> tactic
    24   val COND              : (thm -> bool) -> tactic -> tactic -> tactic
    25   val DETERM            : tactic -> tactic
    26   val EVERY             : tactic list -> tactic
    27   val EVERY'            : ('a -> tactic) list -> 'a -> tactic
    28   val EVERY1            : (int -> tactic) list -> tactic
    29   val FILTER            : (thm -> bool) -> tactic -> tactic
    30   val FIRST             : tactic list -> tactic
    31   val FIRST'            : ('a -> tactic) list -> 'a -> tactic
    32   val FIRST1            : (int -> tactic) list -> tactic
    33   val FIRSTGOAL         : (int -> tactic) -> tactic
    34   val INTLEAVE          : tactic * tactic -> tactic
    35   val INTLEAVE'         : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    36   val METAHYPS          : (thm list -> tactic) -> int -> tactic
    37   val no_tac            : tactic
    38   val ORELSE            : tactic * tactic -> tactic
    39   val ORELSE'           : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    40   val pause_tac         : tactic
    41   val print_tac         : string -> tactic
    42   val PRIMITIVE         : (thm -> thm) -> tactic
    43   val PRIMSEQ           : (thm -> thm Seq.seq) -> tactic
    44   val RANGE             : (int -> tactic) list -> int -> tactic
    45   val REPEAT            : tactic -> tactic
    46   val REPEAT1           : tactic -> tactic
    47   val REPEAT_FIRST      : (int -> tactic) -> tactic
    48   val REPEAT_SOME       : (int -> tactic) -> tactic
    49   val REPEAT_DETERM_N   : int -> tactic -> tactic
    50   val REPEAT_DETERM     : tactic -> tactic
    51   val REPEAT_DETERM1    : tactic -> tactic
    52   val REPEAT_DETERM_FIRST: (int -> tactic) -> tactic
    53   val REPEAT_DETERM_SOME: (int -> tactic) -> tactic
    54   val DETERM_UNTIL      : (thm -> bool) -> tactic -> tactic
    55   val SELECT_GOAL       : tactic -> int -> tactic
    56   val SINGLE            : tactic -> thm -> thm option
    57   val SOMEGOAL          : (int -> tactic) -> tactic
    58   val strip_context     : term -> (string * typ) list * term list * term
    59   val SUBGOAL           : ((term*int) -> tactic) -> int -> tactic
    60   val suppress_tracing  : bool ref
    61   val THEN              : tactic * tactic -> tactic
    62   val THEN'             : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    63   val THEN_ALL_NEW      : (int -> tactic) * (int -> tactic) -> int -> tactic
    64   val REPEAT_ALL_NEW    : (int -> tactic) -> int -> tactic
    65   val THEN_ELSE         : tactic * (tactic*tactic) -> tactic
    66   val traced_tac        : (thm -> (thm * thm Seq.seq) option) -> tactic
    67   val tracify           : bool ref -> tactic -> tactic
    68   val trace_REPEAT      : bool ref
    69   val TRY               : tactic -> tactic
    70   val TRYALL            : (int -> tactic) -> tactic
    71 end;
    72 
    73 
    74 structure Tactical : TACTICAL =
    75 struct
    76 
    77 (**** Tactics ****)
    78 
    79 (*A tactic maps a proof tree to a sequence of proof trees:
    80     if length of sequence = 0 then the tactic does not apply;
    81     if length > 1 then backtracking on the alternatives can occur.*)
    82 
    83 type tactic = thm -> thm Seq.seq;
    84 
    85 
    86 (*** LCF-style tacticals ***)
    87 
    88 (*the tactical THEN performs one tactic followed by another*)
    89 fun (tac1 THEN tac2) st = Seq.maps tac2 (tac1 st);
    90 
    91 
    92 (*The tactical ORELSE uses the first tactic that returns a nonempty sequence.
    93   Like in LCF, ORELSE commits to either tac1 or tac2 immediately.
    94   Does not backtrack to tac2 if tac1 was initially chosen. *)
    95 fun (tac1 ORELSE tac2) st =
    96     case Seq.pull(tac1 st) of
    97         NONE       => tac2 st
    98       | sequencecell => Seq.make(fn()=> sequencecell);
    99 
   100 
   101 (*The tactical APPEND combines the results of two tactics.
   102   Like ORELSE, but allows backtracking on both tac1 and tac2.
   103   The tactic tac2 is not applied until needed.*)
   104 fun (tac1 APPEND tac2) st =
   105   Seq.append(tac1 st,
   106                   Seq.make(fn()=> Seq.pull (tac2 st)));
   107 
   108 (*Like APPEND, but interleaves results of tac1 and tac2.*)
   109 fun (tac1 INTLEAVE tac2) st =
   110     Seq.interleave(tac1 st,
   111                         Seq.make(fn()=> Seq.pull (tac2 st)));
   112 
   113 (*Conditional tactic.
   114         tac1 ORELSE tac2 = tac1 THEN_ELSE (all_tac, tac2)
   115         tac1 THEN tac2   = tac1 THEN_ELSE (tac2, no_tac)
   116 *)
   117 fun (tac THEN_ELSE (tac1, tac2)) st =
   118     case Seq.pull(tac st) of
   119         NONE    => tac2 st                                   (*failed; try tactic 2*)
   120       | seqcell => Seq.maps tac1 (Seq.make(fn()=> seqcell)); (*succeeded; use tactic 1*)
   121 
   122 
   123 (*Versions for combining tactic-valued functions, as in
   124      SOMEGOAL (resolve_tac rls THEN' assume_tac) *)
   125 fun (tac1 THEN' tac2) x = tac1 x THEN tac2 x;
   126 fun (tac1 ORELSE' tac2) x = tac1 x ORELSE tac2 x;
   127 fun (tac1 APPEND' tac2) x = tac1 x APPEND tac2 x;
   128 fun (tac1 INTLEAVE' tac2) x = tac1 x INTLEAVE tac2 x;
   129 
   130 (*passes all proofs through unchanged;  identity of THEN*)
   131 fun all_tac st = Seq.single st;
   132 
   133 (*passes no proofs through;  identity of ORELSE and APPEND*)
   134 fun no_tac st  = Seq.empty;
   135 
   136 
   137 (*Make a tactic deterministic by chopping the tail of the proof sequence*)
   138 fun DETERM tac = Seq.DETERM tac;
   139 
   140 (*Conditional tactical: testfun controls which tactic to use next.
   141   Beware: due to eager evaluation, both thentac and elsetac are evaluated.*)
   142 fun COND testfun thenf elsef = (fn prf =>
   143     if testfun prf then  thenf prf   else  elsef prf);
   144 
   145 (*Do the tactic or else do nothing*)
   146 fun TRY tac = tac ORELSE all_tac;
   147 
   148 (*** List-oriented tactics ***)
   149 
   150 local
   151   (*This version of EVERY avoids backtracking over repeated states*)
   152 
   153   fun EVY (trail, []) st =
   154         Seq.make (fn()=> SOME(st,
   155                         Seq.make (fn()=> Seq.pull (evyBack trail))))
   156     | EVY (trail, tac::tacs) st =
   157           case Seq.pull(tac st) of
   158               NONE    => evyBack trail              (*failed: backtrack*)
   159             | SOME(st',q) => EVY ((st',q,tacs)::trail, tacs) st'
   160   and evyBack [] = Seq.empty (*no alternatives*)
   161     | evyBack ((st',q,tacs)::trail) =
   162           case Seq.pull q of
   163               NONE        => evyBack trail
   164             | SOME(st,q') => if eq_thm (st',st)
   165                              then evyBack ((st',q',tacs)::trail)
   166                              else EVY ((st,q',tacs)::trail, tacs) st
   167 in
   168 
   169 (* EVERY [tac1,...,tacn]   equals    tac1 THEN ... THEN tacn   *)
   170 fun EVERY tacs = EVY ([], tacs);
   171 end;
   172 
   173 
   174 (* EVERY' [tac1,...,tacn] i  equals    tac1 i THEN ... THEN tacn i   *)
   175 fun EVERY' tacs i = EVERY (map (fn f => f i) tacs);
   176 
   177 (*Apply every tactic to 1*)
   178 fun EVERY1 tacs = EVERY' tacs 1;
   179 
   180 (* FIRST [tac1,...,tacn]   equals    tac1 ORELSE ... ORELSE tacn   *)
   181 fun FIRST tacs = foldr (op ORELSE) no_tac tacs;
   182 
   183 (* FIRST' [tac1,...,tacn] i  equals    tac1 i ORELSE ... ORELSE tacn i   *)
   184 fun FIRST' tacs = foldr (op ORELSE') (K no_tac) tacs;
   185 
   186 (*Apply first tactic to 1*)
   187 fun FIRST1 tacs = FIRST' tacs 1;
   188 
   189 (*Apply tactics on consecutive subgoals*)
   190 fun RANGE [] _ = all_tac
   191   | RANGE (tac :: tacs) i = RANGE tacs (i + 1) THEN tac i;
   192 
   193 
   194 (*** Tracing tactics ***)
   195 
   196 (*Print the current proof state and pass it on.*)
   197 fun print_tac msg =
   198     (fn st =>
   199      (tracing msg;
   200       tracing ((Pretty.string_of o Pretty.chunks o 
   201                  Display.pretty_goals (! Display.goals_limit)) st); 
   202       Seq.single st));
   203 
   204 (*Pause until a line is typed -- if non-empty then fail. *)
   205 fun pause_tac st =
   206   (tracing "** Press RETURN to continue:";
   207    if TextIO.inputLine TextIO.stdIn = "\n" then Seq.single st
   208    else (tracing "Goodbye";  Seq.empty));
   209 
   210 exception TRACE_EXIT of thm
   211 and TRACE_QUIT;
   212 
   213 (*Tracing flags*)
   214 val trace_REPEAT= ref false
   215 and suppress_tracing = ref false;
   216 
   217 (*Handle all tracing commands for current state and tactic *)
   218 fun exec_trace_command flag (tac, st) =
   219    case TextIO.inputLine(TextIO.stdIn) of
   220        "\n" => tac st
   221      | "f\n" => Seq.empty
   222      | "o\n" => (flag:=false;  tac st)
   223      | "s\n" => (suppress_tracing:=true;  tac st)
   224      | "x\n" => (tracing "Exiting now";  raise (TRACE_EXIT st))
   225      | "quit\n" => raise TRACE_QUIT
   226      | _     => (tracing
   227 "Type RETURN to continue or...\n\
   228 \     f    - to fail here\n\
   229 \     o    - to switch tracing off\n\
   230 \     s    - to suppress tracing until next entry to a tactical\n\
   231 \     x    - to exit at this point\n\
   232 \     quit - to abort this tracing run\n\
   233 \** Well? "     ;  exec_trace_command flag (tac, st));
   234 
   235 
   236 (*Extract from a tactic, a thm->thm seq function that handles tracing*)
   237 fun tracify flag tac st =
   238   if !flag andalso not (!suppress_tracing)
   239            then (Display.print_goals (! Display.goals_limit) st;
   240                  tracing "** Press RETURN to continue:";
   241                  exec_trace_command flag (tac,st))
   242   else tac st;
   243 
   244 (*Create a tactic whose outcome is given by seqf, handling TRACE_EXIT*)
   245 fun traced_tac seqf st =
   246     (suppress_tracing := false;
   247      Seq.make (fn()=> seqf st
   248                          handle TRACE_EXIT st' => SOME(st', Seq.empty)));
   249 
   250 
   251 (*Deterministic DO..UNTIL: only retains the first outcome; tail recursive.
   252   Forces repitition until predicate on state is fulfilled.*)
   253 fun DETERM_UNTIL p tac =
   254 let val tac = tracify trace_REPEAT tac
   255     fun drep st = if p st then SOME (st, Seq.empty)
   256                           else (case Seq.pull(tac st) of
   257                                   NONE        => NONE
   258                                 | SOME(st',_) => drep st')
   259 in  traced_tac drep  end;
   260 
   261 (*Deterministic REPEAT: only retains the first outcome;
   262   uses less space than REPEAT; tail recursive.
   263   If non-negative, n bounds the number of repetitions.*)
   264 fun REPEAT_DETERM_N n tac =
   265   let val tac = tracify trace_REPEAT tac
   266       fun drep 0 st = SOME(st, Seq.empty)
   267         | drep n st =
   268            (case Seq.pull(tac st) of
   269                 NONE       => SOME(st, Seq.empty)
   270               | SOME(st',_) => drep (n-1) st')
   271   in  traced_tac (drep n)  end;
   272 
   273 (*Allows any number of repetitions*)
   274 val REPEAT_DETERM = REPEAT_DETERM_N ~1;
   275 
   276 (*General REPEAT: maintains a stack of alternatives; tail recursive*)
   277 fun REPEAT tac =
   278   let val tac = tracify trace_REPEAT tac
   279       fun rep qs st =
   280         case Seq.pull(tac st) of
   281             NONE       => SOME(st, Seq.make(fn()=> repq qs))
   282           | SOME(st',q) => rep (q::qs) st'
   283       and repq [] = NONE
   284         | repq(q::qs) = case Seq.pull q of
   285             NONE       => repq qs
   286           | SOME(st,q) => rep (q::qs) st
   287   in  traced_tac (rep [])  end;
   288 
   289 (*Repeat 1 or more times*)
   290 fun REPEAT_DETERM1 tac = DETERM tac THEN REPEAT_DETERM tac;
   291 fun REPEAT1 tac = tac THEN REPEAT tac;
   292 
   293 
   294 (** Filtering tacticals **)
   295 
   296 fun FILTER pred tac st = Seq.filter pred (tac st);
   297 
   298 (*Accept only next states that change the theorem somehow*)
   299 fun CHANGED tac st =
   300   let fun diff st' = not (Thm.eq_thm (st, st'));
   301   in Seq.filter diff (tac st) end;
   302 
   303 (*Accept only next states that change the theorem's prop field
   304   (changes to signature, hyps, etc. don't count)*)
   305 fun CHANGED_PROP tac st =
   306   let fun diff st' = not (Drule.eq_thm_prop (st, st'));
   307   in Seq.filter diff (tac st) end;
   308 
   309 
   310 (*** Tacticals based on subgoal numbering ***)
   311 
   312 (*For n subgoals, performs tac(n) THEN ... THEN tac(1)
   313   Essential to work backwards since tac(i) may add/delete subgoals at i. *)
   314 fun ALLGOALS tac st =
   315   let fun doall 0 = all_tac
   316         | doall n = tac(n) THEN doall(n-1)
   317   in  doall(nprems_of st)st  end;
   318 
   319 (*For n subgoals, performs tac(n) ORELSE ... ORELSE tac(1)  *)
   320 fun SOMEGOAL tac st =
   321   let fun find 0 = no_tac
   322         | find n = tac(n) ORELSE find(n-1)
   323   in  find(nprems_of st)st  end;
   324 
   325 (*For n subgoals, performs tac(1) ORELSE ... ORELSE tac(n).
   326   More appropriate than SOMEGOAL in some cases.*)
   327 fun FIRSTGOAL tac st =
   328   let fun find (i,n) = if i>n then no_tac else  tac(i) ORELSE find (i+1,n)
   329   in  find(1, nprems_of st)st  end;
   330 
   331 (*Repeatedly solve some using tac. *)
   332 fun REPEAT_SOME tac = REPEAT1 (SOMEGOAL (REPEAT1 o tac));
   333 fun REPEAT_DETERM_SOME tac = REPEAT_DETERM1 (SOMEGOAL (REPEAT_DETERM1 o tac));
   334 
   335 (*Repeatedly solve the first possible subgoal using tac. *)
   336 fun REPEAT_FIRST tac = REPEAT1 (FIRSTGOAL (REPEAT1 o tac));
   337 fun REPEAT_DETERM_FIRST tac = REPEAT_DETERM1 (FIRSTGOAL (REPEAT_DETERM1 o tac));
   338 
   339 (*For n subgoals, tries to apply tac to n,...1  *)
   340 fun TRYALL tac = ALLGOALS (TRY o tac);
   341 
   342 
   343 (*Make a tactic for subgoal i, if there is one.  *)
   344 fun SUBGOAL goalfun i st =
   345   (case try Logic.nth_prem (i, Thm.prop_of st) of
   346     SOME goal => goalfun (goal, i) st
   347   | NONE => Seq.empty);
   348 
   349 (*Returns all states that have changed in subgoal i, counted from the LAST
   350   subgoal.  For stac, for example.*)
   351 fun CHANGED_GOAL tac i st =
   352     let val np = nprems_of st
   353         val d = np-i                 (*distance from END*)
   354         val t = List.nth(prems_of st, i-1)
   355         fun diff st' =
   356             nprems_of st' - d <= 0   (*the subgoal no longer exists*)
   357             orelse
   358              not (Pattern.aeconv (t,
   359                                   List.nth(prems_of st',
   360                                            nprems_of st' - d - 1)))
   361     in  Seq.filter diff (tac i st)  end
   362     handle Subscript => Seq.empty  (*no subgoal i*);
   363 
   364 fun (tac1 THEN_ALL_NEW tac2) i st =
   365   st |> (tac1 i THEN (fn st' => Seq.INTERVAL tac2 i (i + nprems_of st' - nprems_of st) st'));
   366 
   367 (*repeatedly dig into any emerging subgoals*)
   368 fun REPEAT_ALL_NEW tac =
   369   tac THEN_ALL_NEW (TRY o (fn i => REPEAT_ALL_NEW tac i));
   370 
   371 
   372 (*** SELECT_GOAL ***)
   373 
   374 (*Tactical for restricting the effect of a tactic to subgoal i.
   375   Works by making a new state from subgoal i, applying tac to it, and
   376   composing the resulting metathm with the original state.*)
   377 
   378 (*Does the work of SELECT_GOAL. *)
   379 fun select tac st i =
   380   let
   381     val thm = Drule.mk_triv_goal (adjust_maxidx (List.nth (cprems_of st, i-1)));
   382     fun restore th = Seq.hd (bicompose false (false, th, nprems_of th) 1
   383       (Thm.incr_indexes (#maxidx (rep_thm th) + 1) Drule.rev_triv_goal));
   384     fun next st' = bicompose false (false, restore st', nprems_of st') i st;
   385   in Seq.maps next (tac thm) end;
   386 
   387 fun SELECT_GOAL tac i st =
   388   let val np = nprems_of st
   389   in  if 1<=i andalso i<=np then
   390           (*If only one subgoal, then just apply tactic*)
   391           if np=1 then tac st else select tac st i
   392       else Seq.empty
   393   end;
   394 
   395 
   396 (*Strips assumptions in goal yielding  ( [x1,...,xm], [H1,...,Hn], B )
   397     H1,...,Hn are the hypotheses;  x1...xm are variants of the parameters.
   398   Main difference from strip_assums concerns parameters:
   399     it replaces the bound variables by free variables.  *)
   400 fun strip_context_aux (params, Hs, Const("==>", _) $ H $ B) =
   401         strip_context_aux (params, H::Hs, B)
   402   | strip_context_aux (params, Hs, Const("all",_)$Abs(a,T,t)) =
   403         let val (b,u) = variant_abs(a,T,t)
   404         in  strip_context_aux ((b,T)::params, Hs, u)  end
   405   | strip_context_aux (params, Hs, B) = (rev params, rev Hs, B);
   406 
   407 fun strip_context A = strip_context_aux ([],[],A);
   408 
   409 
   410 (**** METAHYPS -- tactical for using hypotheses as meta-level assumptions
   411        METAHYPS (fn prems => tac prems) i
   412 
   413 converts subgoal i, of the form !!x1...xm. [| A1;...;An] ==> A into a new
   414 proof state A==>A, supplying A1,...,An as meta-level assumptions (in
   415 "prems").  The parameters x1,...,xm become free variables.  If the
   416 resulting proof state is [| B1;...;Bk] ==> C (possibly assuming A1,...,An)
   417 then it is lifted back into the original context, yielding k subgoals.
   418 
   419 Replaces unknowns in the context by Frees having the prefix METAHYP_
   420 New unknowns in [| B1;...;Bk] ==> C are lifted over x1,...,xm.
   421 DOES NOT HANDLE TYPE UNKNOWNS.
   422 ****)
   423 
   424 local
   425 
   426   (*Left-to-right replacements: ctpairs = [...,(vi,ti),...].
   427     Instantiates distinct free variables by terms of same type.*)
   428   fun free_instantiate ctpairs =
   429       forall_elim_list (map snd ctpairs) o forall_intr_list (map fst ctpairs);
   430 
   431   fun free_of s ((a,i), T) =
   432         Free(s ^ (case i of 0 => a | _ => a ^ "_" ^ string_of_int i),
   433              T)
   434 
   435   fun mk_inst (var as Var(v,T))  = (var,  free_of "METAHYP1_" (v,T))
   436 in
   437 
   438 fun metahyps_aux_tac tacf (prem,i) state =
   439   let val {sign,maxidx,...} = rep_thm state
   440       val cterm = cterm_of sign
   441       (*find all vars in the hyps -- should find tvars also!*)
   442       val hyps_vars = foldr add_term_vars [] (Logic.strip_assums_hyp prem)
   443       val insts = map mk_inst hyps_vars
   444       (*replace the hyps_vars by Frees*)
   445       val prem' = subst_atomic insts prem
   446       val (params,hyps,concl) = strip_context prem'
   447       val fparams = map Free params
   448       val cparams = map cterm fparams
   449       and chyps = map cterm hyps
   450       val hypths = map assume chyps
   451       fun swap_ctpair (t,u) = (cterm u, cterm t)
   452       (*Subgoal variables: make Free; lift type over params*)
   453       fun mk_subgoal_inst concl_vars (var as Var(v,T)) =
   454           if var mem concl_vars
   455           then (var, true, free_of "METAHYP2_" (v,T))
   456           else (var, false,
   457                 free_of "METAHYP2_" (v, map #2 params --->T))
   458       (*Instantiate subgoal vars by Free applied to params*)
   459       fun mk_ctpair (t,in_concl,u) =
   460           if in_concl then (cterm t,  cterm u)
   461           else (cterm t,  cterm (list_comb (u,fparams)))
   462       (*Restore Vars with higher type and index*)
   463       fun mk_subgoal_swap_ctpair
   464                 (t as Var((a,i),_), in_concl, u as Free(_,U)) =
   465           if in_concl then (cterm u, cterm t)
   466           else (cterm u, cterm(Var((a, i+maxidx), U)))
   467       (*Embed B in the original context of params and hyps*)
   468       fun embed B = list_all_free (params, Logic.list_implies (hyps, B))
   469       (*Strip the context using elimination rules*)
   470       fun elim Bhyp = implies_elim_list (forall_elim_list cparams Bhyp) hypths
   471       (*A form of lifting that discharges assumptions.*)
   472       fun relift st =
   473         let val prop = #prop(rep_thm st)
   474             val subgoal_vars = (*Vars introduced in the subgoals*)
   475                   foldr add_term_vars [] (Logic.strip_imp_prems prop)
   476             and concl_vars = add_term_vars (Logic.strip_imp_concl prop, [])
   477             val subgoal_insts = map (mk_subgoal_inst concl_vars) subgoal_vars
   478             val st' = Thm.instantiate ([], map mk_ctpair subgoal_insts) st
   479             val emBs = map (cterm o embed) (prems_of st')
   480             val Cth  = implies_elim_list st' (map (elim o assume) emBs)
   481         in  (*restore the unknowns to the hypotheses*)
   482             free_instantiate (map swap_ctpair insts @
   483                               map mk_subgoal_swap_ctpair subgoal_insts)
   484                 (*discharge assumptions from state in same order*)
   485                 (implies_intr_list emBs
   486                   (forall_intr_list cparams (implies_intr_list chyps Cth)))
   487         end
   488       val subprems = map (forall_elim_vars 0) hypths
   489       and st0 = trivial (cterm concl)
   490       (*function to replace the current subgoal*)
   491       fun next st = bicompose false (false, relift st, nprems_of st)
   492                     i state
   493   in Seq.maps next (tacf subprems st0) end;
   494 end;
   495 
   496 fun METAHYPS tacf = SUBGOAL (metahyps_aux_tac tacf);
   497 
   498 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm seq.*)
   499 fun PRIMSEQ thmfun st =  thmfun st handle THM _ => Seq.empty;
   500 
   501 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm.*)
   502 fun PRIMITIVE thmfun = PRIMSEQ (Seq.single o thmfun);
   503 
   504 (* Inverse (more or less) of PRIMITIVE *)
   505 fun SINGLE tacf = Option.map fst o Seq.pull o tacf
   506 		  
   507 end;
   508 
   509 open Tactical;