src/Pure/PIDE/document.ML
author wenzelm
Sat Mar 09 23:57:07 2019 +0100 (2 months ago ago)
changeset 70067 0cb8753bdb50
parent 70064 f8293bf510a0
permissions -rw-r--r--
clarified signature;
     1 (*  Title:      Pure/PIDE/document.ML
     2     Author:     Makarius
     3 
     4 Document as collection of named nodes, each consisting of an editable
     5 list of commands, associated with asynchronous execution process.
     6 *)
     7 
     8 signature DOCUMENT =
     9 sig
    10   val timing: bool Unsynchronized.ref
    11   type node_header = {master: string, header: Thy_Header.header, errors: string list}
    12   type overlay = Document_ID.command * (string * string list)
    13   datatype node_edit =
    14     Edits of (Document_ID.command option * Document_ID.command option) list |
    15     Deps of node_header |
    16     Perspective of bool * Document_ID.command list * overlay list
    17   type edit = string * node_edit
    18   type state
    19   val init_state: state
    20   val define_blob: string -> string -> state -> state
    21   type blob_digest = (string * string option) Exn.result
    22   val define_command: Document_ID.command -> string -> blob_digest list -> int ->
    23     ((int * int) * string) list -> state -> state
    24   val command_exec: state -> string -> Document_ID.command -> Command.exec option
    25   val remove_versions: Document_ID.version list -> state -> state
    26   val start_execution: state -> state
    27   val update: Document_ID.version -> Document_ID.version -> edit list -> string list -> state ->
    28     Document_ID.exec list * (Document_ID.command * Document_ID.exec list) list * state
    29   val state: unit -> state
    30   val change_state: (state -> state) -> unit
    31 end;
    32 
    33 structure Document: DOCUMENT =
    34 struct
    35 
    36 val timing = Unsynchronized.ref false;
    37 fun timeit msg e = cond_timeit (! timing) msg e;
    38 
    39 
    40 
    41 (** document structure **)
    42 
    43 fun err_dup kind id = error ("Duplicate " ^ kind ^ ": " ^ Document_ID.print id);
    44 fun err_undef kind id = error ("Undefined " ^ kind ^ ": " ^ Document_ID.print id);
    45 
    46 type node_header =
    47   {master: string, header: Thy_Header.header, errors: string list};
    48 
    49 type perspective =
    50  {required: bool,  (*required node*)
    51   visible: Inttab.set,  (*visible commands*)
    52   visible_last: Document_ID.command option,  (*last visible command*)
    53   overlays: (string * string list) list Inttab.table};  (*command id -> print functions with args*)
    54 
    55 structure Entries = Linear_Set(type key = Document_ID.command val ord = int_ord);
    56 
    57 abstype node = Node of
    58  {header: node_header,  (*master directory, theory header, errors*)
    59   keywords: Keyword.keywords option,  (*outer syntax keywords*)
    60   perspective: perspective,  (*command perspective*)
    61   entries: Command.exec option Entries.T,  (*command entries with executions*)
    62   result: (Document_ID.command * Command.eval) option,  (*result of last execution*)
    63   consolidated: unit lazy}  (*consolidated status of eval forks*)
    64 and version = Version of node String_Graph.T  (*development graph wrt. static imports*)
    65 with
    66 
    67 fun make_node (header, keywords, perspective, entries, result, consolidated) =
    68   Node {header = header, keywords = keywords, perspective = perspective,
    69     entries = entries, result = result, consolidated = consolidated};
    70 
    71 fun map_node f (Node {header, keywords, perspective, entries, result, consolidated}) =
    72   make_node (f (header, keywords, perspective, entries, result, consolidated));
    73 
    74 fun make_perspective (required, command_ids, overlays) : perspective =
    75  {required = required,
    76   visible = Inttab.make_set command_ids,
    77   visible_last = try List.last command_ids,
    78   overlays = Inttab.make_list overlays};
    79 
    80 val no_header: node_header =
    81   {master = "", header = Thy_Header.make ("", Position.none) [] [], errors = []};
    82 val no_perspective = make_perspective (false, [], []);
    83 
    84 val empty_node =
    85   make_node (no_header, NONE, no_perspective, Entries.empty, NONE, Lazy.value ());
    86 
    87 fun is_no_perspective ({required, visible, visible_last, overlays}: perspective) =
    88   not required andalso
    89   Inttab.is_empty visible andalso
    90   is_none visible_last andalso
    91   Inttab.is_empty overlays;
    92 
    93 fun is_empty_node (Node {header, keywords, perspective, entries, result, consolidated}) =
    94   header = no_header andalso
    95   is_none keywords andalso
    96   is_no_perspective perspective andalso
    97   Entries.is_empty entries andalso
    98   is_none result andalso
    99   Lazy.is_finished consolidated;
   100 
   101 
   102 (* basic components *)
   103 
   104 fun master_directory (Node {header = {master, ...}, ...}) =
   105   (case try Url.explode master of
   106     SOME (Url.File path) => path
   107   | _ => Path.current);
   108 
   109 fun set_header master header errors =
   110   map_node (fn (_, keywords, perspective, entries, result, consolidated) =>
   111     ({master = master, header = header, errors = errors},
   112       keywords, perspective, entries, result, consolidated));
   113 
   114 fun get_header (Node {header, ...}) = header;
   115 
   116 fun set_keywords keywords =
   117   map_node (fn (header, _, perspective, entries, result, consolidated) =>
   118     (header, keywords, perspective, entries, result, consolidated));
   119 
   120 fun get_keywords (Node {keywords, ...}) = keywords;
   121 
   122 fun read_header node span =
   123   let
   124     val {header, errors, ...} = get_header node;
   125     val _ =
   126       if null errors then ()
   127       else
   128         cat_lines errors |>
   129         (case Position.get_id (Position.thread_data ()) of
   130           NONE => I
   131         | SOME id => Protocol_Message.command_positions_yxml id)
   132         |> error;
   133     val {name = (name, _), imports, ...} = header;
   134     val {name = (_, pos), imports = imports', keywords} =
   135       Thy_Header.read_tokens Position.none span;
   136     val imports'' = (map #1 imports ~~ map #2 imports') handle ListPair.UnequalLengths => imports;
   137   in Thy_Header.make (name, pos) imports'' keywords end;
   138 
   139 fun get_perspective (Node {perspective, ...}) = perspective;
   140 
   141 fun set_perspective args =
   142   map_node (fn (header, keywords, _, entries, result, consolidated) =>
   143     (header, keywords, make_perspective args, entries, result, consolidated));
   144 
   145 val required_node = #required o get_perspective;
   146 val visible_command = Inttab.defined o #visible o get_perspective;
   147 val visible_last = #visible_last o get_perspective;
   148 val visible_node = is_some o visible_last
   149 val overlays = Inttab.lookup_list o #overlays o get_perspective;
   150 
   151 fun map_entries f =
   152   map_node (fn (header, keywords, perspective, entries, result, consolidated) =>
   153     (header, keywords, perspective, f entries, result, consolidated));
   154 
   155 fun get_entries (Node {entries, ...}) = entries;
   156 
   157 fun iterate_entries f = Entries.iterate NONE f o get_entries;
   158 fun iterate_entries_after start f (Node {entries, ...}) =
   159   (case Entries.get_after entries start of
   160     NONE => I
   161   | SOME id => Entries.iterate (SOME id) f entries);
   162 
   163 fun get_result (Node {result, ...}) = result;
   164 
   165 fun set_result result =
   166   map_node (fn (header, keywords, perspective, entries, _, consolidated) =>
   167     (header, keywords, perspective, entries, result, consolidated));
   168 
   169 fun pending_result node =
   170   (case get_result node of
   171     SOME (_, eval) => not (Command.eval_finished eval)
   172   | NONE => false);
   173 
   174 fun finished_result node =
   175   (case get_result node of
   176     SOME (_, eval) => Command.eval_finished eval
   177   | NONE => false);
   178 
   179 fun finished_result_theory node =
   180   if finished_result node then
   181     let
   182       val (result_id, eval) = the (get_result node);
   183       val st = Command.eval_result_state eval;
   184     in SOME (result_id, Toplevel.end_theory Position.none st) handle ERROR _ => NONE end
   185   else NONE;
   186 
   187 val reset_consolidated =
   188   map_node (fn (header, keywords, perspective, entries, result, _) =>
   189     (header, keywords, perspective, entries, result, Lazy.lazy I));
   190 
   191 fun get_consolidated (Node {consolidated, ...}) = consolidated;
   192 
   193 val is_consolidated = Lazy.is_finished o get_consolidated;
   194 
   195 fun commit_consolidated node =
   196   (Lazy.force (get_consolidated node); Output.status (Markup.markup_only Markup.consolidated));
   197 
   198 fun could_consolidate node =
   199   not (is_consolidated node) andalso is_some (finished_result_theory node);
   200 
   201 fun get_node nodes name = String_Graph.get_node nodes name
   202   handle String_Graph.UNDEF _ => empty_node;
   203 fun default_node name = String_Graph.default_node (name, empty_node);
   204 fun update_node name f = default_node name #> String_Graph.map_node name f;
   205 
   206 
   207 (* node edits and associated executions *)
   208 
   209 type overlay = Document_ID.command * (string * string list);
   210 
   211 datatype node_edit =
   212   Edits of (Document_ID.command option * Document_ID.command option) list |
   213   Deps of node_header |
   214   Perspective of bool * Document_ID.command list * overlay list;
   215 
   216 type edit = string * node_edit;
   217 
   218 val after_entry = Entries.get_after o get_entries;
   219 
   220 fun lookup_entry node id =
   221   (case Entries.lookup (get_entries node) id of
   222     NONE => NONE
   223   | SOME (exec, _) => exec);
   224 
   225 fun the_entry node id =
   226   (case Entries.lookup (get_entries node) id of
   227     NONE => err_undef "command entry" id
   228   | SOME (exec, _) => exec);
   229 
   230 fun assign_entry (command_id, exec) node =
   231   if is_none (Entries.lookup (get_entries node) command_id) then node
   232   else map_entries (Entries.update (command_id, exec)) node;
   233 
   234 fun reset_after id entries =
   235   (case Entries.get_after entries id of
   236     NONE => entries
   237   | SOME next => Entries.update (next, NONE) entries);
   238 
   239 val edit_node = map_entries o fold
   240   (fn (id, SOME id2) => Entries.insert_after id (id2, NONE)
   241     | (id, NONE) => Entries.delete_after id #> reset_after id);
   242 
   243 
   244 (* version operations *)
   245 
   246 val empty_version = Version String_Graph.empty;
   247 
   248 fun nodes_of (Version nodes) = nodes;
   249 val node_of = get_node o nodes_of;
   250 
   251 fun cycle_msg names = "Cyclic dependency of " ^ space_implode " via " (map quote names);
   252 
   253 fun edit_nodes (name, node_edit) (Version nodes) =
   254   Version
   255     (case node_edit of
   256       Edits edits => update_node name (edit_node edits) nodes
   257     | Deps {master, header, errors} =>
   258         let
   259           val imports = map fst (#imports header);
   260           val nodes1 = nodes
   261             |> default_node name
   262             |> fold default_node imports;
   263           val nodes2 = nodes1
   264             |> String_Graph.Keys.fold
   265                 (fn dep => String_Graph.del_edge (dep, name)) (String_Graph.imm_preds nodes1 name);
   266           val (nodes3, errors1) =
   267             (String_Graph.add_deps_acyclic (name, imports) nodes2, errors)
   268               handle String_Graph.CYCLES cs => (nodes2, errors @ map cycle_msg cs);
   269         in String_Graph.map_node name (set_header master header errors1) nodes3 end
   270     | Perspective perspective => update_node name (set_perspective perspective) nodes);
   271 
   272 fun update_keywords name nodes =
   273   nodes |> String_Graph.map_node name (fn node =>
   274     if is_empty_node node then node
   275     else
   276       let
   277         val {master, header, errors} = get_header node;
   278         val imports_keywords = map_filter (get_keywords o get_node nodes o #1) (#imports header);
   279         val keywords =
   280           Library.foldl Keyword.merge_keywords (Session.get_keywords (), imports_keywords);
   281         val (keywords', errors') =
   282           (Keyword.add_keywords (#keywords header) keywords, errors)
   283             handle ERROR msg =>
   284               (keywords, if member (op =) errors msg then errors else errors @ [msg]);
   285       in
   286         node
   287         |> set_header master header errors'
   288         |> set_keywords (SOME keywords')
   289       end);
   290 
   291 fun edit_keywords edits (Version nodes) =
   292   Version
   293     (fold update_keywords
   294       (String_Graph.all_succs nodes (map_filter (fn (a, Deps _) => SOME a | _ => NONE) edits))
   295       nodes);
   296 
   297 fun put_node (name, node) (Version nodes) =
   298   let
   299     val nodes1 = update_node name (K node) nodes;
   300     val nodes2 =
   301       if String_Graph.is_maximal nodes1 name andalso is_empty_node node
   302       then String_Graph.del_node name nodes1
   303       else nodes1;
   304   in Version nodes2 end;
   305 
   306 end;
   307 
   308 
   309 
   310 (** main state -- document structure and execution process **)
   311 
   312 type blob_digest = (string * string option) Exn.result;  (*file node name, raw digest*)
   313 
   314 type execution =
   315  {version_id: Document_ID.version,  (*static version id*)
   316   execution_id: Document_ID.execution,  (*dynamic execution id*)
   317   delay_request: unit future,  (*pending event timer request*)
   318   parallel_prints: Command.exec list};  (*parallel prints for early execution*)
   319 
   320 val no_execution: execution =
   321   {version_id = Document_ID.none,
   322    execution_id = Document_ID.none,
   323    delay_request = Future.value (),
   324    parallel_prints = []};
   325 
   326 fun new_execution version_id delay_request parallel_prints : execution =
   327   {version_id = version_id,
   328    execution_id = Execution.start (),
   329    delay_request = delay_request,
   330    parallel_prints = parallel_prints};
   331 
   332 abstype state = State of
   333  {versions: version Inttab.table,  (*version id -> document content*)
   334   blobs: (SHA1.digest * string list) Symtab.table,  (*raw digest -> digest, lines*)
   335   commands: (string * blob_digest list * int * Token.T list lazy) Inttab.table,
   336     (*command id -> name, inlined files, token index of files, command span*)
   337   execution: execution}  (*current execution process*)
   338 with
   339 
   340 fun make_state (versions, blobs, commands, execution) =
   341   State {versions = versions, blobs = blobs, commands = commands, execution = execution};
   342 
   343 fun map_state f (State {versions, blobs, commands, execution}) =
   344   make_state (f (versions, blobs, commands, execution));
   345 
   346 val init_state =
   347   make_state (Inttab.make [(Document_ID.none, empty_version)],
   348     Symtab.empty, Inttab.empty, no_execution);
   349 
   350 
   351 (* document versions *)
   352 
   353 fun parallel_prints_node node =
   354   iterate_entries (fn (_, opt_exec) => fn rev_result =>
   355     (case opt_exec of
   356       SOME (eval, prints) =>
   357         (case filter Command.parallel_print prints of
   358           [] => SOME rev_result
   359         | prints' => SOME ((eval, prints') :: rev_result))
   360     | NONE => NONE)) node [] |> rev;
   361 
   362 fun define_version version_id version assigned_nodes =
   363   map_state (fn (versions, blobs, commands, {delay_request, ...}) =>
   364     let
   365       val version' = fold put_node assigned_nodes version;
   366       val versions' = Inttab.update_new (version_id, version') versions
   367         handle Inttab.DUP dup => err_dup "document version" dup;
   368       val parallel_prints = maps (parallel_prints_node o #2) assigned_nodes;
   369       val execution' = new_execution version_id delay_request parallel_prints;
   370     in (versions', blobs, commands, execution') end);
   371 
   372 fun the_version (State {versions, ...}) version_id =
   373   (case Inttab.lookup versions version_id of
   374     NONE => err_undef "document version" version_id
   375   | SOME version => version);
   376 
   377 fun delete_version version_id versions =
   378   Inttab.delete version_id versions
   379     handle Inttab.UNDEF _ => err_undef "document version" version_id;
   380 
   381 
   382 (* inlined files *)
   383 
   384 fun define_blob digest text =
   385   map_state (fn (versions, blobs, commands, execution) =>
   386     let val blobs' = Symtab.update (digest, (SHA1.fake digest, split_lines text)) blobs
   387     in (versions, blobs', commands, execution) end);
   388 
   389 fun the_blob (State {blobs, ...}) digest =
   390   (case Symtab.lookup blobs digest of
   391     NONE => error ("Undefined blob: " ^ digest)
   392   | SOME content => content);
   393 
   394 fun resolve_blob state (blob_digest: blob_digest) =
   395   blob_digest |> Exn.map_res (fn (file_node, raw_digest) =>
   396     (file_node, Option.map (the_blob state) raw_digest));
   397 
   398 fun blob_reports pos (blob_digest: blob_digest) =
   399   (case blob_digest of Exn.Res (file_node, _) => [(pos, Markup.path file_node)] | _ => []);
   400 
   401 
   402 (* commands *)
   403 
   404 fun define_command command_id name blobs_digests blobs_index toks =
   405   map_state (fn (versions, blobs, commands, execution) =>
   406     let
   407       val id = Document_ID.print command_id;
   408       val span =
   409         Lazy.lazy_name "Document.define_command" (fn () =>
   410           Position.setmp_thread_data (Position.id_only id)
   411             (fn () =>
   412               let
   413                 val (tokens, _) = fold_map Token.make toks (Position.id id);
   414                 val _ =
   415                   if blobs_index < 0
   416                   then (*inlined errors*)
   417                     map_filter Exn.get_exn blobs_digests
   418                     |> List.app (Output.error_message o Runtime.exn_message)
   419                   else (*auxiliary files*)
   420                     let val pos = Token.pos_of (nth tokens blobs_index)
   421                     in Position.reports (maps (blob_reports pos) blobs_digests) end;
   422               in tokens end) ());
   423       val commands' =
   424         Inttab.update_new (command_id, (name, blobs_digests, blobs_index, span)) commands
   425           handle Inttab.DUP dup => err_dup "command" dup;
   426       val _ =
   427         Position.setmp_thread_data (Position.id_only id)
   428           (fn () => Output.status (Markup.markup_only Markup.accepted)) ();
   429     in (versions, blobs, commands', execution) end);
   430 
   431 fun the_command (State {commands, ...}) command_id =
   432   (case Inttab.lookup commands command_id of
   433     NONE => err_undef "command" command_id
   434   | SOME command => command);
   435 
   436 val the_command_name = #1 oo the_command;
   437 
   438 
   439 (* execution *)
   440 
   441 fun get_execution (State {execution, ...}) = execution;
   442 fun get_execution_version state = the_version state (#version_id (get_execution state));
   443 
   444 fun command_exec state node_name command_id =
   445   let
   446     val version = get_execution_version state;
   447     val node = get_node (nodes_of version) node_name;
   448   in the_entry node command_id end;
   449 
   450 end;
   451 
   452 
   453 (* remove_versions *)
   454 
   455 fun remove_versions version_ids state = state |> map_state (fn (versions, _, _, execution) =>
   456   let
   457     val _ =
   458       member (op =) version_ids (#version_id execution) andalso
   459         error ("Attempt to remove execution version " ^ Document_ID.print (#version_id execution));
   460 
   461     val versions' = fold delete_version version_ids versions;
   462     val commands' =
   463       (versions', Inttab.empty) |->
   464         Inttab.fold (fn (_, version) => nodes_of version |>
   465           String_Graph.fold (fn (_, (node, _)) => node |>
   466             iterate_entries (fn ((_, command_id), _) =>
   467               SOME o Inttab.insert (K true) (command_id, the_command state command_id))));
   468     val blobs' =
   469       (commands', Symtab.empty) |->
   470         Inttab.fold (fn (_, (_, blobs, _, _)) => blobs |>
   471           fold (fn Exn.Res (_, SOME b) => Symtab.update (b, the_blob state b) | _ => I));
   472 
   473   in (versions', blobs', commands', execution) end);
   474 
   475 
   476 (* document execution *)
   477 
   478 fun make_required nodes =
   479   let
   480     fun all_preds P =
   481       String_Graph.fold (fn (a, (node, _)) => P node ? cons a) nodes []
   482       |> String_Graph.all_preds nodes
   483       |> Symtab.make_set;
   484 
   485     val all_visible = all_preds visible_node;
   486     val all_required = all_preds required_node;
   487   in
   488     Symtab.fold (fn (a, ()) =>
   489       exists (Symtab.defined all_visible) (String_Graph.immediate_succs nodes a) ?
   490         Symtab.update (a, ())) all_visible all_required
   491   end;
   492 
   493 fun start_execution state = state |> map_state (fn (versions, blobs, commands, execution) =>
   494   timeit "Document.start_execution" (fn () =>
   495     let
   496       val {version_id, execution_id, delay_request, parallel_prints} = execution;
   497 
   498       val delay = seconds (Options.default_real "editor_execution_delay");
   499 
   500       val _ = Future.cancel delay_request;
   501       val delay_request' = Event_Timer.future {physical = true} (Time.now () + delay);
   502       val delay = Future.task_of delay_request';
   503 
   504       val parallel_prints' = parallel_prints
   505         |> map_filter (Command.exec_parallel_prints execution_id [delay]);
   506 
   507       fun finished_import (name, (node, _)) =
   508         finished_result node orelse is_some (Thy_Info.lookup_theory name);
   509 
   510       val nodes = nodes_of (the_version state version_id);
   511       val required = make_required nodes;
   512       val _ =
   513         nodes |> String_Graph.schedule
   514           (fn deps => fn (name, node) =>
   515             if Symtab.defined required name orelse visible_node node orelse pending_result node then
   516               let
   517                 val future =
   518                   (singleton o Future.forks)
   519                    {name = "theory:" ^ name,
   520                     group = SOME (Future.new_group NONE),
   521                     deps = delay :: Execution.active_tasks name @ maps (the_list o #2 o #2) deps,
   522                     pri = 0, interrupts = false}
   523                   (fn () =>
   524                    (Execution.worker_task_active true name;
   525                     if forall finished_import deps then
   526                       iterate_entries (fn (_, opt_exec) => fn () =>
   527                         (case opt_exec of
   528                           SOME exec =>
   529                             if Execution.is_running execution_id
   530                             then SOME (Command.exec execution_id exec)
   531                             else NONE
   532                         | NONE => NONE)) node ()
   533                     else ();
   534                     Execution.worker_task_active false name)
   535                       handle exn =>
   536                        (Output.system_message (Runtime.exn_message exn);
   537                         Execution.worker_task_active false name;
   538                         Exn.reraise exn));
   539               in (node, SOME (Future.task_of future)) end
   540             else (node, NONE));
   541       val execution' =
   542         {version_id = version_id, execution_id = execution_id,
   543           delay_request = delay_request', parallel_prints = parallel_prints'};
   544     in (versions, blobs, commands, execution') end));
   545 
   546 
   547 
   548 (** document update **)
   549 
   550 (* exec state assignment *)
   551 
   552 type assign_update = Command.exec option Inttab.table;  (*command id -> exec*)
   553 
   554 val assign_update_empty: assign_update = Inttab.empty;
   555 fun assign_update_defined (tab: assign_update) command_id = Inttab.defined tab command_id;
   556 fun assign_update_change entry (tab: assign_update) = Inttab.update entry tab;
   557 fun assign_update_apply (tab: assign_update) node = Inttab.fold assign_entry tab node;
   558 
   559 fun assign_update_new upd (tab: assign_update) =
   560   Inttab.update_new upd tab
   561     handle Inttab.DUP dup => err_dup "exec state assignment" dup;
   562 
   563 fun assign_update_result (tab: assign_update) =
   564   Inttab.fold (fn (command_id, exec) => cons (command_id, Command.exec_ids exec)) tab [];
   565 
   566 
   567 (* update *)
   568 
   569 local
   570 
   571 fun init_theory deps node span =
   572   let
   573     val master_dir = master_directory node;
   574     val header = read_header node span;
   575     val imports = #imports header;
   576 
   577     fun maybe_eval_result eval = Command.eval_result_state eval
   578       handle Fail _ => Toplevel.init_toplevel ();
   579 
   580     fun maybe_end_theory pos st = SOME (Toplevel.end_theory pos st)
   581       handle ERROR msg => (Output.error_message msg; NONE);
   582 
   583     val parents_reports =
   584       imports |> map_filter (fn (import, pos) =>
   585         (case Thy_Info.lookup_theory import of
   586           NONE =>
   587             maybe_end_theory pos
   588               (case get_result (snd (the (AList.lookup (op =) deps import))) of
   589                 NONE => Toplevel.init_toplevel ()
   590               | SOME (_, eval) => maybe_eval_result eval)
   591         | some => some)
   592         |> Option.map (fn thy => (thy, (pos, Theory.get_markup thy))));
   593 
   594     val parents =
   595       if null parents_reports then [Theory.get_pure ()] else map #1 parents_reports;
   596     val _ = Position.reports (map #2 parents_reports);
   597     val thy = Resources.begin_theory master_dir header parents;
   598     val _ = Output.status (Markup.markup_only Markup.initialized);
   599   in thy end;
   600 
   601 fun check_root_theory node =
   602   let
   603     val master_dir = master_directory node;
   604     val header = #header (get_header node);
   605     val header_name = #1 (#name header);
   606     val parent =
   607       if header_name = Sessions.root_name then
   608         SOME (Thy_Info.get_theory Sessions.theory_name)
   609       else if member (op =) Thy_Header.ml_roots header_name then
   610         SOME (Thy_Info.get_theory Thy_Header.ml_bootstrapN)
   611       else NONE;
   612   in parent |> Option.map (fn thy => Resources.begin_theory master_dir header [thy]) end;
   613 
   614 fun check_theory full name node =
   615   is_some (Thy_Info.lookup_theory name) orelse
   616   null (#errors (get_header node)) andalso (not full orelse is_some (get_result node));
   617 
   618 fun last_common keywords state node_required node0 node =
   619   let
   620     fun update_flags prev (visible, initial) =
   621       let
   622         val visible' = visible andalso prev <> visible_last node;
   623         val initial' = initial andalso
   624           (case prev of
   625             NONE => true
   626           | SOME command_id => the_command_name state command_id <> Thy_Header.theoryN);
   627       in (visible', initial') end;
   628 
   629     fun get_common ((prev, command_id), opt_exec) (_, ok, flags, assign_update) =
   630       if ok then
   631         let
   632           val flags' as (visible', _) = update_flags prev flags;
   633           val ok' =
   634             (case (lookup_entry node0 command_id, opt_exec) of
   635               (SOME (eval0, _), SOME (eval, _)) =>
   636                 Command.eval_eq (eval0, eval) andalso
   637                   (visible' orelse node_required orelse Command.eval_running eval)
   638             | _ => false);
   639           val assign_update' = assign_update |> ok' ?
   640             (case opt_exec of
   641               SOME (eval, prints) =>
   642                 let
   643                   val command_visible = visible_command node command_id;
   644                   val command_overlays = overlays node command_id;
   645                   val command_name = the_command_name state command_id;
   646                 in
   647                   (case
   648                     Command.print command_visible command_overlays keywords command_name eval prints
   649                    of
   650                     SOME prints' => assign_update_new (command_id, SOME (eval, prints'))
   651                   | NONE => I)
   652                 end
   653             | NONE => I);
   654         in SOME (prev, ok', flags', assign_update') end
   655       else NONE;
   656     val (common, ok, flags, assign_update') =
   657       iterate_entries get_common node (NONE, true, (true, true), assign_update_empty);
   658     val (common', flags') =
   659       if ok then
   660         let val last = Entries.get_after (get_entries node) common
   661         in (last, update_flags last flags) end
   662       else (common, flags);
   663   in (assign_update', common', flags') end;
   664 
   665 fun illegal_init _ = error "Illegal theory header";
   666 
   667 fun new_exec keywords state node proper_init command_id' (assign_update, command_exec, init) =
   668   if not proper_init andalso is_none init then NONE
   669   else
   670     let
   671       val command_visible = visible_command node command_id';
   672       val command_overlays = overlays node command_id';
   673       val (command_name, blob_digests, blobs_index, span0) = the_command state command_id';
   674       val blobs = map (resolve_blob state) blob_digests;
   675       val span = Lazy.force span0;
   676 
   677       val eval' =
   678         Command.eval keywords (master_directory node) (fn () => the_default illegal_init init span)
   679           (blobs, blobs_index) command_id' span (#1 (#2 command_exec));
   680       val prints' =
   681         perhaps (Command.print command_visible command_overlays keywords command_name eval') [];
   682       val exec' = (eval', prints');
   683 
   684       val assign_update' = assign_update_new (command_id', SOME exec') assign_update;
   685       val init' = if command_name = Thy_Header.theoryN then NONE else init;
   686     in SOME (assign_update', (command_id', exec'), init') end;
   687 
   688 fun removed_execs node0 (command_id, exec_ids) =
   689   subtract (op =) exec_ids (Command.exec_ids (lookup_entry node0 command_id));
   690 
   691 fun print_consolidation options the_command_span node_name (assign_update, node) =
   692   (case finished_result_theory node of
   693     SOME (result_id, thy) =>
   694       let
   695         val active_tasks =
   696           (node, false) |-> iterate_entries (fn (_, opt_exec) => fn active =>
   697             if active then NONE
   698             else
   699               (case opt_exec of
   700                 NONE => NONE
   701               | SOME (eval, _) =>
   702                   SOME (not (null (Execution.snapshot [Command.eval_exec_id eval])))));
   703       in
   704         if not active_tasks then
   705           let
   706             val consolidation =
   707               if Options.bool options "editor_presentation" then
   708                 let
   709                   val (_, offsets, rev_segments) =
   710                     iterate_entries (fn (_, opt_exec) => fn (offset, offsets, segments) =>
   711                       (case opt_exec of
   712                         SOME (eval, _) =>
   713                           let
   714                             val command_id = Command.eval_command_id eval;
   715                             val span = the_command_span command_id;
   716 
   717                             val exec_id = Command.eval_exec_id eval;
   718                             val tr = Command.eval_result_command eval;
   719                             val st' = Command.eval_result_state eval;
   720 
   721                             val offset' = offset + the_default 0 (Command_Span.symbol_length span);
   722                             val offsets' = offsets
   723                               |> Inttab.update (command_id, offset)
   724                               |> Inttab.update (exec_id, offset);
   725                             val segments' = (span, tr, st') :: segments;
   726                           in SOME (offset', offsets', segments') end
   727                       | NONE => NONE)) node (0, Inttab.empty, []);
   728 
   729                   val adjust = Inttab.lookup offsets;
   730                   val segments =
   731                     rev rev_segments |> map (fn (span, tr, st') =>
   732                       {span = Command_Span.adjust_offsets adjust span, command = tr, state = st'});
   733 
   734                   val presentation_context: Thy_Info.presentation_context =
   735                    {options = options,
   736                     file_pos = Position.file node_name,
   737                     adjust_pos = Position.adjust_offsets adjust,
   738                     segments = segments};
   739                 in
   740                   fn _ =>
   741                     Exn.release
   742                       (Exn.capture (Thy_Info.apply_presentation presentation_context) thy
   743                         before commit_consolidated node)
   744                 end
   745               else fn _ => commit_consolidated node;
   746 
   747             val result_entry =
   748               (case lookup_entry node result_id of
   749                 NONE => err_undef "result command entry" result_id
   750               | SOME (eval, prints) =>
   751                   let
   752                     val print = eval |> Command.print0
   753                       {pri = Task_Queue.urgent_pri + 1, print_fn = K consolidation};
   754                   in (result_id, SOME (eval, print :: prints)) end);
   755 
   756             val assign_update' = assign_update |> assign_update_change result_entry;
   757             val node' = node |> assign_entry result_entry;
   758           in (assign_update', node') end
   759         else (assign_update, node)
   760       end
   761   | NONE => (assign_update, node));
   762 in
   763 
   764 fun update old_version_id new_version_id edits consolidate state =
   765   Runtime.exn_trace_system (fn () =>
   766   let
   767     val options = Options.default ();
   768     val the_command_span = Outer_Syntax.make_span o Lazy.force o #4 o the_command state;
   769 
   770     val old_version = the_version state old_version_id;
   771     val new_version =
   772       timeit "Document.edit_nodes"
   773         (fn () => old_version |> fold edit_nodes edits |> edit_keywords edits);
   774 
   775     val consolidate = Symtab.defined (Symtab.make_set consolidate);
   776     val nodes = nodes_of new_version;
   777     val required = make_required nodes;
   778     val required0 = make_required (nodes_of old_version);
   779     val edited = fold (fn (name, _) => Symtab.update (name, ())) edits Symtab.empty;
   780 
   781     val updated = timeit "Document.update" (fn () =>
   782       nodes |> String_Graph.schedule
   783         (fn deps => fn (name, node) =>
   784           (singleton o Future.forks)
   785             {name = "Document.update", group = NONE,
   786               deps = map (Future.task_of o #2) deps, pri = 1, interrupts = false}
   787             (fn () =>
   788               timeit ("Document.update " ^ name) (fn () =>
   789                 Runtime.exn_trace_system (fn () =>
   790                   let
   791                     val root_theory = check_root_theory node;
   792                     val keywords = the_default (Session.get_keywords ()) (get_keywords node);
   793 
   794                     val maybe_consolidate = consolidate name andalso could_consolidate node;
   795                     val imports = map (apsnd Future.join) deps;
   796                     val imports_result_changed = exists (#4 o #1 o #2) imports;
   797                     val node_required = Symtab.defined required name;
   798                   in
   799                     if Symtab.defined edited name orelse maybe_consolidate orelse
   800                       visible_node node orelse imports_result_changed orelse
   801                       Symtab.defined required0 name <> node_required
   802                     then
   803                       let
   804                         val node0 = node_of old_version name;
   805                         val init = init_theory imports node;
   806                         val proper_init =
   807                           is_some root_theory orelse
   808                             check_theory false name node andalso
   809                             forall (fn (name, (_, node)) => check_theory true name node) imports;
   810 
   811                         val (print_execs, common, (still_visible, initial)) =
   812                           if imports_result_changed then (assign_update_empty, NONE, (true, true))
   813                           else last_common keywords state node_required node0 node;
   814 
   815                         val common_command_exec =
   816                           (case common of
   817                             SOME id => (id, the_default Command.no_exec (the_entry node id))
   818                           | NONE => (Document_ID.none, Command.init_exec root_theory));
   819 
   820                         val (updated_execs, (command_id', exec'), _) =
   821                           (print_execs, common_command_exec, if initial then SOME init else NONE)
   822                           |> (still_visible orelse node_required) ?
   823                             iterate_entries_after common
   824                               (fn ((prev, id), _) => fn res =>
   825                                 if not node_required andalso prev = visible_last node then NONE
   826                                 else new_exec keywords state node proper_init id res) node;
   827 
   828                         val assign_update =
   829                           (node0, updated_execs) |-> iterate_entries_after common
   830                             (fn ((_, command_id0), exec0) => fn res =>
   831                               if is_none exec0 then NONE
   832                               else if assign_update_defined updated_execs command_id0 then SOME res
   833                               else SOME (assign_update_new (command_id0, NONE) res));
   834 
   835                         val last_exec =
   836                           if command_id' = Document_ID.none then NONE else SOME command_id';
   837                         val result =
   838                           if is_none last_exec orelse is_some (after_entry node last_exec) then NONE
   839                           else SOME (command_id', #1 exec');
   840 
   841                         val result_changed =
   842                           not (eq_option (Command.eval_eq o apply2 #2) (get_result node0, result));
   843                         val (assign_update', node') = node
   844                           |> assign_update_apply assign_update
   845                           |> set_result result
   846                           |> result_changed ? reset_consolidated
   847                           |> pair assign_update
   848                           |> (not result_changed andalso maybe_consolidate) ?
   849                               print_consolidation options the_command_span name;
   850 
   851                         val assign_result = assign_update_result assign_update';
   852                         val removed = maps (removed_execs node0) assign_result;
   853                         val _ = List.app Execution.cancel removed;
   854 
   855                         val assigned_node = SOME (name, node');
   856                       in ((removed, assign_result, assigned_node, result_changed), node') end
   857                     else (([], [], NONE, false), node)
   858                   end))))
   859       |> Future.joins |> map #1);
   860 
   861     val removed = maps #1 updated;
   862     val assign_result = maps #2 updated;
   863     val assigned_nodes = map_filter #3 updated;
   864 
   865     val state' = state
   866       |> define_version new_version_id new_version assigned_nodes;
   867 
   868   in (removed, assign_result, state') end);
   869 
   870 end;
   871 
   872 
   873 
   874 (** global state **)
   875 
   876 val global_state = Synchronized.var "Document.global_state" init_state;
   877 
   878 fun state () = Synchronized.value global_state;
   879 val change_state = Synchronized.change global_state;
   880 
   881 end;