src/Pure/Isar/local_theory.ML
author wenzelm
Sat Sep 27 15:20:39 2008 +0200 (2008-09-27 ago)
changeset 28379 0de8a35b866a
parent 28115 cd0d170d4dc6
child 28395 984fcc8feb24
permissions -rw-r--r--
Theory.checkpoint for main operations, admits concurrent proofs;
     1 (*  Title:      Pure/Isar/local_theory.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Local theory operations, with abstract target context.
     6 *)
     7 
     8 type local_theory = Proof.context;
     9 
    10 signature LOCAL_THEORY =
    11 sig
    12   type operations
    13   val group_of: local_theory -> string
    14   val group_properties_of: local_theory -> Properties.T
    15   val group_position_of: local_theory -> Properties.T
    16   val set_group: string -> local_theory -> local_theory
    17   val target_of: local_theory -> Proof.context
    18   val raw_theory_result: (theory -> 'a * theory) -> local_theory -> 'a * local_theory
    19   val raw_theory: (theory -> theory) -> local_theory -> local_theory
    20   val checkpoint: local_theory -> local_theory
    21   val full_naming: local_theory -> NameSpace.naming
    22   val full_name: local_theory -> bstring -> string
    23   val theory_result: (theory -> 'a * theory) -> local_theory -> 'a * local_theory
    24   val theory: (theory -> theory) -> local_theory -> local_theory
    25   val target_result: (Proof.context -> 'a * Proof.context) -> local_theory -> 'a * local_theory
    26   val target: (Proof.context -> Proof.context) -> local_theory -> local_theory
    27   val affirm: local_theory -> local_theory
    28   val pretty: local_theory -> Pretty.T list
    29   val abbrev: Syntax.mode -> (Name.binding * mixfix) * term -> local_theory ->
    30     (term * term) * local_theory
    31   val define: string -> (Name.binding * mixfix) * (Attrib.binding * term) -> local_theory ->
    32     (term * (string * thm)) * local_theory
    33   val note: string -> Attrib.binding * thm list -> local_theory -> (string * thm list) * local_theory
    34   val notes: string -> (Attrib.binding * (thm list * Attrib.src list) list) list ->
    35     local_theory -> (string * thm list) list * local_theory
    36   val type_syntax: declaration -> local_theory -> local_theory
    37   val term_syntax: declaration -> local_theory -> local_theory
    38   val declaration: declaration -> local_theory -> local_theory
    39   val notation: bool -> Syntax.mode -> (term * mixfix) list -> local_theory -> local_theory
    40   val target_morphism: local_theory -> morphism
    41   val init: string -> operations -> Proof.context -> local_theory
    42   val restore: local_theory -> local_theory
    43   val reinit: local_theory -> local_theory
    44   val exit: local_theory -> Proof.context
    45 end;
    46 
    47 structure LocalTheory: LOCAL_THEORY =
    48 struct
    49 
    50 (** local theory data **)
    51 
    52 (* type lthy *)
    53 
    54 type operations =
    55  {pretty: local_theory -> Pretty.T list,
    56   abbrev: Syntax.mode -> (Name.binding * mixfix) * term -> local_theory ->
    57     (term * term) * local_theory,
    58   define: string ->
    59     (Name.binding * mixfix) * (Attrib.binding * term) -> local_theory ->
    60     (term * (string * thm)) * local_theory,
    61   notes: string ->
    62     (Attrib.binding * (thm list * Attrib.src list) list) list ->
    63     local_theory -> (string * thm list) list * local_theory,
    64   type_syntax: declaration -> local_theory -> local_theory,
    65   term_syntax: declaration -> local_theory -> local_theory,
    66   declaration: declaration -> local_theory -> local_theory,
    67   reinit: local_theory -> local_theory,
    68   exit: local_theory -> Proof.context};
    69 
    70 datatype lthy = LThy of
    71  {group: string,
    72   theory_prefix: string,
    73   operations: operations,
    74   target: Proof.context};
    75 
    76 fun make_lthy (group, theory_prefix, operations, target) =
    77   LThy {group = group, theory_prefix = theory_prefix, operations = operations, target = target};
    78 
    79 
    80 (* context data *)
    81 
    82 structure Data = ProofDataFun
    83 (
    84   type T = lthy option;
    85   fun init _ = NONE;
    86 );
    87 
    88 fun get_lthy lthy =
    89   (case Data.get lthy of
    90     NONE => error "No local theory context"
    91   | SOME (LThy data) => data);
    92 
    93 fun map_lthy f lthy =
    94   let val {group, theory_prefix, operations, target} = get_lthy lthy
    95   in Data.put (SOME (make_lthy (f (group, theory_prefix, operations, target)))) lthy end;
    96 
    97 
    98 (* group *)
    99 
   100 val group_of = #group o get_lthy;
   101 
   102 fun group_properties_of lthy =
   103   (case group_of lthy of
   104     "" => []
   105   | group => [(Markup.groupN, group)]);
   106 
   107 fun group_position_of lthy =
   108   group_properties_of lthy @ Position.properties_of (Position.thread_data ());
   109 
   110 fun set_group group = map_lthy (fn (_, theory_prefix, operations, target) =>
   111   (group, theory_prefix, operations, target));
   112 
   113 
   114 (* target *)
   115 
   116 val target_of = #target o get_lthy;
   117 val affirm = tap target_of;
   118 
   119 fun map_target f = map_lthy (fn (group, theory_prefix, operations, target) =>
   120   (group, theory_prefix, operations, f target));
   121 
   122 
   123 (* substructure mappings *)
   124 
   125 fun raw_theory_result f lthy =
   126   let
   127     val (res, thy') = f (ProofContext.theory_of lthy);
   128     val lthy' = lthy
   129       |> map_target (ProofContext.transfer thy')
   130       |> ProofContext.transfer thy';
   131   in (res, lthy') end;
   132 
   133 fun raw_theory f = #2 o raw_theory_result (f #> pair ());
   134 
   135 val checkpoint = raw_theory Theory.checkpoint;
   136 
   137 fun full_naming lthy =
   138   Sign.naming_of (ProofContext.theory_of lthy)
   139   |> NameSpace.sticky_prefix (#theory_prefix (get_lthy lthy))
   140   |> NameSpace.qualified_names;
   141 
   142 val full_name = NameSpace.full o full_naming;
   143 
   144 fun theory_result f lthy = lthy |> raw_theory_result (fn thy => thy
   145   |> Sign.sticky_prefix (#theory_prefix (get_lthy lthy))
   146   |> Sign.qualified_names
   147   |> f
   148   ||> Sign.restore_naming thy);
   149 
   150 fun theory f = #2 o theory_result (f #> pair ());
   151 
   152 fun target_result f lthy =
   153   let
   154     val (res, ctxt') = f (target_of lthy);
   155     val thy' = ProofContext.theory_of ctxt';
   156     val lthy' = lthy
   157       |> map_target (K ctxt')
   158       |> ProofContext.transfer thy';
   159   in (res, lthy') end;
   160 
   161 fun target f = #2 o target_result (f #> pair ());
   162 
   163 
   164 (* basic operations *)
   165 
   166 fun operation f lthy = f (#operations (get_lthy lthy)) lthy;
   167 fun operation1 f x = operation (fn ops => f ops x);
   168 fun operation2 f x y lthy = operation (fn ops => f ops x y) lthy;
   169 
   170 val pretty = operation #pretty;
   171 val abbrev = apsnd checkpoint ooo operation2 #abbrev;
   172 val define = apsnd checkpoint ooo operation2 #define;
   173 val notes = apsnd checkpoint ooo operation2 #notes;
   174 val type_syntax = checkpoint oo operation1 #type_syntax;
   175 val term_syntax = checkpoint oo operation1 #term_syntax;
   176 val declaration = checkpoint oo operation1 #declaration;
   177 
   178 fun note kind (a, ths) = notes kind [(a, [(ths, [])])] #>> the_single;
   179 
   180 fun target_morphism lthy =
   181   ProofContext.export_morphism lthy (target_of lthy) $>
   182   Morphism.thm_morphism Goal.norm_result;
   183 
   184 fun notation add mode raw_args lthy =
   185   let val args = map (apfst (Morphism.term (target_morphism lthy))) raw_args
   186   in term_syntax (ProofContext.target_notation add mode args) lthy end;
   187 
   188 
   189 (* init -- exit *)
   190 
   191 fun init theory_prefix operations target = target |> Data.map
   192   (fn NONE => SOME (make_lthy ("", theory_prefix, operations, target))
   193     | SOME _ => error "Local theory already initialized")
   194   |> checkpoint;
   195 
   196 fun restore lthy =
   197   let val {group = _, theory_prefix, operations, target} = get_lthy lthy
   198   in init theory_prefix operations target end;
   199 
   200 val reinit = checkpoint o operation #reinit;
   201 val exit = ProofContext.theory Theory.checkpoint o operation #exit;
   202 
   203 end;