src/Pure/theory.ML
author wenzelm
Mon Jan 04 23:20:35 2010 +0100 (2010-01-04 ago)
changeset 34259 2ba492b8b6e8
parent 34245 25bd3ed2ac9f
child 35845 e5980f0ad025
permissions -rw-r--r--
discontinued old TheoryDataFun, but retain Theory_Data_PP with is Pretty.pp argument to merge (still required in exotic situations -- hard to get rid of);
     1 (*  Title:      Pure/theory.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical theory content: axioms, definitions, and begin/end wrappers.
     5 *)
     6 
     7 signature THEORY =
     8 sig
     9   val eq_thy: theory * theory -> bool
    10   val subthy: theory * theory -> bool
    11   val assert_super: theory -> theory -> theory
    12   val parents_of: theory -> theory list
    13   val ancestors_of: theory -> theory list
    14   val check_thy: theory -> theory_ref
    15   val deref: theory_ref -> theory
    16   val merge: theory * theory -> theory
    17   val merge_refs: theory_ref * theory_ref -> theory_ref
    18   val merge_list: theory list -> theory
    19   val checkpoint: theory -> theory
    20   val copy: theory -> theory
    21   val requires: theory -> string -> string -> unit
    22   val axiom_space: theory -> Name_Space.T
    23   val axiom_table: theory -> term Symtab.table
    24   val axioms_of: theory -> (string * term) list
    25   val all_axioms_of: theory -> (string * term) list
    26   val defs_of: theory -> Defs.T
    27   val at_begin: (theory -> theory option) -> theory -> theory
    28   val at_end: (theory -> theory option) -> theory -> theory
    29   val begin_theory: string -> theory list -> theory
    30   val end_theory: theory -> theory
    31   val add_axioms_i: (binding * term) list -> theory -> theory
    32   val add_axioms: (binding * string) list -> theory -> theory
    33   val add_deps: string -> string * typ -> (string * typ) list -> theory -> theory
    34   val add_defs_i: bool -> bool -> (binding * term) list -> theory -> theory
    35   val add_defs: bool -> bool -> (binding * string) list -> theory -> theory
    36   val add_finals_i: bool -> term list -> theory -> theory
    37   val add_finals: bool -> string list -> theory -> theory
    38   val specify_const: (binding * typ) * mixfix -> theory -> term * theory
    39 end
    40 
    41 structure Theory: THEORY =
    42 struct
    43 
    44 
    45 (** theory context operations **)
    46 
    47 val eq_thy = Context.eq_thy;
    48 val subthy = Context.subthy;
    49 
    50 fun assert_super thy1 thy2 =
    51   if subthy (thy1, thy2) then thy2
    52   else raise THEORY ("Not a super theory", [thy1, thy2]);
    53 
    54 val parents_of = Context.parents_of;
    55 val ancestors_of = Context.ancestors_of;
    56 
    57 val check_thy = Context.check_thy;
    58 val deref = Context.deref;
    59 
    60 val merge = Context.merge;
    61 val merge_refs = Context.merge_refs;
    62 
    63 fun merge_list [] = raise THEORY ("Empty merge of theories", [])
    64   | merge_list (thy :: thys) = Library.foldl merge (thy, thys);
    65 
    66 val checkpoint = Context.checkpoint_thy;
    67 val copy = Context.copy_thy;
    68 
    69 fun requires thy name what =
    70   if exists (fn thy' => Context.theory_name thy' = name) (thy :: ancestors_of thy) then ()
    71   else error ("Require theory " ^ quote name ^ " as an ancestor for " ^ what);
    72 
    73 
    74 
    75 (** datatype thy **)
    76 
    77 type wrapper = (theory -> theory option) * stamp;
    78 
    79 fun apply_wrappers (wrappers: wrapper list) =
    80   perhaps (perhaps_loop (perhaps_apply (map fst wrappers)));
    81 
    82 datatype thy = Thy of
    83  {axioms: term Name_Space.table,
    84   defs: Defs.T,
    85   wrappers: wrapper list * wrapper list};
    86 
    87 fun make_thy (axioms, defs, wrappers) = Thy {axioms = axioms, defs = defs, wrappers = wrappers};
    88 
    89 structure ThyData = Theory_Data_PP
    90 (
    91   type T = thy;
    92   val empty_axioms = Name_Space.empty_table "axiom" : term Name_Space.table;
    93   val empty = make_thy (empty_axioms, Defs.empty, ([], []));
    94 
    95   fun extend (Thy {axioms = _, defs, wrappers}) = make_thy (empty_axioms, defs, wrappers);
    96 
    97   fun merge pp (thy1, thy2) =
    98     let
    99       val Thy {axioms = _, defs = defs1, wrappers = (bgs1, ens1)} = thy1;
   100       val Thy {axioms = _, defs = defs2, wrappers = (bgs2, ens2)} = thy2;
   101 
   102       val axioms' = empty_axioms;
   103       val defs' = Defs.merge pp (defs1, defs2);
   104       val bgs' = Library.merge (eq_snd op =) (bgs1, bgs2);
   105       val ens' = Library.merge (eq_snd op =) (ens1, ens2);
   106     in make_thy (axioms', defs', (bgs', ens')) end;
   107 );
   108 
   109 fun rep_theory thy = ThyData.get thy |> (fn Thy args => args);
   110 
   111 fun map_thy f = ThyData.map (fn (Thy {axioms, defs, wrappers}) =>
   112   make_thy (f (axioms, defs, wrappers)));
   113 
   114 
   115 fun map_axioms f = map_thy (fn (axioms, defs, wrappers) => (f axioms, defs, wrappers));
   116 fun map_defs f = map_thy (fn (axioms, defs, wrappers) => (axioms, f defs, wrappers));
   117 fun map_wrappers f = map_thy (fn (axioms, defs, wrappers) => (axioms, defs, f wrappers));
   118 
   119 
   120 (* basic operations *)
   121 
   122 val axiom_space = #1 o #axioms o rep_theory;
   123 val axiom_table = #2 o #axioms o rep_theory;
   124 
   125 val axioms_of = Symtab.dest o #2 o #axioms o rep_theory;
   126 fun all_axioms_of thy = maps axioms_of (thy :: ancestors_of thy);
   127 
   128 val defs_of = #defs o rep_theory;
   129 
   130 
   131 (* begin/end theory *)
   132 
   133 val begin_wrappers = rev o #1 o #wrappers o rep_theory;
   134 val end_wrappers = rev o #2 o #wrappers o rep_theory;
   135 
   136 fun at_begin f = map_wrappers (apfst (cons (f, stamp ())));
   137 fun at_end f = map_wrappers (apsnd (cons (f, stamp ())));
   138 
   139 fun begin_theory name imports =
   140   let
   141     val thy = Context.begin_thy Syntax.pp_global name imports;
   142     val wrappers = begin_wrappers thy;
   143   in
   144     thy
   145     |> Sign.local_path
   146     |> Sign.map_naming (Name_Space.set_theory_name name)
   147     |> apply_wrappers wrappers
   148   end;
   149 
   150 fun end_theory thy =
   151   thy |> apply_wrappers (end_wrappers thy) |> Context.finish_thy;
   152 
   153 
   154 
   155 (** add axioms **)
   156 
   157 (* prepare axioms *)
   158 
   159 fun cert_axm thy (b, raw_tm) =
   160   let
   161     val t = Sign.cert_prop thy raw_tm
   162       handle TYPE (msg, _, _) => error msg
   163         | TERM (msg, _) => error msg;
   164   in
   165     Term.no_dummy_patterns t handle TERM (msg, _) => error msg;
   166     (b, Sign.no_vars (Syntax.pp_global thy) t)
   167   end;
   168 
   169 fun read_axm thy (b, str) =
   170   cert_axm thy (b, Syntax.read_prop_global thy str) handle ERROR msg =>
   171     cat_error msg ("The error(s) above occurred in axiom " ^ quote (Binding.str_of b));
   172 
   173 
   174 (* add_axioms(_i) *)
   175 
   176 local
   177 
   178 fun gen_add_axioms prep_axm raw_axms thy = thy |> map_axioms (fn axioms =>
   179   let
   180     val axms = map (apsnd Logic.varify o prep_axm thy) raw_axms;
   181     val axioms' = fold (#2 oo Name_Space.define true (Sign.naming_of thy)) axms axioms;
   182   in axioms' end);
   183 
   184 in
   185 
   186 val add_axioms_i = gen_add_axioms cert_axm;
   187 val add_axioms = gen_add_axioms read_axm;
   188 
   189 end;
   190 
   191 
   192 
   193 (** add constant definitions **)
   194 
   195 (* dependencies *)
   196 
   197 fun dependencies thy unchecked def description lhs rhs =
   198   let
   199     val pp = Syntax.pp_global thy;
   200     val consts = Sign.consts_of thy;
   201     fun prep const =
   202       let val Const (c, T) = Sign.no_vars pp (Const const)
   203       in (c, Consts.typargs consts (c, Logic.varifyT T)) end;
   204 
   205     val lhs_vars = Term.add_tfreesT (#2 lhs) [];
   206     val rhs_extras = fold (#2 #> Term.fold_atyps (fn TFree v =>
   207       if member (op =) lhs_vars v then I else insert (op =) v | _ => I)) rhs [];
   208     val _ =
   209       if null rhs_extras then ()
   210       else error ("Specification depends on extra type variables: " ^
   211         commas_quote (map (Pretty.string_of_typ pp o TFree) rhs_extras) ^
   212         "\nThe error(s) above occurred in " ^ quote description);
   213   in Defs.define pp unchecked def description (prep lhs) (map prep rhs) end;
   214 
   215 fun add_deps a raw_lhs raw_rhs thy =
   216   let
   217     val lhs :: rhs = map (dest_Const o Sign.cert_term thy o Const) (raw_lhs :: raw_rhs);
   218     val description = if a = "" then #1 lhs ^ " axiom" else a;
   219   in thy |> map_defs (dependencies thy false NONE description lhs rhs) end;
   220 
   221 fun specify_const decl thy =
   222   let val (t as Const const, thy') = Sign.declare_const decl thy
   223   in (t, add_deps "" const [] thy') end;
   224 
   225 
   226 (* check_overloading *)
   227 
   228 fun check_overloading thy overloaded (c, T) =
   229   let
   230     val declT = Sign.the_const_constraint thy c
   231       handle TYPE (msg, _, _) => error msg;
   232     val T' = Logic.varifyT T;
   233 
   234     fun message txt =
   235       [Pretty.block [Pretty.str "Specification of constant ",
   236         Pretty.str c, Pretty.str " ::", Pretty.brk 1, Pretty.quote (Syntax.pretty_typ_global thy T)],
   237         Pretty.str txt] |> Pretty.chunks |> Pretty.string_of;
   238   in
   239     if Sign.typ_instance thy (declT, T') then ()
   240     else if Type.raw_instance (declT, T') then
   241       error (setmp_CRITICAL show_sorts true
   242         message "imposes additional sort constraints on the constant declaration")
   243     else if overloaded then ()
   244     else warning (message "is strictly less general than the declared type");
   245     (c, T)
   246   end;
   247 
   248 
   249 (* check_def *)
   250 
   251 fun check_def thy unchecked overloaded (b, tm) defs =
   252   let
   253     val ctxt = ProofContext.init thy;
   254     val name = Sign.full_name thy b;
   255     val (lhs_const, rhs) = Sign.cert_def ctxt tm;
   256     val rhs_consts = fold_aterms (fn Const const => insert (op =) const | _ => I) rhs [];
   257     val _ = check_overloading thy overloaded lhs_const;
   258   in defs |> dependencies thy unchecked (SOME name) name lhs_const rhs_consts end
   259   handle ERROR msg => cat_error msg (Pretty.string_of (Pretty.block
   260    [Pretty.str ("The error(s) above occurred in definition " ^ quote (Binding.str_of b) ^ ":"),
   261     Pretty.fbrk, Pretty.quote (Syntax.pretty_term_global thy tm)]));
   262 
   263 
   264 (* add_defs(_i) *)
   265 
   266 local
   267 
   268 fun gen_add_defs prep_axm unchecked overloaded raw_axms thy =
   269   let val axms = map (prep_axm thy) raw_axms in
   270     thy
   271     |> map_defs (fold (check_def thy unchecked overloaded) axms)
   272     |> add_axioms_i axms
   273   end;
   274 
   275 in
   276 
   277 val add_defs_i = gen_add_defs cert_axm;
   278 val add_defs = gen_add_defs read_axm;
   279 
   280 end;
   281 
   282 
   283 (* add_finals(_i) *)
   284 
   285 local
   286 
   287 fun gen_add_finals prep_term overloaded args thy =
   288   let
   289     fun const_of (Const const) = const
   290       | const_of (Free _) = error "Attempt to finalize variable (or undeclared constant)"
   291       | const_of _ = error "Attempt to finalize non-constant term";
   292     fun specify (c, T) = dependencies thy false NONE (c ^ " axiom") (c, T) [];
   293     val finalize = specify o check_overloading thy overloaded o const_of o
   294       Sign.cert_term thy o prep_term thy;
   295   in thy |> map_defs (fold finalize args) end;
   296 
   297 in
   298 
   299 val add_finals_i = gen_add_finals (K I);
   300 val add_finals = gen_add_finals Syntax.read_term_global;
   301 
   302 end;
   303 
   304 end;