src/Pure/Isar/proof.ML
author haftmann
Mon Nov 29 11:38:59 2010 +0100 (2010-11-29 ago)
changeset 40803 3f66ea311d44
parent 40642 99c6ce92669b
child 40960 9e54eb514a46
permissions -rw-r--r--
tuned
     1 (*  Title:      Pure/Isar/proof.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 The Isar/VM proof language interpreter: maintains a structured flow of
     5 context elements, goals, refinements, and facts.
     6 *)
     7 
     8 signature PROOF =
     9 sig
    10   type context = Proof.context
    11   type method = Method.method
    12   type state
    13   val init: context -> state
    14   val level: state -> int
    15   val assert_bottom: bool -> state -> state
    16   val context_of: state -> context
    17   val theory_of: state -> theory
    18   val map_context: (context -> context) -> state -> state
    19   val map_context_result : (context -> 'a * context) -> state -> 'a * state
    20   val map_contexts: (context -> context) -> state -> state
    21   val propagate_ml_env: state -> state
    22   val bind_terms: (indexname * term option) list -> state -> state
    23   val put_thms: bool -> string * thm list option -> state -> state
    24   val the_facts: state -> thm list
    25   val the_fact: state -> thm
    26   val put_facts: thm list option -> state -> state
    27   val assert_forward: state -> state
    28   val assert_chain: state -> state
    29   val assert_forward_or_chain: state -> state
    30   val assert_backward: state -> state
    31   val assert_no_chain: state -> state
    32   val enter_forward: state -> state
    33   val goal_message: (unit -> Pretty.T) -> state -> state
    34   val verbose: bool Unsynchronized.ref
    35   val pretty_state: int -> state -> Pretty.T list
    36   val pretty_goals: bool -> state -> Pretty.T list
    37   val refine: Method.text -> state -> state Seq.seq
    38   val refine_end: Method.text -> state -> state Seq.seq
    39   val refine_insert: thm list -> state -> state
    40   val goal_tac: thm -> int -> tactic
    41   val refine_goals: (context -> thm -> unit) -> context -> thm list -> state -> state Seq.seq
    42   val raw_goal: state -> {context: context, facts: thm list, goal: thm}
    43   val goal: state -> {context: context, facts: thm list, goal: thm}
    44   val simple_goal: state -> {context: context, goal: thm}
    45   val status_markup: state -> Markup.T
    46   val let_bind: (term list * term) list -> state -> state
    47   val let_bind_cmd: (string list * string) list -> state -> state
    48   val write: Syntax.mode -> (term * mixfix) list -> state -> state
    49   val write_cmd: Syntax.mode -> (string * mixfix) list -> state -> state
    50   val fix: (binding * typ option * mixfix) list -> state -> state
    51   val fix_cmd: (binding * string option * mixfix) list -> state -> state
    52   val assm: Assumption.export ->
    53     (Thm.binding * (term * term list) list) list -> state -> state
    54   val assm_cmd: Assumption.export ->
    55     (Attrib.binding * (string * string list) list) list -> state -> state
    56   val assume: (Thm.binding * (term * term list) list) list -> state -> state
    57   val assume_cmd: (Attrib.binding * (string * string list) list) list -> state -> state
    58   val presume: (Thm.binding * (term * term list) list) list -> state -> state
    59   val presume_cmd: (Attrib.binding * (string * string list) list) list -> state -> state
    60   val def: (Thm.binding * ((binding * mixfix) * (term * term list))) list -> state -> state
    61   val def_cmd: (Attrib.binding * ((binding * mixfix) * (string * string list))) list -> state -> state
    62   val chain: state -> state
    63   val chain_facts: thm list -> state -> state
    64   val note_thmss: (Thm.binding * (thm list * attribute list) list) list -> state -> state
    65   val note_thmss_cmd: (Attrib.binding * (Facts.ref * Attrib.src list) list) list -> state -> state
    66   val from_thmss: ((thm list * attribute list) list) list -> state -> state
    67   val from_thmss_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    68   val with_thmss: ((thm list * attribute list) list) list -> state -> state
    69   val with_thmss_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    70   val using: ((thm list * attribute list) list) list -> state -> state
    71   val using_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    72   val unfolding: ((thm list * attribute list) list) list -> state -> state
    73   val unfolding_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    74   val invoke_case: string * string option list * attribute list -> state -> state
    75   val invoke_case_cmd: string * string option list * Attrib.src list -> state -> state
    76   val begin_block: state -> state
    77   val next_block: state -> state
    78   val end_block: state -> state
    79   val proof: Method.text option -> state -> state Seq.seq
    80   val defer: int option -> state -> state Seq.seq
    81   val prefer: int -> state -> state Seq.seq
    82   val apply: Method.text -> state -> state Seq.seq
    83   val apply_end: Method.text -> state -> state Seq.seq
    84   val local_goal: (context -> ((string * string) * (string * thm list) list) -> unit) ->
    85     (theory -> 'a -> attribute) ->
    86     (context * 'b list -> context * (term list list * (context -> context))) ->
    87     string -> Method.text option -> (thm list list -> state -> state) ->
    88     ((binding * 'a list) * 'b) list -> state -> state
    89   val local_qed: Method.text option * bool -> state -> state
    90   val theorem: Method.text option -> (thm list list -> context -> context) ->
    91     (term * term list) list list -> context -> state
    92   val theorem_cmd: Method.text option -> (thm list list -> context -> context) ->
    93     (string * string list) list list -> context -> state
    94   val global_qed: Method.text option * bool -> state -> context
    95   val local_terminal_proof: Method.text * Method.text option -> state -> state
    96   val local_default_proof: state -> state
    97   val local_immediate_proof: state -> state
    98   val local_skip_proof: bool -> state -> state
    99   val local_done_proof: state -> state
   100   val global_terminal_proof: Method.text * Method.text option -> state -> context
   101   val global_default_proof: state -> context
   102   val global_immediate_proof: state -> context
   103   val global_skip_proof: bool -> state -> context
   104   val global_done_proof: state -> context
   105   val have: Method.text option -> (thm list list -> state -> state) ->
   106     (Thm.binding * (term * term list) list) list -> bool -> state -> state
   107   val have_cmd: Method.text option -> (thm list list -> state -> state) ->
   108     (Attrib.binding * (string * string list) list) list -> bool -> state -> state
   109   val show: Method.text option -> (thm list list -> state -> state) ->
   110     (Thm.binding * (term * term list) list) list -> bool -> state -> state
   111   val show_cmd: Method.text option -> (thm list list -> state -> state) ->
   112     (Attrib.binding * (string * string list) list) list -> bool -> state -> state
   113   val schematic_goal: state -> bool
   114   val is_relevant: state -> bool
   115   val local_future_proof: (state -> ('a * state) Future.future) ->
   116     state -> 'a Future.future * state
   117   val global_future_proof: (state -> ('a * Proof.context) Future.future) ->
   118     state -> 'a Future.future * context
   119   val local_future_terminal_proof: Method.text * Method.text option -> bool -> state -> state
   120   val global_future_terminal_proof: Method.text * Method.text option -> bool -> state -> context
   121 end;
   122 
   123 structure Proof: PROOF =
   124 struct
   125 
   126 type context = Proof.context;
   127 type method = Method.method;
   128 
   129 
   130 (** proof state **)
   131 
   132 (* datatype state *)
   133 
   134 datatype mode = Forward | Chain | Backward;
   135 
   136 datatype state =
   137   State of node Stack.T
   138 and node =
   139   Node of
   140    {context: context,
   141     facts: thm list option,
   142     mode: mode,
   143     goal: goal option}
   144 and goal =
   145   Goal of
   146    {statement: (string * Position.T) * term list list * term,
   147       (*goal kind and statement (starting with vars), initial proposition*)
   148     messages: (unit -> Pretty.T) list,    (*persistent messages (hints etc.)*)
   149     using: thm list,                      (*goal facts*)
   150     goal: thm,                            (*subgoals ==> statement*)
   151     before_qed: Method.text option,
   152     after_qed:
   153       (thm list list -> state -> state) *
   154       (thm list list -> context -> context)};
   155 
   156 fun make_goal (statement, messages, using, goal, before_qed, after_qed) =
   157   Goal {statement = statement, messages = messages, using = using, goal = goal,
   158     before_qed = before_qed, after_qed = after_qed};
   159 
   160 fun make_node (context, facts, mode, goal) =
   161   Node {context = context, facts = facts, mode = mode, goal = goal};
   162 
   163 fun map_node f (Node {context, facts, mode, goal}) =
   164   make_node (f (context, facts, mode, goal));
   165 
   166 val init_context =
   167   ProofContext.set_stmt true #>
   168   ProofContext.map_naming (K ProofContext.local_naming);
   169 
   170 fun init ctxt =
   171   State (Stack.init (make_node (init_context ctxt, NONE, Forward, NONE)));
   172 
   173 fun current (State st) = Stack.top st |> (fn Node node => node);
   174 fun map_current f (State st) = State (Stack.map_top (map_node f) st);
   175 fun map_all f (State st) = State (Stack.map_all (map_node f) st);
   176 
   177 
   178 
   179 (** basic proof state operations **)
   180 
   181 (* block structure *)
   182 
   183 fun open_block (State st) = State (Stack.push st);
   184 
   185 fun close_block (State st) = State (Stack.pop st)
   186   handle Empty => error "Unbalanced block parentheses";
   187 
   188 fun level (State st) = Stack.level st;
   189 
   190 fun assert_bottom b state =
   191   let val b' = (level state <= 2) in
   192     if b andalso not b' then error "Not at bottom of proof!"
   193     else if not b andalso b' then error "Already at bottom of proof!"
   194     else state
   195   end;
   196 
   197 
   198 (* context *)
   199 
   200 val context_of = #context o current;
   201 val theory_of = ProofContext.theory_of o context_of;
   202 
   203 fun map_context f =
   204   map_current (fn (ctxt, facts, mode, goal) => (f ctxt, facts, mode, goal));
   205 
   206 fun map_context_result f state =
   207   f (context_of state) ||> (fn ctxt => map_context (K ctxt) state);
   208 
   209 fun map_contexts f = map_all (fn (ctxt, facts, mode, goal) => (f ctxt, facts, mode, goal));
   210 
   211 fun propagate_ml_env state = map_contexts
   212   (Context.proof_map (ML_Env.inherit (Context.Proof (context_of state)))) state;
   213 
   214 val bind_terms = map_context o ProofContext.bind_terms;
   215 val put_thms = map_context oo ProofContext.put_thms;
   216 
   217 
   218 (* facts *)
   219 
   220 val get_facts = #facts o current;
   221 
   222 fun the_facts state =
   223   (case get_facts state of SOME facts => facts
   224   | NONE => error "No current facts available");
   225 
   226 fun the_fact state =
   227   (case the_facts state of [thm] => thm
   228   | _ => error "Single theorem expected");
   229 
   230 fun put_facts facts =
   231   map_current (fn (ctxt, _, mode, goal) => (ctxt, facts, mode, goal)) #>
   232   put_thms true (Auto_Bind.thisN, facts);
   233 
   234 fun these_factss more_facts (named_factss, state) =
   235   (named_factss, state |> put_facts (SOME (maps snd named_factss @ more_facts)));
   236 
   237 fun export_facts inner outer =
   238   (case get_facts inner of
   239     NONE => put_facts NONE outer
   240   | SOME thms =>
   241       thms
   242       |> ProofContext.export (context_of inner) (context_of outer)
   243       |> (fn ths => put_facts (SOME ths) outer));
   244 
   245 
   246 (* mode *)
   247 
   248 val get_mode = #mode o current;
   249 fun put_mode mode = map_current (fn (ctxt, facts, _, goal) => (ctxt, facts, mode, goal));
   250 
   251 val mode_name = (fn Forward => "state" | Chain => "chain" | Backward => "prove");
   252 
   253 fun assert_mode pred state =
   254   let val mode = get_mode state in
   255     if pred mode then state
   256     else error ("Illegal application of proof command in " ^ quote (mode_name mode) ^ " mode")
   257   end;
   258 
   259 val assert_forward = assert_mode (fn mode => mode = Forward);
   260 val assert_chain = assert_mode (fn mode => mode = Chain);
   261 val assert_forward_or_chain = assert_mode (fn mode => mode = Forward orelse mode = Chain);
   262 val assert_backward = assert_mode (fn mode => mode = Backward);
   263 val assert_no_chain = assert_mode (fn mode => mode <> Chain);
   264 
   265 val enter_forward = put_mode Forward;
   266 val enter_chain = put_mode Chain;
   267 val enter_backward = put_mode Backward;
   268 
   269 
   270 (* current goal *)
   271 
   272 fun current_goal state =
   273   (case current state of
   274     {context, goal = SOME (Goal goal), ...} => (context, goal)
   275   | _ => error "No current goal!");
   276 
   277 fun assert_current_goal g state =
   278   let val g' = can current_goal state in
   279     if g andalso not g' then error "No goal in this block!"
   280     else if not g andalso g' then error "Goal present in this block!"
   281     else state
   282   end;
   283 
   284 fun put_goal goal = map_current (fn (ctxt, using, mode, _) => (ctxt, using, mode, goal));
   285 
   286 val before_qed = #before_qed o #2 o current_goal;
   287 
   288 
   289 (* nested goal *)
   290 
   291 fun map_goal f g (State (Node {context, facts, mode, goal = SOME goal}, nodes)) =
   292       let
   293         val Goal {statement, messages, using, goal, before_qed, after_qed} = goal;
   294         val goal' = make_goal (g (statement, messages, using, goal, before_qed, after_qed));
   295       in State (make_node (f context, facts, mode, SOME goal'), nodes) end
   296   | map_goal f g (State (nd, node :: nodes)) =
   297       let val State (node', nodes') = map_goal f g (State (node, nodes))
   298       in map_context f (State (nd, node' :: nodes')) end
   299   | map_goal _ _ state = state;
   300 
   301 fun set_goal goal = map_goal I (fn (statement, _, using, _, before_qed, after_qed) =>
   302   (statement, [], using, goal, before_qed, after_qed));
   303 
   304 fun goal_message msg = map_goal I (fn (statement, messages, using, goal, before_qed, after_qed) =>
   305   (statement, msg :: messages, using, goal, before_qed, after_qed));
   306 
   307 fun using_facts using = map_goal I (fn (statement, _, _, goal, before_qed, after_qed) =>
   308   (statement, [], using, goal, before_qed, after_qed));
   309 
   310 local
   311   fun find i state =
   312     (case try current_goal state of
   313       SOME (ctxt, goal) => (ctxt, (i, goal))
   314     | NONE => find (i + 1) (close_block state handle ERROR _ => error "No goal present"));
   315 in val find_goal = find 0 end;
   316 
   317 fun get_goal state =
   318   let val (ctxt, (_, {using, goal, ...})) = find_goal state
   319   in (ctxt, (using, goal)) end;
   320 
   321 
   322 
   323 (** pretty_state **)
   324 
   325 val verbose = ProofContext.verbose;
   326 
   327 fun pretty_facts _ _ NONE = []
   328   | pretty_facts s ctxt (SOME ths) =
   329       [Pretty.big_list (s ^ "this:") (map (Display.pretty_thm ctxt) ths), Pretty.str ""];
   330 
   331 fun pretty_state nr state =
   332   let
   333     val {context = ctxt, facts, mode, goal = _} = current state;
   334 
   335     fun levels_up 0 = ""
   336       | levels_up 1 = "1 level up"
   337       | levels_up i = string_of_int i ^ " levels up";
   338 
   339     fun subgoals 0 = ""
   340       | subgoals 1 = "1 subgoal"
   341       | subgoals n = string_of_int n ^ " subgoals";
   342 
   343     fun description strs =
   344       (case filter_out (fn s => s = "") strs of [] => ""
   345       | strs' => enclose " (" ")" (commas strs'));
   346 
   347     fun prt_goal (SOME (_, (i,
   348       {statement = ((_, pos), _, _), messages, using, goal, before_qed = _, after_qed = _}))) =
   349           pretty_facts "using " ctxt
   350             (if mode <> Backward orelse null using then NONE else SOME using) @
   351           [Pretty.str ("goal" ^
   352             description [levels_up (i div 2), subgoals (Thm.nprems_of goal)] ^ ":")] @
   353           Goal_Display.pretty_goals ctxt goal @
   354           (map (fn msg => Position.setmp_thread_data pos msg ()) (rev messages))
   355       | prt_goal NONE = [];
   356 
   357     val prt_ctxt =
   358       if ! verbose orelse mode = Forward then ProofContext.pretty_context ctxt
   359       else if mode = Backward then ProofContext.pretty_ctxt ctxt
   360       else [];
   361   in
   362     [Pretty.str ("proof (" ^ mode_name mode ^ "): step " ^ string_of_int nr ^
   363       (if ! verbose then ", depth " ^ string_of_int (level state div 2 - 1) else "")),
   364       Pretty.str ""] @
   365     (if null prt_ctxt then [] else prt_ctxt @ [Pretty.str ""]) @
   366     (if ! verbose orelse mode = Forward then
   367        pretty_facts "" ctxt facts @ prt_goal (try find_goal state)
   368      else if mode = Chain then pretty_facts "picking " ctxt facts
   369      else prt_goal (try find_goal state))
   370   end;
   371 
   372 fun pretty_goals main state =
   373   let
   374     val (_, (_, goal)) = get_goal state;
   375     val ctxt = context_of state
   376       |> Config.put Goal_Display.show_main_goal main
   377       |> Config.put Goal_Display.goals_total false;
   378   in Goal_Display.pretty_goals ctxt goal end;
   379 
   380 
   381 
   382 (** proof steps **)
   383 
   384 (* refine via method *)
   385 
   386 local
   387 
   388 fun goalN i = "goal" ^ string_of_int i;
   389 fun goals st = map goalN (1 upto Thm.nprems_of st);
   390 
   391 fun no_goal_cases st = map (rpair NONE) (goals st);
   392 
   393 fun goal_cases st =
   394   Rule_Cases.make_common (Thm.theory_of_thm st, Thm.prop_of st) (map (rpair []) (goals st));
   395 
   396 fun apply_method current_context meth state =
   397   let
   398     val (goal_ctxt, (_, {statement, messages = _, using, goal, before_qed, after_qed})) =
   399       find_goal state;
   400     val ctxt = if current_context then context_of state else goal_ctxt;
   401   in
   402     Method.apply meth ctxt using goal |> Seq.map (fn (meth_cases, goal') =>
   403       state
   404       |> map_goal
   405           (ProofContext.add_cases false (no_goal_cases goal @ goal_cases goal') #>
   406            ProofContext.add_cases true meth_cases)
   407           (K (statement, [], using, goal', before_qed, after_qed)))
   408   end;
   409 
   410 fun select_goals n meth state =
   411   state
   412   |> (#2 o #2 o get_goal)
   413   |> ALLGOALS Goal.conjunction_tac
   414   |> Seq.maps (fn goal =>
   415     state
   416     |> Seq.lift set_goal (Goal.extract 1 n goal |> Seq.maps (Goal.conjunction_tac 1))
   417     |> Seq.maps meth
   418     |> Seq.maps (fn state' => state'
   419       |> Seq.lift set_goal (Goal.retrofit 1 n (#2 (#2 (get_goal state'))) goal))
   420     |> Seq.maps (apply_method true (K Method.succeed)));
   421 
   422 fun apply_text cc text state =
   423   let
   424     val thy = theory_of state;
   425 
   426     fun eval (Method.Basic m) = apply_method cc m
   427       | eval (Method.Source src) = apply_method cc (Method.method thy src)
   428       | eval (Method.Source_i src) = apply_method cc (Method.method_i thy src)
   429       | eval (Method.Then txts) = Seq.EVERY (map eval txts)
   430       | eval (Method.Orelse txts) = Seq.FIRST (map eval txts)
   431       | eval (Method.Try txt) = Seq.TRY (eval txt)
   432       | eval (Method.Repeat1 txt) = Seq.REPEAT1 (eval txt)
   433       | eval (Method.SelectGoals (n, txt)) = select_goals n (eval txt);
   434   in eval text state end;
   435 
   436 in
   437 
   438 val refine = apply_text true;
   439 val refine_end = apply_text false;
   440 fun refine_insert ths = Seq.hd o refine (Method.Basic (K (Method.insert ths)));
   441 
   442 end;
   443 
   444 
   445 (* refine via sub-proof *)
   446 
   447 fun finish_tac 0 = K all_tac
   448   | finish_tac n =
   449       Goal.norm_hhf_tac THEN'
   450       SUBGOAL (fn (goal, i) =>
   451         if can Logic.unprotect (Logic.strip_assums_concl goal) then
   452           Tactic.etac Drule.protectI i THEN finish_tac (n - 1) i
   453         else finish_tac (n - 1) (i + 1));
   454 
   455 fun goal_tac rule =
   456   Goal.norm_hhf_tac THEN'
   457   Tactic.rtac rule THEN'
   458   finish_tac (Thm.nprems_of rule);
   459 
   460 fun refine_goals print_rule inner raw_rules state =
   461   let
   462     val (outer, (_, goal)) = get_goal state;
   463     fun refine rule st = (print_rule outer rule; FINDGOAL (goal_tac rule) st);
   464   in
   465     raw_rules
   466     |> ProofContext.goal_export inner outer
   467     |> (fn rules => Seq.lift set_goal (EVERY (map refine rules) goal) state)
   468   end;
   469 
   470 
   471 (* conclude_goal *)
   472 
   473 fun conclude_goal ctxt goal propss =
   474   let
   475     val thy = ProofContext.theory_of ctxt;
   476     val string_of_term = Syntax.string_of_term ctxt;
   477     val string_of_thm = Display.string_of_thm ctxt;
   478 
   479     val ngoals = Thm.nprems_of goal;
   480     val _ = ngoals = 0 orelse error (Pretty.string_of (Pretty.chunks
   481       (Goal_Display.pretty_goals ctxt goal @
   482         [Pretty.str (string_of_int ngoals ^ " unsolved goal(s)!")])));
   483 
   484     val extra_hyps = Assumption.extra_hyps ctxt goal;
   485     val _ = null extra_hyps orelse
   486       error ("Additional hypotheses:\n" ^ cat_lines (map string_of_term extra_hyps));
   487 
   488     fun lost_structure () = error ("Lost goal structure:\n" ^ string_of_thm goal);
   489 
   490     val th = Goal.conclude
   491       (if length (flat propss) > 1 then Thm.norm_proof goal else goal)
   492       handle THM _ => lost_structure ();
   493     val goal_propss = filter_out null propss;
   494     val results =
   495       Conjunction.elim_balanced (length goal_propss) th
   496       |> map2 Conjunction.elim_balanced (map length goal_propss)
   497       handle THM _ => lost_structure ();
   498     val _ = Unify.matches_list thy (flat goal_propss) (map Thm.prop_of (flat results)) orelse
   499       error ("Proved a different theorem:\n" ^ string_of_thm th);
   500     val _ = Thm.check_shyps (Variable.sorts_of ctxt) th;
   501 
   502     fun recover_result ([] :: pss) thss = [] :: recover_result pss thss
   503       | recover_result (_ :: pss) (ths :: thss) = ths :: recover_result pss thss
   504       | recover_result [] [] = []
   505       | recover_result _ _ = lost_structure ();
   506   in recover_result propss results end;
   507 
   508 
   509 (* goal views -- corresponding to methods *)
   510 
   511 fun raw_goal state =
   512   let val (ctxt, (facts, goal)) = get_goal state
   513   in {context = ctxt, facts = facts, goal = goal} end;
   514 
   515 val goal = raw_goal o refine_insert [];
   516 
   517 fun simple_goal state =
   518   let
   519     val (_, (facts, _)) = get_goal state;
   520     val (ctxt, (_, goal)) = get_goal (refine_insert facts state);
   521   in {context = ctxt, goal = goal} end;
   522 
   523 fun status_markup state =
   524   (case try goal state of
   525     SOME {goal, ...} => Markup.proof_state (Thm.nprems_of goal)
   526   | NONE => Markup.empty);
   527 
   528 
   529 
   530 (*** structured proof commands ***)
   531 
   532 (** context elements **)
   533 
   534 (* let bindings *)
   535 
   536 local
   537 
   538 fun gen_bind bind args state =
   539   state
   540   |> assert_forward
   541   |> map_context (bind true args #> snd)
   542   |> put_facts NONE;
   543 
   544 in
   545 
   546 val let_bind = gen_bind ProofContext.match_bind_i;
   547 val let_bind_cmd = gen_bind ProofContext.match_bind;
   548 
   549 end;
   550 
   551 
   552 (* concrete syntax *)
   553 
   554 local
   555 
   556 fun gen_write prep_arg mode args =
   557   assert_forward
   558   #> map_context (fn ctxt => ctxt |> ProofContext.notation true mode (map (prep_arg ctxt) args))
   559   #> put_facts NONE;
   560 
   561 in
   562 
   563 val write = gen_write (K I);
   564 
   565 val write_cmd =
   566   gen_write (fn ctxt => fn (c, mx) =>
   567     (ProofContext.read_const ctxt false (Syntax.mixfixT mx) c, mx));
   568 
   569 end;
   570 
   571 
   572 (* fix *)
   573 
   574 local
   575 
   576 fun gen_fix prep_vars args =
   577   assert_forward
   578   #> map_context (fn ctxt => snd (ProofContext.add_fixes (prep_vars ctxt args) ctxt))
   579   #> put_facts NONE;
   580 
   581 in
   582 
   583 val fix = gen_fix (K I);
   584 val fix_cmd = gen_fix (fn ctxt => fn args => fst (ProofContext.read_vars args ctxt));
   585 
   586 end;
   587 
   588 
   589 (* assume etc. *)
   590 
   591 local
   592 
   593 fun gen_assume asm prep_att exp args state =
   594   state
   595   |> assert_forward
   596   |> map_context_result (asm exp (Attrib.map_specs (prep_att (theory_of state)) args))
   597   |> these_factss [] |> #2;
   598 
   599 in
   600 
   601 val assm = gen_assume ProofContext.add_assms_i (K I);
   602 val assm_cmd = gen_assume ProofContext.add_assms Attrib.attribute;
   603 val assume = assm Assumption.assume_export;
   604 val assume_cmd = assm_cmd Assumption.assume_export;
   605 val presume = assm Assumption.presume_export;
   606 val presume_cmd = assm_cmd Assumption.presume_export;
   607 
   608 end;
   609 
   610 
   611 (* def *)
   612 
   613 local
   614 
   615 fun gen_def prep_att prep_vars prep_binds args state =
   616   let
   617     val _ = assert_forward state;
   618     val thy = theory_of state;
   619 
   620     val (raw_name_atts, (raw_vars, raw_rhss)) = args |> split_list ||> split_list;
   621     val name_atts = map (apsnd (map (prep_att thy))) raw_name_atts;
   622   in
   623     state
   624     |> map_context_result (prep_vars (map (fn (x, mx) => (x, NONE, mx)) raw_vars))
   625     |>> map (fn (x, _, mx) => (x, mx))
   626     |-> (fn vars =>
   627       map_context_result (prep_binds false (map swap raw_rhss))
   628       #-> (fn rhss => map_context_result (Local_Defs.add_defs (vars ~~ (name_atts ~~ rhss)))))
   629     |-> (put_facts o SOME o map (#2 o #2))
   630   end;
   631 
   632 in
   633 
   634 val def = gen_def (K I) ProofContext.cert_vars ProofContext.match_bind_i;
   635 val def_cmd = gen_def Attrib.attribute ProofContext.read_vars ProofContext.match_bind;
   636 
   637 end;
   638 
   639 
   640 
   641 (** facts **)
   642 
   643 (* chain *)
   644 
   645 fun clean_facts ctxt =
   646   put_facts (SOME (filter_out Thm.is_dummy (the_facts ctxt))) ctxt;
   647 
   648 val chain =
   649   assert_forward
   650   #> clean_facts
   651   #> enter_chain;
   652 
   653 fun chain_facts facts =
   654   put_facts (SOME facts)
   655   #> chain;
   656 
   657 
   658 (* note etc. *)
   659 
   660 fun no_binding args = map (pair (Binding.empty, [])) args;
   661 
   662 local
   663 
   664 fun gen_thmss more_facts opt_chain opt_result prep_atts prep_fact args state =
   665   state
   666   |> assert_forward
   667   |> map_context_result (ProofContext.note_thmss ""
   668     (Attrib.map_facts_refs (prep_atts (theory_of state)) (prep_fact (context_of state)) args))
   669   |> these_factss (more_facts state)
   670   ||> opt_chain
   671   |> opt_result;
   672 
   673 in
   674 
   675 val note_thmss = gen_thmss (K []) I #2 (K I) (K I);
   676 val note_thmss_cmd = gen_thmss (K []) I #2 Attrib.attribute ProofContext.get_fact;
   677 
   678 val from_thmss = gen_thmss (K []) chain #2 (K I) (K I) o no_binding;
   679 val from_thmss_cmd = gen_thmss (K []) chain #2 Attrib.attribute ProofContext.get_fact o no_binding;
   680 
   681 val with_thmss = gen_thmss the_facts chain #2 (K I) (K I) o no_binding;
   682 val with_thmss_cmd = gen_thmss the_facts chain #2 Attrib.attribute ProofContext.get_fact o no_binding;
   683 
   684 val local_results = gen_thmss (K []) I I (K I) (K I) o map (apsnd Thm.simple_fact);
   685 
   686 end;
   687 
   688 
   689 (* using/unfolding *)
   690 
   691 local
   692 
   693 fun gen_using f g prep_atts prep_fact args state =
   694   state
   695   |> assert_backward
   696   |> map_context_result
   697     (ProofContext.note_thmss ""
   698       (Attrib.map_facts_refs (prep_atts (theory_of state)) (prep_fact (context_of state))
   699         (no_binding args)))
   700   |> (fn (named_facts, state') =>
   701     state' |> map_goal I (fn (statement, _, using, goal, before_qed, after_qed) =>
   702       let
   703         val ctxt = context_of state';
   704         val ths = maps snd named_facts;
   705       in (statement, [], f ctxt ths using, g ctxt ths goal, before_qed, after_qed) end));
   706 
   707 fun append_using _ ths using = using @ filter_out Thm.is_dummy ths;
   708 fun unfold_using ctxt ths = map (Local_Defs.unfold ctxt ths);
   709 val unfold_goals = Local_Defs.unfold_goals;
   710 
   711 in
   712 
   713 val using = gen_using append_using (K (K I)) (K I) (K I);
   714 val using_cmd = gen_using append_using (K (K I)) Attrib.attribute ProofContext.get_fact;
   715 val unfolding = gen_using unfold_using unfold_goals (K I) (K I);
   716 val unfolding_cmd = gen_using unfold_using unfold_goals Attrib.attribute ProofContext.get_fact;
   717 
   718 end;
   719 
   720 
   721 (* case *)
   722 
   723 local
   724 
   725 fun qualified_binding a =
   726   Binding.qualify true (Long_Name.qualifier a) (Binding.name (Long_Name.base_name a));
   727 
   728 fun gen_invoke_case prep_att (name, xs, raw_atts) state =
   729   let
   730     val atts = map (prep_att (theory_of state)) raw_atts;
   731     val (asms, state') = state |> map_context_result (fn ctxt =>
   732       ctxt |> ProofContext.apply_case (ProofContext.get_case ctxt name xs));
   733     val assumptions = asms |> map (fn (a, ts) => ((qualified_binding a, atts), map (rpair []) ts));
   734   in
   735     state'
   736     |> assume assumptions
   737     |> bind_terms Auto_Bind.no_facts
   738     |> `the_facts |-> (fn thms => note_thmss [((Binding.name name, []), [(thms, [])])])
   739   end;
   740 
   741 in
   742 
   743 val invoke_case = gen_invoke_case (K I);
   744 val invoke_case_cmd = gen_invoke_case Attrib.attribute;
   745 
   746 end;
   747 
   748 
   749 
   750 (** proof structure **)
   751 
   752 (* blocks *)
   753 
   754 val begin_block =
   755   assert_forward
   756   #> open_block
   757   #> put_goal NONE
   758   #> open_block;
   759 
   760 val next_block =
   761   assert_forward
   762   #> close_block
   763   #> open_block
   764   #> put_goal NONE
   765   #> put_facts NONE;
   766 
   767 fun end_block state =
   768   state
   769   |> assert_forward
   770   |> close_block
   771   |> assert_current_goal false
   772   |> close_block
   773   |> export_facts state;
   774 
   775 
   776 (* sub-proofs *)
   777 
   778 fun proof opt_text =
   779   assert_backward
   780   #> refine (the_default Method.default_text opt_text)
   781   #> Seq.map (using_facts [] #> enter_forward);
   782 
   783 fun end_proof bot txt state =
   784   state
   785   |> assert_forward
   786   |> assert_bottom bot
   787   |> close_block
   788   |> assert_current_goal true
   789   |> using_facts []
   790   |> `before_qed |-> (refine o the_default Method.succeed_text)
   791   |> Seq.maps (refine (Method.finish_text txt));
   792 
   793 fun check_result msg sq =
   794   (case Seq.pull sq of
   795     NONE => error msg
   796   | SOME (s, _) => s);
   797 
   798 fun check_finish sq = check_result "Failed to finish proof" sq;
   799 
   800 
   801 (* unstructured refinement *)
   802 
   803 fun defer i = assert_no_chain #> refine (Method.Basic (K (Method.defer i)));
   804 fun prefer i = assert_no_chain #> refine (Method.Basic (K (Method.prefer i)));
   805 
   806 fun apply text = assert_backward #> refine text #> Seq.map (using_facts []);
   807 fun apply_end text = assert_forward #> refine_end text;
   808 
   809 
   810 
   811 (** goals **)
   812 
   813 (* generic goals *)
   814 
   815 local
   816 
   817 val is_var =
   818   can (dest_TVar o Logic.dest_type o Logic.dest_term) orf
   819   can (dest_Var o Logic.dest_term);
   820 
   821 fun implicit_vars props =
   822   let
   823     val (var_props, _) = take_prefix is_var props;
   824     val explicit_vars = fold Term.add_vars var_props [];
   825     val vars = filter_out (member (op =) explicit_vars) (fold Term.add_vars props []);
   826   in map (Logic.mk_term o Var) vars end;
   827 
   828 fun refine_terms n =
   829   refine (Method.Basic (K (RAW_METHOD
   830     (K (HEADGOAL (PRECISE_CONJUNCTS n
   831       (HEADGOAL (CONJUNCTS (ALLGOALS (rtac Drule.termI))))))))))
   832   #> Seq.hd;
   833 
   834 in
   835 
   836 fun generic_goal prepp kind before_qed after_qed raw_propp state =
   837   let
   838     val thy = theory_of state;
   839     val cert = Thm.cterm_of thy;
   840     val chaining = can assert_chain state;
   841     val pos = Position.thread_data ();
   842 
   843     val ((propss, after_ctxt), goal_state) =
   844       state
   845       |> assert_forward_or_chain
   846       |> enter_forward
   847       |> open_block
   848       |> map_context_result (fn ctxt => swap (prepp (ctxt, raw_propp)));
   849     val props = flat propss;
   850 
   851     val vars = implicit_vars props;
   852     val propss' = vars :: propss;
   853     val goal_propss = filter_out null propss';
   854     val goal =
   855       cert (Logic.mk_conjunction_balanced (map Logic.mk_conjunction_balanced goal_propss))
   856       |> Thm.weaken_sorts (Variable.sorts_of (context_of goal_state));
   857     val statement = ((kind, pos), propss', Thm.term_of goal);
   858     val after_qed' = after_qed |>> (fn after_local =>
   859       fn results => map_context after_ctxt #> after_local results);
   860   in
   861     goal_state
   862     |> map_context (init_context #> Variable.set_body true)
   863     |> put_goal (SOME (make_goal (statement, [], [], Goal.init goal, before_qed, after_qed')))
   864     |> map_context (ProofContext.auto_bind_goal props)
   865     |> chaining ? (`the_facts #-> using_facts)
   866     |> put_facts NONE
   867     |> open_block
   868     |> put_goal NONE
   869     |> enter_backward
   870     |> not (null vars) ? refine_terms (length goal_propss)
   871     |> null props ? (refine (Method.Basic Method.assumption) #> Seq.hd)
   872   end;
   873 
   874 fun generic_qed after_ctxt state =
   875   let
   876     val (goal_ctxt, {statement = (_, stmt, _), goal, after_qed, ...}) = current_goal state;
   877     val outer_state = state |> close_block;
   878     val outer_ctxt = context_of outer_state;
   879 
   880     val props =
   881       flat (tl stmt)
   882       |> Variable.exportT_terms goal_ctxt outer_ctxt;
   883     val results =
   884       tl (conclude_goal goal_ctxt goal stmt)
   885       |> burrow (ProofContext.export goal_ctxt outer_ctxt);
   886   in
   887     outer_state
   888     |> map_context (after_ctxt props)
   889     |> pair (after_qed, results)
   890   end;
   891 
   892 end;
   893 
   894 
   895 (* local goals *)
   896 
   897 fun local_goal print_results prep_att prepp kind before_qed after_qed stmt state =
   898   let
   899     val thy = theory_of state;
   900     val ((names, attss), propp) =
   901       Attrib.map_specs (prep_att thy) stmt |> split_list |>> split_list;
   902 
   903     fun after_qed' results =
   904       local_results ((names ~~ attss) ~~ results)
   905       #-> (fn res => tap (fn st => print_results (context_of st) ((kind, ""), res) : unit))
   906       #> after_qed results;
   907   in
   908     state
   909     |> generic_goal prepp kind before_qed (after_qed', K I) propp
   910     |> tap (Variable.warn_extra_tfrees (context_of state) o context_of)
   911   end;
   912 
   913 fun local_qeds txt =
   914   end_proof false txt
   915   #> Seq.map (generic_qed ProofContext.auto_bind_facts #->
   916     (fn ((after_qed, _), results) => after_qed results));
   917 
   918 fun local_qed txt = local_qeds txt #> check_finish;
   919 
   920 
   921 (* global goals *)
   922 
   923 fun global_goal prepp before_qed after_qed propp ctxt =
   924   init ctxt
   925   |> generic_goal (prepp #> ProofContext.auto_fixes) "" before_qed (K I, after_qed) propp;
   926 
   927 val theorem = global_goal ProofContext.bind_propp_schematic_i;
   928 val theorem_cmd = global_goal ProofContext.bind_propp_schematic;
   929 
   930 fun global_qeds txt =
   931   end_proof true txt
   932   #> Seq.map (generic_qed (K I) #> (fn (((_, after_qed), results), state) =>
   933     after_qed results (context_of state)));
   934 
   935 fun global_qed txt = global_qeds txt #> check_finish;
   936 
   937 
   938 (* concluding steps *)
   939 
   940 fun terminal_proof qed initial terminal =
   941   proof (SOME initial) #> Seq.maps (qed terminal) #> check_finish;
   942 
   943 fun local_terminal_proof (text, opt_text) = terminal_proof local_qeds text (opt_text, true);
   944 val local_default_proof = local_terminal_proof (Method.default_text, NONE);
   945 val local_immediate_proof = local_terminal_proof (Method.this_text, NONE);
   946 fun local_skip_proof int = local_terminal_proof (Method.sorry_text int, NONE);
   947 val local_done_proof = terminal_proof local_qeds Method.done_text (NONE, false);
   948 
   949 fun global_terminal_proof (text, opt_text) = terminal_proof global_qeds text (opt_text, true);
   950 val global_default_proof = global_terminal_proof (Method.default_text, NONE);
   951 val global_immediate_proof = global_terminal_proof (Method.this_text, NONE);
   952 fun global_skip_proof int = global_terminal_proof (Method.sorry_text int, NONE);
   953 val global_done_proof = terminal_proof global_qeds Method.done_text (NONE, false);
   954 
   955 
   956 (* common goal statements *)
   957 
   958 local
   959 
   960 fun gen_have prep_att prepp before_qed after_qed stmt int =
   961   local_goal (Proof_Display.print_results int) prep_att prepp "have" before_qed after_qed stmt;
   962 
   963 fun gen_show prep_att prepp before_qed after_qed stmt int state =
   964   let
   965     val testing = Unsynchronized.ref false;
   966     val rule = Unsynchronized.ref (NONE: thm option);
   967     fun fail_msg ctxt =
   968       "Local statement will fail to refine any pending goal" ::
   969       (case ! rule of NONE => [] | SOME th => [Proof_Display.string_of_rule ctxt "Failed" th])
   970       |> cat_lines;
   971 
   972     fun print_results ctxt res =
   973       if ! testing then () else Proof_Display.print_results int ctxt res;
   974     fun print_rule ctxt th =
   975       if ! testing then rule := SOME th
   976       else if int then Output.urgent_message (Proof_Display.string_of_rule ctxt "Successful" th)
   977       else ();
   978     val test_proof =
   979       try (local_skip_proof true)
   980       |> Unsynchronized.setmp testing true
   981       |> Exn.capture;
   982 
   983     fun after_qed' results =
   984       refine_goals print_rule (context_of state) (flat results)
   985       #> check_result "Failed to refine any pending goal"
   986       #> after_qed results;
   987   in
   988     state
   989     |> local_goal print_results prep_att prepp "show" before_qed after_qed' stmt
   990     |> int ? (fn goal_state =>
   991       (case test_proof goal_state of
   992         Exn.Result (SOME _) => goal_state
   993       | Exn.Result NONE => error (fail_msg (context_of goal_state))
   994       | Exn.Exn exn =>
   995           if Exn.is_interrupt exn then reraise exn
   996           else raise Exn.EXCEPTIONS ([exn, ERROR (fail_msg (context_of goal_state))])))
   997   end;
   998 
   999 in
  1000 
  1001 val have = gen_have (K I) ProofContext.bind_propp_i;
  1002 val have_cmd = gen_have Attrib.attribute ProofContext.bind_propp;
  1003 val show = gen_show (K I) ProofContext.bind_propp_i;
  1004 val show_cmd = gen_show Attrib.attribute ProofContext.bind_propp;
  1005 
  1006 end;
  1007 
  1008 
  1009 
  1010 (** future proofs **)
  1011 
  1012 (* relevant proof states *)
  1013 
  1014 fun is_schematic t =
  1015   Term.exists_subterm Term.is_Var t orelse
  1016   Term.exists_type (Term.exists_subtype Term.is_TVar) t;
  1017 
  1018 fun schematic_goal state =
  1019   let val (_, (_, {statement = (_, _, prop), ...})) = find_goal state
  1020   in is_schematic prop end;
  1021 
  1022 fun is_relevant state =
  1023   (case try find_goal state of
  1024     NONE => true
  1025   | SOME (_, (_, {statement = (_, _, prop), goal, ...})) =>
  1026       is_schematic prop orelse not (Logic.protect prop aconv Thm.concl_of goal));
  1027 
  1028 
  1029 (* full proofs *)
  1030 
  1031 local
  1032 
  1033 fun future_proof done get_context fork_proof state =
  1034   let
  1035     val _ = assert_backward state;
  1036     val (goal_ctxt, (_, goal)) = find_goal state;
  1037     val {statement as (kind, _, prop), messages, using, goal, before_qed, after_qed} = goal;
  1038     val goal_txt = prop :: map Thm.term_of (Assumption.all_assms_of goal_ctxt);
  1039 
  1040     val _ = is_relevant state andalso error "Cannot fork relevant proof";
  1041 
  1042     val prop' = Logic.protect prop;
  1043     val statement' = (kind, [[], [prop']], prop');
  1044     val goal' = Thm.adjust_maxidx_thm (Thm.maxidx_of goal)
  1045       (Drule.comp_no_flatten (goal, Thm.nprems_of goal) 1 Drule.protectI);
  1046 
  1047     fun after_local' [[th]] = put_thms false (Auto_Bind.thisN, SOME [th]);
  1048     fun after_global' [[th]] = ProofContext.put_thms false (Auto_Bind.thisN, SOME [th]);
  1049     val after_qed' = (after_local', after_global');
  1050     val this_name = ProofContext.full_name goal_ctxt (Binding.name Auto_Bind.thisN);
  1051 
  1052     val result_ctxt =
  1053       state
  1054       |> map_contexts (fold Variable.declare_term goal_txt)
  1055       |> map_goal I (K (statement', messages, using, goal', before_qed, after_qed'))
  1056       |> fork_proof;
  1057 
  1058     val future_thm = result_ctxt |> Future.map (fn (_, x) =>
  1059       ProofContext.get_fact_single (get_context x) (Facts.named this_name));
  1060     val finished_goal = Goal.future_result goal_ctxt future_thm prop';
  1061     val state' =
  1062       state
  1063       |> map_goal I (K (statement, messages, using, finished_goal, NONE, after_qed))
  1064       |> done;
  1065   in (Future.map #1 result_ctxt, state') end;
  1066 
  1067 in
  1068 
  1069 fun local_future_proof x = future_proof local_done_proof context_of x;
  1070 fun global_future_proof x = future_proof global_done_proof I x;
  1071 
  1072 end;
  1073 
  1074 
  1075 (* terminal proofs *)
  1076 
  1077 local
  1078 
  1079 fun future_terminal_proof proof1 proof2 meths int state =
  1080   if int orelse is_relevant state orelse not (Goal.local_future_enabled ())
  1081   then proof1 meths state
  1082   else snd (proof2 (fn state' => Goal.fork (fn () => ((), proof1 meths state'))) state);
  1083 
  1084 in
  1085 
  1086 fun local_future_terminal_proof x =
  1087   future_terminal_proof local_terminal_proof local_future_proof x;
  1088 
  1089 fun global_future_terminal_proof x =
  1090   future_terminal_proof global_terminal_proof global_future_proof x;
  1091 
  1092 end;
  1093 
  1094 end;
  1095