src/HOL/Imperative_HOL/Array.thy
author haftmann
Tue Jul 13 16:00:56 2010 +0200 (2010-07-13 ago)
changeset 37804 0145e59c1f6c
parent 37803 582d0fbd201e
child 37805 0f797d586ce5
permissions -rw-r--r--
qualified names for (almost) all array operations
     1 (*  Title:      HOL/Imperative_HOL/Array.thy
     2     Author:     John Matthews, Galois Connections; Alexander Krauss, Lukas Bulwahn & Florian Haftmann, TU Muenchen
     3 *)
     4 
     5 header {* Monadic arrays *}
     6 
     7 theory Array
     8 imports Heap_Monad
     9 begin
    10 
    11 subsection {* Primitives *}
    12 
    13 definition present :: "heap \<Rightarrow> 'a\<Colon>heap array \<Rightarrow> bool" where
    14   "present h a \<longleftrightarrow> addr_of_array a < lim h"
    15 
    16 definition (*FIXME get :: "heap \<Rightarrow> 'a\<Colon>heap array \<Rightarrow> 'a list" where*)
    17   get_array :: "'a\<Colon>heap array \<Rightarrow> heap \<Rightarrow> 'a list" where
    18   "get_array a h = map from_nat (arrays h (TYPEREP('a)) (addr_of_array a))"
    19 
    20 definition set :: "'a\<Colon>heap array \<Rightarrow> 'a list \<Rightarrow> heap \<Rightarrow> heap" where
    21   "set a x = arrays_update (\<lambda>h. h(TYPEREP('a) := ((h(TYPEREP('a))) (addr_of_array a:=map to_nat x))))"
    22 
    23 definition alloc :: "'a list \<Rightarrow> heap \<Rightarrow> 'a\<Colon>heap array \<times> heap" where
    24   "alloc xs h = (let
    25      l = lim h;
    26      r = Array l;
    27      h'' = set r xs (h\<lparr>lim := l + 1\<rparr>)
    28    in (r, h''))"
    29 
    30 definition length :: "heap \<Rightarrow> 'a\<Colon>heap array \<Rightarrow> nat" where
    31   "length h a = List.length (get_array a h)"
    32   
    33 definition update :: "'a\<Colon>heap array \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> heap \<Rightarrow> heap" where
    34   "update a i x h = set a ((get_array a h)[i:=x]) h"
    35 
    36 definition noteq :: "'a\<Colon>heap array \<Rightarrow> 'b\<Colon>heap array \<Rightarrow> bool" (infix "=!!=" 70) where
    37   "r =!!= s \<longleftrightarrow> TYPEREP('a) \<noteq> TYPEREP('b) \<or> addr_of_array r \<noteq> addr_of_array s"
    38 
    39 
    40 subsection {* Monad operations *}
    41 
    42 definition new :: "nat \<Rightarrow> 'a\<Colon>heap \<Rightarrow> 'a array Heap" where
    43   [code del]: "new n x = Heap_Monad.heap (alloc (replicate n x))"
    44 
    45 definition of_list :: "'a\<Colon>heap list \<Rightarrow> 'a array Heap" where
    46   [code del]: "of_list xs = Heap_Monad.heap (alloc xs)"
    47 
    48 definition make :: "nat \<Rightarrow> (nat \<Rightarrow> 'a\<Colon>heap) \<Rightarrow> 'a array Heap" where
    49   [code del]: "make n f = Heap_Monad.heap (alloc (map f [0 ..< n]))"
    50 
    51 definition len :: "'a\<Colon>heap array \<Rightarrow> nat Heap" where
    52   [code del]: "len a = Heap_Monad.tap (\<lambda>h. length h a)"
    53 
    54 definition nth :: "'a\<Colon>heap array \<Rightarrow> nat \<Rightarrow> 'a Heap" where
    55   [code del]: "nth a i = Heap_Monad.guard (\<lambda>h. i < length h a)
    56     (\<lambda>h. (get_array a h ! i, h))"
    57 
    58 definition upd :: "nat \<Rightarrow> 'a \<Rightarrow> 'a\<Colon>heap array \<Rightarrow> 'a\<Colon>heap array Heap" where
    59   [code del]: "upd i x a = Heap_Monad.guard (\<lambda>h. i < length h a)
    60     (\<lambda>h. (a, update a i x h))"
    61 
    62 definition map_entry :: "nat \<Rightarrow> ('a\<Colon>heap \<Rightarrow> 'a) \<Rightarrow> 'a array \<Rightarrow> 'a array Heap" where
    63   [code del]: "map_entry i f a = Heap_Monad.guard (\<lambda>h. i < length h a)
    64     (\<lambda>h. (a, update a i (f (get_array a h ! i)) h))"
    65 
    66 definition swap :: "nat \<Rightarrow> 'a \<Rightarrow> 'a\<Colon>heap array \<Rightarrow> 'a Heap" where
    67   [code del]: "swap i x a = Heap_Monad.guard (\<lambda>h. i < length h a)
    68     (\<lambda>h. (get_array a h ! i, update a i x h))"
    69 
    70 definition freeze :: "'a\<Colon>heap array \<Rightarrow> 'a list Heap" where
    71   [code del]: "freeze a = Heap_Monad.tap (\<lambda>h. get_array a h)"
    72 
    73 
    74 subsection {* Properties *}
    75 
    76 text {* FIXME: Does there exist a "canonical" array axiomatisation in
    77 the literature?  *}
    78 
    79 text {* Primitives *}
    80 
    81 lemma noteq_arrs_sym: "a =!!= b \<Longrightarrow> b =!!= a"
    82   and unequal_arrs [simp]: "a \<noteq> a' \<longleftrightarrow> a =!!= a'"
    83   unfolding noteq_def by auto
    84 
    85 lemma noteq_arrs_irrefl: "r =!!= r \<Longrightarrow> False"
    86   unfolding noteq_def by auto
    87 
    88 lemma present_new_arr: "present h a \<Longrightarrow> a =!!= fst (alloc xs h)"
    89   by (simp add: present_def noteq_def alloc_def Let_def)
    90 
    91 lemma array_get_set_eq [simp]: "get_array r (set r x h) = x"
    92   by (simp add: get_array_def set_def o_def)
    93 
    94 lemma array_get_set_neq [simp]: "r =!!= s \<Longrightarrow> get_array r (set s x h) = get_array r h"
    95   by (simp add: noteq_def get_array_def set_def)
    96 
    97 lemma set_array_same [simp]:
    98   "set r x (set r y h) = set r x h"
    99   by (simp add: set_def)
   100 
   101 lemma array_set_set_swap:
   102   "r =!!= r' \<Longrightarrow> set r x (set r' x' h) = set r' x' (set r x h)"
   103   by (simp add: Let_def expand_fun_eq noteq_def set_def)
   104 
   105 lemma get_array_update_eq [simp]:
   106   "get_array a (update a i v h) = (get_array a h) [i := v]"
   107   by (simp add: update_def)
   108 
   109 lemma nth_update_array_neq_array [simp]:
   110   "a =!!= b \<Longrightarrow> get_array a (update b j v h) ! i = get_array a h ! i"
   111   by (simp add: update_def noteq_def)
   112 
   113 lemma get_arry_array_update_elem_neqIndex [simp]:
   114   "i \<noteq> j \<Longrightarrow> get_array a (update a j v h) ! i = get_array a h ! i"
   115   by simp
   116 
   117 lemma length_update [simp]: 
   118   "length (update b i v h) = length h"
   119   by (simp add: update_def length_def set_def get_array_def expand_fun_eq)
   120 
   121 lemma update_swap_neqArray:
   122   "a =!!= a' \<Longrightarrow> 
   123   update a i v (update a' i' v' h) 
   124   = update a' i' v' (update a i v h)"
   125 apply (unfold update_def)
   126 apply simp
   127 apply (subst array_set_set_swap, assumption)
   128 apply (subst array_get_set_neq)
   129 apply (erule noteq_arrs_sym)
   130 apply (simp)
   131 done
   132 
   133 lemma update_swap_neqIndex:
   134   "\<lbrakk> i \<noteq> i' \<rbrakk> \<Longrightarrow> update a i v (update a i' v' h) = update a i' v' (update a i v h)"
   135   by (auto simp add: update_def array_set_set_swap list_update_swap)
   136 
   137 lemma get_array_init_array_list:
   138   "get_array (fst (alloc ls h)) (snd (alloc ls' h)) = ls'"
   139   by (simp add: Let_def split_def alloc_def)
   140 
   141 lemma set_array:
   142   "set (fst (alloc ls h))
   143      new_ls (snd (alloc ls h))
   144        = snd (alloc new_ls h)"
   145   by (simp add: Let_def split_def alloc_def)
   146 
   147 lemma array_present_update [simp]: 
   148   "present (update b i v h) = present h"
   149   by (simp add: update_def present_def set_def get_array_def expand_fun_eq)
   150 
   151 lemma array_present_array [simp]:
   152   "present (snd (alloc xs h)) (fst (alloc xs h))"
   153   by (simp add: present_def alloc_def set_def Let_def)
   154 
   155 lemma not_array_present_array [simp]:
   156   "\<not> present h (fst (alloc xs h))"
   157   by (simp add: present_def alloc_def Let_def)
   158 
   159 
   160 text {* Monad operations *}
   161 
   162 lemma execute_new [execute_simps]:
   163   "execute (new n x) h = Some (alloc (replicate n x) h)"
   164   by (simp add: new_def execute_simps)
   165 
   166 lemma success_newI [success_intros]:
   167   "success (new n x) h"
   168   by (auto intro: success_intros simp add: new_def)
   169 
   170 lemma crel_newI [crel_intros]:
   171   assumes "(a, h') = alloc (replicate n x) h"
   172   shows "crel (new n x) h h' a"
   173   by (rule crelI) (simp add: assms execute_simps)
   174 
   175 lemma crel_newE [crel_elims]:
   176   assumes "crel (new n x) h h' r"
   177   obtains "r = fst (alloc (replicate n x) h)" "h' = snd (alloc (replicate n x) h)" 
   178     "get_array r h' = replicate n x" "present h' r" "\<not> present h r"
   179   using assms by (rule crelE) (simp add: get_array_init_array_list execute_simps)
   180 
   181 lemma execute_of_list [execute_simps]:
   182   "execute (of_list xs) h = Some (alloc xs h)"
   183   by (simp add: of_list_def execute_simps)
   184 
   185 lemma success_of_listI [success_intros]:
   186   "success (of_list xs) h"
   187   by (auto intro: success_intros simp add: of_list_def)
   188 
   189 lemma crel_of_listI [crel_intros]:
   190   assumes "(a, h') = alloc xs h"
   191   shows "crel (of_list xs) h h' a"
   192   by (rule crelI) (simp add: assms execute_simps)
   193 
   194 lemma crel_of_listE [crel_elims]:
   195   assumes "crel (of_list xs) h h' r"
   196   obtains "r = fst (alloc xs h)" "h' = snd (alloc xs h)" 
   197     "get_array r h' = xs" "present h' r" "\<not> present h r"
   198   using assms by (rule crelE) (simp add: get_array_init_array_list execute_simps)
   199 
   200 lemma execute_make [execute_simps]:
   201   "execute (make n f) h = Some (alloc (map f [0 ..< n]) h)"
   202   by (simp add: make_def execute_simps)
   203 
   204 lemma success_makeI [success_intros]:
   205   "success (make n f) h"
   206   by (auto intro: success_intros simp add: make_def)
   207 
   208 lemma crel_makeI [crel_intros]:
   209   assumes "(a, h') = alloc (map f [0 ..< n]) h"
   210   shows "crel (make n f) h h' a"
   211   by (rule crelI) (simp add: assms execute_simps)
   212 
   213 lemma crel_makeE [crel_elims]:
   214   assumes "crel (make n f) h h' r"
   215   obtains "r = fst (alloc (map f [0 ..< n]) h)" "h' = snd (alloc (map f [0 ..< n]) h)" 
   216     "get_array r h' = map f [0 ..< n]" "present h' r" "\<not> present h r"
   217   using assms by (rule crelE) (simp add: get_array_init_array_list execute_simps)
   218 
   219 lemma execute_len [execute_simps]:
   220   "execute (len a) h = Some (length h a, h)"
   221   by (simp add: len_def execute_simps)
   222 
   223 lemma success_lenI [success_intros]:
   224   "success (len a) h"
   225   by (auto intro: success_intros simp add: len_def)
   226 
   227 lemma crel_lengthI [crel_intros]:
   228   assumes "h' = h" "r = length h a"
   229   shows "crel (len a) h h' r"
   230   by (rule crelI) (simp add: assms execute_simps)
   231 
   232 lemma crel_lengthE [crel_elims]:
   233   assumes "crel (len a) h h' r"
   234   obtains "r = length h' a" "h' = h" 
   235   using assms by (rule crelE) (simp add: execute_simps)
   236 
   237 lemma execute_nth [execute_simps]:
   238   "i < length h a \<Longrightarrow>
   239     execute (nth a i) h = Some (get_array a h ! i, h)"
   240   "i \<ge> length h a \<Longrightarrow> execute (nth a i) h = None"
   241   by (simp_all add: nth_def execute_simps)
   242 
   243 lemma success_nthI [success_intros]:
   244   "i < length h a \<Longrightarrow> success (nth a i) h"
   245   by (auto intro: success_intros simp add: nth_def)
   246 
   247 lemma crel_nthI [crel_intros]:
   248   assumes "i < length h a" "h' = h" "r = get_array a h ! i"
   249   shows "crel (nth a i) h h' r"
   250   by (rule crelI) (insert assms, simp add: execute_simps)
   251 
   252 lemma crel_nthE [crel_elims]:
   253   assumes "crel (nth a i) h h' r"
   254   obtains "i < length h a" "r = get_array a h ! i" "h' = h"
   255   using assms by (rule crelE)
   256     (erule successE, cases "i < length h a", simp_all add: execute_simps)
   257 
   258 lemma execute_upd [execute_simps]:
   259   "i < length h a \<Longrightarrow>
   260     execute (upd i x a) h = Some (a, update a i x h)"
   261   "i \<ge> length h a \<Longrightarrow> execute (upd i x a) h = None"
   262   by (simp_all add: upd_def execute_simps)
   263 
   264 lemma success_updI [success_intros]:
   265   "i < length h a \<Longrightarrow> success (upd i x a) h"
   266   by (auto intro: success_intros simp add: upd_def)
   267 
   268 lemma crel_updI [crel_intros]:
   269   assumes "i < length h a" "h' = update a i v h"
   270   shows "crel (upd i v a) h h' a"
   271   by (rule crelI) (insert assms, simp add: execute_simps)
   272 
   273 lemma crel_updE [crel_elims]:
   274   assumes "crel (upd i v a) h h' r"
   275   obtains "r = a" "h' = update a i v h" "i < length h a"
   276   using assms by (rule crelE)
   277     (erule successE, cases "i < length h a", simp_all add: execute_simps)
   278 
   279 lemma execute_map_entry [execute_simps]:
   280   "i < length h a \<Longrightarrow>
   281    execute (map_entry i f a) h =
   282       Some (a, update a i (f (get_array a h ! i)) h)"
   283   "i \<ge> length h a \<Longrightarrow> execute (map_entry i f a) h = None"
   284   by (simp_all add: map_entry_def execute_simps)
   285 
   286 lemma success_map_entryI [success_intros]:
   287   "i < length h a \<Longrightarrow> success (map_entry i f a) h"
   288   by (auto intro: success_intros simp add: map_entry_def)
   289 
   290 lemma crel_map_entryI [crel_intros]:
   291   assumes "i < length h a" "h' = update a i (f (get_array a h ! i)) h" "r = a"
   292   shows "crel (map_entry i f a) h h' r"
   293   by (rule crelI) (insert assms, simp add: execute_simps)
   294 
   295 lemma crel_map_entryE [crel_elims]:
   296   assumes "crel (map_entry i f a) h h' r"
   297   obtains "r = a" "h' = update a i (f (get_array a h ! i)) h" "i < length h a"
   298   using assms by (rule crelE)
   299     (erule successE, cases "i < length h a", simp_all add: execute_simps)
   300 
   301 lemma execute_swap [execute_simps]:
   302   "i < length h a \<Longrightarrow>
   303    execute (swap i x a) h =
   304       Some (get_array a h ! i, update a i x h)"
   305   "i \<ge> length h a \<Longrightarrow> execute (swap i x a) h = None"
   306   by (simp_all add: swap_def execute_simps)
   307 
   308 lemma success_swapI [success_intros]:
   309   "i < length h a \<Longrightarrow> success (swap i x a) h"
   310   by (auto intro: success_intros simp add: swap_def)
   311 
   312 lemma crel_swapI [crel_intros]:
   313   assumes "i < length h a" "h' = update a i x h" "r = get_array a h ! i"
   314   shows "crel (swap i x a) h h' r"
   315   by (rule crelI) (insert assms, simp add: execute_simps)
   316 
   317 lemma crel_swapE [crel_elims]:
   318   assumes "crel (swap i x a) h h' r"
   319   obtains "r = get_array a h ! i" "h' = update a i x h" "i < length h a"
   320   using assms by (rule crelE)
   321     (erule successE, cases "i < length h a", simp_all add: execute_simps)
   322 
   323 lemma execute_freeze [execute_simps]:
   324   "execute (freeze a) h = Some (get_array a h, h)"
   325   by (simp add: freeze_def execute_simps)
   326 
   327 lemma success_freezeI [success_intros]:
   328   "success (freeze a) h"
   329   by (auto intro: success_intros simp add: freeze_def)
   330 
   331 lemma crel_freezeI [crel_intros]:
   332   assumes "h' = h" "r = get_array a h"
   333   shows "crel (freeze a) h h' r"
   334   by (rule crelI) (insert assms, simp add: execute_simps)
   335 
   336 lemma crel_freezeE [crel_elims]:
   337   assumes "crel (freeze a) h h' r"
   338   obtains "h' = h" "r = get_array a h"
   339   using assms by (rule crelE) (simp add: execute_simps)
   340 
   341 lemma upd_return:
   342   "upd i x a \<guillemotright> return a = upd i x a"
   343   by (rule Heap_eqI) (simp add: bind_def guard_def upd_def execute_simps)
   344 
   345 lemma array_make:
   346   "new n x = make n (\<lambda>_. x)"
   347   by (rule Heap_eqI) (simp add: map_replicate_trivial execute_simps)
   348 
   349 lemma array_of_list_make:
   350   "of_list xs = make (List.length xs) (\<lambda>n. xs ! n)"
   351   by (rule Heap_eqI) (simp add: map_nth execute_simps)
   352 
   353 hide_const (open) present (*get*) set alloc length update noteq new of_list make len nth upd map_entry swap freeze
   354 
   355 
   356 subsection {* Code generator setup *}
   357 
   358 subsubsection {* Logical intermediate layer *}
   359 
   360 definition new' where
   361   [code del]: "new' = Array.new o Code_Numeral.nat_of"
   362 
   363 lemma [code]:
   364   "Array.new = new' o Code_Numeral.of_nat"
   365   by (simp add: new'_def o_def)
   366 
   367 definition of_list' where
   368   [code del]: "of_list' i xs = Array.of_list (take (Code_Numeral.nat_of i) xs)"
   369 
   370 lemma [code]:
   371   "Array.of_list xs = of_list' (Code_Numeral.of_nat (List.length xs)) xs"
   372   by (simp add: of_list'_def)
   373 
   374 definition make' where
   375   [code del]: "make' i f = Array.make (Code_Numeral.nat_of i) (f o Code_Numeral.of_nat)"
   376 
   377 lemma [code]:
   378   "Array.make n f = make' (Code_Numeral.of_nat n) (f o Code_Numeral.nat_of)"
   379   by (simp add: make'_def o_def)
   380 
   381 definition len' where
   382   [code del]: "len' a = Array.len a \<guillemotright>= (\<lambda>n. return (Code_Numeral.of_nat n))"
   383 
   384 lemma [code]:
   385   "Array.len a = len' a \<guillemotright>= (\<lambda>i. return (Code_Numeral.nat_of i))"
   386   by (simp add: len'_def)
   387 
   388 definition nth' where
   389   [code del]: "nth' a = Array.nth a o Code_Numeral.nat_of"
   390 
   391 lemma [code]:
   392   "Array.nth a n = nth' a (Code_Numeral.of_nat n)"
   393   by (simp add: nth'_def)
   394 
   395 definition upd' where
   396   [code del]: "upd' a i x = Array.upd (Code_Numeral.nat_of i) x a \<guillemotright> return ()"
   397 
   398 lemma [code]:
   399   "Array.upd i x a = upd' a (Code_Numeral.of_nat i) x \<guillemotright> return a"
   400   by (simp add: upd'_def upd_return)
   401 
   402 lemma [code]:
   403   "Array.map_entry i f a = do {
   404      x \<leftarrow> Array.nth a i;
   405      Array.upd i (f x) a
   406    }"
   407   by (rule Heap_eqI) (simp add: bind_def guard_def map_entry_def execute_simps)
   408 
   409 lemma [code]:
   410   "Array.swap i x a = do {
   411      y \<leftarrow> Array.nth a i;
   412      Array.upd i x a;
   413      return y
   414    }"
   415   by (rule Heap_eqI) (simp add: bind_def guard_def swap_def execute_simps)
   416 
   417 lemma [code]:
   418   "Array.freeze a = do {
   419      n \<leftarrow> Array.len a;
   420      Heap_Monad.fold_map (\<lambda>i. Array.nth a i) [0..<n]
   421    }"
   422 proof (rule Heap_eqI)
   423   fix h
   424   have *: "List.map
   425      (\<lambda>x. fst (the (if x < Array.length h a
   426                     then Some (get_array a h ! x, h) else None)))
   427      [0..<Array.length h a] =
   428        List.map (List.nth (get_array a h)) [0..<Array.length h a]"
   429     by simp
   430   have "execute (Heap_Monad.fold_map (Array.nth a) [0..<Array.length h a]) h =
   431     Some (get_array a h, h)"
   432     apply (subst execute_fold_map_unchanged_heap)
   433     apply (simp_all add: nth_def guard_def *)
   434     apply (simp add: length_def map_nth)
   435     done
   436   then have "execute (do {
   437       n \<leftarrow> Array.len a;
   438       Heap_Monad.fold_map (Array.nth a) [0..<n]
   439     }) h = Some (get_array a h, h)"
   440     by (auto intro: execute_bind_eq_SomeI simp add: execute_simps)
   441   then show "execute (Array.freeze a) h = execute (do {
   442       n \<leftarrow> Array.len a;
   443       Heap_Monad.fold_map (Array.nth a) [0..<n]
   444     }) h" by (simp add: execute_simps)
   445 qed
   446 
   447 hide_const (open) new' of_list' make' len' nth' upd'
   448 
   449 
   450 text {* SML *}
   451 
   452 code_type array (SML "_/ array")
   453 code_const Array (SML "raise/ (Fail/ \"bare Array\")")
   454 code_const Array.new' (SML "(fn/ ()/ =>/ Array.array/ ((_),/ (_)))")
   455 code_const Array.of_list' (SML "(fn/ ()/ =>/ Array.fromList/ _)")
   456 code_const Array.make' (SML "(fn/ ()/ =>/ Array.tabulate/ ((_),/ (_)))")
   457 code_const Array.len' (SML "(fn/ ()/ =>/ Array.length/ _)")
   458 code_const Array.nth' (SML "(fn/ ()/ =>/ Array.sub/ ((_),/ (_)))")
   459 code_const Array.upd' (SML "(fn/ ()/ =>/ Array.update/ ((_),/ (_),/ (_)))")
   460 
   461 code_reserved SML Array
   462 
   463 
   464 text {* OCaml *}
   465 
   466 code_type array (OCaml "_/ array")
   467 code_const Array (OCaml "failwith/ \"bare Array\"")
   468 code_const Array.new' (OCaml "(fun/ ()/ ->/ Array.make/ (Big'_int.int'_of'_big'_int/ _)/ _)")
   469 code_const Array.of_list' (OCaml "(fun/ ()/ ->/ Array.of'_list/ _)")
   470 code_const Array.len' (OCaml "(fun/ ()/ ->/ Big'_int.big'_int'_of'_int/ (Array.length/ _))")
   471 code_const Array.nth' (OCaml "(fun/ ()/ ->/ Array.get/ _/ (Big'_int.int'_of'_big'_int/ _))")
   472 code_const Array.upd' (OCaml "(fun/ ()/ ->/ Array.set/ _/ (Big'_int.int'_of'_big'_int/ _)/ _)")
   473 
   474 code_reserved OCaml Array
   475 
   476 
   477 text {* Haskell *}
   478 
   479 code_type array (Haskell "Heap.STArray/ Heap.RealWorld/ _")
   480 code_const Array (Haskell "error/ \"bare Array\"")
   481 code_const Array.new' (Haskell "Heap.newArray/ (0,/ _)")
   482 code_const Array.of_list' (Haskell "Heap.newListArray/ (0,/ _)")
   483 code_const Array.len' (Haskell "Heap.lengthArray")
   484 code_const Array.nth' (Haskell "Heap.readArray")
   485 code_const Array.upd' (Haskell "Heap.writeArray")
   486 
   487 end