src/Pure/PIDE/command.ML
author wenzelm
Fri Jul 12 12:04:16 2013 +0200 (2013-07-12 ago)
changeset 52607 33a133d50616
parent 52606 0d68d108d7e0
child 52609 c8f8c29193de
permissions -rw-r--r--
clarified execution: maintain running execs only, check "stable" separately via memo (again);
tuned signatures;
     1 (*  Title:      Pure/PIDE/command.ML
     2     Author:     Makarius
     3 
     4 Prover command execution: read -- eval -- print.
     5 *)
     6 
     7 signature COMMAND =
     8 sig
     9   val read: (unit -> theory) -> Token.T list -> Toplevel.transition
    10   type eval
    11   val eval_eq: eval * eval -> bool
    12   val eval_result_state: eval -> Toplevel.state
    13   val eval_stable: eval -> bool
    14   val eval: (unit -> theory) -> Token.T list -> eval -> eval
    15   type print
    16   val print: bool -> string -> eval -> print list -> print list option
    17   type print_fn = Toplevel.transition -> Toplevel.state -> unit
    18   val print_function: {name: string, pri: int, persistent: bool} ->
    19     ({command_name: string} -> print_fn option) -> unit
    20   val no_print_function: string -> unit
    21   type exec = eval * print list
    22   val no_exec: exec
    23   val exec_ids: exec option -> Document_ID.exec list
    24   val exec: Document_ID.execution -> exec -> unit
    25 end;
    26 
    27 structure Command: COMMAND =
    28 struct
    29 
    30 (** memo results -- including physical interrupts! **)
    31 
    32 datatype 'a expr =
    33   Expr of Document_ID.exec * (unit -> 'a) |
    34   Result of 'a Exn.result;
    35 
    36 abstype 'a memo = Memo of 'a expr Synchronized.var
    37 with
    38 
    39 fun memo exec_id e = Memo (Synchronized.var "Command.memo" (Expr (exec_id, e)));
    40 fun memo_value a = Memo (Synchronized.var "Command.memo" (Result (Exn.Res a)));
    41 
    42 fun memo_result (Memo v) =
    43   (case Synchronized.value v of
    44     Expr (exec_id, _) => error ("Unfinished execution result: " ^ Document_ID.print exec_id)
    45   | Result res => Exn.release res);
    46 
    47 fun memo_stable (Memo v) =
    48   (case Synchronized.value v of
    49    Expr _ => true
    50  | Result res => not (Exn.is_interrupt_exn res));
    51 
    52 fun memo_exec execution_id (Memo v) =
    53   (case Synchronized.value v of
    54     Result res => res
    55   | Expr _ =>
    56       Synchronized.timed_access v (fn _ => SOME Time.zeroTime)
    57         (fn Result res => SOME (res, Result res)
    58           | expr as Expr (exec_id, e) =>
    59               uninterruptible (fn restore_attributes => fn () =>
    60                 if Execution.running execution_id exec_id then
    61                   let
    62                     val res = Exn.capture (restore_attributes e) ();
    63                     val _ = Execution.finished exec_id;
    64                   in SOME (res, Result res) end
    65                 else SOME (Exn.interrupt_exn, expr)) ())
    66       |> (fn NONE => error "Concurrent execution attempt" | SOME res => res))
    67   |> Exn.release |> ignore;
    68 
    69 fun memo_fork params execution_id (Memo v) =
    70   (case Synchronized.value v of
    71     Result _ => ()
    72   | _ => ignore ((singleton o Future.forks) params (fn () => memo_exec execution_id (Memo v))));
    73 
    74 end;
    75 
    76 
    77 
    78 (** main phases of execution **)
    79 
    80 (* read *)
    81 
    82 fun read init span =
    83   let
    84     val outer_syntax = #2 (Outer_Syntax.get_syntax ());
    85     val command_reports = Outer_Syntax.command_reports outer_syntax;
    86 
    87     val proper_range =
    88       Position.set_range (Token.position_range_of (#1 (take_suffix Token.is_improper span)));
    89     val pos =
    90       (case find_first Token.is_command span of
    91         SOME tok => Token.position_of tok
    92       | NONE => proper_range);
    93 
    94     val (is_malformed, token_reports) = Thy_Syntax.reports_of_tokens span;
    95     val _ = Position.reports_text (token_reports @ maps command_reports span);
    96   in
    97     if is_malformed then Toplevel.malformed pos "Malformed command syntax"
    98     else
    99       (case Outer_Syntax.read_spans outer_syntax span of
   100         [tr] =>
   101           if Keyword.is_control (Toplevel.name_of tr) then
   102             Toplevel.malformed pos "Illegal control command"
   103           else Toplevel.modify_init init tr
   104       | [] => Toplevel.ignored (Position.set_range (Token.position_range_of span))
   105       | _ => Toplevel.malformed proper_range "Exactly one command expected")
   106       handle ERROR msg => Toplevel.malformed proper_range msg
   107   end;
   108 
   109 
   110 (* eval *)
   111 
   112 type eval_state =
   113   {failed: bool, malformed: bool, command: Toplevel.transition, state: Toplevel.state};
   114 val init_eval_state =
   115   {failed = false, malformed = false, command = Toplevel.empty, state = Toplevel.toplevel};
   116 
   117 datatype eval = Eval of {exec_id: Document_ID.exec, eval_process: eval_state memo};
   118 
   119 fun eval_eq (Eval {exec_id, ...}, Eval {exec_id = exec_id', ...}) = exec_id = exec_id';
   120 
   121 fun eval_result (Eval {eval_process, ...}) = memo_result eval_process;
   122 val eval_result_state = #state o eval_result;
   123 
   124 fun eval_stable (Eval {exec_id, eval_process}) =
   125   Goal.stable_futures exec_id andalso memo_stable eval_process;
   126 
   127 local
   128 
   129 fun run int tr st =
   130   if Goal.future_enabled () andalso Keyword.is_diag (Toplevel.name_of tr) then
   131     (Goal.fork_params {name = "Toplevel.diag", pos = Toplevel.pos_of tr, pri = ~1}
   132       (fn () => Toplevel.command_exception int tr st); ([], SOME st))
   133   else Toplevel.command_errors int tr st;
   134 
   135 fun check_cmts span tr st' =
   136   Toplevel.setmp_thread_position tr
   137     (fn () =>
   138       Outer_Syntax.side_comments span |> maps (fn cmt =>
   139         (Thy_Output.check_text (Token.source_position_of cmt) st'; [])
   140           handle exn => ML_Compiler.exn_messages_ids exn)) ();
   141 
   142 fun proof_status tr st =
   143   (case try Toplevel.proof_of st of
   144     SOME prf => Toplevel.status tr (Proof.status_markup prf)
   145   | NONE => ());
   146 
   147 fun eval_state span tr ({malformed, state = st, ...}: eval_state) =
   148   if malformed then
   149     {failed = true, malformed = malformed, command = tr, state = Toplevel.toplevel}
   150   else
   151     let
   152       val malformed' = Toplevel.is_malformed tr;
   153       val is_init = Toplevel.is_init tr;
   154       val is_proof = Keyword.is_proof (Toplevel.name_of tr);
   155 
   156       val _ = Multithreading.interrupted ();
   157       val _ = Toplevel.status tr Markup.running;
   158       val (errs1, result) = run (is_init orelse is_proof) (Toplevel.set_print false tr) st;
   159       val errs2 = (case result of NONE => [] | SOME st' => check_cmts span tr st');
   160       val errs = errs1 @ errs2;
   161       val _ = Toplevel.status tr Markup.finished;
   162       val _ = List.app (Future.error_msg (Toplevel.pos_of tr)) errs;
   163     in
   164       (case result of
   165         NONE =>
   166           let
   167             val _ = if null errs then Exn.interrupt () else ();
   168             val _ = Toplevel.status tr Markup.failed;
   169           in {failed = true, malformed = malformed', command = tr, state = st} end
   170       | SOME st' =>
   171           let
   172             val _ = proof_status tr st';
   173           in {failed = false, malformed = malformed', command = tr, state = st'} end)
   174     end;
   175 
   176 in
   177 
   178 fun eval init span eval0 =
   179   let
   180     val exec_id = Document_ID.make ();
   181     fun process () =
   182       let
   183         val tr =
   184           Position.setmp_thread_data (Position.id_only (Document_ID.print exec_id))
   185             (fn () => read init span |> Toplevel.exec_id exec_id) ();
   186       in eval_state span tr (eval_result eval0) end;
   187   in Eval {exec_id = exec_id, eval_process = memo exec_id process} end;
   188 
   189 end;
   190 
   191 
   192 (* print *)
   193 
   194 datatype print = Print of
   195  {name: string, pri: int, persistent: bool,
   196   exec_id: Document_ID.exec, print_process: unit memo};
   197 
   198 type print_fn = Toplevel.transition -> Toplevel.state -> unit;
   199 
   200 local
   201 
   202 type print_function = string * (int * bool * ({command_name: string} -> print_fn option));
   203 val print_functions = Synchronized.var "Command.print_functions" ([]: print_function list);
   204 
   205 fun print_error tr e =
   206   (Toplevel.setmp_thread_position tr o Runtime.controlled_execution) e () handle exn =>
   207     List.app (Future.error_msg (Toplevel.pos_of tr)) (ML_Compiler.exn_messages_ids exn);
   208 
   209 fun print_eq (Print {exec_id, ...}, Print {exec_id = exec_id', ...}) = exec_id = exec_id';
   210 
   211 fun print_stable (Print {exec_id, print_process, ...}) =
   212   Goal.stable_futures exec_id andalso memo_stable print_process;
   213 
   214 fun print_persistent (Print {persistent, ...}) = persistent;
   215 
   216 in
   217 
   218 fun print command_visible command_name eval old_prints =
   219   let
   220     fun new_print (name, (pri, persistent, get_fn)) =
   221       let
   222         fun make_print strict print_fn =
   223           let
   224             val exec_id = Document_ID.make ();
   225             fun process () =
   226               let
   227                 val {failed, command, state = st', ...} = eval_result eval;
   228                 val tr = Toplevel.exec_id exec_id command;
   229               in
   230                 if failed andalso not strict then ()
   231                 else print_error tr (fn () => print_fn tr st')
   232               end;
   233           in
   234            Print {
   235              name = name, pri = pri, persistent = persistent,
   236              exec_id = exec_id, print_process = memo exec_id process}
   237           end;
   238       in
   239         (case Exn.capture (Runtime.controlled_execution get_fn) {command_name = command_name} of
   240           Exn.Res NONE => NONE
   241         | Exn.Res (SOME print_fn) => SOME (make_print false print_fn)
   242         | Exn.Exn exn => SOME (make_print true (fn _ => fn _ => reraise exn)))
   243       end;
   244 
   245     val new_prints =
   246       if command_visible then
   247         rev (Synchronized.value print_functions) |> map_filter (fn pr =>
   248           (case find_first (fn Print {name, ...} => name = fst pr) old_prints of
   249             SOME print => if print_stable print then SOME print else new_print pr
   250           | NONE => new_print pr))
   251       else filter (fn print => print_persistent print andalso print_stable print) old_prints;
   252   in
   253     if eq_list print_eq (old_prints, new_prints) then NONE else SOME new_prints
   254   end;
   255 
   256 fun print_function {name, pri, persistent} f =
   257   Synchronized.change print_functions (fn funs =>
   258    (if not (AList.defined (op =) funs name) then ()
   259     else warning ("Redefining command print function: " ^ quote name);
   260     AList.update (op =) (name, (pri, persistent, f)) funs));
   261 
   262 fun no_print_function name =
   263   Synchronized.change print_functions (filter_out (equal name o #1));
   264 
   265 end;
   266 
   267 val _ =
   268   print_function {name = "print_state", pri = 0, persistent = true}
   269     (fn {command_name} => SOME (fn tr => fn st' =>
   270       let
   271         val is_init = Keyword.is_theory_begin command_name;
   272         val is_proof = Keyword.is_proof command_name;
   273         val do_print =
   274           not is_init andalso
   275             (Toplevel.print_of tr orelse (is_proof andalso Toplevel.is_proof st'));
   276       in if do_print then Toplevel.print_state false st' else () end));
   277 
   278 
   279 (* combined execution *)
   280 
   281 type exec = eval * print list;
   282 val no_exec: exec =
   283   (Eval {exec_id = Document_ID.none, eval_process = memo_value init_eval_state}, []);
   284 
   285 fun exec_ids NONE = []
   286   | exec_ids (SOME (Eval {exec_id, ...}, prints)) =
   287       exec_id :: map (fn Print {exec_id, ...} => exec_id) prints;
   288 
   289 local
   290 
   291 fun run_print execution_id (Print {name, pri, print_process, ...}) =
   292   (if Multithreading.enabled () then
   293     memo_fork {name = name, group = NONE, deps = [], pri = pri, interrupts = true}
   294   else memo_exec) execution_id print_process;
   295 
   296 in
   297 
   298 fun exec execution_id (Eval {eval_process, ...}, prints) =
   299   (memo_exec execution_id eval_process; List.app (run_print execution_id) prints);
   300 
   301 end;
   302 
   303 end;
   304