src/Pure/PIDE/resources.ML
author wenzelm
Mon Apr 10 16:43:12 2017 +0200 (2017-04-10 ago)
changeset 65457 2bf0d2fcd506
parent 65454 2b22b7d8649f
child 65471 05e5bffcf1d8
permissions -rw-r--r--
proper import qualifier for global theories;
clarified uniqueness;
     1 (*  Title:      Pure/PIDE/resources.ML
     2     Author:     Makarius
     3 
     4 Resources for theories and auxiliary files.
     5 *)
     6 
     7 signature RESOURCES =
     8 sig
     9   val set_session_base:
    10     {default_qualifier: string,
    11      global_theories: (string * string) list,
    12      loaded_theories: (string * string) list,
    13      known_theories: (string * string) list} -> unit
    14   val reset_session_base: unit -> unit
    15   val default_qualifier: unit -> string
    16   val global_theory: string -> string option
    17   val loaded_theory: string -> Path.T option
    18   val known_theory: string -> Path.T option
    19   val master_directory: theory -> Path.T
    20   val imports_of: theory -> (string * Position.T) list
    21   val thy_path: Path.T -> Path.T
    22   val theory_qualifier: string -> string
    23   val import_name: string -> Path.T -> string ->
    24     {node_name: Path.T, master_dir: Path.T, theory_name: string}
    25   val check_thy: Path.T -> string ->
    26    {master: Path.T * SHA1.digest, text: string, theory_pos: Position.T,
    27     imports: (string * Position.T) list, keywords: Thy_Header.keywords}
    28   val parse_files: string -> (theory -> Token.file list) parser
    29   val provide: Path.T * SHA1.digest -> theory -> theory
    30   val provide_parse_files: string -> (theory -> Token.file list * theory) parser
    31   val loaded_files_current: theory -> bool
    32   val begin_theory: Path.T -> Thy_Header.header -> theory list -> theory
    33   val load_thy: bool -> HTML.symbols -> (Toplevel.transition -> Time.time) -> int ->
    34     Path.T -> Thy_Header.header -> Position.T -> string -> theory list ->
    35     theory * (unit -> unit) * int
    36 end;
    37 
    38 structure Resources: RESOURCES =
    39 struct
    40 
    41 (* session base *)
    42 
    43 val init_session_base =
    44   {default_qualifier = "Draft",
    45    global_theories = Symtab.empty: string Symtab.table,
    46    loaded_theories = Symtab.empty: Path.T Symtab.table,
    47    known_theories = Symtab.empty: Path.T Symtab.table};
    48 
    49 val global_session_base =
    50   Synchronized.var "Sessions.base" init_session_base;
    51 
    52 fun set_session_base {default_qualifier, global_theories, loaded_theories, known_theories} =
    53   Synchronized.change global_session_base
    54     (fn _ =>
    55       {default_qualifier =
    56         if default_qualifier <> "" then default_qualifier
    57         else #default_qualifier init_session_base,
    58        global_theories = Symtab.make global_theories,
    59        loaded_theories = Symtab.make (map (apsnd Path.explode) loaded_theories),
    60        known_theories = Symtab.make (map (apsnd Path.explode) known_theories)});
    61 
    62 fun reset_session_base () =
    63   Synchronized.change global_session_base (K init_session_base);
    64 
    65 fun get_session_base f = f (Synchronized.value global_session_base);
    66 
    67 fun default_qualifier () = get_session_base #default_qualifier;
    68 fun global_theory a = Symtab.lookup (get_session_base #global_theories) a;
    69 fun loaded_theory a = Symtab.lookup (get_session_base #loaded_theories) a;
    70 fun known_theory a = Symtab.lookup (get_session_base #known_theories) a;
    71 
    72 
    73 (* manage source files *)
    74 
    75 type files =
    76  {master_dir: Path.T,  (*master directory of theory source*)
    77   imports: (string * Position.T) list,  (*source specification of imports*)
    78   provided: (Path.T * SHA1.digest) list};  (*source path, digest*)
    79 
    80 fun make_files (master_dir, imports, provided): files =
    81  {master_dir = master_dir, imports = imports, provided = provided};
    82 
    83 structure Files = Theory_Data
    84 (
    85   type T = files;
    86   val empty = make_files (Path.current, [], []);
    87   fun extend _ = empty;
    88   fun merge _ = empty;
    89 );
    90 
    91 fun map_files f =
    92   Files.map (fn {master_dir, imports, provided} =>
    93     make_files (f (master_dir, imports, provided)));
    94 
    95 
    96 val master_directory = #master_dir o Files.get;
    97 val imports_of = #imports o Files.get;
    98 
    99 fun put_deps master_dir imports = map_files (fn _ => (master_dir, imports, []));
   100 
   101 
   102 (* theory files *)
   103 
   104 val thy_path = Path.ext "thy";
   105 
   106 fun theory_qualifier theory =
   107   (case global_theory theory of
   108     SOME qualifier => qualifier
   109   | NONE => Long_Name.qualifier theory);
   110 
   111 fun import_name qualifier dir s =
   112   let
   113     val theory0 = Thy_Header.import_name s;
   114     val theory =
   115       if Long_Name.is_qualified theory0 orelse is_some (global_theory theory0)
   116         orelse true (* FIXME *) then theory0
   117       else Long_Name.qualify qualifier theory0;
   118     val node_name =
   119       the (get_first (fn e => e ())
   120         [fn () => loaded_theory theory,
   121          fn () => loaded_theory theory0,
   122          fn () => known_theory theory,
   123          fn () => known_theory theory0,
   124          fn () => SOME (File.full_path dir (thy_path (Path.expand (Path.explode s))))])
   125   in {node_name = node_name, master_dir = Path.dir node_name, theory_name = theory} end;
   126 
   127 fun check_file dir file = File.check_file (File.full_path dir file);
   128 
   129 fun check_thy dir thy_name =
   130   let
   131     val thy_base_name = Long_Name.base_name thy_name;
   132     val master_file =
   133       (case known_theory thy_name of
   134         SOME known_path => check_file Path.current known_path
   135       | NONE => check_file dir (thy_path (Path.basic thy_base_name)));
   136     val text = File.read master_file;
   137 
   138     val {name = (name, pos), imports, keywords} =
   139       Thy_Header.read (Path.position master_file) text;
   140     val _ =
   141       thy_base_name <> name andalso
   142         error ("Bad theory name " ^ quote name ^
   143           " for file " ^ Path.print (Path.base master_file) ^ Position.here pos);
   144   in
   145    {master = (master_file, SHA1.digest text), text = text, theory_pos = pos,
   146     imports = imports, keywords = keywords}
   147   end;
   148 
   149 
   150 (* load files *)
   151 
   152 fun parse_files cmd =
   153   Scan.ahead Parse.not_eof -- Parse.path >> (fn (tok, name) => fn thy =>
   154     (case Token.get_files tok of
   155       [] =>
   156         let
   157           val keywords = Thy_Header.get_keywords thy;
   158           val master_dir = master_directory thy;
   159           val pos = Token.pos_of tok;
   160           val src_paths = Keyword.command_files keywords cmd (Path.explode name);
   161         in map (Command.read_file master_dir pos) src_paths end
   162     | files => map Exn.release files));
   163 
   164 fun provide (src_path, id) =
   165   map_files (fn (master_dir, imports, provided) =>
   166     if AList.defined (op =) provided src_path then
   167       error ("Duplicate use of source file: " ^ Path.print src_path)
   168     else (master_dir, imports, (src_path, id) :: provided));
   169 
   170 fun provide_parse_files cmd =
   171   parse_files cmd >> (fn files => fn thy =>
   172     let
   173       val fs = files thy;
   174       val thy' = fold (fn {src_path, digest, ...} => provide (src_path, digest)) fs thy;
   175     in (fs, thy') end);
   176 
   177 fun load_file thy src_path =
   178   let
   179     val full_path = check_file (master_directory thy) src_path;
   180     val text = File.read full_path;
   181     val id = SHA1.digest text;
   182   in ((full_path, id), text) end;
   183 
   184 fun loaded_files_current thy =
   185   #provided (Files.get thy) |>
   186     forall (fn (src_path, id) =>
   187       (case try (load_file thy) src_path of
   188         NONE => false
   189       | SOME ((_, id'), _) => id = id'));
   190 
   191 
   192 (* load theory *)
   193 
   194 fun begin_theory master_dir {name, imports, keywords} parents =
   195   Theory.begin_theory name parents
   196   |> put_deps master_dir imports
   197   |> Thy_Header.add_keywords keywords;
   198 
   199 fun excursion keywords master_dir last_timing init elements =
   200   let
   201     fun prepare_span st span =
   202       Command_Span.content span
   203       |> Command.read keywords (Command.read_thy st) master_dir init ([], ~1)
   204       |> (fn tr => Toplevel.put_timing (last_timing tr) tr);
   205 
   206     fun element_result span_elem (st, _) =
   207       let
   208         val elem = Thy_Syntax.map_element (prepare_span st) span_elem;
   209         val (results, st') = Toplevel.element_result keywords elem st;
   210         val pos' = Toplevel.pos_of (Thy_Syntax.last_element elem);
   211       in (results, (st', pos')) end;
   212 
   213     val (results, (end_state, end_pos)) =
   214       fold_map element_result elements (Toplevel.toplevel, Position.none);
   215 
   216     val thy = Toplevel.end_theory end_pos end_state;
   217   in (results, thy) end;
   218 
   219 fun load_thy document symbols last_timing update_time master_dir header text_pos text parents =
   220   let
   221     val (name, _) = #name header;
   222     val keywords =
   223       fold (curry Keyword.merge_keywords o Thy_Header.get_keywords) parents
   224         (Keyword.add_keywords (#keywords header) Keyword.empty_keywords);
   225 
   226     val toks = Token.explode keywords text_pos text;
   227     val spans = Outer_Syntax.parse_spans toks;
   228     val elements = Thy_Syntax.parse_elements keywords spans;
   229 
   230     fun init () =
   231       begin_theory master_dir header parents
   232       |> Present.begin_theory update_time
   233         (fn () => implode (map (HTML.present_span symbols keywords) spans));
   234 
   235     val (results, thy) =
   236       cond_timeit true ("theory " ^ quote name)
   237         (fn () => excursion keywords master_dir last_timing init elements);
   238 
   239     fun present () =
   240       let
   241         val res = filter_out (Toplevel.is_ignored o #1) (maps Toplevel.join_results results);
   242       in
   243         if exists (Toplevel.is_skipped_proof o #2) res then
   244           warning ("Cannot present theory with skipped proofs: " ^ quote name)
   245         else
   246           let val tex_source = Thy_Output.present_thy thy res toks |> Buffer.content;
   247           in if document then Present.theory_output name tex_source else () end
   248       end;
   249 
   250   in (thy, present, size text) end;
   251 
   252 
   253 (* antiquotations *)
   254 
   255 local
   256 
   257 fun err msg pos = error (msg ^ Position.here pos);
   258 
   259 fun check_path check_file ctxt dir (name, pos) =
   260   let
   261     val _ = Context_Position.report ctxt pos Markup.language_path;
   262 
   263     val path = Path.append dir (Path.explode name) handle ERROR msg => err msg pos;
   264     val _ = Path.expand path handle ERROR msg => err msg pos;
   265     val _ = Context_Position.report ctxt pos (Markup.path (Path.smart_implode path));
   266     val _ =
   267       (case check_file of
   268         NONE => path
   269       | SOME check => (check path handle ERROR msg => err msg pos));
   270   in path end;
   271 
   272 fun document_antiq check_file ctxt (name, pos) =
   273   let
   274     val dir = master_directory (Proof_Context.theory_of ctxt);
   275     val _ = check_path check_file ctxt dir (name, pos);
   276   in
   277     space_explode "/" name
   278     |> map Latex.output_ascii
   279     |> space_implode (Latex.output_ascii "/" ^ "\\discretionary{}{}{}")
   280     |> enclose "\\isatt{" "}"
   281   end;
   282 
   283 fun ML_antiq check_file ctxt (name, pos) =
   284   let val path = check_path check_file ctxt Path.current (name, pos);
   285   in "Path.explode " ^ ML_Syntax.print_string (Path.implode path) end;
   286 
   287 in
   288 
   289 val _ = Theory.setup
   290  (Thy_Output.antiquotation @{binding path} (Scan.lift (Parse.position Parse.path))
   291     (document_antiq NONE o #context) #>
   292   Thy_Output.antiquotation @{binding file} (Scan.lift (Parse.position Parse.path))
   293     (document_antiq (SOME File.check_file) o #context) #>
   294   Thy_Output.antiquotation @{binding dir} (Scan.lift (Parse.position Parse.path))
   295     (document_antiq (SOME File.check_dir) o #context) #>
   296   ML_Antiquotation.value @{binding path}
   297     (Args.context -- Scan.lift (Parse.position Parse.path)
   298       >> uncurry (ML_antiq NONE)) #>
   299   ML_Antiquotation.value @{binding file}
   300     (Args.context -- Scan.lift (Parse.position Parse.path)
   301       >> uncurry (ML_antiq (SOME File.check_file))) #>
   302   ML_Antiquotation.value @{binding dir}
   303     (Args.context -- Scan.lift (Parse.position Parse.path)
   304       >> uncurry (ML_antiq (SOME File.check_dir))));
   305 
   306 end;
   307 
   308 end;