src/HOL/Tools/Nitpick/nitpick.ML
author blanchet
Tue Apr 24 09:47:40 2012 +0200 (2012-04-24 ago)
changeset 47715 04400144c6fc
parent 47670 24babc4b1925
child 47716 dc9c8ce4aac5
permissions -rw-r--r--
handle TPTP definitions as definitions in Nitpick rather than as axioms
     1 (*  Title:      HOL/Tools/Nitpick/nitpick.ML
     2     Author:     Jasmin Blanchette, TU Muenchen
     3     Copyright   2008, 2009, 2010
     4 
     5 Finite model generation for HOL formulas using Kodkod.
     6 *)
     7 
     8 signature NITPICK =
     9 sig
    10   type styp = Nitpick_Util.styp
    11   type term_postprocessor = Nitpick_Model.term_postprocessor
    12 
    13   datatype mode = Auto_Try | Try | Normal | TPTP
    14 
    15   type params =
    16     {cards_assigns: (typ option * int list) list,
    17      maxes_assigns: (styp option * int list) list,
    18      iters_assigns: (styp option * int list) list,
    19      bitss: int list,
    20      bisim_depths: int list,
    21      boxes: (typ option * bool option) list,
    22      finitizes: (typ option * bool option) list,
    23      monos: (typ option * bool option) list,
    24      stds: (typ option * bool) list,
    25      wfs: (styp option * bool option) list,
    26      sat_solver: string,
    27      blocking: bool,
    28      falsify: bool,
    29      debug: bool,
    30      verbose: bool,
    31      overlord: bool,
    32      user_axioms: bool option,
    33      assms: bool,
    34      whacks: term list,
    35      merge_type_vars: bool,
    36      binary_ints: bool option,
    37      destroy_constrs: bool,
    38      specialize: bool,
    39      star_linear_preds: bool,
    40      total_consts: bool option,
    41      needs: term list option,
    42      peephole_optim: bool,
    43      datatype_sym_break: int,
    44      kodkod_sym_break: int,
    45      timeout: Time.time option,
    46      tac_timeout: Time.time option,
    47      max_threads: int,
    48      show_datatypes: bool,
    49      show_skolems: bool,
    50      show_consts: bool,
    51      evals: term list,
    52      formats: (term option * int list) list,
    53      atomss: (typ option * string list) list,
    54      max_potential: int,
    55      max_genuine: int,
    56      check_potential: bool,
    57      check_genuine: bool,
    58      batch_size: int,
    59      expect: string}
    60 
    61   val genuineN : string
    62   val quasi_genuineN : string
    63   val potentialN : string
    64   val noneN : string
    65   val unknownN : string
    66   val register_frac_type : string -> (string * string) list -> theory -> theory
    67   val unregister_frac_type : string -> theory -> theory
    68   val register_codatatype : typ -> string -> styp list -> theory -> theory
    69   val unregister_codatatype : typ -> theory -> theory
    70   val register_term_postprocessor :
    71     typ -> term_postprocessor -> theory -> theory
    72   val unregister_term_postprocessor : typ -> theory -> theory
    73   val pick_nits_in_term :
    74     Proof.state -> params -> mode -> int -> int -> int -> (term * term) list
    75     -> term list -> term list -> term -> string * Proof.state
    76   val pick_nits_in_subgoal :
    77     Proof.state -> params -> mode -> int -> int -> string * Proof.state
    78 end;
    79 
    80 structure Nitpick : NITPICK =
    81 struct
    82 
    83 open Nitpick_Util
    84 open Nitpick_HOL
    85 open Nitpick_Preproc
    86 open Nitpick_Mono
    87 open Nitpick_Scope
    88 open Nitpick_Peephole
    89 open Nitpick_Rep
    90 open Nitpick_Nut
    91 open Nitpick_Kodkod
    92 open Nitpick_Model
    93 
    94 structure KK = Kodkod
    95 
    96 datatype mode = Auto_Try | Try | Normal | TPTP
    97 
    98 fun is_mode_nt mode = (mode = Normal orelse mode = TPTP)
    99 
   100 type params =
   101   {cards_assigns: (typ option * int list) list,
   102    maxes_assigns: (styp option * int list) list,
   103    iters_assigns: (styp option * int list) list,
   104    bitss: int list,
   105    bisim_depths: int list,
   106    boxes: (typ option * bool option) list,
   107    finitizes: (typ option * bool option) list,
   108    monos: (typ option * bool option) list,
   109    stds: (typ option * bool) list,
   110    wfs: (styp option * bool option) list,
   111    sat_solver: string,
   112    blocking: bool,
   113    falsify: bool,
   114    debug: bool,
   115    verbose: bool,
   116    overlord: bool,
   117    user_axioms: bool option,
   118    assms: bool,
   119    whacks: term list,
   120    merge_type_vars: bool,
   121    binary_ints: bool option,
   122    destroy_constrs: bool,
   123    specialize: bool,
   124    star_linear_preds: bool,
   125    total_consts: bool option,
   126    needs: term list option,
   127    peephole_optim: bool,
   128    datatype_sym_break: int,
   129    kodkod_sym_break: int,
   130    timeout: Time.time option,
   131    tac_timeout: Time.time option,
   132    max_threads: int,
   133    show_datatypes: bool,
   134    show_skolems: bool,
   135    show_consts: bool,
   136    evals: term list,
   137    formats: (term option * int list) list,
   138    atomss: (typ option * string list) list,
   139    max_potential: int,
   140    max_genuine: int,
   141    check_potential: bool,
   142    check_genuine: bool,
   143    batch_size: int,
   144    expect: string}
   145 
   146 val genuineN = "genuine"
   147 val quasi_genuineN = "quasi_genuine"
   148 val potentialN = "potential"
   149 val noneN = "none"
   150 val unknownN = "unknown"
   151 
   152 (* TODO: eliminate these historical aliases *)
   153 val register_frac_type = Nitpick_HOL.register_frac_type_global
   154 val unregister_frac_type = Nitpick_HOL.unregister_frac_type_global
   155 val register_codatatype = Nitpick_HOL.register_codatatype_global
   156 val unregister_codatatype = Nitpick_HOL.unregister_codatatype_global
   157 val register_term_postprocessor =
   158   Nitpick_Model.register_term_postprocessor_global
   159 val unregister_term_postprocessor =
   160   Nitpick_Model.unregister_term_postprocessor_global
   161 
   162 type problem_extension =
   163   {free_names: nut list,
   164    sel_names: nut list,
   165    nonsel_names: nut list,
   166    rel_table: nut NameTable.table,
   167    unsound: bool,
   168    scope: scope}
   169 
   170 type rich_problem = KK.problem * problem_extension
   171 
   172 fun pretties_for_formulas _ _ [] = []
   173   | pretties_for_formulas ctxt s ts =
   174     [Pretty.str (s ^ plural_s_for_list ts ^ ":"),
   175      Pretty.indent indent_size (Pretty.chunks
   176          (map2 (fn j => fn t =>
   177                    Pretty.block [t |> shorten_names_in_term
   178                                    |> Syntax.pretty_term ctxt,
   179                                  Pretty.str (if j = 1 then "." else ";")])
   180                (length ts downto 1) ts))]
   181 
   182 fun install_java_message () =
   183   "Nitpick requires Java Development Kit 1.6/1.7 via ISABELLE_JDK_HOME setting."
   184 fun install_kodkodi_message () =
   185   "Nitpick requires the external Java program Kodkodi. To install it, download \
   186   \the package from \"http://www21.in.tum.de/~blanchet/#software\" and add the \
   187   \\"kodkodi-x.y.z\" directory's full path to " ^
   188   Path.print (Path.expand (Path.explode "$ISABELLE_HOME_USER/etc/components")) ^
   189   " on a line of its own."
   190 
   191 val max_unsound_delay_ms = 200
   192 val max_unsound_delay_percent = 2
   193 
   194 fun unsound_delay_for_timeout NONE = max_unsound_delay_ms
   195   | unsound_delay_for_timeout (SOME timeout) =
   196     Int.max (0, Int.min (max_unsound_delay_ms,
   197                          Time.toMilliseconds timeout
   198                          * max_unsound_delay_percent div 100))
   199 
   200 fun passed_deadline NONE = false
   201   | passed_deadline (SOME time) = Time.compare (Time.now (), time) <> LESS
   202 
   203 fun none_true assigns = forall (not_equal (SOME true) o snd) assigns
   204 
   205 fun has_lonely_bool_var (@{const Pure.conjunction}
   206                          $ (@{const Trueprop} $ Free _) $ _) = true
   207   | has_lonely_bool_var _ = false
   208 
   209 val syntactic_sorts =
   210   @{sort "{default,zero,one,plus,minus,uminus,times,inverse,abs,sgn,ord,equal}"} @
   211   @{sort numeral}
   212 fun has_tfree_syntactic_sort (TFree (_, S as _ :: _)) =
   213     subset (op =) (S, syntactic_sorts)
   214   | has_tfree_syntactic_sort _ = false
   215 val has_syntactic_sorts = exists_type (exists_subtype has_tfree_syntactic_sort)
   216 
   217 fun plazy f = Pretty.blk (0, pstrs (f ()))
   218 
   219 fun pick_them_nits_in_term deadline state (params : params) mode i n step
   220                            subst def_assm_ts nondef_assm_ts orig_t =
   221   let
   222     val timer = Timer.startRealTimer ()
   223     val thy = Proof.theory_of state
   224     val ctxt = Proof.context_of state
   225 (* FIXME: reintroduce code before new release:
   226 
   227     val nitpick_thy = Thy_Info.get_theory "Nitpick"
   228     val _ = Theory.subthy (nitpick_thy, thy) orelse
   229             error "You must import the theory \"Nitpick\" to use Nitpick"
   230 *)
   231     val {cards_assigns, maxes_assigns, iters_assigns, bitss, bisim_depths,
   232          boxes, finitizes, monos, stds, wfs, sat_solver, falsify, debug,
   233          verbose, overlord, user_axioms, assms, whacks, merge_type_vars,
   234          binary_ints, destroy_constrs, specialize, star_linear_preds,
   235          total_consts, needs, peephole_optim, datatype_sym_break,
   236          kodkod_sym_break, tac_timeout, max_threads, show_datatypes,
   237          show_skolems, show_consts, evals, formats, atomss, max_potential,
   238          max_genuine, check_potential, check_genuine, batch_size, ...} = params
   239     val state_ref = Unsynchronized.ref state
   240     fun pprint print =
   241       if mode = Auto_Try then
   242         Unsynchronized.change state_ref o Proof.goal_message o K
   243         o Pretty.chunks o cons (Pretty.str "") o single
   244         o Pretty.mark Isabelle_Markup.hilite
   245       else
   246         print o Pretty.string_of
   247     val pprint_a = pprint Output.urgent_message
   248     fun pprint_nt f = () |> is_mode_nt mode ? pprint Output.urgent_message o f
   249     fun pprint_v f = () |> verbose ? pprint Output.urgent_message o f
   250     fun pprint_d f = () |> debug ? pprint tracing o f
   251     val print = pprint Output.urgent_message o curry Pretty.blk 0 o pstrs
   252     fun print_t f = () |> mode = TPTP ? print o f
   253 (*
   254     val print_g = pprint tracing o Pretty.str
   255 *)
   256     val print_nt = pprint_nt o K o plazy
   257     val print_v = pprint_v o K o plazy
   258 
   259     fun check_deadline () =
   260       if passed_deadline deadline then raise TimeLimit.TimeOut else ()
   261 
   262     val (def_assm_ts, nondef_assm_ts) =
   263       if assms orelse mode <> Normal then (def_assm_ts, nondef_assm_ts)
   264       else ([], [])
   265     val _ =
   266       if step = 0 then
   267         print_nt (fn () => "Nitpicking formula...")
   268       else
   269         pprint_nt (fn () => Pretty.chunks (
   270             pretties_for_formulas ctxt ("Nitpicking " ^
   271                 (if i <> 1 orelse n <> 1 then
   272                    "subgoal " ^ string_of_int i ^ " of " ^ string_of_int n
   273                  else
   274                    "goal")) [Logic.list_implies (nondef_assm_ts, orig_t)]))
   275     val _ = print_v (enclose "Timestamp: " "." o Date.fmt "%H:%M:%S"
   276                      o Date.fromTimeLocal o Time.now)
   277     val neg_t = if falsify then Logic.mk_implies (orig_t, @{prop False})
   278                 else orig_t
   279     val conj_ts = neg_t :: def_assm_ts @ nondef_assm_ts @ evals @ these needs
   280     val tfree_table =
   281       if merge_type_vars then merged_type_var_table_for_terms thy conj_ts
   282       else []
   283     val merge_tfrees = merge_type_vars_in_term thy merge_type_vars tfree_table
   284     val neg_t = neg_t |> merge_tfrees
   285     val def_assm_ts = def_assm_ts |> map merge_tfrees
   286     val nondef_assm_ts = nondef_assm_ts |> map merge_tfrees
   287     val evals = evals |> map merge_tfrees
   288     val needs = needs |> Option.map (map merge_tfrees)
   289     val conj_ts = neg_t :: def_assm_ts @ nondef_assm_ts @ evals @ these needs
   290     val original_max_potential = max_potential
   291     val original_max_genuine = max_genuine
   292     val max_bisim_depth = fold Integer.max bisim_depths ~1
   293     val case_names = case_const_names ctxt stds
   294     val defs = def_assm_ts @ all_defs_of thy subst
   295     val nondefs = all_nondefs_of ctxt subst
   296     val def_tables = const_def_tables ctxt subst defs
   297     val nondef_table = const_nondef_table nondefs
   298     val simp_table = Unsynchronized.ref (const_simp_table ctxt subst)
   299     val psimp_table = const_psimp_table ctxt subst
   300     val choice_spec_table = const_choice_spec_table ctxt subst
   301     val nondefs =
   302       nondefs |> filter_out (is_choice_spec_axiom thy choice_spec_table)
   303     val intro_table = inductive_intro_table ctxt subst def_tables
   304     val ground_thm_table = ground_theorem_table thy
   305     val ersatz_table = ersatz_table ctxt
   306     val hol_ctxt as {wf_cache, ...} =
   307       {thy = thy, ctxt = ctxt, max_bisim_depth = max_bisim_depth, boxes = boxes,
   308        stds = stds, wfs = wfs, user_axioms = user_axioms, debug = debug,
   309        whacks = whacks, binary_ints = binary_ints,
   310        destroy_constrs = destroy_constrs, specialize = specialize,
   311        star_linear_preds = star_linear_preds, total_consts = total_consts,
   312        needs = needs, tac_timeout = tac_timeout, evals = evals,
   313        case_names = case_names, def_tables = def_tables,
   314        nondef_table = nondef_table, nondefs = nondefs, simp_table = simp_table,
   315        psimp_table = psimp_table, choice_spec_table = choice_spec_table,
   316        intro_table = intro_table, ground_thm_table = ground_thm_table,
   317        ersatz_table = ersatz_table, skolems = Unsynchronized.ref [],
   318        special_funs = Unsynchronized.ref [],
   319        unrolled_preds = Unsynchronized.ref [], wf_cache = Unsynchronized.ref [],
   320        constr_cache = Unsynchronized.ref []}
   321     val pseudo_frees = []
   322     val real_frees = fold Term.add_frees conj_ts []
   323     val _ = null (fold Term.add_tvars conj_ts []) orelse
   324             error "Nitpick cannot handle goals with schematic type variables."
   325     val (nondef_ts, def_ts, need_ts, got_all_mono_user_axioms,
   326          no_poly_user_axioms, binarize) =
   327       preprocess_formulas hol_ctxt nondef_assm_ts neg_t
   328     val got_all_user_axioms =
   329       got_all_mono_user_axioms andalso no_poly_user_axioms
   330 
   331     fun print_wf (x, (gfp, wf)) =
   332       pprint_nt (fn () => Pretty.blk (0,
   333           pstrs ("The " ^ (if gfp then "co" else "") ^ "inductive predicate \"")
   334           @ Syntax.pretty_term ctxt (Const x) ::
   335           pstrs (if wf then
   336                    "\" was proved well-founded. Nitpick can compute it \
   337                    \efficiently."
   338                  else
   339                    "\" could not be proved well-founded. Nitpick might need to \
   340                    \unroll it.")))
   341     val _ = if verbose then List.app print_wf (!wf_cache) else ()
   342     val das_wort_formula = if falsify then "Negated conjecture" else "Formula"
   343     val _ =
   344       pprint_d (fn () => Pretty.chunks
   345           (pretties_for_formulas ctxt das_wort_formula [hd nondef_ts] @
   346            pretties_for_formulas ctxt "Relevant definitional axiom" def_ts @
   347            pretties_for_formulas ctxt "Relevant nondefinitional axiom"
   348                                  (tl nondef_ts)))
   349     val _ = List.app (ignore o Term.type_of) (nondef_ts @ def_ts)
   350             handle TYPE (_, Ts, ts) =>
   351                    raise TYPE ("Nitpick.pick_them_nits_in_term", Ts, ts)
   352 
   353     val nondef_us = nondef_ts |> map (nut_from_term hol_ctxt Eq)
   354     val def_us = def_ts |> map (nut_from_term hol_ctxt DefEq)
   355     val need_us = need_ts |> map (nut_from_term hol_ctxt Eq)
   356     val (free_names, const_names) =
   357       fold add_free_and_const_names (nondef_us @ def_us @ need_us) ([], [])
   358     val (sel_names, nonsel_names) =
   359       List.partition (is_sel o nickname_of) const_names
   360     val sound_finitizes = none_true finitizes
   361     val standard = forall snd stds
   362 (*
   363     val _ =
   364       List.app (print_g o string_for_nut ctxt) (nondef_us @ def_us @ need_us)
   365 *)
   366 
   367     val unique_scope = forall (curry (op =) 1 o length o snd) cards_assigns
   368     fun monotonicity_message Ts extra =
   369       let val pretties = map (pretty_maybe_quote o pretty_for_type ctxt) Ts in
   370         Pretty.blk (0,
   371           pstrs ("The type" ^ plural_s_for_list pretties ^ " ") @
   372           pretty_serial_commas "and" pretties @
   373           pstrs (" " ^
   374                  (if none_true monos then
   375                     "passed the monotonicity test"
   376                   else
   377                     (if length pretties = 1 then "is" else "are") ^
   378                     " considered monotonic") ^
   379                  ". " ^ extra))
   380       end
   381     fun is_type_fundamentally_monotonic T =
   382       (is_datatype ctxt stds T andalso not (is_quot_type ctxt T) andalso
   383        (not (is_pure_typedef ctxt T) orelse is_univ_typedef ctxt T)) orelse
   384       is_number_type ctxt T orelse is_bit_type T
   385     fun is_type_actually_monotonic T =
   386       formulas_monotonic hol_ctxt binarize T (nondef_ts, def_ts)
   387     fun is_type_kind_of_monotonic T =
   388       case triple_lookup (type_match thy) monos T of
   389         SOME (SOME false) => false
   390       | _ => is_type_actually_monotonic T
   391     fun is_type_monotonic T =
   392       unique_scope orelse
   393       case triple_lookup (type_match thy) monos T of
   394         SOME (SOME b) => b
   395       | _ => is_type_fundamentally_monotonic T orelse
   396              is_type_actually_monotonic T
   397     fun is_deep_datatype_finitizable T =
   398       triple_lookup (type_match thy) finitizes T = SOME (SOME true)
   399     fun is_shallow_datatype_finitizable (T as Type (@{type_name fun_box}, _)) =
   400         is_type_kind_of_monotonic T
   401       | is_shallow_datatype_finitizable T =
   402         case triple_lookup (type_match thy) finitizes T of
   403           SOME (SOME b) => b
   404         | _ => is_type_kind_of_monotonic T
   405     fun is_datatype_deep T =
   406       not standard orelse T = @{typ unit} orelse T = nat_T orelse
   407       is_word_type T orelse
   408       exists (curry (op =) T o domain_type o type_of) sel_names
   409     val all_Ts = ground_types_in_terms hol_ctxt binarize (nondef_ts @ def_ts)
   410                  |> sort Term_Ord.typ_ord
   411     val _ =
   412       if verbose andalso binary_ints = SOME true andalso
   413          exists (member (op =) [nat_T, int_T]) all_Ts then
   414         print_v (K "The option \"binary_ints\" will be ignored because of the \
   415                    \presence of rationals, reals, \"Suc\", \"gcd\", or \"lcm\" \
   416                    \in the problem or because of the \"non_std\" option.")
   417       else
   418         ()
   419     val _ =
   420       if mode = Normal andalso
   421          exists (fn Type (@{type_name Datatype.node}, _) => true | _ => false)
   422                 all_Ts then
   423         print_nt (K ("Warning: The problem involves directly or indirectly the \
   424                      \internal type " ^ quote @{type_name Datatype.node} ^
   425                      ". This type is very Nitpick-unfriendly, and its presence \
   426                      \usually indicates either a failure of abstraction or a \
   427                      \quirk in Nitpick."))
   428       else
   429         ()
   430     val (mono_Ts, nonmono_Ts) = List.partition is_type_monotonic all_Ts
   431     val _ =
   432       if verbose andalso not unique_scope then
   433         case filter_out is_type_fundamentally_monotonic mono_Ts of
   434           [] => ()
   435         | interesting_mono_Ts =>
   436           pprint_v (K (monotonicity_message interesting_mono_Ts
   437                           "Nitpick might be able to skip some scopes."))
   438       else
   439         ()
   440     val (deep_dataTs, shallow_dataTs) =
   441       all_Ts |> filter (is_datatype ctxt stds)
   442              |> List.partition is_datatype_deep
   443     val finitizable_dataTs =
   444       (deep_dataTs |> filter_out (is_finite_type hol_ctxt)
   445                    |> filter is_deep_datatype_finitizable) @
   446       (shallow_dataTs |> filter_out (is_finite_type hol_ctxt)
   447                       |> filter is_shallow_datatype_finitizable)
   448     val _ =
   449       if verbose andalso not (null finitizable_dataTs) then
   450         pprint_v (K (monotonicity_message finitizable_dataTs
   451                          "Nitpick can use a more precise finite encoding."))
   452       else
   453         ()
   454     (* This detection code is an ugly hack. Fortunately, it is used only to
   455        provide a hint to the user. *)
   456     fun is_struct_induct_step (name, (Rule_Cases.Case {fixes, assumes, ...}, _)) =
   457       not (null fixes) andalso
   458       exists (String.isSuffix ".hyps" o fst) assumes andalso
   459       exists (exists (curry (op =) name o shortest_name o fst)
   460               o datatype_constrs hol_ctxt) deep_dataTs
   461     val likely_in_struct_induct_step =
   462       exists is_struct_induct_step (Proof_Context.cases_of ctxt)
   463     val _ = if standard andalso likely_in_struct_induct_step then
   464               pprint_nt (fn () => Pretty.blk (0,
   465                   pstrs "Hint: To check that the induction hypothesis is \
   466                         \general enough, try this command: " @
   467                   [Pretty.mark Isabelle_Markup.sendback (Pretty.blk (0,
   468                        pstrs ("nitpick [non_std, show_all]")))] @ pstrs "."))
   469             else
   470               ()
   471 (*
   472     val _ = print_g "Monotonic types:"
   473     val _ = List.app (print_g o string_for_type ctxt) mono_Ts
   474     val _ = print_g "Nonmonotonic types:"
   475     val _ = List.app (print_g o string_for_type ctxt) nonmono_Ts
   476 *)
   477 
   478     val incremental = Int.max (max_potential, max_genuine) >= 2
   479     val actual_sat_solver =
   480       if sat_solver <> "smart" then
   481         if incremental andalso
   482            not (member (op =) (Kodkod_SAT.configured_sat_solvers true)
   483                        sat_solver) then
   484           (print_nt (K ("An incremental SAT solver is required: \"SAT4J\" will \
   485                         \be used instead of " ^ quote sat_solver ^ "."));
   486            "SAT4J")
   487         else
   488           sat_solver
   489       else
   490         Kodkod_SAT.smart_sat_solver_name incremental
   491     val _ =
   492       if sat_solver = "smart" then
   493         print_v (fn () =>
   494             "Using SAT solver " ^ quote actual_sat_solver ^ ". The following" ^
   495             (if incremental then " incremental " else " ") ^
   496             "solvers are configured: " ^
   497             commas_quote (Kodkod_SAT.configured_sat_solvers incremental) ^ ".")
   498       else
   499         ()
   500 
   501     val too_big_scopes = Unsynchronized.ref []
   502 
   503     fun problem_for_scope unsound
   504             (scope as {card_assigns, bits, bisim_depth, datatypes, ofs, ...}) =
   505       let
   506         val _ = not (exists (fn other => scope_less_eq other scope)
   507                             (!too_big_scopes)) orelse
   508                 raise TOO_LARGE ("Nitpick.pick_them_nits_in_term.\
   509                                  \problem_for_scope", "too large scope")
   510 (*
   511         val _ = print_g "Offsets:"
   512         val _ = List.app (fn (T, j0) =>
   513                              print_g (string_for_type ctxt T ^ " = " ^
   514                                     string_of_int j0))
   515                          (Typtab.dest ofs)
   516 *)
   517         val effective_total_consts =
   518           case total_consts of
   519             SOME b => b
   520           | NONE => forall (is_exact_type datatypes true) all_Ts
   521         val main_j0 = offset_of_type ofs bool_T
   522         val (nat_card, nat_j0) = spec_of_type scope nat_T
   523         val (int_card, int_j0) = spec_of_type scope int_T
   524         val _ = (nat_j0 = main_j0 andalso int_j0 = main_j0) orelse
   525                 raise BAD ("Nitpick.pick_them_nits_in_term.problem_for_scope",
   526                            "bad offsets")
   527         val kk = kodkod_constrs peephole_optim nat_card int_card main_j0
   528         val (free_names, rep_table) =
   529           choose_reps_for_free_vars scope pseudo_frees free_names
   530                                     NameTable.empty
   531         val (sel_names, rep_table) = choose_reps_for_all_sels scope rep_table
   532         val (nonsel_names, rep_table) =
   533           choose_reps_for_consts scope effective_total_consts nonsel_names
   534                                  rep_table
   535         val (guiltiest_party, min_highest_arity) =
   536           NameTable.fold (fn (name, R) => fn (s, n) =>
   537                              let val n' = arity_of_rep R in
   538                                if n' > n then (nickname_of name, n') else (s, n)
   539                              end) rep_table ("", 1)
   540         val min_univ_card =
   541           NameTable.fold (Integer.max o min_univ_card_of_rep o snd) rep_table
   542                          (univ_card nat_card int_card main_j0 [] KK.True)
   543         val _ = if debug then ()
   544                 else check_arity guiltiest_party min_univ_card min_highest_arity
   545 
   546         val def_us =
   547           def_us |> map (choose_reps_in_nut scope unsound rep_table true)
   548         val nondef_us =
   549           nondef_us |> map (choose_reps_in_nut scope unsound rep_table false)
   550         val need_us =
   551           need_us |> map (choose_reps_in_nut scope unsound rep_table false)
   552 (*
   553         val _ = List.app (print_g o string_for_nut ctxt)
   554                          (free_names @ sel_names @ nonsel_names @
   555                           nondef_us @ def_us @ need_us)
   556 *)
   557         val (free_rels, pool, rel_table) =
   558           rename_free_vars free_names initial_pool NameTable.empty
   559         val (sel_rels, pool, rel_table) =
   560           rename_free_vars sel_names pool rel_table
   561         val (other_rels, pool, rel_table) =
   562           rename_free_vars nonsel_names pool rel_table
   563         val nondef_us = nondef_us |> map (rename_vars_in_nut pool rel_table)
   564         val def_us = def_us |> map (rename_vars_in_nut pool rel_table)
   565         val need_us = need_us |> map (rename_vars_in_nut pool rel_table)
   566         val nondef_fs = map (kodkod_formula_from_nut ofs kk) nondef_us
   567         val def_fs = map (kodkod_formula_from_nut ofs kk) def_us
   568         val formula = fold (fold s_and) [def_fs, nondef_fs] KK.True
   569         val comment = (if unsound then "unsound" else "sound") ^ "\n" ^
   570                       Print_Mode.setmp [] multiline_string_for_scope scope
   571         val kodkod_sat_solver =
   572           Kodkod_SAT.sat_solver_spec actual_sat_solver |> snd
   573         val bit_width = if bits = 0 then 16 else bits + 1
   574         val delay =
   575           if unsound then
   576             Option.map (fn time => Time.- (time, Time.now ())) deadline
   577             |> unsound_delay_for_timeout
   578           else
   579             0
   580         val settings = [("solver", commas_quote kodkod_sat_solver),
   581                         ("bit_width", string_of_int bit_width),
   582                         ("symmetry_breaking", string_of_int kodkod_sym_break),
   583                         ("sharing", "3"),
   584                         ("flatten", "false"),
   585                         ("delay", signed_string_of_int delay)]
   586         val plain_rels = free_rels @ other_rels
   587         val plain_bounds = map (bound_for_plain_rel ctxt debug) plain_rels
   588         val plain_axioms = map (declarative_axiom_for_plain_rel kk) plain_rels
   589         val need_vals =
   590           map (fn dtype as {typ, ...} =>
   591                   (typ, needed_values_for_datatype need_us ofs dtype)) datatypes
   592         val sel_bounds =
   593           map (bound_for_sel_rel ctxt debug need_vals datatypes) sel_rels
   594         val dtype_axioms =
   595           declarative_axioms_for_datatypes hol_ctxt binarize need_us need_vals
   596               datatype_sym_break bits ofs kk rel_table datatypes
   597         val declarative_axioms = plain_axioms @ dtype_axioms
   598         val univ_card = Int.max (univ_card nat_card int_card main_j0
   599                                      (plain_bounds @ sel_bounds) formula,
   600                                  main_j0 |> bits > 0 ? Integer.add (bits + 1))
   601         val (built_in_bounds, built_in_axioms) =
   602           bounds_and_axioms_for_built_in_rels_in_formulas debug univ_card
   603               nat_card int_card main_j0 (formula :: declarative_axioms)
   604         val bounds = built_in_bounds @ plain_bounds @ sel_bounds
   605                      |> not debug ? merge_bounds
   606         val axioms = built_in_axioms @ declarative_axioms
   607         val highest_arity =
   608           fold Integer.max (map (fst o fst) (maps fst bounds)) 0
   609         val formula = fold_rev s_and axioms formula
   610         val _ = if bits = 0 then () else check_bits bits formula
   611         val _ = if debug orelse formula = KK.False then ()
   612                 else check_arity "" univ_card highest_arity
   613       in
   614         SOME ({comment = comment, settings = settings, univ_card = univ_card,
   615                tuple_assigns = [], bounds = bounds,
   616                int_bounds = if bits = 0 then sequential_int_bounds univ_card
   617                             else pow_of_two_int_bounds bits main_j0,
   618                expr_assigns = [], formula = formula},
   619               {free_names = free_names, sel_names = sel_names,
   620                nonsel_names = nonsel_names, rel_table = rel_table,
   621                unsound = unsound, scope = scope})
   622       end
   623       handle TOO_LARGE (loc, msg) =>
   624              if loc = "Nitpick_Kodkod.check_arity" andalso
   625                 not (Typtab.is_empty ofs) then
   626                problem_for_scope unsound
   627                    {hol_ctxt = hol_ctxt, binarize = binarize,
   628                     card_assigns = card_assigns, bits = bits,
   629                     bisim_depth = bisim_depth, datatypes = datatypes,
   630                     ofs = Typtab.empty}
   631              else if loc = "Nitpick.pick_them_nits_in_term.\
   632                            \problem_for_scope" then
   633                NONE
   634              else
   635                (Unsynchronized.change too_big_scopes (cons scope);
   636                 print_v (fn () =>
   637                     "Limit reached: " ^ msg ^ ". Skipping " ^
   638                     (if unsound then "potential component of " else "") ^
   639                     "scope.");
   640                 NONE)
   641            | TOO_SMALL (_, msg) =>
   642              (print_v (fn () =>
   643                   "Limit reached: " ^ msg ^ ". Skipping " ^
   644                   (if unsound then "potential component of " else "") ^
   645                   "scope.");
   646               NONE)
   647 
   648     val das_wort_model =
   649       (if falsify then "counterexample" else "model")
   650       |> not standard ? prefix "nonstandard "
   651 
   652     val scopes = Unsynchronized.ref []
   653     val generated_scopes = Unsynchronized.ref []
   654     val generated_problems = Unsynchronized.ref ([] : rich_problem list)
   655     val checked_problems = Unsynchronized.ref (SOME [])
   656     val met_potential = Unsynchronized.ref 0
   657 
   658     fun update_checked_problems problems =
   659       List.app (Unsynchronized.change checked_problems o Option.map o cons
   660                 o nth problems)
   661     fun show_kodkod_warning "" = ()
   662       | show_kodkod_warning s = print_nt (fn () => "Kodkod warning: " ^ s ^ ".")
   663 
   664     fun print_and_check_model genuine bounds
   665             ({free_names, sel_names, nonsel_names, rel_table, scope, ...}
   666              : problem_extension) =
   667       let
   668         val (reconstructed_model, codatatypes_ok) =
   669           reconstruct_hol_model
   670               {show_datatypes = show_datatypes, show_skolems = show_skolems,
   671                show_consts = show_consts}
   672               scope formats atomss real_frees pseudo_frees free_names sel_names
   673               nonsel_names rel_table bounds
   674         val genuine_means_genuine =
   675           got_all_user_axioms andalso none_true wfs andalso
   676           sound_finitizes andalso total_consts <> SOME true andalso
   677           codatatypes_ok
   678         fun assms_prop () =
   679           Logic.mk_conjunction_list (neg_t :: def_assm_ts @ nondef_assm_ts)
   680       in
   681         (print_t (fn () =>
   682              "% SZS status " ^
   683              (if genuine then
   684                 if falsify then "CounterSatisfiable" else "Satisfiable"
   685               else
   686                 "Unknown") ^ "\n" ^
   687              "% SZS output start FiniteModel");
   688          pprint_a (Pretty.chunks
   689              [Pretty.blk (0,
   690                   (pstrs ((if mode = Auto_Try then "Auto " else "") ^
   691                           "Nitpick found a" ^
   692                           (if not genuine then " potentially spurious "
   693                            else if genuine_means_genuine then " "
   694                            else " quasi genuine ") ^ das_wort_model) @
   695                    (case pretties_for_scope scope verbose of
   696                       [] => []
   697                     | pretties => pstrs " for " @ pretties) @
   698                    [Pretty.str ":\n"])),
   699               Pretty.indent indent_size reconstructed_model]);
   700          print_t (K "% SZS output end FiniteModel");
   701          if genuine then
   702            (if check_genuine andalso standard then
   703               case prove_hol_model scope tac_timeout free_names sel_names
   704                                    rel_table bounds (assms_prop ()) of
   705                 SOME true =>
   706                 print ("Confirmation by \"auto\": The above " ^
   707                        das_wort_model ^ " is really genuine.")
   708               | SOME false =>
   709                 if genuine_means_genuine then
   710                   error ("A supposedly genuine " ^ das_wort_model ^ " was \
   711                          \shown to be spurious by \"auto\".\nThis should never \
   712                          \happen.\nPlease send a bug report to blanchet\
   713                          \te@in.tum.de.")
   714                  else
   715                    print ("Refutation by \"auto\": The above " ^
   716                           das_wort_model ^ " is spurious.")
   717                | NONE => print "No confirmation by \"auto\"."
   718             else
   719               ();
   720             if not standard andalso likely_in_struct_induct_step then
   721               print "The existence of a nonstandard model suggests that the \
   722                     \induction hypothesis is not general enough or may even be \
   723                     \wrong. See the Nitpick manual's \"Inductive Properties\" \
   724                     \section for details (\"isabelle doc nitpick\")."
   725             else
   726               ();
   727             if has_lonely_bool_var orig_t then
   728               print "Hint: Maybe you forgot a colon after the lemma's name?"
   729             else if has_syntactic_sorts orig_t then
   730               print "Hint: Maybe you forgot a type constraint?"
   731             else
   732               ();
   733             if not genuine_means_genuine then
   734               if no_poly_user_axioms then
   735                 let
   736                   val options =
   737                     [] |> not got_all_mono_user_axioms
   738                           ? cons ("user_axioms", "\"true\"")
   739                        |> not (none_true wfs)
   740                           ? cons ("wf", "\"smart\" or \"false\"")
   741                        |> not sound_finitizes
   742                           ? cons ("finitize", "\"smart\" or \"false\"")
   743                        |> total_consts = SOME true
   744                           ? cons ("total_consts", "\"smart\" or \"false\"")
   745                        |> not codatatypes_ok
   746                           ? cons ("bisim_depth", "a nonnegative value")
   747                   val ss =
   748                     map (fn (name, value) => quote name ^ " set to " ^ value)
   749                         options
   750                 in
   751                   print ("Try again with " ^
   752                          space_implode " " (serial_commas "and" ss) ^
   753                          " to confirm that the " ^ das_wort_model ^
   754                          " is genuine.")
   755                 end
   756               else
   757                 print ("Nitpick is unable to guarantee the authenticity of \
   758                        \the " ^ das_wort_model ^ " in the presence of \
   759                        \polymorphic axioms.")
   760             else
   761               ();
   762             NONE)
   763          else
   764            if not genuine then
   765              (Unsynchronized.inc met_potential;
   766               if check_potential then
   767                 let
   768                   val status = prove_hol_model scope tac_timeout free_names
   769                                                sel_names rel_table bounds
   770                                                (assms_prop ())
   771                 in
   772                   (case status of
   773                      SOME true => print ("Confirmation by \"auto\": The \
   774                                          \above " ^ das_wort_model ^
   775                                          " is genuine.")
   776                    | SOME false => print ("Refutation by \"auto\": The above " ^
   777                                           das_wort_model ^ " is spurious.")
   778                    | NONE => print "No confirmation by \"auto\".");
   779                   status
   780                 end
   781               else
   782                 NONE)
   783            else
   784              NONE)
   785         |> pair genuine_means_genuine
   786       end
   787     fun solve_any_problem (found_really_genuine, max_potential, max_genuine,
   788                            donno) first_time problems =
   789       let
   790         val max_potential = Int.max (0, max_potential)
   791         val max_genuine = Int.max (0, max_genuine)
   792         fun print_and_check genuine (j, bounds) =
   793           print_and_check_model genuine bounds (snd (nth problems j))
   794         val max_solutions = max_potential + max_genuine
   795                             |> not incremental ? Integer.min 1
   796       in
   797         if max_solutions <= 0 then
   798           (found_really_genuine, 0, 0, donno)
   799         else
   800           case KK.solve_any_problem debug overlord deadline max_threads
   801                                     max_solutions (map fst problems) of
   802             KK.JavaNotInstalled =>
   803             (print_nt install_java_message;
   804              (found_really_genuine, max_potential, max_genuine, donno + 1))
   805           | KK.JavaTooOld =>
   806             (print_nt install_java_message;
   807              (found_really_genuine, max_potential, max_genuine, donno + 1))
   808           | KK.KodkodiNotInstalled =>
   809             (print_nt install_kodkodi_message;
   810              (found_really_genuine, max_potential, max_genuine, donno + 1))
   811           | KK.Normal ([], unsat_js, s) =>
   812             (update_checked_problems problems unsat_js; show_kodkod_warning s;
   813              (found_really_genuine, max_potential, max_genuine, donno))
   814           | KK.Normal (sat_ps, unsat_js, s) =>
   815             let
   816               val (lib_ps, con_ps) =
   817                 List.partition (#unsound o snd o nth problems o fst) sat_ps
   818             in
   819               update_checked_problems problems (unsat_js @ map fst lib_ps);
   820               show_kodkod_warning s;
   821               if null con_ps then
   822                 let
   823                   val genuine_codes =
   824                     lib_ps |> take max_potential
   825                            |> map (print_and_check false)
   826                            |> filter (curry (op =) (SOME true) o snd)
   827                   val found_really_genuine =
   828                     found_really_genuine orelse exists fst genuine_codes
   829                   val num_genuine = length genuine_codes
   830                   val max_genuine = max_genuine - num_genuine
   831                   val max_potential = max_potential
   832                                       - (length lib_ps - num_genuine)
   833                 in
   834                   if max_genuine <= 0 then
   835                     (found_really_genuine, 0, 0, donno)
   836                   else
   837                     let
   838                       (* "co_js" is the list of sound problems whose unsound
   839                          pendants couldn't be satisfied and hence that most
   840                          probably can't be satisfied themselves. *)
   841                       val co_js =
   842                         map (fn j => j - 1) unsat_js
   843                         |> filter (fn j =>
   844                                       j >= 0 andalso
   845                                       scopes_equivalent
   846                                           (#scope (snd (nth problems j)),
   847                                            #scope (snd (nth problems (j + 1)))))
   848                       val bye_js = sort_distinct int_ord (map fst sat_ps @
   849                                                           unsat_js @ co_js)
   850                       val problems =
   851                         problems |> filter_out_indices bye_js
   852                                  |> max_potential <= 0
   853                                     ? filter_out (#unsound o snd)
   854                     in
   855                       solve_any_problem (found_really_genuine, max_potential,
   856                                          max_genuine, donno) false problems
   857                     end
   858                 end
   859               else
   860                 let
   861                   val genuine_codes =
   862                     con_ps |> take max_genuine
   863                            |> map (print_and_check true)
   864                   val max_genuine = max_genuine - length genuine_codes
   865                   val found_really_genuine =
   866                     found_really_genuine orelse exists fst genuine_codes
   867                 in
   868                   if max_genuine <= 0 orelse not first_time then
   869                     (found_really_genuine, 0, max_genuine, donno)
   870                   else
   871                     let
   872                       val bye_js = sort_distinct int_ord
   873                                                  (map fst sat_ps @ unsat_js)
   874                       val problems =
   875                         problems |> filter_out_indices bye_js
   876                                  |> filter_out (#unsound o snd)
   877                     in
   878                       solve_any_problem (found_really_genuine, 0, max_genuine,
   879                                          donno) false problems
   880                     end
   881                 end
   882             end
   883           | KK.TimedOut unsat_js =>
   884             (update_checked_problems problems unsat_js; raise TimeLimit.TimeOut)
   885           | KK.Error (s, unsat_js) =>
   886             (update_checked_problems problems unsat_js;
   887              print_v (K ("Kodkod error: " ^ s ^ "."));
   888              (found_really_genuine, max_potential, max_genuine, donno + 1))
   889       end
   890 
   891     fun run_batch j n scopes (found_really_genuine, max_potential, max_genuine,
   892                               donno) =
   893       let
   894         val _ =
   895           if null scopes then
   896             print_nt (K "The scope specification is inconsistent.")
   897           else if verbose then
   898             pprint_nt (fn () => Pretty.chunks
   899                 [Pretty.blk (0,
   900                      pstrs ((if n > 1 then
   901                                "Batch " ^ string_of_int (j + 1) ^ " of " ^
   902                                signed_string_of_int n ^ ": "
   903                              else
   904                                "") ^
   905                             "Trying " ^ string_of_int (length scopes) ^
   906                             " scope" ^ plural_s_for_list scopes ^ ":")),
   907                  Pretty.indent indent_size
   908                      (Pretty.chunks (map2
   909                           (fn j => fn scope =>
   910                               Pretty.block (
   911                                   (case pretties_for_scope scope true of
   912                                      [] => [Pretty.str "Empty"]
   913                                    | pretties => pretties) @
   914                                   [Pretty.str (if j = 1 then "." else ";")]))
   915                           (length scopes downto 1) scopes))])
   916           else
   917             ()
   918         fun add_problem_for_scope (scope, unsound) (problems, donno) =
   919           (check_deadline ();
   920            case problem_for_scope unsound scope of
   921              SOME problem =>
   922              (problems
   923               |> (null problems orelse
   924                   not (KK.problems_equivalent (fst problem, fst (hd problems))))
   925                   ? cons problem, donno)
   926            | NONE => (problems, donno + 1))
   927         val (problems, donno) =
   928           fold add_problem_for_scope
   929                (map_product pair scopes
   930                     ((if max_genuine > 0 then [false] else []) @
   931                      (if max_potential > 0 then [true] else [])))
   932                ([], donno)
   933         val _ = Unsynchronized.change generated_problems (append problems)
   934         val _ = Unsynchronized.change generated_scopes (append scopes)
   935         val _ =
   936           if j + 1 = n then
   937             let
   938               val (unsound_problems, sound_problems) =
   939                 List.partition (#unsound o snd) (!generated_problems)
   940             in
   941               if not (null sound_problems) andalso
   942                  forall (KK.is_problem_trivially_false o fst)
   943                         sound_problems then
   944                 print_nt (fn () =>
   945                     "Warning: The conjecture " ^
   946                     (if falsify then "either trivially holds"
   947                      else "is either trivially unsatisfiable") ^
   948                     " for the given scopes or lies outside Nitpick's supported \
   949                     \fragment." ^
   950                     (if exists (not o KK.is_problem_trivially_false o fst)
   951                                unsound_problems then
   952                        " Only potentially spurious " ^ das_wort_model ^
   953                        "s may be found."
   954                      else
   955                        ""))
   956               else
   957                 ()
   958             end
   959           else
   960             ()
   961       in
   962         solve_any_problem (found_really_genuine, max_potential, max_genuine,
   963                            donno) true (rev problems)
   964       end
   965 
   966     fun scope_count (problems : rich_problem list) scope =
   967       length (filter (curry scopes_equivalent scope o #scope o snd) problems)
   968     fun excipit did_so_and_so =
   969       let
   970         val do_filter =
   971           if !met_potential = max_potential then filter_out (#unsound o snd)
   972           else I
   973         val total = length (!scopes)
   974         val unsat =
   975           fold (fn scope =>
   976                    case scope_count (do_filter (!generated_problems)) scope of
   977                      0 => I
   978                    | n =>
   979                      scope_count (do_filter (these (!checked_problems)))
   980                                  scope = n
   981                      ? Integer.add 1) (!generated_scopes) 0
   982       in
   983         (if mode = TPTP then "% SZS status Unknown\n" else "") ^
   984         "Nitpick " ^ did_so_and_so ^
   985         (if is_some (!checked_problems) andalso total > 0 then
   986            " " ^ string_of_int unsat ^ " of " ^ string_of_int total ^ " scope"
   987            ^ plural_s total
   988          else
   989            "") ^ "."
   990       end
   991 
   992     val (skipped, the_scopes) =
   993       all_scopes hol_ctxt binarize cards_assigns maxes_assigns iters_assigns
   994                  bitss bisim_depths mono_Ts nonmono_Ts deep_dataTs
   995                  finitizable_dataTs
   996     val _ = if skipped > 0 then
   997               print_nt (fn () => "Too many scopes. Skipping " ^
   998                                  string_of_int skipped ^ " scope" ^
   999                                  plural_s skipped ^
  1000                                  ". (Consider using \"mono\" or \
  1001                                  \\"merge_type_vars\" to prevent this.)")
  1002             else
  1003               ()
  1004     val _ = scopes := the_scopes
  1005 
  1006     fun run_batches _ _ []
  1007                     (found_really_genuine, max_potential, max_genuine, donno) =
  1008         if donno > 0 andalso max_genuine > 0 then
  1009           (print_nt (fn () => excipit "checked"); unknownN)
  1010         else if max_genuine = original_max_genuine then
  1011           if max_potential = original_max_potential then
  1012             (print_t (K "% SZS status Unknown");
  1013              print_nt (fn () =>
  1014                  "Nitpick found no " ^ das_wort_model ^ "." ^
  1015                  (if not standard andalso likely_in_struct_induct_step then
  1016                     " This suggests that the induction hypothesis might be \
  1017                     \general enough to prove this subgoal."
  1018                   else
  1019                     "")); if skipped > 0 then unknownN else noneN)
  1020           else
  1021             (print_nt (fn () =>
  1022                  excipit ("could not find a" ^
  1023                           (if max_genuine = 1 then
  1024                              " better " ^ das_wort_model ^ "."
  1025                            else
  1026                              "ny better " ^ das_wort_model ^ "s.") ^
  1027                           " It checked"));
  1028              potentialN)
  1029         else if found_really_genuine then
  1030           genuineN
  1031         else
  1032           quasi_genuineN
  1033       | run_batches j n (batch :: batches) z =
  1034         let val (z as (_, _, max_genuine, _)) = run_batch j n batch z in
  1035           run_batches (j + 1) n (if max_genuine > 0 then batches else []) z
  1036         end
  1037 
  1038     val batches = batch_list batch_size (!scopes)
  1039     val outcome_code =
  1040       run_batches 0 (length batches) batches
  1041                   (false, max_potential, max_genuine, 0)
  1042       handle TimeLimit.TimeOut =>
  1043              (print_nt (fn () => excipit "ran out of time after checking");
  1044               if !met_potential > 0 then potentialN else unknownN)
  1045     val _ = print_v (fn () =>
  1046                 "Total time: " ^ string_from_time (Timer.checkRealTimer timer) ^
  1047                 ".")
  1048   in (outcome_code, !state_ref) end
  1049 
  1050 (* Give the inner timeout a chance. *)
  1051 val timeout_bonus = seconds 1.0
  1052 
  1053 fun pick_nits_in_term state (params as {debug, timeout, expect, ...}) mode i n
  1054                       step subst def_assm_ts nondef_assm_ts orig_t =
  1055   let
  1056     val print_nt = if is_mode_nt mode then Output.urgent_message else K ()
  1057     val print_t = if mode = TPTP then Output.urgent_message else K ()
  1058   in
  1059     if getenv "KODKODI" = "" then
  1060       (* The "expect" argument is deliberately ignored if Kodkodi is missing so
  1061          that the "Nitpick_Examples" can be processed on any machine. *)
  1062       (print_nt (Pretty.string_of (plazy install_kodkodi_message));
  1063        ("no_kodkodi", state))
  1064     else
  1065       let
  1066         val unknown_outcome = (unknownN, state)
  1067         val deadline = Option.map (curry Time.+ (Time.now ())) timeout
  1068         val outcome as (outcome_code, _) =
  1069           time_limit (if debug orelse is_none timeout then NONE
  1070                       else SOME (Time.+ (the timeout, timeout_bonus)))
  1071               (pick_them_nits_in_term deadline state params mode i n step subst
  1072                                       def_assm_ts nondef_assm_ts) orig_t
  1073           handle TOO_LARGE (_, details) =>
  1074                  (print_t "% SZS status Unknown";
  1075                   print_nt ("Limit reached: " ^ details ^ "."); unknown_outcome)
  1076                | TOO_SMALL (_, details) =>
  1077                  (print_t "% SZS status Unknown";
  1078                   print_nt ("Limit reached: " ^ details ^ "."); unknown_outcome)
  1079                | Kodkod.SYNTAX (_, details) =>
  1080                  (print_t "% SZS status Unknown";
  1081                   print_nt ("Malformed Kodkodi output: " ^ details ^ ".");
  1082                   unknown_outcome)
  1083                | TimeLimit.TimeOut =>
  1084                  (print_t "% SZS status TimedOut";
  1085                   print_nt "Nitpick ran out of time."; unknown_outcome)
  1086       in
  1087         if expect = "" orelse outcome_code = expect then outcome
  1088         else error ("Unexpected outcome: " ^ quote outcome_code ^ ".")
  1089       end
  1090   end
  1091 
  1092 fun is_fixed_equation ctxt
  1093                       (Const (@{const_name "=="}, _) $ Free (s, _) $ Const _) =
  1094     Variable.is_fixed ctxt s
  1095   | is_fixed_equation _ _ = false
  1096 fun extract_fixed_frees ctxt (assms, t) =
  1097   let
  1098     val (subst, other_assms) =
  1099       List.partition (is_fixed_equation ctxt) assms
  1100       |>> map Logic.dest_equals
  1101   in (subst, other_assms, subst_atomic subst t) end
  1102 
  1103 fun pick_nits_in_subgoal state params mode i step =
  1104   let
  1105     val ctxt = Proof.context_of state
  1106     val t = state |> Proof.raw_goal |> #goal |> prop_of
  1107   in
  1108     case Logic.count_prems t of
  1109       0 => (Output.urgent_message "No subgoal!"; (noneN, state))
  1110     | n =>
  1111       let
  1112         val t = Logic.goal_params t i |> fst
  1113         val assms = map term_of (Assumption.all_assms_of ctxt)
  1114         val (subst, assms, t) = extract_fixed_frees ctxt (assms, t)
  1115       in pick_nits_in_term state params mode i n step subst [] assms t end
  1116   end
  1117 
  1118 end;