src/Pure/tctical.ML
author wenzelm
Thu May 31 23:47:36 2007 +0200 (2007-05-31 ago)
changeset 23178 07ba6b58b3d2
parent 23139 aa899bce7c3b
child 23224 e9fb2ff046fc
permissions -rw-r--r--
simplified/unified list fold;
     1 (*  Title:      Pure/tctical.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Tacticals.
     7 *)
     8 
     9 infix 1 THEN THEN' THEN_ALL_NEW;
    10 infix 0 ORELSE APPEND INTLEAVE ORELSE' APPEND' INTLEAVE';
    11 infix 0 THEN_ELSE;
    12 
    13 
    14 signature TACTICAL =
    15 sig
    16   type tactic  (* = thm -> thm Seq.seq*)
    17   val all_tac           : tactic
    18   val ALLGOALS          : (int -> tactic) -> tactic
    19   val APPEND            : tactic * tactic -> tactic
    20   val APPEND'           : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    21   val CHANGED           : tactic -> tactic
    22   val CHANGED_PROP      : tactic -> tactic
    23   val CHANGED_GOAL      : (int -> tactic) -> int -> tactic
    24   val COND              : (thm -> bool) -> tactic -> tactic -> tactic
    25   val DETERM            : tactic -> tactic
    26   val EVERY             : tactic list -> tactic
    27   val EVERY'            : ('a -> tactic) list -> 'a -> tactic
    28   val EVERY1            : (int -> tactic) list -> tactic
    29   val FILTER            : (thm -> bool) -> tactic -> tactic
    30   val FIRST             : tactic list -> tactic
    31   val FIRST'            : ('a -> tactic) list -> 'a -> tactic
    32   val FIRST1            : (int -> tactic) list -> tactic
    33   val FIRSTGOAL         : (int -> tactic) -> tactic
    34   val INTLEAVE          : tactic * tactic -> tactic
    35   val INTLEAVE'         : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    36   val METAHYPS          : (thm list -> tactic) -> int -> tactic
    37   val metahyps_thms     : int -> thm -> thm list option
    38   val no_tac            : tactic
    39   val ORELSE            : tactic * tactic -> tactic
    40   val ORELSE'           : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    41   val pause_tac         : tactic
    42   val print_tac         : string -> tactic
    43   val PRIMITIVE         : (thm -> thm) -> tactic
    44   val PRIMSEQ           : (thm -> thm Seq.seq) -> tactic
    45   val RANGE             : (int -> tactic) list -> int -> tactic
    46   val REPEAT            : tactic -> tactic
    47   val REPEAT1           : tactic -> tactic
    48   val REPEAT_FIRST      : (int -> tactic) -> tactic
    49   val REPEAT_SOME       : (int -> tactic) -> tactic
    50   val REPEAT_DETERM_N   : int -> tactic -> tactic
    51   val REPEAT_DETERM     : tactic -> tactic
    52   val REPEAT_DETERM1    : tactic -> tactic
    53   val REPEAT_DETERM_FIRST: (int -> tactic) -> tactic
    54   val REPEAT_DETERM_SOME: (int -> tactic) -> tactic
    55   val DETERM_UNTIL      : (thm -> bool) -> tactic -> tactic
    56   val SINGLE            : tactic -> thm -> thm option
    57   val SOMEGOAL          : (int -> tactic) -> tactic
    58   val strip_context     : term -> (string * typ) list * term list * term
    59   val SUBGOAL           : ((term*int) -> tactic) -> int -> tactic
    60   val suppress_tracing  : bool ref
    61   val THEN              : tactic * tactic -> tactic
    62   val THEN'             : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    63   val THEN_ALL_NEW      : (int -> tactic) * (int -> tactic) -> int -> tactic
    64   val REPEAT_ALL_NEW    : (int -> tactic) -> int -> tactic
    65   val THEN_ELSE         : tactic * (tactic*tactic) -> tactic
    66   val traced_tac        : (thm -> (thm * thm Seq.seq) option) -> tactic
    67   val tracify           : bool ref -> tactic -> tactic
    68   val trace_REPEAT      : bool ref
    69   val TRY               : tactic -> tactic
    70   val TRYALL            : (int -> tactic) -> tactic
    71 end;
    72 
    73 
    74 structure Tactical : TACTICAL =
    75 struct
    76 
    77 (**** Tactics ****)
    78 
    79 (*A tactic maps a proof tree to a sequence of proof trees:
    80     if length of sequence = 0 then the tactic does not apply;
    81     if length > 1 then backtracking on the alternatives can occur.*)
    82 
    83 type tactic = thm -> thm Seq.seq;
    84 
    85 
    86 (*** LCF-style tacticals ***)
    87 
    88 (*the tactical THEN performs one tactic followed by another*)
    89 fun (tac1 THEN tac2) st = Seq.maps tac2 (tac1 st);
    90 
    91 
    92 (*The tactical ORELSE uses the first tactic that returns a nonempty sequence.
    93   Like in LCF, ORELSE commits to either tac1 or tac2 immediately.
    94   Does not backtrack to tac2 if tac1 was initially chosen. *)
    95 fun (tac1 ORELSE tac2) st =
    96     case Seq.pull(tac1 st) of
    97         NONE       => tac2 st
    98       | sequencecell => Seq.make(fn()=> sequencecell);
    99 
   100 
   101 (*The tactical APPEND combines the results of two tactics.
   102   Like ORELSE, but allows backtracking on both tac1 and tac2.
   103   The tactic tac2 is not applied until needed.*)
   104 fun (tac1 APPEND tac2) st =
   105   Seq.append (tac1 st) (Seq.make(fn()=> Seq.pull (tac2 st)));
   106 
   107 (*Like APPEND, but interleaves results of tac1 and tac2.*)
   108 fun (tac1 INTLEAVE tac2) st =
   109     Seq.interleave(tac1 st,
   110                         Seq.make(fn()=> Seq.pull (tac2 st)));
   111 
   112 (*Conditional tactic.
   113         tac1 ORELSE tac2 = tac1 THEN_ELSE (all_tac, tac2)
   114         tac1 THEN tac2   = tac1 THEN_ELSE (tac2, no_tac)
   115 *)
   116 fun (tac THEN_ELSE (tac1, tac2)) st =
   117     case Seq.pull(tac st) of
   118         NONE    => tac2 st                                   (*failed; try tactic 2*)
   119       | seqcell => Seq.maps tac1 (Seq.make(fn()=> seqcell)); (*succeeded; use tactic 1*)
   120 
   121 
   122 (*Versions for combining tactic-valued functions, as in
   123      SOMEGOAL (resolve_tac rls THEN' assume_tac) *)
   124 fun (tac1 THEN' tac2) x = tac1 x THEN tac2 x;
   125 fun (tac1 ORELSE' tac2) x = tac1 x ORELSE tac2 x;
   126 fun (tac1 APPEND' tac2) x = tac1 x APPEND tac2 x;
   127 fun (tac1 INTLEAVE' tac2) x = tac1 x INTLEAVE tac2 x;
   128 
   129 (*passes all proofs through unchanged;  identity of THEN*)
   130 fun all_tac st = Seq.single st;
   131 
   132 (*passes no proofs through;  identity of ORELSE and APPEND*)
   133 fun no_tac st  = Seq.empty;
   134 
   135 
   136 (*Make a tactic deterministic by chopping the tail of the proof sequence*)
   137 fun DETERM tac = Seq.DETERM tac;
   138 
   139 (*Conditional tactical: testfun controls which tactic to use next.
   140   Beware: due to eager evaluation, both thentac and elsetac are evaluated.*)
   141 fun COND testfun thenf elsef = (fn prf =>
   142     if testfun prf then  thenf prf   else  elsef prf);
   143 
   144 (*Do the tactic or else do nothing*)
   145 fun TRY tac = tac ORELSE all_tac;
   146 
   147 (*** List-oriented tactics ***)
   148 
   149 local
   150   (*This version of EVERY avoids backtracking over repeated states*)
   151 
   152   fun EVY (trail, []) st =
   153         Seq.make (fn()=> SOME(st,
   154                         Seq.make (fn()=> Seq.pull (evyBack trail))))
   155     | EVY (trail, tac::tacs) st =
   156           case Seq.pull(tac st) of
   157               NONE    => evyBack trail              (*failed: backtrack*)
   158             | SOME(st',q) => EVY ((st',q,tacs)::trail, tacs) st'
   159   and evyBack [] = Seq.empty (*no alternatives*)
   160     | evyBack ((st',q,tacs)::trail) =
   161           case Seq.pull q of
   162               NONE        => evyBack trail
   163             | SOME(st,q') => if Thm.eq_thm (st',st)
   164                              then evyBack ((st',q',tacs)::trail)
   165                              else EVY ((st,q',tacs)::trail, tacs) st
   166 in
   167 
   168 (* EVERY [tac1,...,tacn]   equals    tac1 THEN ... THEN tacn   *)
   169 fun EVERY tacs = EVY ([], tacs);
   170 end;
   171 
   172 
   173 (* EVERY' [tac1,...,tacn] i  equals    tac1 i THEN ... THEN tacn i   *)
   174 fun EVERY' tacs i = EVERY (map (fn f => f i) tacs);
   175 
   176 (*Apply every tactic to 1*)
   177 fun EVERY1 tacs = EVERY' tacs 1;
   178 
   179 (* FIRST [tac1,...,tacn]   equals    tac1 ORELSE ... ORELSE tacn   *)
   180 fun FIRST tacs = fold_rev (curry op ORELSE) tacs no_tac;
   181 
   182 (* FIRST' [tac1,...,tacn] i  equals    tac1 i ORELSE ... ORELSE tacn i   *)
   183 fun FIRST' tacs = fold_rev (curry op ORELSE') tacs (K no_tac);
   184 
   185 (*Apply first tactic to 1*)
   186 fun FIRST1 tacs = FIRST' tacs 1;
   187 
   188 (*Apply tactics on consecutive subgoals*)
   189 fun RANGE [] _ = all_tac
   190   | RANGE (tac :: tacs) i = RANGE tacs (i + 1) THEN tac i;
   191 
   192 
   193 (*** Tracing tactics ***)
   194 
   195 (*Print the current proof state and pass it on.*)
   196 fun print_tac msg =
   197     (fn st =>
   198      (tracing msg;
   199       tracing ((Pretty.string_of o Pretty.chunks o 
   200                  Display.pretty_goals (! Display.goals_limit)) st); 
   201       Seq.single st));
   202 
   203 (*Pause until a line is typed -- if non-empty then fail. *)
   204 fun pause_tac st =
   205   (tracing "** Press RETURN to continue:";
   206    if TextIO.inputLine TextIO.stdIn = SOME "\n" then Seq.single st
   207    else (tracing "Goodbye";  Seq.empty));
   208 
   209 exception TRACE_EXIT of thm
   210 and TRACE_QUIT;
   211 
   212 (*Tracing flags*)
   213 val trace_REPEAT= ref false
   214 and suppress_tracing = ref false;
   215 
   216 (*Handle all tracing commands for current state and tactic *)
   217 fun exec_trace_command flag (tac, st) =
   218    case TextIO.inputLine TextIO.stdIn of
   219        SOME "\n" => tac st
   220      | SOME "f\n" => Seq.empty
   221      | SOME "o\n" => (flag:=false;  tac st)
   222      | SOME "s\n" => (suppress_tracing:=true;  tac st)
   223      | SOME "x\n" => (tracing "Exiting now";  raise (TRACE_EXIT st))
   224      | SOME "quit\n" => raise TRACE_QUIT
   225      | _     => (tracing
   226 "Type RETURN to continue or...\n\
   227 \     f    - to fail here\n\
   228 \     o    - to switch tracing off\n\
   229 \     s    - to suppress tracing until next entry to a tactical\n\
   230 \     x    - to exit at this point\n\
   231 \     quit - to abort this tracing run\n\
   232 \** Well? "     ;  exec_trace_command flag (tac, st));
   233 
   234 
   235 (*Extract from a tactic, a thm->thm seq function that handles tracing*)
   236 fun tracify flag tac st =
   237   if !flag andalso not (!suppress_tracing)
   238            then (Display.print_goals (! Display.goals_limit) st;
   239                  tracing "** Press RETURN to continue:";
   240                  exec_trace_command flag (tac,st))
   241   else tac st;
   242 
   243 (*Create a tactic whose outcome is given by seqf, handling TRACE_EXIT*)
   244 fun traced_tac seqf st =
   245     (suppress_tracing := false;
   246      Seq.make (fn()=> seqf st
   247                          handle TRACE_EXIT st' => SOME(st', Seq.empty)));
   248 
   249 
   250 (*Deterministic DO..UNTIL: only retains the first outcome; tail recursive.
   251   Forces repitition until predicate on state is fulfilled.*)
   252 fun DETERM_UNTIL p tac =
   253 let val tac = tracify trace_REPEAT tac
   254     fun drep st = if p st then SOME (st, Seq.empty)
   255                           else (case Seq.pull(tac st) of
   256                                   NONE        => NONE
   257                                 | SOME(st',_) => drep st')
   258 in  traced_tac drep  end;
   259 
   260 (*Deterministic REPEAT: only retains the first outcome;
   261   uses less space than REPEAT; tail recursive.
   262   If non-negative, n bounds the number of repetitions.*)
   263 fun REPEAT_DETERM_N n tac =
   264   let val tac = tracify trace_REPEAT tac
   265       fun drep 0 st = SOME(st, Seq.empty)
   266         | drep n st =
   267            (case Seq.pull(tac st) of
   268                 NONE       => SOME(st, Seq.empty)
   269               | SOME(st',_) => drep (n-1) st')
   270   in  traced_tac (drep n)  end;
   271 
   272 (*Allows any number of repetitions*)
   273 val REPEAT_DETERM = REPEAT_DETERM_N ~1;
   274 
   275 (*General REPEAT: maintains a stack of alternatives; tail recursive*)
   276 fun REPEAT tac =
   277   let val tac = tracify trace_REPEAT tac
   278       fun rep qs st =
   279         case Seq.pull(tac st) of
   280             NONE       => SOME(st, Seq.make(fn()=> repq qs))
   281           | SOME(st',q) => rep (q::qs) st'
   282       and repq [] = NONE
   283         | repq(q::qs) = case Seq.pull q of
   284             NONE       => repq qs
   285           | SOME(st,q) => rep (q::qs) st
   286   in  traced_tac (rep [])  end;
   287 
   288 (*Repeat 1 or more times*)
   289 fun REPEAT_DETERM1 tac = DETERM tac THEN REPEAT_DETERM tac;
   290 fun REPEAT1 tac = tac THEN REPEAT tac;
   291 
   292 
   293 (** Filtering tacticals **)
   294 
   295 fun FILTER pred tac st = Seq.filter pred (tac st);
   296 
   297 (*Accept only next states that change the theorem somehow*)
   298 fun CHANGED tac st =
   299   let fun diff st' = not (Thm.eq_thm (st, st'));
   300   in Seq.filter diff (tac st) end;
   301 
   302 (*Accept only next states that change the theorem's prop field
   303   (changes to signature, hyps, etc. don't count)*)
   304 fun CHANGED_PROP tac st =
   305   let fun diff st' = not (Thm.eq_thm_prop (st, st'));
   306   in Seq.filter diff (tac st) end;
   307 
   308 
   309 (*** Tacticals based on subgoal numbering ***)
   310 
   311 (*For n subgoals, performs tac(n) THEN ... THEN tac(1)
   312   Essential to work backwards since tac(i) may add/delete subgoals at i. *)
   313 fun ALLGOALS tac st =
   314   let fun doall 0 = all_tac
   315         | doall n = tac(n) THEN doall(n-1)
   316   in  doall(nprems_of st)st  end;
   317 
   318 (*For n subgoals, performs tac(n) ORELSE ... ORELSE tac(1)  *)
   319 fun SOMEGOAL tac st =
   320   let fun find 0 = no_tac
   321         | find n = tac(n) ORELSE find(n-1)
   322   in  find(nprems_of st)st  end;
   323 
   324 (*For n subgoals, performs tac(1) ORELSE ... ORELSE tac(n).
   325   More appropriate than SOMEGOAL in some cases.*)
   326 fun FIRSTGOAL tac st =
   327   let fun find (i,n) = if i>n then no_tac else  tac(i) ORELSE find (i+1,n)
   328   in  find(1, nprems_of st)st  end;
   329 
   330 (*Repeatedly solve some using tac. *)
   331 fun REPEAT_SOME tac = REPEAT1 (SOMEGOAL (REPEAT1 o tac));
   332 fun REPEAT_DETERM_SOME tac = REPEAT_DETERM1 (SOMEGOAL (REPEAT_DETERM1 o tac));
   333 
   334 (*Repeatedly solve the first possible subgoal using tac. *)
   335 fun REPEAT_FIRST tac = REPEAT1 (FIRSTGOAL (REPEAT1 o tac));
   336 fun REPEAT_DETERM_FIRST tac = REPEAT_DETERM1 (FIRSTGOAL (REPEAT_DETERM1 o tac));
   337 
   338 (*For n subgoals, tries to apply tac to n,...1  *)
   339 fun TRYALL tac = ALLGOALS (TRY o tac);
   340 
   341 
   342 (*Make a tactic for subgoal i, if there is one.  *)
   343 fun SUBGOAL goalfun i st =
   344   (case try Logic.nth_prem (i, Thm.prop_of st) of
   345     SOME goal => goalfun (goal, i) st
   346   | NONE => Seq.empty);
   347 
   348 (*Returns all states that have changed in subgoal i, counted from the LAST
   349   subgoal.  For stac, for example.*)
   350 fun CHANGED_GOAL tac i st =
   351     let val np = nprems_of st
   352         val d = np-i                 (*distance from END*)
   353         val t = List.nth(prems_of st, i-1)
   354         fun diff st' =
   355             nprems_of st' - d <= 0   (*the subgoal no longer exists*)
   356             orelse
   357              not (Pattern.aeconv (t,
   358                                   List.nth(prems_of st',
   359                                            nprems_of st' - d - 1)))
   360     in  Seq.filter diff (tac i st)  end
   361     handle Subscript => Seq.empty  (*no subgoal i*);
   362 
   363 fun (tac1 THEN_ALL_NEW tac2) i st =
   364   st |> (tac1 i THEN (fn st' => Seq.INTERVAL tac2 i (i + nprems_of st' - nprems_of st) st'));
   365 
   366 (*repeatedly dig into any emerging subgoals*)
   367 fun REPEAT_ALL_NEW tac =
   368   tac THEN_ALL_NEW (TRY o (fn i => REPEAT_ALL_NEW tac i));
   369 
   370 
   371 (*Strips assumptions in goal yielding  ( [x1,...,xm], [H1,...,Hn], B )
   372     H1,...,Hn are the hypotheses;  x1...xm are variants of the parameters.
   373   Main difference from strip_assums concerns parameters:
   374     it replaces the bound variables by free variables.  *)
   375 fun strip_context_aux (params, Hs, Const("==>", _) $ H $ B) =
   376         strip_context_aux (params, H::Hs, B)
   377   | strip_context_aux (params, Hs, Const("all",_)$Abs(a,T,t)) =
   378         let val (b,u) = Syntax.variant_abs(a,T,t)
   379         in  strip_context_aux ((b,T)::params, Hs, u)  end
   380   | strip_context_aux (params, Hs, B) = (rev params, rev Hs, B);
   381 
   382 fun strip_context A = strip_context_aux ([],[],A);
   383 
   384 
   385 (**** METAHYPS -- tactical for using hypotheses as meta-level assumptions
   386        METAHYPS (fn prems => tac prems) i
   387 
   388 converts subgoal i, of the form !!x1...xm. [| A1;...;An] ==> A into a new
   389 proof state A==>A, supplying A1,...,An as meta-level assumptions (in
   390 "prems").  The parameters x1,...,xm become free variables.  If the
   391 resulting proof state is [| B1;...;Bk] ==> C (possibly assuming A1,...,An)
   392 then it is lifted back into the original context, yielding k subgoals.
   393 
   394 Replaces unknowns in the context by Frees having the prefix METAHYP_
   395 New unknowns in [| B1;...;Bk] ==> C are lifted over x1,...,xm.
   396 DOES NOT HANDLE TYPE UNKNOWNS.
   397 ****)
   398 
   399 local
   400 
   401   (*Left-to-right replacements: ctpairs = [...,(vi,ti),...].
   402     Instantiates distinct free variables by terms of same type.*)
   403   fun free_instantiate ctpairs =
   404       forall_elim_list (map snd ctpairs) o forall_intr_list (map fst ctpairs);
   405 
   406   fun free_of s ((a,i), T) =
   407         Free(s ^ (case i of 0 => a | _ => a ^ "_" ^ string_of_int i),
   408              T)
   409 
   410   fun mk_inst (var as Var(v,T))  = (var,  free_of "METAHYP1_" (v,T))
   411 in
   412 
   413 (*Common code for METAHYPS and metahyps_thms*)
   414 fun metahyps_split_prem prem =
   415   let (*find all vars in the hyps -- should find tvars also!*)
   416       val hyps_vars = List.foldr add_term_vars [] (Logic.strip_assums_hyp prem)
   417       val insts = map mk_inst hyps_vars
   418       (*replace the hyps_vars by Frees*)
   419       val prem' = subst_atomic insts prem
   420       val (params,hyps,concl) = strip_context prem'
   421   in (insts,params,hyps,concl)  end;
   422 
   423 fun metahyps_aux_tac tacf (prem,gno) state =
   424   let val (insts,params,hyps,concl) = metahyps_split_prem prem 
   425       val {thy = sign,maxidx,...} = rep_thm state
   426       val cterm = cterm_of sign
   427       val chyps = map cterm hyps
   428       val hypths = map assume chyps
   429       val subprems = map (forall_elim_vars 0) hypths
   430       val fparams = map Free params
   431       val cparams = map cterm fparams
   432       fun swap_ctpair (t,u) = (cterm u, cterm t)
   433       (*Subgoal variables: make Free; lift type over params*)
   434       fun mk_subgoal_inst concl_vars (var as Var(v,T)) =
   435           if member (op =) concl_vars var
   436           then (var, true, free_of "METAHYP2_" (v,T))
   437           else (var, false,
   438                 free_of "METAHYP2_" (v, map #2 params --->T))
   439       (*Instantiate subgoal vars by Free applied to params*)
   440       fun mk_ctpair (t,in_concl,u) =
   441           if in_concl then (cterm t,  cterm u)
   442           else (cterm t,  cterm (list_comb (u,fparams)))
   443       (*Restore Vars with higher type and index*)
   444       fun mk_subgoal_swap_ctpair
   445                 (t as Var((a,i),_), in_concl, u as Free(_,U)) =
   446           if in_concl then (cterm u, cterm t)
   447           else (cterm u, cterm(Var((a, i+maxidx), U)))
   448       (*Embed B in the original context of params and hyps*)
   449       fun embed B = list_all_free (params, Logic.list_implies (hyps, B))
   450       (*Strip the context using elimination rules*)
   451       fun elim Bhyp = implies_elim_list (forall_elim_list cparams Bhyp) hypths
   452       (*A form of lifting that discharges assumptions.*)
   453       fun relift st =
   454         let val prop = Thm.prop_of st
   455             val subgoal_vars = (*Vars introduced in the subgoals*)
   456                   List.foldr add_term_vars [] (Logic.strip_imp_prems prop)
   457             and concl_vars = add_term_vars (Logic.strip_imp_concl prop, [])
   458             val subgoal_insts = map (mk_subgoal_inst concl_vars) subgoal_vars
   459             val st' = Thm.instantiate ([], map mk_ctpair subgoal_insts) st
   460             val emBs = map (cterm o embed) (prems_of st')
   461             val Cth  = implies_elim_list st' (map (elim o assume) emBs)
   462         in  (*restore the unknowns to the hypotheses*)
   463             free_instantiate (map swap_ctpair insts @
   464                               map mk_subgoal_swap_ctpair subgoal_insts)
   465                 (*discharge assumptions from state in same order*)
   466                 (implies_intr_list emBs
   467                   (forall_intr_list cparams (implies_intr_list chyps Cth)))
   468         end
   469       (*function to replace the current subgoal*)
   470       fun next st = bicompose false (false, relift st, nprems_of st)
   471                     gno state
   472   in Seq.maps next (tacf subprems (trivial (cterm concl))) end;
   473 
   474 end;
   475 
   476 (*Returns the theorem list that METAHYPS would supply to its tactic*)
   477 fun metahyps_thms i state =
   478   let val prem = Logic.nth_prem (i, Thm.prop_of state) 
   479       val (insts,params,hyps,concl) = metahyps_split_prem prem 
   480       val cterm = cterm_of (Thm.theory_of_thm state)
   481   in SOME (map (forall_elim_vars 0 o assume o cterm) hyps) end
   482   handle TERM ("nth_prem", [A]) => NONE;
   483 
   484 local
   485 
   486 fun print_vars_terms thy (n,thm) =
   487   let
   488     fun typed ty = " has type: " ^ Sign.string_of_typ thy ty;
   489     fun find_vars thy (Const (c, ty)) =
   490         (case Term.typ_tvars ty
   491          of [] => I
   492           | _ => insert (op =) (c ^ typed ty))
   493       | find_vars thy (Var (xi, ty)) = insert (op =) (Term.string_of_vname xi ^ typed ty)
   494       | find_vars _ (Free _) = I
   495       | find_vars _ (Bound _) = I
   496       | find_vars thy (Abs (_, _, t)) = find_vars thy t
   497       | find_vars thy (t1 $ t2) = 
   498           find_vars thy t1 #> find_vars thy t1;
   499     val prem = Logic.nth_prem (n, Thm.prop_of thm)
   500     val tms = find_vars thy prem []
   501   in
   502     (warning "Found schematic vars in assumptions:"; warning (cat_lines tms))
   503   end;
   504 
   505 in
   506 
   507 fun METAHYPS tacf n thm = SUBGOAL (metahyps_aux_tac tacf) n thm
   508     handle THM("assume: variables",_,_) => (print_vars_terms (theory_of_thm thm) (n,thm); Seq.empty)
   509 
   510 end; (*local*)
   511 
   512 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm seq.*)
   513 fun PRIMSEQ thmfun st =  thmfun st handle THM _ => Seq.empty;
   514 
   515 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm.*)
   516 fun PRIMITIVE thmfun = PRIMSEQ (Seq.single o thmfun);
   517 
   518 (* Inverse (more or less) of PRIMITIVE *)
   519 fun SINGLE tacf = Option.map fst o Seq.pull o tacf
   520 
   521 end;
   522 
   523 open Tactical;