src/Pure/axclass.ML
author wenzelm
Mon Feb 12 20:45:12 2001 +0100 (2001-02-12 ago)
changeset 11101 014e7b5c77ba
parent 10507 ea5de7c64c23
child 11353 7f6eff7bc97a
permissions -rw-r--r--
support \<subseteq> syntax in classes/classrel/axclass/instance;
     1 (*  Title:      Pure/axclass.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Axiomatic type class package.
     6 *)
     7 
     8 signature AX_CLASS =
     9 sig
    10   val quiet_mode: bool ref
    11   val print_axclasses: theory -> unit
    12   val add_classrel_thms: thm list -> theory -> theory
    13   val add_arity_thms: thm list -> theory -> theory
    14   val add_axclass: bclass * xclass list -> ((bstring * string) * Args.src list) list
    15     -> theory -> theory * {intro: thm, axioms: thm list}
    16   val add_axclass_i: bclass * class list -> ((bstring * term) * theory attribute list) list
    17     -> theory -> theory * {intro: thm, axioms: thm list}
    18   val add_inst_subclass: xclass * xclass -> string list -> thm list
    19     -> tactic option -> theory -> theory
    20   val add_inst_subclass_i: class * class -> string list -> thm list
    21     -> tactic option -> theory -> theory
    22   val add_inst_arity: xstring * string list * string -> string list
    23     -> thm list -> tactic option -> theory -> theory
    24   val add_inst_arity_i: string * sort list * sort -> string list
    25     -> thm list -> tactic option -> theory -> theory
    26   val default_intro_classes_tac: thm list -> int -> tactic
    27   val axclass_tac: thm list -> tactic
    28   val prove_subclass: theory -> class * class -> thm list
    29     -> tactic option -> thm
    30   val prove_arity: theory -> string * sort list * class -> thm list
    31     -> tactic option -> thm
    32   val goal_subclass: theory -> xclass * xclass -> thm list
    33   val goal_arity: theory -> xstring * string list * xclass -> thm list
    34   val instance_subclass_proof: (xclass * xclass) * Comment.text -> bool -> theory -> ProofHistory.T
    35   val instance_subclass_proof_i: (class * class) * Comment.text -> bool -> theory -> ProofHistory.T
    36   val instance_arity_proof: (xstring * string list * xclass) * Comment.text
    37     -> bool -> theory -> ProofHistory.T
    38   val instance_arity_proof_i: (string * sort list * class) * Comment.text
    39     -> bool -> theory -> ProofHistory.T
    40   val setup: (theory -> theory) list
    41 end;
    42 
    43 structure AxClass : AX_CLASS =
    44 struct
    45 
    46 
    47 (** utilities **)
    48 
    49 (* messages *)
    50 
    51 val quiet_mode = ref false;
    52 fun message s = if ! quiet_mode then () else writeln s;
    53 
    54 
    55 (* type vars *)
    56 
    57 fun map_typ_frees f (Type (t, tys)) = Type (t, map (map_typ_frees f) tys)
    58   | map_typ_frees f (TFree a) = f a
    59   | map_typ_frees _ a = a;
    60 
    61 val map_term_tfrees = map_term_types o map_typ_frees;
    62 
    63 fun aT S = TFree ("'a", S);
    64 
    65 fun dest_varT (TFree (x, S)) = ((x, ~1), S)
    66   | dest_varT (TVar xi_S) = xi_S
    67   | dest_varT T = raise TYPE ("dest_varT", [T], []);
    68 
    69 
    70 (* get axioms and theorems *)
    71 
    72 val is_def = Logic.is_equals o #prop o rep_thm;
    73 
    74 fun witnesses thy names thms =
    75   PureThy.get_thmss thy names @ thms @ filter is_def (map snd (axioms_of thy));
    76 
    77 
    78 
    79 (** abstract syntax operations **)
    80 
    81 (* names *)
    82 
    83 fun intro_name c = c ^ "I";
    84 val introN = "intro";
    85 val axiomsN = "axioms";
    86 
    87 
    88 (* subclass relations as terms *)
    89 
    90 fun mk_classrel (c1, c2) = Logic.mk_inclass (aT [c1], c2);
    91 
    92 fun dest_classrel tm =
    93   let
    94     fun err () = raise TERM ("dest_classrel", [tm]);
    95 
    96     val (ty, c2) = Logic.dest_inclass tm handle TERM _ => err ();
    97     val c1 = (case dest_varT ty of (_, [c]) => c | _ => err ())
    98       handle TYPE _ => err ();
    99   in (c1, c2) end;
   100 
   101 
   102 (* arities as terms *)
   103 
   104 fun mk_arity (t, ss, c) =
   105   let
   106     val names = tl (variantlist (replicate (length ss + 1) "'", []));
   107     val tfrees = ListPair.map TFree (names, ss);
   108   in Logic.mk_inclass (Type (t, tfrees), c) end;
   109 
   110 fun dest_arity tm =
   111   let
   112     fun err () = raise TERM ("dest_arity", [tm]);
   113 
   114     val (ty, c) = Logic.dest_inclass tm handle TERM _ => err ();
   115     val (t, tvars) =
   116       (case ty of
   117         Type (t, tys) => (t, map dest_varT tys handle TYPE _ => err ())
   118       | _ => err ());
   119     val ss =
   120       if null (gen_duplicates eq_fst tvars)
   121       then map snd tvars else err ();
   122   in (t, ss, c) end;
   123 
   124 
   125 
   126 (** add theorems as axioms **)
   127 
   128 fun prep_thm_axm thy thm =
   129   let
   130     fun err msg = raise THM ("prep_thm_axm: " ^ msg, 0, [thm]);
   131 
   132     val {sign, hyps, prop, ...} = rep_thm thm;
   133   in
   134     if not (Sign.subsig (sign, Theory.sign_of thy)) then
   135       err "theorem not of same theory"
   136     else if not (null (extra_shyps thm)) orelse not (null hyps) then
   137       err "theorem may not contain hypotheses"
   138     else prop
   139   end;
   140 
   141 (*theorems expressing class relations*)
   142 fun add_classrel_thms thms thy =
   143   let
   144     fun prep_thm thm =
   145       let
   146         val prop = prep_thm_axm thy thm;
   147         val (c1, c2) = dest_classrel prop handle TERM _ =>
   148           raise THM ("add_classrel_thms: theorem is not a class relation", 0, [thm]);
   149       in (c1, c2) end;
   150   in Theory.add_classrel_i (map prep_thm thms) thy end;
   151 
   152 (*theorems expressing arities*)
   153 fun add_arity_thms thms thy =
   154   let
   155     fun prep_thm thm =
   156       let
   157         val prop = prep_thm_axm thy thm;
   158         val (t, ss, c) = dest_arity prop handle TERM _ =>
   159           raise THM ("add_arity_thms: theorem is not an arity", 0, [thm]);
   160       in (t, ss, [c]) end;
   161   in Theory.add_arities_i (map prep_thm thms) thy end;
   162 
   163 
   164 
   165 (** axclass info **)
   166 
   167 (* data kind 'Pure/axclasses' *)
   168 
   169 type axclass_info =
   170   {super_classes: class list,
   171     intro: thm,
   172     axioms: thm list};
   173 
   174 structure AxclassesArgs =
   175 struct
   176   val name = "Pure/axclasses";
   177   type T = axclass_info Symtab.table;
   178 
   179   val empty = Symtab.empty;
   180   val copy = I;
   181   val prep_ext = I;
   182   fun merge (tab1, tab2) = Symtab.merge (K true) (tab1, tab2);
   183 
   184   fun print sg tab =
   185     let
   186       val ext_class = Sign.cond_extern sg Sign.classK;
   187       val ext_thm = PureThy.cond_extern_thm_sg sg;
   188 
   189       fun pretty_class c cs = Pretty.block
   190         (Pretty.str (ext_class c) :: Pretty.str " <" :: Pretty.brk 1 ::
   191           Pretty.breaks (map (Pretty.str o ext_class) cs));
   192 
   193       fun pretty_thms name thms = Pretty.big_list (name ^ ":")
   194         (map (Display.pretty_thm_sg sg) thms);
   195 
   196       fun pretty_axclass (name, {super_classes, intro, axioms}) = Pretty.block (Pretty.fbreaks
   197         [pretty_class name super_classes, pretty_thms introN [intro], pretty_thms axiomsN axioms]);
   198     in Pretty.writeln (Pretty.chunks (map pretty_axclass (Symtab.dest tab))) end;
   199 end;
   200 
   201 structure AxclassesData = TheoryDataFun(AxclassesArgs);
   202 val print_axclasses = AxclassesData.print;
   203 
   204 
   205 (* get and put data *)
   206 
   207 fun lookup_axclass_info_sg sg c = Symtab.lookup (AxclassesData.get_sg sg, c);
   208 
   209 fun get_axclass_info thy c =
   210   (case lookup_axclass_info_sg (Theory.sign_of thy) c of
   211     None => error ("Unknown axclass " ^ quote c)
   212   | Some info => info);
   213 
   214 fun put_axclass_info c info thy =
   215   thy |> AxclassesData.put (Symtab.update ((c, info), AxclassesData.get thy));
   216 
   217 
   218 
   219 (** add axiomatic type classes **)
   220 
   221 (* errors *)
   222 
   223 fun err_not_logic c =
   224   error ("Axiomatic class " ^ quote c ^ " not subclass of " ^ quote logicC);
   225 
   226 fun err_bad_axsort ax c =
   227   error ("Sort constraint in axiom " ^ quote ax ^ " not supersort of " ^ quote c);
   228 
   229 fun err_bad_tfrees ax =
   230   error ("More than one type variable in axiom " ^ quote ax);
   231 
   232 
   233 (* ext_axclass *)
   234 
   235 fun ext_axclass prep_class prep_axm prep_att (bclass, raw_super_classes) raw_axioms_atts thy =
   236   let
   237     val sign = Theory.sign_of thy;
   238 
   239     val class = Sign.full_name sign bclass;
   240     val super_classes = map (prep_class sign) raw_super_classes;
   241     val axms = map (prep_axm sign o fst) raw_axioms_atts;
   242     val atts = map (map (prep_att thy) o snd) raw_axioms_atts;
   243 
   244     (*declare class*)
   245     val class_thy =
   246       thy |> Theory.add_classes_i [(bclass, super_classes)];
   247     val class_sign = Theory.sign_of class_thy;
   248 
   249     (*prepare abstract axioms*)
   250     fun abs_axm ax =
   251       if null (term_tfrees ax) then
   252         Logic.mk_implies (Logic.mk_inclass (aT logicS, class), ax)
   253       else map_term_tfrees (K (aT [class])) ax;
   254     val abs_axms = map (abs_axm o #2) axms;
   255 
   256     (*prepare introduction rule*)
   257     val _ = if Sign.subsort class_sign ([class], logicS) then () else err_not_logic class;
   258 
   259     fun axm_sort (name, ax) =
   260       (case term_tfrees ax of
   261         [] => []
   262       | [(_, S)] => if Sign.subsort class_sign ([class], S) then S else err_bad_axsort name class
   263       | _ => err_bad_tfrees name);
   264     val axS = Sign.norm_sort class_sign (logicC :: flat (map axm_sort axms));
   265 
   266     val int_axm = Logic.close_form o map_term_tfrees (K (aT axS));
   267     fun inclass c = Logic.mk_inclass (aT axS, c);
   268 
   269     val intro_axm = Logic.list_implies
   270       (map inclass super_classes @ map (int_axm o #2) axms, inclass class);
   271 
   272     (*declare axioms and rule*)
   273     val (axms_thy, ([intro], [axioms])) =
   274       class_thy
   275       |> Theory.add_path bclass
   276       |> PureThy.add_axioms_i [Thm.no_attributes (introN, intro_axm)]
   277       |>>> PureThy.add_axiomss_i [Thm.no_attributes (axiomsN, abs_axms)];
   278     val info = {super_classes = super_classes, intro = intro, axioms = axioms};
   279 
   280     (*store info*)
   281     val final_thy =
   282       axms_thy
   283       |> (#1 o PureThy.add_thms ((map #1 axms ~~ axioms) ~~ atts))
   284       |> Theory.parent_path
   285       |> (#1 o PureThy.add_thms [Thm.no_attributes (intro_name bclass, intro)])
   286       |> put_axclass_info class info;
   287   in (final_thy, {intro = intro, axioms = axioms}) end;
   288 
   289 
   290 (* external interfaces *)
   291 
   292 val add_axclass = ext_axclass Sign.intern_class Theory.read_axm Attrib.global_attribute;
   293 val add_axclass_i = ext_axclass (K I) Theory.cert_axm (K I);
   294 
   295 
   296 
   297 (** prove class relations and type arities **)
   298 
   299 (* class_axms *)
   300 
   301 fun class_axms sign =
   302   let val classes = Sign.classes sign in
   303     map (Thm.class_triv sign) classes @
   304     mapfilter (apsome #intro o lookup_axclass_info_sg sign) classes
   305   end;
   306 
   307 
   308 (* intro_classes *)
   309 
   310 fun intro_classes_tac facts i st =
   311   ((Method.insert_tac facts THEN'
   312     REPEAT_ALL_NEW (resolve_tac (class_axms (Thm.sign_of_thm st)))) i
   313     THEN Tactic.distinct_subgoals_tac) st;    (*affects all subgoals!?*)
   314 
   315 val intro_classes_method =
   316   ("intro_classes", Method.no_args (Method.METHOD (HEADGOAL o intro_classes_tac)),
   317     "back-chain introduction rules of axiomatic type classes");
   318 
   319 
   320 (* default method *)
   321 
   322 fun default_intro_classes_tac [] i = intro_classes_tac [] i
   323   | default_intro_classes_tac _ _ = Tactical.no_tac;    (*no error message!*)
   324 
   325 fun default_tac rules ctxt facts =
   326   HEADGOAL (Method.some_rule_tac rules ctxt facts ORELSE' default_intro_classes_tac facts);
   327 
   328 val default_method =
   329   ("default", Method.thms_ctxt_args (Method.METHOD oo default_tac), "apply some rule")
   330 
   331 
   332 (* axclass_tac *)
   333 
   334 (*(1) repeatedly resolve goals of form "OFCLASS(ty, c_class)",
   335       try class_trivs first, then "cI" axioms
   336   (2) rewrite goals using user supplied definitions
   337   (3) repeatedly resolve goals with user supplied non-definitions*)
   338 
   339 fun axclass_tac thms =
   340   let
   341     val defs = filter is_def thms;
   342     val non_defs = filter_out is_def thms;
   343   in
   344     HEADGOAL (intro_classes_tac []) THEN
   345     TRY (rewrite_goals_tac defs) THEN
   346     TRY (REPEAT_FIRST (fn i => assume_tac i ORELSE resolve_tac non_defs i))
   347   end;
   348 
   349 
   350 (* provers *)
   351 
   352 fun prove mk_prop str_of thy sig_prop thms usr_tac =
   353   let
   354     val sign = Theory.sign_of thy;
   355     val goal = Thm.cterm_of sign (mk_prop sig_prop)
   356       handle TERM (msg, _) => error msg
   357         | TYPE (msg, _, _) => error msg;
   358     val tac = axclass_tac thms THEN (if_none usr_tac all_tac);
   359   in
   360     prove_goalw_cterm [] goal (K [tac])
   361   end
   362   handle ERROR => error ("The error(s) above occurred while trying to prove "
   363     ^ quote (str_of (Theory.sign_of thy, sig_prop)));
   364 
   365 val prove_subclass =
   366   prove mk_classrel (fn (sg, c1_c2) => Sign.str_of_classrel sg c1_c2);
   367 
   368 val prove_arity =
   369   prove mk_arity (fn (sg, (t, Ss, c)) => Sign.str_of_arity sg (t, Ss, [c]));
   370 
   371 
   372 
   373 (** add proved subclass relations and arities **)
   374 
   375 (* prepare classes and arities *)
   376 
   377 fun read_class sg c = Sign.certify_class sg (Sign.intern_class sg c);
   378 
   379 fun cert_classrel sg cc = Library.pairself (Sign.certify_class sg) cc;
   380 fun read_classrel sg cc = Library.pairself (read_class sg) cc;
   381 
   382 fun check_tycon sg t =
   383   let val {tycons, abbrs, ...} = Type.rep_tsig (Sign.tsig_of sg) in
   384     if is_some (Symtab.lookup (abbrs, t)) then
   385       error ("Illegal type abbreviation: " ^ quote t)
   386     else if is_none (Symtab.lookup (tycons, t)) then
   387       error ("Undeclared type constructor: " ^ quote t)
   388     else t
   389   end;
   390 
   391 fun prep_arity prep_tycon prep_sort prep_x sg (t, Ss, x) =
   392   (check_tycon sg (prep_tycon sg t), map (prep_sort sg) Ss, prep_x sg x);
   393 
   394 val read_arity = prep_arity Sign.intern_tycon Sign.read_sort Sign.read_sort;
   395 val cert_arity = prep_arity (K I) Sign.certify_sort Sign.certify_sort;
   396 val read_simple_arity = prep_arity Sign.intern_tycon Sign.read_sort Sign.intern_class;
   397 fun cert_simple_arity arg = prep_arity (K I) Sign.certify_sort (K I) arg;
   398 
   399 
   400 (* old-style instance declarations *)
   401 
   402 fun ext_inst_subclass prep_classrel raw_c1_c2 names thms usr_tac thy =
   403   let val c1_c2 = prep_classrel (Theory.sign_of thy) raw_c1_c2 in
   404     message ("Proving class inclusion " ^
   405       quote (Sign.str_of_classrel (Theory.sign_of thy) c1_c2) ^ " ...");
   406     thy |> add_classrel_thms [prove_subclass thy c1_c2 (witnesses thy names thms) usr_tac]
   407   end;
   408 
   409 fun ext_inst_arity prep_arity (raw_t, raw_Ss, raw_cs) names thms usr_tac thy =
   410   let
   411     val sign = Theory.sign_of thy;
   412     val (t, Ss, cs) = prep_arity sign (raw_t, raw_Ss, raw_cs);
   413     val wthms = witnesses thy names thms;
   414     fun prove c =
   415      (message ("Proving type arity " ^
   416         quote (Sign.str_of_arity sign (t, Ss, [c])) ^ " ...");
   417         prove_arity thy (t, Ss, c) wthms usr_tac);
   418   in add_arity_thms (map prove cs) thy end;
   419 
   420 
   421 val add_inst_subclass = ext_inst_subclass read_classrel;
   422 val add_inst_subclass_i = ext_inst_subclass cert_classrel;
   423 val add_inst_arity = ext_inst_arity read_arity;
   424 val add_inst_arity_i = ext_inst_arity cert_arity;
   425 
   426 
   427 (* make old-style interactive goals *)
   428 
   429 fun mk_goal mk_prop thy sig_prop =
   430   Goals.goalw_cterm [] (Thm.cterm_of (Theory.sign_of thy) (mk_prop (Theory.sign_of thy) sig_prop));
   431 
   432 val goal_subclass = mk_goal (mk_classrel oo read_classrel);
   433 val goal_arity = mk_goal (mk_arity oo read_simple_arity);
   434 
   435 
   436 
   437 (** instance proof interfaces **)
   438 
   439 fun inst_attribute add_thms (thy, thm) = (add_thms [thm] thy, thm);
   440 
   441 fun inst_proof mk_prop add_thms (sig_prop, comment) int thy =
   442   thy
   443   |> IsarThy.theorem_i ((("", [inst_attribute add_thms]),
   444     (mk_prop (Theory.sign_of thy) sig_prop, ([], []))), comment) int;
   445 
   446 val instance_subclass_proof = inst_proof (mk_classrel oo read_classrel) add_classrel_thms;
   447 val instance_subclass_proof_i = inst_proof (mk_classrel oo cert_classrel) add_classrel_thms;
   448 val instance_arity_proof = inst_proof (mk_arity oo read_simple_arity) add_arity_thms;
   449 val instance_arity_proof_i = inst_proof (mk_arity oo cert_simple_arity) add_arity_thms;
   450 
   451 
   452 
   453 (** package setup **)
   454 
   455 (* setup theory *)
   456 
   457 val setup =
   458  [AxclassesData.init,
   459   Method.add_methods [intro_classes_method, default_method]];
   460 
   461 
   462 (* outer syntax *)
   463 
   464 local structure P = OuterParse and K = OuterSyntax.Keyword in
   465 
   466 val axclassP =
   467   OuterSyntax.command "axclass" "define axiomatic type class" K.thy_decl
   468     (((P.name -- Scan.optional ((P.$$$ "\\<subseteq>" || P.$$$ "<") |--
   469         P.!!! (P.list1 P.xname)) []) --| P.marg_comment)
   470       -- Scan.repeat (P.spec_name --| P.marg_comment)
   471       >> (fn (cls, axs) => Toplevel.theory (#1 o add_axclass cls axs)));
   472 
   473 val instanceP =
   474   OuterSyntax.command "instance" "prove type arity or subclass relation" K.thy_goal
   475     ((P.xname -- ((P.$$$ "\\<subseteq>" || P.$$$ "<") |-- P.xname)
   476         -- P.marg_comment >> instance_subclass_proof ||
   477       (P.xname -- (P.$$$ "::" |-- P.simple_arity) >> P.triple2) -- P.marg_comment
   478         >> instance_arity_proof)
   479       >> (Toplevel.print oo Toplevel.theory_to_proof));
   480 
   481 val _ = OuterSyntax.add_parsers [axclassP, instanceP];
   482 
   483 end;
   484 
   485 
   486 end;