src/Pure/sign.ML
author wenzelm
Thu Feb 25 22:05:34 2010 +0100 (2010-02-25 ago)
changeset 35359 3ec03a3cd9d0
parent 35262 9ea4445d2ccf
child 35395 ba804f4c82c6
permissions -rw-r--r--
provide direct access to the different kinds of type declarations;
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val rep_sg: theory ->
    11    {naming: Name_Space.naming,
    12     syn: Syntax.syntax,
    13     tsig: Type.tsig,
    14     consts: Consts.T}
    15   val map_naming: (Name_Space.naming -> Name_Space.naming) -> theory -> theory
    16   val naming_of: theory -> Name_Space.naming
    17   val full_name: theory -> binding -> string
    18   val full_name_path: theory -> string -> binding -> string
    19   val full_bname: theory -> bstring -> string
    20   val full_bname_path: theory -> string -> bstring -> string
    21   val syn_of: theory -> Syntax.syntax
    22   val tsig_of: theory -> Type.tsig
    23   val classes_of: theory -> Sorts.algebra
    24   val all_classes: theory -> class list
    25   val super_classes: theory -> class -> class list
    26   val minimize_sort: theory -> sort -> sort
    27   val complete_sort: theory -> sort -> sort
    28   val defaultS: theory -> sort
    29   val subsort: theory -> sort * sort -> bool
    30   val of_sort: theory -> typ * sort -> bool
    31   val witness_sorts: theory -> (typ * sort) list -> sort list -> (typ * sort) list
    32   val is_logtype: theory -> string -> bool
    33   val typ_instance: theory -> typ * typ -> bool
    34   val typ_equiv: theory -> typ * typ -> bool
    35   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    36   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    37   val consts_of: theory -> Consts.T
    38   val the_const_constraint: theory -> string -> typ
    39   val const_type: theory -> string -> typ option
    40   val the_const_type: theory -> string -> typ
    41   val declared_tyname: theory -> string -> bool
    42   val declared_const: theory -> string -> bool
    43   val const_monomorphic: theory -> string -> bool
    44   val const_typargs: theory -> string * typ -> typ list
    45   val const_instance: theory -> string * typ list -> typ
    46   val mk_const: theory -> string * typ list -> term
    47   val class_space: theory -> Name_Space.T
    48   val type_space: theory -> Name_Space.T
    49   val const_space: theory -> Name_Space.T
    50   val intern_class: theory -> xstring -> string
    51   val extern_class: theory -> string -> xstring
    52   val intern_type: theory -> xstring -> string
    53   val extern_type: theory -> string -> xstring
    54   val intern_const: theory -> xstring -> string
    55   val extern_const: theory -> string -> xstring
    56   val intern_sort: theory -> sort -> sort
    57   val extern_sort: theory -> sort -> sort
    58   val intern_typ: theory -> typ -> typ
    59   val extern_typ: theory -> typ -> typ
    60   val intern_term: theory -> term -> term
    61   val extern_term: theory -> term -> term
    62   val intern_tycons: theory -> typ -> typ
    63   val the_type_decl: theory -> string -> Type.decl
    64   val arity_number: theory -> string -> int
    65   val arity_sorts: theory -> string -> sort -> sort list
    66   val certify_class: theory -> class -> class
    67   val certify_sort: theory -> sort -> sort
    68   val certify_typ: theory -> typ -> typ
    69   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    70   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
    71   val certify_term: theory -> term -> term * typ * int
    72   val cert_term: theory -> term -> term
    73   val cert_prop: theory -> term -> term
    74   val no_frees: Pretty.pp -> term -> term
    75   val no_vars: Pretty.pp -> term -> term
    76   val cert_def: Proof.context -> term -> (string * typ) * term
    77   val read_class: theory -> xstring -> class
    78   val read_arity: theory -> xstring * string list * string -> arity
    79   val cert_arity: theory -> arity -> arity
    80   val add_defsort: string -> theory -> theory
    81   val add_defsort_i: sort -> theory -> theory
    82   val add_types: (binding * int * mixfix) list -> theory -> theory
    83   val add_nonterminals: binding list -> theory -> theory
    84   val add_tyabbrs: (binding * string list * string * mixfix) list -> theory -> theory
    85   val add_tyabbrs_i: (binding * string list * typ * mixfix) list -> theory -> theory
    86   val add_syntax: (string * string * mixfix) list -> theory -> theory
    87   val add_syntax_i: (string * typ * mixfix) list -> theory -> theory
    88   val add_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    89   val add_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    90   val del_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    91   val del_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    92   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    93   val declare_const: (binding * typ) * mixfix -> theory -> term * theory
    94   val add_consts: (binding * string * mixfix) list -> theory -> theory
    95   val add_consts_i: (binding * typ * mixfix) list -> theory -> theory
    96   val add_abbrev: string -> binding * term -> theory -> (term * term) * theory
    97   val revert_abbrev: string -> string -> theory -> theory
    98   val add_const_constraint: string * typ option -> theory -> theory
    99   val primitive_class: binding * class list -> theory -> theory
   100   val primitive_classrel: class * class -> theory -> theory
   101   val primitive_arity: arity -> theory -> theory
   102   val add_trfuns:
   103     (string * (ast list -> ast)) list *
   104     (string * (term list -> term)) list *
   105     (string * (term list -> term)) list *
   106     (string * (ast list -> ast)) list -> theory -> theory
   107   val add_trfunsT:
   108     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
   109   val add_advanced_trfuns:
   110     (string * (Proof.context -> ast list -> ast)) list *
   111     (string * (Proof.context -> term list -> term)) list *
   112     (string * (Proof.context -> term list -> term)) list *
   113     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
   114   val add_advanced_trfunsT:
   115     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
   116   val add_tokentrfuns:
   117     (string * string * (Proof.context -> string -> Pretty.T)) list -> theory -> theory
   118   val add_mode_tokentrfuns: string -> (string * (Proof.context -> string -> Pretty.T)) list
   119     -> theory -> theory
   120   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   121   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   122   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
   123   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
   124   val new_group: theory -> theory
   125   val reset_group: theory -> theory
   126   val add_path: string -> theory -> theory
   127   val root_path: theory -> theory
   128   val parent_path: theory -> theory
   129   val mandatory_path: string -> theory -> theory
   130   val qualified_path: bool -> binding -> theory -> theory
   131   val local_path: theory -> theory
   132   val restore_naming: theory -> theory -> theory
   133   val hide_class: bool -> string -> theory -> theory
   134   val hide_type: bool -> string -> theory -> theory
   135   val hide_const: bool -> string -> theory -> theory
   136 end
   137 
   138 structure Sign: SIGN =
   139 struct
   140 
   141 (** datatype sign **)
   142 
   143 datatype sign = Sign of
   144  {naming: Name_Space.naming,    (*common naming conventions*)
   145   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   146   tsig: Type.tsig,              (*order-sorted signature of types*)
   147   consts: Consts.T};            (*polymorphic constants*)
   148 
   149 fun make_sign (naming, syn, tsig, consts) =
   150   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   151 
   152 structure SignData = Theory_Data_PP
   153 (
   154   type T = sign;
   155   fun extend (Sign {syn, tsig, consts, ...}) =
   156     make_sign (Name_Space.default_naming, syn, tsig, consts);
   157 
   158   val empty =
   159     make_sign (Name_Space.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   160 
   161   fun merge pp (sign1, sign2) =
   162     let
   163       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   164       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   165 
   166       val naming = Name_Space.default_naming;
   167       val syn = Syntax.merge_syntaxes syn1 syn2;
   168       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   169       val consts = Consts.merge (consts1, consts2);
   170     in make_sign (naming, syn, tsig, consts) end;
   171 );
   172 
   173 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   174 
   175 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   176   make_sign (f (naming, syn, tsig, consts)));
   177 
   178 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   179 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   180 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   181 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   182 
   183 
   184 (* naming *)
   185 
   186 val naming_of = #naming o rep_sg;
   187 
   188 val full_name = Name_Space.full_name o naming_of;
   189 fun full_name_path thy path = Name_Space.full_name (Name_Space.add_path path (naming_of thy));
   190 
   191 fun full_bname thy = Name_Space.full_name (naming_of thy) o Binding.name;
   192 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   193 
   194 
   195 (* syntax *)
   196 
   197 val syn_of = #syn o rep_sg;
   198 
   199 
   200 (* type signature *)
   201 
   202 val tsig_of = #tsig o rep_sg;
   203 
   204 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   205 val all_classes = Sorts.all_classes o classes_of;
   206 val super_classes = Sorts.super_classes o classes_of;
   207 val minimize_sort = Sorts.minimize_sort o classes_of;
   208 val complete_sort = Sorts.complete_sort o classes_of;
   209 
   210 val defaultS = Type.defaultS o tsig_of;
   211 val subsort = Type.subsort o tsig_of;
   212 val of_sort = Type.of_sort o tsig_of;
   213 val witness_sorts = Type.witness_sorts o tsig_of;
   214 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   215 
   216 val typ_instance = Type.typ_instance o tsig_of;
   217 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   218 val typ_match = Type.typ_match o tsig_of;
   219 val typ_unify = Type.unify o tsig_of;
   220 
   221 
   222 (* polymorphic constants *)
   223 
   224 val consts_of = #consts o rep_sg;
   225 val the_const_constraint = Consts.the_constraint o consts_of;
   226 val the_const_type = Consts.the_type o consts_of;
   227 val const_type = try o the_const_type;
   228 val const_monomorphic = Consts.is_monomorphic o consts_of;
   229 val const_typargs = Consts.typargs o consts_of;
   230 val const_instance = Consts.instance o consts_of;
   231 
   232 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   233 
   234 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   235 val declared_const = can o the_const_constraint;
   236 
   237 
   238 
   239 (** intern / extern names **)
   240 
   241 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   242 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   243 val const_space = Consts.space_of o consts_of;
   244 
   245 val intern_class = Name_Space.intern o class_space;
   246 val extern_class = Name_Space.extern o class_space;
   247 val intern_type = Name_Space.intern o type_space;
   248 val extern_type = Name_Space.extern o type_space;
   249 val intern_const = Name_Space.intern o const_space;
   250 val extern_const = Name_Space.extern o const_space;
   251 
   252 val intern_sort = map o intern_class;
   253 val extern_sort = map o extern_class;
   254 
   255 local
   256 
   257 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   258   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   259   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   260 
   261 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   262   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   263   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   264   | map_term _ _ _ (t as Bound _) = t
   265   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   266   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   267 
   268 val add_classesT = Term.fold_atyps
   269   (fn TFree (_, S) => fold (insert (op =)) S
   270     | TVar (_, S) => fold (insert (op =)) S
   271     | _ => I);
   272 
   273 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   274   | add_tyconsT _ = I;
   275 
   276 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   277 
   278 fun mapping add_names f t =
   279   let
   280     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   281     val tab = map_filter f' (add_names t []);
   282     fun get x = the_default x (AList.lookup (op =) tab x);
   283   in get end;
   284 
   285 fun typ_mapping f g thy T =
   286   T |> map_typ
   287     (mapping add_classesT (f thy) T)
   288     (mapping add_tyconsT (g thy) T);
   289 
   290 fun term_mapping f g h thy t =
   291   t |> map_term
   292     (mapping (Term.fold_types add_classesT) (f thy) t)
   293     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   294     (mapping add_consts (h thy) t);
   295 
   296 in
   297 
   298 val intern_typ = typ_mapping intern_class intern_type;
   299 val extern_typ = typ_mapping extern_class extern_type;
   300 val intern_term = term_mapping intern_class intern_type intern_const;
   301 val extern_term = term_mapping extern_class extern_type (K Syntax.mark_const);
   302 val intern_tycons = typ_mapping (K I) intern_type;
   303 
   304 end;
   305 
   306 
   307 
   308 (** certify entities **)    (*exception TYPE*)
   309 
   310 (* certify wrt. type signature *)
   311 
   312 val the_type_decl = Type.the_decl o tsig_of;
   313 val arity_number = Type.arity_number o tsig_of;
   314 fun arity_sorts thy = Type.arity_sorts (Syntax.pp_global thy) (tsig_of thy);
   315 
   316 val certify_class         = Type.cert_class o tsig_of;
   317 val certify_sort          = Type.cert_sort o tsig_of;
   318 val certify_typ           = Type.cert_typ o tsig_of;
   319 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   320 
   321 
   322 (* certify term/prop *)
   323 
   324 local
   325 
   326 fun type_check pp tm =
   327   let
   328     fun err_appl why bs t T u U =
   329       let
   330         val xs = map Free bs;           (*we do not rename here*)
   331         val t' = subst_bounds (xs, t);
   332         val u' = subst_bounds (xs, u);
   333         val msg = cat_lines
   334           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   335       in raise TYPE (msg, [T, U], [t', u']) end;
   336 
   337     fun typ_of (_, Const (_, T)) = T
   338       | typ_of (_, Free  (_, T)) = T
   339       | typ_of (_, Var (_, T)) = T
   340       | typ_of (bs, Bound i) = snd (nth bs i handle Subscript =>
   341           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   342       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   343       | typ_of (bs, t $ u) =
   344           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   345             (case T of
   346               Type ("fun", [T1, T2]) =>
   347                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   348             | _ => err_appl "Operator not of function type" bs t T u U)
   349           end;
   350   in typ_of ([], tm) end;
   351 
   352 fun err msg = raise TYPE (msg, [], []);
   353 
   354 fun check_vars (t $ u) = (check_vars t; check_vars u)
   355   | check_vars (Abs (_, _, t)) = check_vars t
   356   | check_vars (Free (x, _)) =
   357       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   358   | check_vars (Var (xi as (_, i), _)) =
   359       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   360   | check_vars _ = ();
   361 
   362 in
   363 
   364 fun certify' prop pp do_expand consts thy tm =
   365   let
   366     val _ = check_vars tm;
   367     val tm' = Term.map_types (certify_typ thy) tm;
   368     val T = type_check pp tm';
   369     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   370     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   371   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   372 
   373 fun certify_term thy = certify' false (Syntax.pp_global thy) true (consts_of thy) thy;
   374 fun cert_term_abbrev thy = #1 o certify' false (Syntax.pp_global thy) false (consts_of thy) thy;
   375 val cert_term = #1 oo certify_term;
   376 fun cert_prop thy = #1 o certify' true (Syntax.pp_global thy) true (consts_of thy) thy;
   377 
   378 end;
   379 
   380 
   381 (* specifications *)
   382 
   383 fun no_variables kind add addT mk mkT pp tm =
   384   (case (add tm [], addT tm []) of
   385     ([], []) => tm
   386   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   387       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   388        Pretty.commas (map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   389 
   390 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   391 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   392 
   393 fun cert_def ctxt tm =
   394   let val ((lhs, rhs), _) = tm
   395     |> no_vars (Syntax.pp ctxt)
   396     |> Logic.strip_imp_concl
   397     |> Primitive_Defs.dest_def ctxt Term.is_Const (K false) (K false)
   398   in (Term.dest_Const (Term.head_of lhs), rhs) end
   399   handle TERM (msg, _) => error msg;
   400 
   401 
   402 
   403 (** read and certify entities **)    (*exception ERROR*)
   404 
   405 (* classes *)
   406 
   407 fun read_class thy c = certify_class thy (intern_class thy c)
   408   handle TYPE (msg, _, _) => error msg;
   409 
   410 
   411 (* type arities *)
   412 
   413 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   414   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   415   in Type.add_arity (Syntax.pp_global thy) arity (tsig_of thy); arity end;
   416 
   417 val read_arity = prep_arity intern_type Syntax.read_sort_global;
   418 val cert_arity = prep_arity (K I) certify_sort;
   419 
   420 
   421 
   422 (** signature extension functions **)  (*exception ERROR/TYPE*)
   423 
   424 (* add default sort *)
   425 
   426 fun gen_add_defsort prep_sort s thy =
   427   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   428 
   429 val add_defsort = gen_add_defsort Syntax.read_sort_global;
   430 val add_defsort_i = gen_add_defsort certify_sort;
   431 
   432 
   433 (* add type constructors *)
   434 
   435 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   436   let
   437     val syn' = Syntax.update_type_gram (map (fn (a, n, mx) => (Name.of_binding a, n, mx)) types) syn;
   438     val decls = map (fn (a, n, _) => (a, n)) types;
   439     val tsig' = fold (Type.add_type naming) decls tsig;
   440   in (naming, syn', tsig', consts) end);
   441 
   442 
   443 (* add nonterminals *)
   444 
   445 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   446   let
   447     val syn' = Syntax.update_consts (map Name.of_binding ns) syn;
   448     val tsig' = fold (Type.add_nonterminal naming) ns tsig;
   449   in (naming, syn', tsig', consts) end);
   450 
   451 
   452 (* add type abbreviations *)
   453 
   454 fun gen_add_tyabbr parse_typ (b, vs, rhs, mx) thy =
   455   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   456     let
   457       val ctxt = ProofContext.init thy;
   458       val syn' = Syntax.update_type_gram [(Name.of_binding b, length vs, mx)] syn;
   459       val abbr = (b, vs, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt rhs))
   460         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote (Binding.str_of b));
   461       val tsig' = Type.add_abbrev naming abbr tsig;
   462     in (naming, syn', tsig', consts) end);
   463 
   464 val add_tyabbrs = fold (gen_add_tyabbr Syntax.parse_typ);
   465 val add_tyabbrs_i = fold (gen_add_tyabbr (K I));
   466 
   467 
   468 (* modify syntax *)
   469 
   470 fun gen_syntax change_gram parse_typ mode args thy =
   471   let
   472     val ctxt = ProofContext.init thy;
   473     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   474       handle ERROR msg => cat_error msg ("in syntax declaration " ^ quote c);
   475   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   476 
   477 fun gen_add_syntax x = gen_syntax Syntax.update_const_gram x;
   478 
   479 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   480 val add_modesyntax_i = gen_add_syntax (K I);
   481 val add_syntax = add_modesyntax Syntax.mode_default;
   482 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   483 val del_modesyntax = gen_syntax Syntax.remove_const_gram Syntax.parse_typ;
   484 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram (K I);
   485 
   486 fun notation add mode args thy =
   487   let
   488     val change_gram = if add then Syntax.update_const_gram else Syntax.remove_const_gram;
   489     fun const_syntax (Const (c, _), mx) =
   490           (case try (Consts.type_scheme (consts_of thy)) c of
   491             SOME T => SOME (Syntax.mark_const c, T, mx)
   492           | NONE => NONE)
   493       | const_syntax _ = NONE;
   494   in gen_syntax change_gram (K I) mode (map_filter const_syntax args) thy end;
   495 
   496 
   497 (* add constants *)
   498 
   499 local
   500 
   501 fun gen_add_consts parse_typ raw_args thy =
   502   let
   503     val ctxt = ProofContext.init thy;
   504     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   505     fun prep (b, raw_T, mx) =
   506       let
   507         val c = full_name thy b;
   508         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   509           cat_error msg ("in declaration of constant " ^ quote (Binding.str_of b));
   510         val T' = Logic.varifyT T;
   511       in ((b, T'), (Syntax.mark_const c, T', mx), Const (c, T)) end;
   512     val args = map prep raw_args;
   513   in
   514     thy
   515     |> map_consts (fold (Consts.declare (naming_of thy) o #1) args)
   516     |> add_syntax_i (map #2 args)
   517     |> pair (map #3 args)
   518   end;
   519 
   520 in
   521 
   522 fun add_consts args = snd o gen_add_consts Syntax.parse_typ args;
   523 fun add_consts_i args = snd o gen_add_consts (K I) args;
   524 
   525 fun declare_const ((b, T), mx) thy =
   526   let
   527     val pos = Binding.pos_of b;
   528     val ([const as Const (c, _)], thy') = gen_add_consts (K I) [(b, T, mx)] thy;
   529     val _ = Position.report (Markup.const_decl c) pos;
   530   in (const, thy') end;
   531 
   532 end;
   533 
   534 
   535 (* abbreviations *)
   536 
   537 fun add_abbrev mode (b, raw_t) thy =
   538   let
   539     val pp = Syntax.pp_global thy;
   540     val prep_tm = no_frees pp o Term.no_dummy_patterns o cert_term_abbrev thy;
   541     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   542       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Binding.str_of b));
   543     val (res, consts') = consts_of thy
   544       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode (b, t);
   545   in (res, thy |> map_consts (K consts')) end;
   546 
   547 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   548 
   549 
   550 (* add constraints *)
   551 
   552 fun add_const_constraint (c, opt_T) thy =
   553   let
   554     fun prepT raw_T =
   555       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   556       in cert_term thy (Const (c, T)); T end
   557       handle TYPE (msg, _, _) => error msg;
   558   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   559 
   560 
   561 (* primitive classes and arities *)
   562 
   563 fun primitive_class (bclass, classes) thy =
   564   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   565     let
   566       val syn' = Syntax.update_consts [Name.of_binding bclass] syn;
   567       val tsig' = Type.add_class (Syntax.pp_global thy) naming (bclass, classes) tsig;
   568     in (naming, syn', tsig', consts) end)
   569   |> add_consts_i [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   570 
   571 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (Syntax.pp_global thy) arg);
   572 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (Syntax.pp_global thy) arg);
   573 
   574 
   575 (* add translation functions *)
   576 
   577 local
   578 
   579 fun mk trs = map Syntax.mk_trfun trs;
   580 
   581 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   582   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   583 
   584 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   585 
   586 in
   587 
   588 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax.non_typed_tr';
   589 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   590 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax.non_typed_tr'';
   591 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   592 
   593 end;
   594 
   595 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   596 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   597 
   598 
   599 (* translation rules *)
   600 
   601 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   602   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   603   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   604 
   605 val add_trrules = gen_trrules Syntax.update_trrules;
   606 val del_trrules = gen_trrules Syntax.remove_trrules;
   607 val add_trrules_i = map_syn o Syntax.update_trrules_i;
   608 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   609 
   610 
   611 (* naming *)
   612 
   613 val new_group = map_naming Name_Space.new_group;
   614 val reset_group = map_naming Name_Space.reset_group;
   615 
   616 val add_path = map_naming o Name_Space.add_path;
   617 val root_path = map_naming Name_Space.root_path;
   618 val parent_path = map_naming Name_Space.parent_path;
   619 val mandatory_path = map_naming o Name_Space.mandatory_path;
   620 val qualified_path = map_naming oo Name_Space.qualified_path;
   621 
   622 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   623 
   624 val restore_naming = map_naming o K o naming_of;
   625 
   626 
   627 (* hide names *)
   628 
   629 val hide_class = map_tsig oo Type.hide_class;
   630 val hide_type = map_tsig oo Type.hide_type;
   631 val hide_const = map_consts oo Consts.hide;
   632 
   633 end;