src/Pure/PIDE/document.ML
author wenzelm
Fri Jul 08 22:00:53 2011 +0200 (2011-07-08 ago)
changeset 43713 1ba5331b4623
parent 43668 aad4f1956098
child 43722 9b5dadb0c28d
permissions -rw-r--r--
moved global state to structure Document (again);
     1 (*  Title:      Pure/PIDE/document.ML
     2     Author:     Makarius
     3 
     4 Document as collection of named nodes, each consisting of an editable
     5 list of commands, associated with asynchronous execution process.
     6 *)
     7 
     8 signature DOCUMENT =
     9 sig
    10   type id = int
    11   type version_id = id
    12   type command_id = id
    13   type exec_id = id
    14   val no_id: id
    15   val new_id: unit -> id
    16   val parse_id: string -> id
    17   val print_id: id -> string
    18   type edit = string * ((command_id option * command_id option) list) option
    19   type state
    20   val init_state: state
    21   val get_theory: state -> version_id -> Position.T -> string -> theory
    22   val cancel_execution: state -> unit -> unit
    23   val define_command: command_id -> string -> state -> state
    24   val edit: version_id -> version_id -> edit list -> state -> (command_id * exec_id) list * state
    25   val execute: version_id -> state -> state
    26   val state: unit -> state
    27   val change_state: (state -> state) -> unit
    28 end;
    29 
    30 structure Document: DOCUMENT =
    31 struct
    32 
    33 (* unique identifiers *)
    34 
    35 type id = int;
    36 type version_id = id;
    37 type command_id = id;
    38 type exec_id = id;
    39 
    40 val no_id = 0;
    41 val new_id = Synchronized.counter ();
    42 
    43 val parse_id = Markup.parse_int;
    44 val print_id = Markup.print_int;
    45 
    46 fun err_dup kind id = error ("Duplicate " ^ kind ^ ": " ^ print_id id);
    47 fun err_undef kind id = error ("Undefined " ^ kind ^ ": " ^ print_id id);
    48 
    49 
    50 
    51 (** document structure **)
    52 
    53 structure Entries = Linear_Set(type key = command_id val ord = int_ord);
    54 
    55 abstype node = Node of
    56   {last: exec_id, entries: exec_id option Entries.T}  (*command entries with excecutions*)
    57 and version = Version of node Graph.T  (*development graph wrt. static imports*)
    58 with
    59 
    60 fun make_node (last, entries) =
    61   Node {last = last, entries = entries};
    62 
    63 fun get_last (Node {last, ...}) = last;
    64 fun set_last last (Node {entries, ...}) = make_node (last, entries);
    65 
    66 fun map_entries f (Node {last, entries}) = make_node (last, f entries);
    67 fun fold_entries start f (Node {entries, ...}) = Entries.fold start f entries;
    68 fun first_entry start P (Node {entries, ...}) = Entries.get_first start P entries;
    69 
    70 val empty_node = make_node (no_id, Entries.empty);
    71 val empty_version = Version Graph.empty;
    72 
    73 
    74 (* node edits and associated executions *)
    75 
    76 type edit =
    77   string *
    78   (*NONE: remove node, SOME: insert/remove commands*)
    79   ((command_id option * command_id option) list) option;
    80 
    81 fun the_entry (Node {entries, ...}) id =
    82   (case Entries.lookup entries id of
    83     NONE => err_undef "command entry" id
    84   | SOME entry => entry);
    85 
    86 fun update_entry (id, exec_id) =
    87   map_entries (Entries.update (id, SOME exec_id));
    88 
    89 fun reset_after id entries =
    90   (case Entries.get_after entries id of
    91     NONE => entries
    92   | SOME next => Entries.update (next, NONE) entries);
    93 
    94 val edit_node = map_entries o fold
    95   (fn (id, SOME id2) => Entries.insert_after id (id2, NONE)
    96     | (id, NONE) => Entries.delete_after id #> reset_after id);
    97 
    98 
    99 (* version operations *)
   100 
   101 fun nodes_of (Version nodes) = nodes;
   102 val node_names_of = Graph.keys o nodes_of;
   103 
   104 fun get_node version name = Graph.get_node (nodes_of version) name
   105   handle Graph.UNDEF _ => empty_node;
   106 
   107 fun edit_nodes (name, SOME edits) (Version nodes) =
   108       Version (nodes
   109         |> Graph.default_node (name, empty_node)
   110         |> Graph.map_node name (edit_node edits))
   111   | edit_nodes (name, NONE) (Version nodes) =
   112       Version (perhaps (try (Graph.del_node name)) nodes);
   113 
   114 fun put_node name node (Version nodes) =
   115   Version (nodes
   116     |> Graph.default_node (name, empty_node)
   117     |> Graph.map_node name (K node));
   118 
   119 end;
   120 
   121 
   122 
   123 (** global state -- document structure and execution process **)
   124 
   125 abstype state = State of
   126  {versions: version Inttab.table,  (*version_id -> document content*)
   127   commands: Toplevel.transition future Inttab.table,  (*command_id -> transition (future parsing)*)
   128   execs: (bool * Toplevel.state) lazy Inttab.table,  (*exec_id -> execution process*)
   129   execution: unit future list}  (*global execution process*)
   130 with
   131 
   132 fun make_state (versions, commands, execs, execution) =
   133   State {versions = versions, commands = commands, execs = execs, execution = execution};
   134 
   135 fun map_state f (State {versions, commands, execs, execution}) =
   136   make_state (f (versions, commands, execs, execution));
   137 
   138 val init_state =
   139   make_state (Inttab.make [(no_id, empty_version)],
   140     Inttab.make [(no_id, Future.value Toplevel.empty)],
   141     Inttab.make [(no_id, Lazy.value (true, Toplevel.toplevel))],
   142     []);
   143 
   144 
   145 (* document versions *)
   146 
   147 fun define_version (id: version_id) version =
   148   map_state (fn (versions, commands, execs, execution) =>
   149     let val versions' = Inttab.update_new (id, version) versions
   150       handle Inttab.DUP dup => err_dup "document version" dup
   151     in (versions', commands, execs, execution) end);
   152 
   153 fun the_version (State {versions, ...}) (id: version_id) =
   154   (case Inttab.lookup versions id of
   155     NONE => err_undef "document version" id
   156   | SOME version => version);
   157 
   158 
   159 (* commands *)
   160 
   161 fun define_command (id: command_id) text =
   162   map_state (fn (versions, commands, execs, execution) =>
   163     let
   164       val id_string = print_id id;
   165       val tr = Future.fork_pri 2 (fn () =>
   166         Position.setmp_thread_data (Position.id_only id_string)
   167           (fn () => Outer_Syntax.prepare_command (Position.id id_string) text) ());
   168       val commands' =
   169         Inttab.update_new (id, tr) commands
   170           handle Inttab.DUP dup => err_dup "command" dup;
   171     in (versions, commands', execs, execution) end);
   172 
   173 fun the_command (State {commands, ...}) (id: command_id) =
   174   (case Inttab.lookup commands id of
   175     NONE => err_undef "command" id
   176   | SOME tr => tr);
   177 
   178 fun join_commands (State {commands, ...}) =
   179   Inttab.fold (fn (_, tr) => fn () => ignore (Future.join_result tr)) commands ();
   180 
   181 
   182 (* command executions *)
   183 
   184 fun define_exec (id: exec_id) exec =
   185   map_state (fn (versions, commands, execs, execution) =>
   186     let val execs' = Inttab.update_new (id, exec) execs
   187       handle Inttab.DUP dup => err_dup "command execution" dup
   188     in (versions, commands, execs', execution) end);
   189 
   190 fun the_exec (State {execs, ...}) (id: exec_id) =
   191   (case Inttab.lookup execs id of
   192     NONE => err_undef "command execution" id
   193   | SOME exec => exec);
   194 
   195 fun get_theory state version_id pos name =
   196   let
   197     val last = get_last (get_node (the_version state version_id) name);
   198     val st = #2 (Lazy.force (the_exec state last));
   199   in Toplevel.end_theory pos st end;
   200 
   201 
   202 (* document execution *)
   203 
   204 fun cancel_execution (State {execution, ...}) =
   205   (List.app Future.cancel execution;
   206     fn () => ignore (Future.join_results execution));
   207 
   208 end;
   209 
   210 
   211 
   212 (* toplevel transactions *)
   213 
   214 local
   215 
   216 fun timing tr t = Toplevel.status tr (Markup.timing t);
   217 
   218 fun proof_status tr st =
   219   (case try Toplevel.proof_of st of
   220     SOME prf => Toplevel.status tr (Proof.status_markup prf)
   221   | NONE => ());
   222 
   223 fun async_state tr st =
   224   ignore
   225     (singleton
   226       (Future.forks {name = "Document.async_state",
   227         group = SOME (Task_Queue.new_group NONE), deps = [], pri = 0})
   228       (fn () =>
   229         Toplevel.setmp_thread_position tr
   230           (fn () => Toplevel.print_state false st) ()));
   231 
   232 fun run int tr st =
   233   (case Toplevel.transition int tr st of
   234     SOME (st', NONE) => ([], SOME st')
   235   | SOME (_, SOME exn_info) =>
   236       (case ML_Compiler.exn_messages (Runtime.EXCURSION_FAIL exn_info) of
   237         [] => Exn.interrupt ()
   238       | errs => (errs, NONE))
   239   | NONE => ([ML_Compiler.exn_message Runtime.TERMINATE], NONE));
   240 
   241 in
   242 
   243 fun run_command thy_name raw_tr st =
   244   (case
   245       (case Toplevel.init_of raw_tr of
   246         SOME name => Exn.capture (fn () =>
   247           let
   248             val path = Path.explode thy_name;
   249             val _ = Thy_Header.consistent_name (Path.implode (Path.base path)) name;
   250           in Toplevel.modify_master (SOME (Path.dir path)) raw_tr end) ()
   251       | NONE => Exn.Result raw_tr) of
   252     Exn.Result tr =>
   253       let
   254         val is_init = is_some (Toplevel.init_of tr);
   255         val is_proof = Keyword.is_proof (Toplevel.name_of tr);
   256         val do_print = not is_init andalso (Toplevel.print_of tr orelse is_proof);
   257 
   258         val start = Timing.start ();
   259         val (errs, result) =
   260           if Toplevel.is_toplevel st andalso not is_init then ([], SOME st)
   261           else run (is_init orelse is_proof) (Toplevel.set_print false tr) st;
   262         val _ = timing tr (Timing.result start);
   263         val _ = List.app (Toplevel.error_msg tr) errs;
   264         val res =
   265           (case result of
   266             NONE => (Toplevel.status tr Markup.failed; (false, st))
   267           | SOME st' =>
   268              (Toplevel.status tr Markup.finished;
   269               proof_status tr st';
   270               if do_print then async_state tr st' else ();
   271               (true, st')));
   272       in res end
   273   | Exn.Exn exn =>
   274       if Exn.is_interrupt exn then reraise exn
   275       else
   276        (Toplevel.error_msg raw_tr (ML_Compiler.exn_message exn);
   277         Toplevel.status raw_tr Markup.failed;
   278         (false, Toplevel.toplevel)));
   279 
   280 end;
   281 
   282 
   283 
   284 
   285 (** editing **)
   286 
   287 (* edit *)
   288 
   289 local
   290 
   291 fun is_changed node' ((_, id), exec) =
   292   (case try (the_entry node') id of
   293     NONE => true
   294   | SOME exec' => exec' <> exec);
   295 
   296 fun new_exec name (id: command_id) (exec_id, updates, state) =
   297   let
   298     val exec = the_exec state exec_id;
   299     val exec_id' = new_id ();
   300     val future_tr = the_command state id;
   301     val exec' =
   302       Lazy.lazy (fn () =>
   303         let
   304           val st = #2 (Lazy.force exec);
   305           val exec_tr = Toplevel.put_id (print_id exec_id') (Future.join future_tr);
   306         in run_command name exec_tr st end);
   307     val state' = define_exec exec_id' exec' state;
   308   in (exec_id', (id, exec_id') :: updates, state') end;
   309 
   310 in
   311 
   312 fun edit (old_id: version_id) (new_id: version_id) edits state =
   313   let
   314     val old_version = the_version state old_id;
   315     val _ = Time.now ();  (* FIXME odd workaround *)
   316     val new_version = fold edit_nodes edits old_version;
   317 
   318     fun update_node name (rev_updates, version, st) =
   319       let val node = get_node version name in
   320         (case first_entry NONE (is_changed (get_node old_version name)) node of
   321           NONE => (rev_updates, version, st)
   322         | SOME ((prev, id), _) =>
   323             let
   324               val prev_exec =
   325                 (case prev of
   326                   NONE => no_id
   327                 | SOME prev_id => the_default no_id (the_entry node prev_id));
   328               val (last, rev_upds, st') =
   329                 fold_entries (SOME id) (new_exec name o #2 o #1) node (prev_exec, [], st);
   330               val node' = node |> fold update_entry rev_upds |> set_last last;
   331             in (rev_upds @ rev_updates, put_node name node' version, st') end)
   332       end;
   333 
   334     (* FIXME proper node deps *)
   335     val (rev_updates, new_version', state') =
   336       fold update_node (node_names_of new_version) ([], new_version, state);
   337     val state'' = define_version new_id new_version' state';
   338 
   339     val _ = join_commands state'';  (* FIXME async!? *)
   340   in (rev rev_updates, state'') end;
   341 
   342 end;
   343 
   344 
   345 (* execute *)
   346 
   347 fun execute version_id state =
   348   state |> map_state (fn (versions, commands, execs, _) =>
   349     let
   350       val version = the_version state version_id;
   351 
   352       fun force_exec NONE = ()
   353         | force_exec (SOME exec_id) = ignore (Lazy.force (the_exec state exec_id));
   354 
   355       val execution' = (* FIXME proper node deps *)
   356         Future.forks {name = "Document.execute", group = NONE, deps = [], pri = 1}
   357           [fn () =>
   358             node_names_of version |> List.app (fn name =>
   359               fold_entries NONE (fn (_, exec) => fn () => force_exec exec)
   360                   (get_node version name) ())];
   361 
   362     in (versions, commands, execs, execution') end);
   363 
   364 
   365 
   366 (** global state **)
   367 
   368 val global_state = Synchronized.var "Document" init_state;
   369 
   370 fun state () = Synchronized.value global_state;
   371 val change_state = Synchronized.change global_state;
   372 
   373 end;
   374