src/Pure/Isar/specification.ML
author wenzelm
Sun Apr 17 21:42:47 2011 +0200 (2011-04-17 ago)
changeset 42381 309ec68442c6
parent 42375 774df7c59508
child 42440 5e7a7343ab11
permissions -rw-r--r--
added Binding.print convenience, which includes quote already;
     1 (*  Title:      Pure/Isar/specification.ML
     2     Author:     Makarius
     3 
     4 Derived local theory specifications --- with type-inference and
     5 toplevel polymorphism.
     6 *)
     7 
     8 signature SPECIFICATION =
     9 sig
    10   val print_consts: local_theory -> (string * typ -> bool) -> (string * typ) list -> unit
    11   val check_spec:
    12     (binding * typ option * mixfix) list -> (Attrib.binding * term) list -> Proof.context ->
    13     (((binding * typ) * mixfix) list * (Attrib.binding * term) list) * Proof.context
    14   val read_spec:
    15     (binding * string option * mixfix) list -> (Attrib.binding * string) list -> Proof.context ->
    16     (((binding * typ) * mixfix) list * (Attrib.binding * term) list) * Proof.context
    17   val check_free_spec:
    18     (binding * typ option * mixfix) list -> (Attrib.binding * term) list -> Proof.context ->
    19     (((binding * typ) * mixfix) list * (Attrib.binding * term) list) * Proof.context
    20   val read_free_spec:
    21     (binding * string option * mixfix) list -> (Attrib.binding * string) list -> Proof.context ->
    22     (((binding * typ) * mixfix) list * (Attrib.binding * term) list) * Proof.context
    23   val check_specification: (binding * typ option * mixfix) list ->
    24     (Attrib.binding * term list) list -> Proof.context ->
    25     (((binding * typ) * mixfix) list * (Attrib.binding * term list) list) * Proof.context
    26   val read_specification: (binding * string option * mixfix) list ->
    27     (Attrib.binding * string list) list -> Proof.context ->
    28     (((binding * typ) * mixfix) list * (Attrib.binding * term list) list) * Proof.context
    29   val axiomatization: (binding * typ option * mixfix) list ->
    30     (Attrib.binding * term list) list -> theory ->
    31     (term list * thm list list) * theory
    32   val axiomatization_cmd: (binding * string option * mixfix) list ->
    33     (Attrib.binding * string list) list -> theory ->
    34     (term list * thm list list) * theory
    35   val axiom: Attrib.binding * term -> theory -> thm * theory
    36   val axiom_cmd: Attrib.binding * string -> theory -> thm * theory
    37   val definition:
    38     (binding * typ option * mixfix) option * (Attrib.binding * term) ->
    39     local_theory -> (term * (string * thm)) * local_theory
    40   val definition_cmd:
    41     (binding * string option * mixfix) option * (Attrib.binding * string) ->
    42     local_theory -> (term * (string * thm)) * local_theory
    43   val abbreviation: Syntax.mode -> (binding * typ option * mixfix) option * term ->
    44     local_theory -> local_theory
    45   val abbreviation_cmd: Syntax.mode -> (binding * string option * mixfix) option * string ->
    46     local_theory -> local_theory
    47   val type_notation: bool -> Syntax.mode -> (typ * mixfix) list -> local_theory -> local_theory
    48   val type_notation_cmd: bool -> Syntax.mode -> (string * mixfix) list -> local_theory -> local_theory
    49   val notation: bool -> Syntax.mode -> (term * mixfix) list -> local_theory -> local_theory
    50   val notation_cmd: bool -> Syntax.mode -> (string * mixfix) list -> local_theory -> local_theory
    51   val theorems: string ->
    52     (Attrib.binding * (thm list * Attrib.src list) list) list ->
    53     local_theory -> (string * thm list) list * local_theory
    54   val theorems_cmd: string ->
    55     (Attrib.binding * (Facts.ref * Attrib.src list) list) list ->
    56     local_theory -> (string * thm list) list * local_theory
    57   val theorem: string -> Method.text option ->
    58     (thm list list -> local_theory -> local_theory) -> Attrib.binding ->
    59     Element.context_i list -> Element.statement_i ->
    60     bool -> local_theory -> Proof.state
    61   val theorem_cmd: string -> Method.text option ->
    62     (thm list list -> local_theory -> local_theory) -> Attrib.binding ->
    63     Element.context list -> Element.statement ->
    64     bool -> local_theory -> Proof.state
    65   val schematic_theorem: string -> Method.text option ->
    66     (thm list list -> local_theory -> local_theory) -> Attrib.binding ->
    67     Element.context_i list -> Element.statement_i ->
    68     bool -> local_theory -> Proof.state
    69   val schematic_theorem_cmd: string -> Method.text option ->
    70     (thm list list -> local_theory -> local_theory) -> Attrib.binding ->
    71     Element.context list -> Element.statement ->
    72     bool -> local_theory -> Proof.state
    73   val add_theorem_hook: (bool -> Proof.state -> Proof.state) -> Context.generic -> Context.generic
    74 end;
    75 
    76 structure Specification: SPECIFICATION =
    77 struct
    78 
    79 (* diagnostics *)
    80 
    81 fun print_consts _ _ [] = ()
    82   | print_consts ctxt pred cs = Pretty.writeln (Proof_Display.pretty_consts ctxt pred cs);
    83 
    84 
    85 (* prepare specification *)
    86 
    87 local
    88 
    89 fun close_forms ctxt i xs As =
    90   let
    91     fun add_free (Free (x, _)) = if Variable.is_fixed ctxt x then I else insert (op =) x
    92       | add_free _ = I;
    93 
    94     val commons = map #1 xs;
    95     val _ =
    96       (case duplicates (op =) commons of [] => ()
    97       | dups => error ("Duplicate local variables " ^ commas_quote dups));
    98     val frees = rev ((fold o fold_aterms) add_free As (rev commons));
    99     val types = map (Type_Infer.param i o rpair []) (Name.invents Name.context Name.aT (length frees));
   100     val uniform_typing = the o AList.lookup (op =) (frees ~~ types);
   101 
   102     fun abs_body lev y (Abs (x, T, b)) = Abs (x, T, abs_body (lev + 1) y b)
   103       | abs_body lev y (t $ u) = abs_body lev y t $ abs_body lev y u
   104       | abs_body lev y (t as Free (x, T)) =
   105           if x = y then Type.constraint (uniform_typing x) (Type.constraint T (Bound lev))
   106           else t
   107       | abs_body _ _ a = a;
   108     fun close (y, U) B =
   109       let val B' = abs_body 0 y (Term.incr_boundvars 1 B)
   110       in if Term.is_dependent B' then Term.all dummyT $ Abs (y, U, B') else B end;
   111     fun close_form A =
   112       let
   113         val occ_frees = rev (fold_aterms add_free A []);
   114         val bounds = xs @ map (rpair dummyT) (subtract (op =) commons occ_frees);
   115       in fold_rev close bounds A end;
   116   in map close_form As end;
   117 
   118 fun prepare prep_vars parse_prop prep_att do_close raw_vars raw_specss ctxt =
   119   let
   120     val thy = Proof_Context.theory_of ctxt;
   121 
   122     val (vars, vars_ctxt) = ctxt |> prep_vars raw_vars;
   123     val (xs, params_ctxt) = vars_ctxt |> Proof_Context.add_fixes vars;
   124 
   125     val Asss =
   126       (map o map) snd raw_specss
   127       |> (burrow o burrow) (Par_List.map_name "Specification.parse_prop" (parse_prop params_ctxt));
   128     val names = Variable.names_of (params_ctxt |> (fold o fold o fold) Variable.declare_term Asss)
   129       |> fold Name.declare xs;
   130     val Asss' = #1 ((fold_map o fold_map o fold_map) Term.free_dummy_patterns Asss names);
   131     val idx = (fold o fold o fold) Term.maxidx_term Asss' ~1 + 1;
   132     val specs =
   133       (if do_close then
   134         #1 (fold_map
   135             (fn Ass => fn i => (burrow (close_forms params_ctxt i []) Ass, i + 1)) Asss' idx)
   136       else Asss')
   137       |> flat |> burrow (Syntax.check_props params_ctxt);
   138     val specs_ctxt = params_ctxt |> (fold o fold) Variable.declare_term specs;
   139 
   140     val Ts = specs_ctxt |> fold_map Proof_Context.inferred_param xs |> fst;
   141     val params = map2 (fn (b, _, mx) => fn T => ((b, T), mx)) vars Ts;
   142     val name_atts = map (fn ((name, atts), _) => (name, map (prep_att thy) atts)) (flat raw_specss);
   143   in ((params, name_atts ~~ specs), specs_ctxt) end;
   144 
   145 
   146 fun single_spec (a, prop) = [(a, [prop])];
   147 fun the_spec (a, [prop]) = (a, prop);
   148 
   149 fun prep_spec prep_vars parse_prop prep_att do_close vars specs =
   150   prepare prep_vars parse_prop prep_att do_close
   151     vars (map single_spec specs) #>> apsnd (map the_spec);
   152 
   153 in
   154 
   155 fun check_spec x = prep_spec Proof_Context.cert_vars (K I) (K I) true x;
   156 fun read_spec x = prep_spec Proof_Context.read_vars Syntax.parse_prop Attrib.intern_src true x;
   157 
   158 fun check_free_spec x = prep_spec Proof_Context.cert_vars (K I) (K I) false x;
   159 fun read_free_spec x = prep_spec Proof_Context.read_vars Syntax.parse_prop Attrib.intern_src false x;
   160 
   161 fun check_specification vars specs =
   162   prepare Proof_Context.cert_vars (K I) (K I) true vars [specs];
   163 
   164 fun read_specification vars specs =
   165   prepare Proof_Context.read_vars Syntax.parse_prop Attrib.intern_src true vars [specs];
   166 
   167 end;
   168 
   169 
   170 (* axiomatization -- within global theory *)
   171 
   172 fun gen_axioms do_print prep raw_vars raw_specs thy =
   173   let
   174     val ((vars, specs), _) = prep raw_vars raw_specs (Proof_Context.init_global thy);
   175     val xs = map (fn ((b, T), _) => (Variable.name b, T)) vars;
   176 
   177     (*consts*)
   178     val (consts, consts_thy) = thy |> fold_map Theory.specify_const vars;
   179     val subst = Term.subst_atomic (map Free xs ~~ consts);
   180 
   181     (*axioms*)
   182     val (axioms, axioms_thy) = (specs, consts_thy) |-> fold_map (fn ((b, atts), props) =>
   183         fold_map Thm.add_axiom_global
   184           (map (apfst (fn a => Binding.map_name (K a) b))
   185             (Global_Theory.name_multi (Variable.name b) (map subst props)))
   186         #>> (fn ths => ((b, atts), [(map #2 ths, [])])));
   187 
   188     (*facts*)
   189     val (facts, facts_lthy) = axioms_thy
   190       |> Named_Target.theory_init
   191       |> Spec_Rules.add Spec_Rules.Unknown (consts, maps (maps #1 o #2) axioms)
   192       |> Local_Theory.notes axioms;
   193 
   194     val _ =
   195       if not do_print then ()
   196       else print_consts facts_lthy (K false) xs;
   197   in ((consts, map #2 facts), Local_Theory.exit_global facts_lthy) end;
   198 
   199 val axiomatization = gen_axioms false check_specification;
   200 val axiomatization_cmd = gen_axioms true read_specification;
   201 
   202 fun axiom (b, ax) = axiomatization [] [(b, [ax])] #>> (hd o hd o snd);
   203 fun axiom_cmd (b, ax) = axiomatization_cmd [] [(b, [ax])] #>> (hd o hd o snd);
   204 
   205 
   206 (* definition *)
   207 
   208 fun gen_def do_print prep (raw_var, raw_spec) lthy =
   209   let
   210     val (vars, [((raw_name, atts), prop)]) = fst (prep (the_list raw_var) [raw_spec] lthy);
   211     val (((x, T), rhs), prove) = Local_Defs.derived_def lthy true prop;
   212     val var as (b, _) =
   213       (case vars of
   214         [] => (Binding.name x, NoSyn)
   215       | [((b, _), mx)] =>
   216           let
   217             val y = Variable.name b;
   218             val _ = x = y orelse
   219               error ("Head of definition " ^ quote x ^ " differs from declaration " ^ quote y ^
   220                 Position.str_of (Binding.pos_of b));
   221           in (b, mx) end);
   222     val name = Thm.def_binding_optional b raw_name;
   223     val ((lhs, (_, raw_th)), lthy2) = lthy
   224       |> Local_Theory.define (var, ((Binding.suffix_name "_raw" name, []), rhs));
   225 
   226     val th = prove lthy2 raw_th;
   227     val lthy3 = lthy2 |> Spec_Rules.add Spec_Rules.Equational ([lhs], [th]);
   228 
   229     val ([(def_name, [th'])], lthy4) = lthy3
   230       |> Local_Theory.notes_kind Thm.definitionK
   231         [((name, Code.add_default_eqn_attrib :: atts), [([th], [])])];
   232 
   233     val lhs' = Morphism.term (Local_Theory.target_morphism lthy4) lhs;
   234     val _ =
   235       if not do_print then ()
   236       else print_consts lthy4 (member (op =) (Term.add_frees lhs' [])) [(x, T)];
   237   in ((lhs, (def_name, th')), lthy4) end;
   238 
   239 val definition = gen_def false check_free_spec;
   240 val definition_cmd = gen_def true read_free_spec;
   241 
   242 
   243 (* abbreviation *)
   244 
   245 fun gen_abbrev do_print prep mode (raw_var, raw_prop) lthy =
   246   let
   247     val ((vars, [(_, prop)]), _) =
   248       prep (the_list raw_var) [(Attrib.empty_binding, raw_prop)]
   249         (lthy |> Proof_Context.set_mode Proof_Context.mode_abbrev);
   250     val ((x, T), rhs) = Local_Defs.abs_def (#2 (Local_Defs.cert_def lthy prop));
   251     val var =
   252       (case vars of
   253         [] => (Binding.name x, NoSyn)
   254       | [((b, _), mx)] =>
   255           let
   256             val y = Variable.name b;
   257             val _ = x = y orelse
   258               error ("Head of abbreviation " ^ quote x ^ " differs from declaration " ^ quote y ^
   259                 Position.str_of (Binding.pos_of b));
   260           in (b, mx) end);
   261     val lthy' = lthy
   262       |> Proof_Context.set_syntax_mode mode    (* FIXME ?!? *)
   263       |> Local_Theory.abbrev mode (var, rhs) |> snd
   264       |> Proof_Context.restore_syntax_mode lthy;
   265 
   266     val _ = if not do_print then () else print_consts lthy' (K false) [(x, T)];
   267   in lthy' end;
   268 
   269 val abbreviation = gen_abbrev false check_free_spec;
   270 val abbreviation_cmd = gen_abbrev true read_free_spec;
   271 
   272 
   273 (* notation *)
   274 
   275 local
   276 
   277 fun gen_type_notation prep_type add mode args lthy =
   278   lthy |> Local_Theory.type_notation add mode (map (apfst (prep_type lthy)) args);
   279 
   280 fun gen_notation prep_const add mode args lthy =
   281   lthy |> Local_Theory.notation add mode (map (apfst (prep_const lthy)) args);
   282 
   283 in
   284 
   285 val type_notation = gen_type_notation (K I);
   286 val type_notation_cmd = gen_type_notation (fn ctxt => Proof_Context.read_type_name ctxt false);
   287 
   288 val notation = gen_notation (K I);
   289 val notation_cmd = gen_notation (fn ctxt => Proof_Context.read_const ctxt false dummyT);
   290 
   291 end;
   292 
   293 
   294 (* fact statements *)
   295 
   296 fun gen_theorems prep_fact prep_att kind raw_facts lthy =
   297   let
   298     val attrib = prep_att (Proof_Context.theory_of lthy);
   299     val facts = raw_facts |> map (fn ((name, atts), bs) =>
   300       ((name, map attrib atts),
   301         bs |> map (fn (b, more_atts) => (prep_fact lthy b, map attrib more_atts))));
   302     val (res, lthy') = lthy |> Local_Theory.notes_kind kind facts;
   303     val _ = Proof_Display.print_results true lthy' ((kind, ""), res);
   304   in (res, lthy') end;
   305 
   306 val theorems = gen_theorems (K I) (K I);
   307 val theorems_cmd = gen_theorems Proof_Context.get_fact Attrib.intern_src;
   308 
   309 
   310 (* complex goal statements *)
   311 
   312 local
   313 
   314 fun prep_statement prep_att prep_stmt elems concl ctxt =
   315   (case concl of
   316     Element.Shows shows =>
   317       let
   318         val (propp, elems_ctxt) = prep_stmt elems (map snd shows) ctxt;
   319         val prems = Assumption.local_prems_of elems_ctxt ctxt;
   320         val stmt = Attrib.map_specs prep_att (map fst shows ~~ propp);
   321         val goal_ctxt = fold (fold (Variable.auto_fixes o fst)) propp elems_ctxt;
   322       in ((prems, stmt, NONE), goal_ctxt) end
   323   | Element.Obtains obtains =>
   324       let
   325         val case_names = obtains |> map_index (fn (i, (b, _)) =>
   326           if Binding.is_empty b then string_of_int (i + 1) else Variable.name b);
   327         val constraints = obtains |> map (fn (_, (vars, _)) =>
   328           Element.Constrains
   329             (vars |> map_filter (fn (x, SOME T) => SOME (Variable.name x, T) | _ => NONE)));
   330 
   331         val raw_propp = obtains |> map (fn (_, (_, props)) => map (rpair []) props);
   332         val (propp, elems_ctxt) = prep_stmt (elems @ constraints) raw_propp ctxt;
   333 
   334         val thesis = Object_Logic.fixed_judgment (Proof_Context.theory_of ctxt) Auto_Bind.thesisN;
   335 
   336         fun assume_case ((name, (vars, _)), asms) ctxt' =
   337           let
   338             val bs = map fst vars;
   339             val xs = map Variable.name bs;
   340             val props = map fst asms;
   341             val (Ts, _) = ctxt'
   342               |> fold Variable.declare_term props
   343               |> fold_map Proof_Context.inferred_param xs;
   344             val asm = Term.list_all_free (xs ~~ Ts, Logic.list_implies (props, thesis));
   345           in
   346             ctxt' |> (snd o Proof_Context.add_fixes (map (fn b => (b, NONE, NoSyn)) bs));
   347             ctxt' |> Variable.auto_fixes asm
   348             |> Proof_Context.add_assms_i Assumption.assume_export
   349               [((name, [Context_Rules.intro_query NONE]), [(asm, [])])]
   350             |>> (fn [(_, [th])] => th)
   351           end;
   352 
   353         val atts = map (Attrib.internal o K)
   354           [Rule_Cases.consumes (~ (length obtains)), Rule_Cases.case_names case_names];
   355         val prems = Assumption.local_prems_of elems_ctxt ctxt;
   356         val stmt = [((Binding.empty, atts), [(thesis, [])])];
   357 
   358         val (facts, goal_ctxt) = elems_ctxt
   359           |> (snd o Proof_Context.add_fixes [(Binding.name Auto_Bind.thesisN, NONE, NoSyn)])
   360           |> fold_map assume_case (obtains ~~ propp)
   361           |-> (fn ths =>
   362             Proof_Context.note_thmss "" [((Binding.name Obtain.thatN, []), [(ths, [])])] #>
   363             #2 #> pair ths);
   364       in ((prems, stmt, SOME facts), goal_ctxt) end);
   365 
   366 structure Theorem_Hook = Generic_Data
   367 (
   368   type T = ((bool -> Proof.state -> Proof.state) * stamp) list;
   369   val empty = [];
   370   val extend = I;
   371   fun merge data : T = Library.merge (eq_snd op =) data;
   372 );
   373 
   374 fun gen_theorem schematic prep_att prep_stmt
   375     kind before_qed after_qed (name, raw_atts) raw_elems raw_concl int lthy =
   376   let
   377     val _ = Local_Theory.affirm lthy;
   378     val thy = Proof_Context.theory_of lthy;
   379 
   380     val attrib = prep_att thy;
   381     val atts = map attrib raw_atts;
   382     val elems = raw_elems |> map (Element.map_ctxt_attrib attrib);
   383     val ((prems, stmt, facts), goal_ctxt) =
   384       prep_statement attrib prep_stmt elems raw_concl lthy;
   385 
   386     fun after_qed' results goal_ctxt' =
   387       let val results' =
   388         burrow (map Goal.norm_result o Proof_Context.export goal_ctxt' lthy) results
   389       in
   390         lthy
   391         |> Local_Theory.notes_kind kind
   392           (map2 (fn (a, _) => fn ths => (a, [(ths, [])])) stmt results')
   393         |> (fn (res, lthy') =>
   394           if Binding.is_empty name andalso null atts then
   395             (Proof_Display.print_results true lthy' ((kind, ""), res); lthy')
   396           else
   397             let
   398               val ([(res_name, _)], lthy'') = lthy'
   399                 |> Local_Theory.notes_kind kind [((name, atts), [(maps #2 res, [])])];
   400               val _ = Proof_Display.print_results true lthy' ((kind, res_name), res);
   401             in lthy'' end)
   402         |> after_qed results'
   403       end;
   404   in
   405     goal_ctxt
   406     |> Proof_Context.note_thmss "" [((Binding.name Auto_Bind.assmsN, []), [(prems, [])])]
   407     |> snd
   408     |> Proof.theorem before_qed after_qed' (map snd stmt)
   409     |> (case facts of NONE => I | SOME ths => Proof.refine_insert ths)
   410     |> tap (fn state => not schematic andalso Proof.schematic_goal state andalso
   411         error "Illegal schematic goal statement")
   412     |> Library.apply (map (fn (f, _) => f int) (rev (Theorem_Hook.get (Context.Proof goal_ctxt))))
   413   end;
   414 
   415 in
   416 
   417 val theorem = gen_theorem false (K I) Expression.cert_statement;
   418 val theorem_cmd = gen_theorem false Attrib.intern_src Expression.read_statement;
   419 
   420 val schematic_theorem = gen_theorem true (K I) Expression.cert_statement;
   421 val schematic_theorem_cmd = gen_theorem true Attrib.intern_src Expression.read_statement;
   422 
   423 fun add_theorem_hook f = Theorem_Hook.map (cons (f, stamp ()));
   424 
   425 end;
   426 
   427 end;