src/Pure/Isar/token.ML
author haftmann
Mon Nov 29 11:38:59 2010 +0100 (2010-11-29 ago)
changeset 40803 3f66ea311d44
parent 40627 becf5d5187cc
child 40958 755f8fe7ced9
permissions -rw-r--r--
tuned
     1 (*  Title:      Pure/Isar/token.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Outer token syntax for Isabelle/Isar.
     5 *)
     6 
     7 signature TOKEN =
     8 sig
     9   datatype kind =
    10     Command | Keyword | Ident | LongIdent | SymIdent | Var | TypeIdent | TypeVar |
    11     Nat | Float | String | AltString | Verbatim | Space | Comment | InternalValue |
    12     Malformed | Error of string | Sync | EOF
    13   datatype value =
    14     Text of string | Typ of typ | Term of term | Fact of thm list |
    15     Attribute of morphism -> attribute
    16   type T
    17   val str_of_kind: kind -> string
    18   val position_of: T -> Position.T
    19   val end_position_of: T -> Position.T
    20   val pos_of: T -> string
    21   val eof: T
    22   val is_eof: T -> bool
    23   val not_eof: T -> bool
    24   val not_sync: T -> bool
    25   val stopper: T Scan.stopper
    26   val kind_of: T -> kind
    27   val is_kind: kind -> T -> bool
    28   val keyword_with: (string -> bool) -> T -> bool
    29   val ident_with: (string -> bool) -> T -> bool
    30   val is_proper: T -> bool
    31   val is_semicolon: T -> bool
    32   val is_comment: T -> bool
    33   val is_begin_ignore: T -> bool
    34   val is_end_ignore: T -> bool
    35   val is_blank: T -> bool
    36   val is_newline: T -> bool
    37   val source_of: T -> string
    38   val source_position_of: T -> Symbol_Pos.text * Position.T
    39   val content_of: T -> string
    40   val unparse: T -> string
    41   val text_of: T -> string * string
    42   val get_value: T -> value option
    43   val map_value: (value -> value) -> T -> T
    44   val mk_text: string -> T
    45   val mk_typ: typ -> T
    46   val mk_term: term -> T
    47   val mk_fact: thm list -> T
    48   val mk_attribute: (morphism -> attribute) -> T
    49   val assignable: T -> T
    50   val assign: value option -> T -> unit
    51   val closure: T -> T
    52   val ident_or_symbolic: string -> bool
    53   val !!! : string -> (Symbol_Pos.T list -> 'a) -> Symbol_Pos.T list -> 'a
    54   val source_proper: (T, 'a) Source.source -> (T, (T, 'a) Source.source) Source.source
    55   val source': {do_recover: bool Option.option} -> (unit -> Scan.lexicon * Scan.lexicon) ->
    56     (Symbol_Pos.T, 'a) Source.source -> (T, (Symbol_Pos.T, 'a) Source.source) Source.source
    57   val source: {do_recover: bool Option.option} -> (unit -> Scan.lexicon * Scan.lexicon) ->
    58     Position.T -> (Symbol.symbol, 'a) Source.source -> (T,
    59       (Symbol_Pos.T, Position.T * (Symbol.symbol, 'a) Source.source) Source.source) Source.source
    60   val read_antiq: Scan.lexicon -> (T list -> 'a * T list) -> Symbol_Pos.T list * Position.T -> 'a
    61 end;
    62 
    63 structure Token: TOKEN =
    64 struct
    65 
    66 (** tokens **)
    67 
    68 (* token values *)
    69 
    70 (*The value slot assigns an (optional) internal value to a token,
    71   usually as a side-effect of special scanner setup (see also
    72   args.ML).  Note that an assignable ref designates an intermediate
    73   state of internalization -- it is NOT meant to persist.*)
    74 
    75 datatype value =
    76   Text of string |
    77   Typ of typ |
    78   Term of term |
    79   Fact of thm list |
    80   Attribute of morphism -> attribute;
    81 
    82 datatype slot =
    83   Slot |
    84   Value of value option |
    85   Assignable of value option Unsynchronized.ref;
    86 
    87 
    88 (* datatype token *)
    89 
    90 datatype kind =
    91   Command | Keyword | Ident | LongIdent | SymIdent | Var | TypeIdent | TypeVar |
    92   Nat | Float | String | AltString | Verbatim | Space | Comment | InternalValue |
    93   Malformed | Error of string | Sync | EOF;
    94 
    95 datatype T = Token of (Symbol_Pos.text * Position.range) * (kind * string) * slot;
    96 
    97 val str_of_kind =
    98  fn Command => "command"
    99   | Keyword => "keyword"
   100   | Ident => "identifier"
   101   | LongIdent => "long identifier"
   102   | SymIdent => "symbolic identifier"
   103   | Var => "schematic variable"
   104   | TypeIdent => "type variable"
   105   | TypeVar => "schematic type variable"
   106   | Nat => "natural number"
   107   | Float => "floating-point number"
   108   | String => "string"
   109   | AltString => "back-quoted string"
   110   | Verbatim => "verbatim text"
   111   | Space => "white space"
   112   | Comment => "comment text"
   113   | InternalValue => "internal value"
   114   | Malformed => "malformed symbolic character"
   115   | Error _ => "bad input"
   116   | Sync => "sync marker"
   117   | EOF => "end-of-file";
   118 
   119 
   120 (* position *)
   121 
   122 fun position_of (Token ((_, (pos, _)), _, _)) = pos;
   123 fun end_position_of (Token ((_, (_, pos)), _, _)) = pos;
   124 
   125 val pos_of = Position.str_of o position_of;
   126 
   127 
   128 (* control tokens *)
   129 
   130 fun mk_eof pos = Token (("", (pos, Position.none)), (EOF, ""), Slot);
   131 val eof = mk_eof Position.none;
   132 
   133 fun is_eof (Token (_, (EOF, _), _)) = true
   134   | is_eof _ = false;
   135 
   136 val not_eof = not o is_eof;
   137 
   138 fun not_sync (Token (_, (Sync, _), _)) = false
   139   | not_sync _ = true;
   140 
   141 val stopper =
   142   Scan.stopper (fn [] => eof | toks => mk_eof (end_position_of (List.last toks))) is_eof;
   143 
   144 
   145 (* kind of token *)
   146 
   147 fun kind_of (Token (_, (k, _), _)) = k;
   148 fun is_kind k (Token (_, (k', _), _)) = k = k';
   149 
   150 fun keyword_with pred (Token (_, (Keyword, x), _)) = pred x
   151   | keyword_with _ _ = false;
   152 
   153 fun ident_with pred (Token (_, (Ident, x), _)) = pred x
   154   | ident_with _ _ = false;
   155 
   156 fun is_proper (Token (_, (Space, _), _)) = false
   157   | is_proper (Token (_, (Comment, _), _)) = false
   158   | is_proper _ = true;
   159 
   160 fun is_semicolon (Token (_, (Keyword, ";"), _)) = true
   161   | is_semicolon _ = false;
   162 
   163 fun is_comment (Token (_, (Comment, _), _)) = true
   164   | is_comment _ = false;
   165 
   166 fun is_begin_ignore (Token (_, (Comment, "<"), _)) = true
   167   | is_begin_ignore _ = false;
   168 
   169 fun is_end_ignore (Token (_, (Comment, ">"), _)) = true
   170   | is_end_ignore _ = false;
   171 
   172 
   173 (* blanks and newlines -- space tokens obey lines *)
   174 
   175 fun is_blank (Token (_, (Space, x), _)) = not (String.isSuffix "\n" x)
   176   | is_blank _ = false;
   177 
   178 fun is_newline (Token (_, (Space, x), _)) = String.isSuffix "\n" x
   179   | is_newline _ = false;
   180 
   181 
   182 (* token content *)
   183 
   184 fun source_of (Token ((source, (pos, _)), _, _)) =
   185   YXML.string_of (XML.Elem (Markup.token (Position.properties_of pos), [XML.Text source]));
   186 
   187 fun source_position_of (Token ((source, (pos, _)), _, _)) = (source, pos);
   188 
   189 fun content_of (Token (_, (_, x), _)) = x;
   190 
   191 
   192 (* unparse *)
   193 
   194 fun escape q =
   195   implode o map (fn s => if s = q orelse s = "\\" then "\\" ^ s else s) o Symbol.explode;
   196 
   197 fun unparse (Token (_, (kind, x), _)) =
   198   (case kind of
   199     String => x |> quote o escape "\""
   200   | AltString => x |> enclose "`" "`" o escape "`"
   201   | Verbatim => x |> enclose "{*" "*}"
   202   | Comment => x |> enclose "(*" "*)"
   203   | Sync => ""
   204   | EOF => ""
   205   | _ => x);
   206 
   207 fun text_of tok =
   208   if is_semicolon tok then ("terminator", "")
   209   else
   210     let
   211       val k = str_of_kind (kind_of tok);
   212       val s = unparse tok;
   213     in
   214       if s = "" then (k, "")
   215       else if size s < 40 andalso not (exists_string (fn c => c = "\n") s) then (k ^ " " ^ s, "")
   216       else (k, s)
   217     end;
   218 
   219 
   220 
   221 (** associated values **)
   222 
   223 (* access values *)
   224 
   225 fun get_value (Token (_, _, Value v)) = v
   226   | get_value _ = NONE;
   227 
   228 fun map_value f (Token (x, y, Value (SOME v))) = Token (x, y, Value (SOME (f v)))
   229   | map_value _ tok = tok;
   230 
   231 
   232 (* make values *)
   233 
   234 fun mk_value k v = Token ((k, Position.no_range), (InternalValue, k), Value (SOME v));
   235 
   236 val mk_text = mk_value "<text>" o Text;
   237 val mk_typ = mk_value "<typ>" o Typ;
   238 val mk_term = mk_value "<term>" o Term;
   239 val mk_fact = mk_value "<fact>" o Fact;
   240 val mk_attribute = mk_value "<attribute>" o Attribute;
   241 
   242 
   243 (* static binding *)
   244 
   245 (*1st stage: make empty slots assignable*)
   246 fun assignable (Token (x, y, Slot)) = Token (x, y, Assignable (Unsynchronized.ref NONE))
   247   | assignable tok = tok;
   248 
   249 (*2nd stage: assign values as side-effect of scanning*)
   250 fun assign v (Token (_, _, Assignable r)) = r := v
   251   | assign _ _ = ();
   252 
   253 (*3rd stage: static closure of final values*)
   254 fun closure (Token (x, y, Assignable (Unsynchronized.ref v))) = Token (x, y, Value v)
   255   | closure tok = tok;
   256 
   257 
   258 
   259 (** scanners **)
   260 
   261 open Basic_Symbol_Pos;
   262 
   263 fun !!! msg = Symbol_Pos.!!! ("Outer lexical error: " ^ msg);
   264 
   265 
   266 (* scan symbolic idents *)
   267 
   268 val is_sym_char = member (op =) (raw_explode "!#$%&*+-/<=>?@^_|~");
   269 
   270 val scan_symid =
   271   Scan.many1 (is_sym_char o Symbol_Pos.symbol) ||
   272   Scan.one (Symbol.is_symbolic o Symbol_Pos.symbol) >> single;
   273 
   274 fun is_symid str =
   275   (case try Symbol.explode str of
   276     SOME [s] => Symbol.is_symbolic s orelse is_sym_char s
   277   | SOME ss => forall is_sym_char ss
   278   | _ => false);
   279 
   280 fun ident_or_symbolic "begin" = false
   281   | ident_or_symbolic ":" = true
   282   | ident_or_symbolic "::" = true
   283   | ident_or_symbolic s = Syntax.is_identifier s orelse is_symid s;
   284 
   285 
   286 (* scan verbatim text *)
   287 
   288 val scan_verb =
   289   $$$ "*" --| Scan.ahead (~$$$ "}") ||
   290   Scan.one (fn (s, _) => s <> "*" andalso Symbol.is_regular s) >> single;
   291 
   292 val scan_verbatim =
   293   (Symbol_Pos.scan_pos --| $$$ "{" --| $$$ "*") -- !!! "missing end of verbatim text"
   294     (Symbol_Pos.change_prompt
   295       ((Scan.repeat scan_verb >> flat) -- ($$$ "*" |-- $$$ "}" |-- Symbol_Pos.scan_pos)));
   296 
   297 
   298 (* scan space *)
   299 
   300 fun is_space s = Symbol.is_blank s andalso s <> "\n";
   301 
   302 val scan_space =
   303   Scan.many1 (is_space o Symbol_Pos.symbol) @@@ Scan.optional ($$$ "\n") [] ||
   304   Scan.many (is_space o Symbol_Pos.symbol) @@@ $$$ "\n";
   305 
   306 
   307 (* scan comment *)
   308 
   309 val scan_comment =
   310   Symbol_Pos.scan_pos -- (Symbol_Pos.scan_comment_body !!! -- Symbol_Pos.scan_pos);
   311 
   312 
   313 
   314 (** token sources **)
   315 
   316 fun source_proper src = src |> Source.filter is_proper;
   317 
   318 local
   319 
   320 fun token_leq ((_, syms1), (_, syms2)) = length syms1 <= length syms2;
   321 
   322 fun token k ss =
   323   Token ((Symbol_Pos.implode ss, Symbol_Pos.range ss), (k, Symbol_Pos.untabify_content ss), Slot);
   324 
   325 fun token_range k (pos1, (ss, pos2)) =
   326   Token (Symbol_Pos.implode_range pos1 pos2 ss, (k, Symbol_Pos.untabify_content ss), Slot);
   327 
   328 fun scan (lex1, lex2) = !!! "bad input"
   329   (Symbol_Pos.scan_string >> token_range String ||
   330     Symbol_Pos.scan_alt_string >> token_range AltString ||
   331     scan_verbatim >> token_range Verbatim ||
   332     scan_comment >> token_range Comment ||
   333     scan_space >> token Space ||
   334     Scan.one (Symbol.is_malformed o Symbol_Pos.symbol) >> (token Malformed o single) ||
   335     Scan.one (Symbol.is_sync o Symbol_Pos.symbol) >> (token Sync o single) ||
   336     (Scan.max token_leq
   337       (Scan.max token_leq
   338         (Scan.literal lex2 >> pair Command)
   339         (Scan.literal lex1 >> pair Keyword))
   340       (Syntax.scan_longid >> pair LongIdent ||
   341         Syntax.scan_id >> pair Ident ||
   342         Syntax.scan_var >> pair Var ||
   343         Syntax.scan_tid >> pair TypeIdent ||
   344         Syntax.scan_tvar >> pair TypeVar ||
   345         Syntax.scan_float >> pair Float ||
   346         Syntax.scan_nat >> pair Nat ||
   347         scan_symid >> pair SymIdent) >> uncurry token));
   348 
   349 fun recover msg =
   350   Scan.many ((Symbol.is_regular andf (not o Symbol.is_blank)) o Symbol_Pos.symbol)
   351   >> (single o token (Error msg));
   352 
   353 in
   354 
   355 fun source' {do_recover} get_lex =
   356   Source.source Symbol_Pos.stopper (Scan.bulk (fn xs => scan (get_lex ()) xs))
   357     (Option.map (rpair recover) do_recover);
   358 
   359 fun source do_recover get_lex pos src =
   360   Symbol_Pos.source pos src
   361   |> source' do_recover get_lex;
   362 
   363 end;
   364 
   365 
   366 (* read_antiq *)
   367 
   368 fun read_antiq lex scan (syms, pos) =
   369   let
   370     fun err msg = cat_error msg ("Malformed antiquotation" ^ Position.str_of pos ^ ":\n" ^
   371       "@{" ^ Symbol_Pos.content syms ^ "}");
   372 
   373     val res =
   374       Source.of_list syms
   375       |> source' {do_recover = NONE} (K (lex, Scan.empty_lexicon))
   376       |> source_proper
   377       |> Source.source stopper (Scan.error (Scan.bulk scan)) NONE
   378       |> Source.exhaust;
   379   in (case res of [x] => x | _ => err "") handle ERROR msg => err msg end;
   380 
   381 end;