src/HOL/ex/Dedekind_Real.thy
author haftmann
Fri Oct 01 16:05:25 2010 +0200 (2010-10-01 ago)
changeset 39910 10097e0a9dbd
parent 37765 26bdfb7b680b
child 40822 98a5faa5aec0
permissions -rw-r--r--
constant `contents` renamed to `the_elem`
     1 (*  Title:      HOL/ex/Dedekind_Real.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge
     3     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     4 
     5 The positive reals as Dedekind sections of positive
     6 rationals. Fundamentals of Abstract Analysis [Gleason- p. 121]
     7 provides some of the definitions.
     8 *)
     9 
    10 theory Dedekind_Real
    11 imports Rat Lubs
    12 begin
    13 
    14 section {* Positive real numbers *}
    15 
    16 text{*Could be generalized and moved to @{text Groups}*}
    17 lemma add_eq_exists: "\<exists>x. a+x = (b::rat)"
    18 by (rule_tac x="b-a" in exI, simp)
    19 
    20 definition
    21   cut :: "rat set => bool" where
    22   "cut A = ({} \<subset> A &
    23             A < {r. 0 < r} &
    24             (\<forall>y \<in> A. ((\<forall>z. 0<z & z < y --> z \<in> A) & (\<exists>u \<in> A. y < u))))"
    25 
    26 lemma interval_empty_iff:
    27   "{y. (x::'a::dense_linorder) < y \<and> y < z} = {} \<longleftrightarrow> \<not> x < z"
    28   by (auto dest: dense)
    29 
    30 
    31 lemma cut_of_rat: 
    32   assumes q: "0 < q" shows "cut {r::rat. 0 < r & r < q}" (is "cut ?A")
    33 proof -
    34   from q have pos: "?A < {r. 0 < r}" by force
    35   have nonempty: "{} \<subset> ?A"
    36   proof
    37     show "{} \<subseteq> ?A" by simp
    38     show "{} \<noteq> ?A"
    39       by (force simp only: q eq_commute [of "{}"] interval_empty_iff)
    40   qed
    41   show ?thesis
    42     by (simp add: cut_def pos nonempty,
    43         blast dest: dense intro: order_less_trans)
    44 qed
    45 
    46 
    47 typedef preal = "{A. cut A}"
    48   by (blast intro: cut_of_rat [OF zero_less_one])
    49 
    50 definition
    51   psup :: "preal set => preal" where
    52   "psup P = Abs_preal (\<Union>X \<in> P. Rep_preal X)"
    53 
    54 definition
    55   add_set :: "[rat set,rat set] => rat set" where
    56   "add_set A B = {w. \<exists>x \<in> A. \<exists>y \<in> B. w = x + y}"
    57 
    58 definition
    59   diff_set :: "[rat set,rat set] => rat set" where
    60   "diff_set A B = {w. \<exists>x. 0 < w & 0 < x & x \<notin> B & x + w \<in> A}"
    61 
    62 definition
    63   mult_set :: "[rat set,rat set] => rat set" where
    64   "mult_set A B = {w. \<exists>x \<in> A. \<exists>y \<in> B. w = x * y}"
    65 
    66 definition
    67   inverse_set :: "rat set => rat set" where
    68   "inverse_set A = {x. \<exists>y. 0 < x & x < y & inverse y \<notin> A}"
    69 
    70 instantiation preal :: "{ord, plus, minus, times, inverse, one}"
    71 begin
    72 
    73 definition
    74   preal_less_def:
    75     "R < S == Rep_preal R < Rep_preal S"
    76 
    77 definition
    78   preal_le_def:
    79     "R \<le> S == Rep_preal R \<subseteq> Rep_preal S"
    80 
    81 definition
    82   preal_add_def:
    83     "R + S == Abs_preal (add_set (Rep_preal R) (Rep_preal S))"
    84 
    85 definition
    86   preal_diff_def:
    87     "R - S == Abs_preal (diff_set (Rep_preal R) (Rep_preal S))"
    88 
    89 definition
    90   preal_mult_def:
    91     "R * S == Abs_preal (mult_set (Rep_preal R) (Rep_preal S))"
    92 
    93 definition
    94   preal_inverse_def:
    95     "inverse R == Abs_preal (inverse_set (Rep_preal R))"
    96 
    97 definition "R / S = R * inverse (S\<Colon>preal)"
    98 
    99 definition
   100   preal_one_def:
   101     "1 == Abs_preal {x. 0 < x & x < 1}"
   102 
   103 instance ..
   104 
   105 end
   106 
   107 
   108 text{*Reduces equality on abstractions to equality on representatives*}
   109 declare Abs_preal_inject [simp]
   110 declare Abs_preal_inverse [simp]
   111 
   112 lemma rat_mem_preal: "0 < q ==> {r::rat. 0 < r & r < q} \<in> preal"
   113 by (simp add: preal_def cut_of_rat)
   114 
   115 lemma preal_nonempty: "A \<in> preal ==> \<exists>x\<in>A. 0 < x"
   116 by (unfold preal_def cut_def, blast)
   117 
   118 lemma preal_Ex_mem: "A \<in> preal \<Longrightarrow> \<exists>x. x \<in> A"
   119 by (drule preal_nonempty, fast)
   120 
   121 lemma preal_imp_psubset_positives: "A \<in> preal ==> A < {r. 0 < r}"
   122 by (force simp add: preal_def cut_def)
   123 
   124 lemma preal_exists_bound: "A \<in> preal ==> \<exists>x. 0 < x & x \<notin> A"
   125 by (drule preal_imp_psubset_positives, auto)
   126 
   127 lemma preal_exists_greater: "[| A \<in> preal; y \<in> A |] ==> \<exists>u \<in> A. y < u"
   128 by (unfold preal_def cut_def, blast)
   129 
   130 lemma preal_downwards_closed: "[| A \<in> preal; y \<in> A; 0 < z; z < y |] ==> z \<in> A"
   131 by (unfold preal_def cut_def, blast)
   132 
   133 text{*Relaxing the final premise*}
   134 lemma preal_downwards_closed':
   135      "[| A \<in> preal; y \<in> A; 0 < z; z \<le> y |] ==> z \<in> A"
   136 apply (simp add: order_le_less)
   137 apply (blast intro: preal_downwards_closed)
   138 done
   139 
   140 text{*A positive fraction not in a positive real is an upper bound.
   141  Gleason p. 122 - Remark (1)*}
   142 
   143 lemma not_in_preal_ub:
   144   assumes A: "A \<in> preal"
   145     and notx: "x \<notin> A"
   146     and y: "y \<in> A"
   147     and pos: "0 < x"
   148   shows "y < x"
   149 proof (cases rule: linorder_cases)
   150   assume "x<y"
   151   with notx show ?thesis
   152     by (simp add:  preal_downwards_closed [OF A y] pos)
   153 next
   154   assume "x=y"
   155   with notx and y show ?thesis by simp
   156 next
   157   assume "y<x"
   158   thus ?thesis .
   159 qed
   160 
   161 text {* preal lemmas instantiated to @{term "Rep_preal X"} *}
   162 
   163 lemma mem_Rep_preal_Ex: "\<exists>x. x \<in> Rep_preal X"
   164 by (rule preal_Ex_mem [OF Rep_preal])
   165 
   166 lemma Rep_preal_exists_bound: "\<exists>x>0. x \<notin> Rep_preal X"
   167 by (rule preal_exists_bound [OF Rep_preal])
   168 
   169 lemmas not_in_Rep_preal_ub = not_in_preal_ub [OF Rep_preal]
   170 
   171 
   172 subsection{*Properties of Ordering*}
   173 
   174 instance preal :: order
   175 proof
   176   fix w :: preal
   177   show "w \<le> w" by (simp add: preal_le_def)
   178 next
   179   fix i j k :: preal
   180   assume "i \<le> j" and "j \<le> k"
   181   then show "i \<le> k" by (simp add: preal_le_def)
   182 next
   183   fix z w :: preal
   184   assume "z \<le> w" and "w \<le> z"
   185   then show "z = w" by (simp add: preal_le_def Rep_preal_inject)
   186 next
   187   fix z w :: preal
   188   show "z < w \<longleftrightarrow> z \<le> w \<and> \<not> w \<le> z"
   189   by (auto simp add: preal_le_def preal_less_def Rep_preal_inject)
   190 qed  
   191 
   192 lemma preal_imp_pos: "[|A \<in> preal; r \<in> A|] ==> 0 < r"
   193 by (insert preal_imp_psubset_positives, blast)
   194 
   195 instance preal :: linorder
   196 proof
   197   fix x y :: preal
   198   show "x <= y | y <= x"
   199     apply (auto simp add: preal_le_def)
   200     apply (rule ccontr)
   201     apply (blast dest: not_in_Rep_preal_ub intro: preal_imp_pos [OF Rep_preal]
   202              elim: order_less_asym)
   203     done
   204 qed
   205 
   206 instantiation preal :: distrib_lattice
   207 begin
   208 
   209 definition
   210   "(inf \<Colon> preal \<Rightarrow> preal \<Rightarrow> preal) = min"
   211 
   212 definition
   213   "(sup \<Colon> preal \<Rightarrow> preal \<Rightarrow> preal) = max"
   214 
   215 instance
   216   by intro_classes
   217     (auto simp add: inf_preal_def sup_preal_def min_max.sup_inf_distrib1)
   218 
   219 end
   220 
   221 subsection{*Properties of Addition*}
   222 
   223 lemma preal_add_commute: "(x::preal) + y = y + x"
   224 apply (unfold preal_add_def add_set_def)
   225 apply (rule_tac f = Abs_preal in arg_cong)
   226 apply (force simp add: add_commute)
   227 done
   228 
   229 text{*Lemmas for proving that addition of two positive reals gives
   230  a positive real*}
   231 
   232 text{*Part 1 of Dedekind sections definition*}
   233 lemma add_set_not_empty:
   234      "[|A \<in> preal; B \<in> preal|] ==> {} \<subset> add_set A B"
   235 apply (drule preal_nonempty)+
   236 apply (auto simp add: add_set_def)
   237 done
   238 
   239 text{*Part 2 of Dedekind sections definition.  A structured version of
   240 this proof is @{text preal_not_mem_mult_set_Ex} below.*}
   241 lemma preal_not_mem_add_set_Ex:
   242      "[|A \<in> preal; B \<in> preal|] ==> \<exists>q>0. q \<notin> add_set A B"
   243 apply (insert preal_exists_bound [of A] preal_exists_bound [of B], auto) 
   244 apply (rule_tac x = "x+xa" in exI)
   245 apply (simp add: add_set_def, clarify)
   246 apply (drule (3) not_in_preal_ub)+
   247 apply (force dest: add_strict_mono)
   248 done
   249 
   250 lemma add_set_not_rat_set:
   251    assumes A: "A \<in> preal" 
   252        and B: "B \<in> preal"
   253      shows "add_set A B < {r. 0 < r}"
   254 proof
   255   from preal_imp_pos [OF A] preal_imp_pos [OF B]
   256   show "add_set A B \<subseteq> {r. 0 < r}" by (force simp add: add_set_def) 
   257 next
   258   show "add_set A B \<noteq> {r. 0 < r}"
   259     by (insert preal_not_mem_add_set_Ex [OF A B], blast) 
   260 qed
   261 
   262 text{*Part 3 of Dedekind sections definition*}
   263 lemma add_set_lemma3:
   264      "[|A \<in> preal; B \<in> preal; u \<in> add_set A B; 0 < z; z < u|] 
   265       ==> z \<in> add_set A B"
   266 proof (unfold add_set_def, clarify)
   267   fix x::rat and y::rat
   268   assume A: "A \<in> preal" 
   269     and B: "B \<in> preal"
   270     and [simp]: "0 < z"
   271     and zless: "z < x + y"
   272     and x:  "x \<in> A"
   273     and y:  "y \<in> B"
   274   have xpos [simp]: "0<x" by (rule preal_imp_pos [OF A x])
   275   have ypos [simp]: "0<y" by (rule preal_imp_pos [OF B y])
   276   have xypos [simp]: "0 < x+y" by (simp add: pos_add_strict)
   277   let ?f = "z/(x+y)"
   278   have fless: "?f < 1" by (simp add: zless pos_divide_less_eq)
   279   show "\<exists>x' \<in> A. \<exists>y'\<in>B. z = x' + y'"
   280   proof (intro bexI)
   281     show "z = x*?f + y*?f"
   282       by (simp add: left_distrib [symmetric] divide_inverse mult_ac
   283           order_less_imp_not_eq2)
   284   next
   285     show "y * ?f \<in> B"
   286     proof (rule preal_downwards_closed [OF B y])
   287       show "0 < y * ?f"
   288         by (simp add: divide_inverse zero_less_mult_iff)
   289     next
   290       show "y * ?f < y"
   291         by (insert mult_strict_left_mono [OF fless ypos], simp)
   292     qed
   293   next
   294     show "x * ?f \<in> A"
   295     proof (rule preal_downwards_closed [OF A x])
   296       show "0 < x * ?f"
   297         by (simp add: divide_inverse zero_less_mult_iff)
   298     next
   299       show "x * ?f < x"
   300         by (insert mult_strict_left_mono [OF fless xpos], simp)
   301     qed
   302   qed
   303 qed
   304 
   305 text{*Part 4 of Dedekind sections definition*}
   306 lemma add_set_lemma4:
   307      "[|A \<in> preal; B \<in> preal; y \<in> add_set A B|] ==> \<exists>u \<in> add_set A B. y < u"
   308 apply (auto simp add: add_set_def)
   309 apply (frule preal_exists_greater [of A], auto) 
   310 apply (rule_tac x="u + y" in exI)
   311 apply (auto intro: add_strict_left_mono)
   312 done
   313 
   314 lemma mem_add_set:
   315      "[|A \<in> preal; B \<in> preal|] ==> add_set A B \<in> preal"
   316 apply (simp (no_asm_simp) add: preal_def cut_def)
   317 apply (blast intro!: add_set_not_empty add_set_not_rat_set
   318                      add_set_lemma3 add_set_lemma4)
   319 done
   320 
   321 lemma preal_add_assoc: "((x::preal) + y) + z = x + (y + z)"
   322 apply (simp add: preal_add_def mem_add_set Rep_preal)
   323 apply (force simp add: add_set_def add_ac)
   324 done
   325 
   326 instance preal :: ab_semigroup_add
   327 proof
   328   fix a b c :: preal
   329   show "(a + b) + c = a + (b + c)" by (rule preal_add_assoc)
   330   show "a + b = b + a" by (rule preal_add_commute)
   331 qed
   332 
   333 
   334 subsection{*Properties of Multiplication*}
   335 
   336 text{*Proofs essentially same as for addition*}
   337 
   338 lemma preal_mult_commute: "(x::preal) * y = y * x"
   339 apply (unfold preal_mult_def mult_set_def)
   340 apply (rule_tac f = Abs_preal in arg_cong)
   341 apply (force simp add: mult_commute)
   342 done
   343 
   344 text{*Multiplication of two positive reals gives a positive real.*}
   345 
   346 text{*Lemmas for proving positive reals multiplication set in @{typ preal}*}
   347 
   348 text{*Part 1 of Dedekind sections definition*}
   349 lemma mult_set_not_empty:
   350      "[|A \<in> preal; B \<in> preal|] ==> {} \<subset> mult_set A B"
   351 apply (insert preal_nonempty [of A] preal_nonempty [of B]) 
   352 apply (auto simp add: mult_set_def)
   353 done
   354 
   355 text{*Part 2 of Dedekind sections definition*}
   356 lemma preal_not_mem_mult_set_Ex:
   357    assumes A: "A \<in> preal" 
   358        and B: "B \<in> preal"
   359      shows "\<exists>q. 0 < q & q \<notin> mult_set A B"
   360 proof -
   361   from preal_exists_bound [OF A]
   362   obtain x where [simp]: "0 < x" "x \<notin> A" by blast
   363   from preal_exists_bound [OF B]
   364   obtain y where [simp]: "0 < y" "y \<notin> B" by blast
   365   show ?thesis
   366   proof (intro exI conjI)
   367     show "0 < x*y" by (simp add: mult_pos_pos)
   368     show "x * y \<notin> mult_set A B"
   369     proof -
   370       { fix u::rat and v::rat
   371               assume "u \<in> A" and "v \<in> B" and "x*y = u*v"
   372               moreover
   373               with prems have "u<x" and "v<y" by (blast dest: not_in_preal_ub)+
   374               moreover
   375               with prems have "0\<le>v"
   376                 by (blast intro: preal_imp_pos [OF B]  order_less_imp_le prems)
   377               moreover
   378         from calculation
   379               have "u*v < x*y" by (blast intro: mult_strict_mono prems)
   380               ultimately have False by force }
   381       thus ?thesis by (auto simp add: mult_set_def)
   382     qed
   383   qed
   384 qed
   385 
   386 lemma mult_set_not_rat_set:
   387   assumes A: "A \<in> preal" 
   388     and B: "B \<in> preal"
   389   shows "mult_set A B < {r. 0 < r}"
   390 proof
   391   show "mult_set A B \<subseteq> {r. 0 < r}"
   392     by (force simp add: mult_set_def
   393       intro: preal_imp_pos [OF A] preal_imp_pos [OF B] mult_pos_pos)
   394   show "mult_set A B \<noteq> {r. 0 < r}"
   395     using preal_not_mem_mult_set_Ex [OF A B] by blast
   396 qed
   397 
   398 
   399 
   400 text{*Part 3 of Dedekind sections definition*}
   401 lemma mult_set_lemma3:
   402      "[|A \<in> preal; B \<in> preal; u \<in> mult_set A B; 0 < z; z < u|] 
   403       ==> z \<in> mult_set A B"
   404 proof (unfold mult_set_def, clarify)
   405   fix x::rat and y::rat
   406   assume A: "A \<in> preal" 
   407     and B: "B \<in> preal"
   408     and [simp]: "0 < z"
   409     and zless: "z < x * y"
   410     and x:  "x \<in> A"
   411     and y:  "y \<in> B"
   412   have [simp]: "0<y" by (rule preal_imp_pos [OF B y])
   413   show "\<exists>x' \<in> A. \<exists>y' \<in> B. z = x' * y'"
   414   proof
   415     show "\<exists>y'\<in>B. z = (z/y) * y'"
   416     proof
   417       show "z = (z/y)*y"
   418         by (simp add: divide_inverse mult_commute [of y] mult_assoc
   419                       order_less_imp_not_eq2)
   420       show "y \<in> B" by fact
   421     qed
   422   next
   423     show "z/y \<in> A"
   424     proof (rule preal_downwards_closed [OF A x])
   425       show "0 < z/y"
   426         by (simp add: zero_less_divide_iff)
   427       show "z/y < x" by (simp add: pos_divide_less_eq zless)
   428     qed
   429   qed
   430 qed
   431 
   432 text{*Part 4 of Dedekind sections definition*}
   433 lemma mult_set_lemma4:
   434      "[|A \<in> preal; B \<in> preal; y \<in> mult_set A B|] ==> \<exists>u \<in> mult_set A B. y < u"
   435 apply (auto simp add: mult_set_def)
   436 apply (frule preal_exists_greater [of A], auto) 
   437 apply (rule_tac x="u * y" in exI)
   438 apply (auto intro: preal_imp_pos [of A] preal_imp_pos [of B] 
   439                    mult_strict_right_mono)
   440 done
   441 
   442 
   443 lemma mem_mult_set:
   444      "[|A \<in> preal; B \<in> preal|] ==> mult_set A B \<in> preal"
   445 apply (simp (no_asm_simp) add: preal_def cut_def)
   446 apply (blast intro!: mult_set_not_empty mult_set_not_rat_set
   447                      mult_set_lemma3 mult_set_lemma4)
   448 done
   449 
   450 lemma preal_mult_assoc: "((x::preal) * y) * z = x * (y * z)"
   451 apply (simp add: preal_mult_def mem_mult_set Rep_preal)
   452 apply (force simp add: mult_set_def mult_ac)
   453 done
   454 
   455 instance preal :: ab_semigroup_mult
   456 proof
   457   fix a b c :: preal
   458   show "(a * b) * c = a * (b * c)" by (rule preal_mult_assoc)
   459   show "a * b = b * a" by (rule preal_mult_commute)
   460 qed
   461 
   462 
   463 text{* Positive real 1 is the multiplicative identity element *}
   464 
   465 lemma preal_mult_1: "(1::preal) * z = z"
   466 proof (induct z)
   467   fix A :: "rat set"
   468   assume A: "A \<in> preal"
   469   have "{w. \<exists>u. 0 < u \<and> u < 1 & (\<exists>v \<in> A. w = u * v)} = A" (is "?lhs = A")
   470   proof
   471     show "?lhs \<subseteq> A"
   472     proof clarify
   473       fix x::rat and u::rat and v::rat
   474       assume upos: "0<u" and "u<1" and v: "v \<in> A"
   475       have vpos: "0<v" by (rule preal_imp_pos [OF A v])
   476       hence "u*v < 1*v" by (simp only: mult_strict_right_mono prems)
   477       thus "u * v \<in> A"
   478         by (force intro: preal_downwards_closed [OF A v] mult_pos_pos 
   479           upos vpos)
   480     qed
   481   next
   482     show "A \<subseteq> ?lhs"
   483     proof clarify
   484       fix x::rat
   485       assume x: "x \<in> A"
   486       have xpos: "0<x" by (rule preal_imp_pos [OF A x])
   487       from preal_exists_greater [OF A x]
   488       obtain v where v: "v \<in> A" and xlessv: "x < v" ..
   489       have vpos: "0<v" by (rule preal_imp_pos [OF A v])
   490       show "\<exists>u. 0 < u \<and> u < 1 \<and> (\<exists>v\<in>A. x = u * v)"
   491       proof (intro exI conjI)
   492         show "0 < x/v"
   493           by (simp add: zero_less_divide_iff xpos vpos)
   494         show "x / v < 1"
   495           by (simp add: pos_divide_less_eq vpos xlessv)
   496         show "\<exists>v'\<in>A. x = (x / v) * v'"
   497         proof
   498           show "x = (x/v)*v"
   499             by (simp add: divide_inverse mult_assoc vpos
   500                           order_less_imp_not_eq2)
   501           show "v \<in> A" by fact
   502         qed
   503       qed
   504     qed
   505   qed
   506   thus "1 * Abs_preal A = Abs_preal A"
   507     by (simp add: preal_one_def preal_mult_def mult_set_def 
   508                   rat_mem_preal A)
   509 qed
   510 
   511 instance preal :: comm_monoid_mult
   512 by intro_classes (rule preal_mult_1)
   513 
   514 
   515 subsection{*Distribution of Multiplication across Addition*}
   516 
   517 lemma mem_Rep_preal_add_iff:
   518       "(z \<in> Rep_preal(R+S)) = (\<exists>x \<in> Rep_preal R. \<exists>y \<in> Rep_preal S. z = x + y)"
   519 apply (simp add: preal_add_def mem_add_set Rep_preal)
   520 apply (simp add: add_set_def) 
   521 done
   522 
   523 lemma mem_Rep_preal_mult_iff:
   524       "(z \<in> Rep_preal(R*S)) = (\<exists>x \<in> Rep_preal R. \<exists>y \<in> Rep_preal S. z = x * y)"
   525 apply (simp add: preal_mult_def mem_mult_set Rep_preal)
   526 apply (simp add: mult_set_def) 
   527 done
   528 
   529 lemma distrib_subset1:
   530      "Rep_preal (w * (x + y)) \<subseteq> Rep_preal (w * x + w * y)"
   531 apply (auto simp add: Bex_def mem_Rep_preal_add_iff mem_Rep_preal_mult_iff)
   532 apply (force simp add: right_distrib)
   533 done
   534 
   535 lemma preal_add_mult_distrib_mean:
   536   assumes a: "a \<in> Rep_preal w"
   537     and b: "b \<in> Rep_preal w"
   538     and d: "d \<in> Rep_preal x"
   539     and e: "e \<in> Rep_preal y"
   540   shows "\<exists>c \<in> Rep_preal w. a * d + b * e = c * (d + e)"
   541 proof
   542   let ?c = "(a*d + b*e)/(d+e)"
   543   have [simp]: "0<a" "0<b" "0<d" "0<e" "0<d+e"
   544     by (blast intro: preal_imp_pos [OF Rep_preal] a b d e pos_add_strict)+
   545   have cpos: "0 < ?c"
   546     by (simp add: zero_less_divide_iff zero_less_mult_iff pos_add_strict)
   547   show "a * d + b * e = ?c * (d + e)"
   548     by (simp add: divide_inverse mult_assoc order_less_imp_not_eq2)
   549   show "?c \<in> Rep_preal w"
   550   proof (cases rule: linorder_le_cases)
   551     assume "a \<le> b"
   552     hence "?c \<le> b"
   553       by (simp add: pos_divide_le_eq right_distrib mult_right_mono
   554                     order_less_imp_le)
   555     thus ?thesis by (rule preal_downwards_closed' [OF Rep_preal b cpos])
   556   next
   557     assume "b \<le> a"
   558     hence "?c \<le> a"
   559       by (simp add: pos_divide_le_eq right_distrib mult_right_mono
   560                     order_less_imp_le)
   561     thus ?thesis by (rule preal_downwards_closed' [OF Rep_preal a cpos])
   562   qed
   563 qed
   564 
   565 lemma distrib_subset2:
   566      "Rep_preal (w * x + w * y) \<subseteq> Rep_preal (w * (x + y))"
   567 apply (auto simp add: Bex_def mem_Rep_preal_add_iff mem_Rep_preal_mult_iff)
   568 apply (drule_tac w=w and x=x and y=y in preal_add_mult_distrib_mean, auto)
   569 done
   570 
   571 lemma preal_add_mult_distrib2: "(w * ((x::preal) + y)) = (w * x) + (w * y)"
   572 apply (rule Rep_preal_inject [THEN iffD1])
   573 apply (rule equalityI [OF distrib_subset1 distrib_subset2])
   574 done
   575 
   576 lemma preal_add_mult_distrib: "(((x::preal) + y) * w) = (x * w) + (y * w)"
   577 by (simp add: preal_mult_commute preal_add_mult_distrib2)
   578 
   579 instance preal :: comm_semiring
   580 by intro_classes (rule preal_add_mult_distrib)
   581 
   582 
   583 subsection{*Existence of Inverse, a Positive Real*}
   584 
   585 lemma mem_inv_set_ex:
   586   assumes A: "A \<in> preal" shows "\<exists>x y. 0 < x & x < y & inverse y \<notin> A"
   587 proof -
   588   from preal_exists_bound [OF A]
   589   obtain x where [simp]: "0<x" "x \<notin> A" by blast
   590   show ?thesis
   591   proof (intro exI conjI)
   592     show "0 < inverse (x+1)"
   593       by (simp add: order_less_trans [OF _ less_add_one]) 
   594     show "inverse(x+1) < inverse x"
   595       by (simp add: less_imp_inverse_less less_add_one)
   596     show "inverse (inverse x) \<notin> A"
   597       by (simp add: order_less_imp_not_eq2)
   598   qed
   599 qed
   600 
   601 text{*Part 1 of Dedekind sections definition*}
   602 lemma inverse_set_not_empty:
   603      "A \<in> preal ==> {} \<subset> inverse_set A"
   604 apply (insert mem_inv_set_ex [of A])
   605 apply (auto simp add: inverse_set_def)
   606 done
   607 
   608 text{*Part 2 of Dedekind sections definition*}
   609 
   610 lemma preal_not_mem_inverse_set_Ex:
   611    assumes A: "A \<in> preal"  shows "\<exists>q. 0 < q & q \<notin> inverse_set A"
   612 proof -
   613   from preal_nonempty [OF A]
   614   obtain x where x: "x \<in> A" and  xpos [simp]: "0<x" ..
   615   show ?thesis
   616   proof (intro exI conjI)
   617     show "0 < inverse x" by simp
   618     show "inverse x \<notin> inverse_set A"
   619     proof -
   620       { fix y::rat 
   621         assume ygt: "inverse x < y"
   622         have [simp]: "0 < y" by (simp add: order_less_trans [OF _ ygt])
   623         have iyless: "inverse y < x" 
   624           by (simp add: inverse_less_imp_less [of x] ygt)
   625         have "inverse y \<in> A"
   626           by (simp add: preal_downwards_closed [OF A x] iyless)}
   627      thus ?thesis by (auto simp add: inverse_set_def)
   628     qed
   629   qed
   630 qed
   631 
   632 lemma inverse_set_not_rat_set:
   633    assumes A: "A \<in> preal"  shows "inverse_set A < {r. 0 < r}"
   634 proof
   635   show "inverse_set A \<subseteq> {r. 0 < r}"  by (force simp add: inverse_set_def)
   636 next
   637   show "inverse_set A \<noteq> {r. 0 < r}"
   638     by (insert preal_not_mem_inverse_set_Ex [OF A], blast)
   639 qed
   640 
   641 text{*Part 3 of Dedekind sections definition*}
   642 lemma inverse_set_lemma3:
   643      "[|A \<in> preal; u \<in> inverse_set A; 0 < z; z < u|] 
   644       ==> z \<in> inverse_set A"
   645 apply (auto simp add: inverse_set_def)
   646 apply (auto intro: order_less_trans)
   647 done
   648 
   649 text{*Part 4 of Dedekind sections definition*}
   650 lemma inverse_set_lemma4:
   651      "[|A \<in> preal; y \<in> inverse_set A|] ==> \<exists>u \<in> inverse_set A. y < u"
   652 apply (auto simp add: inverse_set_def)
   653 apply (drule dense [of y]) 
   654 apply (blast intro: order_less_trans)
   655 done
   656 
   657 
   658 lemma mem_inverse_set:
   659      "A \<in> preal ==> inverse_set A \<in> preal"
   660 apply (simp (no_asm_simp) add: preal_def cut_def)
   661 apply (blast intro!: inverse_set_not_empty inverse_set_not_rat_set
   662                      inverse_set_lemma3 inverse_set_lemma4)
   663 done
   664 
   665 
   666 subsection{*Gleason's Lemma 9-3.4, page 122*}
   667 
   668 lemma Gleason9_34_exists:
   669   assumes A: "A \<in> preal"
   670     and "\<forall>x\<in>A. x + u \<in> A"
   671     and "0 \<le> z"
   672   shows "\<exists>b\<in>A. b + (of_int z) * u \<in> A"
   673 proof (cases z rule: int_cases)
   674   case (nonneg n)
   675   show ?thesis
   676   proof (simp add: prems, induct n)
   677     case 0
   678       from preal_nonempty [OF A]
   679       show ?case  by force 
   680     case (Suc k)
   681       from this obtain b where "b \<in> A" "b + of_nat k * u \<in> A" ..
   682       hence "b + of_int (int k)*u + u \<in> A" by (simp add: prems)
   683       thus ?case by (force simp add: algebra_simps prems) 
   684   qed
   685 next
   686   case (neg n)
   687   with prems show ?thesis by simp
   688 qed
   689 
   690 lemma Gleason9_34_contra:
   691   assumes A: "A \<in> preal"
   692     shows "[|\<forall>x\<in>A. x + u \<in> A; 0 < u; 0 < y; y \<notin> A|] ==> False"
   693 proof (induct u, induct y)
   694   fix a::int and b::int
   695   fix c::int and d::int
   696   assume bpos [simp]: "0 < b"
   697     and dpos [simp]: "0 < d"
   698     and closed: "\<forall>x\<in>A. x + (Fract c d) \<in> A"
   699     and upos: "0 < Fract c d"
   700     and ypos: "0 < Fract a b"
   701     and notin: "Fract a b \<notin> A"
   702   have cpos [simp]: "0 < c" 
   703     by (simp add: zero_less_Fract_iff [OF dpos, symmetric] upos) 
   704   have apos [simp]: "0 < a" 
   705     by (simp add: zero_less_Fract_iff [OF bpos, symmetric] ypos) 
   706   let ?k = "a*d"
   707   have frle: "Fract a b \<le> Fract ?k 1 * (Fract c d)" 
   708   proof -
   709     have "?thesis = ((a * d * b * d) \<le> c * b * (a * d * b * d))"
   710       by (simp add: order_less_imp_not_eq2 mult_ac) 
   711     moreover
   712     have "(1 * (a * d * b * d)) \<le> c * b * (a * d * b * d)"
   713       by (rule mult_mono, 
   714           simp_all add: int_one_le_iff_zero_less zero_less_mult_iff 
   715                         order_less_imp_le)
   716     ultimately
   717     show ?thesis by simp
   718   qed
   719   have k: "0 \<le> ?k" by (simp add: order_less_imp_le zero_less_mult_iff)  
   720   from Gleason9_34_exists [OF A closed k]
   721   obtain z where z: "z \<in> A" 
   722              and mem: "z + of_int ?k * Fract c d \<in> A" ..
   723   have less: "z + of_int ?k * Fract c d < Fract a b"
   724     by (rule not_in_preal_ub [OF A notin mem ypos])
   725   have "0<z" by (rule preal_imp_pos [OF A z])
   726   with frle and less show False by (simp add: Fract_of_int_eq) 
   727 qed
   728 
   729 
   730 lemma Gleason9_34:
   731   assumes A: "A \<in> preal"
   732     and upos: "0 < u"
   733   shows "\<exists>r \<in> A. r + u \<notin> A"
   734 proof (rule ccontr, simp)
   735   assume closed: "\<forall>r\<in>A. r + u \<in> A"
   736   from preal_exists_bound [OF A]
   737   obtain y where y: "y \<notin> A" and ypos: "0 < y" by blast
   738   show False
   739     by (rule Gleason9_34_contra [OF A closed upos ypos y])
   740 qed
   741 
   742 
   743 
   744 subsection{*Gleason's Lemma 9-3.6*}
   745 
   746 lemma lemma_gleason9_36:
   747   assumes A: "A \<in> preal"
   748     and x: "1 < x"
   749   shows "\<exists>r \<in> A. r*x \<notin> A"
   750 proof -
   751   from preal_nonempty [OF A]
   752   obtain y where y: "y \<in> A" and  ypos: "0<y" ..
   753   show ?thesis 
   754   proof (rule classical)
   755     assume "~(\<exists>r\<in>A. r * x \<notin> A)"
   756     with y have ymem: "y * x \<in> A" by blast 
   757     from ypos mult_strict_left_mono [OF x]
   758     have yless: "y < y*x" by simp 
   759     let ?d = "y*x - y"
   760     from yless have dpos: "0 < ?d" and eq: "y + ?d = y*x" by auto
   761     from Gleason9_34 [OF A dpos]
   762     obtain r where r: "r\<in>A" and notin: "r + ?d \<notin> A" ..
   763     have rpos: "0<r" by (rule preal_imp_pos [OF A r])
   764     with dpos have rdpos: "0 < r + ?d" by arith
   765     have "~ (r + ?d \<le> y + ?d)"
   766     proof
   767       assume le: "r + ?d \<le> y + ?d" 
   768       from ymem have yd: "y + ?d \<in> A" by (simp add: eq)
   769       have "r + ?d \<in> A" by (rule preal_downwards_closed' [OF A yd rdpos le])
   770       with notin show False by simp
   771     qed
   772     hence "y < r" by simp
   773     with ypos have  dless: "?d < (r * ?d)/y"
   774       by (simp add: pos_less_divide_eq mult_commute [of ?d]
   775                     mult_strict_right_mono dpos)
   776     have "r + ?d < r*x"
   777     proof -
   778       have "r + ?d < r + (r * ?d)/y" by (simp add: dless)
   779       also with ypos have "... = (r/y) * (y + ?d)"
   780         by (simp only: algebra_simps divide_inverse, simp)
   781       also have "... = r*x" using ypos
   782         by simp
   783       finally show "r + ?d < r*x" .
   784     qed
   785     with r notin rdpos
   786     show "\<exists>r\<in>A. r * x \<notin> A" by (blast dest:  preal_downwards_closed [OF A])
   787   qed  
   788 qed
   789 
   790 subsection{*Existence of Inverse: Part 2*}
   791 
   792 lemma mem_Rep_preal_inverse_iff:
   793       "(z \<in> Rep_preal(inverse R)) = 
   794        (0 < z \<and> (\<exists>y. z < y \<and> inverse y \<notin> Rep_preal R))"
   795 apply (simp add: preal_inverse_def mem_inverse_set Rep_preal)
   796 apply (simp add: inverse_set_def) 
   797 done
   798 
   799 lemma Rep_preal_one:
   800      "Rep_preal 1 = {x. 0 < x \<and> x < 1}"
   801 by (simp add: preal_one_def rat_mem_preal)
   802 
   803 lemma subset_inverse_mult_lemma:
   804   assumes xpos: "0 < x" and xless: "x < 1"
   805   shows "\<exists>r u y. 0 < r & r < y & inverse y \<notin> Rep_preal R & 
   806     u \<in> Rep_preal R & x = r * u"
   807 proof -
   808   from xpos and xless have "1 < inverse x" by (simp add: one_less_inverse_iff)
   809   from lemma_gleason9_36 [OF Rep_preal this]
   810   obtain r where r: "r \<in> Rep_preal R" 
   811              and notin: "r * (inverse x) \<notin> Rep_preal R" ..
   812   have rpos: "0<r" by (rule preal_imp_pos [OF Rep_preal r])
   813   from preal_exists_greater [OF Rep_preal r]
   814   obtain u where u: "u \<in> Rep_preal R" and rless: "r < u" ..
   815   have upos: "0<u" by (rule preal_imp_pos [OF Rep_preal u])
   816   show ?thesis
   817   proof (intro exI conjI)
   818     show "0 < x/u" using xpos upos
   819       by (simp add: zero_less_divide_iff)  
   820     show "x/u < x/r" using xpos upos rpos
   821       by (simp add: divide_inverse mult_less_cancel_left rless) 
   822     show "inverse (x / r) \<notin> Rep_preal R" using notin
   823       by (simp add: divide_inverse mult_commute) 
   824     show "u \<in> Rep_preal R" by (rule u) 
   825     show "x = x / u * u" using upos 
   826       by (simp add: divide_inverse mult_commute) 
   827   qed
   828 qed
   829 
   830 lemma subset_inverse_mult: 
   831      "Rep_preal 1 \<subseteq> Rep_preal(inverse R * R)"
   832 apply (auto simp add: Bex_def Rep_preal_one mem_Rep_preal_inverse_iff 
   833                       mem_Rep_preal_mult_iff)
   834 apply (blast dest: subset_inverse_mult_lemma) 
   835 done
   836 
   837 lemma inverse_mult_subset_lemma:
   838   assumes rpos: "0 < r" 
   839     and rless: "r < y"
   840     and notin: "inverse y \<notin> Rep_preal R"
   841     and q: "q \<in> Rep_preal R"
   842   shows "r*q < 1"
   843 proof -
   844   have "q < inverse y" using rpos rless
   845     by (simp add: not_in_preal_ub [OF Rep_preal notin] q)
   846   hence "r * q < r/y" using rpos
   847     by (simp add: divide_inverse mult_less_cancel_left)
   848   also have "... \<le> 1" using rpos rless
   849     by (simp add: pos_divide_le_eq)
   850   finally show ?thesis .
   851 qed
   852 
   853 lemma inverse_mult_subset:
   854      "Rep_preal(inverse R * R) \<subseteq> Rep_preal 1"
   855 apply (auto simp add: Bex_def Rep_preal_one mem_Rep_preal_inverse_iff
   856                       mem_Rep_preal_mult_iff)
   857 apply (simp add: zero_less_mult_iff preal_imp_pos [OF Rep_preal]) 
   858 apply (blast intro: inverse_mult_subset_lemma) 
   859 done
   860 
   861 lemma preal_mult_inverse: "inverse R * R = (1::preal)"
   862 apply (rule Rep_preal_inject [THEN iffD1])
   863 apply (rule equalityI [OF inverse_mult_subset subset_inverse_mult]) 
   864 done
   865 
   866 lemma preal_mult_inverse_right: "R * inverse R = (1::preal)"
   867 apply (rule preal_mult_commute [THEN subst])
   868 apply (rule preal_mult_inverse)
   869 done
   870 
   871 
   872 text{*Theorems needing @{text Gleason9_34}*}
   873 
   874 lemma Rep_preal_self_subset: "Rep_preal (R) \<subseteq> Rep_preal(R + S)"
   875 proof 
   876   fix r
   877   assume r: "r \<in> Rep_preal R"
   878   have rpos: "0<r" by (rule preal_imp_pos [OF Rep_preal r])
   879   from mem_Rep_preal_Ex 
   880   obtain y where y: "y \<in> Rep_preal S" ..
   881   have ypos: "0<y" by (rule preal_imp_pos [OF Rep_preal y])
   882   have ry: "r+y \<in> Rep_preal(R + S)" using r y
   883     by (auto simp add: mem_Rep_preal_add_iff)
   884   show "r \<in> Rep_preal(R + S)" using r ypos rpos 
   885     by (simp add:  preal_downwards_closed [OF Rep_preal ry]) 
   886 qed
   887 
   888 lemma Rep_preal_sum_not_subset: "~ Rep_preal (R + S) \<subseteq> Rep_preal(R)"
   889 proof -
   890   from mem_Rep_preal_Ex 
   891   obtain y where y: "y \<in> Rep_preal S" ..
   892   have ypos: "0<y" by (rule preal_imp_pos [OF Rep_preal y])
   893   from  Gleason9_34 [OF Rep_preal ypos]
   894   obtain r where r: "r \<in> Rep_preal R" and notin: "r + y \<notin> Rep_preal R" ..
   895   have "r + y \<in> Rep_preal (R + S)" using r y
   896     by (auto simp add: mem_Rep_preal_add_iff)
   897   thus ?thesis using notin by blast
   898 qed
   899 
   900 lemma Rep_preal_sum_not_eq: "Rep_preal (R + S) \<noteq> Rep_preal(R)"
   901 by (insert Rep_preal_sum_not_subset, blast)
   902 
   903 text{*at last, Gleason prop. 9-3.5(iii) page 123*}
   904 lemma preal_self_less_add_left: "(R::preal) < R + S"
   905 apply (unfold preal_less_def less_le)
   906 apply (simp add: Rep_preal_self_subset Rep_preal_sum_not_eq [THEN not_sym])
   907 done
   908 
   909 
   910 subsection{*Subtraction for Positive Reals*}
   911 
   912 text{*Gleason prop. 9-3.5(iv), page 123: proving @{prop "A < B ==> \<exists>D. A + D =
   913 B"}. We define the claimed @{term D} and show that it is a positive real*}
   914 
   915 text{*Part 1 of Dedekind sections definition*}
   916 lemma diff_set_not_empty:
   917      "R < S ==> {} \<subset> diff_set (Rep_preal S) (Rep_preal R)"
   918 apply (auto simp add: preal_less_def diff_set_def elim!: equalityE) 
   919 apply (frule_tac x1 = S in Rep_preal [THEN preal_exists_greater])
   920 apply (drule preal_imp_pos [OF Rep_preal], clarify)
   921 apply (cut_tac a=x and b=u in add_eq_exists, force) 
   922 done
   923 
   924 text{*Part 2 of Dedekind sections definition*}
   925 lemma diff_set_nonempty:
   926      "\<exists>q. 0 < q & q \<notin> diff_set (Rep_preal S) (Rep_preal R)"
   927 apply (cut_tac X = S in Rep_preal_exists_bound)
   928 apply (erule exE)
   929 apply (rule_tac x = x in exI, auto)
   930 apply (simp add: diff_set_def) 
   931 apply (auto dest: Rep_preal [THEN preal_downwards_closed])
   932 done
   933 
   934 lemma diff_set_not_rat_set:
   935   "diff_set (Rep_preal S) (Rep_preal R) < {r. 0 < r}" (is "?lhs < ?rhs")
   936 proof
   937   show "?lhs \<subseteq> ?rhs" by (auto simp add: diff_set_def) 
   938   show "?lhs \<noteq> ?rhs" using diff_set_nonempty by blast
   939 qed
   940 
   941 text{*Part 3 of Dedekind sections definition*}
   942 lemma diff_set_lemma3:
   943      "[|R < S; u \<in> diff_set (Rep_preal S) (Rep_preal R); 0 < z; z < u|] 
   944       ==> z \<in> diff_set (Rep_preal S) (Rep_preal R)"
   945 apply (auto simp add: diff_set_def) 
   946 apply (rule_tac x=x in exI) 
   947 apply (drule Rep_preal [THEN preal_downwards_closed], auto)
   948 done
   949 
   950 text{*Part 4 of Dedekind sections definition*}
   951 lemma diff_set_lemma4:
   952      "[|R < S; y \<in> diff_set (Rep_preal S) (Rep_preal R)|] 
   953       ==> \<exists>u \<in> diff_set (Rep_preal S) (Rep_preal R). y < u"
   954 apply (auto simp add: diff_set_def) 
   955 apply (drule Rep_preal [THEN preal_exists_greater], clarify) 
   956 apply (cut_tac a="x+y" and b=u in add_eq_exists, clarify)  
   957 apply (rule_tac x="y+xa" in exI) 
   958 apply (auto simp add: add_ac)
   959 done
   960 
   961 lemma mem_diff_set:
   962      "R < S ==> diff_set (Rep_preal S) (Rep_preal R) \<in> preal"
   963 apply (unfold preal_def cut_def)
   964 apply (blast intro!: diff_set_not_empty diff_set_not_rat_set
   965                      diff_set_lemma3 diff_set_lemma4)
   966 done
   967 
   968 lemma mem_Rep_preal_diff_iff:
   969       "R < S ==>
   970        (z \<in> Rep_preal(S-R)) = 
   971        (\<exists>x. 0 < x & 0 < z & x \<notin> Rep_preal R & x + z \<in> Rep_preal S)"
   972 apply (simp add: preal_diff_def mem_diff_set Rep_preal)
   973 apply (force simp add: diff_set_def) 
   974 done
   975 
   976 
   977 text{*proving that @{term "R + D \<le> S"}*}
   978 
   979 lemma less_add_left_lemma:
   980   assumes Rless: "R < S"
   981     and a: "a \<in> Rep_preal R"
   982     and cb: "c + b \<in> Rep_preal S"
   983     and "c \<notin> Rep_preal R"
   984     and "0 < b"
   985     and "0 < c"
   986   shows "a + b \<in> Rep_preal S"
   987 proof -
   988   have "0<a" by (rule preal_imp_pos [OF Rep_preal a])
   989   moreover
   990   have "a < c" using prems
   991     by (blast intro: not_in_Rep_preal_ub ) 
   992   ultimately show ?thesis using prems
   993     by (simp add: preal_downwards_closed [OF Rep_preal cb]) 
   994 qed
   995 
   996 lemma less_add_left_le1:
   997        "R < (S::preal) ==> R + (S-R) \<le> S"
   998 apply (auto simp add: Bex_def preal_le_def mem_Rep_preal_add_iff 
   999                       mem_Rep_preal_diff_iff)
  1000 apply (blast intro: less_add_left_lemma) 
  1001 done
  1002 
  1003 subsection{*proving that @{term "S \<le> R + D"} --- trickier*}
  1004 
  1005 lemma lemma_sum_mem_Rep_preal_ex:
  1006      "x \<in> Rep_preal S ==> \<exists>e. 0 < e & x + e \<in> Rep_preal S"
  1007 apply (drule Rep_preal [THEN preal_exists_greater], clarify) 
  1008 apply (cut_tac a=x and b=u in add_eq_exists, auto) 
  1009 done
  1010 
  1011 lemma less_add_left_lemma2:
  1012   assumes Rless: "R < S"
  1013     and x:     "x \<in> Rep_preal S"
  1014     and xnot: "x \<notin>  Rep_preal R"
  1015   shows "\<exists>u v z. 0 < v & 0 < z & u \<in> Rep_preal R & z \<notin> Rep_preal R & 
  1016                      z + v \<in> Rep_preal S & x = u + v"
  1017 proof -
  1018   have xpos: "0<x" by (rule preal_imp_pos [OF Rep_preal x])
  1019   from lemma_sum_mem_Rep_preal_ex [OF x]
  1020   obtain e where epos: "0 < e" and xe: "x + e \<in> Rep_preal S" by blast
  1021   from  Gleason9_34 [OF Rep_preal epos]
  1022   obtain r where r: "r \<in> Rep_preal R" and notin: "r + e \<notin> Rep_preal R" ..
  1023   with x xnot xpos have rless: "r < x" by (blast intro: not_in_Rep_preal_ub)
  1024   from add_eq_exists [of r x]
  1025   obtain y where eq: "x = r+y" by auto
  1026   show ?thesis 
  1027   proof (intro exI conjI)
  1028     show "r \<in> Rep_preal R" by (rule r)
  1029     show "r + e \<notin> Rep_preal R" by (rule notin)
  1030     show "r + e + y \<in> Rep_preal S" using xe eq by (simp add: add_ac)
  1031     show "x = r + y" by (simp add: eq)
  1032     show "0 < r + e" using epos preal_imp_pos [OF Rep_preal r]
  1033       by simp
  1034     show "0 < y" using rless eq by arith
  1035   qed
  1036 qed
  1037 
  1038 lemma less_add_left_le2: "R < (S::preal) ==> S \<le> R + (S-R)"
  1039 apply (auto simp add: preal_le_def)
  1040 apply (case_tac "x \<in> Rep_preal R")
  1041 apply (cut_tac Rep_preal_self_subset [of R], force)
  1042 apply (auto simp add: Bex_def mem_Rep_preal_add_iff mem_Rep_preal_diff_iff)
  1043 apply (blast dest: less_add_left_lemma2)
  1044 done
  1045 
  1046 lemma less_add_left: "R < (S::preal) ==> R + (S-R) = S"
  1047 by (blast intro: antisym [OF less_add_left_le1 less_add_left_le2])
  1048 
  1049 lemma less_add_left_Ex: "R < (S::preal) ==> \<exists>D. R + D = S"
  1050 by (fast dest: less_add_left)
  1051 
  1052 lemma preal_add_less2_mono1: "R < (S::preal) ==> R + T < S + T"
  1053 apply (auto dest!: less_add_left_Ex simp add: preal_add_assoc)
  1054 apply (rule_tac y1 = D in preal_add_commute [THEN subst])
  1055 apply (auto intro: preal_self_less_add_left simp add: preal_add_assoc [symmetric])
  1056 done
  1057 
  1058 lemma preal_add_less2_mono2: "R < (S::preal) ==> T + R < T + S"
  1059 by (auto intro: preal_add_less2_mono1 simp add: preal_add_commute [of T])
  1060 
  1061 lemma preal_add_right_less_cancel: "R + T < S + T ==> R < (S::preal)"
  1062 apply (insert linorder_less_linear [of R S], auto)
  1063 apply (drule_tac R = S and T = T in preal_add_less2_mono1)
  1064 apply (blast dest: order_less_trans) 
  1065 done
  1066 
  1067 lemma preal_add_left_less_cancel: "T + R < T + S ==> R <  (S::preal)"
  1068 by (auto elim: preal_add_right_less_cancel simp add: preal_add_commute [of T])
  1069 
  1070 lemma preal_add_less_cancel_left: "(T + (R::preal) < T + S) = (R < S)"
  1071 by (blast intro: preal_add_less2_mono2 preal_add_left_less_cancel)
  1072 
  1073 lemma preal_add_le_cancel_left: "(T + (R::preal) \<le> T + S) = (R \<le> S)"
  1074 by (simp add: linorder_not_less [symmetric] preal_add_less_cancel_left) 
  1075 
  1076 lemma preal_add_right_cancel: "(R::preal) + T = S + T ==> R = S"
  1077 apply (insert linorder_less_linear [of R S], safe)
  1078 apply (drule_tac [!] T = T in preal_add_less2_mono1, auto)
  1079 done
  1080 
  1081 lemma preal_add_left_cancel: "C + A = C + B ==> A = (B::preal)"
  1082 by (auto intro: preal_add_right_cancel simp add: preal_add_commute)
  1083 
  1084 instance preal :: linordered_cancel_ab_semigroup_add
  1085 proof
  1086   fix a b c :: preal
  1087   show "a + b = a + c \<Longrightarrow> b = c" by (rule preal_add_left_cancel)
  1088   show "a \<le> b \<Longrightarrow> c + a \<le> c + b" by (simp only: preal_add_le_cancel_left)
  1089 qed
  1090 
  1091 
  1092 subsection{*Completeness of type @{typ preal}*}
  1093 
  1094 text{*Prove that supremum is a cut*}
  1095 
  1096 text{*Part 1 of Dedekind sections definition*}
  1097 
  1098 lemma preal_sup_set_not_empty:
  1099      "P \<noteq> {} ==> {} \<subset> (\<Union>X \<in> P. Rep_preal(X))"
  1100 apply auto
  1101 apply (cut_tac X = x in mem_Rep_preal_Ex, auto)
  1102 done
  1103 
  1104 
  1105 text{*Part 2 of Dedekind sections definition*}
  1106 
  1107 lemma preal_sup_not_exists:
  1108      "\<forall>X \<in> P. X \<le> Y ==> \<exists>q. 0 < q & q \<notin> (\<Union>X \<in> P. Rep_preal(X))"
  1109 apply (cut_tac X = Y in Rep_preal_exists_bound)
  1110 apply (auto simp add: preal_le_def)
  1111 done
  1112 
  1113 lemma preal_sup_set_not_rat_set:
  1114      "\<forall>X \<in> P. X \<le> Y ==> (\<Union>X \<in> P. Rep_preal(X)) < {r. 0 < r}"
  1115 apply (drule preal_sup_not_exists)
  1116 apply (blast intro: preal_imp_pos [OF Rep_preal])  
  1117 done
  1118 
  1119 text{*Part 3 of Dedekind sections definition*}
  1120 lemma preal_sup_set_lemma3:
  1121      "[|P \<noteq> {}; \<forall>X \<in> P. X \<le> Y; u \<in> (\<Union>X \<in> P. Rep_preal(X)); 0 < z; z < u|]
  1122       ==> z \<in> (\<Union>X \<in> P. Rep_preal(X))"
  1123 by (auto elim: Rep_preal [THEN preal_downwards_closed])
  1124 
  1125 text{*Part 4 of Dedekind sections definition*}
  1126 lemma preal_sup_set_lemma4:
  1127      "[|P \<noteq> {}; \<forall>X \<in> P. X \<le> Y; y \<in> (\<Union>X \<in> P. Rep_preal(X)) |]
  1128           ==> \<exists>u \<in> (\<Union>X \<in> P. Rep_preal(X)). y < u"
  1129 by (blast dest: Rep_preal [THEN preal_exists_greater])
  1130 
  1131 lemma preal_sup:
  1132      "[|P \<noteq> {}; \<forall>X \<in> P. X \<le> Y|] ==> (\<Union>X \<in> P. Rep_preal(X)) \<in> preal"
  1133 apply (unfold preal_def cut_def)
  1134 apply (blast intro!: preal_sup_set_not_empty preal_sup_set_not_rat_set
  1135                      preal_sup_set_lemma3 preal_sup_set_lemma4)
  1136 done
  1137 
  1138 lemma preal_psup_le:
  1139      "[| \<forall>X \<in> P. X \<le> Y;  x \<in> P |] ==> x \<le> psup P"
  1140 apply (simp (no_asm_simp) add: preal_le_def) 
  1141 apply (subgoal_tac "P \<noteq> {}") 
  1142 apply (auto simp add: psup_def preal_sup) 
  1143 done
  1144 
  1145 lemma psup_le_ub: "[| P \<noteq> {}; \<forall>X \<in> P. X \<le> Y |] ==> psup P \<le> Y"
  1146 apply (simp (no_asm_simp) add: preal_le_def)
  1147 apply (simp add: psup_def preal_sup) 
  1148 apply (auto simp add: preal_le_def)
  1149 done
  1150 
  1151 text{*Supremum property*}
  1152 lemma preal_complete:
  1153      "[| P \<noteq> {}; \<forall>X \<in> P. X \<le> Y |] ==> (\<exists>X \<in> P. Z < X) = (Z < psup P)"
  1154 apply (simp add: preal_less_def psup_def preal_sup)
  1155 apply (auto simp add: preal_le_def)
  1156 apply (rename_tac U) 
  1157 apply (cut_tac x = U and y = Z in linorder_less_linear)
  1158 apply (auto simp add: preal_less_def)
  1159 done
  1160 
  1161 section {*Defining the Reals from the Positive Reals*}
  1162 
  1163 definition
  1164   realrel   ::  "((preal * preal) * (preal * preal)) set" where
  1165   "realrel = {p. \<exists>x1 y1 x2 y2. p = ((x1,y1),(x2,y2)) & x1+y2 = x2+y1}"
  1166 
  1167 typedef (Real)  real = "UNIV//realrel"
  1168   by (auto simp add: quotient_def)
  1169 
  1170 definition
  1171   (** these don't use the overloaded "real" function: users don't see them **)
  1172   real_of_preal :: "preal => real" where
  1173   "real_of_preal m = Abs_Real (realrel `` {(m + 1, 1)})"
  1174 
  1175 instantiation real :: "{zero, one, plus, minus, uminus, times, inverse, ord, abs, sgn}"
  1176 begin
  1177 
  1178 definition
  1179   real_zero_def: "0 = Abs_Real(realrel``{(1, 1)})"
  1180 
  1181 definition
  1182   real_one_def: "1 = Abs_Real(realrel``{(1 + 1, 1)})"
  1183 
  1184 definition
  1185   real_add_def: "z + w =
  1186        the_elem (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
  1187                  { Abs_Real(realrel``{(x+u, y+v)}) })"
  1188 
  1189 definition
  1190   real_minus_def: "- r =  the_elem (\<Union>(x,y) \<in> Rep_Real(r). { Abs_Real(realrel``{(y,x)}) })"
  1191 
  1192 definition
  1193   real_diff_def: "r - (s::real) = r + - s"
  1194 
  1195 definition
  1196   real_mult_def:
  1197     "z * w =
  1198        the_elem (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
  1199                  { Abs_Real(realrel``{(x*u + y*v, x*v + y*u)}) })"
  1200 
  1201 definition
  1202   real_inverse_def: "inverse (R::real) = (THE S. (R = 0 & S = 0) | S * R = 1)"
  1203 
  1204 definition
  1205   real_divide_def: "R / (S::real) = R * inverse S"
  1206 
  1207 definition
  1208   real_le_def: "z \<le> (w::real) \<longleftrightarrow>
  1209     (\<exists>x y u v. x+v \<le> u+y & (x,y) \<in> Rep_Real z & (u,v) \<in> Rep_Real w)"
  1210 
  1211 definition
  1212   real_less_def: "x < (y\<Colon>real) \<longleftrightarrow> x \<le> y \<and> x \<noteq> y"
  1213 
  1214 definition
  1215   real_abs_def:  "abs (r::real) = (if r < 0 then - r else r)"
  1216 
  1217 definition
  1218   real_sgn_def: "sgn (x::real) = (if x=0 then 0 else if 0<x then 1 else - 1)"
  1219 
  1220 instance ..
  1221 
  1222 end
  1223 
  1224 subsection {* Equivalence relation over positive reals *}
  1225 
  1226 lemma preal_trans_lemma:
  1227   assumes "x + y1 = x1 + y"
  1228       and "x + y2 = x2 + y"
  1229   shows "x1 + y2 = x2 + (y1::preal)"
  1230 proof -
  1231   have "(x1 + y2) + x = (x + y2) + x1" by (simp add: add_ac)
  1232   also have "... = (x2 + y) + x1"  by (simp add: prems)
  1233   also have "... = x2 + (x1 + y)"  by (simp add: add_ac)
  1234   also have "... = x2 + (x + y1)"  by (simp add: prems)
  1235   also have "... = (x2 + y1) + x"  by (simp add: add_ac)
  1236   finally have "(x1 + y2) + x = (x2 + y1) + x" .
  1237   thus ?thesis by (rule add_right_imp_eq)
  1238 qed
  1239 
  1240 
  1241 lemma realrel_iff [simp]: "(((x1,y1),(x2,y2)) \<in> realrel) = (x1 + y2 = x2 + y1)"
  1242 by (simp add: realrel_def)
  1243 
  1244 lemma equiv_realrel: "equiv UNIV realrel"
  1245 apply (auto simp add: equiv_def refl_on_def sym_def trans_def realrel_def)
  1246 apply (blast dest: preal_trans_lemma) 
  1247 done
  1248 
  1249 text{*Reduces equality of equivalence classes to the @{term realrel} relation:
  1250   @{term "(realrel `` {x} = realrel `` {y}) = ((x,y) \<in> realrel)"} *}
  1251 lemmas equiv_realrel_iff = 
  1252        eq_equiv_class_iff [OF equiv_realrel UNIV_I UNIV_I]
  1253 
  1254 declare equiv_realrel_iff [simp]
  1255 
  1256 
  1257 lemma realrel_in_real [simp]: "realrel``{(x,y)}: Real"
  1258 by (simp add: Real_def realrel_def quotient_def, blast)
  1259 
  1260 declare Abs_Real_inject [simp]
  1261 declare Abs_Real_inverse [simp]
  1262 
  1263 
  1264 text{*Case analysis on the representation of a real number as an equivalence
  1265       class of pairs of positive reals.*}
  1266 lemma eq_Abs_Real [case_names Abs_Real, cases type: real]: 
  1267      "(!!x y. z = Abs_Real(realrel``{(x,y)}) ==> P) ==> P"
  1268 apply (rule Rep_Real [of z, unfolded Real_def, THEN quotientE])
  1269 apply (drule arg_cong [where f=Abs_Real])
  1270 apply (auto simp add: Rep_Real_inverse)
  1271 done
  1272 
  1273 
  1274 subsection {* Addition and Subtraction *}
  1275 
  1276 lemma real_add_congruent2_lemma:
  1277      "[|a + ba = aa + b; ab + bc = ac + bb|]
  1278       ==> a + ab + (ba + bc) = aa + ac + (b + (bb::preal))"
  1279 apply (simp add: add_assoc)
  1280 apply (rule add_left_commute [of ab, THEN ssubst])
  1281 apply (simp add: add_assoc [symmetric])
  1282 apply (simp add: add_ac)
  1283 done
  1284 
  1285 lemma real_add:
  1286      "Abs_Real (realrel``{(x,y)}) + Abs_Real (realrel``{(u,v)}) =
  1287       Abs_Real (realrel``{(x+u, y+v)})"
  1288 proof -
  1289   have "(\<lambda>z w. (\<lambda>(x,y). (\<lambda>(u,v). {Abs_Real (realrel `` {(x+u, y+v)})}) w) z)
  1290         respects2 realrel"
  1291     by (simp add: congruent2_def, blast intro: real_add_congruent2_lemma) 
  1292   thus ?thesis
  1293     by (simp add: real_add_def UN_UN_split_split_eq
  1294                   UN_equiv_class2 [OF equiv_realrel equiv_realrel])
  1295 qed
  1296 
  1297 lemma real_minus: "- Abs_Real(realrel``{(x,y)}) = Abs_Real(realrel `` {(y,x)})"
  1298 proof -
  1299   have "(\<lambda>(x,y). {Abs_Real (realrel``{(y,x)})}) respects realrel"
  1300     by (simp add: congruent_def add_commute) 
  1301   thus ?thesis
  1302     by (simp add: real_minus_def UN_equiv_class [OF equiv_realrel])
  1303 qed
  1304 
  1305 instance real :: ab_group_add
  1306 proof
  1307   fix x y z :: real
  1308   show "(x + y) + z = x + (y + z)"
  1309     by (cases x, cases y, cases z, simp add: real_add add_assoc)
  1310   show "x + y = y + x"
  1311     by (cases x, cases y, simp add: real_add add_commute)
  1312   show "0 + x = x"
  1313     by (cases x, simp add: real_add real_zero_def add_ac)
  1314   show "- x + x = 0"
  1315     by (cases x, simp add: real_minus real_add real_zero_def add_commute)
  1316   show "x - y = x + - y"
  1317     by (simp add: real_diff_def)
  1318 qed
  1319 
  1320 
  1321 subsection {* Multiplication *}
  1322 
  1323 lemma real_mult_congruent2_lemma:
  1324      "!!(x1::preal). [| x1 + y2 = x2 + y1 |] ==>
  1325           x * x1 + y * y1 + (x * y2 + y * x2) =
  1326           x * x2 + y * y2 + (x * y1 + y * x1)"
  1327 apply (simp add: add_left_commute add_assoc [symmetric])
  1328 apply (simp add: add_assoc right_distrib [symmetric])
  1329 apply (simp add: add_commute)
  1330 done
  1331 
  1332 lemma real_mult_congruent2:
  1333     "(%p1 p2.
  1334         (%(x1,y1). (%(x2,y2). 
  1335           { Abs_Real (realrel``{(x1*x2 + y1*y2, x1*y2+y1*x2)}) }) p2) p1)
  1336      respects2 realrel"
  1337 apply (rule congruent2_commuteI [OF equiv_realrel], clarify)
  1338 apply (simp add: mult_commute add_commute)
  1339 apply (auto simp add: real_mult_congruent2_lemma)
  1340 done
  1341 
  1342 lemma real_mult:
  1343       "Abs_Real((realrel``{(x1,y1)})) * Abs_Real((realrel``{(x2,y2)})) =
  1344        Abs_Real(realrel `` {(x1*x2+y1*y2,x1*y2+y1*x2)})"
  1345 by (simp add: real_mult_def UN_UN_split_split_eq
  1346          UN_equiv_class2 [OF equiv_realrel equiv_realrel real_mult_congruent2])
  1347 
  1348 lemma real_mult_commute: "(z::real) * w = w * z"
  1349 by (cases z, cases w, simp add: real_mult add_ac mult_ac)
  1350 
  1351 lemma real_mult_assoc: "((z1::real) * z2) * z3 = z1 * (z2 * z3)"
  1352 apply (cases z1, cases z2, cases z3)
  1353 apply (simp add: real_mult algebra_simps)
  1354 done
  1355 
  1356 lemma real_mult_1: "(1::real) * z = z"
  1357 apply (cases z)
  1358 apply (simp add: real_mult real_one_def algebra_simps)
  1359 done
  1360 
  1361 lemma real_add_mult_distrib: "((z1::real) + z2) * w = (z1 * w) + (z2 * w)"
  1362 apply (cases z1, cases z2, cases w)
  1363 apply (simp add: real_add real_mult algebra_simps)
  1364 done
  1365 
  1366 text{*one and zero are distinct*}
  1367 lemma real_zero_not_eq_one: "0 \<noteq> (1::real)"
  1368 proof -
  1369   have "(1::preal) < 1 + 1"
  1370     by (simp add: preal_self_less_add_left)
  1371   thus ?thesis
  1372     by (simp add: real_zero_def real_one_def)
  1373 qed
  1374 
  1375 instance real :: comm_ring_1
  1376 proof
  1377   fix x y z :: real
  1378   show "(x * y) * z = x * (y * z)" by (rule real_mult_assoc)
  1379   show "x * y = y * x" by (rule real_mult_commute)
  1380   show "1 * x = x" by (rule real_mult_1)
  1381   show "(x + y) * z = x * z + y * z" by (rule real_add_mult_distrib)
  1382   show "0 \<noteq> (1::real)" by (rule real_zero_not_eq_one)
  1383 qed
  1384 
  1385 subsection {* Inverse and Division *}
  1386 
  1387 lemma real_zero_iff: "Abs_Real (realrel `` {(x, x)}) = 0"
  1388 by (simp add: real_zero_def add_commute)
  1389 
  1390 text{*Instead of using an existential quantifier and constructing the inverse
  1391 within the proof, we could define the inverse explicitly.*}
  1392 
  1393 lemma real_mult_inverse_left_ex: "x \<noteq> 0 ==> \<exists>y. y*x = (1::real)"
  1394 apply (simp add: real_zero_def real_one_def, cases x)
  1395 apply (cut_tac x = xa and y = y in linorder_less_linear)
  1396 apply (auto dest!: less_add_left_Ex simp add: real_zero_iff)
  1397 apply (rule_tac
  1398         x = "Abs_Real (realrel``{(1, inverse (D) + 1)})"
  1399        in exI)
  1400 apply (rule_tac [2]
  1401         x = "Abs_Real (realrel``{(inverse (D) + 1, 1)})" 
  1402        in exI)
  1403 apply (auto simp add: real_mult preal_mult_inverse_right algebra_simps)
  1404 done
  1405 
  1406 lemma real_mult_inverse_left: "x \<noteq> 0 ==> inverse(x)*x = (1::real)"
  1407 apply (simp add: real_inverse_def)
  1408 apply (drule real_mult_inverse_left_ex, safe)
  1409 apply (rule theI, assumption, rename_tac z)
  1410 apply (subgoal_tac "(z * x) * y = z * (x * y)")
  1411 apply (simp add: mult_commute)
  1412 apply (rule mult_assoc)
  1413 done
  1414 
  1415 
  1416 subsection{*The Real Numbers form a Field*}
  1417 
  1418 instance real :: field_inverse_zero
  1419 proof
  1420   fix x y z :: real
  1421   show "x \<noteq> 0 ==> inverse x * x = 1" by (rule real_mult_inverse_left)
  1422   show "x / y = x * inverse y" by (simp add: real_divide_def)
  1423   show "inverse 0 = (0::real)" by (simp add: real_inverse_def)
  1424 qed
  1425 
  1426 
  1427 subsection{*The @{text "\<le>"} Ordering*}
  1428 
  1429 lemma real_le_refl: "w \<le> (w::real)"
  1430 by (cases w, force simp add: real_le_def)
  1431 
  1432 text{*The arithmetic decision procedure is not set up for type preal.
  1433   This lemma is currently unused, but it could simplify the proofs of the
  1434   following two lemmas.*}
  1435 lemma preal_eq_le_imp_le:
  1436   assumes eq: "a+b = c+d" and le: "c \<le> a"
  1437   shows "b \<le> (d::preal)"
  1438 proof -
  1439   have "c+d \<le> a+d" by (simp add: prems)
  1440   hence "a+b \<le> a+d" by (simp add: prems)
  1441   thus "b \<le> d" by simp
  1442 qed
  1443 
  1444 lemma real_le_lemma:
  1445   assumes l: "u1 + v2 \<le> u2 + v1"
  1446       and "x1 + v1 = u1 + y1"
  1447       and "x2 + v2 = u2 + y2"
  1448   shows "x1 + y2 \<le> x2 + (y1::preal)"
  1449 proof -
  1450   have "(x1+v1) + (u2+y2) = (u1+y1) + (x2+v2)" by (simp add: prems)
  1451   hence "(x1+y2) + (u2+v1) = (x2+y1) + (u1+v2)" by (simp add: add_ac)
  1452   also have "... \<le> (x2+y1) + (u2+v1)" by (simp add: prems)
  1453   finally show ?thesis by simp
  1454 qed
  1455 
  1456 lemma real_le: 
  1457      "(Abs_Real(realrel``{(x1,y1)}) \<le> Abs_Real(realrel``{(x2,y2)})) =  
  1458       (x1 + y2 \<le> x2 + y1)"
  1459 apply (simp add: real_le_def)
  1460 apply (auto intro: real_le_lemma)
  1461 done
  1462 
  1463 lemma real_le_antisym: "[| z \<le> w; w \<le> z |] ==> z = (w::real)"
  1464 by (cases z, cases w, simp add: real_le)
  1465 
  1466 lemma real_trans_lemma:
  1467   assumes "x + v \<le> u + y"
  1468       and "u + v' \<le> u' + v"
  1469       and "x2 + v2 = u2 + y2"
  1470   shows "x + v' \<le> u' + (y::preal)"
  1471 proof -
  1472   have "(x+v') + (u+v) = (x+v) + (u+v')" by (simp add: add_ac)
  1473   also have "... \<le> (u+y) + (u+v')" by (simp add: prems)
  1474   also have "... \<le> (u+y) + (u'+v)" by (simp add: prems)
  1475   also have "... = (u'+y) + (u+v)"  by (simp add: add_ac)
  1476   finally show ?thesis by simp
  1477 qed
  1478 
  1479 lemma real_le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::real)"
  1480 apply (cases i, cases j, cases k)
  1481 apply (simp add: real_le)
  1482 apply (blast intro: real_trans_lemma)
  1483 done
  1484 
  1485 instance real :: order
  1486 proof
  1487   fix u v :: real
  1488   show "u < v \<longleftrightarrow> u \<le> v \<and> \<not> v \<le> u" 
  1489     by (auto simp add: real_less_def intro: real_le_antisym)
  1490 qed (assumption | rule real_le_refl real_le_trans real_le_antisym)+
  1491 
  1492 (* Axiom 'linorder_linear' of class 'linorder': *)
  1493 lemma real_le_linear: "(z::real) \<le> w | w \<le> z"
  1494 apply (cases z, cases w)
  1495 apply (auto simp add: real_le real_zero_def add_ac)
  1496 done
  1497 
  1498 instance real :: linorder
  1499   by (intro_classes, rule real_le_linear)
  1500 
  1501 
  1502 lemma real_le_eq_diff: "(x \<le> y) = (x-y \<le> (0::real))"
  1503 apply (cases x, cases y) 
  1504 apply (auto simp add: real_le real_zero_def real_diff_def real_add real_minus
  1505                       add_ac)
  1506 apply (simp_all add: add_assoc [symmetric])
  1507 done
  1508 
  1509 lemma real_add_left_mono: 
  1510   assumes le: "x \<le> y" shows "z + x \<le> z + (y::real)"
  1511 proof -
  1512   have "z + x - (z + y) = (z + -z) + (x - y)" 
  1513     by (simp add: algebra_simps) 
  1514   with le show ?thesis 
  1515     by (simp add: real_le_eq_diff[of x] real_le_eq_diff[of "z+x"] diff_minus)
  1516 qed
  1517 
  1518 lemma real_sum_gt_zero_less: "(0 < S + (-W::real)) ==> (W < S)"
  1519 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
  1520 
  1521 lemma real_less_sum_gt_zero: "(W < S) ==> (0 < S + (-W::real))"
  1522 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
  1523 
  1524 lemma real_mult_order: "[| 0 < x; 0 < y |] ==> (0::real) < x * y"
  1525 apply (cases x, cases y)
  1526 apply (simp add: linorder_not_le [where 'a = real, symmetric] 
  1527                  linorder_not_le [where 'a = preal] 
  1528                   real_zero_def real_le real_mult)
  1529   --{*Reduce to the (simpler) @{text "\<le>"} relation *}
  1530 apply (auto dest!: less_add_left_Ex
  1531      simp add: algebra_simps preal_self_less_add_left)
  1532 done
  1533 
  1534 lemma real_mult_less_mono2: "[| (0::real) < z; x < y |] ==> z * x < z * y"
  1535 apply (rule real_sum_gt_zero_less)
  1536 apply (drule real_less_sum_gt_zero [of x y])
  1537 apply (drule real_mult_order, assumption)
  1538 apply (simp add: right_distrib)
  1539 done
  1540 
  1541 instantiation real :: distrib_lattice
  1542 begin
  1543 
  1544 definition
  1545   "(inf \<Colon> real \<Rightarrow> real \<Rightarrow> real) = min"
  1546 
  1547 definition
  1548   "(sup \<Colon> real \<Rightarrow> real \<Rightarrow> real) = max"
  1549 
  1550 instance
  1551   by default (auto simp add: inf_real_def sup_real_def min_max.sup_inf_distrib1)
  1552 
  1553 end
  1554 
  1555 
  1556 subsection{*The Reals Form an Ordered Field*}
  1557 
  1558 instance real :: linordered_field_inverse_zero
  1559 proof
  1560   fix x y z :: real
  1561   show "x \<le> y ==> z + x \<le> z + y" by (rule real_add_left_mono)
  1562   show "x < y ==> 0 < z ==> z * x < z * y" by (rule real_mult_less_mono2)
  1563   show "\<bar>x\<bar> = (if x < 0 then -x else x)" by (simp only: real_abs_def)
  1564   show "sgn x = (if x=0 then 0 else if 0<x then 1 else - 1)"
  1565     by (simp only: real_sgn_def)
  1566 qed
  1567 
  1568 text{*The function @{term real_of_preal} requires many proofs, but it seems
  1569 to be essential for proving completeness of the reals from that of the
  1570 positive reals.*}
  1571 
  1572 lemma real_of_preal_add:
  1573      "real_of_preal ((x::preal) + y) = real_of_preal x + real_of_preal y"
  1574 by (simp add: real_of_preal_def real_add algebra_simps)
  1575 
  1576 lemma real_of_preal_mult:
  1577      "real_of_preal ((x::preal) * y) = real_of_preal x* real_of_preal y"
  1578 by (simp add: real_of_preal_def real_mult algebra_simps)
  1579 
  1580 
  1581 text{*Gleason prop 9-4.4 p 127*}
  1582 lemma real_of_preal_trichotomy:
  1583       "\<exists>m. (x::real) = real_of_preal m | x = 0 | x = -(real_of_preal m)"
  1584 apply (simp add: real_of_preal_def real_zero_def, cases x)
  1585 apply (auto simp add: real_minus add_ac)
  1586 apply (cut_tac x = x and y = y in linorder_less_linear)
  1587 apply (auto dest!: less_add_left_Ex simp add: add_assoc [symmetric])
  1588 done
  1589 
  1590 lemma real_of_preal_leD:
  1591       "real_of_preal m1 \<le> real_of_preal m2 ==> m1 \<le> m2"
  1592 by (simp add: real_of_preal_def real_le)
  1593 
  1594 lemma real_of_preal_lessI: "m1 < m2 ==> real_of_preal m1 < real_of_preal m2"
  1595 by (auto simp add: real_of_preal_leD linorder_not_le [symmetric])
  1596 
  1597 lemma real_of_preal_lessD:
  1598       "real_of_preal m1 < real_of_preal m2 ==> m1 < m2"
  1599 by (simp add: real_of_preal_def real_le linorder_not_le [symmetric])
  1600 
  1601 lemma real_of_preal_less_iff [simp]:
  1602      "(real_of_preal m1 < real_of_preal m2) = (m1 < m2)"
  1603 by (blast intro: real_of_preal_lessI real_of_preal_lessD)
  1604 
  1605 lemma real_of_preal_le_iff:
  1606      "(real_of_preal m1 \<le> real_of_preal m2) = (m1 \<le> m2)"
  1607 by (simp add: linorder_not_less [symmetric])
  1608 
  1609 lemma real_of_preal_zero_less: "0 < real_of_preal m"
  1610 apply (insert preal_self_less_add_left [of 1 m])
  1611 apply (auto simp add: real_zero_def real_of_preal_def
  1612                       real_less_def real_le_def add_ac)
  1613 apply (rule_tac x="m + 1" in exI, rule_tac x="1" in exI)
  1614 apply (simp add: add_ac)
  1615 done
  1616 
  1617 lemma real_of_preal_minus_less_zero: "- real_of_preal m < 0"
  1618 by (simp add: real_of_preal_zero_less)
  1619 
  1620 lemma real_of_preal_not_minus_gt_zero: "~ 0 < - real_of_preal m"
  1621 proof -
  1622   from real_of_preal_minus_less_zero
  1623   show ?thesis by (blast dest: order_less_trans)
  1624 qed
  1625 
  1626 
  1627 subsection{*Theorems About the Ordering*}
  1628 
  1629 lemma real_gt_zero_preal_Ex: "(0 < x) = (\<exists>y. x = real_of_preal y)"
  1630 apply (auto simp add: real_of_preal_zero_less)
  1631 apply (cut_tac x = x in real_of_preal_trichotomy)
  1632 apply (blast elim!: real_of_preal_not_minus_gt_zero [THEN notE])
  1633 done
  1634 
  1635 lemma real_gt_preal_preal_Ex:
  1636      "real_of_preal z < x ==> \<exists>y. x = real_of_preal y"
  1637 by (blast dest!: real_of_preal_zero_less [THEN order_less_trans]
  1638              intro: real_gt_zero_preal_Ex [THEN iffD1])
  1639 
  1640 lemma real_ge_preal_preal_Ex:
  1641      "real_of_preal z \<le> x ==> \<exists>y. x = real_of_preal y"
  1642 by (blast dest: order_le_imp_less_or_eq real_gt_preal_preal_Ex)
  1643 
  1644 lemma real_less_all_preal: "y \<le> 0 ==> \<forall>x. y < real_of_preal x"
  1645 by (auto elim: order_le_imp_less_or_eq [THEN disjE] 
  1646             intro: real_of_preal_zero_less [THEN [2] order_less_trans] 
  1647             simp add: real_of_preal_zero_less)
  1648 
  1649 lemma real_less_all_real2: "~ 0 < y ==> \<forall>x. y < real_of_preal x"
  1650 by (blast intro!: real_less_all_preal linorder_not_less [THEN iffD1])
  1651 
  1652 
  1653 subsection{*Numerals and Arithmetic*}
  1654 
  1655 instantiation real :: number_ring
  1656 begin
  1657 
  1658 definition
  1659   real_number_of_def: "(number_of w :: real) = of_int w"
  1660 
  1661 instance
  1662   by intro_classes (simp add: real_number_of_def)
  1663 
  1664 end
  1665 
  1666 subsection {* Completeness of Positive Reals *}
  1667 
  1668 text {*
  1669   Supremum property for the set of positive reals
  1670 
  1671   Let @{text "P"} be a non-empty set of positive reals, with an upper
  1672   bound @{text "y"}.  Then @{text "P"} has a least upper bound
  1673   (written @{text "S"}).
  1674 
  1675   FIXME: Can the premise be weakened to @{text "\<forall>x \<in> P. x\<le> y"}?
  1676 *}
  1677 
  1678 lemma posreal_complete:
  1679   assumes positive_P: "\<forall>x \<in> P. (0::real) < x"
  1680     and not_empty_P: "\<exists>x. x \<in> P"
  1681     and upper_bound_Ex: "\<exists>y. \<forall>x \<in> P. x<y"
  1682   shows "\<exists>S. \<forall>y. (\<exists>x \<in> P. y < x) = (y < S)"
  1683 proof (rule exI, rule allI)
  1684   fix y
  1685   let ?pP = "{w. real_of_preal w \<in> P}"
  1686 
  1687   show "(\<exists>x\<in>P. y < x) = (y < real_of_preal (psup ?pP))"
  1688   proof (cases "0 < y")
  1689     assume neg_y: "\<not> 0 < y"
  1690     show ?thesis
  1691     proof
  1692       assume "\<exists>x\<in>P. y < x"
  1693       have "\<forall>x. y < real_of_preal x"
  1694         using neg_y by (rule real_less_all_real2)
  1695       thus "y < real_of_preal (psup ?pP)" ..
  1696     next
  1697       assume "y < real_of_preal (psup ?pP)"
  1698       obtain "x" where x_in_P: "x \<in> P" using not_empty_P ..
  1699       hence "0 < x" using positive_P by simp
  1700       hence "y < x" using neg_y by simp
  1701       thus "\<exists>x \<in> P. y < x" using x_in_P ..
  1702     qed
  1703   next
  1704     assume pos_y: "0 < y"
  1705 
  1706     then obtain py where y_is_py: "y = real_of_preal py"
  1707       by (auto simp add: real_gt_zero_preal_Ex)
  1708 
  1709     obtain a where "a \<in> P" using not_empty_P ..
  1710     with positive_P have a_pos: "0 < a" ..
  1711     then obtain pa where "a = real_of_preal pa"
  1712       by (auto simp add: real_gt_zero_preal_Ex)
  1713     hence "pa \<in> ?pP" using `a \<in> P` by auto
  1714     hence pP_not_empty: "?pP \<noteq> {}" by auto
  1715 
  1716     obtain sup where sup: "\<forall>x \<in> P. x < sup"
  1717       using upper_bound_Ex ..
  1718     from this and `a \<in> P` have "a < sup" ..
  1719     hence "0 < sup" using a_pos by arith
  1720     then obtain possup where "sup = real_of_preal possup"
  1721       by (auto simp add: real_gt_zero_preal_Ex)
  1722     hence "\<forall>X \<in> ?pP. X \<le> possup"
  1723       using sup by (auto simp add: real_of_preal_lessI)
  1724     with pP_not_empty have psup: "\<And>Z. (\<exists>X \<in> ?pP. Z < X) = (Z < psup ?pP)"
  1725       by (rule preal_complete)
  1726 
  1727     show ?thesis
  1728     proof
  1729       assume "\<exists>x \<in> P. y < x"
  1730       then obtain x where x_in_P: "x \<in> P" and y_less_x: "y < x" ..
  1731       hence "0 < x" using pos_y by arith
  1732       then obtain px where x_is_px: "x = real_of_preal px"
  1733         by (auto simp add: real_gt_zero_preal_Ex)
  1734 
  1735       have py_less_X: "\<exists>X \<in> ?pP. py < X"
  1736       proof
  1737         show "py < px" using y_is_py and x_is_px and y_less_x
  1738           by (simp add: real_of_preal_lessI)
  1739         show "px \<in> ?pP" using x_in_P and x_is_px by simp
  1740       qed
  1741 
  1742       have "(\<exists>X \<in> ?pP. py < X) ==> (py < psup ?pP)"
  1743         using psup by simp
  1744       hence "py < psup ?pP" using py_less_X by simp
  1745       thus "y < real_of_preal (psup {w. real_of_preal w \<in> P})"
  1746         using y_is_py and pos_y by (simp add: real_of_preal_lessI)
  1747     next
  1748       assume y_less_psup: "y < real_of_preal (psup ?pP)"
  1749 
  1750       hence "py < psup ?pP" using y_is_py
  1751         by (simp add: real_of_preal_lessI)
  1752       then obtain "X" where py_less_X: "py < X" and X_in_pP: "X \<in> ?pP"
  1753         using psup by auto
  1754       then obtain x where x_is_X: "x = real_of_preal X"
  1755         by (simp add: real_gt_zero_preal_Ex)
  1756       hence "y < x" using py_less_X and y_is_py
  1757         by (simp add: real_of_preal_lessI)
  1758 
  1759       moreover have "x \<in> P" using x_is_X and X_in_pP by simp
  1760 
  1761       ultimately show "\<exists> x \<in> P. y < x" ..
  1762     qed
  1763   qed
  1764 qed
  1765 
  1766 text {*
  1767   \medskip Completeness properties using @{text "isUb"}, @{text "isLub"} etc.
  1768 *}
  1769 
  1770 lemma posreals_complete:
  1771   assumes positive_S: "\<forall>x \<in> S. 0 < x"
  1772     and not_empty_S: "\<exists>x. x \<in> S"
  1773     and upper_bound_Ex: "\<exists>u. isUb (UNIV::real set) S u"
  1774   shows "\<exists>t. isLub (UNIV::real set) S t"
  1775 proof
  1776   let ?pS = "{w. real_of_preal w \<in> S}"
  1777 
  1778   obtain u where "isUb UNIV S u" using upper_bound_Ex ..
  1779   hence sup: "\<forall>x \<in> S. x \<le> u" by (simp add: isUb_def setle_def)
  1780 
  1781   obtain x where x_in_S: "x \<in> S" using not_empty_S ..
  1782   hence x_gt_zero: "0 < x" using positive_S by simp
  1783   have  "x \<le> u" using sup and x_in_S ..
  1784   hence "0 < u" using x_gt_zero by arith
  1785 
  1786   then obtain pu where u_is_pu: "u = real_of_preal pu"
  1787     by (auto simp add: real_gt_zero_preal_Ex)
  1788 
  1789   have pS_less_pu: "\<forall>pa \<in> ?pS. pa \<le> pu"
  1790   proof
  1791     fix pa
  1792     assume "pa \<in> ?pS"
  1793     then obtain a where "a \<in> S" and "a = real_of_preal pa"
  1794       by simp
  1795     moreover hence "a \<le> u" using sup by simp
  1796     ultimately show "pa \<le> pu"
  1797       using sup and u_is_pu by (simp add: real_of_preal_le_iff)
  1798   qed
  1799 
  1800   have "\<forall>y \<in> S. y \<le> real_of_preal (psup ?pS)"
  1801   proof
  1802     fix y
  1803     assume y_in_S: "y \<in> S"
  1804     hence "0 < y" using positive_S by simp
  1805     then obtain py where y_is_py: "y = real_of_preal py"
  1806       by (auto simp add: real_gt_zero_preal_Ex)
  1807     hence py_in_pS: "py \<in> ?pS" using y_in_S by simp
  1808     with pS_less_pu have "py \<le> psup ?pS"
  1809       by (rule preal_psup_le)
  1810     thus "y \<le> real_of_preal (psup ?pS)"
  1811       using y_is_py by (simp add: real_of_preal_le_iff)
  1812   qed
  1813 
  1814   moreover {
  1815     fix x
  1816     assume x_ub_S: "\<forall>y\<in>S. y \<le> x"
  1817     have "real_of_preal (psup ?pS) \<le> x"
  1818     proof -
  1819       obtain "s" where s_in_S: "s \<in> S" using not_empty_S ..
  1820       hence s_pos: "0 < s" using positive_S by simp
  1821 
  1822       hence "\<exists> ps. s = real_of_preal ps" by (simp add: real_gt_zero_preal_Ex)
  1823       then obtain "ps" where s_is_ps: "s = real_of_preal ps" ..
  1824       hence ps_in_pS: "ps \<in> {w. real_of_preal w \<in> S}" using s_in_S by simp
  1825 
  1826       from x_ub_S have "s \<le> x" using s_in_S ..
  1827       hence "0 < x" using s_pos by simp
  1828       hence "\<exists> px. x = real_of_preal px" by (simp add: real_gt_zero_preal_Ex)
  1829       then obtain "px" where x_is_px: "x = real_of_preal px" ..
  1830 
  1831       have "\<forall>pe \<in> ?pS. pe \<le> px"
  1832       proof
  1833         fix pe
  1834         assume "pe \<in> ?pS"
  1835         hence "real_of_preal pe \<in> S" by simp
  1836         hence "real_of_preal pe \<le> x" using x_ub_S by simp
  1837         thus "pe \<le> px" using x_is_px by (simp add: real_of_preal_le_iff)
  1838       qed
  1839 
  1840       moreover have "?pS \<noteq> {}" using ps_in_pS by auto
  1841       ultimately have "(psup ?pS) \<le> px" by (simp add: psup_le_ub)
  1842       thus "real_of_preal (psup ?pS) \<le> x" using x_is_px by (simp add: real_of_preal_le_iff)
  1843     qed
  1844   }
  1845   ultimately show "isLub UNIV S (real_of_preal (psup ?pS))"
  1846     by (simp add: isLub_def leastP_def isUb_def setle_def setge_def)
  1847 qed
  1848 
  1849 text {*
  1850   \medskip reals Completeness (again!)
  1851 *}
  1852 
  1853 lemma reals_complete:
  1854   assumes notempty_S: "\<exists>X. X \<in> S"
  1855     and exists_Ub: "\<exists>Y. isUb (UNIV::real set) S Y"
  1856   shows "\<exists>t. isLub (UNIV :: real set) S t"
  1857 proof -
  1858   obtain X where X_in_S: "X \<in> S" using notempty_S ..
  1859   obtain Y where Y_isUb: "isUb (UNIV::real set) S Y"
  1860     using exists_Ub ..
  1861   let ?SHIFT = "{z. \<exists>x \<in>S. z = x + (-X) + 1} \<inter> {x. 0 < x}"
  1862 
  1863   {
  1864     fix x
  1865     assume "isUb (UNIV::real set) S x"
  1866     hence S_le_x: "\<forall> y \<in> S. y <= x"
  1867       by (simp add: isUb_def setle_def)
  1868     {
  1869       fix s
  1870       assume "s \<in> {z. \<exists>x\<in>S. z = x + - X + 1}"
  1871       hence "\<exists> x \<in> S. s = x + -X + 1" ..
  1872       then obtain x1 where "x1 \<in> S" and "s = x1 + (-X) + 1" ..
  1873       moreover hence "x1 \<le> x" using S_le_x by simp
  1874       ultimately have "s \<le> x + - X + 1" by arith
  1875     }
  1876     then have "isUb (UNIV::real set) ?SHIFT (x + (-X) + 1)"
  1877       by (auto simp add: isUb_def setle_def)
  1878   } note S_Ub_is_SHIFT_Ub = this
  1879 
  1880   hence "isUb UNIV ?SHIFT (Y + (-X) + 1)" using Y_isUb by simp
  1881   hence "\<exists>Z. isUb UNIV ?SHIFT Z" ..
  1882   moreover have "\<forall>y \<in> ?SHIFT. 0 < y" by auto
  1883   moreover have shifted_not_empty: "\<exists>u. u \<in> ?SHIFT"
  1884     using X_in_S and Y_isUb by auto
  1885   ultimately obtain t where t_is_Lub: "isLub UNIV ?SHIFT t"
  1886     using posreals_complete [of ?SHIFT] by blast
  1887 
  1888   show ?thesis
  1889   proof
  1890     show "isLub UNIV S (t + X + (-1))"
  1891     proof (rule isLubI2)
  1892       {
  1893         fix x
  1894         assume "isUb (UNIV::real set) S x"
  1895         hence "isUb (UNIV::real set) (?SHIFT) (x + (-X) + 1)"
  1896           using S_Ub_is_SHIFT_Ub by simp
  1897         hence "t \<le> (x + (-X) + 1)"
  1898           using t_is_Lub by (simp add: isLub_le_isUb)
  1899         hence "t + X + -1 \<le> x" by arith
  1900       }
  1901       then show "(t + X + -1) <=* Collect (isUb UNIV S)"
  1902         by (simp add: setgeI)
  1903     next
  1904       show "isUb UNIV S (t + X + -1)"
  1905       proof -
  1906         {
  1907           fix y
  1908           assume y_in_S: "y \<in> S"
  1909           have "y \<le> t + X + -1"
  1910           proof -
  1911             obtain "u" where u_in_shift: "u \<in> ?SHIFT" using shifted_not_empty ..
  1912             hence "\<exists> x \<in> S. u = x + - X + 1" by simp
  1913             then obtain "x" where x_and_u: "u = x + - X + 1" ..
  1914             have u_le_t: "u \<le> t" using u_in_shift and t_is_Lub by (simp add: isLubD2)
  1915 
  1916             show ?thesis
  1917             proof cases
  1918               assume "y \<le> x"
  1919               moreover have "x = u + X + - 1" using x_and_u by arith
  1920               moreover have "u + X + - 1  \<le> t + X + -1" using u_le_t by arith
  1921               ultimately show "y  \<le> t + X + -1" by arith
  1922             next
  1923               assume "~(y \<le> x)"
  1924               hence x_less_y: "x < y" by arith
  1925 
  1926               have "x + (-X) + 1 \<in> ?SHIFT" using x_and_u and u_in_shift by simp
  1927               hence "0 < x + (-X) + 1" by simp
  1928               hence "0 < y + (-X) + 1" using x_less_y by arith
  1929               hence "y + (-X) + 1 \<in> ?SHIFT" using y_in_S by simp
  1930               hence "y + (-X) + 1 \<le> t" using t_is_Lub  by (simp add: isLubD2)
  1931               thus ?thesis by simp
  1932             qed
  1933           qed
  1934         }
  1935         then show ?thesis by (simp add: isUb_def setle_def)
  1936       qed
  1937     qed
  1938   qed
  1939 qed
  1940 
  1941 text{*A version of the same theorem without all those predicates!*}
  1942 lemma reals_complete2:
  1943   fixes S :: "(real set)"
  1944   assumes "\<exists>y. y\<in>S" and "\<exists>(x::real). \<forall>y\<in>S. y \<le> x"
  1945   shows "\<exists>x. (\<forall>y\<in>S. y \<le> x) & 
  1946                (\<forall>z. ((\<forall>y\<in>S. y \<le> z) --> x \<le> z))"
  1947 proof -
  1948   have "\<exists>x. isLub UNIV S x" 
  1949     by (rule reals_complete)
  1950        (auto simp add: isLub_def isUb_def leastP_def setle_def setge_def prems)
  1951   thus ?thesis
  1952     by (metis UNIV_I isLub_isUb isLub_le_isUb isUbD isUb_def setleI)
  1953 qed
  1954 
  1955 
  1956 subsection {* The Archimedean Property of the Reals *}
  1957 
  1958 theorem reals_Archimedean:
  1959   fixes x :: real
  1960   assumes x_pos: "0 < x"
  1961   shows "\<exists>n. inverse (of_nat (Suc n)) < x"
  1962 proof (rule ccontr)
  1963   assume contr: "\<not> ?thesis"
  1964   have "\<forall>n. x * of_nat (Suc n) <= 1"
  1965   proof
  1966     fix n
  1967     from contr have "x \<le> inverse (of_nat (Suc n))"
  1968       by (simp add: linorder_not_less)
  1969     hence "x \<le> (1 / (of_nat (Suc n)))"
  1970       by (simp add: inverse_eq_divide)
  1971     moreover have "(0::real) \<le> of_nat (Suc n)"
  1972       by (rule of_nat_0_le_iff)
  1973     ultimately have "x * of_nat (Suc n) \<le> (1 / of_nat (Suc n)) * of_nat (Suc n)"
  1974       by (rule mult_right_mono)
  1975     thus "x * of_nat (Suc n) \<le> 1" by (simp del: of_nat_Suc)
  1976   qed
  1977   hence "{z. \<exists>n. z = x * (of_nat (Suc n))} *<= 1"
  1978     by (simp add: setle_def del: of_nat_Suc, safe, rule spec)
  1979   hence "isUb (UNIV::real set) {z. \<exists>n. z = x * (of_nat (Suc n))} 1"
  1980     by (simp add: isUbI)
  1981   hence "\<exists>Y. isUb (UNIV::real set) {z. \<exists>n. z = x* (of_nat (Suc n))} Y" ..
  1982   moreover have "\<exists>X. X \<in> {z. \<exists>n. z = x* (of_nat (Suc n))}" by auto
  1983   ultimately have "\<exists>t. isLub UNIV {z. \<exists>n. z = x * of_nat (Suc n)} t"
  1984     by (simp add: reals_complete)
  1985   then obtain "t" where
  1986     t_is_Lub: "isLub UNIV {z. \<exists>n. z = x * of_nat (Suc n)} t" ..
  1987 
  1988   have "\<forall>n::nat. x * of_nat n \<le> t + - x"
  1989   proof
  1990     fix n
  1991     from t_is_Lub have "x * of_nat (Suc n) \<le> t"
  1992       by (simp add: isLubD2)
  1993     hence  "x * (of_nat n) + x \<le> t"
  1994       by (simp add: right_distrib)
  1995     thus  "x * (of_nat n) \<le> t + - x" by arith
  1996   qed
  1997 
  1998   hence "\<forall>m. x * of_nat (Suc m) \<le> t + - x" by (simp del: of_nat_Suc)
  1999   hence "{z. \<exists>n. z = x * (of_nat (Suc n))}  *<= (t + - x)"
  2000     by (auto simp add: setle_def)
  2001   hence "isUb (UNIV::real set) {z. \<exists>n. z = x * (of_nat (Suc n))} (t + (-x))"
  2002     by (simp add: isUbI)
  2003   hence "t \<le> t + - x"
  2004     using t_is_Lub by (simp add: isLub_le_isUb)
  2005   thus False using x_pos by arith
  2006 qed
  2007 
  2008 text {*
  2009   There must be other proofs, e.g. @{text Suc} of the largest
  2010   integer in the cut representing @{text "x"}.
  2011 *}
  2012 
  2013 lemma reals_Archimedean2: "\<exists>n. (x::real) < of_nat (n::nat)"
  2014 proof cases
  2015   assume "x \<le> 0"
  2016   hence "x < of_nat (1::nat)" by simp
  2017   thus ?thesis ..
  2018 next
  2019   assume "\<not> x \<le> 0"
  2020   hence x_greater_zero: "0 < x" by simp
  2021   hence "0 < inverse x" by simp
  2022   then obtain n where "inverse (of_nat (Suc n)) < inverse x"
  2023     using reals_Archimedean by blast
  2024   hence "inverse (of_nat (Suc n)) * x < inverse x * x"
  2025     using x_greater_zero by (rule mult_strict_right_mono)
  2026   hence "inverse (of_nat (Suc n)) * x < 1"
  2027     using x_greater_zero by simp
  2028   hence "of_nat (Suc n) * (inverse (of_nat (Suc n)) * x) < of_nat (Suc n) * 1"
  2029     by (rule mult_strict_left_mono) (simp del: of_nat_Suc)
  2030   hence "x < of_nat (Suc n)"
  2031     by (simp add: algebra_simps del: of_nat_Suc)
  2032   thus "\<exists>(n::nat). x < of_nat n" ..
  2033 qed
  2034 
  2035 instance real :: archimedean_field
  2036 proof
  2037   fix r :: real
  2038   obtain n :: nat where "r < of_nat n"
  2039     using reals_Archimedean2 ..
  2040   then have "r \<le> of_int (int n)"
  2041     by simp
  2042   then show "\<exists>z. r \<le> of_int z" ..
  2043 qed
  2044 
  2045 end