src/HOL/Imperative_HOL/Array.thy
author haftmann
Sun Mar 21 06:59:23 2010 +0100 (2010-03-21 ago)
changeset 35846 2ae4b7585501
parent 32580 5b88ae4307ff
child 36176 3fe7e97ccca8
permissions -rw-r--r--
corrected setup for of_list
     1 (*  Title:      HOL/Imperative_HOL/Array.thy
     2     Author:     John Matthews, Galois Connections; Alexander Krauss, Lukas Bulwahn & Florian Haftmann, TU Muenchen
     3 *)
     4 
     5 header {* Monadic arrays *}
     6 
     7 theory Array
     8 imports Heap_Monad
     9 begin
    10 
    11 subsection {* Primitives *}
    12 
    13 definition
    14   new :: "nat \<Rightarrow> 'a\<Colon>heap \<Rightarrow> 'a array Heap" where
    15   [code del]: "new n x = Heap_Monad.heap (Heap.array n x)"
    16 
    17 definition
    18   of_list :: "'a\<Colon>heap list \<Rightarrow> 'a array Heap" where
    19   [code del]: "of_list xs = Heap_Monad.heap (Heap.array_of_list xs)"
    20 
    21 definition
    22   length :: "'a\<Colon>heap array \<Rightarrow> nat Heap" where
    23   [code del]: "length arr = Heap_Monad.heap (\<lambda>h. (Heap.length arr h, h))"
    24 
    25 definition
    26   nth :: "'a\<Colon>heap array \<Rightarrow> nat \<Rightarrow> 'a Heap"
    27 where
    28   [code del]: "nth a i = (do len \<leftarrow> length a;
    29                  (if i < len
    30                      then Heap_Monad.heap (\<lambda>h. (get_array a h ! i, h))
    31                      else raise (''array lookup: index out of range''))
    32               done)"
    33 
    34 definition
    35   upd :: "nat \<Rightarrow> 'a \<Rightarrow> 'a\<Colon>heap array \<Rightarrow> 'a\<Colon>heap array Heap"
    36 where
    37   [code del]: "upd i x a = (do len \<leftarrow> length a;
    38                       (if i < len
    39                            then Heap_Monad.heap (\<lambda>h. (a, Heap.upd a i x h))
    40                            else raise (''array update: index out of range''))
    41                    done)" 
    42 
    43 lemma upd_return:
    44   "upd i x a \<guillemotright> return a = upd i x a"
    45 proof (rule Heap_eqI)
    46   fix h
    47   obtain len h' where "Heap_Monad.execute (Array.length a) h = (len, h')"
    48     by (cases "Heap_Monad.execute (Array.length a) h")
    49   then show "Heap_Monad.execute (upd i x a \<guillemotright> return a) h = Heap_Monad.execute (upd i x a) h"
    50     by (auto simp add: upd_def bindM_def split: sum.split)
    51 qed
    52 
    53 
    54 subsection {* Derivates *}
    55 
    56 definition
    57   map_entry :: "nat \<Rightarrow> ('a\<Colon>heap \<Rightarrow> 'a) \<Rightarrow> 'a array \<Rightarrow> 'a array Heap"
    58 where
    59   "map_entry i f a = (do
    60      x \<leftarrow> nth a i;
    61      upd i (f x) a
    62    done)"
    63 
    64 definition
    65   swap :: "nat \<Rightarrow> 'a \<Rightarrow> 'a\<Colon>heap array \<Rightarrow> 'a Heap"
    66 where
    67   "swap i x a = (do
    68      y \<leftarrow> nth a i;
    69      upd i x a;
    70      return y
    71    done)"
    72 
    73 definition
    74   make :: "nat \<Rightarrow> (nat \<Rightarrow> 'a\<Colon>heap) \<Rightarrow> 'a array Heap"
    75 where
    76   "make n f = of_list (map f [0 ..< n])"
    77 
    78 definition
    79   freeze :: "'a\<Colon>heap array \<Rightarrow> 'a list Heap"
    80 where
    81   "freeze a = (do
    82      n \<leftarrow> length a;
    83      mapM (nth a) [0..<n]
    84    done)"
    85 
    86 definition
    87    map :: "('a\<Colon>heap \<Rightarrow> 'a) \<Rightarrow> 'a array \<Rightarrow> 'a array Heap"
    88 where
    89   "map f a = (do
    90      n \<leftarrow> length a;
    91      mapM (\<lambda>n. map_entry n f a) [0..<n];
    92      return a
    93    done)"
    94 
    95 hide (open) const new map -- {* avoid clashed with some popular names *}
    96 
    97 
    98 subsection {* Properties *}
    99 
   100 lemma array_make [code]:
   101   "Array.new n x = make n (\<lambda>_. x)"
   102   by (induct n) (simp_all add: make_def new_def Heap_Monad.heap_def
   103     monad_simp array_of_list_replicate [symmetric]
   104     map_replicate_trivial replicate_append_same
   105     of_list_def)
   106 
   107 lemma array_of_list_make [code]:
   108   "of_list xs = make (List.length xs) (\<lambda>n. xs ! n)"
   109   unfolding make_def map_nth ..
   110 
   111 
   112 subsection {* Code generator setup *}
   113 
   114 subsubsection {* Logical intermediate layer *}
   115 
   116 definition new' where
   117   [code del]: "new' = Array.new o Code_Numeral.nat_of"
   118 hide (open) const new'
   119 lemma [code]:
   120   "Array.new = Array.new' o Code_Numeral.of_nat"
   121   by (simp add: new'_def o_def)
   122 
   123 definition of_list' where
   124   [code del]: "of_list' i xs = Array.of_list (take (Code_Numeral.nat_of i) xs)"
   125 hide (open) const of_list'
   126 lemma [code]:
   127   "Array.of_list xs = Array.of_list' (Code_Numeral.of_nat (List.length xs)) xs"
   128   by (simp add: of_list'_def)
   129 
   130 definition make' where
   131   [code del]: "make' i f = Array.make (Code_Numeral.nat_of i) (f o Code_Numeral.of_nat)"
   132 hide (open) const make'
   133 lemma [code]:
   134   "Array.make n f = Array.make' (Code_Numeral.of_nat n) (f o Code_Numeral.nat_of)"
   135   by (simp add: make'_def o_def)
   136 
   137 definition length' where
   138   [code del]: "length' = Array.length \<guillemotright>== liftM Code_Numeral.of_nat"
   139 hide (open) const length'
   140 lemma [code]:
   141   "Array.length = Array.length' \<guillemotright>== liftM Code_Numeral.nat_of"
   142   by (simp add: length'_def monad_simp',
   143     simp add: liftM_def comp_def monad_simp,
   144     simp add: monad_simp')
   145 
   146 definition nth' where
   147   [code del]: "nth' a = Array.nth a o Code_Numeral.nat_of"
   148 hide (open) const nth'
   149 lemma [code]:
   150   "Array.nth a n = Array.nth' a (Code_Numeral.of_nat n)"
   151   by (simp add: nth'_def)
   152 
   153 definition upd' where
   154   [code del]: "upd' a i x = Array.upd (Code_Numeral.nat_of i) x a \<guillemotright> return ()"
   155 hide (open) const upd'
   156 lemma [code]:
   157   "Array.upd i x a = Array.upd' a (Code_Numeral.of_nat i) x \<guillemotright> return a"
   158   by (simp add: upd'_def monad_simp upd_return)
   159 
   160 
   161 subsubsection {* SML *}
   162 
   163 code_type array (SML "_/ array")
   164 code_const Array (SML "raise/ (Fail/ \"bare Array\")")
   165 code_const Array.new' (SML "(fn/ ()/ =>/ Array.array/ ((_),/ (_)))")
   166 code_const Array.of_list' (SML "(fn/ ()/ =>/ Array.fromList/ _)")
   167 code_const Array.make' (SML "(fn/ ()/ =>/ Array.tabulate/ ((_),/ (_)))")
   168 code_const Array.length' (SML "(fn/ ()/ =>/ Array.length/ _)")
   169 code_const Array.nth' (SML "(fn/ ()/ =>/ Array.sub/ ((_),/ (_)))")
   170 code_const Array.upd' (SML "(fn/ ()/ =>/ Array.update/ ((_),/ (_),/ (_)))")
   171 
   172 code_reserved SML Array
   173 
   174 
   175 subsubsection {* OCaml *}
   176 
   177 code_type array (OCaml "_/ array")
   178 code_const Array (OCaml "failwith/ \"bare Array\"")
   179 code_const Array.new' (OCaml "(fun/ ()/ ->/ Array.make/ (Big'_int.int'_of'_big'_int/ _)/ _)")
   180 code_const Array.of_list' (OCaml "(fun/ ()/ ->/ Array.of'_list/ _)")
   181 code_const Array.length' (OCaml "(fun/ ()/ ->/ Big'_int.big'_int'_of'_int/ (Array.length/ _))")
   182 code_const Array.nth' (OCaml "(fun/ ()/ ->/ Array.get/ _/ (Big'_int.int'_of'_big'_int/ _))")
   183 code_const Array.upd' (OCaml "(fun/ ()/ ->/ Array.set/ _/ (Big'_int.int'_of'_big'_int/ _)/ _)")
   184 
   185 code_reserved OCaml Array
   186 
   187 
   188 subsubsection {* Haskell *}
   189 
   190 code_type array (Haskell "Heap.STArray/ Heap.RealWorld/ _")
   191 code_const Array (Haskell "error/ \"bare Array\"")
   192 code_const Array.new' (Haskell "Heap.newArray/ (0,/ _)")
   193 code_const Array.of_list' (Haskell "Heap.newListArray/ (0,/ _)")
   194 code_const Array.length' (Haskell "Heap.lengthArray")
   195 code_const Array.nth' (Haskell "Heap.readArray")
   196 code_const Array.upd' (Haskell "Heap.writeArray")
   197 
   198 end