src/Pure/type.ML
author haftmann
Fri Oct 21 14:49:49 2005 +0200 (2005-10-21 ago)
changeset 17952 00eccd84608f
parent 17804 4deae4b33d97
child 18928 042608ffa2ec
permissions -rw-r--r--
abandoned rational number functions in favor of General/rat.ML
     1 (*  Title:      Pure/type.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Lawrence C Paulson, and Markus Wenzel
     4 
     5 Type signatures and certified types, special treatment of type vars,
     6 matching and unification of types, extend and merge type signatures.
     7 *)
     8 
     9 signature TYPE =
    10 sig
    11   (*type signatures and certified types*)
    12   datatype decl =
    13     LogicalType of int |
    14     Abbreviation of string list * typ * bool |
    15     Nonterminal
    16   type tsig
    17   val rep_tsig: tsig ->
    18    {classes: NameSpace.T * Sorts.classes,
    19     default: sort,
    20     types: (decl * stamp) NameSpace.table,
    21     arities: Sorts.arities,
    22     log_types: string list,
    23     witness: (typ * sort) option}
    24   val empty_tsig: tsig
    25   val classes: tsig -> class list
    26   val defaultS: tsig -> sort
    27   val logical_types: tsig -> string list
    28   val universal_witness: tsig -> (typ * sort) option
    29   val eq_sort: tsig -> sort * sort -> bool
    30   val subsort: tsig -> sort * sort -> bool
    31   val of_sort: tsig -> typ * sort -> bool
    32   val cert_class: tsig -> class -> class
    33   val cert_sort: tsig -> sort -> sort
    34   val witness_sorts: tsig -> sort list -> sort list -> (typ * sort) list
    35   val cert_typ: tsig -> typ -> typ
    36   val cert_typ_syntax: tsig -> typ -> typ
    37   val cert_typ_abbrev: tsig -> typ -> typ
    38 
    39   (*special treatment of type vars*)
    40   val strip_sorts: typ -> typ
    41   val no_tvars: typ -> typ
    42   val varifyT: typ -> typ
    43   val unvarifyT: typ -> typ
    44   val varify: term * (string * sort) list -> term * ((string * sort) * indexname) list
    45   val freeze_thaw_type: typ -> typ * (typ -> typ)
    46   val freeze_type: typ -> typ
    47   val freeze_thaw: term -> term * (term -> term)
    48   val freeze: term -> term
    49 
    50   (*matching and unification*)
    51   exception TYPE_MATCH
    52   type tyenv
    53   val lookup: tyenv * (indexname * sort) -> typ option
    54   val typ_match: tsig -> typ * typ -> tyenv -> tyenv
    55   val typ_instance: tsig -> typ * typ -> bool
    56   val raw_match: typ * typ -> tyenv -> tyenv
    57   val raw_instance: typ * typ -> bool
    58   exception TUNIFY
    59   val unify: tsig -> typ * typ -> tyenv * int -> tyenv * int
    60   val raw_unify: typ * typ -> tyenv -> tyenv
    61   val could_unify: typ * typ -> bool
    62   val eq_type: tyenv -> typ * typ -> bool
    63 
    64   (*extend and merge type signatures*)
    65   val add_classes: Pretty.pp -> NameSpace.naming -> (bstring * class list) list -> tsig -> tsig
    66   val hide_classes: bool -> string list -> tsig -> tsig
    67   val add_classrel: Pretty.pp -> (class * class) list -> tsig -> tsig
    68   val set_defsort: sort -> tsig -> tsig
    69   val add_types: NameSpace.naming -> (bstring * int) list -> tsig -> tsig
    70   val add_abbrevs: NameSpace.naming -> (string * string list * typ) list -> tsig -> tsig
    71   val add_nonterminals: NameSpace.naming -> string list -> tsig -> tsig
    72   val hide_types: bool -> string list -> tsig -> tsig
    73   val add_arities: Pretty.pp -> arity list -> tsig -> tsig
    74   val merge_tsigs: Pretty.pp -> tsig * tsig -> tsig
    75 end;
    76 
    77 structure Type: TYPE =
    78 struct
    79 
    80 (** type signatures and certified types **)
    81 
    82 (* type declarations *)
    83 
    84 datatype decl =
    85   LogicalType of int |
    86   Abbreviation of string list * typ * bool |
    87   Nonterminal;
    88 
    89 fun str_of_decl (LogicalType _) = "logical type constructor"
    90   | str_of_decl (Abbreviation _) = "type abbreviation"
    91   | str_of_decl Nonterminal = "syntactic type";
    92 
    93 
    94 (* type tsig *)
    95 
    96 datatype tsig =
    97   TSig of {
    98     classes: NameSpace.T * Sorts.classes,   (*declared classes with proper subclass relation*)
    99     default: sort,                          (*default sort on input*)
   100     types: (decl * stamp) NameSpace.table,  (*declared types*)
   101     arities: Sorts.arities,                 (*image specification of types wrt. sorts*)
   102     log_types: string list,                 (*logical types sorted by number of arguments*)
   103     witness: (typ * sort) option};          (*witness for non-emptiness of strictest sort*)
   104 
   105 fun rep_tsig (TSig comps) = comps;
   106 
   107 fun make_tsig (classes, default, types, arities, log_types, witness) =
   108   TSig {classes = classes, default = default, types = types, arities = arities,
   109     log_types = log_types, witness = witness};
   110 
   111 fun build_tsig (classes, default, types, arities) =
   112   let
   113     val log_types =
   114       Symtab.fold (fn (c, (LogicalType n, _)) => cons (c, n) | _ => I) (snd types) []
   115       |> Library.sort (Library.int_ord o pairself snd) |> map fst;
   116     val witness =
   117       (case Sorts.witness_sorts (snd classes, arities) log_types [] [Graph.keys (snd classes)] of
   118         [w] => SOME w | _ => NONE);
   119   in make_tsig (classes, default, types, arities, log_types, witness) end;
   120 
   121 fun map_tsig f (TSig {classes, default, types, arities, log_types = _, witness = _}) =
   122   build_tsig (f (classes, default, types, arities));
   123 
   124 val empty_tsig =
   125   build_tsig ((NameSpace.empty, Graph.empty), [], NameSpace.empty_table, Symtab.empty);
   126 
   127 
   128 (* classes and sorts *)
   129 
   130 fun classes (TSig {classes = (_, C), ...}) = Graph.keys C;
   131 fun defaultS (TSig {default, ...}) = default;
   132 fun logical_types (TSig {log_types, ...}) = log_types;
   133 fun universal_witness (TSig {witness, ...}) = witness;
   134 
   135 fun eq_sort (TSig {classes, ...}) = Sorts.sort_eq (#2 classes);
   136 fun subsort (TSig {classes, ...}) = Sorts.sort_le (#2 classes);
   137 fun of_sort (TSig {classes, arities, ...}) = Sorts.of_sort (#2 classes, arities);
   138 
   139 fun cert_class (TSig {classes, ...}) = Sorts.certify_class (#2 classes);
   140 fun cert_sort (TSig {classes, ...}) = Sorts.certify_sort (#2 classes);
   141 
   142 fun witness_sorts (tsig as TSig {classes, arities, log_types, ...}) =
   143   Sorts.witness_sorts (#2 classes, arities) log_types;
   144 
   145 
   146 (* certified types *)
   147 
   148 fun bad_nargs t = "Bad number of arguments for type constructor: " ^ quote t;
   149 fun undecl_type c = "Undeclared type constructor: " ^ quote c;
   150 
   151 local
   152 
   153 fun inst_typ env (Type (c, Ts)) = Type (c, map (inst_typ env) Ts)
   154   | inst_typ env (T as TFree (x, _)) = if_none (AList.lookup (op =) env x) T
   155   | inst_typ _ T = T;
   156 
   157 fun certify_typ normalize syntax tsig ty =
   158   let
   159     val TSig {classes = (_, classes), types = (_, types), ...} = tsig;
   160     fun err msg = raise TYPE (msg, [ty], []);
   161 
   162     val check_syntax =
   163       if syntax then K ()
   164       else fn c => err ("Illegal occurrence of syntactic type: " ^ quote c);
   165 
   166     fun cert (T as Type (c, Ts)) =
   167           let
   168             val Ts' = map cert Ts;
   169             fun nargs n = if length Ts <> n then err (bad_nargs c) else ();
   170           in
   171             (case Symtab.lookup types c of
   172               SOME (LogicalType n, _) => (nargs n; Type (c, Ts'))
   173             | SOME (Abbreviation (vs, U, syn), _) => (nargs (length vs);
   174                 if syn then check_syntax c else ();
   175                 if normalize then inst_typ (vs ~~ Ts') U
   176                 else Type (c, Ts'))
   177             | SOME (Nonterminal, _) => (nargs 0; check_syntax c; T)
   178             | NONE => err (undecl_type c))
   179           end
   180       | cert (TFree (x, S)) = TFree (x, Sorts.certify_sort classes S)
   181       | cert (TVar (xi as (_, i), S)) =
   182           if i < 0 then
   183             err ("Malformed type variable: " ^ quote (Term.string_of_vname xi))
   184           else TVar (xi, Sorts.certify_sort classes S);
   185 
   186     val ty' = cert ty;
   187   in if ty = ty' then ty else ty' end;  (*avoid copying of already normal type*)
   188 
   189 in
   190 
   191 val cert_typ        = certify_typ true false;
   192 val cert_typ_syntax = certify_typ true true;
   193 val cert_typ_abbrev = certify_typ false true;
   194 
   195 end;
   196 
   197 
   198 
   199 (** special treatment of type vars **)
   200 
   201 (* strip_sorts *)
   202 
   203 fun strip_sorts (Type (a, Ts)) = Type (a, map strip_sorts Ts)
   204   | strip_sorts (TFree (x, _)) = TFree (x, [])
   205   | strip_sorts (TVar (xi, _)) = TVar (xi, []);
   206 
   207 
   208 (* no_tvars *)
   209 
   210 fun no_tvars T =
   211   (case typ_tvars T of [] => T
   212   | vs => raise TYPE ("Illegal schematic type variable(s): " ^
   213       commas_quote (map (Term.string_of_vname o #1) vs), [T], []));
   214 
   215 
   216 (* varify, unvarify *)
   217 
   218 val varifyT = map_type_tfree (fn (a, S) => TVar ((a, 0), S));
   219 val unvarifyT = map_type_tvar (fn ((a, 0), S) => TFree (a, S) | v => TVar v);
   220 
   221 fun varify (t, fixed) =
   222   let
   223     val fs = add_term_tfrees (t, []) \\ fixed;
   224     val ixns = add_term_tvar_ixns (t, []);
   225     val fmap = fs ~~ map (rpair 0) (variantlist (map fst fs, map #1 ixns))
   226     fun thaw (f as (a, S)) =
   227       (case AList.lookup (op =) fmap f of
   228         NONE => TFree f
   229       | SOME xi => TVar (xi, S));
   230   in (map_term_types (map_type_tfree thaw) t, fmap) end;
   231 
   232 
   233 (* freeze_thaw: freeze TVars in a term; return the "thaw" inverse *)
   234 
   235 local
   236 
   237 fun new_name (ix, (pairs, used)) =
   238   let val v = variant used (string_of_indexname ix)
   239   in ((ix, v) :: pairs, v :: used) end;
   240 
   241 fun freeze_one alist (ix, sort) =
   242   TFree (the (AList.lookup (op =) alist ix), sort)
   243     handle Option =>
   244       raise TYPE ("Failure during freezing of ?" ^ string_of_indexname ix, [], []);
   245 
   246 fun thaw_one alist (a, sort) = TVar (the (AList.lookup (op =) alist a), sort)
   247   handle Option => TFree (a, sort);
   248 
   249 in
   250 
   251 (*this sort of code could replace unvarifyT*)
   252 fun freeze_thaw_type T =
   253   let
   254     val used = add_typ_tfree_names (T, [])
   255     and tvars = map #1 (add_typ_tvars (T, []));
   256     val (alist, _) = foldr new_name ([], used) tvars;
   257   in (map_type_tvar (freeze_one alist) T, map_type_tfree (thaw_one (map swap alist))) end;
   258 
   259 val freeze_type = #1 o freeze_thaw_type;
   260 
   261 fun freeze_thaw t =
   262   let
   263     val used = it_term_types add_typ_tfree_names (t, [])
   264     and tvars = map #1 (it_term_types add_typ_tvars (t, []));
   265     val (alist, _) = foldr new_name ([], used) tvars;
   266   in
   267     (case alist of
   268       [] => (t, fn x => x) (*nothing to do!*)
   269     | _ => (map_term_types (map_type_tvar (freeze_one alist)) t,
   270       map_term_types (map_type_tfree (thaw_one (map swap alist)))))
   271   end;
   272 
   273 val freeze = #1 o freeze_thaw;
   274 
   275 end;
   276 
   277 
   278 
   279 (** matching and unification of types **)
   280 
   281 type tyenv = (sort * typ) Vartab.table;
   282 
   283 fun tvar_clash ixn S S' = raise TYPE ("Type variable " ^
   284   quote (Term.string_of_vname ixn) ^ " has two distinct sorts",
   285   [TVar (ixn, S), TVar (ixn, S')], []);
   286 
   287 fun lookup (tye, (ixn, S)) =
   288   (case Vartab.lookup tye ixn of
   289     NONE => NONE
   290   | SOME (S', T) => if S = S' then SOME T else tvar_clash ixn S S');
   291 
   292 
   293 (* matching *)
   294 
   295 exception TYPE_MATCH;
   296 
   297 fun typ_match tsig =
   298   let
   299     fun match (TVar (v, S), T) subs =
   300           (case lookup (subs, (v, S)) of
   301             NONE =>
   302               if of_sort tsig (T, S) then Vartab.update_new (v, (S, T)) subs
   303               else raise TYPE_MATCH
   304           | SOME U => if U = T then subs else raise TYPE_MATCH)
   305       | match (Type (a, Ts), Type (b, Us)) subs =
   306           if a <> b then raise TYPE_MATCH
   307           else matches (Ts, Us) subs
   308       | match (TFree x, TFree y) subs =
   309           if x = y then subs else raise TYPE_MATCH
   310       | match _ _ = raise TYPE_MATCH
   311     and matches (T :: Ts, U :: Us) subs = matches (Ts, Us) (match (T, U) subs)
   312       | matches _ subs = subs;
   313   in match end;
   314 
   315 fun typ_instance tsig (T, U) =
   316   (typ_match tsig (U, T) Vartab.empty; true) handle TYPE_MATCH => false;
   317 
   318 (*purely structural matching*)
   319 fun raw_match (TVar (v, S), T) subs =
   320       (case lookup (subs, (v, S)) of
   321         NONE => Vartab.update_new (v, (S, T)) subs
   322       | SOME U => if U = T then subs else raise TYPE_MATCH)
   323   | raw_match (Type (a, Ts), Type (b, Us)) subs =
   324       if a <> b then raise TYPE_MATCH
   325       else raw_matches (Ts, Us) subs
   326   | raw_match (TFree x, TFree y) subs =
   327       if x = y then subs else raise TYPE_MATCH
   328   | raw_match _ _ = raise TYPE_MATCH
   329 and raw_matches (T :: Ts, U :: Us) subs = raw_matches (Ts, Us) (raw_match (T, U) subs)
   330   | raw_matches _ subs = subs;
   331 
   332 fun raw_instance (T, U) =
   333   (raw_match (U, T) Vartab.empty; true) handle TYPE_MATCH => false;
   334 
   335 
   336 (* unification *)
   337 
   338 exception TUNIFY;
   339 
   340 (*occurs_check*)
   341 fun occurs v tye =
   342   let
   343     fun occ (Type (_, Ts)) = exists occ Ts
   344       | occ (TFree _) = false
   345       | occ (TVar (w, S)) =
   346           eq_ix (v, w) orelse
   347             (case lookup (tye, (w, S)) of
   348               NONE => false
   349             | SOME U => occ U);
   350   in occ end;
   351 
   352 (*chase variable assignments; if devar returns a type var then it must be unassigned*)
   353 fun devar tye (T as TVar v) =
   354       (case lookup (tye, v) of
   355         SOME U => devar tye U
   356       | NONE => T)
   357   | devar tye T = T;
   358 
   359 (*order-sorted unification*)
   360 fun unify (tsig as TSig {classes = (_, classes), arities, ...}) TU (tyenv, maxidx) =
   361   let
   362     val tyvar_count = ref maxidx;
   363     fun gen_tyvar S = TVar (("'a", inc tyvar_count), S);
   364 
   365     fun mg_domain a S =
   366       Sorts.mg_domain (classes, arities) a S handle Sorts.DOMAIN _ => raise TUNIFY;
   367 
   368     fun meet (_, []) tye = tye
   369       | meet (TVar (xi, S'), S) tye =
   370           if Sorts.sort_le classes (S', S) then tye
   371           else Vartab.update_new
   372             (xi, (S', gen_tyvar (Sorts.inter_sort classes (S', S)))) tye
   373       | meet (TFree (_, S'), S) tye =
   374           if Sorts.sort_le classes (S', S) then tye
   375           else raise TUNIFY
   376       | meet (Type (a, Ts), S) tye = meets (Ts, mg_domain a S) tye
   377     and meets (T :: Ts, S :: Ss) tye = meets (Ts, Ss) (meet (devar tye T, S) tye)
   378       | meets _ tye = tye;
   379 
   380     fun unif (ty1, ty2) tye =
   381       (case (devar tye ty1, devar tye ty2) of
   382         (T as TVar (v, S1), U as TVar (w, S2)) =>
   383           if eq_ix (v, w) then
   384             if S1 = S2 then tye else tvar_clash v S1 S2
   385           else if Sorts.sort_le classes (S1, S2) then
   386             Vartab.update_new (w, (S2, T)) tye
   387           else if Sorts.sort_le classes (S2, S1) then
   388             Vartab.update_new (v, (S1, U)) tye
   389           else
   390             let val S = gen_tyvar (Sorts.inter_sort classes (S1, S2)) in
   391               Vartab.update_new (v, (S1, S)) (Vartab.update_new (w, (S2, S)) tye)
   392             end
   393       | (TVar (v, S), T) =>
   394           if occurs v tye T then raise TUNIFY
   395           else meet (T, S) (Vartab.update_new (v, (S, T)) tye)
   396       | (T, TVar (v, S)) =>
   397           if occurs v tye T then raise TUNIFY
   398           else meet (T, S) (Vartab.update_new (v, (S, T)) tye)
   399       | (Type (a, Ts), Type (b, Us)) =>
   400           if a <> b then raise TUNIFY
   401           else unifs (Ts, Us) tye
   402       | (T, U) => if T = U then tye else raise TUNIFY)
   403     and unifs (T :: Ts, U :: Us) tye = unifs (Ts, Us) (unif (T, U) tye)
   404       | unifs _ tye = tye;
   405   in (unif TU tyenv, ! tyvar_count) end;
   406 
   407 (*purely structural unification*)
   408 fun raw_unify (ty1, ty2) tye =
   409   (case (devar tye ty1, devar tye ty2) of
   410     (T as TVar (v, S1), U as TVar (w, S2)) =>
   411       if eq_ix (v, w) then
   412         if S1 = S2 then tye else tvar_clash v S1 S2
   413       else Vartab.update_new (w, (S2, T)) tye
   414   | (TVar (v, S), T) =>
   415       if occurs v tye T then raise TUNIFY
   416       else Vartab.update_new (v, (S, T)) tye
   417   | (T, TVar (v, S)) =>
   418       if occurs v tye T then raise TUNIFY
   419       else Vartab.update_new (v, (S, T)) tye
   420   | (Type (a, Ts), Type (b, Us)) =>
   421       if a <> b then raise TUNIFY
   422       else raw_unifys (Ts, Us) tye
   423   | (T, U) => if T = U then tye else raise TUNIFY)
   424 and raw_unifys (T :: Ts, U :: Us) tye = raw_unifys (Ts, Us) (raw_unify (T, U) tye)
   425   | raw_unifys _ tye = tye;
   426 
   427 (*fast unification filter*)
   428 fun could_unify (Type (a, Ts), Type (b, Us)) = a = b andalso could_unifys (Ts, Us)
   429   | could_unify (TFree (a, _), TFree (b, _)) = a = b
   430   | could_unify (TVar _, _) = true
   431   | could_unify (_, TVar _) = true
   432   | could_unify _ = false
   433 and could_unifys (T :: Ts, U :: Us) = could_unify (T, U) andalso could_unifys (Ts, Us)
   434   | could_unifys _ = true;
   435 
   436 
   437 (*equality with respect to a type environment*)
   438 fun eq_type tye (T, T') =
   439   (case (devar tye T, devar tye T') of
   440      (Type (s, Ts), Type (s', Ts')) =>
   441        s = s' andalso ListPair.all (eq_type tye) (Ts, Ts')
   442    | (U, U') => U = U');
   443 
   444 
   445 
   446 (** extend and merge type signatures **)
   447 
   448 (* arities *)
   449 
   450 local
   451 
   452 fun err_decl t decl = error ("Illegal " ^ str_of_decl decl ^ ": " ^ quote t);
   453 
   454 fun for_classes _ NONE = ""
   455   | for_classes pp (SOME (c1, c2)) =
   456       " for classes " ^ Pretty.string_of_classrel pp [c1, c2];
   457 
   458 fun err_conflict pp t cc (c, Ss) (c', Ss') =
   459   error ("Conflict of type arities" ^ for_classes pp cc ^ ":\n  " ^
   460     Pretty.string_of_arity pp (t, Ss, [c]) ^ " and\n  " ^
   461     Pretty.string_of_arity pp (t, Ss', [c']));
   462 
   463 fun coregular pp C t (c, Ss) ars =
   464   let
   465     fun conflict (c', Ss') =
   466       if Sorts.class_le C (c, c') andalso not (Sorts.sorts_le C (Ss, Ss')) then
   467         SOME ((c, c'), (c', Ss'))
   468       else if Sorts.class_le C (c', c) andalso not (Sorts.sorts_le C (Ss', Ss)) then
   469         SOME ((c', c), (c', Ss'))
   470       else NONE;
   471   in
   472     (case Library.get_first conflict ars of
   473       SOME ((c1, c2), (c', Ss')) => err_conflict pp t (SOME (c1, c2)) (c, Ss) (c', Ss')
   474     | NONE => (c, Ss) :: ars)
   475   end;
   476 
   477 fun insert pp C t (c, Ss) ars =
   478   (case AList.lookup (op =) ars c of
   479     NONE => coregular pp C t (c, Ss) ars
   480   | SOME Ss' =>
   481       if Sorts.sorts_le C (Ss, Ss') then ars
   482       else if Sorts.sorts_le C (Ss', Ss)
   483       then coregular pp C t (c, Ss) (ars \ (c, Ss'))
   484       else err_conflict pp t NONE (c, Ss) (c, Ss'));
   485 
   486 fun complete C (c, Ss) = map (rpair Ss) (Graph.all_succs C [c]);
   487 
   488 fun insert_arities pp classes (t, ars) arities =
   489   let val ars' =
   490     Symtab.lookup_multi arities t
   491     |> fold_rev (fold_rev (insert pp classes t)) (map (complete classes) ars)
   492   in Symtab.update (t, ars') arities end;
   493 
   494 fun insert_table pp classes = Symtab.fold (fn (t, ars) =>
   495   insert_arities pp classes (t, map (apsnd (map (Sorts.norm_sort classes))) ars));
   496 
   497 in
   498 
   499 fun add_arities pp decls tsig = tsig |> map_tsig (fn (classes, default, types, arities) =>
   500   let
   501     fun prep (t, Ss, S) =
   502       (case Symtab.lookup (snd types) t of
   503         SOME (LogicalType n, _) =>
   504           if length Ss = n then
   505             (t, map (cert_sort tsig) Ss, cert_sort tsig S)
   506               handle TYPE (msg, _, _) => error msg
   507           else error (bad_nargs t)
   508       | SOME (decl, _) => err_decl t decl
   509       | NONE => error (undecl_type t));
   510 
   511     val ars = decls |> map ((fn (t, Ss, S) => (t, map (fn c => (c, Ss)) S)) o prep);
   512     val arities' = fold (insert_arities pp (snd classes)) ars arities;
   513   in (classes, default, types, arities') end);
   514 
   515 fun rebuild_arities pp classes arities =
   516   Symtab.empty
   517   |> insert_table pp classes arities;
   518 
   519 fun merge_arities pp classes (arities1, arities2) =
   520   Symtab.empty
   521   |> insert_table pp classes arities1
   522   |> insert_table pp classes arities2;
   523 
   524 end;
   525 
   526 
   527 (* classes *)
   528 
   529 local
   530 
   531 fun err_dup_classes cs =
   532   error ("Duplicate declaration of class(es): " ^ commas_quote cs);
   533 
   534 fun err_cyclic_classes pp css =
   535   error (cat_lines (map (fn cs =>
   536     "Cycle in class relation: " ^ Pretty.string_of_classrel pp cs) css));
   537 
   538 fun add_class pp naming (c, cs) tsig =
   539   tsig |> map_tsig (fn ((space, classes), default, types, arities) =>
   540     let
   541       val c' = NameSpace.full naming c;
   542       val cs' = map (cert_class tsig) cs
   543         handle TYPE (msg, _, _) => error msg;
   544       val space' = space |> NameSpace.declare naming c';
   545       val classes' = classes |> Graph.new_node (c', stamp ())
   546         handle Graph.DUP dup => err_dup_classes [dup];
   547       val classes'' = classes' |> fold Graph.add_edge_trans_acyclic (map (pair c') cs')
   548         handle Graph.CYCLES css => err_cyclic_classes pp css;
   549     in ((space', classes''), default, types, arities) end);
   550 
   551 in
   552 
   553 val add_classes = fold oo add_class;
   554 
   555 fun add_classrel pp ps tsig =
   556   tsig |> map_tsig (fn ((space, classes), default, types, arities) =>
   557     let
   558       val ps' = map (pairself (cert_class tsig)) ps
   559         handle TYPE (msg, _, _) => error msg;
   560       val classes' = classes |> fold Graph.add_edge_trans_acyclic ps'
   561         handle Graph.CYCLES css => err_cyclic_classes pp css;
   562       val default' = default |> Sorts.norm_sort classes';
   563       val arities' = arities |> rebuild_arities pp classes';
   564     in ((space, classes'), default', types, arities') end);
   565 
   566 fun merge_classes pp ((space1, classes1), (space2, classes2)) =
   567   let
   568     val space = NameSpace.merge (space1, space2);
   569     val classes =
   570       Graph.merge_trans_acyclic (op =) (classes1, classes2)
   571         handle Graph.DUPS cs => err_dup_classes cs
   572           | Graph.CYCLES css => err_cyclic_classes pp css;
   573   in (space, classes) end;
   574 
   575 end;
   576 
   577 fun hide_classes fully cs = map_tsig (fn ((space, classes), default, types, arities) =>
   578   ((fold (NameSpace.hide fully) cs space, classes), default, types, arities));
   579 
   580 
   581 (* default sort *)
   582 
   583 fun set_defsort S tsig = tsig |> map_tsig (fn (classes, _, types, arities) =>
   584   (classes, cert_sort tsig S handle TYPE (msg, _, _) => error msg, types, arities));
   585 
   586 
   587 (* types *)
   588 
   589 local
   590 
   591 fun err_neg_args c =
   592   error ("Negative number of arguments in type constructor declaration: " ^ quote c);
   593 
   594 fun err_in_decls c decl decl' =
   595   let val s = str_of_decl decl and s' = str_of_decl decl' in
   596     if s = s' then error ("Duplicate declaration of " ^ s ^ ": " ^ quote c)
   597     else error ("Conflict of " ^ s ^ " with " ^ s' ^ ": " ^ quote c)
   598   end;
   599 
   600 fun new_decl naming (c, decl) (space, types) =
   601   let
   602     val c' = NameSpace.full naming c;
   603     val space' = NameSpace.declare naming c' space;
   604     val types' =
   605       (case Symtab.lookup types c' of
   606         SOME (decl', _) => err_in_decls c' decl decl'
   607       | NONE => Symtab.update (c', (decl, stamp ())) types);
   608   in (space', types') end;
   609 
   610 fun the_decl (_, types) = fst o the o Symtab.lookup types;
   611 
   612 fun change_types f = map_tsig (fn (classes, default, types, arities) =>
   613   (classes, default, f types, arities));
   614 
   615 fun syntactic types (Type (c, Ts)) =
   616       (case Symtab.lookup types c of SOME (Nonterminal, _) => true | _ => false)
   617         orelse exists (syntactic types) Ts
   618   | syntactic _ _ = false;
   619 
   620 fun add_abbrev naming (a, vs, rhs) tsig = tsig |> change_types (fn types =>
   621   let
   622     fun err msg =
   623       error (msg ^ "\nThe error(s) above occurred in type abbreviation: " ^ quote a);
   624     val rhs' = strip_sorts (no_tvars (cert_typ_syntax tsig rhs))
   625       handle TYPE (msg, _, _) => err msg;
   626   in
   627     (case duplicates vs of
   628       [] => []
   629     | dups => err ("Duplicate variables on lhs: " ^ commas_quote dups));
   630     (case gen_rems (op =) (map (#1 o #1) (typ_tvars rhs'), vs) of
   631       [] => []
   632     | extras => err ("Extra variables on rhs: " ^ commas_quote extras));
   633     types |> new_decl naming (a, Abbreviation (vs, rhs', syntactic (#2 types) rhs'))
   634   end);
   635 
   636 in
   637 
   638 fun add_types naming ps = change_types (fold (new_decl naming) (ps |> map (fn (c, n) =>
   639   if n < 0 then err_neg_args c else (c, LogicalType n))));
   640 
   641 val add_abbrevs = fold o add_abbrev;
   642 
   643 fun add_nonterminals naming = change_types o fold (new_decl naming) o map (rpair Nonterminal);
   644 
   645 fun merge_types (types1, types2) =
   646   NameSpace.merge_tables (Library.eq_snd (op =)) (types1, types2) handle Symtab.DUPS (d :: _) =>
   647     err_in_decls d (the_decl types1 d) (the_decl types2 d);
   648 
   649 end;
   650 
   651 fun hide_types fully cs = map_tsig (fn (classes, default, (space, types), arities) =>
   652   (classes, default, (fold (NameSpace.hide fully) cs space, types), arities));
   653 
   654 
   655 (* merge type signatures *)
   656 
   657 fun merge_tsigs pp (tsig1, tsig2) =
   658   let
   659     val (TSig {classes = classes1, default = default1, types = types1, arities = arities1,
   660       log_types = _, witness = _}) = tsig1;
   661     val (TSig {classes = classes2, default = default2, types = types2, arities = arities2,
   662       log_types = _, witness = _}) = tsig2;
   663 
   664     val classes' = merge_classes pp (classes1, classes2);
   665     val default' = Sorts.inter_sort (#2 classes') (default1, default2);
   666     val types' = merge_types (types1, types2);
   667     val arities' = merge_arities pp (#2 classes') (arities1, arities2);
   668   in build_tsig (classes', default', types', arities') end;
   669 
   670 end;