src/Pure/Isar/code.ML
author haftmann
Mon Nov 29 11:38:59 2010 +0100 (2010-11-29 ago)
changeset 40803 3f66ea311d44
parent 40764 1a8875eacacd
child 40844 5895c525739d
permissions -rw-r--r--
tuned
     1 (*  Title:      Pure/Isar/code.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Abstract executable ingredients of theory.  Management of data
     5 dependent on executable ingredients as synchronized cache; purged
     6 on any change of underlying executable ingredients.
     7 *)
     8 
     9 signature CODE =
    10 sig
    11   (*constants*)
    12   val check_const: theory -> term -> string
    13   val read_bare_const: theory -> string -> string * typ
    14   val read_const: theory -> string -> string
    15   val string_of_const: theory -> string -> string
    16   val cert_signature: theory -> typ -> typ
    17   val read_signature: theory -> string -> typ
    18   val const_typ: theory -> string -> typ
    19   val subst_signatures: theory -> term -> term
    20   val args_number: theory -> string -> int
    21 
    22   (*constructor sets*)
    23   val constrset_of_consts: theory -> (string * typ) list
    24     -> string * ((string * sort) list * (string * ((string * sort) list * typ list)) list)
    25 
    26   (*code equations and certificates*)
    27   val mk_eqn: theory -> thm * bool -> thm * bool
    28   val mk_eqn_warning: theory -> thm -> (thm * bool) option
    29   val mk_eqn_liberal: theory -> thm -> (thm * bool) option
    30   val assert_eqn: theory -> thm * bool -> thm * bool
    31   val const_typ_eqn: theory -> thm -> string * typ
    32   val expand_eta: theory -> int -> thm -> thm
    33   type cert
    34   val empty_cert: theory -> string -> cert
    35   val cert_of_eqns: theory -> string -> (thm * bool) list -> cert
    36   val constrain_cert: theory -> sort list -> cert -> cert
    37   val typargs_deps_of_cert: theory -> cert -> (string * sort) list * (string * typ list) list
    38   val equations_of_cert: theory -> cert -> ((string * sort) list * typ)
    39     * (((term * string option) list * (term * string option)) * (thm option * bool)) list
    40   val bare_thms_of_cert: theory -> cert -> thm list
    41   val pretty_cert: theory -> cert -> Pretty.T list
    42 
    43   (*executable code*)
    44   val add_type: string -> theory -> theory
    45   val add_type_cmd: string -> theory -> theory
    46   val add_signature: string * typ -> theory -> theory
    47   val add_signature_cmd: string * string -> theory -> theory
    48   val add_datatype: (string * typ) list -> theory -> theory
    49   val add_datatype_cmd: string list -> theory -> theory
    50   val datatype_interpretation:
    51     (string * ((string * sort) list * (string * ((string * sort) list * typ list)) list)
    52       -> theory -> theory) -> theory -> theory
    53   val add_abstype: thm -> theory -> theory
    54   val abstype_interpretation:
    55     (string * ((string * sort) list * ((string * ((string * sort) list * typ)) * (string * thm)))
    56       -> theory -> theory) -> theory -> theory
    57   val add_eqn: thm -> theory -> theory
    58   val add_nbe_eqn: thm -> theory -> theory
    59   val add_default_eqn: thm -> theory -> theory
    60   val add_default_eqn_attribute: attribute
    61   val add_default_eqn_attrib: Attrib.src
    62   val add_nbe_default_eqn: thm -> theory -> theory
    63   val add_nbe_default_eqn_attribute: attribute
    64   val add_nbe_default_eqn_attrib: Attrib.src
    65   val del_eqn: thm -> theory -> theory
    66   val del_eqns: string -> theory -> theory
    67   val add_case: thm -> theory -> theory
    68   val add_undefined: string -> theory -> theory
    69   val get_type: theory -> string
    70     -> ((string * sort) list * (string * ((string * sort) list * typ list)) list) * bool
    71   val get_type_of_constr_or_abstr: theory -> string -> (string * bool) option
    72   val is_constr: theory -> string -> bool
    73   val is_abstr: theory -> string -> bool
    74   val get_cert: theory -> ((thm * bool) list -> (thm * bool) list) -> string -> cert
    75   val get_case_scheme: theory -> string -> (int * (int * string list)) option
    76   val get_case_cong: theory -> string -> thm option
    77   val undefineds: theory -> string list
    78   val print_codesetup: theory -> unit
    79 
    80   (*infrastructure*)
    81   val set_code_target_attr: (string -> thm -> theory -> theory) -> theory -> theory
    82 end;
    83 
    84 signature CODE_DATA_ARGS =
    85 sig
    86   type T
    87   val empty: T
    88 end;
    89 
    90 signature CODE_DATA =
    91 sig
    92   type T
    93   val change: theory option -> (T -> T) -> T
    94   val change_yield: theory option -> (T -> 'a * T) -> 'a * T
    95 end;
    96 
    97 signature PRIVATE_CODE =
    98 sig
    99   include CODE
   100   val declare_data: Object.T -> serial
   101   val change_yield_data: serial * ('a -> Object.T) * (Object.T -> 'a)
   102     -> theory -> ('a -> 'b * 'a) -> 'b * 'a
   103 end;
   104 
   105 structure Code : PRIVATE_CODE =
   106 struct
   107 
   108 (** auxiliary **)
   109 
   110 (* printing *)
   111 
   112 fun string_of_typ thy =
   113   Syntax.string_of_typ (Config.put show_sorts true (Syntax.init_pretty_global thy));
   114 
   115 fun string_of_const thy c = case AxClass.inst_of_param thy c
   116  of SOME (c, tyco) => Sign.extern_const thy c ^ " " ^ enclose "[" "]" (Sign.extern_type thy tyco)
   117   | NONE => Sign.extern_const thy c;
   118 
   119 
   120 (* constants *)
   121 
   122 fun typ_equiv tys = Type.raw_instance tys andalso Type.raw_instance (swap tys);
   123 
   124 fun check_bare_const thy t = case try dest_Const t
   125  of SOME c_ty => c_ty
   126   | NONE => error ("Not a constant: " ^ Syntax.string_of_term_global thy t);
   127 
   128 fun check_unoverload thy (c, ty) =
   129   let
   130     val c' = AxClass.unoverload_const thy (c, ty);
   131     val ty_decl = Sign.the_const_type thy c';
   132   in if Sign.typ_equiv thy
   133       (Type.strip_sorts ty_decl, Type.strip_sorts (Logic.varifyT_global ty)) then c'
   134     else error ("Type\n" ^ string_of_typ thy ty
   135       ^ "\nof constant " ^ quote c
   136       ^ "\nis too specific compared to declared type\n"
   137       ^ string_of_typ thy ty_decl)
   138   end; 
   139 
   140 fun check_const thy = check_unoverload thy o check_bare_const thy;
   141 
   142 fun read_bare_const thy = check_bare_const thy o Syntax.read_term_global thy;
   143 
   144 fun read_const thy = check_unoverload thy o read_bare_const thy;
   145 
   146 
   147 (** data store **)
   148 
   149 (* datatypes *)
   150 
   151 datatype typ_spec = Constructors of (string * ((string * sort) list * typ list)) list
   152   | Abstractor of (string * ((string * sort) list * typ)) * (string * thm);
   153 
   154 fun constructors_of (Constructors cos) = (cos, false)
   155   | constructors_of (Abstractor ((co, (vs, ty)), _)) = ([(co, (vs, [ty]))], true);
   156 
   157 
   158 (* functions *)
   159 
   160 datatype fun_spec = Default of (thm * bool) list * (thm * bool) list lazy
   161   | Eqns of (thm * bool) list
   162   | Proj of term * string
   163   | Abstr of thm * string;
   164 
   165 val empty_fun_spec = Default ([], Lazy.value []);
   166 
   167 fun is_default (Default _) = true
   168   | is_default _ = false;
   169 
   170 fun associated_abstype (Abstr (_, tyco)) = SOME tyco
   171   | associated_abstype _ = NONE;
   172 
   173 
   174 (* executable code data *)
   175 
   176 datatype spec = Spec of {
   177   history_concluded: bool,
   178   signatures: int Symtab.table * typ Symtab.table,
   179   functions: ((bool * fun_spec) * (serial * fun_spec) list) Symtab.table
   180     (*with explicit history*),
   181   types: ((serial * ((string * sort) list * typ_spec)) list) Symtab.table
   182     (*with explicit history*),
   183   cases: ((int * (int * string list)) * thm) Symtab.table * unit Symtab.table
   184 };
   185 
   186 fun make_spec (history_concluded, ((signatures, functions), (types, cases))) =
   187   Spec { history_concluded = history_concluded,
   188     signatures = signatures, functions = functions, types = types, cases = cases };
   189 fun map_spec f (Spec { history_concluded = history_concluded, signatures = signatures,
   190   functions = functions, types = types, cases = cases }) =
   191   make_spec (f (history_concluded, ((signatures, functions), (types, cases))));
   192 fun merge_spec (Spec { history_concluded = _, signatures = (tycos1, sigs1), functions = functions1,
   193     types = types1, cases = (cases1, undefs1) },
   194   Spec { history_concluded = _, signatures = (tycos2, sigs2), functions = functions2,
   195     types = types2, cases = (cases2, undefs2) }) =
   196   let
   197     val signatures = (Symtab.merge (op =) (tycos1, tycos2),
   198       Symtab.merge typ_equiv (sigs1, sigs2));
   199     fun merge_functions ((_, history1), (_, history2)) =
   200       let
   201         val raw_history = AList.merge (op = : serial * serial -> bool)
   202           (K true) (history1, history2);
   203         val filtered_history = filter_out (is_default o snd) raw_history;
   204         val history = if null filtered_history
   205           then raw_history else filtered_history;
   206       in ((false, (snd o hd) history), history) end;
   207     val functions = Symtab.join (K merge_functions) (functions1, functions2);
   208     val types = Symtab.join (K (AList.merge (op =) (K true))) (types1, types2);
   209     val cases = (Symtab.merge (K true) (cases1, cases2),
   210       Symtab.merge (K true) (undefs1, undefs2));
   211   in make_spec (false, ((signatures, functions), (types, cases))) end;
   212 
   213 fun history_concluded (Spec { history_concluded, ... }) = history_concluded;
   214 fun the_signatures (Spec { signatures, ... }) = signatures;
   215 fun the_functions (Spec { functions, ... }) = functions;
   216 fun the_types (Spec { types, ... }) = types;
   217 fun the_cases (Spec { cases, ... }) = cases;
   218 val map_history_concluded = map_spec o apfst;
   219 val map_signatures = map_spec o apsnd o apfst o apfst;
   220 val map_functions = map_spec o apsnd o apfst o apsnd;
   221 val map_typs = map_spec o apsnd o apsnd o apfst;
   222 val map_cases = map_spec o apsnd o apsnd o apsnd;
   223 
   224 
   225 (* data slots dependent on executable code *)
   226 
   227 (*private copy avoids potential conflict of table exceptions*)
   228 structure Datatab = Table(type key = int val ord = int_ord);
   229 
   230 local
   231 
   232 type kind = { empty: Object.T };
   233 
   234 val kinds = Unsynchronized.ref (Datatab.empty: kind Datatab.table);
   235 
   236 fun invoke f k = case Datatab.lookup (! kinds) k
   237  of SOME kind => f kind
   238   | NONE => raise Fail "Invalid code data identifier";
   239 
   240 in
   241 
   242 fun declare_data empty =
   243   let
   244     val k = serial ();
   245     val kind = { empty = empty };
   246     val _ = CRITICAL (fn () => Unsynchronized.change kinds (Datatab.update (k, kind)));
   247   in k end;
   248 
   249 fun invoke_init k = invoke (fn kind => #empty kind) k;
   250 
   251 end; (*local*)
   252 
   253 
   254 (* theory store *)
   255 
   256 local
   257 
   258 type data = Object.T Datatab.table;
   259 fun empty_dataref () = Synchronized.var "code data" (NONE : (data * theory_ref) option);
   260 
   261 structure Code_Data = Theory_Data
   262 (
   263   type T = spec * (data * theory_ref) option Synchronized.var;
   264   val empty = (make_spec (false, (((Symtab.empty, Symtab.empty), Symtab.empty),
   265     (Symtab.empty, (Symtab.empty, Symtab.empty)))), empty_dataref ());
   266   val extend = I
   267   fun merge ((spec1, _), (spec2, _)) =
   268     (merge_spec (spec1, spec2), empty_dataref ());
   269 );
   270 
   271 in
   272 
   273 
   274 (* access to executable code *)
   275 
   276 val the_exec = fst o Code_Data.get;
   277 
   278 fun map_exec_purge f = Code_Data.map (fn (exec, _) => (f exec, empty_dataref ()));
   279 
   280 fun change_fun_spec delete c f = (map_exec_purge o map_functions
   281   o (if delete then Symtab.map_entry c else Symtab.map_default (c, ((false, empty_fun_spec), [])))
   282     o apfst) (fn (_, spec) => (true, f spec));
   283 
   284 
   285 (* tackling equation history *)
   286 
   287 fun continue_history thy = if (history_concluded o the_exec) thy
   288   then thy
   289     |> (Code_Data.map o apfst o map_history_concluded) (K false)
   290     |> SOME
   291   else NONE;
   292 
   293 fun conclude_history thy = if (history_concluded o the_exec) thy
   294   then NONE
   295   else thy
   296     |> (Code_Data.map o apfst)
   297         ((map_functions o Symtab.map) (fn _ => fn ((changed, current), history) =>
   298           ((false, current),
   299             if changed then (serial (), current) :: history else history))
   300         #> map_history_concluded (K true))
   301     |> SOME;
   302 
   303 val _ = Context.>> (Context.map_theory (Theory.at_begin continue_history #> Theory.at_end conclude_history));
   304 
   305 
   306 (* access to data dependent on abstract executable code *)
   307 
   308 fun change_yield_data (kind, mk, dest) theory f =
   309   let
   310     val dataref = (snd o Code_Data.get) theory;
   311     val (datatab, thy_ref) = case Synchronized.value dataref
   312      of SOME (datatab, thy_ref) => if Theory.eq_thy (theory, Theory.deref thy_ref)
   313           then (datatab, thy_ref)
   314           else (Datatab.empty, Theory.check_thy theory)
   315       | NONE => (Datatab.empty, Theory.check_thy theory)
   316     val data = case Datatab.lookup datatab kind
   317      of SOME data => data
   318       | NONE => invoke_init kind;
   319     val result as (_, data') = f (dest data);
   320     val _ = Synchronized.change dataref
   321       ((K o SOME) (Datatab.update (kind, mk data') datatab, thy_ref));
   322   in result end;
   323 
   324 end; (*local*)
   325 
   326 
   327 (** foundation **)
   328 
   329 (* constants *)
   330 
   331 fun arity_number thy tyco = case Symtab.lookup ((fst o the_signatures o the_exec) thy) tyco
   332  of SOME n => n
   333   | NONE => Sign.arity_number thy tyco;
   334 
   335 fun build_tsig thy =
   336   let
   337     val (tycos, _) = (the_signatures o the_exec) thy;
   338     val decls = (#types o Type.rep_tsig o Sign.tsig_of) thy
   339       |> snd 
   340       |> Symtab.fold (fn (tyco, n) =>
   341           Symtab.update (tyco, Type.LogicalType n)) tycos;
   342   in
   343     Type.empty_tsig
   344     |> Symtab.fold (fn (tyco, Type.LogicalType n) => Type.add_type Name_Space.default_naming
   345         (Binding.qualified_name tyco, n) | _ => I) decls
   346   end;
   347 
   348 fun cert_signature thy = Logic.varifyT_global o Type.cert_typ (build_tsig thy) o Type.no_tvars;
   349 
   350 fun read_signature thy = cert_signature thy o Type.strip_sorts
   351   o Syntax.parse_typ (ProofContext.init_global thy);
   352 
   353 fun expand_signature thy = Type.cert_typ_mode Type.mode_syntax (Sign.tsig_of thy);
   354 
   355 fun lookup_typ thy = Symtab.lookup ((snd o the_signatures o the_exec) thy);
   356 
   357 fun const_typ thy c = case lookup_typ thy c
   358  of SOME ty => ty
   359   | NONE => (Type.strip_sorts o Sign.the_const_type thy) c;
   360 
   361 fun args_number thy = length o fst o strip_type o const_typ thy;
   362 
   363 fun subst_signature thy c ty =
   364   let
   365     fun mk_subst (Type (_, tys1)) (Type (_, tys2)) =
   366           fold2 mk_subst tys1 tys2
   367       | mk_subst ty (TVar (v, _)) = Vartab.update (v, ([], ty))
   368   in case lookup_typ thy c
   369    of SOME ty' => Envir.subst_type (mk_subst ty (expand_signature thy ty') Vartab.empty) ty'
   370     | NONE => ty
   371   end;
   372 
   373 fun subst_signatures thy = map_aterms (fn Const (c, ty) => Const (c, subst_signature thy c ty) | t => t);
   374 
   375 fun logical_typscheme thy (c, ty) =
   376   (map dest_TFree (Sign.const_typargs thy (c, ty)), Type.strip_sorts ty);
   377 
   378 fun typscheme thy (c, ty) = logical_typscheme thy (c, subst_signature thy c ty);
   379 
   380 
   381 (* datatypes *)
   382 
   383 fun no_constr thy s (c, ty) = error ("Not a datatype constructor:\n" ^ string_of_const thy c
   384   ^ " :: " ^ string_of_typ thy ty ^ "\n" ^ enclose "(" ")" s);
   385 
   386 fun analyze_constructor thy (c, raw_ty) =
   387   let
   388     val _ = Thm.cterm_of thy (Const (c, raw_ty));
   389     val ty = subst_signature thy c raw_ty;
   390     val ty_decl = (Logic.unvarifyT_global o const_typ thy) c;
   391     fun last_typ c_ty ty =
   392       let
   393         val tfrees = Term.add_tfreesT ty [];
   394         val (tyco, vs) = ((apsnd o map) (dest_TFree) o dest_Type o snd o strip_type) ty
   395           handle TYPE _ => no_constr thy "bad type" c_ty
   396         val _ = if tyco = "fun" then no_constr thy "bad type" c_ty else ();
   397         val _ = if has_duplicates (eq_fst (op =)) vs
   398           then no_constr thy "duplicate type variables in datatype" c_ty else ();
   399         val _ = if length tfrees <> length vs
   400           then no_constr thy "type variables missing in datatype" c_ty else ();
   401       in (tyco, vs) end;
   402     val (tyco, _) = last_typ (c, ty) ty_decl;
   403     val (_, vs) = last_typ (c, ty) ty;
   404   in ((tyco, map snd vs), (c, (map fst vs, ty))) end;
   405 
   406 fun constrset_of_consts thy cs =
   407   let
   408     val _ = map (fn (c, _) => if (is_some o AxClass.class_of_param thy) c
   409       then error ("Is a class parameter: " ^ string_of_const thy c) else ()) cs;
   410     fun add ((tyco', sorts'), c) ((tyco, sorts), cs) =
   411       let
   412         val _ = if (tyco' : string) <> tyco
   413           then error "Different type constructors in constructor set"
   414           else ();
   415         val sorts'' =
   416           map2 (curry (Sorts.inter_sort (Sign.classes_of thy))) sorts' sorts
   417       in ((tyco, sorts''), c :: cs) end;
   418     fun inst vs' (c, (vs, ty)) =
   419       let
   420         val the_v = the o AList.lookup (op =) (vs ~~ vs');
   421         val ty' = map_type_tfree (fn (v, _) => TFree (the_v v)) ty;
   422         val (vs'', _) = logical_typscheme thy (c, ty');
   423       in (c, (vs'', (fst o strip_type) ty')) end;
   424     val c' :: cs' = map (analyze_constructor thy) cs;
   425     val ((tyco, sorts), cs'') = fold add cs' (apsnd single c');
   426     val vs = Name.names Name.context Name.aT sorts;
   427     val cs''' = map (inst vs) cs'';
   428   in (tyco, (vs, rev cs''')) end;
   429 
   430 fun get_type_entry thy tyco = case these (Symtab.lookup ((the_types o the_exec) thy) tyco)
   431  of (_, entry) :: _ => SOME entry
   432   | _ => NONE;
   433 
   434 fun get_type thy tyco = case get_type_entry thy tyco
   435  of SOME (vs, spec) => apfst (pair vs) (constructors_of spec)
   436   | NONE => arity_number thy tyco
   437       |> Name.invents Name.context Name.aT
   438       |> map (rpair [])
   439       |> rpair []
   440       |> rpair false;
   441 
   442 fun get_abstype_spec thy tyco = case get_type_entry thy tyco
   443  of SOME (vs, Abstractor spec) => (vs, spec)
   444   | _ => error ("Not an abstract type: " ^ tyco);
   445  
   446 fun get_type_of_constr_or_abstr thy c =
   447   case (snd o strip_type o const_typ thy) c
   448    of Type (tyco, _) => let val ((_, cos), abstract) = get_type thy tyco
   449         in if member (op =) (map fst cos) c then SOME (tyco, abstract) else NONE end
   450     | _ => NONE;
   451 
   452 fun is_constr thy c = case get_type_of_constr_or_abstr thy c
   453  of SOME (_, false) => true
   454    | _ => false;
   455 
   456 fun is_abstr thy c = case get_type_of_constr_or_abstr thy c
   457  of SOME (_, true) => true
   458    | _ => false;
   459 
   460 
   461 (* bare code equations *)
   462 
   463 (* convention for variables:
   464     ?x ?'a   for free-floating theorems (e.g. in the data store)
   465     ?x  'a   for certificates
   466      x  'a   for final representation of equations
   467 *)
   468 
   469 exception BAD_THM of string;
   470 fun bad_thm msg = raise BAD_THM msg;
   471 fun error_thm f thm = f thm handle BAD_THM msg => error msg;
   472 fun warning_thm f thm = SOME (f thm) handle BAD_THM msg => (warning msg; NONE)
   473 fun try_thm f thm = SOME (f thm) handle BAD_THM _ => NONE;
   474 
   475 fun is_linear thm =
   476   let val (_, args) = (strip_comb o fst o Logic.dest_equals o Thm.plain_prop_of) thm
   477   in not (has_duplicates (op =) ((fold o fold_aterms)
   478     (fn Var (v, _) => cons v | _ => I) args [])) end;
   479 
   480 fun check_decl_ty thy (c, ty) =
   481   let
   482     val ty_decl = Sign.the_const_type thy c;
   483   in if Sign.typ_equiv thy (Type.strip_sorts ty_decl, Type.strip_sorts ty) then ()
   484     else bad_thm ("Type\n" ^ string_of_typ thy ty
   485       ^ "\nof constant " ^ quote c
   486       ^ "\nis too specific compared to declared type\n"
   487       ^ string_of_typ thy ty_decl)
   488   end; 
   489 
   490 fun check_eqn thy { allow_nonlinear, allow_consts, allow_pats } thm (lhs, rhs) =
   491   let
   492     fun bad s = bad_thm (s ^ ":\n" ^ Display.string_of_thm_global thy thm);
   493     fun vars_of t = fold_aterms (fn Var (v, _) => insert (op =) v
   494       | Free _ => bad "Illegal free variable in equation"
   495       | _ => I) t [];
   496     fun tvars_of t = fold_term_types (fn _ =>
   497       fold_atyps (fn TVar (v, _) => insert (op =) v
   498         | TFree _ => bad "Illegal free type variable in equation")) t [];
   499     val lhs_vs = vars_of lhs;
   500     val rhs_vs = vars_of rhs;
   501     val lhs_tvs = tvars_of lhs;
   502     val rhs_tvs = tvars_of rhs;
   503     val _ = if null (subtract (op =) lhs_vs rhs_vs)
   504       then ()
   505       else bad "Free variables on right hand side of equation";
   506     val _ = if null (subtract (op =) lhs_tvs rhs_tvs)
   507       then ()
   508       else bad "Free type variables on right hand side of equation";
   509     val (head, args) = strip_comb lhs;
   510     val (c, ty) = case head
   511      of Const (c_ty as (_, ty)) => (AxClass.unoverload_const thy c_ty, ty)
   512       | _ => bad "Equation not headed by constant";
   513     fun check _ (Abs _) = bad "Abstraction on left hand side of equation"
   514       | check 0 (Var _) = ()
   515       | check _ (Var _) = bad "Variable with application on left hand side of equation"
   516       | check n (t1 $ t2) = (check (n+1) t1; check 0 t2)
   517       | check n (Const (c_ty as (c, ty))) =
   518           if allow_pats then let
   519             val c' = AxClass.unoverload_const thy c_ty
   520           in if n = (length o fst o strip_type o subst_signature thy c') ty
   521             then if allow_consts orelse is_constr thy c'
   522               then ()
   523               else bad (quote c ^ " is not a constructor, on left hand side of equation")
   524             else bad ("Partially applied constant " ^ quote c ^ " on left hand side of equation")
   525           end else bad ("Pattern not allowed here, but constant " ^ quote c ^ " encountered on left hand side")
   526     val _ = map (check 0) args;
   527     val _ = if allow_nonlinear orelse is_linear thm then ()
   528       else bad "Duplicate variables on left hand side of equation";
   529     val _ = if (is_none o AxClass.class_of_param thy) c then ()
   530       else bad "Overloaded constant as head in equation";
   531     val _ = if not (is_constr thy c) then ()
   532       else bad "Constructor as head in equation";
   533     val _ = if not (is_abstr thy c) then ()
   534       else bad "Abstractor as head in equation";
   535     val _ = check_decl_ty thy (c, ty);
   536   in () end;
   537 
   538 fun gen_assert_eqn thy check_patterns (thm, proper) =
   539   let
   540     fun bad s = bad_thm (s ^ ":\n" ^ Display.string_of_thm_global thy thm);
   541     val (lhs, rhs) = (Logic.dest_equals o Thm.plain_prop_of) thm
   542       handle TERM _ => bad "Not an equation"
   543            | THM _ => bad "Not a proper equation";
   544     val _ = check_eqn thy { allow_nonlinear = not proper,
   545       allow_consts = not (proper andalso check_patterns), allow_pats = true } thm (lhs, rhs);
   546   in (thm, proper) end;
   547 
   548 fun assert_abs_eqn thy some_tyco thm =
   549   let
   550     fun bad s = bad_thm (s ^ ":\n" ^ Display.string_of_thm_global thy thm);
   551     val (full_lhs, rhs) = (Logic.dest_equals o Thm.plain_prop_of) thm
   552       handle TERM _ => bad "Not an equation"
   553            | THM _ => bad "Not a proper equation";
   554     val (rep, lhs) = dest_comb full_lhs
   555       handle TERM _ => bad "Not an abstract equation";
   556     val (rep_const, ty) = dest_Const rep;
   557     val (tyco, Ts) = (dest_Type o domain_type) ty
   558       handle TERM _ => bad "Not an abstract equation"
   559            | TYPE _ => bad "Not an abstract equation";
   560     val _ = case some_tyco of SOME tyco' => if tyco = tyco' then ()
   561           else bad ("Abstract type mismatch:" ^ quote tyco ^ " vs. " ^ quote tyco')
   562       | NONE => ();
   563     val (vs', (_, (rep', _))) = get_abstype_spec thy tyco;
   564     val _ = if rep_const = rep' then ()
   565       else bad ("Projection mismatch: " ^ quote rep_const ^ " vs. " ^ quote rep');
   566     val _ = check_eqn thy { allow_nonlinear = false,
   567       allow_consts = false, allow_pats = false } thm (lhs, rhs);
   568     val _ = if forall2 (fn T => fn (_, sort) => Sign.of_sort thy (T, sort)) Ts vs' then ()
   569       else error ("Type arguments do not satisfy sort constraints of abstype certificate.");
   570   in (thm, tyco) end;
   571 
   572 fun assert_eqn thy = error_thm (gen_assert_eqn thy true);
   573 
   574 fun meta_rewrite thy = Local_Defs.meta_rewrite_rule (ProofContext.init_global thy);
   575 
   576 fun mk_eqn thy = error_thm (gen_assert_eqn thy false) o
   577   apfst (meta_rewrite thy);
   578 
   579 fun mk_eqn_warning thy = Option.map (fn (thm, _) => (thm, is_linear thm))
   580   o warning_thm (gen_assert_eqn thy false) o rpair false o meta_rewrite thy;
   581 
   582 fun mk_eqn_liberal thy = Option.map (fn (thm, _) => (thm, is_linear thm))
   583   o try_thm (gen_assert_eqn thy false) o rpair false o meta_rewrite thy;
   584 
   585 fun mk_abs_eqn thy = error_thm (assert_abs_eqn thy NONE) o meta_rewrite thy;
   586 
   587 val head_eqn = dest_Const o fst o strip_comb o fst o Logic.dest_equals o Thm.plain_prop_of;
   588 
   589 fun const_typ_eqn thy thm =
   590   let
   591     val (c, ty) = head_eqn thm;
   592     val c' = AxClass.unoverload_const thy (c, ty);
   593       (*permissive wrt. to overloaded constants!*)
   594   in (c', ty) end;
   595 
   596 fun const_eqn thy = fst o const_typ_eqn thy;
   597 
   598 fun const_abs_eqn thy = AxClass.unoverload_const thy o dest_Const o fst o strip_comb o snd
   599   o dest_comb o fst o Logic.dest_equals o Thm.plain_prop_of;
   600 
   601 fun mk_proj tyco vs ty abs rep =
   602   let
   603     val ty_abs = Type (tyco, map TFree vs);
   604     val xarg = Var (("x", 0), ty);
   605   in Logic.mk_equals (Const (rep, ty_abs --> ty) $ (Const (abs, ty --> ty_abs) $ xarg), xarg) end;
   606 
   607 
   608 (* technical transformations of code equations *)
   609 
   610 fun expand_eta thy k thm =
   611   let
   612     val (lhs, rhs) = (Logic.dest_equals o Thm.plain_prop_of) thm;
   613     val (_, args) = strip_comb lhs;
   614     val l = if k = ~1
   615       then (length o fst o strip_abs) rhs
   616       else Int.max (0, k - length args);
   617     val (raw_vars, _) = Term.strip_abs_eta l rhs;
   618     val vars = burrow_fst (Name.variant_list (map (fst o fst) (Term.add_vars lhs [])))
   619       raw_vars;
   620     fun expand (v, ty) thm = Drule.fun_cong_rule thm
   621       (Thm.cterm_of thy (Var ((v, 0), ty)));
   622   in
   623     thm
   624     |> fold expand vars
   625     |> Conv.fconv_rule Drule.beta_eta_conversion
   626   end;
   627 
   628 fun same_arity thy thms =
   629   let
   630     val num_args_of = length o snd o strip_comb o fst o Logic.dest_equals;
   631     val k = fold (Integer.max o num_args_of o Thm.prop_of) thms 0;
   632   in map (expand_eta thy k) thms end;
   633 
   634 fun mk_desymbolization pre post mk vs =
   635   let
   636     val names = map (pre o fst o fst) vs
   637       |> map (Name.desymbolize false)
   638       |> Name.variant_list []
   639       |> map post;
   640   in map_filter (fn (((v, i), x), v') =>
   641     if v = v' andalso i = 0 then NONE
   642     else SOME (((v, i), x), mk ((v', 0), x))) (vs ~~ names)
   643   end;
   644 
   645 fun desymbolize_tvars thms =
   646   let
   647     val tvs = fold (Term.add_tvars o Thm.prop_of) thms [];
   648     val tvar_subst = mk_desymbolization (unprefix "'") (prefix "'") TVar tvs;
   649   in map (Thm.certify_instantiate (tvar_subst, [])) thms end;
   650 
   651 fun desymbolize_vars thm =
   652   let
   653     val vs = Term.add_vars (Thm.prop_of thm) [];
   654     val var_subst = mk_desymbolization I I Var vs;
   655   in Thm.certify_instantiate ([], var_subst) thm end;
   656 
   657 fun canonize_thms thy = desymbolize_tvars #> same_arity thy #> map desymbolize_vars;
   658 
   659 
   660 (* abstype certificates *)
   661 
   662 fun check_abstype_cert thy proto_thm =
   663   let
   664     val thm = (AxClass.unoverload thy o meta_rewrite thy) proto_thm;
   665     fun bad s = bad_thm (s ^ ":\n" ^ Display.string_of_thm_global thy thm);
   666     val (lhs, rhs) = Logic.dest_equals (Thm.plain_prop_of thm)
   667       handle TERM _ => bad "Not an equation"
   668            | THM _ => bad "Not a proper equation";
   669     val ((abs, raw_ty), ((rep, rep_ty), param)) = (apsnd (apfst dest_Const o dest_comb)
   670         o apfst dest_Const o dest_comb) lhs
   671       handle TERM _ => bad "Not an abstype certificate";
   672     val _ = pairself (fn c => if (is_some o AxClass.class_of_param thy) c
   673       then error ("Is a class parameter: " ^ string_of_const thy c) else ()) (abs, rep);
   674     val _ = check_decl_ty thy (abs, raw_ty);
   675     val _ = check_decl_ty thy (rep, rep_ty);
   676     val _ = (fst o dest_Var) param
   677       handle TERM _ => bad "Not an abstype certificate";
   678     val _ = if param = rhs then () else bad "Not an abstype certificate";
   679     val ((tyco, sorts), (abs, (vs, ty'))) = analyze_constructor thy (abs, Logic.unvarifyT_global raw_ty);
   680     val ty = domain_type ty';
   681     val (vs', _) = logical_typscheme thy (abs, ty');
   682   in (tyco, (vs ~~ sorts, ((abs, (vs', ty)), (rep, thm)))) end;
   683 
   684 
   685 (* code equation certificates *)
   686 
   687 fun build_head thy (c, ty) =
   688   Thm.cterm_of thy (Logic.mk_equals (Free ("HEAD", ty), Const (c, ty)));
   689 
   690 fun get_head thy cert_thm =
   691   let
   692     val [head] = (#hyps o Thm.crep_thm) cert_thm;
   693     val (_, Const (c, ty)) = (Logic.dest_equals o Thm.term_of) head;
   694   in (typscheme thy (c, ty), head) end;
   695 
   696 fun typscheme_projection thy =
   697   typscheme thy o dest_Const o fst o dest_comb o fst o Logic.dest_equals;
   698 
   699 fun typscheme_abs thy =
   700   typscheme thy o dest_Const o fst o strip_comb o snd o dest_comb o fst o Logic.dest_equals o Thm.prop_of;
   701 
   702 fun constrain_thm thy vs sorts thm =
   703   let
   704     val mapping = map2 (fn (v, sort) => fn sort' =>
   705       (v, Sorts.inter_sort (Sign.classes_of thy) (sort, sort'))) vs sorts;
   706     val inst = map2 (fn (v, sort) => fn (_, sort') =>
   707       (((v, 0), sort), TFree (v, sort'))) vs mapping;
   708     val subst = (map_types o map_type_tfree)
   709       (fn (v, _) => TFree (v, the (AList.lookup (op =) mapping v)));
   710   in
   711     thm
   712     |> Thm.varifyT_global
   713     |> Thm.certify_instantiate (inst, [])
   714     |> pair subst
   715   end;
   716 
   717 fun concretify_abs thy tyco abs_thm =
   718   let
   719     val (_, ((c, _), (_, cert))) = get_abstype_spec thy tyco;
   720     val lhs = (fst o Logic.dest_equals o Thm.prop_of) abs_thm
   721     val ty = fastype_of lhs;
   722     val ty_abs = (fastype_of o snd o dest_comb) lhs;
   723     val abs = Thm.cterm_of thy (Const (c, ty --> ty_abs));
   724     val raw_concrete_thm = Drule.transitive_thm OF [Thm.symmetric cert, Thm.combination (Thm.reflexive abs) abs_thm];
   725   in (c, (Thm.varifyT_global o zero_var_indexes) raw_concrete_thm) end;
   726 
   727 fun add_rhss_of_eqn thy t =
   728   let
   729     val (args, rhs) = (apfst (snd o strip_comb) o Logic.dest_equals o subst_signatures thy) t;
   730     fun add_const (Const (c, ty)) = insert (op =) (c, Sign.const_typargs thy (c, ty))
   731       | add_const _ = I
   732     val add_consts = fold_aterms add_const
   733   in add_consts rhs o fold add_consts args end;
   734 
   735 fun dest_eqn thy =
   736   apfst (snd o strip_comb) o Logic.dest_equals o subst_signatures thy o Logic.unvarify_global;
   737 
   738 abstype cert = Equations of thm * bool list
   739   | Projection of term * string
   740   | Abstract of thm * string
   741 with
   742 
   743 fun empty_cert thy c = 
   744   let
   745     val raw_ty = Logic.unvarifyT_global (const_typ thy c);
   746     val (vs, _) = logical_typscheme thy (c, raw_ty);
   747     val sortargs = case AxClass.class_of_param thy c
   748      of SOME class => [[class]]
   749       | NONE => (case get_type_of_constr_or_abstr thy c
   750          of SOME (tyco, _) => (map snd o fst o the)
   751               (AList.lookup (op =) ((snd o fst o get_type thy) tyco) c)
   752           | NONE => replicate (length vs) []);
   753     val the_sort = the o AList.lookup (op =) (map fst vs ~~ sortargs);
   754     val ty = map_type_tfree (fn (v, _) => TFree (v, the_sort v)) raw_ty
   755     val chead = build_head thy (c, ty);
   756   in Equations (Thm.weaken chead Drule.dummy_thm, []) end;
   757 
   758 fun cert_of_eqns thy c [] = empty_cert thy c
   759   | cert_of_eqns thy c raw_eqns = 
   760       let
   761         val eqns = burrow_fst (canonize_thms thy) raw_eqns;
   762         val _ = map (assert_eqn thy) eqns;
   763         val (thms, propers) = split_list eqns;
   764         val _ = map (fn thm => if c = const_eqn thy thm then ()
   765           else error ("Wrong head of code equation,\nexpected constant "
   766             ^ string_of_const thy c ^ "\n" ^ Display.string_of_thm_global thy thm)) thms;
   767         fun tvars_of T = rev (Term.add_tvarsT T []);
   768         val vss = map (tvars_of o snd o head_eqn) thms;
   769         fun inter_sorts vs =
   770           fold (curry (Sorts.inter_sort (Sign.classes_of thy)) o snd) vs [];
   771         val sorts = map_transpose inter_sorts vss;
   772         val vts = Name.names Name.context Name.aT sorts;
   773         val thms' =
   774           map2 (fn vs => Thm.certify_instantiate (vs ~~ map TFree vts, [])) vss thms;
   775         val head_thm = Thm.symmetric (Thm.assume (build_head thy (head_eqn (hd thms'))));
   776         fun head_conv ct = if can Thm.dest_comb ct
   777           then Conv.fun_conv head_conv ct
   778           else Conv.rewr_conv head_thm ct;
   779         val rewrite_head = Conv.fconv_rule (Conv.arg1_conv head_conv);
   780         val cert_thm = Conjunction.intr_balanced (map rewrite_head thms');
   781       in Equations (cert_thm, propers) end;
   782 
   783 fun cert_of_proj thy c tyco =
   784   let
   785     val (vs, ((abs, (_, ty)), (rep, _))) = get_abstype_spec thy tyco;
   786     val _ = if c = rep then () else
   787       error ("Wrong head of projection,\nexpected constant " ^ string_of_const thy rep);
   788   in Projection (mk_proj tyco vs ty abs rep, tyco) end;
   789 
   790 fun cert_of_abs thy tyco c raw_abs_thm =
   791   let
   792     val abs_thm = singleton (canonize_thms thy) raw_abs_thm;
   793     val _ = assert_abs_eqn thy (SOME tyco) abs_thm;
   794     val _ = if c = const_abs_eqn thy abs_thm then ()
   795       else error ("Wrong head of abstract code equation,\nexpected constant "
   796         ^ string_of_const thy c ^ "\n" ^ Display.string_of_thm_global thy abs_thm);
   797   in Abstract (Thm.legacy_freezeT abs_thm, tyco) end;
   798 
   799 fun constrain_cert thy sorts (Equations (cert_thm, propers)) =
   800       let
   801         val ((vs, _), head) = get_head thy cert_thm;
   802         val (subst, cert_thm') = cert_thm
   803           |> Thm.implies_intr head
   804           |> constrain_thm thy vs sorts;
   805         val head' = Thm.term_of head
   806           |> subst
   807           |> Thm.cterm_of thy;
   808         val cert_thm'' = cert_thm'
   809           |> Thm.elim_implies (Thm.assume head');
   810       in Equations (cert_thm'', propers) end
   811   | constrain_cert thy _ (cert as Projection _) =
   812       cert
   813   | constrain_cert thy sorts (Abstract (abs_thm, tyco)) =
   814       Abstract (snd (constrain_thm thy (fst (typscheme_abs thy abs_thm)) sorts abs_thm), tyco);
   815 
   816 fun typscheme_of_cert thy (Equations (cert_thm, _)) =
   817       fst (get_head thy cert_thm)
   818   | typscheme_of_cert thy (Projection (proj, _)) =
   819       typscheme_projection thy proj
   820   | typscheme_of_cert thy (Abstract (abs_thm, _)) =
   821       typscheme_abs thy abs_thm;
   822 
   823 fun typargs_deps_of_cert thy (Equations (cert_thm, propers)) =
   824       let
   825         val vs = (fst o fst) (get_head thy cert_thm);
   826         val equations = if null propers then [] else
   827           Thm.prop_of cert_thm
   828           |> Logic.dest_conjunction_balanced (length propers);
   829       in (vs, fold (add_rhss_of_eqn thy) equations []) end
   830   | typargs_deps_of_cert thy (Projection (t, _)) =
   831       (fst (typscheme_projection thy t), add_rhss_of_eqn thy t [])
   832   | typargs_deps_of_cert thy (Abstract (abs_thm, tyco)) =
   833       let
   834         val vs = fst (typscheme_abs thy abs_thm);
   835         val (_, concrete_thm) = concretify_abs thy tyco abs_thm;
   836       in (vs, add_rhss_of_eqn thy (map_types Logic.unvarifyT_global (Thm.prop_of concrete_thm)) []) end;
   837 
   838 fun equations_of_cert thy (cert as Equations (cert_thm, propers)) =
   839       let
   840         val tyscm = typscheme_of_cert thy cert;
   841         val thms = if null propers then [] else
   842           cert_thm
   843           |> Local_Defs.expand [snd (get_head thy cert_thm)]
   844           |> Thm.varifyT_global
   845           |> Conjunction.elim_balanced (length propers);
   846         fun abstractions (args, rhs) = (map (rpair NONE) args, (rhs, NONE));
   847       in (tyscm, map (abstractions o dest_eqn thy o Thm.prop_of) thms ~~ (map SOME thms ~~ propers)) end
   848   | equations_of_cert thy (Projection (t, tyco)) =
   849       let
   850         val (_, ((abs, _), _)) = get_abstype_spec thy tyco;
   851         val tyscm = typscheme_projection thy t;
   852         val t' = map_types Logic.varifyT_global t;
   853         fun abstractions (args, rhs) = (map (rpair (SOME abs)) args, (rhs, NONE));
   854       in (tyscm, [((abstractions o dest_eqn thy) t', (NONE, true))]) end
   855   | equations_of_cert thy (Abstract (abs_thm, tyco)) =
   856       let
   857         val tyscm = typscheme_abs thy abs_thm;
   858         val (abs, concrete_thm) = concretify_abs thy tyco abs_thm;
   859         fun abstractions (args, rhs) = (map (rpair NONE) args, (rhs, (SOME abs)));
   860       in
   861         (tyscm, [((abstractions o dest_eqn thy o Thm.prop_of) concrete_thm,
   862           (SOME (Thm.varifyT_global abs_thm), true))])
   863       end;
   864 
   865 fun pretty_cert thy (cert as Equations _) =
   866       (map_filter (Option.map (Display.pretty_thm_global thy o AxClass.overload thy) o fst o snd)
   867          o snd o equations_of_cert thy) cert
   868   | pretty_cert thy (Projection (t, _)) =
   869       [Syntax.pretty_term_global thy (map_types Logic.varifyT_global t)]
   870   | pretty_cert thy (Abstract (abs_thm, _)) =
   871       [(Display.pretty_thm_global thy o AxClass.overload thy o Thm.varifyT_global) abs_thm];
   872 
   873 fun bare_thms_of_cert thy (cert as Equations _) =
   874       (map_filter (fn (_, (some_thm, proper)) => if proper then some_thm else NONE)
   875         o snd o equations_of_cert thy) cert
   876   | bare_thms_of_cert thy (Projection _) = []
   877   | bare_thms_of_cert thy (Abstract (abs_thm, tyco)) =
   878       [Thm.varifyT_global (snd (concretify_abs thy tyco abs_thm))];
   879 
   880 end;
   881 
   882 
   883 (* code certificate access *)
   884 
   885 fun retrieve_raw thy c =
   886   Symtab.lookup ((the_functions o the_exec) thy) c
   887   |> Option.map (snd o fst)
   888   |> the_default empty_fun_spec
   889 
   890 fun get_cert thy f c = case retrieve_raw thy c
   891  of Default (_, eqns_lazy) => Lazy.force eqns_lazy
   892       |> (map o apfst) (Thm.transfer thy)
   893       |> f
   894       |> (map o apfst) (AxClass.unoverload thy)
   895       |> cert_of_eqns thy c
   896   | Eqns eqns => eqns
   897       |> (map o apfst) (Thm.transfer thy)
   898       |> f
   899       |> (map o apfst) (AxClass.unoverload thy)
   900       |> cert_of_eqns thy c
   901   | Proj (_, tyco) =>
   902       cert_of_proj thy c tyco
   903   | Abstr (abs_thm, tyco) => abs_thm
   904       |> Thm.transfer thy
   905       |> AxClass.unoverload thy
   906       |> cert_of_abs thy tyco c;
   907 
   908 
   909 (* cases *)
   910 
   911 fun case_certificate thm =
   912   let
   913     val ((head, raw_case_expr), cases) = (apfst Logic.dest_equals
   914       o apsnd Logic.dest_conjunctions o Logic.dest_implies o Thm.plain_prop_of) thm;
   915     val _ = case head of Free _ => true
   916       | Var _ => true
   917       | _ => raise TERM ("case_cert", []);
   918     val ([(case_var, _)], case_expr) = Term.strip_abs_eta 1 raw_case_expr;
   919     val (Const (case_const, _), raw_params) = strip_comb case_expr;
   920     val n = find_index (fn Free (v, _) => v = case_var | _ => false) raw_params;
   921     val _ = if n = ~1 then raise TERM ("case_cert", []) else ();
   922     val params = map (fst o dest_Var) (nth_drop n raw_params);
   923     fun dest_case t =
   924       let
   925         val (head' $ t_co, rhs) = Logic.dest_equals t;
   926         val _ = if head' = head then () else raise TERM ("case_cert", []);
   927         val (Const (co, _), args) = strip_comb t_co;
   928         val (Var (param, _), args') = strip_comb rhs;
   929         val _ = if args' = args then () else raise TERM ("case_cert", []);
   930       in (param, co) end;
   931     fun analyze_cases cases =
   932       let
   933         val co_list = fold (AList.update (op =) o dest_case) cases [];
   934       in map (the o AList.lookup (op =) co_list) params end;
   935     fun analyze_let t =
   936       let
   937         val (head' $ arg, Var (param', _) $ arg') = Logic.dest_equals t;
   938         val _ = if head' = head then () else raise TERM ("case_cert", []);
   939         val _ = if arg' = arg then () else raise TERM ("case_cert", []);
   940         val _ = if [param'] = params then () else raise TERM ("case_cert", []);
   941       in [] end;
   942     fun analyze (cases as [let_case]) =
   943           (analyze_cases cases handle Bind => analyze_let let_case)
   944       | analyze cases = analyze_cases cases;
   945   in (case_const, (n, analyze cases)) end;
   946 
   947 fun case_cert thm = case_certificate thm
   948   handle Bind => error "bad case certificate"
   949        | TERM _ => error "bad case certificate";
   950 
   951 fun get_case_scheme thy = Option.map fst o Symtab.lookup ((fst o the_cases o the_exec) thy);
   952 fun get_case_cong thy = Option.map snd o Symtab.lookup ((fst o the_cases o the_exec) thy);
   953 
   954 val undefineds = Symtab.keys o snd o the_cases o the_exec;
   955 
   956 
   957 (* diagnostic *)
   958 
   959 fun print_codesetup thy =
   960   let
   961     val ctxt = ProofContext.init_global thy;
   962     val exec = the_exec thy;
   963     fun pretty_equations const thms =
   964       (Pretty.block o Pretty.fbreaks) (
   965         Pretty.str (string_of_const thy const) :: map (Display.pretty_thm ctxt) thms
   966       );
   967     fun pretty_function (const, Default (_, eqns_lazy)) = pretty_equations const (map fst (Lazy.force eqns_lazy))
   968       | pretty_function (const, Eqns eqns) = pretty_equations const (map fst eqns)
   969       | pretty_function (const, Proj (proj, _)) = Pretty.block
   970           [Pretty.str (string_of_const thy const), Pretty.fbrk, Syntax.pretty_term ctxt proj]
   971       | pretty_function (const, Abstr (thm, _)) = pretty_equations const [thm];
   972     fun pretty_typ (tyco, vs) = Pretty.str
   973       (string_of_typ thy (Type (tyco, map TFree vs)));
   974     fun pretty_typspec (typ, (cos, abstract)) = if null cos
   975       then pretty_typ typ
   976       else (Pretty.block o Pretty.breaks) (
   977         pretty_typ typ
   978         :: Pretty.str "="
   979         :: (if abstract then [Pretty.str "(abstract)"] else [])
   980         @ separate (Pretty.str "|") (map (fn (c, (_, [])) => Pretty.str (string_of_const thy c)
   981              | (c, (_, tys)) =>
   982                  (Pretty.block o Pretty.breaks)
   983                     (Pretty.str (string_of_const thy c)
   984                       :: Pretty.str "of"
   985                       :: map (Pretty.quote o Syntax.pretty_typ_global thy) tys)) cos)
   986       );
   987     fun pretty_case (const, ((_, (_, [])), _)) = Pretty.str (string_of_const thy const)
   988       | pretty_case (const, ((_, (_, cos)), _)) = (Pretty.block o Pretty.breaks) [
   989           Pretty.str (string_of_const thy const), Pretty.str "with",
   990           (Pretty.block o Pretty.commas o map (Pretty.str o string_of_const thy)) cos];
   991     val functions = the_functions exec
   992       |> Symtab.dest
   993       |> (map o apsnd) (snd o fst)
   994       |> sort (string_ord o pairself fst);
   995     val datatypes = the_types exec
   996       |> Symtab.dest
   997       |> map (fn (tyco, (_, (vs, spec)) :: _) =>
   998           ((tyco, vs), constructors_of spec))
   999       |> sort (string_ord o pairself (fst o fst));
  1000     val cases = Symtab.dest ((fst o the_cases o the_exec) thy);
  1001     val undefineds = Symtab.keys ((snd o the_cases o the_exec) thy);
  1002   in
  1003     (Pretty.writeln o Pretty.chunks) [
  1004       Pretty.block (
  1005         Pretty.str "code equations:" :: Pretty.fbrk
  1006         :: (Pretty.fbreaks o map pretty_function) functions
  1007       ),
  1008       Pretty.block (
  1009         Pretty.str "datatypes:" :: Pretty.fbrk
  1010         :: (Pretty.fbreaks o map pretty_typspec) datatypes
  1011       ),
  1012       Pretty.block (
  1013         Pretty.str "cases:" :: Pretty.fbrk
  1014         :: (Pretty.fbreaks o map pretty_case) cases
  1015       ),
  1016       Pretty.block (
  1017         Pretty.str "undefined:" :: Pretty.fbrk
  1018         :: (Pretty.commas o map (Pretty.str o string_of_const thy)) undefineds
  1019       )
  1020     ]
  1021   end;
  1022 
  1023 
  1024 (** declaring executable ingredients **)
  1025 
  1026 (* constant signatures *)
  1027 
  1028 fun add_type tyco thy =
  1029   case Symtab.lookup ((snd o #types o Type.rep_tsig o Sign.tsig_of) thy) tyco
  1030    of SOME (Type.Abbreviation (vs, _, _)) =>
  1031           (map_exec_purge o map_signatures o apfst)
  1032             (Symtab.update (tyco, length vs)) thy
  1033     | _ => error ("No such type abbreviation: " ^ quote tyco);
  1034 
  1035 fun add_type_cmd s thy = add_type (Sign.intern_type thy s) thy;
  1036 
  1037 fun gen_add_signature prep_const prep_signature (raw_c, raw_ty) thy =
  1038   let
  1039     val c = prep_const thy raw_c;
  1040     val ty = prep_signature thy raw_ty;
  1041     val ty' = expand_signature thy ty;
  1042     val ty'' = Sign.the_const_type thy c;
  1043     val _ = if typ_equiv (ty', ty'') then () else
  1044       error ("Illegal constant signature: " ^ Syntax.string_of_typ_global thy ty);
  1045   in
  1046     thy
  1047     |> (map_exec_purge o map_signatures o apsnd) (Symtab.update (c, ty))
  1048   end;
  1049 
  1050 val add_signature = gen_add_signature (K I) cert_signature;
  1051 val add_signature_cmd = gen_add_signature read_const read_signature;
  1052 
  1053 
  1054 (* code equations *)
  1055 
  1056 fun gen_add_eqn default (raw_thm, proper) thy =
  1057   let
  1058     val thm = Thm.close_derivation raw_thm;
  1059     val c = const_eqn thy thm;
  1060     fun update_subsume thy (thm, proper) eqns = 
  1061       let
  1062         val args_of = snd o chop_while is_Var o rev o snd o strip_comb
  1063           o map_types Type.strip_sorts o fst o Logic.dest_equals o Thm.plain_prop_of;
  1064         val args = args_of thm;
  1065         val incr_idx = Logic.incr_indexes ([], Thm.maxidx_of thm + 1);
  1066         fun matches_args args' =
  1067           let
  1068             val k = length args' - length args
  1069           in if k >= 0
  1070             then Pattern.matchess thy (args, (map incr_idx o drop k) args')
  1071             else false
  1072           end;
  1073         fun drop (thm', proper') = if (proper orelse not proper')
  1074           andalso matches_args (args_of thm') then 
  1075             (warning ("Code generator: dropping subsumed code equation\n" ^
  1076                 Display.string_of_thm_global thy thm'); true)
  1077           else false;
  1078       in (thm, proper) :: filter_out drop eqns end;
  1079     fun natural_order thy_ref eqns =
  1080       (eqns, Lazy.lazy (fn () => fold (update_subsume (Theory.deref thy_ref)) eqns []))
  1081     fun add_eqn' true (Default (eqns, _)) =
  1082           Default (natural_order (Theory.check_thy thy) ((thm, proper) :: eqns))
  1083           (*this restores the natural order and drops syntactic redundancies*)
  1084       | add_eqn' true fun_spec = fun_spec
  1085       | add_eqn' false (Eqns eqns) = Eqns (update_subsume thy (thm, proper) eqns)
  1086       | add_eqn' false _ = Eqns [(thm, proper)];
  1087   in change_fun_spec false c (add_eqn' default) thy end;
  1088 
  1089 fun add_eqn thm thy =
  1090   gen_add_eqn false (mk_eqn thy (thm, true)) thy;
  1091 
  1092 fun add_warning_eqn thm thy =
  1093   case mk_eqn_warning thy thm
  1094    of SOME eqn => gen_add_eqn false eqn thy
  1095     | NONE => thy;
  1096 
  1097 fun add_nbe_eqn thm thy =
  1098   gen_add_eqn false (mk_eqn thy (thm, false)) thy;
  1099 
  1100 fun add_default_eqn thm thy =
  1101   case mk_eqn_liberal thy thm
  1102    of SOME eqn => gen_add_eqn true eqn thy
  1103     | NONE => thy;
  1104 
  1105 val add_default_eqn_attribute = Thm.declaration_attribute
  1106   (fn thm => Context.mapping (add_default_eqn thm) I);
  1107 val add_default_eqn_attrib = Attrib.internal (K add_default_eqn_attribute);
  1108 
  1109 fun add_nbe_default_eqn thm thy =
  1110   gen_add_eqn true (mk_eqn thy (thm, false)) thy;
  1111 
  1112 val add_nbe_default_eqn_attribute = Thm.declaration_attribute
  1113   (fn thm => Context.mapping (add_nbe_default_eqn thm) I);
  1114 val add_nbe_default_eqn_attrib = Attrib.internal (K add_nbe_default_eqn_attribute);
  1115 
  1116 fun add_abs_eqn raw_thm thy =
  1117   let
  1118     val (abs_thm, tyco) = (apfst Thm.close_derivation o mk_abs_eqn thy) raw_thm;
  1119     val c = const_abs_eqn thy abs_thm;
  1120   in change_fun_spec false c (K (Abstr (abs_thm, tyco))) thy end;
  1121 
  1122 fun del_eqn thm thy = case mk_eqn_liberal thy thm
  1123  of SOME (thm, _) => let
  1124         fun del_eqn' (Default _) = empty_fun_spec
  1125           | del_eqn' (Eqns eqns) =
  1126               Eqns (filter_out (fn (thm', _) => Thm.eq_thm_prop (thm, thm')) eqns)
  1127           | del_eqn' spec = spec
  1128       in change_fun_spec true (const_eqn thy thm) del_eqn' thy end
  1129   | NONE => thy;
  1130 
  1131 fun del_eqns c = change_fun_spec true c (K empty_fun_spec);
  1132 
  1133 
  1134 (* cases *)
  1135 
  1136 fun case_cong thy case_const (num_args, (pos, _)) =
  1137   let
  1138     val ([x, y], ctxt) = Name.variants ["A", "A'"] Name.context;
  1139     val (zs, _) = Name.variants (replicate (num_args - 1) "") ctxt;
  1140     val (ws, vs) = chop pos zs;
  1141     val T = Logic.unvarifyT_global (Sign.the_const_type thy case_const);
  1142     val Ts = (fst o strip_type) T;
  1143     val T_cong = nth Ts pos;
  1144     fun mk_prem z = Free (z, T_cong);
  1145     fun mk_concl z = list_comb (Const (case_const, T), map2 (curry Free) (ws @ z :: vs) Ts);
  1146     val (prem, concl) = pairself Logic.mk_equals (pairself mk_prem (x, y), pairself mk_concl (x, y));
  1147     fun tac { context, prems } = Simplifier.rewrite_goals_tac prems
  1148       THEN ALLGOALS (ProofContext.fact_tac [Drule.reflexive_thm]);
  1149   in Skip_Proof.prove_global thy (x :: y :: zs) [prem] concl tac end;
  1150 
  1151 fun add_case thm thy =
  1152   let
  1153     val (case_const, (k, case_pats)) = case_cert thm;
  1154     val _ = case filter_out (is_constr thy) case_pats
  1155      of [] => ()
  1156       | cs => error ("Non-constructor(s) in case certificate: " ^ commas (map quote cs));
  1157     val entry = (1 + Int.max (1, length case_pats), (k, case_pats));
  1158   in
  1159     thy
  1160     |> Theory.checkpoint
  1161     |> `(fn thy => case_cong thy case_const entry)
  1162     |-> (fn cong => (map_exec_purge o map_cases o apfst) (Symtab.update (case_const, (entry, cong))))
  1163   end;
  1164 
  1165 fun add_undefined c thy =
  1166   (map_exec_purge o map_cases o apsnd) (Symtab.update (c, ())) thy;
  1167 
  1168 
  1169 (* types *)
  1170 
  1171 fun register_type (tyco, vs_spec) thy =
  1172   let
  1173     val (old_constrs, some_old_proj) =
  1174       case these (Symtab.lookup ((the_types o the_exec) thy) tyco)
  1175        of (_, (_, Constructors cos)) :: _ => (map fst cos, NONE)
  1176         | (_, (_, Abstractor ((co, _), (proj, _)))) :: _ => ([co], SOME proj)
  1177         | [] => ([], NONE)
  1178     val outdated_funs = case some_old_proj
  1179      of NONE => old_constrs
  1180       | SOME old_proj => Symtab.fold
  1181           (fn (c, ((_, spec), _)) =>
  1182             if member (op =) (the_list (associated_abstype spec)) tyco
  1183             then insert (op =) c else I)
  1184             ((the_functions o the_exec) thy) (old_proj :: old_constrs);
  1185     fun drop_outdated_cases cases = fold Symtab.delete_safe
  1186       (Symtab.fold (fn (c, ((_, (_, cos)), _)) =>
  1187         if exists (member (op =) old_constrs) cos
  1188           then insert (op =) c else I) cases []) cases;
  1189   in
  1190     thy
  1191     |> fold del_eqns outdated_funs
  1192     |> map_exec_purge
  1193         ((map_typs o Symtab.map_default (tyco, [])) (cons (serial (), vs_spec))
  1194         #> (map_cases o apfst) drop_outdated_cases)
  1195   end;
  1196 
  1197 fun unoverload_const_typ thy (c, ty) = (AxClass.unoverload_const thy (c, ty), ty);
  1198 
  1199 structure Datatype_Interpretation =
  1200   Interpretation(type T = string * serial val eq = eq_snd (op =) : T * T -> bool);
  1201 
  1202 fun datatype_interpretation f = Datatype_Interpretation.interpretation
  1203   (fn (tyco, _) => fn thy => f (tyco, fst (get_type thy tyco)) thy);
  1204 
  1205 fun add_datatype proto_constrs thy =
  1206   let
  1207     val constrs = map (unoverload_const_typ thy) proto_constrs;
  1208     val (tyco, (vs, cos)) = constrset_of_consts thy constrs;
  1209   in
  1210     thy
  1211     |> fold (del_eqns o fst) constrs
  1212     |> register_type (tyco, (vs, Constructors cos))
  1213     |> Datatype_Interpretation.data (tyco, serial ())
  1214   end;
  1215 
  1216 fun add_datatype_cmd raw_constrs thy =
  1217   add_datatype (map (read_bare_const thy) raw_constrs) thy;
  1218 
  1219 structure Abstype_Interpretation =
  1220   Interpretation(type T = string * serial val eq = eq_snd (op =) : T * T -> bool);
  1221 
  1222 fun abstype_interpretation f = Abstype_Interpretation.interpretation
  1223   (fn (tyco, _) => fn thy => f (tyco, get_abstype_spec thy tyco) thy);
  1224 
  1225 fun add_abstype proto_thm thy =
  1226   let
  1227     val (tyco, (vs, (abs_ty as (abs, (_, ty)), (rep, cert)))) =
  1228       error_thm (check_abstype_cert thy) proto_thm;
  1229   in
  1230     thy
  1231     |> del_eqns abs
  1232     |> register_type (tyco, (vs, Abstractor (abs_ty, (rep, cert))))
  1233     |> change_fun_spec false rep ((K o Proj)
  1234         (map_types Logic.varifyT_global (mk_proj tyco vs ty abs rep), tyco))
  1235     |> Abstype_Interpretation.data (tyco, serial ())
  1236   end;
  1237 
  1238 
  1239 (** infrastructure **)
  1240 
  1241 (* c.f. src/HOL/Tools/recfun_codegen.ML *)
  1242 
  1243 structure Code_Target_Attr = Theory_Data
  1244 (
  1245   type T = (string -> thm -> theory -> theory) option;
  1246   val empty = NONE;
  1247   val extend = I;
  1248   fun merge (f1, f2) = if is_some f1 then f1 else f2;
  1249 );
  1250 
  1251 fun set_code_target_attr f = Code_Target_Attr.map (K (SOME f));
  1252 
  1253 fun code_target_attr prefix thm thy =
  1254   let
  1255     val attr = the_default ((K o K) I) (Code_Target_Attr.get thy);
  1256   in thy |> add_warning_eqn thm |> attr prefix thm end;
  1257 
  1258 
  1259 (* setup *)
  1260 
  1261 val _ = Context.>> (Context.map_theory
  1262   (let
  1263     fun mk_attribute f = Thm.declaration_attribute (fn thm => Context.mapping (f thm) I);
  1264     val code_attribute_parser =
  1265       Args.del |-- Scan.succeed (mk_attribute del_eqn)
  1266       || Args.$$$ "nbe" |-- Scan.succeed (mk_attribute add_nbe_eqn)
  1267       || Args.$$$ "abstype" |-- Scan.succeed (mk_attribute add_abstype)
  1268       || Args.$$$ "abstract" |-- Scan.succeed (mk_attribute add_abs_eqn)
  1269       || (Args.$$$ "target" |-- Args.colon |-- Args.name >>
  1270            (mk_attribute o code_target_attr))
  1271       || Scan.succeed (mk_attribute add_warning_eqn);
  1272   in
  1273     Datatype_Interpretation.init
  1274     #> Attrib.setup (Binding.name "code") (Scan.lift code_attribute_parser)
  1275         "declare theorems for code generation"
  1276   end));
  1277 
  1278 end; (*struct*)
  1279 
  1280 
  1281 (* type-safe interfaces for data dependent on executable code *)
  1282 
  1283 functor Code_Data(Data: CODE_DATA_ARGS): CODE_DATA =
  1284 struct
  1285 
  1286 type T = Data.T;
  1287 exception Data of T;
  1288 fun dest (Data x) = x
  1289 
  1290 val kind = Code.declare_data (Data Data.empty);
  1291 
  1292 val data_op = (kind, Data, dest);
  1293 
  1294 fun change_yield (SOME thy) f = Code.change_yield_data data_op thy f
  1295   | change_yield NONE f = f Data.empty
  1296 
  1297 fun change some_thy f = snd (change_yield some_thy (pair () o f));
  1298 
  1299 end;
  1300 
  1301 structure Code : CODE = struct open Code; end;