src/Pure/proofterm.ML
author wenzelm
Mon May 31 21:06:57 2010 +0200 (2010-05-31 ago)
changeset 37216 3165bc303f66
parent 36883 4ed0d72def50
child 37236 739d8b9c59da
permissions -rw-r--r--
modernized some structure names, keeping a few legacy aliases;
     1 (*  Title:      Pure/proofterm.ML
     2     Author:     Stefan Berghofer, TU Muenchen
     3 
     4 LF style proof terms.
     5 *)
     6 
     7 infix 8 % %% %>;
     8 
     9 signature BASIC_PROOFTERM =
    10 sig
    11   val proofs: int Unsynchronized.ref
    12 
    13   datatype proof =
    14      MinProof
    15    | PBound of int
    16    | Abst of string * typ option * proof
    17    | AbsP of string * term option * proof
    18    | op % of proof * term option
    19    | op %% of proof * proof
    20    | Hyp of term
    21    | PAxm of string * term * typ list option
    22    | OfClass of typ * class
    23    | Oracle of string * term * typ list option
    24    | Promise of serial * term * typ list
    25    | PThm of serial * ((string * term * typ list option) * proof_body future)
    26   and proof_body = PBody of
    27     {oracles: (string * term) OrdList.T,
    28      thms: (serial * (string * term * proof_body future)) OrdList.T,
    29      proof: proof}
    30 
    31   val %> : proof * term -> proof
    32 end;
    33 
    34 signature PROOFTERM =
    35 sig
    36   include BASIC_PROOFTERM
    37 
    38   type oracle = string * term
    39   type pthm = serial * (string * term * proof_body future)
    40   val proof_of: proof_body -> proof
    41   val join_proof: proof_body future -> proof
    42   val fold_proof_atoms: bool -> (proof -> 'a -> 'a) -> proof list -> 'a -> 'a
    43   val fold_body_thms: (string * term * proof_body -> 'a -> 'a) -> proof_body list -> 'a -> 'a
    44   val join_bodies: proof_body list -> unit
    45   val status_of: proof_body list -> {failed: bool, oracle: bool, unfinished: bool}
    46 
    47   val oracle_ord: oracle * oracle -> order
    48   val thm_ord: pthm * pthm -> order
    49   val merge_oracles: oracle OrdList.T -> oracle OrdList.T -> oracle OrdList.T
    50   val merge_thms: pthm OrdList.T -> pthm OrdList.T -> pthm OrdList.T
    51   val all_oracles_of: proof_body -> oracle OrdList.T
    52   val approximate_proof_body: proof -> proof_body
    53 
    54   (** primitive operations **)
    55   val proof_combt: proof * term list -> proof
    56   val proof_combt': proof * term option list -> proof
    57   val proof_combP: proof * proof list -> proof
    58   val strip_combt: proof -> proof * term option list
    59   val strip_combP: proof -> proof * proof list
    60   val strip_thm: proof_body -> proof_body
    61   val map_proof_terms_same: term Same.operation -> typ Same.operation -> proof Same.operation
    62   val map_proof_types_same: typ Same.operation -> proof Same.operation
    63   val map_proof_terms: (term -> term) -> (typ -> typ) -> proof -> proof
    64   val map_proof_types: (typ -> typ) -> proof -> proof
    65   val fold_proof_terms: (term -> 'a -> 'a) -> (typ -> 'a -> 'a) -> proof -> 'a -> 'a
    66   val maxidx_proof: proof -> int -> int
    67   val size_of_proof: proof -> int
    68   val change_type: typ list option -> proof -> proof
    69   val prf_abstract_over: term -> proof -> proof
    70   val prf_incr_bv: int -> int -> int -> int -> proof -> proof
    71   val incr_pboundvars: int -> int -> proof -> proof
    72   val prf_loose_bvar1: proof -> int -> bool
    73   val prf_loose_Pbvar1: proof -> int -> bool
    74   val prf_add_loose_bnos: int -> int -> proof -> int list * int list -> int list * int list
    75   val norm_proof: Envir.env -> proof -> proof
    76   val norm_proof': Envir.env -> proof -> proof
    77   val prf_subst_bounds: term list -> proof -> proof
    78   val prf_subst_pbounds: proof list -> proof -> proof
    79   val freeze_thaw_prf: proof -> proof * (proof -> proof)
    80 
    81   (** proof terms for specific inference rules **)
    82   val implies_intr_proof: term -> proof -> proof
    83   val forall_intr_proof: term -> string -> proof -> proof
    84   val varify_proof: term -> (string * sort) list -> proof -> proof
    85   val legacy_freezeT: term -> proof -> proof
    86   val rotate_proof: term list -> term -> int -> proof -> proof
    87   val permute_prems_proof: term list -> int -> int -> proof -> proof
    88   val generalize: string list * string list -> int -> proof -> proof
    89   val instantiate: ((indexname * sort) * typ) list * ((indexname * typ) * term) list
    90     -> proof -> proof
    91   val lift_proof: term -> int -> term -> proof -> proof
    92   val incr_indexes: int -> proof -> proof
    93   val assumption_proof: term list -> term -> int -> proof -> proof
    94   val bicompose_proof: bool -> term list -> term list -> term list -> term option ->
    95     int -> int -> proof -> proof -> proof
    96   val equality_axms: (string * term) list
    97   val reflexive_axm: proof
    98   val symmetric_axm: proof
    99   val transitive_axm: proof
   100   val equal_intr_axm: proof
   101   val equal_elim_axm: proof
   102   val abstract_rule_axm: proof
   103   val combination_axm: proof
   104   val reflexive: proof
   105   val symmetric: proof -> proof
   106   val transitive: term -> typ -> proof -> proof -> proof
   107   val abstract_rule: term -> string -> proof -> proof
   108   val combination: term -> term -> term -> term -> typ -> proof -> proof -> proof
   109   val equal_intr: term -> term -> proof -> proof -> proof
   110   val equal_elim: term -> term -> proof -> proof -> proof
   111   val strip_shyps_proof: Sorts.algebra -> (typ * sort) list -> (typ * sort) list ->
   112     sort list -> proof -> proof
   113   val classrel_proof: theory -> class * class -> proof
   114   val arity_proof: theory -> string * sort list * class -> proof
   115   val of_sort_proof: theory -> (typ * class -> proof) -> typ * sort -> proof list
   116   val install_axclass_proofs:
   117    {classrel_proof: theory -> class * class -> proof,
   118     arity_proof: theory -> string * sort list * class -> proof} -> unit
   119   val axm_proof: string -> term -> proof
   120   val oracle_proof: string -> term -> oracle * proof
   121 
   122   (** rewriting on proof terms **)
   123   val add_prf_rrule: proof * proof -> theory -> theory
   124   val add_prf_rproc: (typ list -> proof -> (proof * proof) option) -> theory -> theory
   125   val no_skel: proof
   126   val normal_skel: proof
   127   val rewrite_proof: theory -> (proof * proof) list *
   128     (typ list -> proof -> (proof * proof) option) list -> proof -> proof
   129   val rewrite_proof_notypes: (proof * proof) list *
   130     (typ list -> proof -> (proof * proof) option) list -> proof -> proof
   131   val rew_proof: theory -> proof -> proof
   132 
   133   val promise_proof: theory -> serial -> term -> proof
   134   val fulfill_norm_proof: theory -> (serial * proof_body) list -> proof_body -> proof_body
   135   val unconstrain_thm_proofs: bool Unsynchronized.ref
   136   val thm_proof: theory -> string -> sort list -> term list -> term ->
   137     (serial * proof_body future) list -> proof_body -> pthm * proof
   138   val unconstrain_thm_proof: theory -> sort list -> term ->
   139     (serial * proof_body future) list -> proof_body -> pthm * proof
   140   val get_name: term list -> term -> proof -> string
   141   val get_name_unconstrained: sort list -> term list -> term -> proof -> string
   142   val guess_name: proof -> string
   143 end
   144 
   145 structure Proofterm : PROOFTERM =
   146 struct
   147 
   148 (***** datatype proof *****)
   149 
   150 datatype proof =
   151    MinProof
   152  | PBound of int
   153  | Abst of string * typ option * proof
   154  | AbsP of string * term option * proof
   155  | op % of proof * term option
   156  | op %% of proof * proof
   157  | Hyp of term
   158  | PAxm of string * term * typ list option
   159  | OfClass of typ * class
   160  | Oracle of string * term * typ list option
   161  | Promise of serial * term * typ list
   162  | PThm of serial * ((string * term * typ list option) * proof_body future)
   163 and proof_body = PBody of
   164   {oracles: (string * term) OrdList.T,
   165    thms: (serial * (string * term * proof_body future)) OrdList.T,
   166    proof: proof};
   167 
   168 type oracle = string * term;
   169 type pthm = serial * (string * term * proof_body future);
   170 
   171 fun proof_of (PBody {proof, ...}) = proof;
   172 val join_proof = Future.join #> proof_of;
   173 
   174 
   175 (***** proof atoms *****)
   176 
   177 fun fold_proof_atoms all f =
   178   let
   179     fun app (Abst (_, _, prf)) = app prf
   180       | app (AbsP (_, _, prf)) = app prf
   181       | app (prf % _) = app prf
   182       | app (prf1 %% prf2) = app prf1 #> app prf2
   183       | app (prf as PThm (i, (_, body))) = (fn (x, seen) =>
   184           if Inttab.defined seen i then (x, seen)
   185           else
   186             let val (x', seen') =
   187               (if all then app (join_proof body) else I) (x, Inttab.update (i, ()) seen)
   188             in (f prf x', seen') end)
   189       | app prf = (fn (x, seen) => (f prf x, seen));
   190   in fn prfs => fn x => #1 (fold app prfs (x, Inttab.empty)) end;
   191 
   192 fun fold_body_thms f =
   193   let
   194     fun app (PBody {thms, ...}) =
   195      (Future.join_results (map (#3 o #2) thms);
   196       thms |> fold (fn (i, (name, prop, body)) => fn (x, seen) =>
   197         if Inttab.defined seen i then (x, seen)
   198         else
   199           let
   200             val body' = Future.join body;
   201             val (x', seen') = app body' (x, Inttab.update (i, ()) seen);
   202           in (f (name, prop, body') x', seen') end));
   203   in fn bodies => fn x => #1 (fold app bodies (x, Inttab.empty)) end;
   204 
   205 fun join_bodies bodies = fold_body_thms (fn _ => fn () => ()) bodies ();
   206 
   207 fun status_of bodies =
   208   let
   209     fun status (PBody {oracles, thms, ...}) x =
   210       let
   211         val ((oracle, unfinished, failed), seen) =
   212           (thms, x) |-> fold (fn (i, (_, _, body)) => fn (st, seen) =>
   213             if Inttab.defined seen i then (st, seen)
   214             else
   215               let val seen' = Inttab.update (i, ()) seen in
   216                 (case Future.peek body of
   217                   SOME (Exn.Result body') => status body' (st, seen')
   218                 | SOME (Exn.Exn _) =>
   219                     let val (oracle, unfinished, _) = st
   220                     in ((oracle, unfinished, true), seen') end
   221                 | NONE =>
   222                     let val (oracle, _, failed) = st
   223                     in ((oracle, true, failed), seen') end)
   224               end);
   225       in ((oracle orelse not (null oracles), unfinished, failed), seen) end;
   226     val (oracle, unfinished, failed) =
   227       #1 (fold status bodies ((false, false, false), Inttab.empty));
   228   in {oracle = oracle, unfinished = unfinished, failed = failed} end;
   229 
   230 
   231 (* proof body *)
   232 
   233 val oracle_ord = prod_ord fast_string_ord Term_Ord.fast_term_ord;
   234 fun thm_ord ((i, _): pthm, (j, _)) = int_ord (j, i);
   235 
   236 val merge_oracles = OrdList.union oracle_ord;
   237 val merge_thms = OrdList.union thm_ord;
   238 
   239 val all_oracles_of =
   240   let
   241     fun collect (PBody {oracles, thms, ...}) =
   242      (Future.join_results (map (#3 o #2) thms);
   243       thms |> fold (fn (i, (_, _, body)) => fn (x, seen) =>
   244         if Inttab.defined seen i then (x, seen)
   245         else
   246           let
   247             val body' = Future.join body;
   248             val (x', seen') = collect body' (x, Inttab.update (i, ()) seen);
   249           in (merge_oracles oracles x', seen') end));
   250   in fn body => #1 (collect body ([], Inttab.empty)) end;
   251 
   252 fun approximate_proof_body prf =
   253   let
   254     val (oracles, thms) = fold_proof_atoms false
   255       (fn Oracle (s, prop, _) => apfst (cons (s, prop))
   256         | PThm (i, ((name, prop, _), body)) => apsnd (cons (i, (name, prop, body)))
   257         | _ => I) [prf] ([], []);
   258   in
   259     PBody
   260      {oracles = OrdList.make oracle_ord oracles,
   261       thms = OrdList.make thm_ord thms,
   262       proof = prf}
   263   end;
   264 
   265 
   266 (***** proof objects with different levels of detail *****)
   267 
   268 fun (prf %> t) = prf % SOME t;
   269 
   270 val proof_combt = Library.foldl (op %>);
   271 val proof_combt' = Library.foldl (op %);
   272 val proof_combP = Library.foldl (op %%);
   273 
   274 fun strip_combt prf =
   275     let fun stripc (prf % t, ts) = stripc (prf, t::ts)
   276           | stripc  x =  x
   277     in  stripc (prf, [])  end;
   278 
   279 fun strip_combP prf =
   280     let fun stripc (prf %% prf', prfs) = stripc (prf, prf'::prfs)
   281           | stripc  x =  x
   282     in  stripc (prf, [])  end;
   283 
   284 fun strip_thm (body as PBody {proof, ...}) =
   285   (case strip_combt (fst (strip_combP proof)) of
   286     (PThm (_, (_, body')), _) => Future.join body'
   287   | _ => body);
   288 
   289 val mk_Abst = fold_rev (fn (s, T:typ) => fn prf => Abst (s, NONE, prf));
   290 fun mk_AbsP (i, prf) = funpow i (fn prf => AbsP ("H", NONE, prf)) prf;
   291 
   292 fun map_proof_same term typ ofclass =
   293   let
   294     val typs = Same.map typ;
   295 
   296     fun proof (Abst (s, T, prf)) =
   297           (Abst (s, Same.map_option typ T, Same.commit proof prf)
   298             handle Same.SAME => Abst (s, T, proof prf))
   299       | proof (AbsP (s, t, prf)) =
   300           (AbsP (s, Same.map_option term t, Same.commit proof prf)
   301             handle Same.SAME => AbsP (s, t, proof prf))
   302       | proof (prf % t) =
   303           (proof prf % Same.commit (Same.map_option term) t
   304             handle Same.SAME => prf % Same.map_option term t)
   305       | proof (prf1 %% prf2) =
   306           (proof prf1 %% Same.commit proof prf2
   307             handle Same.SAME => prf1 %% proof prf2)
   308       | proof (PAxm (a, prop, SOME Ts)) = PAxm (a, prop, SOME (typs Ts))
   309       | proof (OfClass T_c) = ofclass T_c
   310       | proof (Oracle (a, prop, SOME Ts)) = Oracle (a, prop, SOME (typs Ts))
   311       | proof (Promise (i, prop, Ts)) = Promise (i, prop, typs Ts)
   312       | proof (PThm (i, ((a, prop, SOME Ts), body))) =
   313           PThm (i, ((a, prop, SOME (typs Ts)), body))
   314       | proof _ = raise Same.SAME;
   315   in proof end;
   316 
   317 fun map_proof_terms_same term typ = map_proof_same term typ (fn (T, c) => OfClass (typ T, c));
   318 fun map_proof_types_same typ = map_proof_terms_same (Term_Subst.map_types_same typ) typ;
   319 
   320 fun same eq f x =
   321   let val x' = f x
   322   in if eq (x, x') then raise Same.SAME else x' end;
   323 
   324 fun map_proof_terms f g = Same.commit (map_proof_terms_same (same (op =) f) (same (op =) g));
   325 fun map_proof_types f = Same.commit (map_proof_types_same (same (op =) f));
   326 
   327 fun fold_proof_terms f g (Abst (_, SOME T, prf)) = g T #> fold_proof_terms f g prf
   328   | fold_proof_terms f g (Abst (_, NONE, prf)) = fold_proof_terms f g prf
   329   | fold_proof_terms f g (AbsP (_, SOME t, prf)) = f t #> fold_proof_terms f g prf
   330   | fold_proof_terms f g (AbsP (_, NONE, prf)) = fold_proof_terms f g prf
   331   | fold_proof_terms f g (prf % SOME t) = fold_proof_terms f g prf #> f t
   332   | fold_proof_terms f g (prf % NONE) = fold_proof_terms f g prf
   333   | fold_proof_terms f g (prf1 %% prf2) =
   334       fold_proof_terms f g prf1 #> fold_proof_terms f g prf2
   335   | fold_proof_terms _ g (PAxm (_, _, SOME Ts)) = fold g Ts
   336   | fold_proof_terms _ g (OfClass (T, _)) = g T
   337   | fold_proof_terms _ g (Oracle (_, _, SOME Ts)) = fold g Ts
   338   | fold_proof_terms _ g (Promise (_, _, Ts)) = fold g Ts
   339   | fold_proof_terms _ g (PThm (_, ((_, _, SOME Ts), _))) = fold g Ts
   340   | fold_proof_terms _ _ _ = I;
   341 
   342 fun maxidx_proof prf = fold_proof_terms Term.maxidx_term Term.maxidx_typ prf;
   343 
   344 fun size_of_proof (Abst (_, _, prf)) = 1 + size_of_proof prf
   345   | size_of_proof (AbsP (_, t, prf)) = 1 + size_of_proof prf
   346   | size_of_proof (prf % _) = 1 + size_of_proof prf
   347   | size_of_proof (prf1 %% prf2) = size_of_proof prf1 + size_of_proof prf2
   348   | size_of_proof _ = 1;
   349 
   350 fun change_type opTs (PAxm (name, prop, _)) = PAxm (name, prop, opTs)
   351   | change_type (SOME [T]) (OfClass (_, c)) = OfClass (T, c)
   352   | change_type opTs (Oracle (name, prop, _)) = Oracle (name, prop, opTs)
   353   | change_type opTs (Promise _) = raise Fail "change_type: unexpected promise"
   354   | change_type opTs (PThm (i, ((name, prop, _), body))) =
   355       PThm (i, ((name, prop, opTs), body))
   356   | change_type _ prf = prf;
   357 
   358 
   359 (***** utilities *****)
   360 
   361 fun strip_abs (_::Ts) (Abs (_, _, t)) = strip_abs Ts t
   362   | strip_abs _ t = t;
   363 
   364 fun mk_abs Ts t = Library.foldl (fn (t', T) => Abs ("", T, t')) (t, Ts);
   365 
   366 
   367 (*Abstraction of a proof term over its occurrences of v,
   368     which must contain no loose bound variables.
   369   The resulting proof term is ready to become the body of an Abst.*)
   370 
   371 fun prf_abstract_over v =
   372   let
   373     fun abst' lev u = if v aconv u then Bound lev else
   374       (case u of
   375          Abs (a, T, t) => Abs (a, T, abst' (lev + 1) t)
   376        | f $ t => (abst' lev f $ absth' lev t handle Same.SAME => f $ abst' lev t)
   377        | _ => raise Same.SAME)
   378     and absth' lev t = (abst' lev t handle Same.SAME => t);
   379 
   380     fun abst lev (AbsP (a, t, prf)) =
   381           (AbsP (a, Same.map_option (abst' lev) t, absth lev prf)
   382            handle Same.SAME => AbsP (a, t, abst lev prf))
   383       | abst lev (Abst (a, T, prf)) = Abst (a, T, abst (lev + 1) prf)
   384       | abst lev (prf1 %% prf2) = (abst lev prf1 %% absth lev prf2
   385           handle Same.SAME => prf1 %% abst lev prf2)
   386       | abst lev (prf % t) = (abst lev prf % Option.map (absth' lev) t
   387           handle Same.SAME => prf % Same.map_option (abst' lev) t)
   388       | abst _ _ = raise Same.SAME
   389     and absth lev prf = (abst lev prf handle Same.SAME => prf);
   390 
   391   in absth 0 end;
   392 
   393 
   394 (*increments a proof term's non-local bound variables
   395   required when moving a proof term within abstractions
   396      inc is  increment for bound variables
   397      lev is  level at which a bound variable is considered 'loose'*)
   398 
   399 fun incr_bv' inct tlev t = incr_bv (inct, tlev, t);
   400 
   401 fun prf_incr_bv' incP inct Plev tlev (PBound i) =
   402       if i >= Plev then PBound (i+incP) else raise Same.SAME
   403   | prf_incr_bv' incP inct Plev tlev (AbsP (a, t, body)) =
   404       (AbsP (a, Same.map_option (same (op =) (incr_bv' inct tlev)) t,
   405          prf_incr_bv incP inct (Plev+1) tlev body) handle Same.SAME =>
   406            AbsP (a, t, prf_incr_bv' incP inct (Plev+1) tlev body))
   407   | prf_incr_bv' incP inct Plev tlev (Abst (a, T, body)) =
   408       Abst (a, T, prf_incr_bv' incP inct Plev (tlev+1) body)
   409   | prf_incr_bv' incP inct Plev tlev (prf %% prf') =
   410       (prf_incr_bv' incP inct Plev tlev prf %% prf_incr_bv incP inct Plev tlev prf'
   411        handle Same.SAME => prf %% prf_incr_bv' incP inct Plev tlev prf')
   412   | prf_incr_bv' incP inct Plev tlev (prf % t) =
   413       (prf_incr_bv' incP inct Plev tlev prf % Option.map (incr_bv' inct tlev) t
   414        handle Same.SAME => prf % Same.map_option (same (op =) (incr_bv' inct tlev)) t)
   415   | prf_incr_bv' _ _ _ _ _ = raise Same.SAME
   416 and prf_incr_bv incP inct Plev tlev prf =
   417       (prf_incr_bv' incP inct Plev tlev prf handle Same.SAME => prf);
   418 
   419 fun incr_pboundvars  0 0 prf = prf
   420   | incr_pboundvars incP inct prf = prf_incr_bv incP inct 0 0 prf;
   421 
   422 
   423 fun prf_loose_bvar1 (prf1 %% prf2) k = prf_loose_bvar1 prf1 k orelse prf_loose_bvar1 prf2 k
   424   | prf_loose_bvar1 (prf % SOME t) k = prf_loose_bvar1 prf k orelse loose_bvar1 (t, k)
   425   | prf_loose_bvar1 (_ % NONE) _ = true
   426   | prf_loose_bvar1 (AbsP (_, SOME t, prf)) k = loose_bvar1 (t, k) orelse prf_loose_bvar1 prf k
   427   | prf_loose_bvar1 (AbsP (_, NONE, _)) k = true
   428   | prf_loose_bvar1 (Abst (_, _, prf)) k = prf_loose_bvar1 prf (k+1)
   429   | prf_loose_bvar1 _ _ = false;
   430 
   431 fun prf_loose_Pbvar1 (PBound i) k = i = k
   432   | prf_loose_Pbvar1 (prf1 %% prf2) k = prf_loose_Pbvar1 prf1 k orelse prf_loose_Pbvar1 prf2 k
   433   | prf_loose_Pbvar1 (prf % _) k = prf_loose_Pbvar1 prf k
   434   | prf_loose_Pbvar1 (AbsP (_, _, prf)) k = prf_loose_Pbvar1 prf (k+1)
   435   | prf_loose_Pbvar1 (Abst (_, _, prf)) k = prf_loose_Pbvar1 prf k
   436   | prf_loose_Pbvar1 _ _ = false;
   437 
   438 fun prf_add_loose_bnos plev tlev (PBound i) (is, js) =
   439       if i < plev then (is, js) else (insert (op =) (i-plev) is, js)
   440   | prf_add_loose_bnos plev tlev (prf1 %% prf2) p =
   441       prf_add_loose_bnos plev tlev prf2
   442         (prf_add_loose_bnos plev tlev prf1 p)
   443   | prf_add_loose_bnos plev tlev (prf % opt) (is, js) =
   444       prf_add_loose_bnos plev tlev prf (case opt of
   445           NONE => (is, insert (op =) ~1 js)
   446         | SOME t => (is, add_loose_bnos (t, tlev, js)))
   447   | prf_add_loose_bnos plev tlev (AbsP (_, opt, prf)) (is, js) =
   448       prf_add_loose_bnos (plev+1) tlev prf (case opt of
   449           NONE => (is, insert (op =) ~1 js)
   450         | SOME t => (is, add_loose_bnos (t, tlev, js)))
   451   | prf_add_loose_bnos plev tlev (Abst (_, _, prf)) p =
   452       prf_add_loose_bnos plev (tlev+1) prf p
   453   | prf_add_loose_bnos _ _ _ _ = ([], []);
   454 
   455 
   456 (**** substitutions ****)
   457 
   458 fun del_conflicting_tvars envT T = Term_Subst.instantiateT
   459   (map_filter (fn ixnS as (_, S) =>
   460      (Type.lookup envT ixnS; NONE) handle TYPE _ =>
   461         SOME (ixnS, TFree ("'dummy", S))) (OldTerm.typ_tvars T)) T;
   462 
   463 fun del_conflicting_vars env t = Term_Subst.instantiate
   464   (map_filter (fn ixnS as (_, S) =>
   465      (Type.lookup (Envir.type_env env) ixnS; NONE) handle TYPE _ =>
   466         SOME (ixnS, TFree ("'dummy", S))) (OldTerm.term_tvars t),
   467    map_filter (fn Var (ixnT as (_, T)) =>
   468      (Envir.lookup (env, ixnT); NONE) handle TYPE _ =>
   469         SOME (ixnT, Free ("dummy", T))) (OldTerm.term_vars t)) t;
   470 
   471 fun norm_proof env =
   472   let
   473     val envT = Envir.type_env env;
   474     fun msg s = warning ("type conflict in norm_proof:\n" ^ s);
   475     fun htype f t = f env t handle TYPE (s, _, _) =>
   476       (msg s; f env (del_conflicting_vars env t));
   477     fun htypeT f T = f envT T handle TYPE (s, _, _) =>
   478       (msg s; f envT (del_conflicting_tvars envT T));
   479     fun htypeTs f Ts = f envT Ts handle TYPE (s, _, _) =>
   480       (msg s; f envT (map (del_conflicting_tvars envT) Ts));
   481 
   482     fun norm (Abst (s, T, prf)) =
   483           (Abst (s, Same.map_option (htypeT Envir.norm_type_same) T, Same.commit norm prf)
   484             handle Same.SAME => Abst (s, T, norm prf))
   485       | norm (AbsP (s, t, prf)) =
   486           (AbsP (s, Same.map_option (htype Envir.norm_term_same) t, Same.commit norm prf)
   487             handle Same.SAME => AbsP (s, t, norm prf))
   488       | norm (prf % t) =
   489           (norm prf % Option.map (htype Envir.norm_term) t
   490             handle Same.SAME => prf % Same.map_option (htype Envir.norm_term_same) t)
   491       | norm (prf1 %% prf2) =
   492           (norm prf1 %% Same.commit norm prf2
   493             handle Same.SAME => prf1 %% norm prf2)
   494       | norm (PAxm (s, prop, Ts)) =
   495           PAxm (s, prop, Same.map_option (htypeTs Envir.norm_types_same) Ts)
   496       | norm (OfClass (T, c)) =
   497           OfClass (htypeT Envir.norm_type_same T, c)
   498       | norm (Oracle (s, prop, Ts)) =
   499           Oracle (s, prop, Same.map_option (htypeTs Envir.norm_types_same) Ts)
   500       | norm (Promise (i, prop, Ts)) =
   501           Promise (i, prop, htypeTs Envir.norm_types_same Ts)
   502       | norm (PThm (i, ((s, t, Ts), body))) =
   503           PThm (i, ((s, t, Same.map_option (htypeTs Envir.norm_types_same) Ts), body))
   504       | norm _ = raise Same.SAME;
   505   in Same.commit norm end;
   506 
   507 
   508 (***** Remove some types in proof term (to save space) *****)
   509 
   510 fun remove_types (Abs (s, _, t)) = Abs (s, dummyT, remove_types t)
   511   | remove_types (t $ u) = remove_types t $ remove_types u
   512   | remove_types (Const (s, _)) = Const (s, dummyT)
   513   | remove_types t = t;
   514 
   515 fun remove_types_env (Envir.Envir {maxidx, tenv, tyenv}) =
   516   Envir.Envir {maxidx = maxidx, tenv = Vartab.map (apsnd remove_types) tenv, tyenv = tyenv};
   517 
   518 fun norm_proof' env prf = norm_proof (remove_types_env env) prf;
   519 
   520 
   521 (**** substitution of bound variables ****)
   522 
   523 fun prf_subst_bounds args prf =
   524   let
   525     val n = length args;
   526     fun subst' lev (Bound i) =
   527          (if i<lev then raise Same.SAME    (*var is locally bound*)
   528           else  incr_boundvars lev (nth args (i-lev))
   529                   handle Subscript => Bound (i-n))  (*loose: change it*)
   530       | subst' lev (Abs (a, T, body)) = Abs (a, T,  subst' (lev+1) body)
   531       | subst' lev (f $ t) = (subst' lev f $ substh' lev t
   532           handle Same.SAME => f $ subst' lev t)
   533       | subst' _ _ = raise Same.SAME
   534     and substh' lev t = (subst' lev t handle Same.SAME => t);
   535 
   536     fun subst lev (AbsP (a, t, body)) =
   537         (AbsP (a, Same.map_option (subst' lev) t, substh lev body)
   538           handle Same.SAME => AbsP (a, t, subst lev body))
   539       | subst lev (Abst (a, T, body)) = Abst (a, T, subst (lev+1) body)
   540       | subst lev (prf %% prf') = (subst lev prf %% substh lev prf'
   541           handle Same.SAME => prf %% subst lev prf')
   542       | subst lev (prf % t) = (subst lev prf % Option.map (substh' lev) t
   543           handle Same.SAME => prf % Same.map_option (subst' lev) t)
   544       | subst _ _ = raise Same.SAME
   545     and substh lev prf = (subst lev prf handle Same.SAME => prf);
   546   in case args of [] => prf | _ => substh 0 prf end;
   547 
   548 fun prf_subst_pbounds args prf =
   549   let
   550     val n = length args;
   551     fun subst (PBound i) Plev tlev =
   552          (if i < Plev then raise Same.SAME    (*var is locally bound*)
   553           else incr_pboundvars Plev tlev (nth args (i-Plev))
   554                  handle Subscript => PBound (i-n)  (*loose: change it*))
   555       | subst (AbsP (a, t, body)) Plev tlev = AbsP (a, t, subst body (Plev+1) tlev)
   556       | subst (Abst (a, T, body)) Plev tlev = Abst (a, T, subst body Plev (tlev+1))
   557       | subst (prf %% prf') Plev tlev = (subst prf Plev tlev %% substh prf' Plev tlev
   558           handle Same.SAME => prf %% subst prf' Plev tlev)
   559       | subst (prf % t) Plev tlev = subst prf Plev tlev % t
   560       | subst  prf _ _ = raise Same.SAME
   561     and substh prf Plev tlev = (subst prf Plev tlev handle Same.SAME => prf)
   562   in case args of [] => prf | _ => substh prf 0 0 end;
   563 
   564 
   565 (**** Freezing and thawing of variables in proof terms ****)
   566 
   567 fun frzT names =
   568   map_type_tvar (fn (ixn, xs) => TFree ((the o AList.lookup (op =) names) ixn, xs));
   569 
   570 fun thawT names =
   571   map_type_tfree (fn (s, xs) => case AList.lookup (op =) names s of
   572       NONE => TFree (s, xs)
   573     | SOME ixn => TVar (ixn, xs));
   574 
   575 fun freeze names names' (t $ u) =
   576       freeze names names' t $ freeze names names' u
   577   | freeze names names' (Abs (s, T, t)) =
   578       Abs (s, frzT names' T, freeze names names' t)
   579   | freeze names names' (Const (s, T)) = Const (s, frzT names' T)
   580   | freeze names names' (Free (s, T)) = Free (s, frzT names' T)
   581   | freeze names names' (Var (ixn, T)) =
   582       Free ((the o AList.lookup (op =) names) ixn, frzT names' T)
   583   | freeze names names' t = t;
   584 
   585 fun thaw names names' (t $ u) =
   586       thaw names names' t $ thaw names names' u
   587   | thaw names names' (Abs (s, T, t)) =
   588       Abs (s, thawT names' T, thaw names names' t)
   589   | thaw names names' (Const (s, T)) = Const (s, thawT names' T)
   590   | thaw names names' (Free (s, T)) =
   591       let val T' = thawT names' T
   592       in case AList.lookup (op =) names s of
   593           NONE => Free (s, T')
   594         | SOME ixn => Var (ixn, T')
   595       end
   596   | thaw names names' (Var (ixn, T)) = Var (ixn, thawT names' T)
   597   | thaw names names' t = t;
   598 
   599 fun freeze_thaw_prf prf =
   600   let
   601     val (fs, Tfs, vs, Tvs) = fold_proof_terms
   602       (fn t => fn (fs, Tfs, vs, Tvs) =>
   603          (Term.add_free_names t fs, Term.add_tfree_names t Tfs,
   604           Term.add_var_names t vs, Term.add_tvar_names t Tvs))
   605       (fn T => fn (fs, Tfs, vs, Tvs) =>
   606          (fs, Term.add_tfree_namesT T Tfs,
   607           vs, Term.add_tvar_namesT T Tvs))
   608       prf ([], [], [], []);
   609     val names = vs ~~ Name.variant_list fs (map fst vs);
   610     val names' = Tvs ~~ Name.variant_list Tfs (map fst Tvs);
   611     val rnames = map swap names;
   612     val rnames' = map swap names';
   613   in
   614     (map_proof_terms (freeze names names') (frzT names') prf,
   615      map_proof_terms (thaw rnames rnames') (thawT rnames'))
   616   end;
   617 
   618 
   619 (***** implication introduction *****)
   620 
   621 fun implies_intr_proof h prf =
   622   let
   623     fun abshyp i (Hyp t) = if h aconv t then PBound i else raise Same.SAME
   624       | abshyp i (Abst (s, T, prf)) = Abst (s, T, abshyp i prf)
   625       | abshyp i (AbsP (s, t, prf)) = AbsP (s, t, abshyp (i + 1) prf)
   626       | abshyp i (prf % t) = abshyp i prf % t
   627       | abshyp i (prf1 %% prf2) =
   628           (abshyp i prf1 %% abshyph i prf2
   629             handle Same.SAME => prf1 %% abshyp i prf2)
   630       | abshyp _ _ = raise Same.SAME
   631     and abshyph i prf = (abshyp i prf handle Same.SAME => prf);
   632   in
   633     AbsP ("H", NONE (*h*), abshyph 0 prf)
   634   end;
   635 
   636 
   637 (***** forall introduction *****)
   638 
   639 fun forall_intr_proof x a prf = Abst (a, NONE, prf_abstract_over x prf);
   640 
   641 
   642 (***** varify *****)
   643 
   644 fun varify_proof t fixed prf =
   645   let
   646     val fs = Term.fold_types (Term.fold_atyps
   647       (fn TFree v => if member (op =) fixed v then I else insert (op =) v | _ => I)) t [];
   648     val used = Name.context
   649       |> fold_types (fold_atyps (fn TVar ((a, _), _) => Name.declare a | _ => I)) t;
   650     val fmap = fs ~~ #1 (Name.variants (map fst fs) used);
   651     fun thaw (f as (a, S)) =
   652       (case AList.lookup (op =) fmap f of
   653         NONE => TFree f
   654       | SOME b => TVar ((b, 0), S));
   655   in map_proof_terms (map_types (map_type_tfree thaw)) (map_type_tfree thaw) prf end;
   656 
   657 
   658 local
   659 
   660 fun new_name (ix, (pairs,used)) =
   661   let val v = Name.variant used (string_of_indexname ix)
   662   in  ((ix, v) :: pairs, v :: used)  end;
   663 
   664 fun freeze_one alist (ix, sort) = (case AList.lookup (op =) alist ix of
   665     NONE => TVar (ix, sort)
   666   | SOME name => TFree (name, sort));
   667 
   668 in
   669 
   670 fun legacy_freezeT t prf =
   671   let
   672     val used = OldTerm.it_term_types OldTerm.add_typ_tfree_names (t, [])
   673     and tvars = map #1 (OldTerm.it_term_types OldTerm.add_typ_tvars (t, []));
   674     val (alist, _) = List.foldr new_name ([], used) tvars;
   675   in
   676     (case alist of
   677       [] => prf (*nothing to do!*)
   678     | _ =>
   679       let val frzT = map_type_tvar (freeze_one alist)
   680       in map_proof_terms (map_types frzT) frzT prf end)
   681   end;
   682 
   683 end;
   684 
   685 
   686 (***** rotate assumptions *****)
   687 
   688 fun rotate_proof Bs Bi m prf =
   689   let
   690     val params = Term.strip_all_vars Bi;
   691     val asms = Logic.strip_imp_prems (Term.strip_all_body Bi);
   692     val i = length asms;
   693     val j = length Bs;
   694   in
   695     mk_AbsP (j+1, proof_combP (prf, map PBound
   696       (j downto 1) @ [mk_Abst params (mk_AbsP (i,
   697         proof_combP (proof_combt (PBound i, map Bound ((length params - 1) downto 0)),
   698           map PBound (((i-m-1) downto 0) @ ((i-1) downto (i-m))))))]))
   699   end;
   700 
   701 
   702 (***** permute premises *****)
   703 
   704 fun permute_prems_proof prems j k prf =
   705   let val n = length prems
   706   in mk_AbsP (n, proof_combP (prf,
   707     map PBound ((n-1 downto n-j) @ (k-1 downto 0) @ (n-j-1 downto k))))
   708   end;
   709 
   710 
   711 (***** generalization *****)
   712 
   713 fun generalize (tfrees, frees) idx =
   714   Same.commit (map_proof_terms_same
   715     (Term_Subst.generalize_same (tfrees, frees) idx)
   716     (Term_Subst.generalizeT_same tfrees idx));
   717 
   718 
   719 (***** instantiation *****)
   720 
   721 fun instantiate (instT, inst) =
   722   Same.commit (map_proof_terms_same
   723     (Term_Subst.instantiate_same (instT, map (apsnd remove_types) inst))
   724     (Term_Subst.instantiateT_same instT));
   725 
   726 
   727 (***** lifting *****)
   728 
   729 fun lift_proof Bi inc prop prf =
   730   let
   731     fun lift'' Us Ts t =
   732       strip_abs Ts (Logic.incr_indexes (Us, inc) (mk_abs Ts t));
   733 
   734     fun lift' Us Ts (Abst (s, T, prf)) =
   735           (Abst (s, Same.map_option (Logic.incr_tvar_same inc) T, lifth' Us (dummyT::Ts) prf)
   736            handle Same.SAME => Abst (s, T, lift' Us (dummyT::Ts) prf))
   737       | lift' Us Ts (AbsP (s, t, prf)) =
   738           (AbsP (s, Same.map_option (same (op =) (lift'' Us Ts)) t, lifth' Us Ts prf)
   739            handle Same.SAME => AbsP (s, t, lift' Us Ts prf))
   740       | lift' Us Ts (prf % t) = (lift' Us Ts prf % Option.map (lift'' Us Ts) t
   741           handle Same.SAME => prf % Same.map_option (same (op =) (lift'' Us Ts)) t)
   742       | lift' Us Ts (prf1 %% prf2) = (lift' Us Ts prf1 %% lifth' Us Ts prf2
   743           handle Same.SAME => prf1 %% lift' Us Ts prf2)
   744       | lift' _ _ (PAxm (s, prop, Ts)) =
   745           PAxm (s, prop, (Same.map_option o Same.map) (Logic.incr_tvar_same inc) Ts)
   746       | lift' _ _ (OfClass (T, c)) =
   747           OfClass (Logic.incr_tvar_same inc T, c)
   748       | lift' _ _ (Oracle (s, prop, Ts)) =
   749           Oracle (s, prop, (Same.map_option o Same.map) (Logic.incr_tvar_same inc) Ts)
   750       | lift' _ _ (Promise (i, prop, Ts)) =
   751           Promise (i, prop, Same.map (Logic.incr_tvar_same inc) Ts)
   752       | lift' _ _ (PThm (i, ((s, prop, Ts), body))) =
   753           PThm (i, ((s, prop, (Same.map_option o Same.map) (Logic.incr_tvar inc) Ts), body))
   754       | lift' _ _ _ = raise Same.SAME
   755     and lifth' Us Ts prf = (lift' Us Ts prf handle Same.SAME => prf);
   756 
   757     val ps = map (Logic.lift_all inc Bi) (Logic.strip_imp_prems prop);
   758     val k = length ps;
   759 
   760     fun mk_app b (i, j, prf) =
   761           if b then (i-1, j, prf %% PBound i) else (i, j-1, prf %> Bound j);
   762 
   763     fun lift Us bs i j (Const ("==>", _) $ A $ B) =
   764             AbsP ("H", NONE (*A*), lift Us (true::bs) (i+1) j B)
   765       | lift Us bs i j (Const ("all", _) $ Abs (a, T, t)) =
   766             Abst (a, NONE (*T*), lift (T::Us) (false::bs) i (j+1) t)
   767       | lift Us bs i j _ = proof_combP (lifth' (rev Us) [] prf,
   768             map (fn k => (#3 (fold_rev mk_app bs (i-1, j-1, PBound k))))
   769               (i + k - 1 downto i));
   770   in
   771     mk_AbsP (k, lift [] [] 0 0 Bi)
   772   end;
   773 
   774 fun incr_indexes i =
   775   Same.commit (map_proof_terms_same
   776     (Logic.incr_indexes_same ([], i)) (Logic.incr_tvar_same i));
   777 
   778 
   779 (***** proof by assumption *****)
   780 
   781 fun mk_asm_prf t i m =
   782   let
   783     fun imp_prf _ i 0 = PBound i
   784       | imp_prf (Const ("==>", _) $ A $ B) i m = AbsP ("H", NONE (*A*), imp_prf B (i+1) (m-1))
   785       | imp_prf _ i _ = PBound i;
   786     fun all_prf (Const ("all", _) $ Abs (a, T, t)) = Abst (a, NONE (*T*), all_prf t)
   787       | all_prf t = imp_prf t (~i) m
   788   in all_prf t end;
   789 
   790 fun assumption_proof Bs Bi n prf =
   791   mk_AbsP (length Bs, proof_combP (prf,
   792     map PBound (length Bs - 1 downto 0) @ [mk_asm_prf Bi n ~1]));
   793 
   794 
   795 (***** Composition of object rule with proof state *****)
   796 
   797 fun flatten_params_proof i j n (Const ("==>", _) $ A $ B, k) =
   798       AbsP ("H", NONE (*A*), flatten_params_proof (i+1) j n (B, k))
   799   | flatten_params_proof i j n (Const ("all", _) $ Abs (a, T, t), k) =
   800       Abst (a, NONE (*T*), flatten_params_proof i (j+1) n (t, k))
   801   | flatten_params_proof i j n (_, k) = proof_combP (proof_combt (PBound (k+i),
   802       map Bound (j-1 downto 0)), map PBound (remove (op =) (i-n) (i-1 downto 0)));
   803 
   804 fun bicompose_proof flatten Bs oldAs newAs A n m rprf sprf =
   805   let
   806     val la = length newAs;
   807     val lb = length Bs;
   808   in
   809     mk_AbsP (lb+la, proof_combP (sprf,
   810       map PBound (lb + la - 1 downto la)) %%
   811         proof_combP (rprf, (if n>0 then [mk_asm_prf (the A) n m] else []) @
   812           map (if flatten then flatten_params_proof 0 0 n else PBound o snd)
   813             (oldAs ~~ (la - 1 downto 0))))
   814   end;
   815 
   816 
   817 (***** axioms for equality *****)
   818 
   819 val aT = TFree ("'a", []);
   820 val bT = TFree ("'b", []);
   821 val x = Free ("x", aT);
   822 val y = Free ("y", aT);
   823 val z = Free ("z", aT);
   824 val A = Free ("A", propT);
   825 val B = Free ("B", propT);
   826 val f = Free ("f", aT --> bT);
   827 val g = Free ("g", aT --> bT);
   828 
   829 val equality_axms =
   830  [("reflexive", Logic.mk_equals (x, x)),
   831   ("symmetric", Logic.mk_implies (Logic.mk_equals (x, y), Logic.mk_equals (y, x))),
   832   ("transitive",
   833     Logic.list_implies ([Logic.mk_equals (x, y), Logic.mk_equals (y, z)], Logic.mk_equals (x, z))),
   834   ("equal_intr",
   835     Logic.list_implies ([Logic.mk_implies (A, B), Logic.mk_implies (B, A)], Logic.mk_equals (A, B))),
   836   ("equal_elim", Logic.list_implies ([Logic.mk_equals (A, B), A], B)),
   837   ("abstract_rule",
   838     Logic.mk_implies
   839       (Logic.all x
   840         (Logic.mk_equals (f $ x, g $ x)), Logic.mk_equals (lambda x (f $ x), lambda x (g $ x)))),
   841   ("combination", Logic.list_implies
   842     ([Logic.mk_equals (f, g), Logic.mk_equals (x, y)], Logic.mk_equals (f $ x, g $ y)))];
   843 
   844 val [reflexive_axm, symmetric_axm, transitive_axm, equal_intr_axm,
   845   equal_elim_axm, abstract_rule_axm, combination_axm] =
   846     map (fn (s, t) => PAxm ("Pure." ^ s, Logic.varify_global t, NONE)) equality_axms;
   847 
   848 val reflexive = reflexive_axm % NONE;
   849 
   850 fun symmetric (prf as PAxm ("Pure.reflexive", _, _) % _) = prf
   851   | symmetric prf = symmetric_axm % NONE % NONE %% prf;
   852 
   853 fun transitive _ _ (PAxm ("Pure.reflexive", _, _) % _) prf2 = prf2
   854   | transitive _ _ prf1 (PAxm ("Pure.reflexive", _, _) % _) = prf1
   855   | transitive u (Type ("prop", [])) prf1 prf2 =
   856       transitive_axm % NONE % SOME (remove_types u) % NONE %% prf1 %% prf2
   857   | transitive u T prf1 prf2 =
   858       transitive_axm % NONE % NONE % NONE %% prf1 %% prf2;
   859 
   860 fun abstract_rule x a prf =
   861   abstract_rule_axm % NONE % NONE %% forall_intr_proof x a prf;
   862 
   863 fun check_comb (PAxm ("Pure.combination", _, _) % f % g % _ % _ %% prf %% _) =
   864       is_some f orelse check_comb prf
   865   | check_comb (PAxm ("Pure.transitive", _, _) % _ % _ % _ %% prf1 %% prf2) =
   866       check_comb prf1 andalso check_comb prf2
   867   | check_comb (PAxm ("Pure.symmetric", _, _) % _ % _ %% prf) = check_comb prf
   868   | check_comb _ = false;
   869 
   870 fun combination f g t u (Type (_, [T, U])) prf1 prf2 =
   871   let
   872     val f = Envir.beta_norm f;
   873     val g = Envir.beta_norm g;
   874     val prf =  if check_comb prf1 then
   875         combination_axm % NONE % NONE
   876       else (case prf1 of
   877           PAxm ("Pure.reflexive", _, _) % _ =>
   878             combination_axm %> remove_types f % NONE
   879         | _ => combination_axm %> remove_types f %> remove_types g)
   880   in
   881     (case T of
   882        Type ("fun", _) => prf %
   883          (case head_of f of
   884             Abs _ => SOME (remove_types t)
   885           | Var _ => SOME (remove_types t)
   886           | _ => NONE) %
   887          (case head_of g of
   888             Abs _ => SOME (remove_types u)
   889           | Var _ => SOME (remove_types u)
   890           | _ => NONE) %% prf1 %% prf2
   891      | _ => prf % NONE % NONE %% prf1 %% prf2)
   892   end;
   893 
   894 fun equal_intr A B prf1 prf2 =
   895   equal_intr_axm %> remove_types A %> remove_types B %% prf1 %% prf2;
   896 
   897 fun equal_elim A B prf1 prf2 =
   898   equal_elim_axm %> remove_types A %> remove_types B %% prf1 %% prf2;
   899 
   900 
   901 (**** type classes ****)
   902 
   903 fun strip_shyps_proof algebra present witnessed extra_sorts prf =
   904   let
   905     fun get S2 (T, S1) = if Sorts.sort_le algebra (S1, S2) then SOME T else NONE;
   906     val extra = map (fn S => (TFree ("'dummy", S), S)) extra_sorts;
   907     val replacements = present @ extra @ witnessed;
   908     fun replace T =
   909       if exists (fn (T', _) => T' = T) present then raise Same.SAME
   910       else
   911         (case get_first (get (Type.sort_of_atyp T)) replacements of
   912           SOME T' => T'
   913         | NONE => raise Fail "strip_shyps_proof: bad type variable in proof term");
   914   in Same.commit (map_proof_types_same (Term_Subst.map_atypsT_same replace)) prf end;
   915 
   916 
   917 local
   918 
   919 type axclass_proofs =
   920  {classrel_proof: theory -> class * class -> proof,
   921   arity_proof: theory -> string * sort list * class -> proof};
   922 
   923 val axclass_proofs: axclass_proofs Single_Assignment.var =
   924   Single_Assignment.var "Proofterm.axclass_proofs";
   925 
   926 fun axclass_proof which thy x =
   927   (case Single_Assignment.peek axclass_proofs of
   928     NONE => raise Fail "Axclass proof operations not installed"
   929   | SOME prfs => which prfs thy x);
   930 
   931 in
   932 
   933 val classrel_proof = axclass_proof #classrel_proof;
   934 val arity_proof = axclass_proof #arity_proof;
   935 
   936 fun install_axclass_proofs prfs = Single_Assignment.assign axclass_proofs prfs;
   937 
   938 end;
   939 
   940 
   941 local
   942 
   943 fun canonical_instance typs =
   944   let
   945     val names = Name.invents Name.context Name.aT (length typs);
   946     val instT = map2 (fn a => fn T => (((a, 0), []), Type.strip_sorts T)) names typs;
   947   in instantiate (instT, []) end;
   948 
   949 in
   950 
   951 fun of_sort_proof thy hyps =
   952   Sorts.of_sort_derivation (Sign.classes_of thy)
   953    {class_relation = fn typ => fn (prf, c1) => fn c2 =>
   954       if c1 = c2 then prf
   955       else canonical_instance [typ] (classrel_proof thy (c1, c2)) %% prf,
   956     type_constructor = fn (a, typs) => fn dom => fn c =>
   957       let val Ss = map (map snd) dom and prfs = maps (map fst) dom
   958       in proof_combP (canonical_instance typs (arity_proof thy (a, Ss, c)), prfs) end,
   959     type_variable = fn typ => map (fn c => (hyps (typ, c), c)) (Type.sort_of_atyp typ)};
   960 
   961 end;
   962 
   963 
   964 (***** axioms and theorems *****)
   965 
   966 val proofs = Unsynchronized.ref 2;
   967 
   968 fun vars_of t = map Var (rev (Term.add_vars t []));
   969 fun frees_of t = map Free (rev (Term.add_frees t []));
   970 
   971 fun test_args _ [] = true
   972   | test_args is (Bound i :: ts) =
   973       not (member (op =) is i) andalso test_args (i :: is) ts
   974   | test_args _ _ = false;
   975 
   976 fun is_fun (Type ("fun", _)) = true
   977   | is_fun (TVar _) = true
   978   | is_fun _ = false;
   979 
   980 fun add_funvars Ts (vs, t) =
   981   if is_fun (fastype_of1 (Ts, t)) then
   982     union (op =) vs (map_filter (fn Var (ixn, T) =>
   983       if is_fun T then SOME ixn else NONE | _ => NONE) (vars_of t))
   984   else vs;
   985 
   986 fun add_npvars q p Ts (vs, Const ("==>", _) $ t $ u) =
   987       add_npvars q p Ts (add_npvars q (not p) Ts (vs, t), u)
   988   | add_npvars q p Ts (vs, Const ("all", Type (_, [Type (_, [T, _]), _])) $ t) =
   989       add_npvars q p Ts (vs, if p andalso q then betapply (t, Var (("",0), T)) else t)
   990   | add_npvars q p Ts (vs, Abs (_, T, t)) = add_npvars q p (T::Ts) (vs, t)
   991   | add_npvars _ _ Ts (vs, t) = add_npvars' Ts (vs, t)
   992 and add_npvars' Ts (vs, t) = (case strip_comb t of
   993     (Var (ixn, _), ts) => if test_args [] ts then vs
   994       else Library.foldl (add_npvars' Ts)
   995         (AList.update (op =) (ixn,
   996           Library.foldl (add_funvars Ts) ((these ooo AList.lookup) (op =) vs ixn, ts)) vs, ts)
   997   | (Abs (_, T, u), ts) => Library.foldl (add_npvars' (T::Ts)) (vs, u :: ts)
   998   | (_, ts) => Library.foldl (add_npvars' Ts) (vs, ts));
   999 
  1000 fun prop_vars (Const ("==>", _) $ P $ Q) = union (op =) (prop_vars P) (prop_vars Q)
  1001   | prop_vars (Const ("all", _) $ Abs (_, _, t)) = prop_vars t
  1002   | prop_vars t = (case strip_comb t of
  1003       (Var (ixn, _), _) => [ixn] | _ => []);
  1004 
  1005 fun is_proj t =
  1006   let
  1007     fun is_p i t = (case strip_comb t of
  1008         (Bound j, []) => false
  1009       | (Bound j, ts) => j >= i orelse exists (is_p i) ts
  1010       | (Abs (_, _, u), _) => is_p (i+1) u
  1011       | (_, ts) => exists (is_p i) ts)
  1012   in (case strip_abs_body t of
  1013         Bound _ => true
  1014       | t' => is_p 0 t')
  1015   end;
  1016 
  1017 fun needed_vars prop =
  1018   union (op =) (Library.foldl (uncurry (union (op =)))
  1019     ([], map (uncurry (insert (op =))) (add_npvars true true [] ([], prop))))
  1020   (prop_vars prop);
  1021 
  1022 fun gen_axm_proof c name prop =
  1023   let
  1024     val nvs = needed_vars prop;
  1025     val args = map (fn (v as Var (ixn, _)) =>
  1026         if member (op =) nvs ixn then SOME v else NONE) (vars_of prop) @
  1027       map SOME (frees_of prop);
  1028   in
  1029     proof_combt' (c (name, prop, NONE), args)
  1030   end;
  1031 
  1032 val axm_proof = gen_axm_proof PAxm;
  1033 
  1034 val dummy = Const (Term.dummy_patternN, dummyT);
  1035 
  1036 fun oracle_proof name prop =
  1037   if ! proofs = 0 then ((name, dummy), Oracle (name, dummy, NONE))
  1038   else ((name, prop), gen_axm_proof Oracle name prop);
  1039 
  1040 val shrink_proof =
  1041   let
  1042     fun shrink ls lev (prf as Abst (a, T, body)) =
  1043           let val (b, is, ch, body') = shrink ls (lev+1) body
  1044           in (b, is, ch, if ch then Abst (a, T, body') else prf) end
  1045       | shrink ls lev (prf as AbsP (a, t, body)) =
  1046           let val (b, is, ch, body') = shrink (lev::ls) lev body
  1047           in (b orelse member (op =) is 0, map_filter (fn 0 => NONE | i => SOME (i-1)) is,
  1048             ch, if ch then AbsP (a, t, body') else prf)
  1049           end
  1050       | shrink ls lev prf =
  1051           let val (is, ch, _, prf') = shrink' ls lev [] [] prf
  1052           in (false, is, ch, prf') end
  1053     and shrink' ls lev ts prfs (prf as prf1 %% prf2) =
  1054           let
  1055             val p as (_, is', ch', prf') = shrink ls lev prf2;
  1056             val (is, ch, ts', prf'') = shrink' ls lev ts (p::prfs) prf1
  1057           in (union (op =) is is', ch orelse ch', ts',
  1058               if ch orelse ch' then prf'' %% prf' else prf)
  1059           end
  1060       | shrink' ls lev ts prfs (prf as prf1 % t) =
  1061           let val (is, ch, (ch', t')::ts', prf') = shrink' ls lev (t::ts) prfs prf1
  1062           in (is, ch orelse ch', ts',
  1063               if ch orelse ch' then prf' % t' else prf) end
  1064       | shrink' ls lev ts prfs (prf as PBound i) =
  1065           (if exists (fn SOME (Bound j) => lev-j <= nth ls i | _ => true) ts
  1066              orelse has_duplicates (op =)
  1067                (Library.foldl (fn (js, SOME (Bound j)) => j :: js | (js, _) => js) ([], ts))
  1068              orelse exists #1 prfs then [i] else [], false, map (pair false) ts, prf)
  1069       | shrink' ls lev ts prfs (prf as Hyp _) = ([], false, map (pair false) ts, prf)
  1070       | shrink' ls lev ts prfs (prf as MinProof) = ([], false, map (pair false) ts, prf)
  1071       | shrink' ls lev ts prfs (prf as OfClass _) = ([], false, map (pair false) ts, prf)
  1072       | shrink' ls lev ts prfs prf =
  1073           let
  1074             val prop =
  1075               (case prf of
  1076                 PAxm (_, prop, _) => prop
  1077               | Oracle (_, prop, _) => prop
  1078               | Promise (_, prop, _) => prop
  1079               | PThm (_, ((_, prop, _), _)) => prop
  1080               | _ => raise Fail "shrink: proof not in normal form");
  1081             val vs = vars_of prop;
  1082             val (ts', ts'') = chop (length vs) ts;
  1083             val insts = take (length ts') (map (fst o dest_Var) vs) ~~ ts';
  1084             val nvs = Library.foldl (fn (ixns', (ixn, ixns)) =>
  1085               insert (op =) ixn (case AList.lookup (op =) insts ixn of
  1086                   SOME (SOME t) => if is_proj t then union (op =) ixns ixns' else ixns'
  1087                 | _ => union (op =) ixns ixns'))
  1088                   (needed prop ts'' prfs, add_npvars false true [] ([], prop));
  1089             val insts' = map
  1090               (fn (ixn, x as SOME _) => if member (op =) nvs ixn then (false, x) else (true, NONE)
  1091                 | (_, x) => (false, x)) insts
  1092           in ([], false, insts' @ map (pair false) ts'', prf) end
  1093     and needed (Const ("==>", _) $ t $ u) ts ((b, _, _, _)::prfs) =
  1094           union (op =) (if b then map (fst o dest_Var) (vars_of t) else []) (needed u ts prfs)
  1095       | needed (Var (ixn, _)) (_::_) _ = [ixn]
  1096       | needed _ _ _ = [];
  1097   in shrink end;
  1098 
  1099 
  1100 (**** Simple first order matching functions for terms and proofs ****)
  1101 
  1102 exception PMatch;
  1103 
  1104 (** see pattern.ML **)
  1105 
  1106 fun flt (i: int) = filter (fn n => n < i);
  1107 
  1108 fun fomatch Ts tymatch j =
  1109   let
  1110     fun mtch (instsp as (tyinsts, insts)) = fn
  1111         (Var (ixn, T), t)  =>
  1112           if j>0 andalso not (null (flt j (loose_bnos t)))
  1113           then raise PMatch
  1114           else (tymatch (tyinsts, fn () => (T, fastype_of1 (Ts, t))),
  1115             (ixn, t) :: insts)
  1116       | (Free (a, T), Free (b, U)) =>
  1117           if a=b then (tymatch (tyinsts, K (T, U)), insts) else raise PMatch
  1118       | (Const (a, T), Const (b, U))  =>
  1119           if a=b then (tymatch (tyinsts, K (T, U)), insts) else raise PMatch
  1120       | (f $ t, g $ u) => mtch (mtch instsp (f, g)) (t, u)
  1121       | (Bound i, Bound j) => if i=j then instsp else raise PMatch
  1122       | _ => raise PMatch
  1123   in mtch end;
  1124 
  1125 fun match_proof Ts tymatch =
  1126   let
  1127     fun optmatch _ inst (NONE, _) = inst
  1128       | optmatch _ _ (SOME _, NONE) = raise PMatch
  1129       | optmatch mtch inst (SOME x, SOME y) = mtch inst (x, y)
  1130 
  1131     fun matcht Ts j (pinst, tinst) (t, u) =
  1132       (pinst, fomatch Ts tymatch j tinst (t, Envir.beta_norm u));
  1133     fun matchT (pinst, (tyinsts, insts)) p =
  1134       (pinst, (tymatch (tyinsts, K p), insts));
  1135     fun matchTs inst (Ts, Us) = Library.foldl (uncurry matchT) (inst, Ts ~~ Us);
  1136 
  1137     fun mtch Ts i j (pinst, tinst) (Hyp (Var (ixn, _)), prf) =
  1138           if i = 0 andalso j = 0 then ((ixn, prf) :: pinst, tinst)
  1139           else (case apfst (flt i) (apsnd (flt j)
  1140                   (prf_add_loose_bnos 0 0 prf ([], []))) of
  1141               ([], []) => ((ixn, incr_pboundvars (~i) (~j) prf) :: pinst, tinst)
  1142             | ([], _) => if j = 0 then
  1143                    ((ixn, incr_pboundvars (~i) (~j) prf) :: pinst, tinst)
  1144                  else raise PMatch
  1145             | _ => raise PMatch)
  1146       | mtch Ts i j inst (prf1 % opt1, prf2 % opt2) =
  1147           optmatch (matcht Ts j) (mtch Ts i j inst (prf1, prf2)) (opt1, opt2)
  1148       | mtch Ts i j inst (prf1 %% prf2, prf1' %% prf2') =
  1149           mtch Ts i j (mtch Ts i j inst (prf1, prf1')) (prf2, prf2')
  1150       | mtch Ts i j inst (Abst (_, opT, prf1), Abst (_, opU, prf2)) =
  1151           mtch (the_default dummyT opU :: Ts) i (j+1)
  1152             (optmatch matchT inst (opT, opU)) (prf1, prf2)
  1153       | mtch Ts i j inst (prf1, Abst (_, opU, prf2)) =
  1154           mtch (the_default dummyT opU :: Ts) i (j+1) inst
  1155             (incr_pboundvars 0 1 prf1 %> Bound 0, prf2)
  1156       | mtch Ts i j inst (AbsP (_, opt, prf1), AbsP (_, opu, prf2)) =
  1157           mtch Ts (i+1) j (optmatch (matcht Ts j) inst (opt, opu)) (prf1, prf2)
  1158       | mtch Ts i j inst (prf1, AbsP (_, _, prf2)) =
  1159           mtch Ts (i+1) j inst (incr_pboundvars 1 0 prf1 %% PBound 0, prf2)
  1160       | mtch Ts i j inst (PAxm (s1, _, opTs), PAxm (s2, _, opUs)) =
  1161           if s1 = s2 then optmatch matchTs inst (opTs, opUs)
  1162           else raise PMatch
  1163       | mtch Ts i j inst (OfClass (T1, c1), OfClass (T2, c2)) =
  1164           if c1 = c2 then matchT inst (T1, T2)
  1165           else raise PMatch
  1166       | mtch Ts i j inst (PThm (_, ((name1, prop1, opTs), _)), PThm (_, ((name2, prop2, opUs), _))) =
  1167           if name1 = name2 andalso prop1 = prop2 then
  1168             optmatch matchTs inst (opTs, opUs)
  1169           else raise PMatch
  1170       | mtch _ _ _ inst (PBound i, PBound j) = if i = j then inst else raise PMatch
  1171       | mtch _ _ _ _ _ = raise PMatch
  1172   in mtch Ts 0 0 end;
  1173 
  1174 fun prf_subst (pinst, (tyinsts, insts)) =
  1175   let
  1176     val substT = Envir.subst_type_same tyinsts;
  1177     val substTs = Same.map substT;
  1178 
  1179     fun subst' lev (Var (xi, _)) =
  1180         (case AList.lookup (op =) insts xi of
  1181           NONE => raise Same.SAME
  1182         | SOME u => incr_boundvars lev u)
  1183       | subst' _ (Const (s, T)) = Const (s, substT T)
  1184       | subst' _ (Free (s, T)) = Free (s, substT T)
  1185       | subst' lev (Abs (a, T, body)) =
  1186           (Abs (a, substT T, Same.commit (subst' (lev + 1)) body)
  1187             handle Same.SAME => Abs (a, T, subst' (lev + 1) body))
  1188       | subst' lev (f $ t) =
  1189           (subst' lev f $ Same.commit (subst' lev) t
  1190             handle Same.SAME => f $ subst' lev t)
  1191       | subst' _ _ = raise Same.SAME;
  1192 
  1193     fun subst plev tlev (AbsP (a, t, body)) =
  1194           (AbsP (a, Same.map_option (subst' tlev) t, Same.commit (subst (plev + 1) tlev) body)
  1195             handle Same.SAME => AbsP (a, t, subst (plev + 1) tlev body))
  1196       | subst plev tlev (Abst (a, T, body)) =
  1197           (Abst (a, Same.map_option substT T, Same.commit (subst plev (tlev + 1)) body)
  1198             handle Same.SAME => Abst (a, T, subst plev (tlev + 1) body))
  1199       | subst plev tlev (prf %% prf') =
  1200           (subst plev tlev prf %% Same.commit (subst plev tlev) prf'
  1201             handle Same.SAME => prf %% subst plev tlev prf')
  1202       | subst plev tlev (prf % t) =
  1203           (subst plev tlev prf % Same.commit (Same.map_option (subst' tlev)) t
  1204             handle Same.SAME => prf % Same.map_option (subst' tlev) t)
  1205       | subst plev tlev (Hyp (Var (xi, _))) =
  1206           (case AList.lookup (op =) pinst xi of
  1207             NONE => raise Same.SAME
  1208           | SOME prf' => incr_pboundvars plev tlev prf')
  1209       | subst _ _ (PAxm (id, prop, Ts)) = PAxm (id, prop, Same.map_option substTs Ts)
  1210       | subst _ _ (OfClass (T, c)) = OfClass (substT T, c)
  1211       | subst _ _ (Oracle (id, prop, Ts)) = Oracle (id, prop, Same.map_option substTs Ts)
  1212       | subst _ _ (Promise (i, prop, Ts)) = Promise (i, prop, substTs Ts)
  1213       | subst _ _ (PThm (i, ((id, prop, Ts), body))) =
  1214           PThm (i, ((id, prop, Same.map_option substTs Ts), body))
  1215       | subst _ _ _ = raise Same.SAME;
  1216   in fn t => subst 0 0 t handle Same.SAME => t end;
  1217 
  1218 (*A fast unification filter: true unless the two terms cannot be unified.
  1219   Terms must be NORMAL.  Treats all Vars as distinct. *)
  1220 fun could_unify prf1 prf2 =
  1221   let
  1222     fun matchrands (prf1 %% prf2) (prf1' %% prf2') =
  1223           could_unify prf2 prf2' andalso matchrands prf1 prf1'
  1224       | matchrands (prf % SOME t) (prf' % SOME t') =
  1225           Term.could_unify (t, t') andalso matchrands prf prf'
  1226       | matchrands (prf % _) (prf' % _) = matchrands prf prf'
  1227       | matchrands _ _ = true
  1228 
  1229     fun head_of (prf %% _) = head_of prf
  1230       | head_of (prf % _) = head_of prf
  1231       | head_of prf = prf
  1232 
  1233   in case (head_of prf1, head_of prf2) of
  1234         (_, Hyp (Var _)) => true
  1235       | (Hyp (Var _), _) => true
  1236       | (PAxm (a, _, _), PAxm (b, _, _)) => a = b andalso matchrands prf1 prf2
  1237       | (OfClass (_, c), OfClass (_, d)) => c = d andalso matchrands prf1 prf2
  1238       | (PThm (_, ((a, propa, _), _)), PThm (_, ((b, propb, _), _))) =>
  1239           a = b andalso propa = propb andalso matchrands prf1 prf2
  1240       | (PBound i, PBound j) => i = j andalso matchrands prf1 prf2
  1241       | (AbsP _, _) =>  true   (*because of possible eta equality*)
  1242       | (Abst _, _) =>  true
  1243       | (_, AbsP _) =>  true
  1244       | (_, Abst _) =>  true
  1245       | _ => false
  1246   end;
  1247 
  1248 
  1249 (**** rewriting on proof terms ****)
  1250 
  1251 val no_skel = PBound 0;
  1252 val normal_skel = Hyp (Var ((Name.uu, 0), propT));
  1253 
  1254 fun rewrite_prf tymatch (rules, procs) prf =
  1255   let
  1256     fun rew _ (Abst (_, _, body) % SOME t) = SOME (prf_subst_bounds [t] body, no_skel)
  1257       | rew _ (AbsP (_, _, body) %% prf) = SOME (prf_subst_pbounds [prf] body, no_skel)
  1258       | rew Ts prf =
  1259           (case get_first (fn r => r Ts prf) procs of
  1260             NONE => get_first (fn (prf1, prf2) => SOME (prf_subst
  1261               (match_proof Ts tymatch ([], (Vartab.empty, [])) (prf1, prf)) prf2, prf2)
  1262                  handle PMatch => NONE) (filter (could_unify prf o fst) rules)
  1263           | some => some);
  1264 
  1265     fun rew0 Ts (prf as AbsP (_, _, prf' %% PBound 0)) =
  1266           if prf_loose_Pbvar1 prf' 0 then rew Ts prf
  1267           else
  1268             let val prf'' = incr_pboundvars (~1) 0 prf'
  1269             in SOME (the_default (prf'', no_skel) (rew Ts prf'')) end
  1270       | rew0 Ts (prf as Abst (_, _, prf' % SOME (Bound 0))) =
  1271           if prf_loose_bvar1 prf' 0 then rew Ts prf
  1272           else
  1273             let val prf'' = incr_pboundvars 0 (~1) prf'
  1274             in SOME (the_default (prf'', no_skel) (rew Ts prf'')) end
  1275       | rew0 Ts prf = rew Ts prf;
  1276 
  1277     fun rew1 _ (Hyp (Var _)) _ = NONE
  1278       | rew1 Ts skel prf = (case rew2 Ts skel prf of
  1279           SOME prf1 => (case rew0 Ts prf1 of
  1280               SOME (prf2, skel') => SOME (the_default prf2 (rew1 Ts skel' prf2))
  1281             | NONE => SOME prf1)
  1282         | NONE => (case rew0 Ts prf of
  1283               SOME (prf1, skel') => SOME (the_default prf1 (rew1 Ts skel' prf1))
  1284             | NONE => NONE))
  1285 
  1286     and rew2 Ts skel (prf % SOME t) = (case prf of
  1287             Abst (_, _, body) =>
  1288               let val prf' = prf_subst_bounds [t] body
  1289               in SOME (the_default prf' (rew2 Ts no_skel prf')) end
  1290           | _ => (case rew1 Ts (case skel of skel' % _ => skel' | _ => no_skel) prf of
  1291               SOME prf' => SOME (prf' % SOME t)
  1292             | NONE => NONE))
  1293       | rew2 Ts skel (prf % NONE) = Option.map (fn prf' => prf' % NONE)
  1294           (rew1 Ts (case skel of skel' % _ => skel' | _ => no_skel) prf)
  1295       | rew2 Ts skel (prf1 %% prf2) = (case prf1 of
  1296             AbsP (_, _, body) =>
  1297               let val prf' = prf_subst_pbounds [prf2] body
  1298               in SOME (the_default prf' (rew2 Ts no_skel prf')) end
  1299           | _ =>
  1300             let val (skel1, skel2) = (case skel of
  1301                 skel1 %% skel2 => (skel1, skel2)
  1302               | _ => (no_skel, no_skel))
  1303             in case rew1 Ts skel1 prf1 of
  1304                 SOME prf1' => (case rew1 Ts skel2 prf2 of
  1305                     SOME prf2' => SOME (prf1' %% prf2')
  1306                   | NONE => SOME (prf1' %% prf2))
  1307               | NONE => (case rew1 Ts skel2 prf2 of
  1308                     SOME prf2' => SOME (prf1 %% prf2')
  1309                   | NONE => NONE)
  1310             end)
  1311       | rew2 Ts skel (Abst (s, T, prf)) = (case rew1 (the_default dummyT T :: Ts)
  1312               (case skel of Abst (_, _, skel') => skel' | _ => no_skel) prf of
  1313             SOME prf' => SOME (Abst (s, T, prf'))
  1314           | NONE => NONE)
  1315       | rew2 Ts skel (AbsP (s, t, prf)) = (case rew1 Ts
  1316               (case skel of AbsP (_, _, skel') => skel' | _ => no_skel) prf of
  1317             SOME prf' => SOME (AbsP (s, t, prf'))
  1318           | NONE => NONE)
  1319       | rew2 _ _ _ = NONE;
  1320 
  1321   in the_default prf (rew1 [] no_skel prf) end;
  1322 
  1323 fun rewrite_proof thy = rewrite_prf (fn (tyenv, f) =>
  1324   Sign.typ_match thy (f ()) tyenv handle Type.TYPE_MATCH => raise PMatch);
  1325 
  1326 fun rewrite_proof_notypes rews = rewrite_prf fst rews;
  1327 
  1328 
  1329 (**** theory data ****)
  1330 
  1331 structure Data = Theory_Data
  1332 (
  1333   type T =
  1334     (stamp * (proof * proof)) list *
  1335     (stamp * (typ list -> proof -> (proof * proof) option)) list;
  1336 
  1337   val empty = ([], []);
  1338   val extend = I;
  1339   fun merge ((rules1, procs1), (rules2, procs2)) : T =
  1340     (AList.merge (op =) (K true) (rules1, rules2),
  1341       AList.merge (op =) (K true) (procs1, procs2));
  1342 );
  1343 
  1344 fun get_data thy = let val (rules, procs) = Data.get thy in (map #2 rules, map #2 procs) end;
  1345 fun rew_proof thy = rewrite_prf fst (get_data thy);
  1346 
  1347 fun add_prf_rrule r = (Data.map o apfst) (cons (stamp (), r));
  1348 fun add_prf_rproc p = (Data.map o apsnd) (cons (stamp (), p));
  1349 
  1350 
  1351 (***** promises *****)
  1352 
  1353 fun promise_proof thy i prop =
  1354   let
  1355     val _ = prop |> Term.exists_subterm (fn t =>
  1356       (Term.is_Free t orelse Term.is_Var t) andalso
  1357         raise Fail ("promise_proof: illegal variable " ^ Syntax.string_of_term_global thy t));
  1358     val _ = prop |> Term.exists_type (Term.exists_subtype
  1359       (fn TFree (a, _) => raise Fail ("promise_proof: illegal type variable " ^ quote a)
  1360         | _ => false));
  1361   in Promise (i, prop, map TVar (Term.add_tvars prop [])) end;
  1362 
  1363 fun fulfill_norm_proof thy ps body0 =
  1364   let
  1365     val PBody {oracles = oracles0, thms = thms0, proof = proof0} = body0;
  1366     val oracles = fold (fn (_, PBody {oracles, ...}) => merge_oracles oracles) ps oracles0;
  1367     val thms = fold (fn (_, PBody {thms, ...}) => merge_thms thms) ps thms0;
  1368     val proofs = fold (fn (i, PBody {proof, ...}) => Inttab.update (i, proof)) ps Inttab.empty;
  1369 
  1370     fun fill (Promise (i, prop, Ts)) =
  1371           (case Inttab.lookup proofs i of
  1372             NONE => NONE
  1373           | SOME prf => SOME (instantiate (Term.add_tvars prop [] ~~ Ts, []) prf, normal_skel))
  1374       | fill _ = NONE;
  1375     val (rules, procs) = get_data thy;
  1376     val proof = rewrite_prf fst (rules, K fill :: procs) proof0;
  1377   in PBody {oracles = oracles, thms = thms, proof = proof} end;
  1378 
  1379 fun fulfill_proof_future _ [] postproc body = Future.value (postproc body)
  1380   | fulfill_proof_future thy promises postproc body =
  1381       Future.fork_deps (map snd promises) (fn () =>
  1382         postproc (fulfill_norm_proof thy (map (apsnd Future.join) promises) body));
  1383 
  1384 
  1385 (***** abstraction over sort constraints *****)
  1386 
  1387 fun unconstrainT_prf thy (atyp_map, constraints) =
  1388   let
  1389     fun hyp_map hyp =
  1390       (case AList.lookup (op =) constraints hyp of
  1391         SOME t => Hyp t
  1392       | NONE => raise Fail "unconstrainT_prf: missing constraint");
  1393 
  1394     val typ = Term_Subst.map_atypsT_same (Type.strip_sorts o atyp_map);
  1395     fun ofclass (ty, c) =
  1396       let val ty' = Term.map_atyps atyp_map ty;
  1397       in the_single (of_sort_proof thy hyp_map (ty', [c])) end;
  1398   in
  1399     Same.commit (map_proof_same (Term_Subst.map_types_same typ) typ ofclass)
  1400     #> fold_rev (implies_intr_proof o snd) constraints
  1401   end;
  1402 
  1403 fun unconstrainT_body thy constrs (PBody {oracles, thms, proof}) =
  1404   PBody
  1405    {oracles = oracles,  (* FIXME merge (!), unconstrain (!?!) *)
  1406     thms = thms,  (* FIXME merge (!) *)
  1407     proof = unconstrainT_prf thy constrs proof};
  1408 
  1409 
  1410 (***** theorems *****)
  1411 
  1412 fun prepare_thm_proof do_unconstrain thy name shyps hyps concl promises body =
  1413   let
  1414     val PBody {oracles = oracles0, thms = thms0, proof = prf} = body;
  1415     val prop = Logic.list_implies (hyps, concl);
  1416     val nvs = needed_vars prop;
  1417     val args = map (fn (v as Var (ixn, _)) =>
  1418         if member (op =) nvs ixn then SOME v else NONE) (vars_of prop) @
  1419       map SOME (frees_of prop);
  1420 
  1421     val (postproc, ofclasses, prop1, args1) =
  1422       if do_unconstrain then
  1423         let
  1424           val ((atyp_map, constraints), prop1) = Logic.unconstrainT shyps prop;
  1425           val postproc = unconstrainT_body thy (atyp_map, constraints);
  1426           val args1 =
  1427             (map o Option.map o Term.map_types o Term.map_atyps)
  1428               (Type.strip_sorts o atyp_map) args;
  1429         in (postproc, map (OfClass o fst) constraints, prop1, args1) end
  1430       else (I, [], prop, args);
  1431     val argsP = ofclasses @ map Hyp hyps;
  1432 
  1433     val proof0 =
  1434       if ! proofs = 2 then
  1435         #4 (shrink_proof [] 0 (rew_proof thy (fold_rev implies_intr_proof hyps prf)))
  1436       else MinProof;
  1437     val body0 = PBody {oracles = oracles0, thms = thms0, proof = proof0};
  1438 
  1439     fun new_prf () = (serial (), fulfill_proof_future thy promises postproc body0);
  1440     val (i, body') =
  1441       (case strip_combt (fst (strip_combP prf)) of
  1442         (PThm (i, ((old_name, prop', NONE), body')), args') =>
  1443           if (old_name = "" orelse old_name = name) andalso prop1 = prop' andalso args = args'
  1444           then (i, body')
  1445           else new_prf ()
  1446       | _ => new_prf ());
  1447     val head = PThm (i, ((name, prop1, NONE), body'));
  1448   in ((i, (name, prop1, body')), head, args, argsP, args1) end;
  1449 
  1450 val unconstrain_thm_proofs = Unsynchronized.ref false;
  1451 
  1452 fun thm_proof thy name shyps hyps concl promises body =
  1453   let val (pthm, head, args, argsP, _) =
  1454     prepare_thm_proof (! unconstrain_thm_proofs) thy name shyps hyps concl promises body
  1455   in (pthm, proof_combP (proof_combt' (head, args), argsP)) end;
  1456 
  1457 fun unconstrain_thm_proof thy shyps concl promises body =
  1458   let
  1459     val (pthm, head, _, _, args) =
  1460       prepare_thm_proof true thy "" shyps [] concl promises body
  1461   in (pthm, proof_combt' (head, args)) end;
  1462 
  1463 
  1464 fun get_name hyps prop prf =
  1465   let val prop = Logic.list_implies (hyps, prop) in
  1466     (case strip_combt (fst (strip_combP prf)) of
  1467       (PThm (_, ((name, prop', _), _)), _) => if prop = prop' then name else ""
  1468     | _ => "")
  1469   end;
  1470 
  1471 fun get_name_unconstrained shyps hyps prop prf =
  1472   let val (_, prop) = Logic.unconstrainT shyps (Logic.list_implies (hyps, prop)) in
  1473     (case strip_combt (fst (strip_combP prf)) of
  1474       (PThm (_, ((name, prop', _), _)), _) => if prop = prop' then name else ""
  1475     | _ => "")
  1476   end;
  1477 
  1478 fun guess_name (PThm (_, ((name, _, _), _))) = name
  1479   | guess_name (prf %% Hyp _) = guess_name prf
  1480   | guess_name (prf %% OfClass _) = guess_name prf
  1481   | guess_name (prf % NONE) = guess_name prf
  1482   | guess_name (prf % SOME (Var _)) = guess_name prf
  1483   | guess_name _ = "";
  1484 
  1485 end;
  1486 
  1487 structure Basic_Proofterm : BASIC_PROOFTERM = Proofterm;
  1488 open Basic_Proofterm;