src/Pure/variable.ML
author wenzelm
Thu Aug 30 15:04:42 2007 +0200 (2007-08-30 ago)
changeset 24484 013b98b57b86
parent 22846 fb79144af9a3
child 24694 54f06f7feefa
permissions -rw-r--r--
maintain mode in context (get/set/restore_mode);
     1 (*  Title:      Pure/variable.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Fixed type/term variables and polymorphic term abbreviations.
     6 *)
     7 
     8 signature VARIABLE =
     9 sig
    10   val is_body: Proof.context -> bool
    11   val set_body: bool -> Proof.context -> Proof.context
    12   val restore_body: Proof.context -> Proof.context -> Proof.context
    13   val names_of: Proof.context -> Name.context
    14   val fixes_of: Proof.context -> (string * string) list
    15   val binds_of: Proof.context -> (typ * term) Vartab.table
    16   val constraints_of: Proof.context -> typ Vartab.table * sort Vartab.table
    17   val is_declared: Proof.context -> string -> bool
    18   val is_fixed: Proof.context -> string -> bool
    19   val newly_fixed: Proof.context -> Proof.context -> string -> bool
    20   val add_fixed: Proof.context -> term -> (string * typ) list -> (string * typ) list
    21   val default_type: Proof.context -> string -> typ option
    22   val def_type: Proof.context -> bool -> indexname -> typ option
    23   val def_sort: Proof.context -> indexname -> sort option
    24   val declare_constraints: term -> Proof.context -> Proof.context
    25   val declare_internal: term -> Proof.context -> Proof.context
    26   val declare_term: term -> Proof.context -> Proof.context
    27   val declare_prf: Proofterm.proof -> Proof.context -> Proof.context
    28   val declare_thm: thm -> Proof.context -> Proof.context
    29   val thm_context: thm -> Proof.context
    30   val variant_frees: Proof.context -> term list -> (string * 'a) list -> (string * 'a) list
    31   val add_binds: (indexname * term option) list -> Proof.context -> Proof.context
    32   val expand_binds: Proof.context -> term -> term
    33   val add_fixes: string list -> Proof.context -> string list * Proof.context
    34   val add_fixes_direct: string list -> Proof.context -> Proof.context
    35   val auto_fixes: term -> Proof.context -> Proof.context
    36   val variant_fixes: string list -> Proof.context -> string list * Proof.context
    37   val invent_types: sort list -> Proof.context -> (string * sort) list * Proof.context
    38   val export_terms: Proof.context -> Proof.context -> term list -> term list
    39   val exportT_terms: Proof.context -> Proof.context -> term list -> term list
    40   val exportT: Proof.context -> Proof.context -> thm list -> thm list
    41   val export_prf: Proof.context -> Proof.context -> Proofterm.proof -> Proofterm.proof
    42   val export: Proof.context -> Proof.context -> thm list -> thm list
    43   val export_morphism: Proof.context -> Proof.context -> morphism
    44   val importT_inst: term list -> Proof.context -> ((indexname * sort) * typ) list * Proof.context
    45   val import_inst: bool -> term list -> Proof.context ->
    46     (((indexname * sort) * typ) list * ((indexname * typ) * term) list) * Proof.context
    47   val importT_terms: term list -> Proof.context -> term list * Proof.context
    48   val import_terms: bool -> term list -> Proof.context -> term list * Proof.context
    49   val importT_thms: thm list -> Proof.context -> (ctyp list * thm list) * Proof.context
    50   val import_prf: bool -> Proofterm.proof -> Proof.context -> Proofterm.proof * Proof.context
    51   val import_thms: bool -> thm list -> Proof.context ->
    52     ((ctyp list * cterm list) * thm list) * Proof.context
    53   val tradeT: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    54   val trade: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    55   val focus: cterm -> Proof.context -> (cterm list * cterm) * Proof.context
    56   val focus_subgoal: int -> thm -> Proof.context -> (cterm list * cterm) * Proof.context
    57   val warn_extra_tfrees: Proof.context -> Proof.context -> unit
    58   val polymorphic: Proof.context -> term list -> term list
    59 end;
    60 
    61 structure Variable: VARIABLE =
    62 struct
    63 
    64 (** local context data **)
    65 
    66 datatype data = Data of
    67  {is_body: bool,                        (*inner body mode*)
    68   names: Name.context,                  (*type/term variable names*)
    69   fixes: (string * string) list,        (*term fixes -- extern/intern*)
    70   binds: (typ * term) Vartab.table,     (*term bindings*)
    71   type_occs: string list Symtab.table,  (*type variables -- possibly within term variables*)
    72   constraints:
    73     typ Vartab.table *                  (*type constraints*)
    74     sort Vartab.table};                 (*default sorts*)
    75 
    76 fun make_data (is_body, names, fixes, binds, type_occs, constraints) =
    77   Data {is_body = is_body, names = names, fixes = fixes, binds = binds,
    78     type_occs = type_occs, constraints = constraints};
    79 
    80 structure Data = ProofDataFun
    81 (
    82   type T = data;
    83   fun init thy =
    84     make_data (false, Name.context, [], Vartab.empty, Symtab.empty, (Vartab.empty, Vartab.empty));
    85 );
    86 
    87 fun map_data f =
    88   Data.map (fn Data {is_body, names, fixes, binds, type_occs, constraints} =>
    89     make_data (f (is_body, names, fixes, binds, type_occs, constraints)));
    90 
    91 fun map_names f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    92   (is_body, f names, fixes, binds, type_occs, constraints));
    93 
    94 fun map_fixes f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    95   (is_body, names, f fixes, binds, type_occs, constraints));
    96 
    97 fun map_binds f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    98   (is_body, names, fixes, f binds, type_occs, constraints));
    99 
   100 fun map_type_occs f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   101   (is_body, names, fixes, binds, f type_occs, constraints));
   102 
   103 fun map_constraints f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   104   (is_body, names, fixes, binds, type_occs, f constraints));
   105 
   106 fun rep_data ctxt = Data.get ctxt |> (fn Data args => args);
   107 
   108 val is_body = #is_body o rep_data;
   109 fun set_body b = map_data (fn (_, names, fixes, binds, type_occs, constraints) =>
   110   (b, names, fixes, binds, type_occs, constraints));
   111 fun restore_body ctxt = set_body (is_body ctxt);
   112 
   113 val names_of = #names o rep_data;
   114 val fixes_of = #fixes o rep_data;
   115 val binds_of = #binds o rep_data;
   116 val type_occs_of = #type_occs o rep_data;
   117 val constraints_of = #constraints o rep_data;
   118 
   119 val is_declared = Name.is_declared o names_of;
   120 fun is_fixed ctxt x = exists (fn (_, y) => x = y) (fixes_of ctxt);
   121 fun newly_fixed inner outer x = is_fixed inner x andalso not (is_fixed outer x);
   122 
   123 fun add_fixed ctxt = Term.fold_aterms
   124   (fn Free (x, T) => if is_fixed ctxt x then insert (op =) (x, T) else I | _ => I);
   125 
   126 
   127 
   128 (** declarations **)
   129 
   130 (* default sorts and types *)
   131 
   132 fun default_type ctxt x = Vartab.lookup (#1 (constraints_of ctxt)) (x, ~1);
   133 
   134 fun def_type ctxt pattern xi =
   135   let val {binds, constraints = (types, _), ...} = rep_data ctxt in
   136     (case Vartab.lookup types xi of
   137       NONE =>
   138         if pattern then NONE
   139         else Vartab.lookup binds xi |> Option.map (TypeInfer.polymorphicT o #1)
   140     | some => some)
   141   end;
   142 
   143 val def_sort = Vartab.lookup o #2 o constraints_of;
   144 
   145 
   146 (* names *)
   147 
   148 val declare_type_names = map_names o
   149   fold_types (fold_atyps (fn TFree (a, _) => Name.declare a | _ => I));
   150 
   151 fun declare_names t =
   152   declare_type_names t #>
   153   map_names (fold_aterms (fn Free (x, _) => Name.declare x | _ => I) t);
   154 
   155 
   156 (* type occurrences *)
   157 
   158 val decl_type_occs = fold_term_types
   159   (fn Free (x, _) => fold_atyps (fn TFree (a, _) => Symtab.insert_list (op =) (a, x) | _ => I)
   160     | _ => fold_atyps (fn TFree (a, _) => Symtab.default (a, []) | _ => I));
   161 
   162 val declare_type_occs = map_type_occs o decl_type_occs;
   163 
   164 
   165 (* constraints *)
   166 
   167 fun constrain_tvar (xi, S) =
   168   if S = dummyS then Vartab.delete_safe xi else Vartab.update (xi, S);
   169 
   170 fun declare_constraints t = map_constraints (fn (types, sorts) =>
   171   let
   172     val types' = fold_aterms
   173       (fn Free (x, T) => Vartab.update ((x, ~1), T)
   174         | Var v => Vartab.update v
   175         | _ => I) t types;
   176     val sorts' = fold_types (fold_atyps
   177       (fn TFree (x, S) => constrain_tvar ((x, ~1), S)
   178         | TVar v => constrain_tvar v
   179         | _ => I)) t sorts;
   180   in (types', sorts') end)
   181   #> declare_type_names t;
   182 
   183 
   184 (* common declarations *)
   185 
   186 fun declare_internal t =
   187   declare_names t #>
   188   declare_type_occs t;
   189 
   190 fun declare_term t =
   191   declare_internal t #>
   192   declare_constraints t;
   193 
   194 val declare_prf = Proofterm.fold_proof_terms declare_internal (declare_internal o Logic.mk_type);
   195 
   196 val declare_thm = Thm.fold_terms declare_internal;
   197 fun thm_context th = declare_thm th (ProofContext.init (Thm.theory_of_thm th));
   198 
   199 
   200 (* renaming term/type frees *)
   201 
   202 fun variant_frees ctxt ts frees =
   203   let
   204     val names = names_of (fold declare_names ts ctxt);
   205     val xs = fst (Name.variants (map #1 frees) names);
   206   in xs ~~ map snd frees end;
   207 
   208 
   209 
   210 (** term bindings **)
   211 
   212 fun add_bind (xi, NONE) = map_binds (Vartab.delete_safe xi)
   213   | add_bind ((x, i), SOME t) =
   214       let
   215         val T = Term.fastype_of t;
   216         val t' =
   217           if null (Term.hidden_polymorphism t T) then t
   218           else Var ((x ^ "_has_extra_type_vars_on_rhs", i), T);
   219       in declare_term t' #> map_binds (Vartab.update ((x, i), (T, t'))) end;
   220 
   221 val add_binds = fold add_bind;
   222 
   223 fun expand_binds ctxt =
   224   let
   225     val binds = binds_of ctxt;
   226     val get = fn Var (xi, _) => Vartab.lookup binds xi | _ => NONE;
   227   in Envir.beta_norm o Envir.expand_term get end;
   228 
   229 
   230 
   231 (** fixes **)
   232 
   233 local
   234 
   235 fun no_dups [] = ()
   236   | no_dups dups = error ("Duplicate fixed variable(s): " ^ commas_quote dups);
   237 
   238 fun new_fixes names' xs xs' =
   239   map_names (K names') #>
   240   map_fixes (fn fixes => (rev (xs ~~ xs') @ fixes)) #>
   241   fold (declare_constraints o Syntax.free) xs' #>
   242   pair xs';
   243 
   244 in
   245 
   246 fun add_fixes xs ctxt =
   247   let
   248     val _ =
   249       (case filter (can Name.dest_skolem) xs of [] => ()
   250       | bads => error ("Illegal internal Skolem constant(s): " ^ commas_quote bads));
   251     val _ = no_dups (duplicates (op =) xs);
   252     val (ys, zs) = split_list (fixes_of ctxt);
   253     val names = names_of ctxt;
   254     val (xs', names') =
   255       if is_body ctxt then Name.variants xs names |>> map Name.skolem
   256       else (no_dups (xs inter_string ys); no_dups (xs inter_string zs);
   257         (xs, fold Name.declare xs names));
   258   in ctxt |> new_fixes names' xs xs' end;
   259 
   260 fun variant_fixes raw_xs ctxt =
   261   let
   262     val names = names_of ctxt;
   263     val xs = map Name.clean raw_xs;
   264     val (xs', names') = Name.variants xs names |>> map Name.skolem;
   265   in ctxt |> new_fixes names' xs xs' end;
   266 
   267 end;
   268 
   269 
   270 fun add_fixes_direct xs ctxt = ctxt
   271   |> set_body false
   272   |> (snd o add_fixes xs)
   273   |> restore_body ctxt;
   274 
   275 fun fix_frees t ctxt = ctxt
   276   |> add_fixes_direct
   277       (rev (fold_aterms (fn Free (x, _) =>
   278         if is_fixed ctxt x then I else insert (op =) x | _ => I) t []));
   279 
   280 fun auto_fixes t ctxt =
   281   (if is_body ctxt then ctxt else fix_frees t ctxt)
   282   |> declare_term t;
   283 
   284 fun invent_types Ss ctxt =
   285   let
   286     val tfrees = Name.invents (names_of ctxt) "'a" (length Ss) ~~ Ss;
   287     val ctxt' = fold (declare_constraints o Logic.mk_type o TFree) tfrees ctxt;
   288   in (tfrees, ctxt') end;
   289 
   290 
   291 
   292 (** export -- generalize type/term variables (beware of closure sizes) **)
   293 
   294 fun export_inst inner outer =
   295   let
   296     val declared_outer = is_declared outer;
   297     val fixes_inner = fixes_of inner;
   298     val fixes_outer = fixes_of outer;
   299 
   300     val gen_fixes = map #2 (Library.take (length fixes_inner - length fixes_outer, fixes_inner));
   301     val still_fixed = not o member (op =) gen_fixes;
   302 
   303     val type_occs_inner = type_occs_of inner;
   304     fun gen_fixesT ts =
   305       Symtab.fold (fn (a, xs) =>
   306         if declared_outer a orelse exists still_fixed xs
   307         then I else cons a) (fold decl_type_occs ts type_occs_inner) [];
   308   in (gen_fixesT, gen_fixes) end;
   309 
   310 fun exportT_inst inner outer = #1 (export_inst inner outer);
   311 
   312 fun exportT_terms inner outer =
   313   let val mk_tfrees = exportT_inst inner outer in
   314     fn ts => ts |> map
   315       (TermSubst.generalize (mk_tfrees ts, [])
   316         (fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1))
   317   end;
   318 
   319 fun export_terms inner outer =
   320   let val (mk_tfrees, tfrees) = export_inst inner outer in
   321     fn ts => ts |> map
   322       (TermSubst.generalize (mk_tfrees ts, tfrees)
   323         (fold Term.maxidx_term ts ~1 + 1))
   324   end;
   325 
   326 fun export_prf inner outer prf =
   327   let
   328     val (mk_tfrees, frees) = export_inst (declare_prf prf inner) outer;
   329     val tfrees = mk_tfrees [];
   330     val idx = Proofterm.maxidx_proof prf ~1 + 1;
   331     val gen_term = TermSubst.generalize_option (tfrees, frees) idx;
   332     val gen_typ = TermSubst.generalizeT_option tfrees idx;
   333   in Proofterm.map_proof_terms_option gen_term gen_typ prf end;
   334 
   335 
   336 fun gen_export (mk_tfrees, frees) ths =
   337   let
   338     val tfrees = mk_tfrees (map Thm.full_prop_of ths);
   339     val maxidx = fold Thm.maxidx_thm ths ~1;
   340   in map (Thm.generalize (tfrees, frees) (maxidx + 1)) ths end;
   341 
   342 fun exportT inner outer = gen_export (exportT_inst inner outer, []);
   343 fun export inner outer = gen_export (export_inst inner outer);
   344 
   345 fun export_morphism inner outer =
   346   let
   347     val fact = export inner outer;
   348     val term = singleton (export_terms inner outer);
   349     val typ = Logic.type_map term;
   350   in Morphism.morphism {name = I, var = I, typ = typ, term = term, fact = fact} end;
   351 
   352 
   353 (** import -- fix schematic type/term variables **)
   354 
   355 fun importT_inst ts ctxt =
   356   let
   357     val tvars = rev (fold Term.add_tvars ts []);
   358     val (tfrees, ctxt') = invent_types (map #2 tvars) ctxt;
   359   in (tvars ~~ map TFree tfrees, ctxt') end;
   360 
   361 fun import_inst is_open ts ctxt =
   362   let
   363     val ren = if is_open then I else Name.internal;
   364     val (instT, ctxt') = importT_inst ts ctxt;
   365     val vars = map (apsnd (TermSubst.instantiateT instT)) (rev (fold Term.add_vars ts []));
   366     val (xs, ctxt'') = variant_fixes (map (ren o #1 o #1) vars) ctxt';
   367     val inst = vars ~~ map Free (xs ~~ map #2 vars);
   368   in ((instT, inst), ctxt'') end;
   369 
   370 fun importT_terms ts ctxt =
   371   let val (instT, ctxt') = importT_inst ts ctxt
   372   in (map (TermSubst.instantiate (instT, [])) ts, ctxt') end;
   373 
   374 fun import_terms is_open ts ctxt =
   375   let val (inst, ctxt') = import_inst is_open ts ctxt
   376   in (map (TermSubst.instantiate inst) ts, ctxt') end;
   377 
   378 fun importT_thms ths ctxt =
   379   let
   380     val thy = ProofContext.theory_of ctxt;
   381     val certT = Thm.ctyp_of thy;
   382     val (instT, ctxt') = importT_inst (map Thm.full_prop_of ths) ctxt;
   383     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   384     val ths' = map (Thm.instantiate (instT', [])) ths;
   385   in ((map #2 instT', ths'), ctxt') end;
   386 
   387 fun import_prf is_open prf ctxt =
   388   let
   389     val ts = rev (Proofterm.fold_proof_terms cons (cons o Logic.mk_type) prf []);
   390     val (insts, ctxt') = import_inst is_open ts ctxt;
   391   in (Proofterm.instantiate insts prf, ctxt') end;
   392 
   393 fun import_thms is_open ths ctxt =
   394   let
   395     val thy = ProofContext.theory_of ctxt;
   396     val cert = Thm.cterm_of thy;
   397     val certT = Thm.ctyp_of thy;
   398     val ((instT, inst), ctxt') = import_inst is_open (map Thm.full_prop_of ths) ctxt;
   399     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   400     val inst' = map (fn (v, t) => (cert (Var v), cert t)) inst;
   401     val ths' = map (Thm.instantiate (instT', inst')) ths;
   402   in (((map #2 instT', map #2 inst'), ths'), ctxt') end;
   403 
   404 
   405 (* import/export *)
   406 
   407 fun gen_trade imp exp f ctxt ths =
   408   let val ((_, ths'), ctxt') = imp ths ctxt
   409   in exp ctxt' ctxt (f ctxt' ths') end;
   410 
   411 val tradeT = gen_trade importT_thms exportT;
   412 val trade = gen_trade (import_thms true) export;
   413 
   414 
   415 (* focus on outermost parameters *)
   416 
   417 fun forall_elim_prop t prop =
   418   Thm.beta_conversion false (Thm.capply (Thm.dest_arg prop) t)
   419   |> Thm.cprop_of |> Thm.dest_arg;
   420 
   421 fun focus goal ctxt =
   422   let
   423     val cert = Thm.cterm_of (Thm.theory_of_cterm goal);
   424     val t = Thm.term_of goal;
   425     val ps = Term.variant_frees t (Term.strip_all_vars t);   (*as they are printed :-*)
   426     val (xs, Ts) = split_list ps;
   427     val (xs', ctxt') = variant_fixes xs ctxt;
   428     val ps' = ListPair.map (cert o Free) (xs', Ts);
   429     val goal' = fold forall_elim_prop ps' goal;
   430   in ((ps', goal'), ctxt') end;
   431 
   432 fun focus_subgoal i st =
   433   let
   434     val all_vars = Thm.fold_terms Term.add_vars st [];
   435     val no_binds = map (fn (xi, _) => (xi, NONE)) all_vars;
   436   in
   437     add_binds no_binds #>
   438     fold (declare_constraints o Var) all_vars #>
   439     focus (Thm.cprem_of st i)
   440   end;
   441 
   442 
   443 
   444 (** implicit polymorphism **)
   445 
   446 (* warn_extra_tfrees *)
   447 
   448 fun warn_extra_tfrees ctxt1 ctxt2 =
   449   let
   450     fun occs_typ a = Term.exists_subtype (fn TFree (b, _) => a = b | _ => false);
   451     fun occs_free a x =
   452       (case def_type ctxt1 false (x, ~1) of
   453         SOME T => if occs_typ a T then I else cons (a, x)
   454       | NONE => cons (a, x));
   455 
   456     val occs1 = type_occs_of ctxt1;
   457     val occs2 = type_occs_of ctxt2;
   458     val extras = Symtab.fold (fn (a, xs) =>
   459       if Symtab.defined occs1 a then I else fold (occs_free a) xs) occs2 [];
   460     val tfrees = map #1 extras |> sort_distinct string_ord;
   461     val frees = map #2 extras |> sort_distinct string_ord;
   462   in
   463     if null extras then ()
   464     else warning ("Introduced fixed type variable(s): " ^ commas tfrees ^ " in " ^
   465       space_implode " or " (map quote frees))
   466   end;
   467 
   468 
   469 (* polymorphic terms *)
   470 
   471 fun polymorphic ctxt ts =
   472   let
   473     val ctxt' = fold declare_term ts ctxt;
   474     val occs = type_occs_of ctxt;
   475     val occs' = type_occs_of ctxt';
   476     val types = Symtab.fold (fn (a, _) => if Symtab.defined occs a then I else cons a) occs' [];
   477     val idx = fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1;
   478   in map (TermSubst.generalize (types, []) idx) ts end;
   479 
   480 end;