src/Pure/Isar/generic_target.ML
author haftmann
Mon Nov 29 11:38:59 2010 +0100 (2010-11-29 ago)
changeset 40803 3f66ea311d44
parent 40782 aa533c5e3f48
child 41228 e1fce873b814
permissions -rw-r--r--
tuned
     1 (*  Title:      Pure/Isar/theory_target.ML
     2     Author:     Makarius
     3     Author:     Florian Haftmann, TU Muenchen
     4 
     5 Common target infrastructure.
     6 *)
     7 
     8 signature GENERIC_TARGET =
     9 sig
    10   val define: (((binding * typ) * mixfix) * (binding * term) ->
    11       term list * term list -> local_theory -> (term * thm) * local_theory) ->
    12     (binding * mixfix) * (Attrib.binding * term) -> local_theory ->
    13     (term * (string * thm)) * local_theory
    14   val notes: (string -> (Attrib.binding * (thm list * Args.src list) list) list ->
    15       (Attrib.binding * (thm list * Args.src list) list) list -> local_theory -> local_theory) ->
    16     string -> (Attrib.binding * (thm list * Args.src list) list) list -> local_theory ->
    17     (string * thm list) list * local_theory
    18   val abbrev: (string * bool -> binding * mixfix -> term * term ->
    19       term list -> local_theory -> local_theory) ->
    20     string * bool -> (binding * mixfix) * term -> local_theory ->
    21     (term * term) * local_theory
    22 
    23   val theory_declaration: declaration -> local_theory -> local_theory
    24   val theory_foundation: ((binding * typ) * mixfix) * (binding * term) ->
    25     term list * term list -> local_theory -> (term * thm) * local_theory
    26   val theory_notes: string -> (Attrib.binding * (thm list * Args.src list) list) list ->
    27     local_theory -> local_theory
    28   val theory_abbrev: Syntax.mode -> (binding * mixfix) * term -> local_theory -> local_theory
    29 end;
    30 
    31 structure Generic_Target: GENERIC_TARGET =
    32 struct
    33 
    34 (** lifting primitive to target operations **)
    35 
    36 (* mixfix syntax *)
    37 
    38 fun check_mixfix ctxt (b, extra_tfrees) mx =
    39   if null extra_tfrees then mx
    40   else
    41     (Context_Position.if_visible ctxt warning
    42       ("Additional type variable(s) in specification of " ^ Binding.str_of b ^ ": " ^
    43         commas (map (Syntax.string_of_typ ctxt o TFree) (sort_wrt #1 extra_tfrees)) ^
    44         (if mx = NoSyn then ""
    45          else "\nDropping mixfix syntax " ^ Pretty.string_of (Syntax.pretty_mixfix mx)));
    46       NoSyn);
    47 
    48 
    49 (* define *)
    50 
    51 fun define foundation ((b, mx), ((proto_b_def, atts), rhs)) lthy =
    52   let
    53     val thy = ProofContext.theory_of lthy;
    54     val thy_ctxt = ProofContext.init_global thy;
    55 
    56     val b_def = Thm.def_binding_optional b proto_b_def;
    57 
    58     (*term and type parameters*)
    59     val crhs = Thm.cterm_of thy rhs;
    60     val (defs, rhs') = Local_Defs.export_cterm lthy thy_ctxt crhs ||> Thm.term_of;
    61     val rhs_conv = MetaSimplifier.rewrite true defs crhs;
    62 
    63     val xs = Variable.add_fixed (Local_Theory.target_of lthy) rhs' [];
    64     val T = Term.fastype_of rhs;
    65     val tfreesT = Term.add_tfreesT T (fold (Term.add_tfreesT o #2) xs []);
    66     val extra_tfrees = rev (subtract (op =) tfreesT (Term.add_tfrees rhs []));
    67     val mx' = check_mixfix lthy (b, extra_tfrees) mx;
    68 
    69     val type_params = map (Logic.mk_type o TFree) extra_tfrees;
    70     val term_params =
    71       rev (Variable.fixes_of (Local_Theory.target_of lthy))
    72       |> map_filter (fn (_, x) =>
    73         (case AList.lookup (op =) xs x of
    74           SOME T => SOME (Free (x, T))
    75         | NONE => NONE));
    76     val params = type_params @ term_params;
    77 
    78     val U = map Term.fastype_of params ---> T;
    79 
    80     (*foundation*)
    81     val ((lhs', global_def), lthy2) = foundation
    82       (((b, U), mx'), (b_def, rhs')) (type_params, term_params) lthy;
    83 
    84     (*local definition*)
    85     val ((lhs, local_def), lthy3) = lthy2
    86       |> Local_Defs.add_def ((b, NoSyn), lhs');
    87     val def = Local_Defs.trans_terms lthy3
    88       [(*c == global.c xs*)     local_def,
    89        (*global.c xs == rhs'*)  global_def,
    90        (*rhs' == rhs*)          Thm.symmetric rhs_conv];
    91 
    92     (*note*)
    93     val ([(res_name, [res])], lthy4) = lthy3
    94       |> Local_Theory.notes_kind "" [((b_def, atts), [([def], [])])];
    95   in ((lhs, (res_name, res)), lthy4) end;
    96 
    97 
    98 (* notes *)
    99 
   100 fun import_export_proof ctxt (name, raw_th) =
   101   let
   102     val thy = ProofContext.theory_of ctxt;
   103     val thy_ctxt = ProofContext.init_global thy;
   104     val certT = Thm.ctyp_of thy;
   105     val cert = Thm.cterm_of thy;
   106 
   107     (*export assumes/defines*)
   108     val th = Goal.norm_result raw_th;
   109     val (defs, th') = Local_Defs.export ctxt thy_ctxt th;
   110     val assms = map (MetaSimplifier.rewrite_rule defs o Thm.assume)
   111       (Assumption.all_assms_of ctxt);
   112     val nprems = Thm.nprems_of th' - Thm.nprems_of th;
   113 
   114     (*export fixes*)
   115     val tfrees = map TFree (Thm.fold_terms Term.add_tfrees th' []);
   116     val frees = map Free (Thm.fold_terms Term.add_frees th' []);
   117     val (th'' :: vs) = (th' :: map (Drule.mk_term o cert) (map Logic.mk_type tfrees @ frees))
   118       |> Variable.export ctxt thy_ctxt
   119       |> Drule.zero_var_indexes_list;
   120 
   121     (*thm definition*)
   122     val result = Global_Theory.name_thm true true name th'';
   123 
   124     (*import fixes*)
   125     val (tvars, vars) =
   126       chop (length tfrees) (map (Thm.term_of o Drule.dest_term) vs)
   127       |>> map Logic.dest_type;
   128 
   129     val instT = map_filter (fn (TVar v, T) => SOME (v, T) | _ => NONE) (tvars ~~ tfrees);
   130     val inst = filter (is_Var o fst) (vars ~~ frees);
   131     val cinstT = map (pairself certT o apfst TVar) instT;
   132     val cinst = map (pairself (cert o Term.map_types (Term_Subst.instantiateT instT))) inst;
   133     val result' = Thm.instantiate (cinstT, cinst) result;
   134 
   135     (*import assumes/defines*)
   136     val assm_tac = FIRST' (map (fn assm => Tactic.compose_tac (false, assm, 0)) assms);
   137     val result'' =
   138       (case SINGLE (Seq.INTERVAL assm_tac 1 nprems) result' of
   139         NONE => raise THM ("Failed to re-import result", 0, [result'])
   140       | SOME res => Local_Defs.contract ctxt defs (Thm.cprop_of th) res)
   141       |> Goal.norm_result
   142       |> Global_Theory.name_thm false false name;
   143 
   144   in (result'', result) end;
   145 
   146 fun notes target_notes kind facts lthy =
   147   let
   148     val thy = ProofContext.theory_of lthy;
   149     val facts' = facts
   150       |> map (fn (a, bs) => (a, Global_Theory.burrow_fact (Global_Theory.name_multi
   151           (Local_Theory.full_name lthy (fst a))) bs))
   152       |> Global_Theory.map_facts (import_export_proof lthy);
   153     val local_facts = Global_Theory.map_facts #1 facts';
   154     val global_facts = Global_Theory.map_facts #2 facts';
   155   in
   156     lthy
   157     |> target_notes kind global_facts local_facts
   158     |> ProofContext.note_thmss kind (Attrib.map_facts (Attrib.attribute_i thy) local_facts)
   159   end;
   160 
   161 
   162 (* abbrev *)
   163 
   164 fun abbrev target_abbrev prmode ((b, mx), t) lthy =
   165   let
   166     val thy_ctxt = ProofContext.init_global (ProofContext.theory_of lthy);
   167     val target_ctxt = Local_Theory.target_of lthy;
   168 
   169     val t' = Assumption.export_term lthy target_ctxt t;
   170     val xs = map Free (rev (Variable.add_fixed target_ctxt t' []));
   171     val u = fold_rev lambda xs t';
   172 
   173     val extra_tfrees =
   174       subtract (op =) (Term.add_tfreesT (Term.fastype_of u) []) (Term.add_tfrees u []);
   175     val mx' = check_mixfix lthy (b, extra_tfrees) mx;
   176 
   177     val global_rhs =
   178       singleton (Variable.export_terms (Variable.declare_term u target_ctxt) thy_ctxt) u;
   179   in
   180     lthy
   181     |> target_abbrev prmode (b, mx') (global_rhs, t') xs
   182     |> ProofContext.add_abbrev Print_Mode.internal (b, t) |> snd
   183     |> Local_Defs.fixed_abbrev ((b, NoSyn), t)
   184   end;
   185 
   186 
   187 (** primitive theory operations **)
   188 
   189 fun theory_declaration decl lthy =
   190   let
   191     val global_decl = Morphism.form
   192       (Morphism.transform (Local_Theory.global_morphism lthy) decl);
   193   in
   194     lthy
   195     |> Local_Theory.background_theory (Context.theory_map global_decl)
   196     |> Local_Theory.target (Context.proof_map global_decl)
   197   end;
   198 
   199 fun theory_foundation (((b, U), mx), (b_def, rhs)) (type_params, term_params) lthy =
   200   let
   201     val (const, lthy2) = lthy |> Local_Theory.background_theory_result
   202       (Sign.declare_const ((b, U), mx));
   203     val lhs = list_comb (const, type_params @ term_params);
   204     val ((_, def), lthy3) = lthy2 |> Local_Theory.background_theory_result
   205       (Thm.add_def false false (b_def, Logic.mk_equals (lhs, rhs)));
   206   in ((lhs, def), lthy3) end;
   207 
   208 fun theory_notes kind global_facts lthy =
   209   let
   210     val thy = ProofContext.theory_of lthy;
   211     val global_facts' = Attrib.map_facts (Attrib.attribute_i thy) global_facts;
   212   in
   213     lthy
   214     |> Local_Theory.background_theory (Global_Theory.note_thmss kind global_facts' #> snd)
   215     |> Local_Theory.target (ProofContext.note_thmss kind global_facts' #> snd)
   216   end;
   217 
   218 fun theory_abbrev prmode ((b, mx), t) =
   219   Local_Theory.background_theory
   220     (Sign.add_abbrev (#1 prmode) (b, t) #->
   221       (fn (lhs, _) => Sign.notation true prmode [(lhs, mx)]));
   222 
   223 end;