(*  Title:      HOL/Multivariate_Analysis/Convex_Euclidean_Space.thy

     Author:     Robert Himmelmann, TU Muenchen

     Author:     Bogdan Grechuk, University of Edinburgh

 *)

 header {* Convex sets, functions and related things. *}

 theory Convex_Euclidean_Space

 imports

   Topology_Euclidean_Space

   "~~/src/HOL/Library/Convex"

   "~~/src/HOL/Library/Set_Algebras"

 begin

 (* ------------------------------------------------------------------------- *)

 (* To be moved elsewhere                                                     *)

 (* ------------------------------------------------------------------------- *)

 lemma linear_scaleR: "linear (\<lambda>x. scaleR c x)"

   by (simp add: linear_def scaleR_add_right)

 lemma injective_scaleR: "c \<noteq> 0 \<Longrightarrow> inj (\<lambda>(x::'a::real_vector). scaleR c x)"

   by (simp add: inj_on_def)

 lemma linear_add_cmul:

 assumes "linear f"

 shows "f(a *\<^sub>R x + b *\<^sub>R y) = a *\<^sub>R f x +  b *\<^sub>R f y"

 using linear_add[of f] linear_cmul[of f] assms by (simp) 

 lemma mem_convex_2:

   assumes "convex S" "x : S" "y : S" "u>=0" "v>=0" "u+v=1"

   shows "(u *\<^sub>R x + v *\<^sub>R y) : S"

   using assms convex_def[of S] by auto

 lemma mem_convex_alt:

   assumes "convex S" "x : S" "y : S" "u>=0" "v>=0" "u+v>0"

   shows "((u/(u+v)) *\<^sub>R x + (v/(u+v)) *\<^sub>R y) : S"

 apply (subst mem_convex_2) 

 using assms apply (auto simp add: algebra_simps zero_le_divide_iff)

 using add_divide_distrib[of u v "u+v"] by auto

 lemma inj_on_image_mem_iff: "inj_on f B ==> (A <= B) ==> (f a : f`A) ==> (a : B) ==> (a : A)" 

 by (blast dest: inj_onD)

 lemma independent_injective_on_span_image:

   assumes iS: "independent S" 

      and lf: "linear f" and fi: "inj_on f (span S)"

   shows "independent (f ` S)"

 proof-

   {fix a assume a: "a : S" "f a : span (f ` S - {f a})"

     have eq: "f ` S - {f a} = f ` (S - {a})" using fi a span_inc

       by (auto simp add: inj_on_def)

     from a have "f a : f ` span (S -{a})"

       unfolding eq span_linear_image[OF lf, of "S - {a}"]  by blast

     moreover have "span (S -{a}) <= span S" using span_mono[of "S-{a}" S] by auto

     ultimately have "a : span (S -{a})" using fi a span_inc by (auto simp add: inj_on_def)

     with a(1) iS  have False by (simp add: dependent_def) }

   then show ?thesis unfolding dependent_def by blast

 qed

 lemma dim_image_eq:

 fixes f :: "'n::euclidean_space => 'm::euclidean_space"

 assumes lf: "linear f" and fi: "inj_on f (span S)" 

 shows "dim (f ` S) = dim (S:: ('n::euclidean_space) set)"

 proof-

 obtain B where B_def: "B<=S & independent B & S <= span B & card B = dim S" 

   using basis_exists[of S] by auto

 hence "span S = span B" using span_mono[of B S] span_mono[of S "span B"] span_span[of B] by auto

 hence "independent (f ` B)" using independent_injective_on_span_image[of B f] B_def assms by auto

 moreover have "card (f ` B) = card B" using assms card_image[of f B] subset_inj_on[of f "span S" B] 

    B_def span_inc by auto

 moreover have "(f ` B) <= (f ` S)" using B_def by auto

 ultimately have "dim (f ` S) >= dim S" 

   using independent_card_le_dim[of "f ` B" "f ` S"] B_def by auto

 from this show ?thesis using dim_image_le[of f S] assms by auto

 qed

 lemma linear_injective_on_subspace_0:

 assumes lf: "linear f" and "subspace S"

   shows "inj_on f S <-> (!x : S. f x = 0 --> x = 0)"

 proof-

   have "inj_on f S <-> (!x : S. !y : S. f x = f y --> x = y)" by (simp add: inj_on_def)

   also have "... <-> (!x : S. !y : S. f x - f y = 0 --> x - y = 0)" by simp

   also have "... <-> (!x : S. !y : S. f (x - y) = 0 --> x - y = 0)"

     by (simp add: linear_sub[OF lf])

   also have "... <-> (! x : S. f x = 0 --> x = 0)" 

     using `subspace S` subspace_def[of S] subspace_sub[of S] by auto

   finally show ?thesis .

 qed

 lemma subspace_Inter: "(!s : f. subspace s) ==> subspace (Inter f)"

   unfolding subspace_def by auto 

 lemma span_eq[simp]: "(span s = s) <-> subspace s"

   unfolding span_def by (rule hull_eq, rule subspace_Inter)

 lemma basis_inj_on: "d \<subseteq> {..<DIM('n)} \<Longrightarrow> inj_on (basis :: nat => 'n::euclidean_space) d"

   by(auto simp add: inj_on_def euclidean_eq[where 'a='n])

 lemma finite_substdbasis: "finite {basis i ::'n::euclidean_space |i. i : (d:: nat set)}" (is "finite ?S")

 proof-

   have eq: "?S = basis ` d" by blast

   show ?thesis unfolding eq apply(rule finite_subset[OF _ range_basis_finite]) by auto

 qed

 lemma card_substdbasis: assumes "d \<subseteq> {..<DIM('n::euclidean_space)}"

   shows "card {basis i ::'n::euclidean_space | i. i : d} = card d" (is "card ?S = _")

 proof-

   have eq: "?S = basis ` d" by blast

   show ?thesis unfolding eq using card_image[OF basis_inj_on[of d]] assms by auto

 qed

 lemma substdbasis_expansion_unique: assumes "d\<subseteq>{..<DIM('a::euclidean_space)}"

   shows "setsum (%i. f i *\<^sub>R basis i) d = (x::'a::euclidean_space)

       <-> (!i<DIM('a). (i:d --> f i = x$$i) & (i ~: d --> x $$ i = 0))"

 proof- have *:"\<And>x a b P. x * (if P then a else b) = (if P then x*a else x*b)" by auto

   have **:"finite d" apply(rule finite_subset[OF assms]) by fastforce

   have ***:"\<And>i. (setsum (%i. f i *\<^sub>R ((basis i)::'a)) d) $$ i = (\<Sum>x\<in>d. if x = i then f x else 0)"

     unfolding euclidean_component_setsum euclidean_component_scaleR basis_component *

     apply(rule setsum_cong2) using assms by auto

   show ?thesis unfolding euclidean_eq[where 'a='a] *** setsum_delta[OF **] using assms by auto

 qed

 lemma independent_substdbasis: assumes "d\<subseteq>{..<DIM('a::euclidean_space)}"

   shows "independent {basis i ::'a::euclidean_space |i. i : (d :: nat set)}" (is "independent ?A")

 proof -

   have *: "{basis i |i. i < DIM('a)} = basis ` {..<DIM('a)}" by auto

   show ?thesis

     apply(intro independent_mono[of "{basis i ::'a |i. i : {..<DIM('a::euclidean_space)}}" "?A"] )

     using independent_basis[where 'a='a] assms by (auto simp: *)

 qed

 lemma dim_cball: 

 assumes "0<e"

 shows "dim (cball (0 :: 'n::euclidean_space) e) = DIM('n)"

 proof-

 { fix x :: "'n::euclidean_space" def y == "(e/norm x) *\<^sub>R x"

   hence "y : cball 0 e" using cball_def dist_norm[of 0 y] assms by auto

   moreover have "x = (norm x/e) *\<^sub>R y" using y_def assms by simp

   moreover hence "x = (norm x/e) *\<^sub>R y"  by auto

   ultimately have "x : span (cball 0 e)"

      using span_mul[of y "cball 0 e" "norm x/e"] span_inc[of "cball 0 e"] by auto

 } hence "span (cball 0 e) = (UNIV :: ('n::euclidean_space) set)" by auto 

 from this show ?thesis using dim_span[of "cball (0 :: 'n::euclidean_space) e"] by (auto simp add: dim_UNIV)

 qed

 lemma indep_card_eq_dim_span:

 fixes B :: "('n::euclidean_space) set"

 assumes "independent B"

 shows "finite B & card B = dim (span B)" 

   using assms basis_card_eq_dim[of B "span B"] span_inc by auto

 lemma setsum_not_0: "setsum f A ~= 0 ==> EX a:A. f a ~= 0"

   apply(rule ccontr) by auto

 lemma translate_inj_on: 

 fixes A :: "('a::ab_group_add) set"

 shows "inj_on (%x. a+x) A" unfolding inj_on_def by auto

 lemma translation_assoc:

   fixes a b :: "'a::ab_group_add"

   shows "(\<lambda>x. b+x) ` ((\<lambda>x. a+x) ` S) = (\<lambda>x. (a+b)+x) ` S" by auto

 lemma translation_invert:

   fixes a :: "'a::ab_group_add"

   assumes "(\<lambda>x. a+x) ` A = (\<lambda>x. a+x) ` B"

   shows "A=B"

 proof-

   have "(%x. -a+x) ` ((%x. a+x) ` A) = (%x. -a+x) ` ((%x. a+x) ` B)" using assms by auto

   from this show ?thesis using translation_assoc[of "-a" a A] translation_assoc[of "-a" a B] by auto 

 qed

 lemma translation_galois:

   fixes a :: "'a::ab_group_add"

   shows "T=((\<lambda>x. a+x) ` S) <-> S=((\<lambda>x. (-a)+x) ` T)"

   using translation_assoc[of "-a" a S] apply auto

   using translation_assoc[of a "-a" T] by auto

 lemma translation_inverse_subset:

   assumes "((%x. -a+x) ` V) <= (S :: 'n::ab_group_add set)" 

   shows "V <= ((%x. a+x) ` S)"

 proof-

 { fix x assume "x:V" hence "x-a : S" using assms by auto 

   hence "x : {a + v |v. v : S}" apply auto apply (rule exI[of _ "x-a"]) apply simp done 

   hence "x : ((%x. a+x) ` S)" by auto }

   from this show ?thesis by auto

 qed

 lemma basis_to_basis_subspace_isomorphism:

   assumes s: "subspace (S:: ('n::euclidean_space) set)"

   and t: "subspace (T :: ('m::euclidean_space) set)"

   and d: "dim S = dim T"

   and B: "B <= S" "independent B" "S <= span B" "card B = dim S"

   and C: "C <= T" "independent C" "T <= span C" "card C = dim T"

   shows "EX f. linear f & f ` B = C & f ` S = T & inj_on f S"

 proof-

 (* Proof is a modified copy of the proof of similar lemma subspace_isomorphism

 *)

   from B independent_bound have fB: "finite B" by blast

   from C independent_bound have fC: "finite C" by blast

   from B(4) C(4) card_le_inj[of B C] d obtain f where

     f: "f ` B \<subseteq> C" "inj_on f B" using `finite B` `finite C` by auto

   from linear_independent_extend[OF B(2)] obtain g where

     g: "linear g" "\<forall>x\<in> B. g x = f x" by blast

   from inj_on_iff_eq_card[OF fB, of f] f(2)

   have "card (f ` B) = card B" by simp

   with B(4) C(4) have ceq: "card (f ` B) = card C" using d

     by simp

   have "g ` B = f ` B" using g(2)

     by (auto simp add: image_iff)

   also have "\<dots> = C" using card_subset_eq[OF fC f(1) ceq] .

   finally have gBC: "g ` B = C" .

   have gi: "inj_on g B" using f(2) g(2)

     by (auto simp add: inj_on_def)

   note g0 = linear_indep_image_lemma[OF g(1) fB, unfolded gBC, OF C(2) gi]

   {fix x y assume x: "x \<in> S" and y: "y \<in> S" and gxy:"g x = g y"

     from B(3) x y have x': "x \<in> span B" and y': "y \<in> span B" by blast+

     from gxy have th0: "g (x - y) = 0" by (simp add: linear_sub[OF g(1)])

     have th1: "x - y \<in> span B" using x' y' by (metis span_sub)

     have "x=y" using g0[OF th1 th0] by simp }

   then have giS: "inj_on g S"

     unfolding inj_on_def by blast

   from span_subspace[OF B(1,3) s]

   have "g ` S = span (g ` B)" by (simp add: span_linear_image[OF g(1)])

   also have "\<dots> = span C" unfolding gBC ..

   also have "\<dots> = T" using span_subspace[OF C(1,3) t] .

   finally have gS: "g ` S = T" .

   from g(1) gS giS gBC show ?thesis by blast

 qed

 lemma closure_bounded_linear_image:

   assumes f: "bounded_linear f"

   shows "f ` (closure S) \<subseteq> closure (f ` S)"

   using linear_continuous_on [OF f] closed_closure closure_subset

   by (rule image_closure_subset)

 lemma closure_linear_image:

 fixes f :: "('m::euclidean_space) => ('n::real_normed_vector)"

 assumes "linear f"

 shows "f ` (closure S) <= closure (f ` S)"

   using assms unfolding linear_conv_bounded_linear

   by (rule closure_bounded_linear_image)

 lemma closure_injective_linear_image:

 fixes f :: "('n::euclidean_space) => ('n::euclidean_space)"

 assumes "linear f" "inj f"

 shows "f ` (closure S) = closure (f ` S)"

 proof-

 obtain f' where f'_def: "linear f' & f o f' = id & f' o f = id" 

    using assms linear_injective_isomorphism[of f] isomorphism_expand by auto

 hence "f' ` closure (f ` S) <= closure (S)"

    using closure_linear_image[of f' "f ` S"] image_compose[of f' f] by auto

 hence "f ` f' ` closure (f ` S) <= f ` closure (S)" by auto

 hence "closure (f ` S) <= f ` closure (S)" using image_compose[of f f' "closure (f ` S)"] f'_def by auto

 from this show ?thesis using closure_linear_image[of f S] assms by auto 

 qed

 lemma closure_direct_sum:

 shows "closure (S <*> T) = closure S <*> closure T"

   by (rule closure_Times)

 lemma closure_scaleR:

   fixes S :: "('a::real_normed_vector) set"

   shows "(op *\<^sub>R c) ` (closure S) = closure ((op *\<^sub>R c) ` S)"

 proof

   show "(op *\<^sub>R c) ` (closure S) \<subseteq> closure ((op *\<^sub>R c) ` S)"

     using bounded_linear_scaleR_right

     by (rule closure_bounded_linear_image)

   show "closure ((op *\<^sub>R c) ` S) \<subseteq> (op *\<^sub>R c) ` (closure S)"

     by (intro closure_minimal image_mono closure_subset

       closed_scaling closed_closure)

 qed

 lemma fst_linear: "linear fst" unfolding linear_def by (simp add: algebra_simps)

 lemma snd_linear: "linear snd" unfolding linear_def by (simp add: algebra_simps)

 lemma fst_snd_linear: "linear (%(x,y). x + y)" unfolding linear_def by (simp add: algebra_simps)

 lemma scaleR_2:

   fixes x :: "'a::real_vector"

   shows "scaleR 2 x = x + x"

 unfolding one_add_one_is_two [symmetric] scaleR_left_distrib by simp

 lemma vector_choose_size: "0 <= c ==> \<exists>(x::'a::euclidean_space). norm x = c"

   apply (rule exI[where x="c *\<^sub>R basis 0 ::'a"]) using DIM_positive[where 'a='a] by auto

 lemma setsum_delta_notmem: assumes "x\<notin>s"

   shows "setsum (\<lambda>y. if (y = x) then P x else Q y) s = setsum Q s"

         "setsum (\<lambda>y. if (x = y) then P x else Q y) s = setsum Q s"

         "setsum (\<lambda>y. if (y = x) then P y else Q y) s = setsum Q s"

         "setsum (\<lambda>y. if (x = y) then P y else Q y) s = setsum Q s"

   apply(rule_tac [!] setsum_cong2) using assms by auto

 lemma setsum_delta'':

   fixes s::"'a::real_vector set" assumes "finite s"

   shows "(\<Sum>x\<in>s. (if y = x then f x else 0) *\<^sub>R x) = (if y\<in>s then (f y) *\<^sub>R y else 0)"

 proof-

   have *:"\<And>x y. (if y = x then f x else (0::real)) *\<^sub>R x = (if x=y then (f x) *\<^sub>R x else 0)" by auto

   show ?thesis unfolding * using setsum_delta[OF assms, of y "\<lambda>x. f x *\<^sub>R x"] by auto

 qed

 lemma if_smult:"(if P then x else (y::real)) *\<^sub>R v = (if P then x *\<^sub>R v else y *\<^sub>R v)" by auto

 lemma image_smult_interval:"(\<lambda>x. m *\<^sub>R (x::'a::ordered_euclidean_space)) ` {a..b} =

   (if {a..b} = {} then {} else if 0 \<le> m then {m *\<^sub>R a..m *\<^sub>R b} else {m *\<^sub>R b..m *\<^sub>R a})"

   using image_affinity_interval[of m 0 a b] by auto

 lemma dist_triangle_eq:

   fixes x y z :: "'a::real_inner"

   shows "dist x z = dist x y + dist y z \<longleftrightarrow> norm (x - y) *\<^sub>R (y - z) = norm (y - z) *\<^sub>R (x - y)"

 proof- have *:"x - y + (y - z) = x - z" by auto

   show ?thesis unfolding dist_norm norm_triangle_eq[of "x - y" "y - z", unfolded *]

     by(auto simp add:norm_minus_commute) qed

 lemma norm_minus_eqI:"x = - y \<Longrightarrow> norm x = norm y" by auto

 lemma Min_grI: assumes "finite A" "A \<noteq> {}" "\<forall>a\<in>A. x < a" shows "x < Min A"

   unfolding Min_gr_iff[OF assms(1,2)] using assms(3) by auto

 lemma norm_lt: "norm x < norm y \<longleftrightarrow> inner x x < inner y y"

   unfolding norm_eq_sqrt_inner by simp

 lemma norm_le: "norm x \<le> norm y \<longleftrightarrow> inner x x \<le> inner y y"

   unfolding norm_eq_sqrt_inner by simp

 subsection {* Affine set and affine hull *}

 definition

   affine :: "'a::real_vector set \<Rightarrow> bool" where

   "affine s \<longleftrightarrow> (\<forall>x\<in>s. \<forall>y\<in>s. \<forall>u v. u + v = 1 \<longrightarrow> u *\<^sub>R x + v *\<^sub>R y \<in> s)"

 lemma affine_alt: "affine s \<longleftrightarrow> (\<forall>x\<in>s. \<forall>y\<in>s. \<forall>u::real. (1 - u) *\<^sub>R x + u *\<^sub>R y \<in> s)"

 unfolding affine_def by(metis eq_diff_eq')

 lemma affine_empty[intro]: "affine {}"

   unfolding affine_def by auto

 lemma affine_sing[intro]: "affine {x}"

   unfolding affine_alt by (auto simp add: scaleR_left_distrib [symmetric])

 lemma affine_UNIV[intro]: "affine UNIV"

   unfolding affine_def by auto

 lemma affine_Inter: "(\<forall>s\<in>f. affine s) \<Longrightarrow> affine (\<Inter> f)"

   unfolding affine_def by auto 

 lemma affine_Int: "affine s \<Longrightarrow> affine t \<Longrightarrow> affine (s \<inter> t)"

   unfolding affine_def by auto

 lemma affine_affine_hull: "affine(affine hull s)"

   unfolding hull_def using affine_Inter[of "{t. affine t \<and> s \<subseteq> t}"]

   by auto

 lemma affine_hull_eq[simp]: "(affine hull s = s) \<longleftrightarrow> affine s"

 by (metis affine_affine_hull hull_same)

 subsubsection {* Some explicit formulations (from Lars Schewe) *}

 lemma affine: fixes V::"'a::real_vector set"

   shows "affine V \<longleftrightarrow> (\<forall>s u. finite s \<and> s \<noteq> {} \<and> s \<subseteq> V \<and> setsum u s = 1 \<longrightarrow> (setsum (\<lambda>x. (u x) *\<^sub>R x)) s \<in> V)"

 unfolding affine_def apply rule apply(rule, rule, rule) apply(erule conjE)+ 

 defer apply(rule, rule, rule, rule, rule) proof-

   fix x y u v assume as:"x \<in> V" "y \<in> V" "u + v = (1::real)"

     "\<forall>s u. finite s \<and> s \<noteq> {} \<and> s \<subseteq> V \<and> setsum u s = 1 \<longrightarrow> (\<Sum>x\<in>s. u x *\<^sub>R x) \<in> V"

   thus "u *\<^sub>R x + v *\<^sub>R y \<in> V" apply(cases "x=y")

     using as(4)[THEN spec[where x="{x,y}"], THEN spec[where x="\<lambda>w. if w = x then u else v"]] and as(1-3) 

     by(auto simp add: scaleR_left_distrib[THEN sym])

 next

   fix s u assume as:"\<forall>x\<in>V. \<forall>y\<in>V. \<forall>u v. u + v = 1 \<longrightarrow> u *\<^sub>R x + v *\<^sub>R y \<in> V"

     "finite s" "s \<noteq> {}" "s \<subseteq> V" "setsum u s = (1::real)"

   def n \<equiv> "card s"

   have "card s = 0 \<or> card s = 1 \<or> card s = 2 \<or> card s > 2" by auto

   thus "(\<Sum>x\<in>s. u x *\<^sub>R x) \<in> V" proof(auto simp only: disjE)

     assume "card s = 2" hence "card s = Suc (Suc 0)" by auto

     then obtain a b where "s = {a, b}" unfolding card_Suc_eq by auto

     thus ?thesis using as(1)[THEN bspec[where x=a], THEN bspec[where x=b]] using as(4,5)

       by(auto simp add: setsum_clauses(2))

   next assume "card s > 2" thus ?thesis using as and n_def proof(induct n arbitrary: u s)

       case (Suc n) fix s::"'a set" and u::"'a \<Rightarrow> real"

       assume IA:"\<And>u s.  \<lbrakk>2 < card s; \<forall>x\<in>V. \<forall>y\<in>V. \<forall>u v. u + v = 1 \<longrightarrow> u *\<^sub>R x + v *\<^sub>R y \<in> V; finite s;

                s \<noteq> {}; s \<subseteq> V; setsum u s = 1; n = card s \<rbrakk> \<Longrightarrow> (\<Sum>x\<in>s. u x *\<^sub>R x) \<in> V" and

         as:"Suc n = card s" "2 < card s" "\<forall>x\<in>V. \<forall>y\<in>V. \<forall>u v. u + v = 1 \<longrightarrow> u *\<^sub>R x + v *\<^sub>R y \<in> V"

            "finite s" "s \<noteq> {}" "s \<subseteq> V" "setsum u s = 1"

       have "\<exists>x\<in>s. u x \<noteq> 1" proof(rule_tac ccontr)

         assume " \<not> (\<exists>x\<in>s. u x \<noteq> 1)" hence "setsum u s = real_of_nat (card s)" unfolding card_eq_setsum by auto

         thus False using as(7) and `card s > 2` by (metis One_nat_def

           less_Suc0 Zero_not_Suc of_nat_1 of_nat_eq_iff numeral_2_eq_2)

       qed

       then obtain x where x:"x\<in>s" "u x \<noteq> 1" by auto

       have c:"card (s - {x}) = card s - 1" apply(rule card_Diff_singleton) using `x\<in>s` as(4) by auto

       have *:"s = insert x (s - {x})" "finite (s - {x})" using `x\<in>s` and as(4) by auto

       have **:"setsum u (s - {x}) = 1 - u x"

         using setsum_clauses(2)[OF *(2), of u x, unfolded *(1)[THEN sym] as(7)] by auto

       have ***:"inverse (1 - u x) * setsum u (s - {x}) = 1" unfolding ** using `u x \<noteq> 1` by auto

       have "(\<Sum>xa\<in>s - {x}. (inverse (1 - u x) * u xa) *\<^sub>R xa) \<in> V" proof(cases "card (s - {x}) > 2")

         case True hence "s - {x} \<noteq> {}" "card (s - {x}) = n" unfolding c and as(1)[symmetric] proof(rule_tac ccontr) 

           assume "\<not> s - {x} \<noteq> {}" hence "card (s - {x}) = 0" unfolding card_0_eq[OF *(2)] by simp 

           thus False using True by auto qed auto

         thus ?thesis apply(rule_tac IA[of "s - {x}" "\<lambda>y. (inverse (1 - u x) * u y)"])

         unfolding setsum_right_distrib[THEN sym] using as and *** and True by auto

       next case False hence "card (s - {x}) = Suc (Suc 0)" using as(2) and c by auto

         then obtain a b where "(s - {x}) = {a, b}" "a\<noteq>b" unfolding card_Suc_eq by auto

         thus ?thesis using as(3)[THEN bspec[where x=a], THEN bspec[where x=b]]

           using *** *(2) and `s \<subseteq> V` unfolding setsum_right_distrib by(auto simp add: setsum_clauses(2)) qed

       hence "u x + (1 - u x) = 1 \<Longrightarrow> u x *\<^sub>R x + (1 - u x) *\<^sub>R ((\<Sum>xa\<in>s - {x}. u xa *\<^sub>R xa) /\<^sub>R (1 - u x)) \<in> V"

         apply-apply(rule as(3)[rule_format]) 

         unfolding  RealVector.scaleR_right.setsum using x(1) as(6) by auto

       thus "(\<Sum>x\<in>s. u x *\<^sub>R x) \<in> V" unfolding scaleR_scaleR[THEN sym] and scaleR_right.setsum [symmetric]

          apply(subst *) unfolding setsum_clauses(2)[OF *(2)]

          using `u x \<noteq> 1` by auto 

     qed auto

   next assume "card s = 1" then obtain a where "s={a}" by(auto simp add: card_Suc_eq)

     thus ?thesis using as(4,5) by simp

   qed(insert `s\<noteq>{}` `finite s`, auto)

 qed

 lemma affine_hull_explicit:

   "affine hull p = {y. \<exists>s u. finite s \<and> s \<noteq> {} \<and> s \<subseteq> p \<and> setsum u s = 1 \<and> setsum (\<lambda>v. (u v) *\<^sub>R v) s = y}"

   apply(rule hull_unique) apply(subst subset_eq) prefer 3 apply rule unfolding mem_Collect_eq

   apply (erule exE)+ apply(erule conjE)+ prefer 2 apply rule proof-

   fix x assume "x\<in>p" thus "\<exists>s u. finite s \<and> s \<noteq> {} \<and> s \<subseteq> p \<and> setsum u s = 1 \<and> (\<Sum>v\<in>s. u v *\<^sub>R v) = x"

     apply(rule_tac x="{x}" in exI, rule_tac x="\<lambda>x. 1" in exI) by auto

 next

   fix t x s u assume as:"p \<subseteq> t" "affine t" "finite s" "s \<noteq> {}" "s \<subseteq> p" "setsum u s = 1" "(\<Sum>v\<in>s. u v *\<^sub>R v) = x" 

   thus "x \<in> t" using as(2)[unfolded affine, THEN spec[where x=s], THEN spec[where x=u]] by auto

 next

   show "affine {y. \<exists>s u. finite s \<and> s \<noteq> {} \<and> s \<subseteq> p \<and> setsum u s = 1 \<and> (\<Sum>v\<in>s. u v *\<^sub>R v) = y}" unfolding affine_def

     apply(rule,rule,rule,rule,rule) unfolding mem_Collect_eq proof-

     fix u v ::real assume uv:"u + v = 1"

     fix x assume "\<exists>s u. finite s \<and> s \<noteq> {} \<and> s \<subseteq> p \<and> setsum u s = 1 \<and> (\<Sum>v\<in>s. u v *\<^sub>R v) = x"

     then obtain sx ux where x:"finite sx" "sx \<noteq> {}" "sx \<subseteq> p" "setsum ux sx = 1" "(\<Sum>v\<in>sx. ux v *\<^sub>R v) = x" by auto

     fix y assume "\<exists>s u. finite s \<and> s \<noteq> {} \<and> s \<subseteq> p \<and> setsum u s = 1 \<and> (\<Sum>v\<in>s. u v *\<^sub>R v) = y"

     then obtain sy uy where y:"finite sy" "sy \<noteq> {}" "sy \<subseteq> p" "setsum uy sy = 1" "(\<Sum>v\<in>sy. uy v *\<^sub>R v) = y" by auto

     have xy:"finite (sx \<union> sy)" using x(1) y(1) by auto

     have **:"(sx \<union> sy) \<inter> sx = sx" "(sx \<union> sy) \<inter> sy = sy" by auto

     show "\<exists>s ua. finite s \<and> s \<noteq> {} \<and> s \<subseteq> p \<and> setsum ua s = 1 \<and> (\<Sum>v\<in>s. ua v *\<^sub>R v) = u *\<^sub>R x + v *\<^sub>R y"

       apply(rule_tac x="sx \<union> sy" in exI)

       apply(rule_tac x="\<lambda>a. (if a\<in>sx then u * ux a else 0) + (if a\<in>sy then v * uy a else 0)" in exI)

       unfolding scaleR_left_distrib setsum_addf if_smult scaleR_zero_left  ** setsum_restrict_set[OF xy, THEN sym]

       unfolding scaleR_scaleR[THEN sym] RealVector.scaleR_right.setsum [symmetric] and setsum_right_distrib[THEN sym]

       unfolding x y using x(1-3) y(1-3) uv by simp qed qed

 lemma affine_hull_finite:

   assumes "finite s"

   shows "affine hull s = {y. \<exists>u. setsum u s = 1 \<and> setsum (\<lambda>v. u v *\<^sub>R v) s = y}"

   unfolding affine_hull_explicit and set_eq_iff and mem_Collect_eq apply (rule,rule)

   apply(erule exE)+ apply(erule conjE)+ defer apply(erule exE) apply(erule conjE) proof-

   fix x u assume "setsum u s = 1" "(\<Sum>v\<in>s. u v *\<^sub>R v) = x"

   thus "\<exists>sa u. finite sa \<and> \<not> (\<forall>x. (x \<in> sa) = (x \<in> {})) \<and> sa \<subseteq> s \<and> setsum u sa = 1 \<and> (\<Sum>v\<in>sa. u v *\<^sub>R v) = x"

     apply(rule_tac x=s in exI, rule_tac x=u in exI) using assms by auto

 next

   fix x t u assume "t \<subseteq> s" hence *:"s \<inter> t = t" by auto

   assume "finite t" "\<not> (\<forall>x. (x \<in> t) = (x \<in> {}))" "setsum u t = 1" "(\<Sum>v\<in>t. u v *\<^sub>R v) = x"

   thus "\<exists>u. setsum u s = 1 \<and> (\<Sum>v\<in>s. u v *\<^sub>R v) = x" apply(rule_tac x="\<lambda>x. if x\<in>t then u x else 0" in exI)

     unfolding if_smult scaleR_zero_left and setsum_restrict_set[OF assms, THEN sym] and * by auto qed

 subsubsection {* Stepping theorems and hence small special cases *}

 lemma affine_hull_empty[simp]: "affine hull {} = {}"

   apply(rule hull_unique) by auto

 lemma affine_hull_finite_step:

   fixes y :: "'a::real_vector"

   shows "(\<exists>u. setsum u {} = w \<and> setsum (\<lambda>x. u x *\<^sub>R x) {} = y) \<longleftrightarrow> w = 0 \<and> y = 0" (is ?th1)

   "finite s \<Longrightarrow> (\<exists>u. setsum u (insert a s) = w \<and> setsum (\<lambda>x. u x *\<^sub>R x) (insert a s) = y) \<longleftrightarrow>

                 (\<exists>v u. setsum u s = w - v \<and> setsum (\<lambda>x. u x *\<^sub>R x) s = y - v *\<^sub>R a)" (is "?as \<Longrightarrow> (?lhs = ?rhs)")

 proof-

   show ?th1 by simp

   assume ?as 

   { assume ?lhs

     then obtain u where u:"setsum u (insert a s) = w \<and> (\<Sum>x\<in>insert a s. u x *\<^sub>R x) = y" by auto

     have ?rhs proof(cases "a\<in>s")

       case True hence *:"insert a s = s" by auto

       show ?thesis using u[unfolded *] apply(rule_tac x=0 in exI) by auto

     next

       case False thus ?thesis apply(rule_tac x="u a" in exI) using u and `?as` by auto 

     qed  } moreover

   { assume ?rhs

     then obtain v u where vu:"setsum u s = w - v"  "(\<Sum>x\<in>s. u x *\<^sub>R x) = y - v *\<^sub>R a" by auto

     have *:"\<And>x M. (if x = a then v else M) *\<^sub>R x = (if x = a then v *\<^sub>R x else M *\<^sub>R x)" by auto

     have ?lhs proof(cases "a\<in>s")

       case True thus ?thesis

         apply(rule_tac x="\<lambda>x. (if x=a then v else 0) + u x" in exI)

         unfolding setsum_clauses(2)[OF `?as`]  apply simp

         unfolding scaleR_left_distrib and setsum_addf 

         unfolding vu and * and scaleR_zero_left

         by (auto simp add: setsum_delta[OF `?as`])

     next

       case False 

       hence **:"\<And>x. x \<in> s \<Longrightarrow> u x = (if x = a then v else u x)"

                "\<And>x. x \<in> s \<Longrightarrow> u x *\<^sub>R x = (if x = a then v *\<^sub>R x else u x *\<^sub>R x)" by auto

       from False show ?thesis

         apply(rule_tac x="\<lambda>x. if x=a then v else u x" in exI)

         unfolding setsum_clauses(2)[OF `?as`] and * using vu

         using setsum_cong2[of s "\<lambda>x. u x *\<^sub>R x" "\<lambda>x. if x = a then v *\<^sub>R x else u x *\<^sub>R x", OF **(2)]

         using setsum_cong2[of s u "\<lambda>x. if x = a then v else u x", OF **(1)] by auto  

     qed }

   ultimately show "?lhs = ?rhs" by blast

 qed

 lemma affine_hull_2:

   fixes a b :: "'a::real_vector"

   shows "affine hull {a,b} = {u *\<^sub>R a + v *\<^sub>R b| u v. (u + v = 1)}" (is "?lhs = ?rhs")

 proof-

   have *:"\<And>x y z. z = x - y \<longleftrightarrow> y + z = (x::real)" 

          "\<And>x y z. z = x - y \<longleftrightarrow> y + z = (x::'a)" by auto

   have "?lhs = {y. \<exists>u. setsum u {a, b} = 1 \<and> (\<Sum>v\<in>{a, b}. u v *\<^sub>R v) = y}"

     using affine_hull_finite[of "{a,b}"] by auto

   also have "\<dots> = {y. \<exists>v u. u b = 1 - v \<and> u b *\<^sub>R b = y - v *\<^sub>R a}"

     by(simp add: affine_hull_finite_step(2)[of "{b}" a]) 

   also have "\<dots> = ?rhs" unfolding * by auto

   finally show ?thesis by auto

 qed

 lemma affine_hull_3:

   fixes a b c :: "'a::real_vector"

   shows "affine hull {a,b,c} = { u *\<^sub>R a + v *\<^sub>R b + w *\<^sub>R c| u v w. u + v + w = 1}" (is "?lhs = ?rhs")

 proof-

   have *:"\<And>x y z. z = x - y \<longleftrightarrow> y + z = (x::real)" 

          "\<And>x y z. z = x - y \<longleftrightarrow> y + z = (x::'a)" by auto

   show ?thesis apply(simp add: affine_hull_finite affine_hull_finite_step)

     unfolding * apply auto

     apply(rule_tac x=v in exI) apply(rule_tac x=va in exI) apply auto

     apply(rule_tac x=u in exI) by force

 qed

 lemma mem_affine:

   assumes "affine S" "x : S" "y : S" "u+v=1"

   shows "(u *\<^sub>R x + v *\<^sub>R y) : S"

   using assms affine_def[of S] by auto

 lemma mem_affine_3:

   assumes "affine S" "x : S" "y : S" "z : S" "u+v+w=1"

   shows "(u *\<^sub>R x + v *\<^sub>R y + w *\<^sub>R z) : S"

 proof-

 have "(u *\<^sub>R x + v *\<^sub>R y + w *\<^sub>R z) : affine hull {x, y, z}"

   using affine_hull_3[of x y z] assms by auto

 moreover have " affine hull {x, y, z} <= affine hull S" 

   using hull_mono[of "{x, y, z}" "S"] assms by auto

 moreover have "affine hull S = S" 

   using assms affine_hull_eq[of S] by auto

 ultimately show ?thesis by auto 

 qed

 lemma mem_affine_3_minus:

   assumes "affine S" "x : S" "y : S" "z : S"

   shows "x + v *\<^sub>R (y-z) : S"

 using mem_affine_3[of S x y z 1 v "-v"] assms by (simp add: algebra_simps)

 subsubsection {* Some relations between affine hull and subspaces *}

 lemma affine_hull_insert_subset_span:

   shows "affine hull (insert a s) \<subseteq> {a + v| v . v \<in> span {x - a | x . x \<in> s}}"

   unfolding subset_eq Ball_def unfolding affine_hull_explicit span_explicit mem_Collect_eq

   apply(rule,rule) apply(erule exE)+ apply(erule conjE)+ proof-

   fix x t u assume as:"finite t" "t \<noteq> {}" "t \<subseteq> insert a s" "setsum u t = 1" "(\<Sum>v\<in>t. u v *\<^sub>R v) = x"

   have "(\<lambda>x. x - a) ` (t - {a}) \<subseteq> {x - a |x. x \<in> s}" using as(3) by auto

   thus "\<exists>v. x = a + v \<and> (\<exists>S u. finite S \<and> S \<subseteq> {x - a |x. x \<in> s} \<and> (\<Sum>v\<in>S. u v *\<^sub>R v) = v)"

     apply(rule_tac x="x - a" in exI)

     apply (rule conjI, simp)

     apply(rule_tac x="(\<lambda>x. x - a) ` (t - {a})" in exI)

     apply(rule_tac x="\<lambda>x. u (x + a)" in exI)

     apply (rule conjI) using as(1) apply simp

     apply (erule conjI)

     using as(1)

     apply (simp add: setsum_reindex[unfolded inj_on_def] scaleR_right_diff_distrib setsum_subtractf scaleR_left.setsum[THEN sym] setsum_diff1 scaleR_left_diff_distrib)

     unfolding as by simp qed

 lemma affine_hull_insert_span:

   assumes "a \<notin> s"

   shows "affine hull (insert a s) =

             {a + v | v . v \<in> span {x - a | x.  x \<in> s}}"

   apply(rule, rule affine_hull_insert_subset_span) unfolding subset_eq Ball_def

   unfolding affine_hull_explicit and mem_Collect_eq proof(rule,rule,erule exE,erule conjE)

   fix y v assume "y = a + v" "v \<in> span {x - a |x. x \<in> s}"

   then obtain t u where obt:"finite t" "t \<subseteq> {x - a |x. x \<in> s}" "a + (\<Sum>v\<in>t. u v *\<^sub>R v) = y" unfolding span_explicit by auto

   def f \<equiv> "(\<lambda>x. x + a) ` t"

   have f:"finite f" "f \<subseteq> s" "(\<Sum>v\<in>f. u (v - a) *\<^sub>R (v - a)) = y - a" unfolding f_def using obt 

     by(auto simp add: setsum_reindex[unfolded inj_on_def])

   have *:"f \<inter> {a} = {}" "f \<inter> - {a} = f" using f(2) assms by auto

   show "\<exists>sa u. finite sa \<and> sa \<noteq> {} \<and> sa \<subseteq> insert a s \<and> setsum u sa = 1 \<and> (\<Sum>v\<in>sa. u v *\<^sub>R v) = y"

     apply(rule_tac x="insert a f" in exI)

     apply(rule_tac x="\<lambda>x. if x=a then 1 - setsum (\<lambda>x. u (x - a)) f else u (x - a)" in exI)

     using assms and f unfolding setsum_clauses(2)[OF f(1)] and if_smult

     unfolding setsum_cases[OF f(1), of "\<lambda>x. x = a"]

     by (auto simp add: setsum_subtractf scaleR_left.setsum algebra_simps *) qed

 lemma affine_hull_span:

   assumes "a \<in> s"

   shows "affine hull s = {a + v | v. v \<in> span {x - a | x. x \<in> s - {a}}}"

   using affine_hull_insert_span[of a "s - {a}", unfolded insert_Diff[OF assms]] by auto

 subsubsection {* Parallel affine sets *}

 definition affine_parallel :: "'a::real_vector set => 'a::real_vector set => bool"

 where "affine_parallel S T = (? a. T = ((%x. a + x) ` S))"

 lemma affine_parallel_expl_aux:

    fixes S T :: "'a::real_vector set"

    assumes "!x. (x : S <-> (a+x) : T)" 

    shows "T = ((%x. a + x) ` S)"

 proof-

 { fix x assume "x : T" hence "(-a)+x : S" using assms by auto

   hence " x : ((%x. a + x) ` S)" using imageI[of "-a+x" S "(%x. a+x)"] by auto}

 moreover have "T >= ((%x. a + x) ` S)" using assms by auto 

 ultimately show ?thesis by auto

 qed

 lemma affine_parallel_expl: 

    "affine_parallel S T = (? a. !x. (x : S <-> (a+x) : T))" 

    unfolding affine_parallel_def using affine_parallel_expl_aux[of S _ T] by auto

 lemma affine_parallel_reflex: "affine_parallel S S" unfolding affine_parallel_def apply (rule exI[of _ "0"]) by auto

 lemma affine_parallel_commut:

 assumes "affine_parallel A B" shows "affine_parallel B A" 

 proof-

 from assms obtain a where "B=((%x. a + x) ` A)" unfolding affine_parallel_def by auto 

 from this show ?thesis using translation_galois[of B a A] unfolding affine_parallel_def by auto

 qed

 lemma affine_parallel_assoc:

 assumes "affine_parallel A B" "affine_parallel B C"

 shows "affine_parallel A C" 

 proof-

 from assms obtain ab where "B=((%x. ab + x) ` A)" unfolding affine_parallel_def by auto 

 moreover 

 from assms obtain bc where "C=((%x. bc + x) ` B)" unfolding affine_parallel_def by auto

 ultimately show ?thesis using translation_assoc[of bc ab A] unfolding affine_parallel_def by auto 

 qed

 lemma affine_translation_aux:

   fixes a :: "'a::real_vector"

   assumes "affine ((%x. a + x) ` S)" shows "affine S"

 proof-

 { fix x y u v

   assume xy: "x : S" "y : S" "(u :: real)+v=1"

   hence "(a+x):((%x. a + x) ` S)" "(a+y):((%x. a + x) ` S)" by auto

   hence h1: "u *\<^sub>R  (a+x) + v *\<^sub>R (a+y) : ((%x. a + x) ` S)" using xy assms unfolding affine_def by auto

   have "u *\<^sub>R (a+x) + v *\<^sub>R (a+y) = (u+v) *\<^sub>R a + (u *\<^sub>R x + v *\<^sub>R y)" by (simp add:algebra_simps)

   also have "...= a + (u *\<^sub>R x + v *\<^sub>R y)" using `u+v=1` by auto

   ultimately have "a + (u *\<^sub>R x + v *\<^sub>R y) : ((%x. a + x) ` S)" using h1 by auto

   hence "u *\<^sub>R x + v *\<^sub>R y : S" by auto

 } from this show ?thesis unfolding affine_def by auto

 qed

 lemma affine_translation:

   fixes a :: "'a::real_vector"

   shows "affine S <-> affine ((%x. a + x) ` S)"

 proof-

 have "affine S ==> affine ((%x. a + x) ` S)" using affine_translation_aux[of "-a" "((%x. a + x) ` S)"]  using translation_assoc[of "-a" a S] by auto

 from this show ?thesis using affine_translation_aux by auto

 qed

 lemma parallel_is_affine:

 fixes S T :: "'a::real_vector set"

 assumes "affine S" "affine_parallel S T"

 shows "affine T"

 proof-

   from assms obtain a where "T=((%x. a + x) ` S)" unfolding affine_parallel_def by auto 

   from this show ?thesis using affine_translation assms by auto

 qed

 lemma subspace_imp_affine: "subspace s \<Longrightarrow> affine s"

   unfolding subspace_def affine_def by auto

 subsubsection {* Subspace parallel to an affine set *}

 lemma subspace_affine:

   shows "subspace S <-> (affine S & 0 : S)"

 proof-

 have h0: "subspace S ==> (affine S & 0 : S)" using subspace_imp_affine[of S] subspace_0 by auto

 { assume assm: "affine S & 0 : S"

   { fix c :: real 

     fix x assume x_def: "x : S"

     have "c *\<^sub>R x = (1-c) *\<^sub>R 0 + c *\<^sub>R x" by auto

     moreover have "(1-c) *\<^sub>R 0 + c *\<^sub>R x : S" using affine_alt[of S] assm x_def by auto

     ultimately have "c *\<^sub>R x : S" by auto

   } hence h1: "!c. !x : S. c *\<^sub>R x : S" by auto

   { fix x y assume xy_def: "x : S" "y : S"

     def u == "(1 :: real)/2"

     have "(1/2) *\<^sub>R (x+y) = (1/2) *\<^sub>R (x+y)" by auto

     moreover have "(1/2) *\<^sub>R (x+y)=(1/2) *\<^sub>R x + (1-(1/2)) *\<^sub>R y" by (simp add: algebra_simps)

     moreover have "(1-u) *\<^sub>R x + u *\<^sub>R y : S" using affine_alt[of S] assm xy_def by auto

     ultimately have "(1/2) *\<^sub>R (x+y) : S" using u_def by auto

     moreover have "(x+y) = 2 *\<^sub>R ((1/2) *\<^sub>R (x+y))" by auto

     ultimately have "(x+y) : S" using h1[rule_format, of "(1/2) *\<^sub>R (x+y)" "2"] by auto

   } hence "!x : S. !y : S. (x+y) : S" by auto 

   hence "subspace S" using h1 assm unfolding subspace_def by auto

 } from this show ?thesis using h0 by metis

 qed

 lemma affine_diffs_subspace:

   assumes "affine S" "a : S"

   shows "subspace ((%x. (-a)+x) ` S)"

 proof-

 have "affine ((%x. (-a)+x) ` S)" using  affine_translation assms by auto  

 moreover have "0 : ((%x. (-a)+x) ` S)" using assms exI[of "(%x. x:S & -a+x=0)" a] by auto

 ultimately show ?thesis using subspace_affine by auto 

 qed

 lemma parallel_subspace_explicit:

 assumes "affine S" "a : S"

 assumes "L == {y. ? x : S. (-a)+x=y}" 

 shows "subspace L & affine_parallel S L" 

 proof-

 have par: "affine_parallel S L" unfolding affine_parallel_def using assms by auto

 hence "affine L" using assms parallel_is_affine by auto  

 moreover have "0 : L" using assms apply auto using exI[of "(%x. x:S & -a+x=0)" a] by auto

 ultimately show ?thesis using subspace_affine par by auto 

 qed

 lemma parallel_subspace_aux:

 assumes "subspace A" "subspace B" "affine_parallel A B"

 shows "A>=B"

 proof-

 from assms obtain a where a_def: "!x. (x : A <-> (a+x) : B)" using affine_parallel_expl[of A B] by auto

 hence "-a : A" using assms subspace_0[of B] by auto

 hence "a : A" using assms subspace_neg[of A "-a"] by auto

 from this show ?thesis using assms a_def unfolding subspace_def by auto

 qed

 lemma parallel_subspace:

 assumes "subspace A" "subspace B" "affine_parallel A B"

 shows "A=B"

 proof-

 have "A>=B" using assms parallel_subspace_aux by auto

 moreover have "A<=B" using assms parallel_subspace_aux[of B A] affine_parallel_commut by auto

 ultimately show ?thesis by auto  

 qed

 lemma affine_parallel_subspace:

 assumes "affine S" "S ~= {}"

 shows "?!L. subspace L & affine_parallel S L" 

 proof-

 have ex: "? L. subspace L & affine_parallel S L" using assms  parallel_subspace_explicit by auto 

 { fix L1 L2 assume ass: "subspace L1 & affine_parallel S L1" "subspace L2 & affine_parallel S L2"

   hence "affine_parallel L1 L2" using affine_parallel_commut[of S L1] affine_parallel_assoc[of L1 S L2] by auto

   hence "L1=L2" using ass parallel_subspace by auto

 } from this show ?thesis using ex by auto

 qed

 subsection {* Cones *}

 definition

   cone :: "'a::real_vector set \<Rightarrow> bool" where

   "cone s \<longleftrightarrow> (\<forall>x\<in>s. \<forall>c\<ge>0. (c *\<^sub>R x) \<in> s)"

 lemma cone_empty[intro, simp]: "cone {}"

   unfolding cone_def by auto

 lemma cone_univ[intro, simp]: "cone UNIV"

   unfolding cone_def by auto

 lemma cone_Inter[intro]: "(\<forall>s\<in>f. cone s) \<Longrightarrow> cone(\<Inter> f)"

   unfolding cone_def by auto

 subsubsection {* Conic hull *}

 lemma cone_cone_hull: "cone (cone hull s)"

   unfolding hull_def by auto

 lemma cone_hull_eq: "(cone hull s = s) \<longleftrightarrow> cone s"

   apply(rule hull_eq)

   using cone_Inter unfolding subset_eq by auto

 lemma mem_cone:

   assumes "cone S" "x : S" "c>=0"

   shows "c *\<^sub>R x : S"

   using assms cone_def[of S] by auto

 lemma cone_contains_0:

 assumes "cone S"

 shows "(S ~= {}) <-> (0 : S)"

 proof-

 { assume "S ~= {}" from this obtain a where "a:S" by auto

   hence "0 : S" using assms mem_cone[of S a 0] by auto

 } from this show ?thesis by auto

 qed

 lemma cone_0: "cone {0}"

 unfolding cone_def by auto

 lemma cone_Union[intro]: "(!s:f. cone s) --> (cone (Union f))"

   unfolding cone_def by blast

 lemma cone_iff:

 assumes "S ~= {}"

 shows "cone S <-> 0:S & (!c. c>0 --> ((op *\<^sub>R c) ` S) = S)"

 proof-

 { assume "cone S"

   { fix c assume "(c :: real)>0"

     { fix x assume "x : S" hence "x : (op *\<^sub>R c) ` S" unfolding image_def

         using `cone S` `c>0` mem_cone[of S x "1/c"]

         exI[of "(%t. t:S & x = c *\<^sub>R t)" "(1 / c) *\<^sub>R x"] by auto

     }

     moreover

     { fix x assume "x : (op *\<^sub>R c) ` S"

       (*from this obtain t where "t:S & x = c *\<^sub>R t" by auto*)

       hence "x:S" using `cone S` `c>0` unfolding cone_def image_def `c>0` by auto

     }

     ultimately have "((op *\<^sub>R c) ` S) = S" by auto

   } hence "0:S & (!c. c>0 --> ((op *\<^sub>R c) ` S) = S)" using `cone S` cone_contains_0[of S] assms by auto

 }

 moreover

 { assume a: "0:S & (!c. c>0 --> ((op *\<^sub>R c) ` S) = S)"

   { fix x assume "x:S"

     fix c1 assume "(c1 :: real)>=0"

     hence "(c1=0) | (c1>0)" by auto

     hence "c1 *\<^sub>R x : S" using a `x:S` by auto

   }

  hence "cone S" unfolding cone_def by auto

 } ultimately show ?thesis by blast

 qed

 lemma cone_hull_empty:

 "cone hull {} = {}"

 by (metis cone_empty cone_hull_eq)

 lemma cone_hull_empty_iff:

 shows "(S = {}) <-> (cone hull S = {})"

 by (metis bot_least cone_hull_empty hull_subset xtrans(5))

 lemma cone_hull_contains_0: 

 shows "(S ~= {}) <-> (0 : cone hull S)"

 using cone_cone_hull[of S] cone_contains_0[of "cone hull S"] cone_hull_empty_iff[of S] by auto

 lemma mem_cone_hull:

   assumes "x : S" "c>=0"

   shows "c *\<^sub>R x : cone hull S"

 by (metis assms cone_cone_hull hull_inc mem_cone)

 lemma cone_hull_expl:

 shows "cone hull S = {c *\<^sub>R x | c x. c>=0 & x : S}" (is "?lhs = ?rhs")

 proof-

 { fix x assume "x : ?rhs"

   from this obtain cx xx where x_def: "x= cx *\<^sub>R xx & (cx :: real)>=0 & xx : S" by auto

   fix c assume c_def: "(c :: real)>=0"

   hence "c *\<^sub>R x = (c*cx) *\<^sub>R xx" using x_def by (simp add: algebra_simps)

   moreover have "(c*cx) >= 0" using c_def x_def using mult_nonneg_nonneg by auto

   ultimately have "c *\<^sub>R x : ?rhs" using x_def by auto

 } hence "cone ?rhs" unfolding cone_def by auto

   hence "?rhs : Collect cone" unfolding mem_Collect_eq by auto

 { fix x assume "x : S" hence "1 *\<^sub>R x : ?rhs" apply auto apply(rule_tac x="1" in exI) by auto

   hence "x : ?rhs" by auto

 } hence "S <= ?rhs" by auto

 hence "?lhs <= ?rhs" using `?rhs : Collect cone` hull_minimal[of S "?rhs" "cone"] by auto

 moreover

 { fix x assume "x : ?rhs"

   from this obtain cx xx where x_def: "x= cx *\<^sub>R xx & (cx :: real)>=0 & xx : S" by auto

   hence "xx : cone hull S" using hull_subset[of S] by auto

   hence "x : ?lhs" using x_def cone_cone_hull[of S] cone_def[of "cone hull S"] by auto

 } ultimately show ?thesis by auto

 qed

 lemma cone_closure:

   fixes S :: "('a::real_normed_vector) set"

   assumes "cone S" shows "cone (closure S)"

 proof-

 { assume "S = {}" hence ?thesis by auto }

 moreover

 { assume "S ~= {}" hence "0:S & (!c. c>0 --> op *\<^sub>R c ` S = S)" using cone_iff[of S] assms by auto

   hence "0:(closure S) & (!c. c>0 --> op *\<^sub>R c ` (closure S) = (closure S))"

      using closure_subset by (auto simp add: closure_scaleR)

   hence ?thesis using cone_iff[of "closure S"] by auto

 }

 ultimately show ?thesis by blast

 qed

 subsection {* Affine dependence and consequential theorems (from Lars Schewe) *}

 definition

   affine_dependent :: "'a::real_vector set \<Rightarrow> bool" where

   "affine_dependent s \<longleftrightarrow> (\<exists>x\<in>s. x \<in> (affine hull (s - {x})))"

 lemma affine_dependent_explicit:

   "affine_dependent p \<longleftrightarrow>

     (\<exists>s u. finite s \<and> s \<subseteq> p \<and> setsum u s = 0 \<and>

     (\<exists>v\<in>s. u v \<noteq> 0) \<and> setsum (\<lambda>v. u v *\<^sub>R v) s = 0)"

   unfolding affine_dependent_def affine_hull_explicit mem_Collect_eq apply(rule)

   apply(erule bexE,erule exE,erule exE) apply(erule conjE)+ defer apply(erule exE,erule exE) apply(erule conjE)+ apply(erule bexE)

 proof-

   fix x s u assume as:"x \<in> p" "finite s" "s \<noteq> {}" "s \<subseteq> p - {x}" "setsum u s = 1" "(\<Sum>v\<in>s. u v *\<^sub>R v) = x"

   have "x\<notin>s" using as(1,4) by auto

   show "\<exists>s u. finite s \<and> s \<subseteq> p \<and> setsum u s = 0 \<and> (\<exists>v\<in>s. u v \<noteq> 0) \<and> (\<Sum>v\<in>s. u v *\<^sub>R v) = 0"

     apply(rule_tac x="insert x s" in exI, rule_tac x="\<lambda>v. if v = x then - 1 else u v" in exI)

     unfolding if_smult and setsum_clauses(2)[OF as(2)] and setsum_delta_notmem[OF `x\<notin>s`] and as using as by auto 

 next

   fix s u v assume as:"finite s" "s \<subseteq> p" "setsum u s = 0" "(\<Sum>v\<in>s. u v *\<^sub>R v) = 0" "v \<in> s" "u v \<noteq> 0"

   have "s \<noteq> {v}" using as(3,6) by auto

   thus "\<exists>x\<in>p. \<exists>s u. finite s \<and> s \<noteq> {} \<and> s \<subseteq> p - {x} \<and> setsum u s = 1 \<and> (\<Sum>v\<in>s. u v *\<^sub>R v) = x" 

     apply(rule_tac x=v in bexI, rule_tac x="s - {v}" in exI, rule_tac x="\<lambda>x. - (1 / u v) * u x" in exI)

     unfolding scaleR_scaleR[THEN sym] and scaleR_right.setsum [symmetric] unfolding setsum_right_distrib[THEN sym] and setsum_diff1[OF as(1)] using as by auto

 qed

 lemma affine_dependent_explicit_finite:

   fixes s :: "'a::real_vector set" assumes "finite s"

   shows "affine_dependent s \<longleftrightarrow> (\<exists>u. setsum u s = 0 \<and> (\<exists>v\<in>s. u v \<noteq> 0) \<and> setsum (\<lambda>v. u v *\<^sub>R v) s = 0)"

   (is "?lhs = ?rhs")

 proof

   have *:"\<And>vt u v. (if vt then u v else 0) *\<^sub>R v = (if vt then (u v) *\<^sub>R v else (0::'a))" by auto

   assume ?lhs

   then obtain t u v where "finite t" "t \<subseteq> s" "setsum u t = 0" "v\<in>t" "u v \<noteq> 0"  "(\<Sum>v\<in>t. u v *\<^sub>R v) = 0"

     unfolding affine_dependent_explicit by auto

   thus ?rhs apply(rule_tac x="\<lambda>x. if x\<in>t then u x else 0" in exI)

     apply auto unfolding * and setsum_restrict_set[OF assms, THEN sym]

     unfolding Int_absorb1[OF `t\<subseteq>s`] by auto

 next

   assume ?rhs

   then obtain u v where "setsum u s = 0"  "v\<in>s" "u v \<noteq> 0" "(\<Sum>v\<in>s. u v *\<^sub>R v) = 0" by auto

   thus ?lhs unfolding affine_dependent_explicit using assms by auto

 qed

 subsection {* Connectedness of convex sets *}

 lemma connected_real_lemma:

   fixes f :: "real \<Rightarrow> 'a::metric_space"

   assumes ab: "a \<le> b" and fa: "f a \<in> e1" and fb: "f b \<in> e2"

   and dst: "\<And>e x. a <= x \<Longrightarrow> x <= b \<Longrightarrow> 0 < e ==> \<exists>d > 0. \<forall>y. abs(y - x) < d \<longrightarrow> dist(f y) (f x) < e"

   and e1: "\<forall>y \<in> e1. \<exists>e > 0. \<forall>y'. dist y' y < e \<longrightarrow> y' \<in> e1"

   and e2: "\<forall>y \<in> e2. \<exists>e > 0. \<forall>y'. dist y' y < e \<longrightarrow> y' \<in> e2"

   and e12: "~(\<exists>x \<ge> a. x <= b \<and> f x \<in> e1 \<and> f x \<in> e2)"

   shows "\<exists>x \<ge> a. x <= b \<and> f x \<notin> e1 \<and> f x \<notin> e2" (is "\<exists> x. ?P x")

 proof-

   let ?S = "{c. \<forall>x \<ge> a. x <= c \<longrightarrow> f x \<in> e1}"

   have Se: " \<exists>x. x \<in> ?S" apply (rule exI[where x=a]) by (auto simp add: fa)

   have Sub: "\<exists>y. isUb UNIV ?S y"

     apply (rule exI[where x= b])

     using ab fb e12 by (auto simp add: isUb_def setle_def)

   from reals_complete[OF Se Sub] obtain l where

     l: "isLub UNIV ?S l"by blast

   have alb: "a \<le> l" "l \<le> b" using l ab fa fb e12

     apply (auto simp add: isLub_def leastP_def isUb_def setle_def setge_def)

     by (metis linorder_linear)

   have ale1: "\<forall>z \<ge> a. z < l \<longrightarrow> f z \<in> e1" using l

     apply (auto simp add: isLub_def leastP_def isUb_def setle_def setge_def)

     by (metis linorder_linear not_le)

     have th1: "\<And>z x e d :: real. z <= x + e \<Longrightarrow> e < d ==> z < x \<or> abs(z - x) < d" by arith

     have th2: "\<And>e x:: real. 0 < e ==> ~(x + e <= x)" by arith

     have "\<And>d::real. 0 < d \<Longrightarrow> 0 < d/2 \<and> d/2 < d" by simp

     then have th3: "\<And>d::real. d > 0 \<Longrightarrow> \<exists>e > 0. e < d" by blast

     {assume le2: "f l \<in> e2"

       from le2 fa fb e12 alb have la: "l \<noteq> a" by metis

       hence lap: "l - a > 0" using alb by arith

       from e2[rule_format, OF le2] obtain e where

         e: "e > 0" "\<forall>y. dist y (f l) < e \<longrightarrow> y \<in> e2" by metis

       from dst[OF alb e(1)] obtain d where

         d: "d > 0" "\<forall>y. \<bar>y - l\<bar> < d \<longrightarrow> dist (f y) (f l) < e" by metis

       let ?d' = "min (d/2) ((l - a)/2)"

       have "?d' < d \<and> 0 < ?d' \<and> ?d' < l - a" using lap d(1)

         by (simp add: min_max.less_infI2)

       then have "\<exists>d'. d' < d \<and> d' >0 \<and> l - d' > a" by auto

       then obtain d' where d': "d' > 0" "d' < d" "l - d' > a" by metis

       from d e have th0: "\<forall>y. \<bar>y - l\<bar> < d \<longrightarrow> f y \<in> e2" by metis

       from th0[rule_format, of "l - d'"] d' have "f (l - d') \<in> e2" by auto

       moreover

       have "f (l - d') \<in> e1" using ale1[rule_format, of "l -d'"] d' by auto

       ultimately have False using e12 alb d' by auto}

     moreover

     {assume le1: "f l \<in> e1"

     from le1 fa fb e12 alb have lb: "l \<noteq> b" by metis

       hence blp: "b - l > 0" using alb by arith

       from e1[rule_format, OF le1] obtain e where

         e: "e > 0" "\<forall>y. dist y (f l) < e \<longrightarrow> y \<in> e1" by metis

       from dst[OF alb e(1)] obtain d where

         d: "d > 0" "\<forall>y. \<bar>y - l\<bar> < d \<longrightarrow> dist (f y) (f l) < e" by metis

       have "\<And>d::real. 0 < d \<Longrightarrow> d/2 < d \<and> 0 < d/2" by simp

       then have "\<exists>d'. d' < d \<and> d' >0" using d(1) by blast

       then obtain d' where d': "d' > 0" "d' < d" by metis

       from d e have th0: "\<forall>y. \<bar>y - l\<bar> < d \<longrightarrow> f y \<in> e1" by auto

       hence "\<forall>y. l \<le> y \<and> y \<le> l + d' \<longrightarrow> f y \<in> e1" using d' by auto

       with ale1 have "\<forall>y. a \<le> y \<and> y \<le> l + d' \<longrightarrow> f y \<in> e1" by auto

       with l d' have False

         by (auto simp add: isLub_def isUb_def setle_def setge_def leastP_def) }

     ultimately show ?thesis using alb by metis

 qed

 lemma convex_connected:

   fixes s :: "'a::real_normed_vector set"

   assumes "convex s" shows "connected s"

 proof-

   { fix e1 e2 assume as:"open e1" "open e2" "e1 \<inter> e2 \<inter> s = {}" "s \<subseteq> e1 \<union> e2" 

     assume "e1 \<inter> s \<noteq> {}" "e2 \<inter> s \<noteq> {}"

     then obtain x1 x2 where x1:"x1\<in>e1" "x1\<in>s" and x2:"x2\<in>e2" "x2\<in>s" by auto

     hence n:"norm (x1 - x2) > 0" unfolding zero_less_norm_iff using as(3) by auto

     { fix x e::real assume as:"0 \<le> x" "x \<le> 1" "0 < e"

       { fix y have *:"(1 - x) *\<^sub>R x1 + x *\<^sub>R x2 - ((1 - y) *\<^sub>R x1 + y *\<^sub>R x2) = (y - x) *\<^sub>R x1 - (y - x) *\<^sub>R x2"

           by (simp add: algebra_simps)

         assume "\<bar>y - x\<bar> < e / norm (x1 - x2)"

         hence "norm ((1 - x) *\<^sub>R x1 + x *\<^sub>R x2 - ((1 - y) *\<^sub>R x1 + y *\<^sub>R x2)) < e"

           unfolding * and scaleR_right_diff_distrib[THEN sym]

           unfolding less_divide_eq using n by auto  }

       hence "\<exists>d>0. \<forall>y. \<bar>y - x\<bar> < d \<longrightarrow> norm ((1 - x) *\<^sub>R x1 + x *\<^sub>R x2 - ((1 - y) *\<^sub>R x1 + y *\<^sub>R x2)) < e"

         apply(rule_tac x="e / norm (x1 - x2)" in exI) using as

         apply auto unfolding zero_less_divide_iff using n by simp  }  note * = this

     have "\<exists>x\<ge>0. x \<le> 1 \<and> (1 - x) *\<^sub>R x1 + x *\<^sub>R x2 \<notin> e1 \<and> (1 - x) *\<^sub>R x1 + x *\<^sub>R x2 \<notin> e2"

       apply(rule connected_real_lemma) apply (simp add: `x1\<in>e1` `x2\<in>e2` dist_commute)+

       using * apply(simp add: dist_norm)

       using as(1,2)[unfolded open_dist] apply simp

       using as(1,2)[unfolded open_dist] apply simp

       using assms[unfolded convex_alt, THEN bspec[where x=x1], THEN bspec[where x=x2]] using x1 x2

       using as(3) by auto

     then obtain x where "x\<ge>0" "x\<le>1" "(1 - x) *\<^sub>R x1 + x *\<^sub>R x2 \<notin> e1"  "(1 - x) *\<^sub>R x1 + x *\<^sub>R x2 \<notin> e2" by auto

     hence False using as(4) 

       using assms[unfolded convex_alt, THEN bspec[where x=x1], THEN bspec[where x=x2]]

       using x1(2) x2(2) by auto  }

   thus ?thesis unfolding connected_def by auto

 qed

 text {* One rather trivial consequence. *}

 lemma connected_UNIV[intro]: "connected (UNIV :: 'a::real_normed_vector set)"

   by(simp add: convex_connected convex_UNIV)

 text {* Balls, being convex, are connected. *}

 lemma convex_box: fixes a::"'a::euclidean_space"

   assumes "\<And>i. i<DIM('a) \<Longrightarrow> convex {x. P i x}"

   shows "convex {x. \<forall>i<DIM('a). P i (x$$i)}"

   using assms unfolding convex_def by auto

 lemma convex_positive_orthant: "convex {x::'a::euclidean_space. (\<forall>i<DIM('a). 0 \<le> x$$i)}"

   by (rule convex_box) (simp add: atLeast_def[symmetric] convex_real_interval)

 lemma convex_local_global_minimum:

   fixes s :: "'a::real_normed_vector set"

   assumes "0<e" "convex_on s f" "ball x e \<subseteq> s" "\<forall>y\<in>ball x e. f x \<le> f y"

   shows "\<forall>y\<in>s. f x \<le> f y"

 proof(rule ccontr)

   have "x\<in>s" using assms(1,3) by auto

   assume "\<not> (\<forall>y\<in>s. f x \<le> f y)"

   then obtain y where "y\<in>s" and y:"f x > f y" by auto

   hence xy:"0 < dist x y" by (auto simp add: dist_nz[THEN sym])

   then obtain u where "0 < u" "u \<le> 1" and u:"u < e / dist x y"

     using real_lbound_gt_zero[of 1 "e / dist x y"] using xy `e>0` and divide_pos_pos[of e "dist x y"] by auto

   hence "f ((1-u) *\<^sub>R x + u *\<^sub>R y) \<le> (1-u) * f x + u * f y" using `x\<in>s` `y\<in>s`

     using assms(2)[unfolded convex_on_def, THEN bspec[where x=x], THEN bspec[where x=y], THEN spec[where x="1-u"]] by auto

   moreover

   have *:"x - ((1 - u) *\<^sub>R x + u *\<^sub>R y) = u *\<^sub>R (x - y)" by (simp add: algebra_simps)

   have "(1 - u) *\<^sub>R x + u *\<^sub>R y \<in> ball x e" unfolding mem_ball dist_norm unfolding * and norm_scaleR and abs_of_pos[OF `0<u`] unfolding dist_norm[THEN sym]

     using u unfolding pos_less_divide_eq[OF xy] by auto

   hence "f x \<le> f ((1 - u) *\<^sub>R x + u *\<^sub>R y)" using assms(4) by auto

   ultimately show False using mult_strict_left_mono[OF y `u>0`] unfolding left_diff_distrib by auto

 qed

 lemma convex_ball:

   fixes x :: "'a::real_normed_vector"

   shows "convex (ball x e)" 

 proof(auto simp add: convex_def)

   fix y z assume yz:"dist x y < e" "dist x z < e"

   fix u v ::real assume uv:"0 \<le> u" "0 \<le> v" "u + v = 1"

   have "dist x (u *\<^sub>R y + v *\<^sub>R z) \<le> u * dist x y + v * dist x z" using uv yz

     using convex_distance[of "ball x e" x, unfolded convex_on_def, THEN bspec[where x=y], THEN bspec[where x=z]] by auto

   thus "dist x (u *\<^sub>R y + v *\<^sub>R z) < e" using convex_bound_lt[OF yz uv] by auto

 qed

 lemma convex_cball:

   fixes x :: "'a::real_normed_vector"

   shows "convex(cball x e)"

 proof(auto simp add: convex_def Ball_def)

   fix y z assume yz:"dist x y \<le> e" "dist x z \<le> e"

   fix u v ::real assume uv:" 0 \<le> u" "0 \<le> v" "u + v = 1"

   have "dist x (u *\<^sub>R y + v *\<^sub>R z) \<le> u * dist x y + v * dist x z" using uv yz

     using convex_distance[of "cball x e" x, unfolded convex_on_def, THEN bspec[where x=y], THEN bspec[where x=z]] by auto

   thus "dist x (u *\<^sub>R y + v *\<^sub>R z) \<le> e" using convex_bound_le[OF yz uv] by auto 

 qed

 lemma connected_ball:

   fixes x :: "'a::real_normed_vector"

   shows "connected (ball x e)"

   using convex_connected convex_ball by auto

 lemma connected_cball:

   fixes x :: "'a::real_normed_vector"

   shows "connected(cball x e)"

   using convex_connected convex_cball by auto

 subsection {* Convex hull *}

 lemma convex_convex_hull: "convex(convex hull s)"

   unfolding hull_def using convex_Inter[of "{t. convex t \<and> s \<subseteq> t}"]

   by auto

 lemma convex_hull_eq: "convex hull s = s \<longleftrightarrow> convex s"

 by (metis convex_convex_hull hull_same)

 lemma bounded_convex_hull:

   fixes s :: "'a::real_normed_vector set"

   assumes "bounded s" shows "bounded(convex hull s)"

 proof- from assms obtain B where B:"\<forall>x\<in>s. norm x \<le> B" unfolding bounded_iff by auto

   show ?thesis apply(rule bounded_subset[OF bounded_cball, of _ 0 B])

     unfolding subset_hull[of convex, OF convex_cball]

     unfolding subset_eq mem_cball dist_norm using B by auto qed

 lemma finite_imp_bounded_convex_hull:

   fixes s :: "'a::real_normed_vector set"

   shows "finite s \<Longrightarrow> bounded(convex hull s)"

   using bounded_convex_hull finite_imp_bounded by auto

 subsubsection {* Convex hull is "preserved" by a linear function *}

 lemma convex_hull_linear_image:

   assumes "bounded_linear f"

   shows "f ` (convex hull s) = convex hull (f ` s)"

   apply rule unfolding subset_eq ball_simps apply(rule_tac[!] hull_induct, rule hull_inc) prefer 3  

   apply(erule imageE)apply(rule_tac x=xa in image_eqI) apply assumption

   apply(rule hull_subset[unfolded subset_eq, rule_format]) apply assumption

 proof-

   interpret f: bounded_linear f by fact

   show "convex {x. f x \<in> convex hull f ` s}" 

   unfolding convex_def by(auto simp add: f.scaleR f.add convex_convex_hull[unfolded convex_def, rule_format]) next

   interpret f: bounded_linear f by fact

   show "convex {x. x \<in> f ` (convex hull s)}" using  convex_convex_hull[unfolded convex_def, of s] 

     unfolding convex_def by (auto simp add: f.scaleR [symmetric] f.add [symmetric])

 qed auto

 lemma in_convex_hull_linear_image:

   assumes "bounded_linear f" "x \<in> convex hull s"

   shows "(f x) \<in> convex hull (f ` s)"

 using convex_hull_linear_image[OF assms(1)] assms(2) by auto

 subsubsection {* Stepping theorems for convex hulls of finite sets *}

 lemma convex_hull_empty[simp]: "convex hull {} = {}"

   apply(rule hull_unique) by auto

 lemma convex_hull_singleton[simp]: "convex hull {a} = {a}"

   apply(rule hull_unique) by auto

 lemma convex_hull_insert:

   fixes s :: "'a::real_vector set"

   assumes "s \<noteq> {}"

   shows "convex hull (insert a s) = {x. \<exists>u\<ge>0. \<exists>v\<ge>0. \<exists>b. (u + v = 1) \<and>

                                     b \<in> (convex hull s) \<and> (x = u *\<^sub>R a + v *\<^sub>R b)}" (is "?xyz = ?hull")

  apply(rule,rule hull_minimal,rule) unfolding insert_iff prefer 3 apply rule proof-

  fix x assume x:"x = a \<or> x \<in> s"

  thus "x\<in>?hull" apply rule unfolding mem_Collect_eq apply(rule_tac x=1 in exI) defer 

    apply(rule_tac x=0 in exI) using assms hull_subset[of s convex] by auto

 next

   fix x assume "x\<in>?hull"

   then obtain u v b where obt:"u\<ge>0" "v\<ge>0" "u + v = 1" "b \<in> convex hull s" "x = u *\<^sub>R a + v *\<^sub>R b" by auto

   have "a\<in>convex hull insert a s" "b\<in>convex hull insert a s"

     using hull_mono[of s "insert a s" convex] hull_mono[of "{a}" "insert a s" convex] and obt(4) by auto

   thus "x\<in> convex hull insert a s" unfolding obt(5) using convex_convex_hull[of "insert a s", unfolded convex_def]

     apply(erule_tac x=a in ballE) apply(erule_tac x=b in ballE) apply(erule_tac x=u in allE) using obt by auto

 next

   show "convex ?hull" unfolding convex_def apply(rule,rule,rule,rule,rule,rule,rule) proof-

     fix x y u v assume as:"(0::real) \<le> u" "0 \<le> v" "u + v = 1" "x\<in>?hull" "y\<in>?hull"

     from as(4) obtain u1 v1 b1 where obt1:"u1\<ge>0" "v1\<ge>0" "u1 + v1 = 1" "b1 \<in> convex hull s" "x = u1 *\<^sub>R a + v1 *\<^sub>R b1" by auto

     from as(5) obtain u2 v2 b2 where obt2:"u2\<ge>0" "v2\<ge>0" "u2 + v2 = 1" "b2 \<in> convex hull s" "y = u2 *\<^sub>R a + v2 *\<^sub>R b2" by auto

     have *:"\<And>(x::'a) s1 s2. x - s1 *\<^sub>R x - s2 *\<^sub>R x = ((1::real) - (s1 + s2)) *\<^sub>R x" by (auto simp add: algebra_simps)

     have "\<exists>b \<in> convex hull s. u *\<^sub>R x + v *\<^sub>R y = (u * u1) *\<^sub>R a + (v * u2) *\<^sub>R a + (b - (u * u1) *\<^sub>R b - (v * u2) *\<^sub>R b)"

     proof(cases "u * v1 + v * v2 = 0")

       have *:"\<And>(x::'a) s1 s2. x - s1 *\<^sub>R x - s2 *\<^sub>R x = ((1::real) - (s1 + s2)) *\<^sub>R x" by (auto simp add: algebra_simps)

       case True hence **:"u * v1 = 0" "v * v2 = 0"

         using mult_nonneg_nonneg[OF `u\<ge>0` `v1\<ge>0`] mult_nonneg_nonneg[OF `v\<ge>0` `v2\<ge>0`] by arith+

       hence "u * u1 + v * u2 = 1" using as(3) obt1(3) obt2(3) by auto

       thus ?thesis unfolding obt1(5) obt2(5) * using assms hull_subset[of s convex] by(auto simp add: ** scaleR_right_distrib)

     next

       have "1 - (u * u1 + v * u2) = (u + v) - (u * u1 + v * u2)" using as(3) obt1(3) obt2(3) by (auto simp add: field_simps)

       also have "\<dots> = u * (v1 + u1 - u1) + v * (v2 + u2 - u2)" using as(3) obt1(3) obt2(3) by (auto simp add: field_simps) 

       also have "\<dots> = u * v1 + v * v2" by simp finally have **:"1 - (u * u1 + v * u2) = u * v1 + v * v2" by auto

       case False have "0 \<le> u * v1 + v * v2" "0 \<le> u * v1" "0 \<le> u * v1 + v * v2" "0 \<le> v * v2" apply -

         apply(rule add_nonneg_nonneg) prefer 4 apply(rule add_nonneg_nonneg) apply(rule_tac [!] mult_nonneg_nonneg)

         using as(1,2) obt1(1,2) obt2(1,2) by auto 

       thus ?thesis unfolding obt1(5) obt2(5) unfolding * and ** using False

         apply(rule_tac x="((u * v1) / (u * v1 + v * v2)) *\<^sub>R b1 + ((v * v2) / (u * v1 + v * v2)) *\<^sub>R b2" in bexI) defer

         apply(rule convex_convex_hull[of s, unfolded convex_def, rule_format]) using obt1(4) obt2(4)

         unfolding add_divide_distrib[THEN sym] and zero_le_divide_iff

         by (auto simp add: scaleR_left_distrib scaleR_right_distrib)

     qed note * = this

     have u1:"u1 \<le> 1" unfolding obt1(3)[THEN sym] and not_le using obt1(2) by auto

     have u2:"u2 \<le> 1" unfolding obt2(3)[THEN sym] and not_le using obt2(2) by auto

     have "u1 * u + u2 * v \<le> (max u1 u2) * u + (max u1 u2) * v" apply(rule add_mono)

       apply(rule_tac [!] mult_right_mono) using as(1,2) obt1(1,2) obt2(1,2) by auto

     also have "\<dots> \<le> 1" unfolding right_distrib[THEN sym] and as(3) using u1 u2 by auto

     finally 

     show "u *\<^sub>R x + v *\<^sub>R y \<in> ?hull" unfolding mem_Collect_eq apply(rule_tac x="u * u1 + v * u2" in exI)

       apply(rule conjI) defer apply(rule_tac x="1 - u * u1 - v * u2" in exI) unfolding Bex_def

       using as(1,2) obt1(1,2) obt2(1,2) * by(auto intro!: mult_nonneg_nonneg add_nonneg_nonneg simp add: algebra_simps)

   qed

 qed

 subsubsection {* Explicit expression for convex hull *}

 lemma convex_hull_indexed:

   fixes s :: "'a::real_vector set"

   shows "convex hull s = {y. \<exists>k u x. (\<forall>i\<in>{1::nat .. k}. 0 \<le> u i \<and> x i \<in> s) \<and>

                             (setsum u {1..k} = 1) \<and>

                             (setsum (\<lambda>i. u i *\<^sub>R x i) {1..k} = y)}" (is "?xyz = ?hull")

   apply(rule hull_unique) apply(rule) defer

   apply(subst convex_def) apply(rule,rule,rule,rule,rule,rule,rule)

 proof-

   fix x assume "x\<in>s"

   thus "x \<in> ?hull" unfolding mem_Collect_eq apply(rule_tac x=1 in exI, rule_tac x="\<lambda>x. 1" in exI) by auto

 next

   fix t assume as:"s \<subseteq> t" "convex t"

   show "?hull \<subseteq> t" apply(rule) unfolding mem_Collect_eq apply(erule exE | erule conjE)+ proof-

     fix x k u y assume assm:"\<forall>i\<in>{1::nat..k}. 0 \<le> u i \<and> y i \<in> s" "setsum u {1..k} = 1" "(\<Sum>i = 1..k. u i *\<^sub>R y i) = x"

     show "x\<in>t" unfolding assm(3)[THEN sym] apply(rule as(2)[unfolded convex, rule_format])

       using assm(1,2) as(1) by auto qed

 next

   fix x y u v assume uv:"0\<le>u" "0\<le>v" "u+v=(1::real)" and xy:"x\<in>?hull" "y\<in>?hull"

   from xy obtain k1 u1 x1 where x:"\<forall>i\<in>{1::nat..k1}. 0\<le>u1 i \<and> x1 i \<in> s" "setsum u1 {Suc 0..k1} = 1" "(\<Sum>i = Suc 0..k1. u1 i *\<^sub>R x1 i) = x" by auto

   from xy obtain k2 u2 x2 where y:"\<forall>i\<in>{1::nat..k2}. 0\<le>u2 i \<and> x2 i \<in> s" "setsum u2 {Suc 0..k2} = 1" "(\<Sum>i = Suc 0..k2. u2 i *\<^sub>R x2 i) = y" by auto

   have *:"\<And>P (x1::'a) x2 s1 s2 i.(if P i then s1 else s2) *\<^sub>R (if P i then x1 else x2) = (if P i then s1 *\<^sub>R x1 else s2 *\<^sub>R x2)"

     "{1..k1 + k2} \<inter> {1..k1} = {1..k1}" "{1..k1 + k2} \<inter> - {1..k1} = (\<lambda>i. i + k1) ` {1..k2}"

     prefer 3 apply(rule,rule) unfolding image_iff apply(rule_tac x="x - k1" in bexI) by(auto simp add: not_le)

   have inj:"inj_on (\<lambda>i. i + k1) {1..k2}" unfolding inj_on_def by auto  

   show "u *\<^sub>R x + v *\<^sub>R y \<in> ?hull" apply(rule)

     apply(rule_tac x="k1 + k2" in exI, rule_tac x="\<lambda>i. if i \<in> {1..k1} then u * u1 i else v * u2 (i - k1)" in exI)

     apply(rule_tac x="\<lambda>i. if i \<in> {1..k1} then x1 i else x2 (i - k1)" in exI) apply(rule,rule) defer apply(rule)

     unfolding * and setsum_cases[OF finite_atLeastAtMost[of 1 "k1 + k2"]] and setsum_reindex[OF inj] and o_def Collect_mem_eq

     unfolding scaleR_scaleR[THEN sym] scaleR_right.setsum [symmetric] setsum_right_distrib[THEN sym] proof-

     fix i assume i:"i \<in> {1..k1+k2}"

     show "0 \<le> (if i \<in> {1..k1} then u * u1 i else v * u2 (i - k1)) \<and> (if i \<in> {1..k1} then x1 i else x2 (i - k1)) \<in> s"

     proof(cases "i\<in>{1..k1}")

       case True thus ?thesis using mult_nonneg_nonneg[of u "u1 i"] and uv(1) x(1)[THEN bspec[where x=i]] by auto

     next def j \<equiv> "i - k1"

       case False with i have "j \<in> {1..k2}" unfolding j_def by auto

       thus ?thesis unfolding j_def[symmetric] using False

         using mult_nonneg_nonneg[of v "u2 j"] and uv(2) y(1)[THEN bspec[where x=j]] by auto qed

   qed(auto simp add: not_le x(2,3) y(2,3) uv(3))

 qed

 lemma convex_hull_finite:

   fixes s :: "'a::real_vector set"

   assumes "finite s"

   shows "convex hull s = {y. \<exists>u. (\<forall>x\<in>s. 0 \<le> u x) \<and>

          setsum u s = 1 \<and> setsum (\<lambda>x. u x *\<^sub>R x) s = y}" (is "?HULL = ?set")

 proof(rule hull_unique, auto simp add: convex_def[of ?set])

   fix x assume "x\<in>s" thus " \<exists>u. (\<forall>x\<in>s. 0 \<le> u x) \<and> setsum u s = 1 \<and> (\<Sum>x\<in>s. u x *\<^sub>R x) = x" 

     apply(rule_tac x="\<lambda>y. if x=y then 1 else 0" in exI) apply auto

     unfolding setsum_delta'[OF assms] and setsum_delta''[OF assms] by auto 

 next

   fix u v ::real assume uv:"0 \<le> u" "0 \<le> v" "u + v = 1"

   fix ux assume ux:"\<forall>x\<in>s. 0 \<le> ux x" "setsum ux s = (1::real)"

   fix uy assume uy:"\<forall>x\<in>s. 0 \<le> uy x" "setsum uy s = (1::real)"

   { fix x assume "x\<in>s"

     hence "0 \<le> u * ux x + v * uy x" using ux(1)[THEN bspec[where x=x]] uy(1)[THEN bspec[where x=x]] and uv(1,2)

       by (auto, metis add_nonneg_nonneg mult_nonneg_nonneg uv(1) uv(2))  }

   moreover have "(\<Sum>x\<in>s. u * ux x + v * uy x) = 1"

     unfolding setsum_addf and setsum_right_distrib[THEN sym] and ux(2) uy(2) using uv(3) by auto

   moreover have "(\<Sum>x\<in>s. (u * ux x + v * uy x) *\<^sub>R x) = u *\<^sub>R (\<Sum>x\<in>s. ux x *\<^sub>R x) + v *\<^sub>R (\<Sum>x\<in>s. uy x *\<^sub>R x)"

     unfolding scaleR_left_distrib and setsum_addf and scaleR_scaleR[THEN sym] and scaleR_right.setsum [symmetric] by auto

   ultimately show "\<exists>uc. (\<forall>x\<in>s. 0 \<le> uc x) \<and> setsum uc s = 1 \<and> (\<Sum>x\<in>s. uc x *\<^sub>R x) = u *\<^sub>R (\<Sum>x\<in>s. ux x *\<^sub>R x) + v *\<^sub>R (\<Sum>x\<in>s. uy x *\<^sub>R x)"

     apply(rule_tac x="\<lambda>x. u * ux x + v * uy x" in exI) by auto 

 next

   fix t assume t:"s \<subseteq> t" "convex t" 

   fix u assume u:"\<forall>x\<in>s. 0 \<le> u x" "setsum u s = (1::real)"

   thus "(\<Sum>x\<in>s. u x *\<^sub>R x) \<in> t" using t(2)[unfolded convex_explicit, THEN spec[where x=s], THEN spec[where x=u]]

     using assms and t(1) by auto

 qed

 subsubsection {* Another formulation from Lars Schewe *}

 lemma setsum_constant_scaleR:

   fixes y :: "'a::real_vector"

   shows "(\<Sum>x\<in>A. y) = of_nat (card A) *\<^sub>R y"

 apply (cases "finite A")

 apply (induct set: finite)

 apply (simp_all add: algebra_simps)

 done

 lemma convex_hull_explicit:

   fixes p :: "'a::real_vector set"

   shows "convex hull p = {y. \<exists>s u. finite s \<and> s \<subseteq> p \<and>

              (\<forall>x\<in>s. 0 \<le> u x) \<and> setsum u s = 1 \<and> setsum (\<lambda>v. u v *\<^sub>R v) s = y}" (is "?lhs = ?rhs")

 proof-

   { fix x assume "x\<in>?lhs"

     then obtain k u y where obt:"\<forall>i\<in>{1::nat..k}. 0 \<le> u i \<and> y i \<in> p" "setsum u {1..k} = 1" "(\<Sum>i = 1..k. u i *\<^sub>R y i) = x"

       unfolding convex_hull_indexed by auto

     have fin:"finite {1..k}" by auto

     have fin':"\<And>v. finite {i \<in> {1..k}. y i = v}" by auto

     { fix j assume "j\<in>{1..k}"

       hence "y j \<in> p" "0 \<le> setsum u {i. Suc 0 \<le> i \<and> i \<le> k \<and> y i = y j}"

         using obt(1)[THEN bspec[where x=j]] and obt(2) apply simp

         apply(rule setsum_nonneg) using obt(1) by auto } 

     moreover

     have "(\<Sum>v\<in>y ` {1..k}. setsum u {i \<in> {1..k}. y i = v}) = 1"  

       unfolding setsum_image_gen[OF fin, THEN sym] using obt(2) by auto

     moreover have "(\<Sum>v\<in>y ` {1..k}. setsum u {i \<in> {1..k}. y i = v} *\<^sub>R v) = x"

       using setsum_image_gen[OF fin, of "\<lambda>i. u i *\<^sub>R y i" y, THEN sym]

       unfolding scaleR_left.setsum using obt(3) by auto

     ultimately have "\<exists>s u. finite s \<and> s \<subseteq> p \<and> (\<forall>x\<in>s. 0 \<le> u x) \<and> setsum u s = 1 \<and> (\<Sum>v\<in>s. u v *\<^sub>R v) = x"

       apply(rule_tac x="y ` {1..k}" in exI)

       apply(rule_tac x="\<lambda>v. setsum u {i\<in>{1..k}. y i = v}" in exI) by auto

     hence "x\<in>?rhs" by auto  }

   moreover

   { fix y assume "y\<in>?rhs"

     then obtain s u where obt:"finite s" "s \<subseteq> p" "\<forall>x\<in>s. 0 \<le> u x" "setsum u s = 1" "(\<Sum>v\<in>s. u v *\<^sub>R v) = y" by auto

     obtain f where f:"inj_on f {1..card s}" "f ` {1..card s} = s" using ex_bij_betw_nat_finite_1[OF obt(1)] unfolding bij_betw_def by auto

     { fix i::nat assume "i\<in>{1..card s}"

       hence "f i \<in> s"  apply(subst f(2)[THEN sym]) by auto

       hence "0 \<le> u (f i)" "f i \<in> p" using obt(2,3) by auto  }

     moreover have *:"finite {1..card s}" by auto

     { fix y assume "y\<in>s"

       then obtain i where "i\<in>{1..card s}" "f i = y" using f using image_iff[of y f "{1..card s}"] by auto

       hence "{x. Suc 0 \<le> x \<and> x \<le> card s \<and> f x = y} = {i}" apply auto using f(1)[unfolded inj_on_def] apply(erule_tac x=x in ballE) by auto

       hence "card {x. Suc 0 \<le> x \<and> x \<le> card s \<and> f x = y} = 1" by auto

       hence "(\<Sum>x\<in>{x \<in> {1..card s}. f x = y}. u (f x)) = u y"

             "(\<Sum>x\<in>{x \<in> {1..card s}. f x = y}. u (f x) *\<^sub>R f x) = u y *\<^sub>R y"

         by (auto simp add: setsum_constant_scaleR)   }

     hence "(\<Sum>x = 1..card s. u (f x)) = 1" "(\<Sum>i = 1..card s. u (f i) *\<^sub>R f i) = y"

       unfolding setsum_image_gen[OF *(1), of "\<lambda>x. u (f x) *\<^sub>R f x" f] and setsum_image_gen[OF *(1), of "\<lambda>x. u (f x)" f] 

       unfolding f using setsum_cong2[of s "\<lambda>y. (\<Sum>x\<in>{x \<in> {1..card s}. f x = y}. u (f x) *\<^sub>R f x)" "\<lambda>v. u v *\<^sub>R v"]

       using setsum_cong2 [of s "\<lambda>y. (\<Sum>x\<in>{x \<in> {1..card s}. f x = y}. u (f x))" u] unfolding obt(4,5) by auto

     ultimately have "\<exists>k u x. (\<forall>i\<in>{1..k}. 0 \<le> u i \<and> x i \<in> p) \<and> setsum u {1..k} = 1 \<and> (\<Sum>i::nat = 1..k. u i *\<^sub>R x i) = y"

       apply(rule_tac x="card s" in exI) apply(rule_tac x="u \<circ> f" in exI) apply(rule_tac x=f in exI) by fastforce

     hence "y \<in> ?lhs" unfolding convex_hull_indexed by auto  }

   ultimately show ?thesis unfolding set_eq_iff by blast

 qed

 subsubsection {* A stepping theorem for that expansion *}

 lemma convex_hull_finite_step:

   fixes s :: "'a::real_vector set" assumes "finite s"

   shows "(\<exists>u. (\<forall>x\<in>insert a s. 0 \<le> u x) \<and> setsum u (insert a s) = w \<and> setsum (\<lambda>x. u x *\<^sub>R x) (insert a s) = y)

      \<longleftrightarrow> (\<exists>v\<ge>0. \<exists>u. (\<forall>x\<in>s. 0 \<le> u x) \<and> setsum u s = w - v \<and> setsum (\<lambda>x. u x *\<^sub>R x) s = y - v *\<^sub>R a)" (is "?lhs = ?rhs")

 proof(rule, case_tac[!] "a\<in>s")

   assume "a\<in>s" hence *:"insert a s = s" by auto

   assume ?lhs thus ?rhs unfolding * apply(rule_tac x=0 in exI) by auto

 next

   assume ?lhs then obtain u where u:"\<forall>x\<in>insert a s. 0 \<le> u x" "setsum u (insert a s) = w" "(\<Sum>x\<in>insert a s. u x *\<^sub>R x) = y" by auto

   assume "a\<notin>s" thus ?rhs apply(rule_tac x="u a" in exI) using u(1)[THEN bspec[where x=a]] apply simp

     apply(rule_tac x=u in exI) using u[unfolded setsum_clauses(2)[OF assms]] and `a\<notin>s` by auto

 next

   assume "a\<in>s" hence *:"insert a s = s" by auto

   have fin:"finite (insert a s)" using assms by auto

   assume ?rhs then obtain v u where uv:"v\<ge>0" "\<forall>x\<in>s. 0 \<le> u x" "setsum u s = w - v" "(\<Sum>x\<in>s. u x *\<^sub>R x) = y - v *\<^sub>R a" by auto

   show ?lhs apply(rule_tac x="\<lambda>x. (if a = x then v else 0) + u x" in exI) unfolding scaleR_left_distrib and setsum_addf and setsum_delta''[OF fin] and setsum_delta'[OF fin]

     unfolding setsum_clauses(2)[OF assms] using uv and uv(2)[THEN bspec[where x=a]] and `a\<in>s` by auto

 next

   assume ?rhs then obtain v u where uv:"v\<ge>0" "\<forall>x\<in>s. 0 \<le> u x" "setsum u s = w - v" "(\<Sum>x\<in>s. u x *\<^sub>R x) = y - v *\<^sub>R a" by auto

   moreover assume "a\<notin>s" moreover have "(\<Sum>x\<in>s. if a = x then v else u x) = setsum u s" "(\<Sum>x\<in>s. (if a = x then v else u x) *\<^sub>R x) = (\<Sum>x\<in>s. u x *\<^sub>R x)"

     apply(rule_tac setsum_cong2) defer apply(rule_tac setsum_cong2) using `a\<notin>s` by auto

   ultimately show ?lhs apply(rule_tac x="\<lambda>x. if a = x then v else u x" in exI)  unfolding setsum_clauses(2)[OF assms] by auto

 qed

 subsubsection {* Hence some special cases *}

 lemma convex_hull_2:

   "convex hull {a,b} = {u *\<^sub>R a + v *\<^sub>R b | u v. 0 \<le> u \<and> 0 \<le> v \<and> u + v = 1}"

 proof- have *:"\<And>u. (\<forall>x\<in>{a, b}. 0 \<le> u x) \<longleftrightarrow> 0 \<le> u a \<and> 0 \<le> u b" by auto have **:"finite {b}" by auto

 show ?thesis apply(simp add: convex_hull_finite) unfolding convex_hull_finite_step[OF **, of a 1, unfolded * conj_assoc]

   apply auto apply(rule_tac x=v in exI) apply(rule_tac x="1 - v" in exI) apply simp

   apply(rule_tac x=u in exI) apply simp apply(rule_tac x="\<lambda>x. v" in exI) by simp qed

 lemma convex_hull_2_alt: "convex hull {a,b} = {a + u *\<^sub>R (b - a) | u.  0 \<le> u \<and> u \<le> 1}"

   unfolding convex_hull_2

 proof(rule Collect_cong) have *:"\<And>x y ::real. x + y = 1 \<longleftrightarrow> x = 1 - y" by auto

   fix x show "(\<exists>v u. x = v *\<^sub>R a + u *\<^sub>R b \<and> 0 \<le> v \<and> 0 \<le> u \<and> v + u = 1) = (\<exists>u. x = a + u *\<^sub>R (b - a) \<and> 0 \<le> u \<and> u \<le> 1)"

     unfolding * apply auto apply(rule_tac[!] x=u in exI) by (auto simp add: algebra_simps) qed

 lemma convex_hull_3:

   "convex hull {a,b,c} = { u *\<^sub>R a + v *\<^sub>R b + w *\<^sub>R c | u v w. 0 \<le> u \<and> 0 \<le> v \<and> 0 \<le> w \<and> u + v + w = 1}"

 proof-

   have fin:"finite {a,b,c}" "finite {b,c}" "finite {c}" by auto

   have *:"\<And>x y z ::real. x + y + z = 1 \<longleftrightarrow> x = 1 - y - z"

     by (auto simp add: field_simps)

   show ?thesis unfolding convex_hull_finite[OF fin(1)] and convex_hull_finite_step[OF fin(2)] and *

     unfolding convex_hull_finite_step[OF fin(3)] apply(rule Collect_cong) apply simp apply auto

     apply(rule_tac x=va in exI) apply (rule_tac x="u c" in exI) apply simp

     apply(rule_tac x="1 - v - w" in exI) apply simp apply(rule_tac x=v in exI) apply simp apply(rule_tac x="\<lambda>x. w" in exI) by simp qed

 lemma convex_hull_3_alt:

   "convex hull {a,b,c} = {a + u *\<^sub>R (b - a) + v *\<^sub>R (c - a) | u v.  0 \<le> u \<and> 0 \<le> v \<and> u + v \<le> 1}"

 proof- have *:"\<And>x y z ::real. x + y + z = 1 \<longleftrightarrow> x = 1 - y - z" by auto

   show ?thesis unfolding convex_hull_3 apply (auto simp add: *) apply(rule_tac x=v in exI) apply(rule_tac x=w in exI) apply (simp add: algebra_simps)

     apply(rule_tac x=u in exI) apply(rule_tac x=v in exI) by (simp add: algebra_simps) qed

 subsection {* Relations among closure notions and corresponding hulls *}

 lemma affine_imp_convex: "affine s \<Longrightarrow> convex s"

   unfolding affine_def convex_def by auto

 lemma subspace_imp_convex: "subspace s \<Longrightarrow> convex s"

   using subspace_imp_affine affine_imp_convex by auto

 lemma affine_hull_subset_span: "(affine hull s) \<subseteq> (span s)"

 by (metis hull_minimal span_inc subspace_imp_affine subspace_span)

 lemma convex_hull_subset_span: "(convex hull s) \<subseteq> (span s)"

 by (metis hull_minimal span_inc subspace_imp_convex subspace_span)

 lemma convex_hull_subset_affine_hull: "(convex hull s) \<subseteq> (affine hull s)"

 by (metis affine_affine_hull affine_imp_convex hull_minimal hull_subset)

 lemma affine_dependent_imp_dependent:

   shows "affine_dependent s \<Longrightarrow> dependent s"

   unfolding affine_dependent_def dependent_def 

   using affine_hull_subset_span by auto

 lemma dependent_imp_affine_dependent:

   assumes "dependent {x - a| x . x \<in> s}" "a \<notin> s"

   shows "affine_dependent (insert a s)"

 proof-

   from assms(1)[unfolded dependent_explicit] obtain S u v 

     where obt:"finite S" "S \<subseteq> {x - a |x. x \<in> s}" "v\<in>S" "u v  \<noteq> 0" "(\<Sum>v\<in>S. u v *\<^sub>R v) = 0" by auto

   def t \<equiv> "(\<lambda>x. x + a) ` S"

   have inj:"inj_on (\<lambda>x. x + a) S" unfolding inj_on_def by auto

   have "0\<notin>S" using obt(2) assms(2) unfolding subset_eq by auto

   have fin:"finite t" and  "t\<subseteq>s" unfolding t_def using obt(1,2) by auto 

   hence "finite (insert a t)" and "insert a t \<subseteq> insert a s" by auto 

   moreover have *:"\<And>P Q. (\<Sum>x\<in>t. (if x = a then P x else Q x)) = (\<Sum>x\<in>t. Q x)"

     apply(rule setsum_cong2) using `a\<notin>s` `t\<subseteq>s` by auto

   have "(\<Sum>x\<in>insert a t. if x = a then - (\<Sum>x\<in>t. u (x - a)) else u (x - a)) = 0"

     unfolding setsum_clauses(2)[OF fin] using `a\<notin>s` `t\<subseteq>s` apply auto unfolding * by auto

   moreover have "\<exists>v\<in>insert a t. (if v = a then - (\<Sum>x\<in>t. u (x - a)) else u (v - a)) \<noteq> 0"

     apply(rule_tac x="v + a" in bexI) using obt(3,4) and `0\<notin>S` unfolding t_def by auto

   moreover have *:"\<And>P Q. (\<Sum>x\<in>t. (if x = a then P x else Q x) *\<^sub>R x) = (\<Sum>x\<in>t. Q x *\<^sub>R x)"

     apply(rule setsum_cong2) using `a\<notin>s` `t\<subseteq>s` by auto

   have "(\<Sum>x\<in>t. u (x - a)) *\<^sub>R a = (\<Sum>v\<in>t. u (v - a) *\<^sub>R v)" 

     unfolding scaleR_left.setsum unfolding t_def and setsum_reindex[OF inj] and o_def

     using obt(5) by (auto simp add: setsum_addf scaleR_right_distrib)

   hence "(\<Sum>v\<in>insert a t. (if v = a then - (\<Sum>x\<in>t. u (x - a)) else u (v - a)) *\<^sub>R v) = 0"

     unfolding setsum_clauses(2)[OF fin] using `a\<notin>s` `t\<subseteq>s` by (auto simp add: *)

   ultimately show ?thesis unfolding affine_dependent_explicit

     apply(rule_tac x="insert a t" in exI) by auto 

 qed

 lemma convex_cone:

   "convex s \<and> cone s \<longleftrightarrow> (\<forall>x\<in>s. \<forall>y\<in>s. (x + y) \<in> s) \<and> (\<forall>x\<in>s. \<forall>c\<ge>0. (c *\<^sub>R x) \<in> s)" (is "?lhs = ?rhs")

 proof-

   { fix x y assume "x\<in>s" "y\<in>s" and ?lhs

     hence "2 *\<^sub>R x \<in>s" "2 *\<^sub>R y \<in> s" unfolding cone_def by auto

     hence "x + y \<in> s" using `?lhs`[unfolded convex_def, THEN conjunct1]

       apply(erule_tac x="2*\<^sub>R x" in ballE) apply(erule_tac x="2*\<^sub>R y" in ballE)

       apply(erule_tac x="1/2" in allE) apply simp apply(erule_tac x="1/2" in allE) by auto  }

   thus ?thesis unfolding convex_def cone_def by blast

 qed

 lemma affine_dependent_biggerset: fixes s::"('a::euclidean_space) set"

   assumes "finite s" "card s \<ge> DIM('a) + 2"

   shows "affine_dependent s"

 proof-

   have "s\<noteq>{}" using assms by auto then obtain a where "a\<in>s" by auto

   have *:"{x - a |x. x \<in> s - {a}} = (\<lambda>x. x - a) ` (s - {a})" by auto

   have "card {x - a |x. x \<in> s - {a}} = card (s - {a})" unfolding * 

     apply(rule card_image) unfolding inj_on_def by auto

   also have "\<dots> > DIM('a)" using assms(2)

     unfolding card_Diff_singleton[OF assms(1) `a\<in>s`] by auto

   finally show ?thesis apply(subst insert_Diff[OF `a\<in>s`, THEN sym])

     apply(rule dependent_imp_affine_dependent)

     apply(rule dependent_biggerset) by auto qed

 lemma affine_dependent_biggerset_general:

   assumes "finite (s::('a::euclidean_space) set)" "card s \<ge> dim s + 2"

   shows "affine_dependent s"

 proof-

   from assms(2) have "s \<noteq> {}" by auto

   then obtain a where "a\<in>s" by auto

   have *:"{x - a |x. x \<in> s - {a}} = (\<lambda>x. x - a) ` (s - {a})" by auto

   have **:"card {x - a |x. x \<in> s - {a}} = card (s - {a})" unfolding * 

     apply(rule card_image) unfolding inj_on_def by auto

   have "dim {x - a |x. x \<in> s - {a}} \<le> dim s"

     apply(rule subset_le_dim) unfolding subset_eq

     using `a\<in>s` by (auto simp add:span_superset span_sub)

   also have "\<dots> < dim s + 1" by auto

   also have "\<dots> \<le> card (s - {a})" using assms

     using card_Diff_singleton[OF assms(1) `a\<in>s`] by auto

   finally show ?thesis apply(subst insert_Diff[OF `a\<in>s`, THEN sym])

     apply(rule dependent_imp_affine_dependent) apply(rule dependent_biggerset_general) unfolding ** by auto qed

 subsection {* Caratheodory's theorem. *}

 lemma convex_hull_caratheodory: fixes p::"('a::euclidean_space) set"

   shows "convex hull p = {y. \<exists>s u. finite s \<and> s \<subseteq> p \<and> card s \<le> DIM('a) + 1 \<and>

   (\<forall>x\<in>s. 0 \<le> u x) \<and> setsum u s = 1 \<and> setsum (\<lambda>v. u v *\<^sub>R v) s = y}"

   unfolding convex_hull_explicit set_eq_iff mem_Collect_eq

 proof(rule,rule)

   fix y let ?P = "\<lambda>n. \<exists>s u. finite s \<and> card s = n \<and> s \<subseteq> p \<and> (\<forall>x\<in>s. 0 \<le> u x) \<and> setsum u s = 1 \<and> (\<Sum>v\<in>s. u v *\<^sub>R v) = y"

   assume "\<exists>s u. finite s \<and> s \<subseteq> p \<and> (\<forall>x\<in>s. 0 \<le> u x) \<and> setsum u s = 1 \<and> (\<Sum>v\<in>s. u v *\<^sub>R v) = y"

   then obtain N where "?P N" by auto

   hence "\<exists>n\<le>N. (\<forall>k<n. \<not> ?P k) \<and> ?P n" apply(rule_tac ex_least_nat_le) by auto

   then obtain n where "?P n" and smallest:"\<forall>k<n. \<not> ?P k" by blast

   then obtain s u where obt:"finite s" "card s = n" "s\<subseteq>p" "\<forall>x\<in>s. 0 \<le> u x" "setsum u s = 1"  "(\<Sum>v\<in>s. u v *\<^sub>R v) = y" by auto

   have "card s \<le> DIM('a) + 1" proof(rule ccontr, simp only: not_le)

     assume "DIM('a) + 1 < card s"

     hence "affine_dependent s" using affine_dependent_biggerset[OF obt(1)] by auto

     then obtain w v where wv:"setsum w s = 0" "v\<in>s" "w v \<noteq> 0" "(\<Sum>v\<in>s. w v *\<^sub>R v) = 0"

       using affine_dependent_explicit_finite[OF obt(1)] by auto

     def i \<equiv> "(\<lambda>v. (u v) / (- w v)) ` {v\<in>s. w v < 0}"  def t \<equiv> "Min i"

     have "\<exists>x\<in>s. w x < 0" proof(rule ccontr, simp add: not_less)

       assume as:"\<forall>x\<in>s. 0 \<le> w x"

       hence "setsum w (s - {v}) \<ge> 0" apply(rule_tac setsum_nonneg) by auto

       hence "setsum w s > 0" unfolding setsum_diff1'[OF obt(1) `v\<in>s`]

         using as[THEN bspec[where x=v]] and `v\<in>s` using `w v \<noteq> 0` by auto

       thus False using wv(1) by auto

     qed hence "i\<noteq>{}" unfolding i_def by auto

     hence "t \<ge> 0" using Min_ge_iff[of i 0 ] and obt(1) unfolding t_def i_def

       using obt(4)[unfolded le_less] apply auto unfolding divide_le_0_iff by auto 

     have t:"\<forall>v\<in>s. u v + t * w v \<ge> 0" proof

       fix v assume "v\<in>s" hence v:"0\<le>u v" using obt(4)[THEN bspec[where x=v]] by auto

       show"0 \<le> u v + t * w v" proof(cases "w v < 0")

         case False thus ?thesis apply(rule_tac add_nonneg_nonneg) 

           using v apply simp apply(rule mult_nonneg_nonneg) using `t\<ge>0` by auto next

         case True hence "t \<le> u v / (- w v)" using `v\<in>s`

           unfolding t_def i_def apply(rule_tac Min_le) using obt(1) by auto 

         thus ?thesis unfolding real_0_le_add_iff

           using pos_le_divide_eq[OF True[unfolded neg_0_less_iff_less[THEN sym]]] by auto

       qed qed

     obtain a where "a\<in>s" and "t = (\<lambda>v. (u v) / (- w v)) a" and "w a < 0"

       using Min_in[OF _ `i\<noteq>{}`] and obt(1) unfolding i_def t_def by auto

     hence a:"a\<in>s" "u a + t * w a = 0" by auto

     have *:"\<And>f. setsum f (s - {a}) = setsum f s - ((f a)::'b::ab_group_add)"

       unfolding setsum_diff1'[OF obt(1) `a\<in>s`] by auto 

     have "(\<Sum>v\<in>s. u v + t * w v) = 1"

       unfolding setsum_addf wv(1) setsum_right_distrib[THEN sym] obt(5) by auto

     moreover have "(\<Sum>v\<in>s. u v *\<^sub>R v + (t * w v) *\<^sub>R v) - (u a *\<^sub>R a + (t * w a) *\<^sub>R a) = y" 

       unfolding setsum_addf obt(6) scaleR_scaleR[THEN sym] scaleR_right.setsum [symmetric] wv(4)

       using a(2) [THEN eq_neg_iff_add_eq_0 [THEN iffD2]] by simp

     ultimately have "?P (n - 1)" apply(rule_tac x="(s - {a})" in exI)

       apply(rule_tac x="\<lambda>v. u v + t * w v" in exI) using obt(1-3) and t and a

       by (auto simp add: * scaleR_left_distrib)

     thus False using smallest[THEN spec[where x="n - 1"]] by auto qed

   thus "\<exists>s u. finite s \<and> s \<subseteq> p \<and> card s \<le> DIM('a) + 1

     \<and> (\<forall>x\<in>s. 0 \<le> u x) \<and> setsum u s = 1 \<and> (\<Sum>v\<in>s. u v *\<^sub>R v) = y" using obt by auto

 qed auto

 lemma caratheodory:

  "convex hull p = {x::'a::euclidean_space. \<exists>s. finite s \<and> s \<subseteq> p \<and>

       card s \<le> DIM('a) + 1 \<and> x \<in> convex hull s}"

   unfolding set_eq_iff apply(rule, rule) unfolding mem_Collect_eq proof-

   fix x assume "x \<in> convex hull p"

   then obtain s u where "finite s" "s \<subseteq> p" "card s \<le> DIM('a) + 1"

      "\<forall>x\<in>s. 0 \<le> u x" "setsum u s = 1" "(\<Sum>v\<in>s. u v *\<^sub>R v) = x"unfolding convex_hull_caratheodory by auto

   thus "\<exists>s. finite s \<and> s \<subseteq> p \<and> card s \<le> DIM('a) + 1 \<and> x \<in> convex hull s"

     apply(rule_tac x=s in exI) using hull_subset[of s convex]

   using convex_convex_hull[unfolded convex_explicit, of s, THEN spec[where x=s], THEN spec[where x=u]] by auto

 next

   fix x assume "\<exists>s. finite s \<and> s \<subseteq> p \<and> card s \<le> DIM('a) + 1 \<and> x \<in> convex hull s"

   then obtain s where "finite s" "s \<subseteq> p" "card s \<le> DIM('a) + 1" "x \<in> convex hull s" by auto

   thus "x \<in> convex hull p" using hull_mono[OF `s\<subseteq>p`] by auto

 qed

 subsection {* Some Properties of Affine Dependent Sets *}

 lemma affine_independent_empty: "~(affine_dependent {})"

   by (simp add: affine_dependent_def)

 lemma affine_independent_sing:

 shows "~(affine_dependent {a})"

  by (simp add: affine_dependent_def)

 lemma affine_hull_translation:

 "affine hull ((%x. a + x) `  S) = (%x. a + x) ` (affine hull S)"

 proof-

 have "affine ((%x. a + x) ` (affine hull S))" using affine_translation affine_affine_hull by auto

 moreover have "(%x. a + x) `  S <= (%x. a + x) ` (affine hull S)" using hull_subset[of S] by auto

 ultimately have h1: "affine hull ((%x. a + x) `  S) <= (%x. a + x) ` (affine hull S)" by (metis hull_minimal)

 have "affine((%x. -a + x) ` (affine hull ((%x. a + x) `  S)))"  using affine_translation affine_affine_hull by auto

 moreover have "(%x. -a + x) ` (%x. a + x) `  S <= (%x. -a + x) ` (affine hull ((%x. a + x) `  S))" using hull_subset[of "(%x. a + x) `  S"] by auto 

 moreover have "S=(%x. -a + x) ` (%x. a + x) `  S" using  translation_assoc[of "-a" a] by auto

 ultimately have "(%x. -a + x) ` (affine hull ((%x. a + x) `  S)) >= (affine hull S)" by (metis hull_minimal)

 hence "affine hull ((%x. a + x) `  S) >= (%x. a + x) ` (affine hull S)" by auto

 from this show ?thesis using h1 by auto

 qed

 lemma affine_dependent_translation:

   assumes "affine_dependent S"

   shows "affine_dependent ((%x. a + x) ` S)"

 proof-

 obtain x where x_def: "x : S & x : affine hull (S - {x})" using assms affine_dependent_def by auto

 have "op + a ` (S - {x}) = op + a ` S - {a + x}" by auto

 hence "a+x : affine hull ((%x. a + x) ` S - {a+x})" using  affine_hull_translation[of a "S-{x}"] x_def by auto

 moreover have "a+x : (%x. a + x) ` S" using x_def by auto  

 ultimately show ?thesis unfolding affine_dependent_def by auto 

 qed

 lemma affine_dependent_translation_eq:

   "affine_dependent S <-> affine_dependent ((%x. a + x) ` S)"

 proof-

 { assume "affine_dependent ((%x. a + x) ` S)" 

   hence "affine_dependent S" using affine_dependent_translation[of "((%x. a + x) ` S)" "-a"] translation_assoc[of "-a" a] by auto  

 } from this show ?thesis using affine_dependent_translation by auto

 qed

 lemma affine_hull_0_dependent:

   assumes "0 : affine hull S"

   shows "dependent S"

 proof-

 obtain s u where s_u_def: "finite s & s ~= {} & s <= S & setsum u s = 1 & (SUM v:s. u v *\<^sub>R v) = 0" using assms affine_hull_explicit[of S] by auto

 hence "EX v:s. u v ~= 0" using setsum_not_0[of "u" "s"] by auto 

 hence "finite s & s <= S & (EX v:s. u v ~= 0 & (SUM v:s. u v *\<^sub>R v) = 0)" using s_u_def by auto

 from this show ?thesis unfolding dependent_explicit[of S] by auto

 qed

 lemma affine_dependent_imp_dependent2:

   assumes "affine_dependent (insert 0 S)"

   shows "dependent S"

 proof-

 obtain x where x_def: "x:insert 0 S & x : affine hull (insert 0 S - {x})" using affine_dependent_def[of "(insert 0 S)"] assms by blast

 hence "x : span (insert 0 S - {x})" using affine_hull_subset_span by auto

 moreover have "span (insert 0 S - {x}) = span (S - {x})" using insert_Diff_if[of "0" S "{x}"] span_insert_0[of "S-{x}"] by auto

 ultimately have "x : span (S - {x})" by auto

 hence "(x~=0) ==> dependent S" using x_def dependent_def by auto

 moreover

 { assume "x=0" hence "0 : affine hull S" using x_def hull_mono[of "S - {0}" S] by auto

                hence "dependent S" using affine_hull_0_dependent by auto  

 } ultimately show ?thesis by auto

 qed

 lemma affine_dependent_iff_dependent:

   assumes "a ~: S"

   shows "affine_dependent (insert a S) <-> dependent ((%x. -a + x) ` S)" 

 proof-

 have "(op + (- a) ` S)={x - a| x . x : S}" by auto

 from this show ?thesis using affine_dependent_translation_eq[of "(insert a S)" "-a"] 

       affine_dependent_imp_dependent2 assms 

       dependent_imp_affine_dependent[of a S] by auto

 qed

 lemma affine_dependent_iff_dependent2:

   assumes "a : S"

   shows "affine_dependent S <-> dependent ((%x. -a + x) ` (S-{a}))"

 proof-

 have "insert a (S - {a})=S" using assms by auto

 from this show ?thesis using assms affine_dependent_iff_dependent[of a "S-{a}"] by auto 

 qed

 lemma affine_hull_insert_span_gen:

   shows "affine hull (insert a s) = (%x. a+x) ` span ((%x. -a+x) ` s)" 

 proof-

 have h1: "{x - a |x. x : s}=((%x. -a+x) ` s)" by auto

 { assume "a ~: s" hence ?thesis using affine_hull_insert_span[of a s] h1 by auto}  

 moreover

 { assume a1: "a : s"

   have "EX x. x:s & -a+x=0" apply (rule exI[of _ a]) using a1 by auto

   hence "insert 0 ((%x. -a+x) ` (s - {a}))=(%x. -a+x) ` s" by auto

   hence "span ((%x. -a+x) ` (s - {a}))=span ((%x. -a+x) ` s)" 

     using span_insert_0[of "op + (- a) ` (s - {a})"] by auto

   moreover have "{x - a |x. x : (s - {a})}=((%x. -a+x) ` (s - {a}))" by auto 

   moreover have "insert a (s - {a})=(insert a s)" using assms by auto

   ultimately have ?thesis using assms affine_hull_insert_span[of "a" "s-{a}"] by auto

 } 

 ultimately show ?thesis by auto  

 qed

 lemma affine_hull_span2:

   assumes "a : s"

   shows "affine hull s = (%x. a+x) ` span ((%x. -a+x) ` (s-{a}))"

   using affine_hull_insert_span_gen[of a "s - {a}", unfolded insert_Diff[OF assms]] by auto

 lemma affine_hull_span_gen:

   assumes "a : affine hull s"

   shows "affine hull s = (%x. a+x) ` span ((%x. -a+x) ` s)"

 proof-

 have "affine hull (insert a s) = affine hull s" using hull_redundant[of a affine s] assms by auto

 from this show ?thesis using affine_hull_insert_span_gen[of a "s"] by auto

 qed

 lemma affine_hull_span_0:

   assumes "0 : affine hull S"

   shows "affine hull S = span S"

 using affine_hull_span_gen[of "0" S] assms by auto

 lemma extend_to_affine_basis:

 fixes S V :: "('n::euclidean_space) set"

 assumes "~(affine_dependent S)" "S <= V" "S~={}"

 shows "? T. ~(affine_dependent T) & S<=T & T<=V & affine hull T = affine hull V"

 proof-

 obtain a where a_def: "a : S" using assms by auto

 hence h0: "independent  ((%x. -a + x) ` (S-{a}))" using affine_dependent_iff_dependent2 assms by auto

 from this obtain B 

    where B_def: "(%x. -a+x) ` (S - {a}) <= B & B <= (%x. -a+x) ` V & independent B & (%x. -a+x) ` V <= span B" 

    using maximal_independent_subset_extend[of "(%x. -a+x) ` (S-{a})" "(%x. -a + x) ` V"] assms by blast

 def T == "(%x. a+x) ` (insert 0 B)" hence "T=insert a ((%x. a+x) ` B)" by auto

 hence "affine hull T = (%x. a+x) ` span B" using affine_hull_insert_span_gen[of a "((%x. a+x) ` B)"] translation_assoc[of "-a" a B] by auto

 hence "V <= affine hull T" using B_def assms translation_inverse_subset[of a V "span B"] by auto

 moreover have "T<=V" using T_def B_def a_def assms by auto

 ultimately have "affine hull T = affine hull V" 

     by (metis Int_absorb1 Int_absorb2 hull_hull hull_mono)

 moreover have "S<=T" using T_def B_def translation_inverse_subset[of a "S-{a}" B] by auto

 moreover have "~(affine_dependent T)" using T_def affine_dependent_translation_eq[of "insert 0 B"] affine_dependent_imp_dependent2 B_def by auto

 ultimately show ?thesis using `T<=V` by auto

 qed

 lemma affine_basis_exists: 

 fixes V :: "('n::euclidean_space) set"

 shows "? B. B <= V & ~(affine_dependent B) & affine hull V = affine hull B"

 proof-

 { assume empt: "V={}" have "? B. B <= V & ~(affine_dependent B) & (affine hull V=affine hull B)" using empt affine_independent_empty by auto

 }

 moreover

 { assume nonempt: "V~={}" obtain x where "x:V" using nonempt by auto

   hence "? B. B <= V & ~(affine_dependent B) & (affine hull V=affine hull B)"

   using affine_dependent_def[of "{x}"] extend_to_affine_basis[of "{x}:: ('n::euclidean_space) set" V] by auto

 }

 ultimately show ?thesis by auto

 qed

 subsection {* Affine Dimension of a Set *}

 definition "aff_dim V = (SOME d :: int. ? B. (affine hull B=affine hull V) & ~(affine_dependent B) & (of_nat(card B) = d+1))"

 lemma aff_dim_basis_exists:

   fixes V :: "('n::euclidean_space) set" 

   shows "? B. (affine hull B=affine hull V) & ~(affine_dependent B) & (of_nat(card B) = aff_dim V+1)"

 proof-

 obtain B where B_def: "~(affine_dependent B) & (affine hull B=affine hull V)" using affine_basis_exists[of V] by auto

 from this show ?thesis unfolding aff_dim_def some_eq_ex[of "%d. ? (B :: ('n::euclidean_space) set). (affine hull B=affine hull V) & ~(affine_dependent B) & (of_nat(card B) = d+1)"] apply auto apply (rule exI[of _ "int (card B)-(1 :: int)"]) apply (rule exI[of _ "B"]) by auto

 qed

 lemma affine_hull_nonempty: "(S ~= {}) <-> affine hull S ~= {}"

 proof-

 have "(S = {}) ==> affine hull S = {}"using affine_hull_empty by auto 

 moreover have "affine hull S = {} ==> S = {}" unfolding hull_def by auto

 ultimately show "(S ~= {}) <-> affine hull S ~= {}" by blast

 qed

 lemma aff_dim_parallel_subspace_aux:

 fixes B :: "('n::euclidean_space) set"

 assumes "~(affine_dependent B)" "a:B"

 shows "finite B & ((card B) - 1 = dim (span ((%x. -a+x) ` (B-{a}))))" 

 proof-

 have "independent ((%x. -a + x) ` (B-{a}))" using affine_dependent_iff_dependent2 assms by auto

 hence fin: "dim (span ((%x. -a+x) ` (B-{a}))) = card ((%x. -a + x) ` (B-{a}))" "finite ((%x. -a + x) ` (B - {a}))"  using indep_card_eq_dim_span[of "(%x. -a+x) ` (B-{a})"] by auto

 { assume emp: "(%x. -a + x) ` (B - {a}) = {}" 

   have "B=insert a ((%x. a + x) ` (%x. -a + x) ` (B - {a}))" using translation_assoc[of "a" "-a" "(B - {a})"] assms by auto

   hence "B={a}" using emp by auto

   hence ?thesis using assms fin by auto  

 }

 moreover

 { assume "(%x. -a + x) ` (B - {a}) ~= {}"

   hence "card ((%x. -a + x) ` (B - {a}))>0" using fin by auto

   moreover have h1: "card ((%x. -a + x) ` (B-{a})) = card (B-{a})"  

      apply (rule card_image) using translate_inj_on by auto

   ultimately have "card (B-{a})>0" by auto

   hence "finite(B-{a})" using card_gt_0_iff[of "(B - {a})"] by auto

   moreover hence "(card (B-{a})= (card B) - 1)" using card_Diff_singleton assms by auto

   ultimately have ?thesis using fin h1 by auto

 } ultimately show ?thesis by auto

 qed

 lemma aff_dim_parallel_subspace:

 fixes V L :: "('n::euclidean_space) set"

 assumes "V ~= {}"

 assumes "subspace L" "affine_parallel (affine hull V) L"

 shows "aff_dim V=int(dim L)"

 proof-

 obtain B where B_def: "affine hull B = affine hull V & ~ affine_dependent B & int (card B) = aff_dim V + 1" using aff_dim_basis_exists by auto

 hence "B~={}" using assms B_def  affine_hull_nonempty[of V] affine_hull_nonempty[of B] by auto 

 from this obtain a where a_def: "a : B" by auto

 def Lb == "span ((%x. -a+x) ` (B-{a}))"

   moreover have "affine_parallel (affine hull B) Lb"

      using Lb_def B_def assms affine_hull_span2[of a B] a_def  affine_parallel_commut[of "Lb" "(affine hull B)"] unfolding affine_parallel_def by auto

   moreover have "subspace Lb" using Lb_def subspace_span by auto

   moreover have "affine hull B ~= {}" using assms B_def affine_hull_nonempty[of V] by auto

   ultimately have "L=Lb" using assms affine_parallel_subspace[of "affine hull B"] affine_affine_hull[of B] B_def by auto 

   hence "dim L=dim Lb" by auto 

   moreover have "(card B) - 1 = dim Lb" "finite B" using Lb_def aff_dim_parallel_subspace_aux a_def B_def by auto

 (*  hence "card B=dim Lb+1" using `B~={}` card_gt_0_iff[of B] by auto *)

   ultimately show ?thesis using B_def `B~={}` card_gt_0_iff[of B] by auto

 qed

 lemma aff_independent_finite:

 fixes B :: "('n::euclidean_space) set"

 assumes "~(affine_dependent B)"

 shows "finite B"

 proof-

 { assume "B~={}" from this obtain a where "a:B" by auto 

   hence ?thesis using aff_dim_parallel_subspace_aux assms by auto 

 } from this show ?thesis by auto

 qed

 lemma independent_finite:

 fixes B :: "('n::euclidean_space) set"

 assumes "independent B" 

 shows "finite B"

 using affine_dependent_imp_dependent[of B] aff_independent_finite[of B] assms by auto

 lemma subspace_dim_equal:

 assumes "subspace (S :: ('n::euclidean_space) set)" "subspace T" "S <= T" "dim S >= dim T"

 shows "S=T"

 proof- 

 obtain B where B_def: "B <= S & independent B & S <= span B & (card B = dim S)" using basis_exists[of S] by auto

 hence "span B <= S" using span_mono[of B S] span_eq[of S] assms by metis 

 hence "span B = S" using B_def by auto

 have "dim S = dim T" using assms dim_subset[of S T] by auto

 hence "T <= span B" using card_eq_dim[of B T] B_def independent_finite assms by auto

 from this show ?thesis using assms `span B=S` by auto

 qed

 lemma span_substd_basis:  assumes "d\<subseteq>{..<DIM('a::euclidean_space)}"

   shows "(span {basis i | i. i : d}) = {x::'a::euclidean_space. (!i<DIM('a). i ~: d --> x$$i = 0)}"

   (is "span ?A = ?B")

 proof-

 have "?A <= ?B" by auto

 moreover have s: "subspace ?B" using subspace_substandard[of "%i. i ~: d"] .

 ultimately have "span ?A <= ?B" using span_mono[of "?A" "?B"] span_eq[of "?B"] by blast

 moreover have "card d <= dim (span ?A)" using independent_card_le_dim[of "?A" "span ?A"] 

    independent_substdbasis[OF assms] card_substdbasis[OF assms] span_inc[of "?A"] by auto

 moreover hence "dim ?B <= dim (span ?A)" using dim_substandard[OF assms] by auto

 ultimately show ?thesis using s subspace_dim_equal[of "span ?A" "?B"] 

   subspace_span[of "?A"] by auto

 qed

 lemma basis_to_substdbasis_subspace_isomorphism:

 fixes B :: "('a::euclidean_space) set" 

 assumes "independent B"

 shows "EX f d. card d = card B & linear f & f ` B = {basis i::'a |i. i : (d :: nat set)} & 

        f ` span B = {x. ALL i<DIM('a). i ~: d --> x $$ i = (0::real)} &  inj_on f (span B) \<and> d\<subseteq>{..<DIM('a)}" 

 proof-

   have B:"card B=dim B" using dim_unique[of B B "card B"] assms span_inc[of B] by auto

   def d \<equiv> "{..<dim B}" have t:"card d = dim B" unfolding d_def by auto

   have "dim B <= DIM('a)" using dim_subset_UNIV[of B] by auto

   hence d:"d\<subseteq>{..<DIM('a)}" unfolding d_def by auto

   let ?t = "{x::'a::euclidean_space. !i<DIM('a). i ~: d --> x$$i = 0}"

   have "EX f. linear f & f ` B = {basis i |i. i : d} &

     f ` span B = ?t & inj_on f (span B)"

     apply (rule basis_to_basis_subspace_isomorphism[of "span B" ?t B "{basis i |i. i : d}"])

     apply(rule subspace_span) apply(rule subspace_substandard) defer

     apply(rule span_inc) apply(rule assms) defer unfolding dim_span[of B] apply(rule B)

     unfolding span_substd_basis[OF d,THEN sym] card_substdbasis[OF d] apply(rule span_inc)

     apply(rule independent_substdbasis[OF d]) apply(rule,assumption)

     unfolding t[THEN sym] span_substd_basis[OF d] dim_substandard[OF d] by auto

   from this t `card B=dim B` show ?thesis using d by auto 

 qed

 lemma aff_dim_empty:

 fixes S :: "('n::euclidean_space) set" 

 shows "S = {} <-> aff_dim S = -1"

 proof-

 obtain B where "affine hull B = affine hull S & ~ affine_dependent B & int (card B) = aff_dim S + 1" using aff_dim_basis_exists by auto

 moreover hence "S={} <-> B={}" using affine_hull_nonempty[of B] affine_hull_nonempty[of S] by auto

 ultimately show ?thesis using aff_independent_finite[of B] card_gt_0_iff[of B] by auto

 qed

 lemma aff_dim_affine_hull:

 shows "aff_dim (affine hull S)=aff_dim S" 

 unfolding aff_dim_def using hull_hull[of _ S] by auto 

 lemma aff_dim_affine_hull2:

 assumes "affine hull S=affine hull T"

 shows "aff_dim S=aff_dim T" unfolding aff_dim_def using assms by auto

 lemma aff_dim_unique: 

 fixes B V :: "('n::euclidean_space) set" 

 assumes "(affine hull B=affine hull V) & ~(affine_dependent B)"

 shows "of_nat(card B) = aff_dim V+1"

 proof-

 { assume "B={}" hence "V={}" using affine_hull_nonempty[of V] affine_hull_nonempty[of B] assms by auto

   hence "aff_dim V = (-1::int)"  using aff_dim_empty by auto  

   hence ?thesis using `B={}` by auto

 }

 moreover

 { assume "B~={}" from this obtain a where a_def: "a:B" by auto 

   def Lb == "span ((%x. -a+x) ` (B-{a}))"

   have "affine_parallel (affine hull B) Lb"

      using Lb_def affine_hull_span2[of a B] a_def  affine_parallel_commut[of "Lb" "(affine hull B)"] 

      unfolding affine_parallel_def by auto

   moreover have "subspace Lb" using Lb_def subspace_span by auto

   ultimately have "aff_dim B=int(dim Lb)" using aff_dim_parallel_subspace[of B Lb] `B~={}` by auto 

   moreover have "(card B) - 1 = dim Lb" "finite B" using Lb_def aff_dim_parallel_subspace_aux a_def assms by auto

   ultimately have "(of_nat(card B) = aff_dim B+1)" using  `B~={}` card_gt_0_iff[of B] by auto

   hence ?thesis using aff_dim_affine_hull2 assms by auto

 } ultimately show ?thesis by blast

 qed

 lemma aff_dim_affine_independent: 

 fixes B :: "('n::euclidean_space) set" 

 assumes "~(affine_dependent B)"

 shows "of_nat(card B) = aff_dim B+1"

   using aff_dim_unique[of B B] assms by auto

 lemma aff_dim_sing: 

 fixes a :: "'n::euclidean_space" 

 shows "aff_dim {a}=0"

   using aff_dim_affine_independent[of "{a}"] affine_independent_sing by auto

 lemma aff_dim_inner_basis_exists:

   fixes V :: "('n::euclidean_space) set" 

   shows "? B. B<=V & (affine hull B=affine hull V) & ~(affine_dependent B) & (of_nat(card B) = aff_dim V+1)"

 proof-

 obtain B where B_def: "~(affine_dependent B) & B<=V & (affine hull B=affine hull V)" using affine_basis_exists[of V] by auto

 moreover hence "of_nat(card B) = aff_dim V+1" using aff_dim_unique by auto

 ultimately show ?thesis by auto

 qed

 lemma aff_dim_le_card:

 fixes V :: "('n::euclidean_space) set" 

 assumes "finite V"

 shows "aff_dim V <= of_nat(card V) - 1"

  proof-

  obtain B where B_def: "B<=V & (of_nat(card B) = aff_dim V+1)" using aff_dim_inner_basis_exists[of V] by auto 

  moreover hence "card B <= card V" using assms card_mono by auto

  ultimately show ?thesis by auto

 qed

 lemma aff_dim_parallel_eq:

 fixes S T :: "('n::euclidean_space) set"

 assumes "affine_parallel (affine hull S) (affine hull T)"

 shows "aff_dim S=aff_dim T"

 proof-

 { assume "T~={}" "S~={}" 

   from this obtain L where L_def: "subspace L & affine_parallel (affine hull T) L" 

        using affine_parallel_subspace[of "affine hull T"] affine_affine_hull[of T] affine_hull_nonempty by auto

   hence "aff_dim T = int(dim L)" using aff_dim_parallel_subspace `T~={}` by auto

   moreover have "subspace L & affine_parallel (affine hull S) L" 

      using L_def affine_parallel_assoc[of "affine hull S" "affine hull T" L] assms by auto

   moreover hence "aff_dim S = int(dim L)" using aff_dim_parallel_subspace `S~={}` by auto 

   ultimately have ?thesis by auto

 }

 moreover

 { assume "S={}" hence "S={} & T={}" using assms affine_hull_nonempty unfolding affine_parallel_def by auto

   hence ?thesis using aff_dim_empty by auto

 }

 moreover

 { assume "T={}" hence "S={} & T={}" using assms affine_hull_nonempty unfolding affine_parallel_def by auto

   hence ?thesis using aff_dim_empty by auto

 }

 ultimately show ?thesis by blast

 qed

 lemma aff_dim_translation_eq:

 fixes a :: "'n::euclidean_space"

 shows "aff_dim ((%x. a + x) ` S)=aff_dim S" 

 proof-

 have "affine_parallel (affine hull S) (affine hull ((%x. a + x) ` S))" unfolding affine_parallel_def apply (rule exI[of _ "a"]) using affine_hull_translation[of a S] by auto

 from this show ?thesis using  aff_dim_parallel_eq[of S "(%x. a + x) ` S"] by auto 

 qed

 lemma aff_dim_affine:

 fixes S L :: "('n::euclidean_space) set"

 assumes "S ~= {}" "affine S"

 assumes "subspace L" "affine_parallel S L"

 shows "aff_dim S=int(dim L)" 

 proof-

 have 1: "(affine hull S) = S" using assms affine_hull_eq[of S] by auto 

 hence "affine_parallel (affine hull S) L" using assms by (simp add:1)

 from this show ?thesis using assms aff_dim_parallel_subspace[of S L] by blast 

 qed

 lemma dim_affine_hull:

 fixes S :: "('n::euclidean_space) set"

 shows "dim (affine hull S)=dim S"

 proof-

 have "dim (affine hull S)>=dim S" using dim_subset by auto

 moreover have "dim(span S) >= dim (affine hull S)" using dim_subset affine_hull_subset_span by auto

 moreover have "dim(span S)=dim S" using dim_span by auto

 ultimately show ?thesis by auto

 qed

 lemma aff_dim_subspace:

 fixes S :: "('n::euclidean_space) set"

 assumes "S ~= {}" "subspace S"

 shows "aff_dim S=int(dim S)" using aff_dim_affine[of S S] assms subspace_imp_affine[of S] affine_parallel_reflex[of S] by auto 

 lemma aff_dim_zero:

 fixes S :: "('n::euclidean_space) set"

 assumes "0 : affine hull S"

 shows "aff_dim S=int(dim S)"

 proof-

 have "subspace(affine hull S)" using subspace_affine[of "affine hull S"] affine_affine_hull assms by auto

 hence "aff_dim (affine hull S) =int(dim (affine hull S))" using assms aff_dim_subspace[of "affine hull S"] by auto  

 from this show ?thesis using aff_dim_affine_hull[of S] dim_affine_hull[of S] by auto

 qed

 lemma aff_dim_univ: "aff_dim (UNIV :: ('n::euclidean_space) set) = int(DIM('n))"

   using aff_dim_subspace[of "(UNIV :: ('n::euclidean_space) set)"]

     dim_UNIV[where 'a="'n::euclidean_space"] by auto

 lemma aff_dim_geq:

   fixes V :: "('n::euclidean_space) set"

   shows "aff_dim V >= -1"

 proof-

 obtain B where B_def: "affine hull B = affine hull V & ~ affine_dependent B & int (card B) = aff_dim V + 1" using aff_dim_basis_exists by auto

 from this show ?thesis by auto

 qed

 lemma independent_card_le_aff_dim: 

   assumes "(B::('n::euclidean_space) set) <= V"

   assumes "~(affine_dependent B)" 

   shows "int(card B) <= aff_dim V+1"

 proof-

 { assume "B~={}" 

   from this obtain T where T_def: "~(affine_dependent T) & B<=T & T<=V & affine hull T = affine hull V" 

   using assms extend_to_affine_basis[of B V] by auto

   hence "of_nat(card T) = aff_dim V+1" using aff_dim_unique by auto

   hence ?thesis using T_def card_mono[of T B] aff_independent_finite[of T] by auto

 }

 moreover

 { assume "B={}"

   moreover have "-1<= aff_dim V" using aff_dim_geq by auto

   ultimately have ?thesis by auto

 }  ultimately show ?thesis by blast

 qed

 lemma aff_dim_subset:

   fixes S T :: "('n::euclidean_space) set"

   assumes "S <= T"

   shows "aff_dim S <= aff_dim T"

 proof-

 obtain B where B_def: "~(affine_dependent B) & B<=S & (affine hull B=affine hull S) & of_nat(card B) = aff_dim S+1" using aff_dim_inner_basis_exists[of S] by auto

 moreover hence "int (card B) <= aff_dim T + 1" using assms independent_card_le_aff_dim[of B T] by auto

 ultimately show ?thesis by auto

 qed

 lemma aff_dim_subset_univ:

 fixes S :: "('n::euclidean_space) set"

 shows "aff_dim S <= int(DIM('n))"

 proof - 

   have "aff_dim (UNIV :: ('n::euclidean_space) set) = int(DIM('n))" using aff_dim_univ by auto

   from this show "aff_dim (S:: ('n::euclidean_space) set) <= int(DIM('n))" using assms aff_dim_subset[of S "(UNIV :: ('n::euclidean_space) set)"] subset_UNIV by auto

 qed

 lemma affine_dim_equal:

 assumes "affine (S :: ('n::euclidean_space) set)" "affine T" "S ~= {}" "S <= T" "aff_dim S = aff_dim T"

 shows "S=T"

 proof-

 obtain a where "a : S" using assms by auto 

 hence "a : T" using assms by auto

 def LS == "{y. ? x : S. (-a)+x=y}"

 hence ls: "subspace LS & affine_parallel S LS" using assms parallel_subspace_explicit[of S a LS] `a : S` by auto 

 hence h1: "int(dim LS) = aff_dim S" using assms aff_dim_affine[of S LS] by auto

 have "T ~= {}" using assms by auto

 def LT == "{y. ? x : T. (-a)+x=y}" 

 hence lt: "subspace LT & affine_parallel T LT" using assms parallel_subspace_explicit[of T a LT] `a : T` by auto

 hence "int(dim LT) = aff_dim T" using assms aff_dim_affine[of T LT] `T ~= {}` by auto 

 hence "dim LS = dim LT" using h1 assms by auto

 moreover have "LS <= LT" using LS_def LT_def assms by auto

 ultimately have "LS=LT" using subspace_dim_equal[of LS LT] ls lt by auto

 moreover have "S = {x. ? y : LS. a+y=x}" using LS_def by auto 

 moreover have "T = {x. ? y : LT. a+y=x}" using LT_def by auto

 ultimately show ?thesis by auto 

 qed

 lemma affine_hull_univ:

 fixes S :: "('n::euclidean_space) set"

 assumes "aff_dim S = int(DIM('n))"

 shows "affine hull S = (UNIV :: ('n::euclidean_space) set)"

 proof-

 have "S ~= {}" using assms aff_dim_empty[of S] by auto

 have h0: "S <= affine hull S" using hull_subset[of S _] by auto

 have h1: "aff_dim (UNIV :: ('n::euclidean_space) set) = aff_dim S" using aff_dim_univ assms by auto

 hence h2: "aff_dim (affine hull S) <= aff_dim (UNIV :: ('n::euclidean_space) set)" using aff_dim_subset_univ[of "affine hull S"] assms h0 by auto  

 have h3: "aff_dim S <= aff_dim (affine hull S)" using h0 aff_dim_subset[of S "affine hull S"] assms by auto

 hence h4: "aff_dim (affine hull S) = aff_dim (UNIV :: ('n::euclidean_space) set)" using h0 h1 h2 by auto

 from this show ?thesis using affine_dim_equal[of "affine hull S" "(UNIV :: ('n::euclidean_space) set)"] affine_affine_hull[of S] affine_UNIV assms h4 h0 `S ~= {}` by auto

 qed

 lemma aff_dim_convex_hull:

 fixes S :: "('n::euclidean_space) set"

 shows "aff_dim (convex hull S)=aff_dim S"

   using aff_dim_affine_hull[of S] convex_hull_subset_affine_hull[of S] 

   hull_subset[of S "convex"] aff_dim_subset[of S "convex hull S"] 

   aff_dim_subset[of "convex hull S" "affine hull S"] by auto

 lemma aff_dim_cball:

 fixes a :: "'n::euclidean_space" 

 assumes "0<e"

 shows "aff_dim (cball a e) = int (DIM('n))"

 proof-

 have "(%x. a + x) ` (cball 0 e)<=cball a e" unfolding cball_def dist_norm by auto

 hence "aff_dim (cball (0 :: 'n::euclidean_space) e) <= aff_dim (cball a e)"

   using aff_dim_translation_eq[of a "cball 0 e"] 

         aff_dim_subset[of "op + a ` cball 0 e" "cball a e"] by auto

 moreover have "aff_dim (cball (0 :: 'n::euclidean_space) e) = int (DIM('n))" 

    using hull_inc[of "(0 :: 'n::euclidean_space)" "cball 0 e"] centre_in_cball[of "(0 :: 'n::euclidean_space)"] assms 

    by (simp add: dim_cball[of e] aff_dim_zero[of "cball 0 e"])

 ultimately show ?thesis using aff_dim_subset_univ[of "cball a e"] by auto 

 qed

 lemma aff_dim_open:

 fixes S :: "('n::euclidean_space) set"

 assumes "open S" "S ~= {}"

 shows "aff_dim S = int (DIM('n))"

 proof-

 obtain x where "x:S" using assms by auto

 from this obtain e where e_def: "e>0 & cball x e <= S" using open_contains_cball[of S] assms by auto

 from this have "aff_dim (cball x e) <= aff_dim S" using aff_dim_subset by auto

 from this show ?thesis using aff_dim_cball[of e x] aff_dim_subset_univ[of S] e_def by auto     

 qed

 lemma low_dim_interior:

 fixes S :: "('n::euclidean_space) set"

 assumes "~(aff_dim S = int (DIM('n)))"

 shows "interior S = {}"

 proof-

 have "aff_dim(interior S) <= aff_dim S" 

    using interior_subset aff_dim_subset[of "interior S" S] by auto 

 from this show ?thesis using aff_dim_open[of "interior S"] aff_dim_subset_univ[of S] assms by auto   

 qed

 subsection {* Relative interior of a set *}

 definition "rel_interior S = {x. ? T. openin (subtopology euclidean (affine hull S)) T & x : T & T <= S}"

 lemma rel_interior: "rel_interior S = {x : S. ? T. open T & x : T & (T Int (affine hull S)) <= S}"

   unfolding rel_interior_def[of S] openin_open[of "affine hull S"] apply auto

 proof-

 fix x T assume a: "x:S" "open T" "x : T" "(T Int (affine hull S)) <= S"

 hence h1: "x : T Int affine hull S" using hull_inc by auto

 show "EX Tb. (EX Ta. open Ta & Tb = affine hull S Int Ta) & x : Tb & Tb <= S"

 apply (rule_tac x="T Int (affine hull S)" in exI)

 using a h1 by auto

 qed

 lemma mem_rel_interior: 

      "x : rel_interior S <-> (? T. open T & x : (T Int S) & (T Int (affine hull S)) <= S)" 

      by (auto simp add: rel_interior)

 lemma mem_rel_interior_ball: "x : rel_interior S <-> x : S & (? e. 0 < e & ((ball x e) Int (affine hull S)) <= S)"

   apply (simp add: rel_interior, safe)

   apply (force simp add: open_contains_ball)

   apply (rule_tac x="ball x e" in exI)

   apply simp

   done

 lemma rel_interior_ball: 

       "rel_interior S = {x : S. ? e. e>0 & ((ball x e) Int (affine hull S)) <= S}" 

       using mem_rel_interior_ball [of _ S] by auto 

 lemma mem_rel_interior_cball: "x : rel_interior S <-> x : S & (? e. 0 < e & ((cball x e) Int (affine hull S)) <= S)"

   apply (simp add: rel_interior, safe) 

   apply (force simp add: open_contains_cball)

   apply (rule_tac x="ball x e" in exI)

   apply (simp add: subset_trans [OF ball_subset_cball])

   apply auto

   done

 lemma rel_interior_cball: "rel_interior S = {x : S. ? e. e>0 & ((cball x e) Int (affine hull S)) <= S}"       using mem_rel_interior_cball [of _ S] by auto

 lemma rel_interior_empty: "rel_interior {} = {}" 

    by (auto simp add: rel_interior_def) 

 lemma affine_hull_sing: "affine hull {a :: 'n::euclidean_space} = {a}"

 by (metis affine_hull_eq affine_sing)

 lemma rel_interior_sing: "rel_interior {a :: 'n::euclidean_space} = {a}"

    unfolding rel_interior_ball affine_hull_sing apply auto

    apply(rule_tac x="1 :: real" in exI) apply simp

    done

 lemma subset_rel_interior:

 fixes S T :: "('n::euclidean_space) set"

 assumes "S<=T" "affine hull S=affine hull T"

 shows "rel_interior S <= rel_interior T"

   using assms by (auto simp add: rel_interior_def)  

 lemma rel_interior_subset: "rel_interior S <= S" 

    by (auto simp add: rel_interior_def)

 lemma rel_interior_subset_closure: "rel_interior S <= closure S" 

    using rel_interior_subset by (auto simp add: closure_def) 

 lemma interior_subset_rel_interior: "interior S <= rel_interior S" 

    by (auto simp add: rel_interior interior_def)

 lemma interior_rel_interior:

 fixes S :: "('n::euclidean_space) set"

 assumes "aff_dim S = int(DIM('n))"

 shows "rel_interior S = interior S"

 proof -

 have "affine hull S = UNIV" using assms affine_hull_univ[of S] by auto 

 from this show ?thesis unfolding rel_interior interior_def by auto

 qed

 lemma rel_interior_open:

 fixes S :: "('n::euclidean_space) set"

 assumes "open S"

 shows "rel_interior S = S"

 by (metis assms interior_eq interior_subset_rel_interior rel_interior_subset set_eq_subset)

 lemma interior_rel_interior_gen:

 fixes S :: "('n::euclidean_space) set"

 shows "interior S = (if aff_dim S = int(DIM('n)) then rel_interior S else {})"

 by (metis interior_rel_interior low_dim_interior)

 lemma rel_interior_univ: 

 fixes S :: "('n::euclidean_space) set"

 shows "rel_interior (affine hull S) = affine hull S"

 proof-

 have h1: "rel_interior (affine hull S) <= affine hull S" using rel_interior_subset by auto 

 { fix x assume x_def: "x : affine hull S"

   obtain e :: real where "e=1" by auto

   hence "e>0 & ball x e Int affine hull (affine hull S) <= affine hull S" using hull_hull[of _ S] by auto

   hence "x : rel_interior (affine hull S)" using x_def rel_interior_ball[of "affine hull S"] by auto

 } from this show ?thesis using h1 by auto 

 qed

 lemma rel_interior_univ2: "rel_interior (UNIV :: ('n::euclidean_space) set) = UNIV"

 by (metis open_UNIV rel_interior_open)

 lemma rel_interior_convex_shrink:

   fixes S :: "('a::euclidean_space) set"

   assumes "convex S" "c : rel_interior S" "x : S" "0 < e" "e <= 1"

   shows "x - e *\<^sub>R (x - c) : rel_interior S"

 proof- 

 (* Proof is a modified copy of the proof of similar lemma mem_interior_convex_shrink 

 *)

 obtain d where "d>0" and d:"ball c d Int affine hull S <= S" 

   using assms(2) unfolding  mem_rel_interior_ball by auto

 {   fix y assume as:"dist (x - e *\<^sub>R (x - c)) y < e * d & y : affine hull S"

     have *:"y = (1 - (1 - e)) *\<^sub>R ((1 / e) *\<^sub>R y - ((1 - e) / e) *\<^sub>R x) + (1 - e) *\<^sub>R x" using `e>0` by (auto simp add: scaleR_left_diff_distrib scaleR_right_diff_distrib)

     have "x : affine hull S" using assms hull_subset[of S] by auto

     moreover have "1 / e + - ((1 - e) / e) = 1" 

        using `e>0` left_diff_distrib[of "1" "(1-e)" "1/e"] by auto

     ultimately have **: "(1 / e) *\<^sub>R y - ((1 - e) / e) *\<^sub>R x : affine hull S"

         using as affine_affine_hull[of S] mem_affine[of "affine hull S" y x "(1 / e)" "-((1 - e) / e)"] by (simp add: algebra_simps)     

     have "dist c ((1 / e) *\<^sub>R y - ((1 - e) / e) *\<^sub>R x) = abs(1/e) * norm (e *\<^sub>R c - y + (1 - e) *\<^sub>R x)"

       unfolding dist_norm unfolding norm_scaleR[THEN sym] apply(rule arg_cong[where f=norm]) using `e>0`

       by(auto simp add:euclidean_eq[where 'a='a] field_simps) 

     also have "... = abs(1/e) * norm (x - e *\<^sub>R (x - c) - y)" by(auto intro!:arg_cong[where f=norm] simp add: algebra_simps)

     also have "... < d" using as[unfolded dist_norm] and `e>0`

       by(auto simp add:pos_divide_less_eq[OF `e>0`] mult_commute)

     finally have "y : S" apply(subst *) 

 apply(rule assms(1)[unfolded convex_alt,rule_format])

       apply(rule d[unfolded subset_eq,rule_format]) unfolding mem_ball using assms(3-5) ** by auto

 } hence "ball (x - e *\<^sub>R (x - c)) (e*d) Int affine hull S <= S" by auto

 moreover have "0 < e*d" using `0<e` `0<d` by (rule mult_pos_pos)

 moreover have "c : S" using assms rel_interior_subset by auto

 moreover hence "x - e *\<^sub>R (x - c) : S"

    using mem_convex[of S x c e] apply (simp add: algebra_simps) using assms by auto

 ultimately show ?thesis 

   using mem_rel_interior_ball[of "x - e *\<^sub>R (x - c)" S] `e>0` by auto

 qed

 lemma interior_real_semiline:

 fixes a :: real

 shows "interior {a..} = {a<..}"

 proof-

 { fix y assume "a<y" hence "y : interior {a..}"

   apply (simp add: mem_interior) apply (rule_tac x="(y-a)" in exI) apply (auto simp add: dist_norm) 

   done }

 moreover

 { fix y assume "y : interior {a..}" (*hence "a<=y" using interior_subset by auto*)

   from this obtain e where e_def: "e>0 & cball y e \<subseteq> {a..}" 

      using mem_interior_cball[of y "{a..}"] by auto

   moreover hence "y-e : cball y e" by (auto simp add: cball_def dist_norm) 

   ultimately have "a<=y-e" by auto

   hence "a<y" using e_def by auto

 } ultimately show ?thesis by auto

 qed

 lemma rel_interior_real_interval:

   fixes a b :: real assumes "a < b" shows "rel_interior {a..b} = {a<..<b}"

 proof-

   have "{a<..<b} \<noteq> {}" using assms unfolding set_eq_iff by (auto intro!: exI[of _ "(a + b) / 2"])

   then show ?thesis

     using interior_rel_interior_gen[of "{a..b}", symmetric]

     by (simp split: split_if_asm add: interior_closed_interval)

 qed

 lemma rel_interior_real_semiline:

   fixes a :: real shows "rel_interior {a..} = {a<..}"

 proof-

   have *: "{a<..} \<noteq> {}" unfolding set_eq_iff by (auto intro!: exI[of _ "a + 1"])

   then show ?thesis using interior_real_semiline

      interior_rel_interior_gen[of "{a..}"]

      by (auto split: split_if_asm)

 qed

 subsubsection {* Relative open sets *}

 definition "rel_open S <-> (rel_interior S) = S"

 lemma rel_open: "rel_open S <-> openin (subtopology euclidean (affine hull S)) S"

  unfolding rel_open_def rel_interior_def apply auto

  using openin_subopen[of "subtopology euclidean (affine hull S)" S] by auto

 lemma opein_rel_interior: 

   "openin (subtopology euclidean (affine hull S)) (rel_interior S)"

   apply (simp add: rel_interior_def)

   apply (subst openin_subopen) by blast

 lemma affine_rel_open: 

   fixes S :: "('n::euclidean_space) set"

   assumes "affine S" shows "rel_open S" 

   unfolding rel_open_def using assms rel_interior_univ[of S] affine_hull_eq[of S] by metis

 lemma affine_closed: 

   fixes S :: "('n::euclidean_space) set"

   assumes "affine S" shows "closed S"

 proof-

 { assume "S ~= {}"

   from this obtain L where L_def: "subspace L & affine_parallel S L"

      using assms affine_parallel_subspace[of S] by auto

   from this obtain "a" where a_def: "S=(op + a ` L)" 

      using affine_parallel_def[of L S] affine_parallel_commut by auto 

   have "closed L" using L_def closed_subspace by auto

   hence "closed S" using closed_translation a_def by auto

 } from this show ?thesis by auto

 qed

 lemma closure_affine_hull:

   fixes S :: "('n::euclidean_space) set"

   shows "closure S <= affine hull S"

   by (intro closure_minimal hull_subset affine_closed affine_affine_hull)

 lemma closure_same_affine_hull:

   fixes S :: "('n::euclidean_space) set"

   shows "affine hull (closure S) = affine hull S"

 proof-

 have "affine hull (closure S) <= affine hull S"

    using hull_mono[of "closure S" "affine hull S" "affine"] closure_affine_hull[of S] hull_hull[of "affine" S] by auto

 moreover have "affine hull (closure S) >= affine hull S"  

    using hull_mono[of "S" "closure S" "affine"] closure_subset by auto

 ultimately show ?thesis by auto  

 qed

 lemma closure_aff_dim: 

   fixes S :: "('n::euclidean_space) set"

   shows "aff_dim (closure S) = aff_dim S"

 proof-

 have "aff_dim S <= aff_dim (closure S)" using aff_dim_subset closure_subset by auto

 moreover have "aff_dim (closure S) <= aff_dim (affine hull S)" 

   using aff_dim_subset closure_affine_hull by auto

 moreover have "aff_dim (affine hull S) = aff_dim S" using aff_dim_affine_hull by auto

 ultimately show ?thesis by auto

 qed

 lemma rel_interior_closure_convex_shrink:

   fixes S :: "(_::euclidean_space) set"

   assumes "convex S" "c : rel_interior S" "x : closure S" "0 < e" "e <= 1"

   shows "x - e *\<^sub>R (x - c) : rel_interior S"

 proof- 

 (* Proof is a modified copy of the proof of similar lemma mem_interior_closure_convex_shrink

 *)

 obtain d where "d>0" and d:"ball c d Int affine hull S <= S" 

   using assms(2) unfolding mem_rel_interior_ball by auto

 have "EX y : S. norm (y - x) * (1 - e) < e * d" proof(cases "x : S")

     case True thus ?thesis using `e>0` `d>0` by(rule_tac bexI[where x=x], auto intro!: mult_pos_pos) next

     case False hence x:"x islimpt S" using assms(3)[unfolded closure_def] by auto

     show ?thesis proof(cases "e=1")

       case True obtain y where "y : S" "y ~= x" "dist y x < 1"

         using x[unfolded islimpt_approachable,THEN spec[where x=1]] by auto

       thus ?thesis apply(rule_tac x=y in bexI) unfolding True using `d>0` by auto next

       case False hence "0 < e * d / (1 - e)" and *:"1 - e > 0"

         using `e<=1` `e>0` `d>0` by(auto intro!:mult_pos_pos divide_pos_pos)

       then obtain y where "y : S" "y ~= x" "dist y x < e * d / (1 - e)"

         using x[unfolded islimpt_approachable,THEN spec[where x="e*d / (1 - e)"]] by auto

       thus ?thesis apply(rule_tac x=y in bexI) unfolding dist_norm using pos_less_divide_eq[OF *] by auto qed qed

   then obtain y where "y : S" and y:"norm (y - x) * (1 - e) < e * d" by auto

   def z == "c + ((1 - e) / e) *\<^sub>R (x - y)"

   have *:"x - e *\<^sub>R (x - c) = y - e *\<^sub>R (y - z)" unfolding z_def using `e>0` by (auto simp add: scaleR_right_diff_distrib scaleR_right_distrib scaleR_left_diff_distrib)

   have zball: "z\<in>ball c d"

     using mem_ball z_def dist_norm[of c] using y and assms(4,5) by (auto simp add:field_simps norm_minus_commute)

   have "x : affine hull S" using closure_affine_hull assms by auto

   moreover have "y : affine hull S" using `y : S` hull_subset[of S] by auto

   moreover have "c : affine hull S" using assms rel_interior_subset hull_subset[of S] by auto

   ultimately have "z : affine hull S" 

     using z_def affine_affine_hull[of S] 

           mem_affine_3_minus [of "affine hull S" c x y "(1 - e) / e"] 

           assms by (auto simp add: field_simps)

   hence "z : S" using d zball by auto

   obtain d1 where "d1>0" and d1:"ball z d1 <= ball c d"

     using zball open_ball[of c d] openE[of "ball c d" z] by auto

   hence "(ball z d1) Int (affine hull S) <= (ball c d) Int (affine hull S)" by auto

   hence "(ball z d1) Int (affine hull S) <= S" using d by auto 

   hence "z : rel_interior S" using mem_rel_interior_ball using `d1>0` `z : S` by auto

   hence "y - e *\<^sub>R (y - z) : rel_interior S" using rel_interior_convex_shrink[of S z y e] assms`y : S` by auto

   thus ?thesis using * by auto 

 qed

 subsubsection{* Relative interior preserves under linear transformations *}

 lemma rel_interior_translation_aux:

 fixes a :: "'n::euclidean_space"

 shows "((%x. a + x) ` rel_interior S) <= rel_interior ((%x. a + x) ` S)"

 proof-

 { fix x assume x_def: "x : rel_interior S"

   from this obtain T where T_def: "open T & x : (T Int S) & (T Int (affine hull S)) <= S" using mem_rel_interior[of x S] by auto 

   from this have "open ((%x. a + x) ` T)" and 

     "(a + x) : (((%x. a + x) ` T) Int ((%x. a + x) ` S))" and 

     "(((%x. a + x) ` T) Int (affine hull ((%x. a + x) ` S))) <= ((%x. a + x) ` S)" 

     using affine_hull_translation[of a S] open_translation[of T a] x_def by auto 

   from this have "(a+x) : rel_interior ((%x. a + x) ` S)" 

     using mem_rel_interior[of "a+x" "((%x. a + x) ` S)"] by auto 

 } from this show ?thesis by auto 

 qed

 lemma rel_interior_translation:

 fixes a :: "'n::euclidean_space"

 shows "rel_interior ((%x. a + x) ` S) = ((%x. a + x) ` rel_interior S)"

 proof-

 have "(%x. (-a) + x) ` rel_interior ((%x. a + x) ` S) <= rel_interior S" 

    using rel_interior_translation_aux[of "-a" "(%x. a + x) ` S"] 

          translation_assoc[of "-a" "a"] by auto

 hence "((%x. a + x) ` rel_interior S) >= rel_interior ((%x. a + x) ` S)" 

    using translation_inverse_subset[of a "rel_interior (op + a ` S)" "rel_interior S"] 

    by auto

 from this show ?thesis using  rel_interior_translation_aux[of a S] by auto 

 qed

 lemma affine_hull_linear_image:

 assumes "bounded_linear f"

 shows "f ` (affine hull s) = affine hull f ` s"

 (* Proof is a modified copy of the proof of similar lemma convex_hull_linear_image

 *)

   apply rule unfolding subset_eq ball_simps apply(rule_tac[!] hull_induct, rule hull_inc) prefer 3  

   apply(erule imageE)apply(rule_tac x=xa in image_eqI) apply assumption

   apply(rule hull_subset[unfolded subset_eq, rule_format]) apply assumption

 proof-

   interpret f: bounded_linear f by fact

   show "affine {x. f x : affine hull f ` s}" 

   unfolding affine_def by(auto simp add: f.scaleR f.add affine_affine_hull[unfolded affine_def, rule_format]) next

   interpret f: bounded_linear f by fact

   show "affine {x. x : f ` (affine hull s)}" using affine_affine_hull[unfolded affine_def, of s] 

     unfolding affine_def by (auto simp add: f.scaleR [symmetric] f.add [symmetric])

 qed auto

 lemma rel_interior_injective_on_span_linear_image:

 fixes f :: "('m::euclidean_space) => ('n::euclidean_space)"

 fixes S :: "('m::euclidean_space) set"

 assumes "bounded_linear f" and "inj_on f (span S)"

 shows "rel_interior (f ` S) = f ` (rel_interior S)"

 proof-

 { fix z assume z_def: "z : rel_interior (f ` S)"

   have "z : f ` S" using z_def rel_interior_subset[of "f ` S"] by auto

   from this obtain x where x_def: "x : S & (f x = z)" by auto

   obtain e2 where e2_def: "e2>0 & cball z e2 Int affine hull (f ` S) <= (f ` S)" 

     using z_def rel_interior_cball[of "f ` S"] by auto

   obtain K where K_def: "K>0 & (! x. norm (f x) <= norm x * K)" 

    using assms RealVector.bounded_linear.pos_bounded[of f] by auto

   def e1 == "1/K" hence e1_def: "e1>0 & (! x. e1 * norm (f x) <= norm x)" 

    using K_def pos_le_divide_eq[of e1] by auto

   def e == "e1 * e2" hence "e>0" using e1_def e2_def mult_pos_pos by auto 

   { fix y assume y_def: "y : cball x e Int affine hull S"

     from this have h1: "f y : affine hull (f ` S)" 

       using affine_hull_linear_image[of f S] assms by auto 

     from y_def have "norm (x-y)<=e1 * e2" 

       using cball_def[of x e] dist_norm[of x y] e_def by auto

     moreover have "(f x)-(f y)=f (x-y)"

        using assms linear_sub[of f x y] linear_conv_bounded_linear[of f] by auto

     moreover have "e1 * norm (f (x-y)) <= norm (x-y)" using e1_def by auto

     ultimately have "e1 * norm ((f x)-(f y)) <= e1 * e2" by auto

     hence "(f y) : (cball z e2)" 

       using cball_def[of "f x" e2] dist_norm[of "f x" "f y"] e1_def x_def by auto

     hence "f y : (f ` S)" using y_def e2_def h1 by auto

     hence "y : S" using assms y_def hull_subset[of S] affine_hull_subset_span 

          inj_on_image_mem_iff[of f "span S" S y] by auto

   } 

   hence "z : f ` (rel_interior S)" using mem_rel_interior_cball[of x S] `e>0` x_def by auto

 } 

 moreover

 { fix x assume x_def: "x : rel_interior S"

   from this obtain e2 where e2_def: "e2>0 & cball x e2 Int affine hull S <= S" 

     using rel_interior_cball[of S] by auto

   have "x : S" using x_def rel_interior_subset by auto

   hence *: "f x : f ` S" by auto

   have "! x:span S. f x = 0 --> x = 0" 

     using assms subspace_span linear_conv_bounded_linear[of f] 

           linear_injective_on_subspace_0[of f "span S"] by auto

   from this obtain e1 where e1_def: "e1>0 & (! x : span S. e1 * norm x <= norm (f x))" 

    using assms injective_imp_isometric[of "span S" f] 

          subspace_span[of S] closed_subspace[of "span S"] by auto

   def e == "e1 * e2" hence "e>0" using e1_def e2_def mult_pos_pos by auto 

   { fix y assume y_def: "y : cball (f x) e Int affine hull (f ` S)"

     from this have "y : f ` (affine hull S)" using affine_hull_linear_image[of f S] assms by auto 

     from this obtain xy where xy_def: "xy : affine hull S & (f xy = y)" by auto

     from this y_def have "norm ((f x)-(f xy))<=e1 * e2" 

       using cball_def[of "f x" e] dist_norm[of "f x" y] e_def by auto

     moreover have "(f x)-(f xy)=f (x-xy)"

        using assms linear_sub[of f x xy] linear_conv_bounded_linear[of f] by auto

     moreover have "x-xy : span S" 

        using subspace_sub[of "span S" x xy] subspace_span `x : S` xy_def 

              affine_hull_subset_span[of S] span_inc by auto

     moreover hence "e1 * norm (x-xy) <= norm (f (x-xy))" using e1_def by auto

     ultimately have "e1 * norm (x-xy) <= e1 * e2" by auto

     hence "xy : (cball x e2)"  using cball_def[of x e2] dist_norm[of x xy] e1_def by auto

     hence "y : (f ` S)" using xy_def e2_def by auto

   } 

   hence "(f x) : rel_interior (f ` S)" 

      using mem_rel_interior_cball[of "(f x)" "(f ` S)"] * `e>0` by auto

 } 

 ultimately show ?thesis by auto

 qed

 lemma rel_interior_injective_linear_image:

 fixes f :: "('m::euclidean_space) => ('n::euclidean_space)"

 assumes "bounded_linear f" and "inj f"

 shows "rel_interior (f ` S) = f ` (rel_interior S)"

 using assms rel_interior_injective_on_span_linear_image[of f S] 

       subset_inj_on[of f "UNIV" "span S"] by auto

 subsection{* Some Properties of subset of standard basis *}

 lemma affine_hull_substd_basis: assumes "d\<subseteq>{..<DIM('a::euclidean_space)}"

   shows "affine hull (insert 0 {basis i | i. i : d}) =

   {x::'a::euclidean_space. (!i<DIM('a). i ~: d --> x$$i = 0)}"

  (is "affine hull (insert 0 ?A) = ?B")

 proof- have *:"\<And>A. op + (0\<Colon>'a) ` A = A" "\<And>A. op + (- (0\<Colon>'a)) ` A = A" by auto

   show ?thesis unfolding affine_hull_insert_span_gen span_substd_basis[OF assms,THEN sym] * ..

 qed

 lemma affine_hull_convex_hull: "affine hull (convex hull S) = affine hull S"

 by (metis Int_absorb1 Int_absorb2 convex_hull_subset_affine_hull hull_hull hull_mono hull_subset)

 subsection {* Openness and compactness are preserved by convex hull operation. *}

 lemma open_convex_hull[intro]:

   fixes s :: "'a::real_normed_vector set"

   assumes "open s"

   shows "open(convex hull s)"

   unfolding open_contains_cball convex_hull_explicit unfolding mem_Collect_eq ball_simps(8)

 proof(rule, rule) fix a

   assume "\<exists>sa u. finite sa \<and> sa \<subseteq> s \<and> (\<forall>x\<in>sa. 0 \<le> u x) \<and> setsum u sa = 1 \<and> (\<Sum>v\<in>sa. u v *\<^sub>R v) = a"

   then obtain t u where obt:"finite t" "t\<subseteq>s" "\<forall>x\<in>t. 0 \<le> u x" "setsum u t = 1" "(\<Sum>v\<in>t. u v *\<^sub>R v) = a" by auto

   from assms[unfolded open_contains_cball] obtain b where b:"\<forall>x\<in>s. 0 < b x \<and> cball x (b x) \<subseteq> s"

     using bchoice[of s "\<lambda>x e. e>0 \<and> cball x e \<subseteq> s"] by auto

   have "b ` t\<noteq>{}" unfolding i_def using obt by auto  def i \<equiv> "b ` t"

   show "\<exists>e>0. cball a e \<subseteq> {y. \<exists>sa u. finite sa \<and> sa \<subseteq> s \<and> (\<forall>x\<in>sa. 0 \<le> u x) \<and> setsum u sa = 1 \<and> (\<Sum>v\<in>sa. u v *\<^sub>R v) = y}"

     apply(rule_tac x="Min i" in exI) unfolding subset_eq apply rule defer apply rule unfolding mem_Collect_eq

   proof-

     show "0 < Min i" unfolding i_def and Min_gr_iff[OF finite_imageI[OF obt(1)] `b \` t\<noteq>{}`]

       using b apply simp apply rule apply(erule_tac x=x in ballE) using `t\<subseteq>s` by auto

   next  fix y assume "y \<in> cball a (Min i)"

     hence y:"norm (a - y) \<le> Min i" unfolding dist_norm[THEN sym] by auto

     { fix x assume "x\<in>t"

       hence "Min i \<le> b x" unfolding i_def apply(rule_tac Min_le) using obt(1) by auto

       hence "x + (y - a) \<in> cball x (b x)" using y unfolding mem_cball dist_norm by auto

       moreover from `x\<in>t` have "x\<in>s" using obt(2) by auto

       ultimately have "x + (y - a) \<in> s" using y and b[THEN bspec[where x=x]] unfolding subset_eq by fast }

     moreover

     have *:"inj_on (\<lambda>v. v + (y - a)) t" unfolding inj_on_def by auto

     have "(\<Sum>v\<in>(\<lambda>v. v + (y - a)) ` t. u (v - (y - a))) = 1"

       unfolding setsum_reindex[OF *] o_def using obt(4) by auto

     moreover have "(\<Sum>v\<in>(\<lambda>v. v + (y - a)) ` t. u (v - (y - a)) *\<^sub>R v) = y"

       unfolding setsum_reindex[OF *] o_def using obt(4,5)

       by (simp add: setsum_addf setsum_subtractf scaleR_left.setsum[THEN sym] scaleR_right_distrib)

     ultimately show "\<exists>sa u. finite sa \<and> (\<forall>x\<in>sa. x \<in> s) \<and> (\<forall>x\<in>sa. 0 \<le> u x) \<and> setsum u sa = 1 \<and> (\<Sum>v\<in>sa. u v *\<^sub>R v) = y"

       apply(rule_tac x="(\<lambda>v. v + (y - a)) ` t" in exI) apply(rule_tac x="\<lambda>v. u (v - (y - a))" in exI)

       using obt(1, 3) by auto

   qed

 qed

 lemma compact_convex_combinations:

   fixes s t :: "'a::real_normed_vector set"

   assumes "compact s" "compact t"

   shows "compact { (1 - u) *\<^sub>R x + u *\<^sub>R y | x y u. 0 \<le> u \<and> u \<le> 1 \<and> x \<in> s \<and> y \<in> t}"

 proof-

   let ?X = "{0..1} \<times> s \<times> t"

   let ?h = "(\<lambda>z. (1 - fst z) *\<^sub>R fst (snd z) + fst z *\<^sub>R snd (snd z))"

   have *:"{ (1 - u) *\<^sub>R x + u *\<^sub>R y | x y u. 0 \<le> u \<and> u \<le> 1 \<and> x \<in> s \<and> y \<in> t} = ?h ` ?X"

     apply(rule set_eqI) unfolding image_iff mem_Collect_eq

     apply rule apply auto

     apply (rule_tac x=u in rev_bexI, simp)

     apply (erule rev_bexI, erule rev_bexI, simp)

     by auto

   have "continuous_on ({0..1} \<times> s \<times> t)

      (\<lambda>z. (1 - fst z) *\<^sub>R fst (snd z) + fst z *\<^sub>R snd (snd z))"

     unfolding continuous_on by (rule ballI) (intro tendsto_intros)

   thus ?thesis unfolding *

     apply (rule compact_continuous_image)

     apply (intro compact_Times compact_interval assms)

     done

 qed

 lemma finite_imp_compact_convex_hull:

   fixes s :: "('a::real_normed_vector) set"

   assumes "finite s" shows "compact (convex hull s)"

 proof (cases "s = {}")

   case True thus ?thesis by simp

 next

   case False with assms show ?thesis

   proof (induct rule: finite_ne_induct)

     case (singleton x) show ?case by simp

   next

     case (insert x A)

     let ?f = "\<lambda>(u, y::'a). u *\<^sub>R x + (1 - u) *\<^sub>R y"

     let ?T = "{0..1::real} \<times> (convex hull A)"

     have "continuous_on ?T ?f"

       unfolding split_def continuous_on by (intro ballI tendsto_intros)

     moreover have "compact ?T"

       by (intro compact_Times compact_interval insert)

     ultimately have "compact (?f ` ?T)"

       by (rule compact_continuous_image)

     also have "?f ` ?T = convex hull (insert x A)"

       unfolding convex_hull_insert [OF `A \<noteq> {}`]

       apply safe

       apply (rule_tac x=a in exI, simp)

       apply (rule_tac x="1 - a" in exI, simp)

       apply fast

       apply (rule_tac x="(u, b)" in image_eqI, simp_all)

       done

     finally show "compact (convex hull (insert x A))" .

   qed

 qed

 lemma compact_convex_hull: fixes s::"('a::euclidean_space) set"

   assumes "compact s"  shows "compact(convex hull s)"

 proof(cases "s={}")

   case True thus ?thesis using compact_empty by simp

 next

   case False then obtain w where "w\<in>s" by auto

   show ?thesis unfolding caratheodory[of s]

   proof(induct ("DIM('a) + 1"))

     have *:"{x.\<exists>sa. finite sa \<and> sa \<subseteq> s \<and> card sa \<le> 0 \<and> x \<in> convex hull sa} = {}" 

       using compact_empty by auto

     case 0 thus ?case unfolding * by simp

   next

     case (Suc n)

     show ?case proof(cases "n=0")

       case True have "{x. \<exists>t. finite t \<and> t \<subseteq> s \<and> card t \<le> Suc n \<and> x \<in> convex hull t} = s"

         unfolding set_eq_iff and mem_Collect_eq proof(rule, rule)

         fix x assume "\<exists>t. finite t \<and> t \<subseteq> s \<and> card t \<le> Suc n \<and> x \<in> convex hull t"

         then obtain t where t:"finite t" "t \<subseteq> s" "card t \<le> Suc n" "x \<in> convex hull t" by auto

         show "x\<in>s" proof(cases "card t = 0")

           case True thus ?thesis using t(4) unfolding card_0_eq[OF t(1)] by simp

         next

           case False hence "card t = Suc 0" using t(3) `n=0` by auto

           then obtain a where "t = {a}" unfolding card_Suc_eq by auto

           thus ?thesis using t(2,4) by simp

         qed

       next

         fix x assume "x\<in>s"

         thus "\<exists>t. finite t \<and> t \<subseteq> s \<and> card t \<le> Suc n \<and> x \<in> convex hull t"

           apply(rule_tac x="{x}" in exI) unfolding convex_hull_singleton by auto 

       qed thus ?thesis using assms by simp

     next

       case False have "{x. \<exists>t. finite t \<and> t \<subseteq> s \<and> card t \<le> Suc n \<and> x \<in> convex hull t} =

         { (1 - u) *\<^sub>R x + u *\<^sub>R y | x y u. 

         0 \<le> u \<and> u \<le> 1 \<and> x \<in> s \<and> y \<in> {x. \<exists>t. finite t \<and> t \<subseteq> s \<and> card t \<le> n \<and> x \<in> convex hull t}}"

         unfolding set_eq_iff and mem_Collect_eq proof(rule,rule)

         fix x assume "\<exists>u v c. x = (1 - c) *\<^sub>R u + c *\<^sub>R v \<and>

           0 \<le> c \<and> c \<le> 1 \<and> u \<in> s \<and> (\<exists>t. finite t \<and> t \<subseteq> s \<and> card t \<le> n \<and> v \<in> convex hull t)"

         then obtain u v c t where obt:"x = (1 - c) *\<^sub>R u + c *\<^sub>R v"

           "0 \<le> c \<and> c \<le> 1" "u \<in> s" "finite t" "t \<subseteq> s" "card t \<le> n"  "v \<in> convex hull t" by auto

         moreover have "(1 - c) *\<^sub>R u + c *\<^sub>R v \<in> convex hull insert u t"

           apply(rule mem_convex) using obt(2) and convex_convex_hull and hull_subset[of "insert u t" convex]

           using obt(7) and hull_mono[of t "insert u t"] by auto

         ultimately show "\<exists>t. finite t \<and> t \<subseteq> s \<and> card t \<le> Suc n \<and> x \<in> convex hull t"

           apply(rule_tac x="insert u t" in exI) by (auto simp add: card_insert_if)

       next