src/Pure/axclass.ML
author wenzelm
Sun Apr 25 23:09:32 2010 +0200 (2010-04-25 ago)
changeset 36330 0584e203960e
parent 36329 85004134055c
child 36346 5518de23101d
permissions -rw-r--r--
renamed Drule.unconstrainTs to Thm.unconstrain_allTs to accomdate the version by krauss/schropp;
less pervasive names;
     1 (*  Title:      Pure/axclass.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Type classes defined as predicates, associated with a record of
     5 parameters.
     6 *)
     7 
     8 signature AX_CLASS =
     9 sig
    10   val define_class: binding * class list -> string list ->
    11     (Thm.binding * term list) list -> theory -> class * theory
    12   val add_classrel: thm -> theory -> theory
    13   val add_arity: thm -> theory -> theory
    14   val prove_classrel: class * class -> tactic -> theory -> theory
    15   val prove_arity: string * sort list * sort -> tactic -> theory -> theory
    16   type info = {def: thm, intro: thm, axioms: thm list, params: (string * typ) list}
    17   val get_info: theory -> class -> info
    18   val class_intros: theory -> thm list
    19   val class_of_param: theory -> string -> class option
    20   val cert_classrel: theory -> class * class -> class * class
    21   val read_classrel: theory -> xstring * xstring -> class * class
    22   val axiomatize_class: binding * class list -> theory -> theory
    23   val axiomatize_class_cmd: binding * xstring list -> theory -> theory
    24   val axiomatize_classrel: (class * class) list -> theory -> theory
    25   val axiomatize_classrel_cmd: (xstring * xstring) list -> theory -> theory
    26   val axiomatize_arity: arity -> theory -> theory
    27   val axiomatize_arity_cmd: xstring * string list * string -> theory -> theory
    28   val instance_name: string * class -> string
    29   val declare_overloaded: string * typ -> theory -> term * theory
    30   val define_overloaded: binding -> string * term -> theory -> thm * theory
    31   val unoverload: theory -> thm -> thm
    32   val overload: theory -> thm -> thm
    33   val unoverload_conv: theory -> conv
    34   val overload_conv: theory -> conv
    35   val unoverload_const: theory -> string * typ -> string
    36   val lookup_inst_param: Consts.T -> ((string * string) * 'a) list -> string * typ -> 'a option
    37   val param_of_inst: theory -> string * string -> string
    38   val inst_of_param: theory -> string -> (string * string) option
    39   val thynames_of_arity: theory -> class * string -> string list
    40 end;
    41 
    42 structure AxClass: AX_CLASS =
    43 struct
    44 
    45 (** theory data **)
    46 
    47 (* axclass info *)
    48 
    49 type info =
    50  {def: thm,
    51   intro: thm,
    52   axioms: thm list,
    53   params: (string * typ) list};
    54 
    55 fun make_axclass (def, intro, axioms, params): info =
    56   {def = def, intro = intro, axioms = axioms, params = params};
    57 
    58 
    59 (* class parameters (canonical order) *)
    60 
    61 type param = string * class;
    62 
    63 fun add_param pp ((x, c): param) params =
    64   (case AList.lookup (op =) params x of
    65     NONE => (x, c) :: params
    66   | SOME c' => error ("Duplicate class parameter " ^ quote x ^
    67       " for " ^ Pretty.string_of_sort pp [c] ^
    68       (if c = c' then "" else " and " ^ Pretty.string_of_sort pp [c'])));
    69 
    70 
    71 (* setup data *)
    72 
    73 datatype data = Data of
    74  {axclasses: info Symtab.table,
    75   params: param list,
    76   proven_classrels: (thm * proof) Symreltab.table,
    77   proven_arities: ((class * sort list) * ((thm * string) * proof)) list Symtab.table,
    78     (*arity theorems with theory name*)
    79   inst_params:
    80     (string * thm) Symtab.table Symtab.table *
    81       (*constant name ~> type constructor ~> (constant name, equation)*)
    82     (string * string) Symtab.table (*constant name ~> (constant name, type constructor)*),
    83   diff_merge_classrels: (class * class) list};
    84 
    85 fun make_data
    86     (axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels) =
    87   Data {axclasses = axclasses, params = params, proven_classrels = proven_classrels,
    88     proven_arities = proven_arities, inst_params = inst_params,
    89     diff_merge_classrels = diff_merge_classrels};
    90 
    91 structure Data = Theory_Data_PP
    92 (
    93   type T = data;
    94   val empty =
    95     make_data (Symtab.empty, [], Symreltab.empty, Symtab.empty, (Symtab.empty, Symtab.empty), []);
    96   val extend = I;
    97   fun merge pp
    98       (Data {axclasses = axclasses1, params = params1, proven_classrels = proven_classrels1,
    99         proven_arities = proven_arities1, inst_params = inst_params1,
   100         diff_merge_classrels = diff_merge_classrels1},
   101        Data {axclasses = axclasses2, params = params2, proven_classrels = proven_classrels2,
   102         proven_arities = proven_arities2, inst_params = inst_params2,
   103         diff_merge_classrels = diff_merge_classrels2}) =
   104     let
   105       val axclasses' = Symtab.merge (K true) (axclasses1, axclasses2);
   106       val params' =
   107         if null params1 then params2
   108         else fold_rev (fn q => if member (op =) params1 q then I else add_param pp q) params2 params1;
   109 
   110       (*transitive closure of classrels and arity completion is done in Theory.at_begin hook*)
   111       val proven_classrels' = Symreltab.join (K #1) (proven_classrels1, proven_classrels2);
   112       val proven_arities' =
   113         Symtab.join (K (Library.merge (eq_fst op =))) (proven_arities1, proven_arities2);
   114 
   115       val classrels1 = Symreltab.keys proven_classrels1;
   116       val classrels2 = Symreltab.keys proven_classrels2;
   117       val diff_merge_classrels' =
   118         subtract (op =) classrels1 classrels2 @
   119         subtract (op =) classrels2 classrels1 @
   120         diff_merge_classrels1 @ diff_merge_classrels2;
   121 
   122       val inst_params' =
   123         (Symtab.join (K (Symtab.merge (K true))) (#1 inst_params1, #1 inst_params2),
   124           Symtab.merge (K true) (#2 inst_params1, #2 inst_params2));
   125     in
   126       make_data (axclasses', params', proven_classrels', proven_arities', inst_params',
   127         diff_merge_classrels')
   128     end;
   129 );
   130 
   131 fun map_data f =
   132   Data.map (fn Data {axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels} =>
   133     make_data (f (axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels)));
   134 
   135 fun map_axclasses f =
   136   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels) =>
   137     (f axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels));
   138 
   139 fun map_params f =
   140   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels) =>
   141     (axclasses, f params, proven_classrels, proven_arities, inst_params, diff_merge_classrels));
   142 
   143 fun map_proven_classrels f =
   144   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels) =>
   145     (axclasses, params, f proven_classrels, proven_arities, inst_params, diff_merge_classrels));
   146 
   147 fun map_proven_arities f =
   148   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels) =>
   149     (axclasses, params, proven_classrels, f proven_arities, inst_params, diff_merge_classrels));
   150 
   151 fun map_inst_params f =
   152   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels) =>
   153     (axclasses, params, proven_classrels, proven_arities, f inst_params, diff_merge_classrels));
   154 
   155 val clear_diff_merge_classrels =
   156   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, _) =>
   157     (axclasses, params, proven_classrels, proven_arities, inst_params, []));
   158 
   159 val rep_data = Data.get #> (fn Data args => args);
   160 
   161 val axclasses_of = #axclasses o rep_data;
   162 val params_of = #params o rep_data;
   163 val proven_classrels_of = #proven_classrels o rep_data;
   164 val proven_arities_of = #proven_arities o rep_data;
   165 val inst_params_of = #inst_params o rep_data;
   166 val diff_merge_classrels_of = #diff_merge_classrels o rep_data;
   167 
   168 
   169 (* maintain axclasses *)
   170 
   171 fun get_info thy c =
   172   (case Symtab.lookup (axclasses_of thy) c of
   173     SOME info => info
   174   | NONE => error ("No such axclass: " ^ quote c));
   175 
   176 fun class_intros thy =
   177   let
   178     fun add_intro c = (case try (get_info thy) c of SOME {intro, ...} => cons intro | _ => I);
   179     val classes = Sign.all_classes thy;
   180   in map (Thm.class_triv thy) classes @ fold add_intro classes [] end;
   181 
   182 
   183 (* maintain params *)
   184 
   185 fun all_params_of thy S =
   186   let val params = params_of thy;
   187   in fold (fn (x, c) => if Sign.subsort thy (S, [c]) then cons x else I) params [] end;
   188 
   189 fun class_of_param thy = AList.lookup (op =) (params_of thy);
   190 
   191 
   192 (* maintain instances *)
   193 
   194 val classrel_prefix = "classrel_";
   195 val arity_prefix = "arity_";
   196 
   197 fun instance_name (a, c) = Long_Name.base_name c ^ "_" ^ Long_Name.base_name a;
   198 
   199 
   200 fun the_classrel thy (c1, c2) =
   201   (case Symreltab.lookup (proven_classrels_of thy) (c1, c2) of
   202     SOME classrel => classrel
   203   | NONE => error ("Unproven class relation " ^
   204       Syntax.string_of_classrel (ProofContext.init thy) [c1, c2]));
   205 
   206 fun the_classrel_thm thy = Thm.transfer thy o #1 o the_classrel thy;
   207 fun the_classrel_prf thy = #2 o the_classrel thy;
   208 
   209 fun put_trancl_classrel ((c1, c2), th) thy =
   210   let
   211     val cert = Thm.cterm_of thy;
   212     val certT = Thm.ctyp_of thy;
   213 
   214     val classes = Sorts.classes_of (Sign.classes_of thy);
   215     val classrels = proven_classrels_of thy;
   216 
   217     fun reflcl_classrel (c1', c2') =
   218       if c1' = c2'
   219       then Thm.trivial (cert (Logic.mk_of_class (TVar ((Name.aT, 0), []), c1')))
   220       else the_classrel_thm thy (c1', c2');
   221     fun gen_classrel (c1_pred, c2_succ) =
   222       let
   223         val th' = ((reflcl_classrel (c1_pred, c1) RS th) RS reflcl_classrel (c2, c2_succ))
   224           |> Drule.instantiate' [SOME (certT (TVar ((Name.aT, 0), [])))] []
   225           |> Thm.close_derivation;
   226         val prf' = Thm.proof_of th';
   227       in ((c1_pred, c2_succ), (th', prf')) end;
   228 
   229     val new_classrels =
   230       Library.map_product pair (c1 :: Graph.imm_preds classes c1) (c2 :: Graph.imm_succs classes c2)
   231       |> filter_out (Symreltab.defined classrels)
   232       |> map gen_classrel;
   233     val needed = not (null new_classrels);
   234   in
   235     (needed,
   236       if needed then map_proven_classrels (fold Symreltab.update new_classrels) thy
   237       else thy)
   238   end;
   239 
   240 fun complete_classrels thy =
   241   let
   242     val classrels = proven_classrels_of thy;
   243     val diff_merge_classrels = diff_merge_classrels_of thy;
   244     val (needed, thy') = (false, thy) |>
   245       fold (fn c12 => fn (needed, thy) =>
   246           put_trancl_classrel (c12, Symreltab.lookup classrels c12 |> the |> #1) thy
   247           |>> (fn b => needed orelse b))
   248         diff_merge_classrels;
   249   in
   250     if null diff_merge_classrels then NONE
   251     else SOME (clear_diff_merge_classrels thy')
   252   end;
   253 
   254 
   255 fun the_arity thy a (c, Ss) =
   256   (case AList.lookup (op =) (Symtab.lookup_list (proven_arities_of thy) a) (c, Ss) of
   257     SOME arity => arity
   258   | NONE => error ("Unproven type arity " ^
   259       Syntax.string_of_arity (ProofContext.init thy) (a, Ss, [c])));
   260 
   261 fun the_arity_thm thy a c_Ss = the_arity thy a c_Ss |> #1 |> #1 |> Thm.transfer thy;
   262 fun the_arity_prf thy a c_Ss = the_arity thy a c_Ss |> #2;
   263 
   264 fun thynames_of_arity thy (c, a) =
   265   Symtab.lookup_list (proven_arities_of thy) a
   266   |> map_filter (fn ((c', _), ((_, name),_)) => if c = c' then SOME name else NONE)
   267   |> rev;
   268 
   269 fun insert_arity_completions thy (t, ((c, Ss), ((th, thy_name), _))) arities =
   270   let
   271     val algebra = Sign.classes_of thy;
   272     val super_class_completions =
   273       Sign.super_classes thy c
   274       |> filter_out (fn c1 => exists (fn ((c2, Ss2), _) => c1 = c2
   275           andalso Sorts.sorts_le algebra (Ss2, Ss)) (Symtab.lookup_list arities t));
   276     val names_and_Ss = Name.names Name.context Name.aT (map (K []) Ss);
   277     val completions = super_class_completions |> map (fn c1 =>
   278       let
   279         val th1 = (th RS the_classrel_thm thy (c, c1))
   280           |> Drule.instantiate' (map (SOME o ctyp_of thy o TVar o apfst (rpair 0)) names_and_Ss) []
   281           |> Thm.close_derivation;
   282         val prf1 = Thm.proof_of th1;
   283       in (((th1, thy_name), prf1), c1) end);
   284     val arities' = fold (fn (th_thy_prf1, c1) => Symtab.cons_list (t, ((c1, Ss), th_thy_prf1)))
   285       completions arities;
   286   in (null completions, arities') end;
   287 
   288 fun put_arity ((t, Ss, c), th) thy =
   289   let
   290     val arity' = (t, ((c, Ss), ((th, Context.theory_name thy), Thm.proof_of th)));
   291   in
   292     thy
   293     |> map_proven_arities
   294       (Symtab.insert_list (eq_fst op =) arity' #>
   295         insert_arity_completions thy arity' #> snd)
   296   end;
   297 
   298 fun complete_arities thy =
   299   let
   300     val arities = proven_arities_of thy;
   301     val (finished, arities') = arities
   302       |> fold_map (insert_arity_completions thy) (Symtab.dest_list arities);
   303   in
   304     if forall I finished
   305     then NONE
   306     else SOME (map_proven_arities (K arities') thy)
   307   end;
   308 
   309 val _ = Context.>> (Context.map_theory
   310   (Theory.at_begin complete_classrels #> Theory.at_begin complete_arities));
   311 
   312 
   313 (* maintain instance parameters *)
   314 
   315 fun get_inst_param thy (c, tyco) =
   316   (case Symtab.lookup (the_default Symtab.empty (Symtab.lookup (#1 (inst_params_of thy)) c)) tyco of
   317     SOME c' => c'
   318   | NONE => error ("No instance parameter for constant " ^ quote c ^ " on type " ^ quote tyco));
   319 
   320 fun add_inst_param (c, tyco) inst =
   321   (map_inst_params o apfst o Symtab.map_default (c, Symtab.empty)) (Symtab.update_new (tyco, inst))
   322   #> (map_inst_params o apsnd) (Symtab.update_new (fst inst, (c, tyco)));
   323 
   324 val inst_of_param = Symtab.lookup o #2 o inst_params_of;
   325 val param_of_inst = fst oo get_inst_param;
   326 
   327 fun inst_thms thy =
   328   Symtab.fold (Symtab.fold (cons o #2 o #2) o #2) (#1 (inst_params_of thy)) [];
   329 
   330 fun get_inst_tyco consts = try (fst o dest_Type o the_single o Consts.typargs consts);
   331 
   332 fun unoverload thy = MetaSimplifier.simplify true (inst_thms thy);
   333 fun overload thy = MetaSimplifier.simplify true (map Thm.symmetric (inst_thms thy));
   334 
   335 fun unoverload_conv thy = MetaSimplifier.rewrite true (inst_thms thy);
   336 fun overload_conv thy = MetaSimplifier.rewrite true (map Thm.symmetric (inst_thms thy));
   337 
   338 fun lookup_inst_param consts params (c, T) =
   339   (case get_inst_tyco consts (c, T) of
   340     SOME tyco => AList.lookup (op =) params (c, tyco)
   341   | NONE => NONE);
   342 
   343 fun unoverload_const thy (c_ty as (c, _)) =
   344   if is_some (class_of_param thy c) then
   345     (case get_inst_tyco (Sign.consts_of thy) c_ty of
   346       SOME tyco => try (param_of_inst thy) (c, tyco) |> the_default c
   347     | NONE => c)
   348   else c;
   349 
   350 
   351 
   352 (** instances **)
   353 
   354 (* class relations *)
   355 
   356 fun cert_classrel thy raw_rel =
   357   let
   358     val string_of_sort = Syntax.string_of_sort_global thy;
   359     val (c1, c2) = pairself (Sign.certify_class thy) raw_rel;
   360     val _ = Sign.primitive_classrel (c1, c2) (Theory.copy thy);
   361     val _ =
   362       (case subtract (op =) (all_params_of thy [c1]) (all_params_of thy [c2]) of
   363         [] => ()
   364       | xs => raise TYPE ("Class " ^ string_of_sort [c1] ^ " lacks parameter(s) " ^
   365           commas_quote xs ^ " of " ^ string_of_sort [c2], [], []));
   366   in (c1, c2) end;
   367 
   368 fun read_classrel thy raw_rel =
   369   cert_classrel thy (pairself (ProofContext.read_class (ProofContext.init thy)) raw_rel)
   370     handle TYPE (msg, _, _) => error msg;
   371 
   372 
   373 (* declaration and definition of instances of overloaded constants *)
   374 
   375 fun inst_tyco_of thy (c, T) =
   376   (case get_inst_tyco (Sign.consts_of thy) (c, T) of
   377     SOME tyco => tyco
   378   | NONE => error ("Illegal type for instantiation of class parameter: " ^
   379       quote (c ^ " :: " ^ Syntax.string_of_typ_global thy T)));
   380 
   381 fun declare_overloaded (c, T) thy =
   382   let
   383     val class =
   384       (case class_of_param thy c of
   385         SOME class => class
   386       | NONE => error ("Not a class parameter: " ^ quote c));
   387     val tyco = inst_tyco_of thy (c, T);
   388     val name_inst = instance_name (tyco, class) ^ "_inst";
   389     val c' = Long_Name.base_name c ^ "_" ^ Long_Name.base_name tyco;
   390     val T' = Type.strip_sorts T;
   391   in
   392     thy
   393     |> Sign.qualified_path true (Binding.name name_inst)
   394     |> Sign.declare_const ((Binding.name c', T'), NoSyn)
   395     |-> (fn const' as Const (c'', _) =>
   396       Thm.add_def false true
   397         (Binding.name (Thm.def_name c'), Logic.mk_equals (Const (c, T'), const'))
   398       #>> apsnd Thm.varifyT_global
   399       #-> (fn (_, thm) => add_inst_param (c, tyco) (c'', thm)
   400         #> PureThy.add_thm ((Binding.conceal (Binding.name c'), thm), [])
   401         #> snd
   402         #> pair (Const (c, T))))
   403     ||> Sign.restore_naming thy
   404   end;
   405 
   406 fun define_overloaded b (c, t) thy =
   407   let
   408     val T = Term.fastype_of t;
   409     val tyco = inst_tyco_of thy (c, T);
   410     val (c', eq) = get_inst_param thy (c, tyco);
   411     val prop = Logic.mk_equals (Const (c', T), t);
   412     val b' = Thm.def_binding_optional
   413       (Binding.name (Long_Name.base_name c ^ "_" ^ Long_Name.base_name tyco)) b;
   414   in
   415     thy
   416     |> Thm.add_def false false (b', prop)
   417     |>> (fn (_, thm) =>  Drule.transitive_thm OF [eq, thm])
   418   end;
   419 
   420 
   421 (* primitive rules *)
   422 
   423 val shyps_topped = forall null o #shyps o Thm.rep_thm;
   424 
   425 fun add_classrel raw_th thy =
   426   let
   427     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   428     val prop = Thm.plain_prop_of th;
   429     fun err () = raise THM ("add_classrel: malformed class relation", 0, [th]);
   430     val rel = Logic.dest_classrel prop handle TERM _ => err ();
   431     val (c1, c2) = cert_classrel thy rel handle TYPE _ => err ();
   432     val th' = th
   433       |> Drule.instantiate' [SOME (ctyp_of thy (TVar ((Name.aT, 0), [c1])))] []
   434       |> Thm.unconstrain_allTs;
   435     val _ = shyps_topped th' orelse raise Fail "add_classrel: nontop shyps after unconstrain";
   436   in
   437     thy
   438     |> Sign.primitive_classrel (c1, c2)
   439     |> (snd oo put_trancl_classrel) ((c1, c2), th')
   440     |> perhaps complete_arities
   441   end;
   442 
   443 fun add_arity raw_th thy =
   444   let
   445     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   446     val prop = Thm.plain_prop_of th;
   447     fun err () = raise THM ("add_arity: malformed type arity", 0, [th]);
   448     val (t, Ss, c) = Logic.dest_arity prop handle TERM _ => err ();
   449     val names = Name.names Name.context Name.aT Ss;
   450     val T = Type (t, map TFree names);
   451     val missing_params = Sign.complete_sort thy [c]
   452       |> maps (these o Option.map #params o try (get_info thy))
   453       |> filter_out (fn (const, _) => can (get_inst_param thy) (const, t))
   454       |> (map o apsnd o map_atyps) (K T);
   455     val _ = map (Sign.certify_sort thy) Ss = Ss orelse err ();
   456     val th' = th
   457       |> Drule.instantiate' (map (SOME o ctyp_of thy o TVar o apfst (rpair 0)) names) []
   458       |> Thm.unconstrain_allTs;
   459     val _ = shyps_topped th' orelse raise Fail "add_arity: nontop shyps after unconstrain";
   460   in
   461     thy
   462     |> fold (snd oo declare_overloaded) missing_params
   463     |> Sign.primitive_arity (t, Ss, [c])
   464     |> put_arity ((t, Ss, c), th')
   465   end;
   466 
   467 
   468 (* tactical proofs *)
   469 
   470 fun prove_classrel raw_rel tac thy =
   471   let
   472     val ctxt = ProofContext.init thy;
   473     val (c1, c2) = cert_classrel thy raw_rel;
   474     val th = Goal.prove ctxt [] [] (Logic.mk_classrel (c1, c2)) (K tac) handle ERROR msg =>
   475       cat_error msg ("The error(s) above occurred while trying to prove class relation " ^
   476         quote (Syntax.string_of_classrel ctxt [c1, c2]));
   477   in
   478     thy
   479     |> PureThy.add_thms [((Binding.name
   480         (prefix classrel_prefix (Logic.name_classrel (c1, c2))), th), [])]
   481     |-> (fn [th'] => add_classrel th')
   482   end;
   483 
   484 fun prove_arity raw_arity tac thy =
   485   let
   486     val ctxt = ProofContext.init thy;
   487     val arity = ProofContext.cert_arity ctxt raw_arity;
   488     val names = map (prefix arity_prefix) (Logic.name_arities arity);
   489     val props = Logic.mk_arities arity;
   490     val ths = Goal.prove_multi ctxt [] [] props
   491       (fn _ => Goal.precise_conjunction_tac (length props) 1 THEN tac) handle ERROR msg =>
   492         cat_error msg ("The error(s) above occurred while trying to prove type arity " ^
   493           quote (Syntax.string_of_arity ctxt arity));
   494   in
   495     thy
   496     |> PureThy.add_thms (map (rpair []) (map Binding.name names ~~ ths))
   497     |-> fold add_arity
   498   end;
   499 
   500 
   501 
   502 (** class definitions **)
   503 
   504 fun split_defined n eq =
   505   let
   506     val intro =
   507       (eq RS Drule.equal_elim_rule2)
   508       |> Conjunction.curry_balanced n
   509       |> n = 0 ? Thm.eq_assumption 1;
   510     val dests =
   511       if n = 0 then []
   512       else
   513         (eq RS Drule.equal_elim_rule1)
   514         |> Balanced_Tree.dest (fn th =>
   515           (th RS Conjunction.conjunctionD1, th RS Conjunction.conjunctionD2)) n;
   516   in (intro, dests) end;
   517 
   518 fun define_class (bclass, raw_super) raw_params raw_specs thy =
   519   let
   520     val ctxt = ProofContext.init thy;
   521     val pp = Syntax.pp ctxt;
   522 
   523 
   524     (* class *)
   525 
   526     val bconst = Binding.map_name Logic.const_of_class bclass;
   527     val class = Sign.full_name thy bclass;
   528     val super = Sign.minimize_sort thy (Sign.certify_sort thy raw_super);
   529 
   530     fun check_constraint (a, S) =
   531       if Sign.subsort thy (super, S) then ()
   532       else error ("Sort constraint of type variable " ^
   533         setmp_CRITICAL show_sorts true (Pretty.string_of_typ pp) (TFree (a, S)) ^
   534         " needs to be weaker than " ^ Pretty.string_of_sort pp super);
   535 
   536 
   537     (* params *)
   538 
   539     val params = raw_params |> map (fn p =>
   540       let
   541         val T = Sign.the_const_type thy p;
   542         val _ =
   543           (case Term.add_tvarsT T [] of
   544             [((a, _), S)] => check_constraint (a, S)
   545           | _ => error ("Exactly one type variable expected in class parameter " ^ quote p));
   546         val T' = Term.map_type_tvar (fn _ => TFree (Name.aT, [class])) T;
   547       in (p, T') end);
   548 
   549 
   550     (* axioms *)
   551 
   552     fun prep_axiom t =
   553       (case Term.add_tfrees t [] of
   554         [(a, S)] => check_constraint (a, S)
   555       | [] => ()
   556       | _ => error ("Multiple type variables in class axiom:\n" ^ Pretty.string_of_term pp t);
   557       t
   558       |> Term.map_types (Term.map_atyps (fn TFree _ => Term.aT [] | U => U))
   559       |> Logic.close_form);
   560 
   561     val axiomss = map (map (prep_axiom o Sign.cert_prop thy) o snd) raw_specs;
   562     val name_atts = map fst raw_specs;
   563 
   564 
   565     (* definition *)
   566 
   567     val conjs = Logic.mk_of_sort (Term.aT [], super) @ flat axiomss;
   568     val class_eq =
   569       Logic.mk_equals (Logic.mk_of_class (Term.aT [], class), Logic.mk_conjunction_balanced conjs);
   570 
   571     val ([def], def_thy) =
   572       thy
   573       |> Sign.primitive_class (bclass, super)
   574       |> PureThy.add_defs false [((Thm.def_binding bconst, class_eq), [])];
   575     val (raw_intro, (raw_classrel, raw_axioms)) =
   576       split_defined (length conjs) def ||> chop (length super);
   577 
   578 
   579     (* facts *)
   580 
   581     val class_triv = Thm.class_triv def_thy class;
   582     val ([(_, [intro]), (_, classrel), (_, axioms)], facts_thy) =
   583       def_thy
   584       |> Sign.qualified_path true bconst
   585       |> PureThy.note_thmss ""
   586         [((Binding.name "intro", []), [([Drule.export_without_context raw_intro], [])]),
   587          ((Binding.name "super", []), [(map Drule.export_without_context raw_classrel, [])]),
   588          ((Binding.name "axioms", []),
   589            [(map (fn th => Drule.export_without_context (class_triv RS th)) raw_axioms, [])])]
   590       ||> Sign.restore_naming def_thy;
   591 
   592 
   593     (* result *)
   594 
   595     val axclass = make_axclass (def, intro, axioms, params);
   596     val result_thy =
   597       facts_thy
   598       |> fold (snd oo put_trancl_classrel) (map (pair class) super ~~ classrel)
   599       |> Sign.qualified_path false bconst
   600       |> PureThy.note_thmss "" (name_atts ~~ map Thm.simple_fact (unflat axiomss axioms)) |> snd
   601       |> Sign.restore_naming facts_thy
   602       |> map_axclasses (Symtab.update (class, axclass))
   603       |> map_params (fold (fn (x, _) => add_param pp (x, class)) params);
   604 
   605   in (class, result_thy) end;
   606 
   607 
   608 
   609 (** axiomatizations **)
   610 
   611 local
   612 
   613 (* old-style axioms *)
   614 
   615 fun add_axiom (b, prop) =
   616   Thm.add_axiom (b, prop) #->
   617   (fn (_, thm) => PureThy.add_thm ((b, Drule.export_without_context thm), []));
   618 
   619 fun axiomatize prep mk name add raw_args thy =
   620   let
   621     val args = prep thy raw_args;
   622     val specs = mk args;
   623     val names = name args;
   624   in
   625     thy
   626     |> fold_map add_axiom (map Binding.name names ~~ specs)
   627     |-> fold add
   628   end;
   629 
   630 fun ax_classrel prep =
   631   axiomatize (map o prep) (map Logic.mk_classrel)
   632     (map (prefix classrel_prefix o Logic.name_classrel)) add_classrel;
   633 
   634 fun ax_arity prep =
   635   axiomatize (prep o ProofContext.init) Logic.mk_arities
   636     (map (prefix arity_prefix) o Logic.name_arities) add_arity;
   637 
   638 fun class_const c =
   639   (Logic.const_of_class c, Term.itselfT (Term.aT []) --> propT);
   640 
   641 fun ax_class prep_class prep_classrel (bclass, raw_super) thy =
   642   let
   643     val class = Sign.full_name thy bclass;
   644     val super = map (prep_class thy) raw_super |> Sign.minimize_sort thy;
   645   in
   646     thy
   647     |> Sign.primitive_class (bclass, super)
   648     |> ax_classrel prep_classrel (map (fn c => (class, c)) super)
   649     |> Theory.add_deps "" (class_const class) (map class_const super)
   650   end;
   651 
   652 in
   653 
   654 val axiomatize_class = ax_class Sign.certify_class cert_classrel;
   655 val axiomatize_class_cmd = ax_class (ProofContext.read_class o ProofContext.init) read_classrel;
   656 val axiomatize_classrel = ax_classrel cert_classrel;
   657 val axiomatize_classrel_cmd = ax_classrel read_classrel;
   658 val axiomatize_arity = ax_arity ProofContext.cert_arity;
   659 val axiomatize_arity_cmd = ax_arity ProofContext.read_arity;
   660 
   661 end;
   662 
   663 end;