src/Pure/Isar/proof_context.ML
author wenzelm
Wed Dec 05 03:18:03 2001 +0100 (2001-12-05 ago)
changeset 12385 389d11fb62c8
parent 12309 03e9287be350
child 12414 61e1681b0b5d
permissions -rw-r--r--
removed unused functionality (weight etc.);
     1 (*  Title:      Pure/Isar/proof_context.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4     License:    GPL (GNU GENERAL PUBLIC LICENSE)
     5 
     6 Proof context information.
     7 *)
     8 
     9 signature PROOF_CONTEXT =
    10 sig
    11   type context
    12   type exporter
    13   exception CONTEXT of string * context
    14   val theory_of: context -> theory
    15   val sign_of: context -> Sign.sg
    16   val syntax_of: context -> Syntax.syntax * string list * string list
    17   val fixed_names_of: context -> string list
    18   val assumptions_of: context -> (cterm list * exporter) list
    19   val prems_of: context -> thm list
    20   val print_proof_data: theory -> unit
    21   val init: theory -> context
    22   val is_fixed: context -> string -> bool
    23   val read_typ: context -> string -> typ
    24   val read_typ_no_norm: context -> string -> typ
    25   val cert_typ: context -> typ -> typ
    26   val cert_typ_no_norm: context -> typ -> typ
    27   val get_skolem: context -> string -> string
    28   val intern_skolem: context -> term -> term
    29   val extern_skolem: context -> term -> term
    30   val read_termTs: context -> (string * typ) list -> term list * (indexname * typ) list
    31   val read_term: context -> string -> term
    32   val read_prop: context -> string -> term
    33   val read_prop_schematic: context -> string -> term
    34   val read_terms: context -> string list -> term list
    35   val read_termT_pats: context -> (string * typ) list -> term list
    36   val read_term_pats: typ -> context -> string list -> term list
    37   val read_prop_pats: context -> string list -> term list
    38   val cert_term: context -> term -> term
    39   val cert_prop: context -> term -> term
    40   val cert_term_pats: typ -> context -> term list -> term list
    41   val cert_prop_pats: context -> term list -> term list
    42   val declare_term: term -> context -> context
    43   val declare_terms: term list -> context -> context
    44   val warn_extra_tfrees: context -> context -> context
    45   val generalizeT: context -> context -> typ -> typ
    46   val generalize: context -> context -> term -> term
    47   val find_free: term -> string -> term option
    48   val export: bool -> context -> context -> thm -> thm Seq.seq
    49   val drop_schematic: indexname * term option -> indexname * term option
    50   val add_binds: (indexname * string option) list -> context -> context
    51   val add_binds_i: (indexname * term option) list -> context -> context
    52   val auto_bind_goal: term list -> context -> context
    53   val auto_bind_facts: term list -> context -> context
    54   val match_bind: bool -> (string list * string) list -> context -> context
    55   val match_bind_i: bool -> (term list * term) list -> context -> context
    56   val read_propp: context * (string * (string list * string list)) list list
    57     -> context * (term * (term list * term list)) list list
    58   val cert_propp: context * (term * (term list * term list)) list list
    59     -> context * (term * (term list * term list)) list list
    60   val read_propp_schematic: context * (string * (string list * string list)) list list
    61     -> context * (term * (term list * term list)) list list
    62   val cert_propp_schematic: context * (term * (term list * term list)) list list
    63     -> context * (term * (term list * term list)) list list
    64   val bind_propp: context * (string * (string list * string list)) list list
    65     -> context * (term list list * (context -> context))
    66   val bind_propp_i: context * (term * (term list * term list)) list list
    67     -> context * (term list list * (context -> context))
    68   val bind_propp_schematic: context * (string * (string list * string list)) list list
    69     -> context * (term list list * (context -> context))
    70   val bind_propp_schematic_i: context * (term * (term list * term list)) list list
    71     -> context * (term list list * (context -> context))
    72   val get_thm: context -> string -> thm
    73   val get_thm_closure: context -> string -> thm
    74   val get_thms: context -> string -> thm list
    75   val get_thms_closure: context -> string -> thm list
    76   val cond_extern: context -> string -> xstring
    77   val qualified: (context -> context) -> context -> context
    78   val put_thm: string * thm -> context -> context
    79   val put_thms: string * thm list -> context -> context
    80   val put_thmss: (string * thm list) list -> context -> context
    81   val reset_thms: string -> context -> context
    82   val have_thmss:
    83     ((string * context attribute list) * (thm list * context attribute list) list) list ->
    84       context -> context * (string * thm list) list
    85   val export_assume: exporter
    86   val export_presume: exporter
    87   val cert_def: context -> term -> string * term
    88   val export_def: exporter
    89   val assume: exporter
    90     -> ((string * context attribute list) * (string * (string list * string list)) list) list
    91     -> context -> context * (string * thm list) list
    92   val assume_i: exporter
    93     -> ((string * context attribute list) * (term * (term list * term list)) list) list
    94     -> context -> context * (string * thm list) list
    95   val read_vars: context * (string list * string option) -> context * (string list * typ option)
    96   val cert_vars: context * (string list * typ option) -> context * (string list * typ option)
    97   val fix: (string list * string option) list -> context -> context
    98   val fix_i: (string list * typ option) list -> context -> context
    99   val fix_direct: (string list * typ option) list -> context -> context
   100   val fix_frees: term list -> context -> context
   101   val bind_skolem: context -> string list -> term -> term
   102   val get_case: context -> string -> string option list -> RuleCases.T
   103   val add_cases: (string * RuleCases.T) list -> context -> context
   104   val apply_case: RuleCases.T -> context -> context * ((indexname * term option) list * term list)
   105   val show_hyps: bool ref
   106   val add_syntax: (string * typ option * mixfix option) list -> context -> context
   107   val pretty_term: context -> term -> Pretty.T
   108   val pretty_typ: context -> typ -> Pretty.T
   109   val pretty_sort: context -> sort -> Pretty.T
   110   val pretty_thm: context -> thm -> Pretty.T
   111   val pretty_thms: context -> thm list -> Pretty.T
   112   val string_of_term: context -> term -> string
   113   val verbose: bool ref
   114   val setmp_verbose: ('a -> 'b) -> 'a -> 'b
   115   val print_syntax: context -> unit
   116   val print_binds: context -> unit
   117   val print_lthms: context -> unit
   118   val print_cases: context -> unit
   119   val prems_limit: int ref
   120   val pretty_asms: context -> Pretty.T list
   121   val pretty_context: context -> Pretty.T list
   122   val setup: (theory -> theory) list
   123 end;
   124 
   125 signature PRIVATE_PROOF_CONTEXT =
   126 sig
   127   include PROOF_CONTEXT
   128   val init_data: Object.kind -> (theory -> Object.T) * (context -> Object.T -> unit)
   129     -> theory -> theory
   130   val print_data: Object.kind -> context -> unit
   131   val get_data: Object.kind -> (Object.T -> 'a) -> context -> 'a
   132   val put_data: Object.kind -> ('a -> Object.T) -> 'a -> context -> context
   133 end;
   134 
   135 structure ProofContext: PRIVATE_PROOF_CONTEXT =
   136 struct
   137 
   138 
   139 (** datatype context **)
   140 
   141 type exporter = bool -> cterm list -> thm -> thm Seq.seq;
   142 
   143 datatype context =
   144   Context of
   145    {thy: theory,                                              (*current theory*)
   146     syntax: Syntax.syntax * string list * string list,        (*syntax with structs and mixfixed*)
   147     data: Object.T Symtab.table,                              (*user data*)
   148     asms:
   149       ((cterm list * exporter) list *                         (*assumes: A ==> _*)
   150         (string * thm list) list) *
   151       (string * string) list,                                 (*fixes: !!x. _*)
   152     binds: (term * typ) option Vartab.table,                  (*term bindings*)
   153     thms: bool * NameSpace.T * thm list option Symtab.table,  (*local thms*)
   154     cases: (string * RuleCases.T) list,                       (*local contexts*)
   155     defs:
   156       typ Vartab.table *                                      (*type constraints*)
   157       sort Vartab.table *                                     (*default sorts*)
   158       string list *                                           (*used type variables*)
   159       term list Symtab.table};                                (*type variable occurrences*)
   160 
   161 exception CONTEXT of string * context;
   162 
   163 
   164 fun make_context (thy, syntax, data, asms, binds, thms, cases, defs) =
   165   Context {thy = thy, syntax = syntax, data = data, asms = asms, binds = binds,
   166     thms = thms, cases = cases, defs = defs};
   167 
   168 fun map_context f (Context {thy, syntax, data, asms, binds, thms, cases, defs}) =
   169   make_context (f (thy, syntax, data, asms, binds, thms, cases, defs));
   170 
   171 fun theory_of (Context {thy, ...}) = thy;
   172 val sign_of = Theory.sign_of o theory_of;
   173 fun syntax_of (Context {syntax, ...}) = syntax;
   174 
   175 fun fixes_of (Context {asms = (_, fixes), ...}) = fixes;
   176 val fixed_names_of = map #2 o fixes_of;
   177 fun is_fixed ctxt x = exists (equal x o #2) (fixes_of ctxt);
   178 fun type_occs (Context {defs = (_, _, _, tab), ...}) = tab;
   179 
   180 fun assumptions_of (Context {asms = ((asms, _), _), ...}) = asms;
   181 fun prems_of (Context {asms = ((_, prems), _), ...}) = flat (map #2 prems);
   182 
   183 
   184 
   185 (** user data **)
   186 
   187 (* errors *)
   188 
   189 fun of_theory thy = "\nof theory " ^ Sign.str_of_sg (Theory.sign_of thy);
   190 
   191 fun err_inconsistent kinds =
   192   error ("Attempt to merge different versions of " ^ commas_quote kinds ^ " proof data");
   193 
   194 fun err_dup_init thy kind =
   195   error ("Duplicate initialization of " ^ quote kind ^ " proof data" ^ of_theory thy);
   196 
   197 fun err_undef ctxt kind =
   198   raise CONTEXT ("Tried to access undefined " ^ quote kind ^ " proof data", ctxt);
   199 
   200 fun err_uninit ctxt kind =
   201   raise CONTEXT ("Tried to access uninitialized " ^ quote kind ^ " proof data" ^
   202     of_theory (theory_of ctxt), ctxt);
   203 
   204 fun err_access ctxt kind =
   205   raise CONTEXT ("Unauthorized access to " ^ quote kind ^ " proof data" ^
   206     of_theory (theory_of ctxt), ctxt);
   207 
   208 
   209 (* data kind 'Isar/proof_data' *)
   210 
   211 structure ProofDataDataArgs =
   212 struct
   213   val name = "Isar/proof_data";
   214   type T = (Object.kind * ((theory -> Object.T) * (context -> Object.T -> unit))) Symtab.table;
   215 
   216   val empty = Symtab.empty;
   217   val copy = I;
   218   val prep_ext = I;
   219   fun merge tabs = Symtab.merge (Object.eq_kind o pairself fst) tabs
   220     handle Symtab.DUPS kinds => err_inconsistent kinds;
   221   fun print _ tab = Pretty.writeln (Pretty.strs (map #1 (Symtab.dest tab)));
   222 end;
   223 
   224 structure ProofDataData = TheoryDataFun(ProofDataDataArgs);
   225 val print_proof_data = ProofDataData.print;
   226 
   227 
   228 (* init proof data *)
   229 
   230 fun init_data kind meths thy =
   231   let
   232     val name = Object.name_of_kind kind;
   233     val tab = Symtab.update_new ((name, (kind, meths)), ProofDataData.get thy)
   234       handle Symtab.DUP _ => err_dup_init thy name;
   235   in thy |> ProofDataData.put tab end;
   236 
   237 
   238 (* access data *)
   239 
   240 fun lookup_data (ctxt as Context {data, ...}) kind =
   241   let
   242     val thy = theory_of ctxt;
   243     val name = Object.name_of_kind kind;
   244   in
   245     (case Symtab.lookup (ProofDataData.get thy, name) of
   246       Some (k, meths) =>
   247         if Object.eq_kind (kind, k) then
   248           (case Symtab.lookup (data, name) of
   249             Some x => (x, meths)
   250           | None => err_undef ctxt name)
   251         else err_access ctxt name
   252     | None => err_uninit ctxt name)
   253   end;
   254 
   255 fun get_data kind f ctxt =
   256   let val (x, _) = lookup_data ctxt kind
   257   in f x handle Match => Object.kind_error kind end;
   258 
   259 fun print_data kind ctxt =
   260   let val (x, (_, prt)) = lookup_data ctxt kind
   261   in prt ctxt x end;
   262 
   263 fun put_data kind f x ctxt =
   264  (lookup_data ctxt kind;
   265   map_context (fn (thy, syntax, data, asms, binds, thms, cases, defs) =>
   266     (thy, syntax, Symtab.update ((Object.name_of_kind kind, f x), data),
   267       asms, binds, thms, cases, defs)) ctxt);
   268 
   269 
   270 (* init context *)
   271 
   272 fun init thy =
   273   let val data = Symtab.map (fn (_, (f, _)) => f thy) (ProofDataData.get thy) in
   274     make_context (thy, (Theory.syn_of thy, [], []), data, (([], []), []), Vartab.empty,
   275       (false, NameSpace.empty, Symtab.empty), [], (Vartab.empty, Vartab.empty, [], Symtab.empty))
   276   end;
   277 
   278 
   279 
   280 (** local syntax **)
   281 
   282 val fixedN = "\\<^fixed>";
   283 val structN = "\\<^struct>";
   284 
   285 fun the_struct structs i =
   286   if 1 <= i andalso i <= length structs then Library.nth_elem (i - 1, structs)
   287   else raise ERROR_MESSAGE ("Illegal reference to implicit structure #" ^ string_of_int i);
   288 
   289 
   290 (* print (ast) translations *)
   291 
   292 fun index_tr' 1 = Syntax.const "_noindex"
   293   | index_tr' i = Syntax.const "_index" $ Syntax.const (Library.string_of_int i);
   294 
   295 fun context_tr' ctxt =
   296   let
   297     val (_, structs, mixfixed) = syntax_of ctxt;
   298 
   299     fun tr' (t $ u) = tr' t $ tr' u
   300       | tr' (Abs (x, T, t)) = Abs (x, T, tr' t)
   301       | tr' (t as Free (x, T)) =
   302           let val i = Library.find_index (equal x) structs + 1 in
   303             if 1 <= i andalso i <= 9 then Syntax.const "_struct" $ index_tr' i
   304             else if x mem_string mixfixed then Const (fixedN ^ x, T)
   305             else t
   306           end
   307       | tr' a = a;
   308   in tr' end;
   309 
   310 fun index_ast_tr' structs s =
   311   (case Syntax.read_nat s of
   312     Some i => Syntax.Variable (the_struct structs i handle ERROR_MESSAGE _ => raise Match)
   313   | None => raise Match);
   314 
   315 fun struct_ast_tr' structs [Syntax.Constant "_noindex"] =
   316       index_ast_tr' structs "1"
   317   | struct_ast_tr' structs [Syntax.Appl [Syntax.Constant "_index", Syntax.Constant s]] =
   318       index_ast_tr' structs s
   319   | struct_ast_tr' _ _ = raise Match;
   320 
   321 
   322 (* parse translations *)
   323 
   324 fun fixed_tr x = (fixedN ^ x, curry Term.list_comb (Syntax.free x));
   325 
   326 fun index_tr (Const ("_noindex", _)) = 1
   327   | index_tr (t as (Const ("_index", _) $ Const (s, _))) =
   328       (case Syntax.read_nat s of Some n => n | None => raise TERM ("index_tr", [t]))
   329   | index_tr t = raise TERM ("index_tr", [t]);
   330 
   331 fun struct_tr structs (idx :: ts) = Syntax.free (the_struct structs (index_tr idx))
   332   | struct_tr _ ts = raise TERM ("struct_tr", ts);
   333 
   334 
   335 (* add_syntax and syn_of *)
   336 
   337 local
   338 
   339 val aT = TFree ("'a", logicS);
   340 
   341 fun mixfix x None mx = (fixedN ^ x, replicate (Syntax.mixfix_args mx) aT ---> aT, mx)
   342   | mixfix x (Some T) mx = (fixedN ^ x, T, mx);
   343 
   344 fun prep_mixfix (_, _, None) = None
   345   | prep_mixfix (x, opt_T, Some mx) = Some (mixfix x opt_T mx);
   346 
   347 fun prep_mixfix' (_, _, None) = None
   348   | prep_mixfix' (x, _, Some Syntax.NoSyn) = None
   349   | prep_mixfix' (x, opt_T, _) = Some (x, mixfix x opt_T (Syntax.Delimfix x));
   350 
   351 fun prep_struct (x, _, None) = Some x
   352   | prep_struct _ = None;
   353 
   354 in
   355 
   356 fun add_syntax decls =
   357   map_context (fn (thy, (syn, structs, mixfixed), data, asms, binds, thms, cases, defs) =>
   358     let
   359       val structs' = structs @ mapfilter prep_struct decls;
   360       val mxs = mapfilter prep_mixfix decls;
   361       val (fixed, mxs_output) = Library.split_list (mapfilter prep_mixfix' decls);
   362       val trs = map fixed_tr fixed;
   363       val syn' = syn
   364         |> Syntax.extend_const_gram ("", false) mxs_output
   365         |> Syntax.extend_const_gram ("", true) mxs
   366         |> Syntax.extend_trfuns ([], trs, [], []);
   367     in (thy, (syn', structs', fixed @ mixfixed), data, asms, binds, thms, cases, defs) end)
   368 
   369 fun syn_of (Context {syntax = (syn, structs, _), ...}) =
   370   syn |> Syntax.extend_trfuns
   371     ([], [("_struct", struct_tr structs)], [], [("_struct", struct_ast_tr' structs)]);
   372 
   373 end;
   374 
   375 
   376 
   377 (** default sorts and types **)
   378 
   379 fun def_sort (Context {defs = (_, sorts, _, _), ...}) xi = Vartab.lookup (sorts, xi);
   380 
   381 fun def_type (Context {binds, defs = (types, _, _, _), ...}) is_pat xi =
   382   (case Vartab.lookup (types, xi) of
   383     None =>
   384       if is_pat then None else
   385         (case Vartab.lookup (binds, xi) of
   386           Some (Some (_, T)) => Some (TypeInfer.polymorphicT T)
   387         | _ => None)
   388   | some => some);
   389 
   390 
   391 
   392 (** prepare types **)
   393 
   394 local
   395 
   396 fun read_typ_aux read ctxt s =
   397   transform_error (read (syn_of ctxt) (sign_of ctxt, def_sort ctxt)) s
   398     handle ERROR_MESSAGE msg => raise CONTEXT (msg, ctxt);
   399 
   400 fun cert_typ_aux cert ctxt raw_T =
   401   cert (sign_of ctxt) raw_T
   402     handle TYPE (msg, _, _) => raise CONTEXT (msg, ctxt);
   403 
   404 in
   405 
   406 val read_typ = read_typ_aux Sign.read_typ';
   407 val read_typ_no_norm = read_typ_aux Sign.read_typ_no_norm';
   408 val cert_typ = cert_typ_aux Sign.certify_typ;
   409 val cert_typ_no_norm = cert_typ_aux Sign.certify_typ_no_norm;
   410 
   411 end;
   412 
   413 
   414 (* internalize Skolem constants *)
   415 
   416 fun lookup_skolem ctxt x = assoc (fixes_of ctxt, x);
   417 fun get_skolem ctxt x = if_none (lookup_skolem ctxt x) x;
   418 
   419 fun no_skolem no_internal ctxt x =
   420   if can Syntax.dest_skolem x then
   421     raise CONTEXT ("Illegal reference to internal Skolem constant: " ^ quote x, ctxt)
   422   else if no_internal andalso can Syntax.dest_internal x then
   423     raise CONTEXT ("Illegal reference to internal variable: " ^ quote x, ctxt)
   424   else x;
   425 
   426 fun intern_skolem ctxt =
   427   let
   428     fun intern (t as Free (x, T)) =
   429           (case lookup_skolem ctxt (no_skolem true ctxt x) of
   430             Some x' => Free (x', T)
   431           | None => t)
   432       | intern (t $ u) = intern t $ intern u
   433       | intern (Abs (x, T, t)) = Abs (x, T, intern t)
   434       | intern a = a;
   435   in intern end;
   436 
   437 
   438 (* externalize Skolem constants -- for printing purposes only *)
   439 
   440 fun extern_skolem ctxt =
   441   let
   442     val rev_fixes = map Library.swap (fixes_of ctxt);
   443 
   444     fun extern (t as Free (x, T)) =
   445           (case assoc (rev_fixes, x) of
   446             Some x' => Free (if lookup_skolem ctxt x' = Some x then x' else NameSpace.hidden x', T)
   447           | None => t)
   448       | extern (t $ u) = extern t $ extern u
   449       | extern (Abs (x, T, t)) = Abs (x, T, extern t)
   450       | extern a = a;
   451   in extern end
   452 
   453 
   454 (** prepare terms and propositions **)
   455 
   456 (*
   457   (1) read / certify wrt. signature of context
   458   (2) intern Skolem constants
   459   (3) expand term bindings
   460 *)
   461 
   462 
   463 (* read / certify wrt. signature *)     (*exception ERROR*) (*exception TERM*)
   464 
   465 fun read_def_termTs freeze syn sg (types, sorts, used) sTs =
   466   Sign.read_def_terms' syn (sg, types, sorts) used freeze sTs;
   467 
   468 fun read_def_termT freeze syn sg defs sT = apfst hd (read_def_termTs freeze syn sg defs [sT]);
   469 
   470 fun read_term_sg freeze syn sg defs s =
   471   #1 (read_def_termT freeze syn sg defs (s, TypeInfer.logicT));
   472 
   473 fun read_prop_sg freeze syn sg defs s = #1 (read_def_termT freeze syn sg defs (s, propT));
   474 
   475 fun read_terms_sg freeze syn sg defs =
   476   #1 o read_def_termTs freeze syn sg defs o map (rpair TypeInfer.logicT);
   477 
   478 fun read_props_sg freeze syn sg defs = #1 o read_def_termTs freeze syn sg defs o map (rpair propT);
   479 
   480 
   481 fun cert_term_sg sg t = Thm.term_of (Thm.cterm_of sg t);
   482 
   483 fun cert_prop_sg sg tm =
   484   let
   485     val ctm = Thm.cterm_of sg tm;
   486     val {t, T, ...} = Thm.rep_cterm ctm;
   487   in if T = propT then t else raise TERM ("Term not of type prop", [t]) end;
   488 
   489 
   490 (* norm_term *)
   491 
   492 (*beta normal form for terms (not eta normal form), chase variables in
   493   bindings environment (code taken from Pure/envir.ML)*)
   494 
   495 fun unifyT ctxt (T, U) =
   496   let val maxidx = Int.max (Term.maxidx_of_typ T, Term.maxidx_of_typ U)
   497   in #1 (Type.unify (Sign.tsig_of (sign_of ctxt)) maxidx Vartab.empty (T, U)) end;
   498 
   499 fun norm_term (ctxt as Context {binds, ...}) schematic =
   500   let
   501     (*raised when norm has no effect on a term, to do sharing instead of copying*)
   502     exception SAME;
   503 
   504     fun norm (t as Var (xi, T)) =
   505           (case Vartab.lookup (binds, xi) of
   506             Some (Some (u, U)) =>
   507               let
   508                 val env = unifyT ctxt (T, U) handle Type.TUNIFY =>
   509                   raise TYPE ("norm_term: ill-typed variable assigment", [T, U], [t, u]);
   510                 val u' = Term.subst_TVars_Vartab env u;
   511               in norm u' handle SAME => u' end
   512           | _ =>
   513             if schematic then raise SAME
   514             else raise CONTEXT ("Unbound schematic variable: " ^ Syntax.string_of_vname xi, ctxt))
   515       | norm (Abs (a, T, body)) =  Abs (a, T, norm body)
   516       | norm (Abs (_, _, body) $ t) = normh (subst_bound (t, body))
   517       | norm (f $ t) =
   518           ((case norm f of
   519             Abs (_, _, body) => normh (subst_bound (t, body))
   520           | nf => nf $ (norm t handle SAME => t)) handle SAME => f $ norm t)
   521       | norm _ =  raise SAME
   522     and normh t = norm t handle SAME => t
   523   in normh end;
   524 
   525 
   526 (* dummy patterns *)
   527 
   528 fun prepare_dummies t = #2 (Term.replace_dummy_patterns (1, t));
   529 
   530 fun reject_dummies ctxt t = Term.no_dummy_patterns t
   531   handle TERM _ => raise CONTEXT ("Illegal dummy pattern(s) in term", ctxt);
   532 
   533 
   534 (* read terms *)
   535 
   536 local
   537 
   538 fun gen_read read app is_pat schematic (ctxt as Context {defs = (_, _, used, _), ...}) s =
   539   (transform_error (read (syn_of ctxt)
   540       (sign_of ctxt) (def_type ctxt is_pat, def_sort ctxt, used)) s
   541     handle TERM (msg, _) => raise CONTEXT (msg, ctxt)
   542     | ERROR_MESSAGE msg => raise CONTEXT (msg, ctxt))
   543   |> app (intern_skolem ctxt)
   544   |> app (if is_pat then I else norm_term ctxt schematic)
   545   |> app (if is_pat then prepare_dummies else (reject_dummies ctxt));
   546 
   547 in
   548 
   549 val read_termTs = gen_read (read_def_termTs false) (apfst o map) false false;
   550 val read_termT_pats = #1 oo gen_read (read_def_termTs false) (apfst o map) true false;
   551 
   552 fun read_term_pats T ctxt pats = read_termT_pats ctxt (map (rpair T) pats);
   553 val read_prop_pats = read_term_pats propT;
   554 
   555 val read_term = gen_read (read_term_sg true) I false false;
   556 val read_prop = gen_read (read_prop_sg true) I false false;
   557 val read_prop_schematic = gen_read (read_prop_sg true) I false true;
   558 val read_terms = gen_read (read_terms_sg true) map false false;
   559 val read_props = gen_read (read_props_sg true) map false;
   560 
   561 end;
   562 
   563 
   564 (* certify terms *)
   565 
   566 local
   567 
   568 fun gen_cert cert is_pat schematic ctxt t = t
   569   |> (if is_pat then I else norm_term ctxt schematic)
   570   |> (fn t' => cert (sign_of ctxt) t' handle TERM (msg, _) => raise CONTEXT (msg, ctxt));
   571 
   572 in
   573 
   574 val cert_term = gen_cert cert_term_sg false false;
   575 val cert_prop = gen_cert cert_prop_sg false false;
   576 val cert_props = map oo gen_cert cert_prop_sg false;
   577 
   578 fun cert_term_pats _ = map o gen_cert cert_term_sg true false;
   579 val cert_prop_pats = map o gen_cert cert_prop_sg true false;
   580 
   581 end;
   582 
   583 
   584 (* declare terms *)
   585 
   586 local
   587 
   588 val ins_types = foldl_aterms
   589   (fn (types, Free (x, T)) => Vartab.update (((x, ~1), T), types)
   590     | (types, Var v) => Vartab.update (v, types)
   591     | (types, _) => types);
   592 
   593 val ins_sorts = foldl_types (foldl_atyps
   594   (fn (sorts, TFree (x, S)) => Vartab.update (((x, ~1), S), sorts)
   595     | (sorts, TVar v) => Vartab.update (v, sorts)
   596     | (sorts, _) => sorts));
   597 
   598 val ins_used = foldl_term_types (fn t => foldl_atyps
   599   (fn (used, TFree (x, _)) => x ins_string used | (used, _) => used));
   600 
   601 val ins_occs = foldl_term_types (fn t => foldl_atyps
   602   (fn (tab, TFree (x, _)) => Symtab.update_multi ((x, t), tab) | (tab, _) => tab));
   603 
   604 fun ins_skolem def_ty = foldr
   605   (fn ((x, x'), types) =>
   606     (case def_ty x' of
   607       Some T => Vartab.update (((x, ~1), T), types)
   608     | None => types));
   609 
   610 fun map_defaults f = map_context (fn (thy, syntax, data, asms, binds, thms, cases, defs) =>
   611   (thy, syntax, data, asms, binds, thms, cases, f defs));
   612 
   613 fun declare_syn (ctxt, t) =
   614   ctxt
   615   |> map_defaults (fn (types, sorts, used, occ) => (ins_types (types, t), sorts, used, occ))
   616   |> map_defaults (fn (types, sorts, used, occ) => (types, ins_sorts (sorts, t), used, occ))
   617   |> map_defaults (fn (types, sorts, used, occ) => (types, sorts, ins_used (used, t), occ));
   618 
   619 fun declare_occ (ctxt as Context {asms = (_, fixes), ...}, t) =
   620   declare_syn (ctxt, t)
   621   |> map_defaults (fn (types, sorts, used, occ) => (types, sorts, used, ins_occs (occ, t)))
   622   |> map_defaults (fn (types, sorts, used, occ) =>
   623       (ins_skolem (fn x => Vartab.lookup (types, (x, ~1))) (fixes, types), sorts, used, occ));
   624 
   625 in
   626 
   627 fun declare_term t ctxt = declare_occ (ctxt, t);
   628 fun declare_terms ts ctxt = foldl declare_occ (ctxt, ts);
   629 fun declare_terms_syntax ts ctxt = foldl declare_syn (ctxt, ts);
   630 
   631 end;
   632 
   633 
   634 
   635 (** pretty printing **)
   636 
   637 fun pretty_term ctxt = Sign.pretty_term' (syn_of ctxt) (sign_of ctxt) o context_tr' ctxt;
   638 val pretty_typ = Sign.pretty_typ o sign_of;
   639 val pretty_sort = Sign.pretty_sort o sign_of;
   640 
   641 val string_of_term = Pretty.string_of oo pretty_term;
   642 
   643 val show_hyps = ref false;
   644 
   645 fun pretty_thm ctxt thm =
   646   if ! show_hyps then setmp Display.show_hyps true (fn () =>
   647     Display.pretty_thm_aux (pretty_sort ctxt, pretty_term ctxt) false thm) ()
   648   else pretty_term ctxt (#prop (Thm.rep_thm thm));
   649 
   650 fun pretty_thms ctxt [th] = pretty_thm ctxt th
   651   | pretty_thms ctxt ths = Pretty.blk (0, Pretty.fbreaks (map (pretty_thm ctxt) ths));
   652 
   653 
   654 
   655 (** Hindley-Milner polymorphism **)
   656 
   657 (* warn_extra_tfrees *)
   658 
   659 fun warn_extra_tfrees
   660     (ctxt1 as Context {defs = (_, _, _, occ1), ...})
   661     (ctxt2 as Context {defs = (_, _, _, occ2), ...}) =
   662   let
   663     fun known_tfree a (Type (_, Ts)) = exists (known_tfree a) Ts
   664       | known_tfree a (TFree (a', _)) = a = a'
   665       | known_tfree _ _ = false;
   666 
   667     val extras =
   668       Library.gen_rems Library.eq_fst (Symtab.dest occ2, Symtab.dest occ1)
   669       |> map (fn (a, ts) => map (pair a) (mapfilter (try (#1 o Term.dest_Free)) ts)) |> flat
   670       |> mapfilter (fn (a, x) =>
   671           (case def_type ctxt1 false (x, ~1) of None => Some (a, x)
   672           | Some T => if known_tfree a T then None else Some (a, x)));
   673     val tfrees = map #1 extras |> Library.sort_strings |> Library.unique_strings;
   674     val frees = map #2 extras |> Library.sort_strings |> Library.unique_strings;
   675   in
   676     if null extras then ()
   677     else warning ("Just introduced free type variable(s): " ^ commas tfrees ^ " in " ^
   678       space_implode " or " frees);
   679     ctxt2
   680   end;
   681 
   682 
   683 (* generalize type variables *)
   684 
   685 fun gen_tfrees inner outer =
   686   let
   687     val extra_fixes = fixed_names_of inner \\ fixed_names_of outer;
   688     fun still_fixed (Free (x, _)) = not (x mem_string extra_fixes)
   689       | still_fixed _ = false;
   690     fun add (gen, (a, xs)) =
   691       if is_some (Symtab.lookup (type_occs outer, a)) orelse exists still_fixed xs
   692       then gen else a :: gen;
   693   in Symtab.foldl add ([], type_occs inner) end;
   694 
   695 fun generalizeT inner outer =
   696   let
   697     val tfrees = gen_tfrees inner outer;
   698     fun gen (x, S) = if x mem_string tfrees then TVar ((x, 0), S) else TFree (x, S);
   699   in Term.map_type_tfree gen end;
   700 
   701 val generalize = Term.map_term_types oo generalizeT;
   702 
   703 
   704 
   705 (** export theorems **)
   706 
   707 fun get_free x (None, t as Free (y, _)) = if x = y then Some t else None
   708   | get_free _ (opt, _) = opt;
   709 
   710 fun find_free t x = foldl_aterms (get_free x) (None, t);
   711 
   712 fun export is_goal inner outer =
   713   let
   714     val tfrees = gen_tfrees inner outer;
   715     val fixes = fixed_names_of inner \\ fixed_names_of outer;
   716     val asms = Library.drop (length (assumptions_of outer), assumptions_of inner);
   717     val exp_asms = map (fn (cprops, exp) => exp is_goal cprops) asms;
   718   in fn thm =>
   719     thm
   720     |> Tactic.norm_hhf
   721     |> Seq.EVERY (rev exp_asms)
   722     |> Seq.map (fn rule =>
   723       let
   724         val {sign, prop, ...} = Thm.rep_thm rule;
   725         val frees = map (Thm.cterm_of sign) (mapfilter (find_free prop) fixes);
   726       in
   727         rule
   728         |> Drule.forall_intr_list frees
   729         |> Tactic.norm_hhf
   730         |> Drule.tvars_intr_list tfrees
   731       end)
   732   end;
   733 
   734 
   735 
   736 (** bindings **)
   737 
   738 (* update_binds *)
   739 
   740 fun del_bind (ctxt, xi) =
   741   ctxt
   742   |> map_context (fn (thy, syntax, data, asms, binds, thms, cases, defs) =>
   743       (thy, syntax, data, asms, Vartab.update ((xi, None), binds), thms, cases, defs));
   744 
   745 fun upd_bind (ctxt, ((x, i), t)) =
   746   let
   747     val T = Term.fastype_of t;
   748     val t' =
   749       if null (Term.term_tvars t \\ Term.typ_tvars T) then t
   750       else Var ((x ^ "_has_extra_type_vars_on_rhs", i), T);
   751   in
   752     ctxt
   753     |> declare_term t'
   754     |> map_context (fn (thy, syntax, data, asms, binds, thms, cases, defs) =>
   755       (thy, syntax, data, asms, Vartab.update (((x, i), Some (t', T)), binds), thms, cases, defs))
   756   end;
   757 
   758 fun del_upd_bind (ctxt, (xi, None)) = del_bind (ctxt, xi)
   759   | del_upd_bind (ctxt, (xi, Some t)) = upd_bind (ctxt, (xi, t));
   760 
   761 fun update_binds bs ctxt = foldl upd_bind (ctxt, bs);
   762 fun delete_update_binds bs ctxt = foldl del_upd_bind (ctxt, bs);
   763 
   764 
   765 (* simult_matches *)
   766 
   767 fun simult_matches ctxt [] = []
   768   | simult_matches ctxt pairs =
   769       let
   770         fun fail () = raise CONTEXT ("Pattern match failed!", ctxt);
   771 
   772         val maxidx = foldl (fn (i, (t1, t2)) =>
   773           Int.max (i, Int.max (Term.maxidx_of_term t1, Term.maxidx_of_term t2))) (~1, pairs);
   774         val envs = Unify.smash_unifiers (sign_of ctxt, Envir.empty maxidx,
   775           map swap pairs);    (*prefer assignment of variables from patterns*)
   776         val env =
   777           (case Seq.pull envs of
   778             None => fail ()
   779           | Some (env, _) => env);    (*ignore further results*)
   780         val domain =
   781           filter_out Term.is_replaced_dummy_pattern (map #1 (Drule.vars_of_terms (map #1 pairs)));
   782         val _ =    (*may not assign variables from text*)
   783           if null (map #1 (Envir.alist_of env) inter (map #1 (Drule.vars_of_terms (map #2 pairs))))
   784           then () else fail ();
   785         fun norm_bind (xi, t) = if xi mem domain then Some (xi, Envir.norm_term env t) else None;
   786       in mapfilter norm_bind (Envir.alist_of env) end;
   787 
   788 
   789 (* add_binds(_i) *)
   790 
   791 local
   792 
   793 fun gen_bind prep (ctxt, (xi as (x, _), raw_t)) =
   794   ctxt |> delete_update_binds [(xi, apsome (prep ctxt) raw_t)];
   795 
   796 fun gen_binds prep binds ctxt = foldl (gen_bind prep) (ctxt, binds);
   797 
   798 in
   799 
   800 fun drop_schematic (b as (xi, Some t)) = if null (Term.term_vars t) then b else (xi, None)
   801   | drop_schematic b = b;
   802 
   803 val add_binds = gen_binds read_term;
   804 val add_binds_i = gen_binds cert_term;
   805 
   806 fun auto_bind f ts ctxt = ctxt |> add_binds_i (map drop_schematic (f (sign_of ctxt) ts));
   807 val auto_bind_goal = auto_bind AutoBind.goal;
   808 val auto_bind_facts = auto_bind AutoBind.facts;
   809 
   810 end;
   811 
   812 
   813 (* match_bind(_i) *)
   814 
   815 local
   816 
   817 fun prep_bind prep_pats (ctxt, (raw_pats, t)) =
   818   let
   819     val ctxt' = declare_term t ctxt;
   820     val pats = prep_pats (fastype_of t) ctxt' raw_pats;
   821     val binds = simult_matches ctxt' (map (rpair t) pats);
   822   in (ctxt', binds) end;
   823 
   824 fun gen_binds prep_terms prep_pats gen raw_binds ctxt =
   825   let
   826     val ts = prep_terms ctxt (map snd raw_binds);
   827     val (ctxt', binds) =
   828       apsnd flat (foldl_map (prep_bind prep_pats) (ctxt, map fst raw_binds ~~ ts));
   829     val binds' =
   830       if gen then map (apsnd (generalize ctxt' ctxt)) binds
   831       else binds;
   832     val binds'' = map (apsnd Some) binds';
   833   in
   834     warn_extra_tfrees ctxt
   835      (if gen then ctxt (*sic!*) |> declare_terms (map #2 binds') |> add_binds_i binds''
   836       else ctxt' |> add_binds_i binds'')
   837   end;
   838 
   839 in
   840 
   841 val match_bind = gen_binds read_terms read_term_pats;
   842 val match_bind_i = gen_binds (map o cert_term) cert_term_pats;
   843 
   844 end;
   845 
   846 
   847 (* propositions with patterns *)
   848 
   849 local
   850 
   851 fun prep_propp schematic prep_props prep_pats (context, args) =
   852   let
   853     fun prep ((ctxt, prop :: props), (_, (raw_pats1, raw_pats2))) =
   854           let
   855             val ctxt' = declare_term prop ctxt;
   856             val pats = prep_pats ctxt' (raw_pats1 @ raw_pats2);    (*simultaneous type inference!*)
   857             val len1 = length raw_pats1;
   858           in ((ctxt', props), (prop, (take (len1, pats), drop (len1, pats)))) end
   859       | prep _ = sys_error "prep_propp";
   860     val ((context', _), propp) = foldl_map (foldl_map prep)
   861         ((context, prep_props schematic context (flat (map (map fst) args))), args);
   862   in (context', propp) end;
   863 
   864 fun matches ctxt (prop, (pats1, pats2)) =
   865   simult_matches ctxt (map (rpair prop) pats1 @ map (rpair (Logic.strip_imp_concl prop)) pats2);
   866 
   867 fun gen_bind_propp prepp (ctxt, raw_args) =
   868   let
   869     val (ctxt', args) = prepp (ctxt, raw_args);
   870     val binds = flat (flat (map (map (matches ctxt')) args));
   871     val propss = map (map #1) args;
   872 
   873     (*generalize result: context evaluated now, binds added later*)
   874     val gen = generalize ctxt' ctxt;
   875     fun gen_binds c = c |> add_binds_i (map (apsnd (Some o gen)) binds);
   876   in (ctxt' |> add_binds_i (map (apsnd Some) binds), (propss, gen_binds)) end;
   877 
   878 in
   879 
   880 val read_propp = prep_propp false read_props read_prop_pats;
   881 val cert_propp = prep_propp false cert_props cert_prop_pats;
   882 val read_propp_schematic = prep_propp true read_props read_prop_pats;
   883 val cert_propp_schematic = prep_propp true cert_props cert_prop_pats;
   884 
   885 val bind_propp = gen_bind_propp read_propp;
   886 val bind_propp_i = gen_bind_propp cert_propp;
   887 val bind_propp_schematic = gen_bind_propp read_propp_schematic;
   888 val bind_propp_schematic_i = gen_bind_propp cert_propp_schematic;
   889 
   890 end;
   891 
   892 
   893 
   894 (** theorems **)
   895 
   896 (* get_thm(s) *)
   897 
   898 (*beware of proper order of evaluation!*)
   899 fun retrieve_thms f g (ctxt as Context {thy, thms = (_, space, tab), ...}) =
   900   let
   901     val sg_ref = Sign.self_ref (Theory.sign_of thy);
   902     val get_from_thy = f thy;
   903   in
   904     fn xname =>
   905       (case Symtab.lookup (tab, NameSpace.intern space xname) of
   906         Some (Some ths) => map (Thm.transfer_sg (Sign.deref sg_ref)) ths
   907       | _ => get_from_thy xname) |> g xname
   908   end;
   909 
   910 val get_thm = retrieve_thms PureThy.get_thms PureThy.single_thm;
   911 val get_thm_closure = retrieve_thms PureThy.get_thms_closure PureThy.single_thm;
   912 val get_thms = retrieve_thms PureThy.get_thms (K I);
   913 val get_thms_closure = retrieve_thms PureThy.get_thms_closure (K I);
   914 
   915 
   916 (* qualified names *)
   917 
   918 fun cond_extern (Context {thms = (_, space, _), ...}) = NameSpace.cond_extern space;
   919 
   920 fun set_qual q = map_context (fn (thy, syntax, data, asms, binds, (_, space, tab), cases, defs) =>
   921   (thy, syntax, data, asms, binds, (q, space, tab), cases, defs));
   922 
   923 fun qualified f (ctxt as Context {thms, ...}) =
   924   ctxt |> set_qual true |> f |> set_qual (#1 thms);
   925 
   926 
   927 (* put_thm(s) *)
   928 
   929 fun put_thms ("", _) ctxt = ctxt
   930   | put_thms (name, ths) ctxt = ctxt |> map_context
   931       (fn (thy, syntax, data, asms, binds, (q, space, tab), cases, defs) =>
   932         if not q andalso NameSpace.is_qualified name then
   933           raise CONTEXT ("Attempt to declare qualified name " ^ quote name, ctxt)
   934         else (thy, syntax, data, asms, binds, (q, NameSpace.extend (space, [name]),
   935           Symtab.update ((name, Some ths), tab)), cases, defs));
   936 
   937 fun put_thm (name, th) = put_thms (name, [th]);
   938 
   939 fun put_thmss [] ctxt = ctxt
   940   | put_thmss (th :: ths) ctxt = ctxt |> put_thms th |> put_thmss ths;
   941 
   942 
   943 (* reset_thms *)
   944 
   945 fun reset_thms name =
   946   map_context (fn (thy, syntax, data, asms, binds, (q, space, tab), cases, defs) =>
   947     (thy, syntax, data, asms, binds, (q, space, Symtab.update ((name, None), tab)), cases, defs));
   948 
   949 
   950 (* have_thmss *)
   951 
   952 fun have_thss (ctxt, ((name, more_attrs), ths_attrs)) =
   953   let
   954     fun app ((ct, ths), (th, attrs)) =
   955       let val (ct', th') = Thm.applys_attributes ((ct, th), attrs @ more_attrs)
   956       in (ct', th' :: ths) end
   957     val (ctxt', rev_thms) = foldl app ((ctxt, []), ths_attrs);
   958     val thms = flat (rev rev_thms);
   959   in (ctxt' |> put_thms (name, thms), (name, thms)) end;
   960 
   961 fun have_thmss args ctxt = foldl_map have_thss (ctxt, args);
   962 
   963 
   964 
   965 (** assumptions **)
   966 
   967 (* basic exporters *)
   968 
   969 fun export_assume true = Seq.single oo Drule.implies_intr_goals
   970   | export_assume false = Seq.single oo Drule.implies_intr_list;
   971 
   972 fun export_presume _ = export_assume false;
   973 
   974 
   975 (* defs *)
   976 
   977 fun cert_def ctxt eq =
   978   let
   979     fun err msg = raise CONTEXT (msg ^
   980       "\nThe error(s) above occurred in local definition: " ^ string_of_term ctxt eq, ctxt);
   981     val (lhs, rhs) = Logic.dest_equals (Term.strip_all_body eq)
   982       handle TERM _ => err "Not a meta-equality (==)";
   983     val (f, xs) = Term.strip_comb lhs;
   984     val (c, _) = Term.dest_Free f handle TERM _ =>
   985       err "Head of lhs must be free or fixed variable";
   986 
   987     fun is_free (Free (x, _)) = not (is_fixed ctxt x)
   988       | is_free _ = false;
   989     val extra_frees = filter is_free (term_frees rhs) \\ xs;
   990   in
   991     conditional (not (forall (is_Bound orf is_free) xs andalso null (duplicates xs))) (fn () =>
   992       err "Arguments of lhs must be distinct free or fixed variables");
   993     conditional (f mem Term.term_frees rhs) (fn () =>
   994       err "Element to be defined occurs on rhs");
   995     conditional (not (null extra_frees)) (fn () =>
   996       err ("Extra free variables on rhs: " ^ commas_quote (map (#1 o dest_Free) extra_frees)));
   997     (c, Term.list_all_free (mapfilter (try Term.dest_Free) xs, eq))
   998   end;
   999 
  1000 fun head_of_def cprop =
  1001   #1 (Term.strip_comb (#1 (Logic.dest_equals (Term.strip_all_body (Thm.term_of cprop)))))
  1002   |> Thm.cterm_of (Thm.sign_of_cterm cprop);
  1003 
  1004 fun export_def _ cprops thm =
  1005   thm
  1006   |> Drule.implies_intr_list cprops
  1007   |> Drule.forall_intr_list (map head_of_def cprops)
  1008   |> Drule.forall_elim_vars 0
  1009   |> RANGE (replicate (length cprops) (Tactic.rtac Drule.reflexive_thm)) 1;
  1010 
  1011 
  1012 (* assume *)
  1013 
  1014 local
  1015 
  1016 fun add_assm (ctxt, ((name, attrs), props)) =
  1017   let
  1018     val cprops = map (Thm.cterm_of (sign_of ctxt)) props;
  1019     val asms = map (Tactic.norm_hhf o Thm.assume) cprops;
  1020 
  1021     val ths = map (fn th => ([th], [])) asms;
  1022     val (ctxt', [(_, thms)]) =
  1023       ctxt
  1024       |> auto_bind_facts props
  1025       |> have_thmss [((name, attrs), ths)];
  1026   in (ctxt', (cprops, (name, asms), (name, thms))) end;
  1027 
  1028 fun gen_assms prepp exp args ctxt =
  1029   let
  1030     val (ctxt1, propss) = prepp (ctxt, map snd args);
  1031     val (ctxt2, results) = foldl_map add_assm (ctxt1, map fst args ~~ propss);
  1032 
  1033     val cprops = flat (map #1 results);
  1034     val asmss = map #2 results;
  1035     val thmss = map #3 results;
  1036     val ctxt3 = ctxt2 |> map_context
  1037       (fn (thy, syntax, data, ((asms_ct, asms_th), fixes), binds, thms, cases, defs) =>
  1038         (thy, syntax, data, ((asms_ct @ [(cprops, exp)], asms_th @ asmss), fixes), binds, thms,
  1039           cases, defs));
  1040     val ctxt4 = ctxt3 |> put_thms ("prems", prems_of ctxt3);
  1041   in (warn_extra_tfrees ctxt ctxt4, thmss) end;
  1042 
  1043 in
  1044 
  1045 val assume = gen_assms (apsnd #1 o bind_propp);
  1046 val assume_i = gen_assms (apsnd #1 o bind_propp_i);
  1047 
  1048 end;
  1049 
  1050 
  1051 (* variables *)
  1052 
  1053 local
  1054 
  1055 fun prep_vars prep_typ no_internal (ctxt, (xs, raw_T)) =
  1056   let
  1057     val _ = (case filter (not o Syntax.is_identifier) (map (no_skolem no_internal ctxt) xs) of
  1058       [] => () | bads => raise CONTEXT ("Bad variable name(s): " ^ commas_quote bads, ctxt));
  1059 
  1060     val opt_T = apsome (prep_typ ctxt) raw_T;
  1061     val T = if_none opt_T TypeInfer.logicT;
  1062     val ctxt' = ctxt |> declare_terms_syntax (map (fn x => Free (x, T)) xs);
  1063   in (ctxt', (xs, opt_T)) end;
  1064 
  1065 in
  1066 
  1067 val read_vars = prep_vars read_typ true;
  1068 val cert_vars = prep_vars cert_typ false;
  1069 
  1070 end;
  1071 
  1072 
  1073 (* fix *)
  1074 
  1075 local
  1076 
  1077 fun map_fixes f =
  1078   map_context (fn (thy, syntax, data, (assumes, fixes), binds, thms, cases, defs) =>
  1079     (thy, syntax, data, (assumes, f fixes), binds, thms, cases, defs));
  1080 
  1081 fun err_dups ctxt xs = raise CONTEXT ("Duplicate variable(s): " ^ commas_quote xs, ctxt);
  1082 
  1083 val declare =
  1084   declare_terms_syntax o mapfilter (fn (_, None) => None | (x, Some T) => Some (Free (x, T)));
  1085 
  1086 fun add_vars xs Ts ctxt =
  1087   let val xs' = Term.variantlist (map Syntax.skolem xs, map #2 (fixes_of ctxt)) in
  1088     ctxt
  1089     |> declare (xs' ~~ Ts)
  1090     |> map_fixes (fn fixes => (xs ~~ xs') @ fixes)
  1091   end;
  1092 
  1093 fun add_vars_direct xs Ts ctxt =
  1094   ctxt
  1095   |> declare (xs ~~ Ts)
  1096   |> map_fixes (fn fixes =>
  1097     (case xs inter_string map #1 fixes of
  1098       [] => (xs ~~ xs) @ fixes
  1099     | dups => err_dups ctxt dups));
  1100 
  1101 
  1102 fun gen_fix prep add raw_vars ctxt =
  1103   let
  1104     val (ctxt', varss) = foldl_map prep (ctxt, raw_vars);
  1105     val vars = rev (flat (map (fn (xs, T) => map (rpair T) xs) varss));
  1106     val xs = map #1 vars;
  1107     val Ts = map #2 vars;
  1108   in
  1109     (case Library.duplicates xs of [] => () | dups => err_dups ctxt dups);
  1110     ctxt' |> add xs Ts
  1111   end;
  1112 
  1113 in
  1114 
  1115 val fix = gen_fix read_vars add_vars;
  1116 val fix_i = gen_fix cert_vars add_vars;
  1117 val fix_direct = gen_fix cert_vars add_vars_direct;
  1118 
  1119 end;
  1120 
  1121 fun fix_frees ts ctxt =
  1122   let
  1123     val frees = foldl Drule.add_frees ([], ts);
  1124     fun new (x, T) = if is_fixed ctxt x then None else Some ([x], Some T);
  1125   in fix_direct (rev (mapfilter new frees)) ctxt end;
  1126 
  1127 
  1128 (*Note: improper use may result in variable capture / dynamic scoping!*)
  1129 fun bind_skolem ctxt xs =
  1130   let
  1131     val ctxt' = ctxt |> fix_i [(xs, None)];
  1132     fun bind (t as Free (x, T)) =
  1133           if x mem_string xs then
  1134             (case lookup_skolem ctxt' x of Some x' => Free (x', T) | None => t)
  1135           else t
  1136       | bind (t $ u) = bind t $ bind u
  1137       | bind (Abs (x, T, t)) = Abs (x, T, bind t)
  1138       | bind a = a;
  1139   in bind end;
  1140 
  1141 
  1142 
  1143 (** cases **)
  1144 
  1145 fun prep_case ctxt name xs {fixes, assumes, binds} =
  1146   let
  1147     fun replace (opt_x :: xs) ((y, T) :: ys) = (if_none opt_x y, T) :: replace xs ys
  1148       | replace [] ys = ys
  1149       | replace (_ :: _) [] = raise CONTEXT ("Too many parameters for case " ^ quote name, ctxt);
  1150   in
  1151     if null (foldr Term.add_typ_tvars (map snd fixes, [])) andalso
  1152       null (foldr Term.add_term_vars (assumes, [])) then
  1153         {fixes = replace xs fixes, assumes = assumes, binds = map drop_schematic binds}
  1154     else raise CONTEXT ("Illegal schematic variable(s) in case " ^ quote name, ctxt)
  1155   end;
  1156 
  1157 fun get_case (ctxt as Context {cases, ...}) name xs =
  1158   (case assoc (cases, name) of
  1159     None => raise CONTEXT ("Unknown case: " ^ quote name, ctxt)
  1160   | Some c => prep_case ctxt name xs c);
  1161 
  1162 
  1163 fun add_cases xs = map_context (fn (thy, syntax, data, asms, binds, thms, cases, defs) =>
  1164   (thy, syntax, data, asms, binds, thms, rev (filter_out (equal "" o #1) xs) @ cases, defs));
  1165 
  1166 
  1167 
  1168 (** print context information **)
  1169 
  1170 val verbose = ref false;
  1171 fun verb f x = if ! verbose then f (x ()) else [];
  1172 fun verb_single x = verb Library.single x;
  1173 
  1174 fun setmp_verbose f x = Library.setmp verbose true f x;
  1175 
  1176 fun pretty_items prt name items =
  1177   let
  1178     fun prt_itms (name, [x]) = Pretty.block [Pretty.str (name ^ ":"), Pretty.brk 1, prt x]
  1179       | prt_itms (name, xs) = Pretty.big_list (name ^ ":") (map prt xs);
  1180   in
  1181     if null items andalso not (! verbose) then []
  1182     else [Pretty.big_list name (map prt_itms items)]
  1183   end;
  1184 
  1185 
  1186 (* local syntax *)
  1187 
  1188 val print_syntax = Syntax.print_syntax o syn_of;
  1189 
  1190 
  1191 (* term bindings *)
  1192 
  1193 val smash_option = fn (_, None) => None | (xi, Some b) => Some (xi, b);
  1194 
  1195 fun pretty_binds (ctxt as Context {binds, ...}) =
  1196   let
  1197     fun prt_bind (xi, (t, T)) = pretty_term ctxt (Logic.mk_equals (Var (xi, T), t));
  1198     val bs = mapfilter smash_option (Vartab.dest binds);
  1199   in
  1200     if null bs andalso not (! verbose) then []
  1201     else [Pretty.big_list "term bindings:" (map prt_bind bs)]
  1202   end;
  1203 
  1204 val print_binds = Pretty.writeln o Pretty.chunks o pretty_binds;
  1205 
  1206 
  1207 (* local theorems *)
  1208 
  1209 fun pretty_lthms (ctxt as Context {thms = (_, space, tab), ...}) =
  1210   pretty_items (pretty_thm ctxt) "facts:"
  1211     (mapfilter smash_option (NameSpace.cond_extern_table space tab));
  1212 
  1213 val print_lthms = Pretty.writeln o Pretty.chunks o pretty_lthms;
  1214 
  1215 
  1216 (* local contexts *)
  1217 
  1218 fun apply_case ({fixes, assumes, binds}: RuleCases.T) ctxt =
  1219   let
  1220     fun bind (c, (x, T)) = (c |> fix_i [([x], Some T)], bind_skolem c [x] (Free (x, T)));
  1221     val (ctxt', xs) = foldl_map bind (ctxt, fixes);
  1222     fun app t = foldl Term.betapply (t, xs);
  1223   in (ctxt', (map (apsnd (apsome app)) binds, map app assumes)) end;
  1224 
  1225 fun pretty_cases (ctxt as Context {cases, ...}) =
  1226   let
  1227     val prt_term = pretty_term ctxt;
  1228 
  1229     fun prt_let (xi, t) = Pretty.block
  1230       [Pretty.quote (prt_term (Var (xi, Term.fastype_of t))), Pretty.str " =", Pretty.brk 1,
  1231         Pretty.quote (prt_term t)];
  1232 
  1233     fun prt_sect _ _ _ [] = []
  1234       | prt_sect s sep prt xs = [Pretty.block (Pretty.breaks (Pretty.str s ::
  1235             flat (Library.separate sep (map (Library.single o prt) xs))))];
  1236 
  1237     fun prt_case (name, (fixes, (lets, asms))) = Pretty.block (Pretty.fbreaks
  1238       (Pretty.str (name ^ ":") ::
  1239         prt_sect "fix" [] (Pretty.str o fst) fixes @
  1240         prt_sect "let" [Pretty.str "and"] prt_let
  1241           (mapfilter (fn (xi, Some t) => Some (xi, t) | _ => None) lets) @
  1242         prt_sect "assume" [] (Pretty.quote o prt_term) asms));
  1243 
  1244     val cases' = rev (Library.gen_distinct Library.eq_fst cases);
  1245   in
  1246     if null cases andalso not (! verbose) then []
  1247     else [Pretty.big_list "cases:"
  1248       (map (prt_case o apsnd (fn c => (#fixes c, #2 (apply_case c ctxt)))) cases')]
  1249   end;
  1250 
  1251 val print_cases = Pretty.writeln o Pretty.chunks o pretty_cases;
  1252 
  1253 
  1254 (* core context *)
  1255 
  1256 val prems_limit = ref 10;
  1257 
  1258 fun pretty_asms ctxt =
  1259   let
  1260     val prt_term = pretty_term ctxt;
  1261 
  1262     (*structures*)
  1263     val (_, structs, _) = syntax_of ctxt;
  1264     val prt_structs = if null structs then []
  1265       else [Pretty.block (Pretty.str "structures:" :: Pretty.brk 1 ::
  1266         Pretty.commas (map Pretty.str structs))];
  1267 
  1268     (*fixes*)
  1269     fun prt_fix (x, x') =
  1270       if x = x' then Pretty.str x
  1271       else Pretty.block [Pretty.str x, Pretty.str " =", Pretty.brk 1, prt_term (Syntax.free x')];
  1272     val fixes = rev (filter_out
  1273       ((can Syntax.dest_internal o #1) orf (fn (_, x') => x' mem_string structs)) (fixes_of ctxt));
  1274     val prt_fixes = if null fixes then []
  1275       else [Pretty.block (Pretty.str "fixed variables:" :: Pretty.brk 1 ::
  1276         Pretty.commas (map prt_fix fixes))];
  1277 
  1278     (*prems*)
  1279     val limit = ! prems_limit;
  1280     val prems = prems_of ctxt;
  1281     val len = length prems;
  1282     val prt_prems = if null prems then []
  1283       else [Pretty.big_list "prems:" ((if len <= limit then [] else [Pretty.str "..."]) @
  1284         map (pretty_thm ctxt) (Library.drop (len - limit, prems)))];
  1285 
  1286   in prt_structs @ prt_fixes @ prt_prems end;
  1287 
  1288 
  1289 (* main context *)
  1290 
  1291 fun pretty_context (ctxt as Context {cases, defs = (types, sorts, used, _), ...}) =
  1292   let
  1293     val prt_term = pretty_term ctxt;
  1294     val prt_typ = pretty_typ ctxt;
  1295     val prt_sort = pretty_sort ctxt;
  1296 
  1297     (*theory*)
  1298     val pretty_thy = Pretty.block
  1299       [Pretty.str "Theory:", Pretty.brk 1, Sign.pretty_sg (sign_of ctxt)];
  1300 
  1301     (*defaults*)
  1302     fun prt_atom prt prtT (x, X) = Pretty.block
  1303       [prt x, Pretty.str " ::", Pretty.brk 1, prtT X];
  1304 
  1305     fun prt_var (x, ~1) = prt_term (Syntax.free x)
  1306       | prt_var xi = prt_term (Syntax.var xi);
  1307 
  1308     fun prt_varT (x, ~1) = prt_typ (TFree (x, []))
  1309       | prt_varT xi = prt_typ (TVar (xi, []));
  1310 
  1311     val prt_defT = prt_atom prt_var prt_typ;
  1312     val prt_defS = prt_atom prt_varT prt_sort;
  1313   in
  1314     verb_single (K pretty_thy) @
  1315     pretty_asms ctxt @
  1316     verb pretty_binds (K ctxt) @
  1317     verb pretty_lthms (K ctxt) @
  1318     verb pretty_cases (K ctxt) @
  1319     verb_single (fn () => Pretty.big_list "type constraints:" (map prt_defT (Vartab.dest types))) @
  1320     verb_single (fn () => Pretty.big_list "default sorts:" (map prt_defS (Vartab.dest sorts))) @
  1321     verb_single (fn () => Pretty.strs ("used type variable names:" :: used))
  1322   end;
  1323 
  1324 
  1325 
  1326 (** theory setup **)
  1327 
  1328 val setup = [ProofDataData.init];
  1329 
  1330 end;