src/Pure/Isar/code.ML
author bulwahn
Fri May 06 11:57:21 2011 +0200 (2011-05-06 ago)
changeset 42707 42d607a9ae65
parent 42375 774df7c59508
child 43326 47cf4bc789aa
permissions -rw-r--r--
improving merge of code specifications by removing code equations of constructors after merging two theories
     1 (*  Title:      Pure/Isar/code.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Abstract executable ingredients of theory.  Management of data
     5 dependent on executable ingredients as synchronized cache; purged
     6 on any change of underlying executable ingredients.
     7 *)
     8 
     9 signature CODE =
    10 sig
    11   (*constants*)
    12   val check_const: theory -> term -> string
    13   val read_bare_const: theory -> string -> string * typ
    14   val read_const: theory -> string -> string
    15   val string_of_const: theory -> string -> string
    16   val cert_signature: theory -> typ -> typ
    17   val read_signature: theory -> string -> typ
    18   val const_typ: theory -> string -> typ
    19   val subst_signatures: theory -> term -> term
    20   val args_number: theory -> string -> int
    21 
    22   (*constructor sets*)
    23   val constrset_of_consts: theory -> (string * typ) list
    24     -> string * ((string * sort) list * (string * ((string * sort) list * typ list)) list)
    25 
    26   (*code equations and certificates*)
    27   val mk_eqn: theory -> thm * bool -> thm * bool
    28   val mk_eqn_warning: theory -> thm -> (thm * bool) option
    29   val mk_eqn_liberal: theory -> thm -> (thm * bool) option
    30   val assert_eqn: theory -> thm * bool -> thm * bool
    31   val const_typ_eqn: theory -> thm -> string * typ
    32   val expand_eta: theory -> int -> thm -> thm
    33   type cert
    34   val empty_cert: theory -> string -> cert
    35   val cert_of_eqns: theory -> string -> (thm * bool) list -> cert
    36   val constrain_cert: theory -> sort list -> cert -> cert
    37   val typargs_deps_of_cert: theory -> cert -> (string * sort) list * (string * typ list) list
    38   val equations_of_cert: theory -> cert -> ((string * sort) list * typ)
    39     * (((term * string option) list * (term * string option)) * (thm option * bool)) list
    40   val bare_thms_of_cert: theory -> cert -> thm list
    41   val pretty_cert: theory -> cert -> Pretty.T list
    42 
    43   (*executable code*)
    44   val add_type: string -> theory -> theory
    45   val add_type_cmd: string -> theory -> theory
    46   val add_signature: string * typ -> theory -> theory
    47   val add_signature_cmd: string * string -> theory -> theory
    48   val add_datatype: (string * typ) list -> theory -> theory
    49   val add_datatype_cmd: string list -> theory -> theory
    50   val datatype_interpretation:
    51     (string * ((string * sort) list * (string * ((string * sort) list * typ list)) list)
    52       -> theory -> theory) -> theory -> theory
    53   val add_abstype: thm -> theory -> theory
    54   val abstype_interpretation:
    55     (string * ((string * sort) list * ((string * ((string * sort) list * typ)) * (string * thm)))
    56       -> theory -> theory) -> theory -> theory
    57   val add_eqn: thm -> theory -> theory
    58   val add_nbe_eqn: thm -> theory -> theory
    59   val add_default_eqn: thm -> theory -> theory
    60   val add_default_eqn_attribute: attribute
    61   val add_default_eqn_attrib: Attrib.src
    62   val add_nbe_default_eqn: thm -> theory -> theory
    63   val add_nbe_default_eqn_attribute: attribute
    64   val add_nbe_default_eqn_attrib: Attrib.src
    65   val del_eqn: thm -> theory -> theory
    66   val del_eqns: string -> theory -> theory
    67   val add_case: thm -> theory -> theory
    68   val add_undefined: string -> theory -> theory
    69   val get_type: theory -> string
    70     -> ((string * sort) list * (string * ((string * sort) list * typ list)) list) * bool
    71   val get_type_of_constr_or_abstr: theory -> string -> (string * bool) option
    72   val is_constr: theory -> string -> bool
    73   val is_abstr: theory -> string -> bool
    74   val get_cert: theory -> ((thm * bool) list -> (thm * bool) list) -> string -> cert
    75   val get_case_scheme: theory -> string -> (int * (int * string list)) option
    76   val get_case_cong: theory -> string -> thm option
    77   val undefineds: theory -> string list
    78   val print_codesetup: theory -> unit
    79 
    80   (*infrastructure*)
    81   val set_code_target_attr: (string -> thm -> theory -> theory) -> theory -> theory
    82 end;
    83 
    84 signature CODE_DATA_ARGS =
    85 sig
    86   type T
    87   val empty: T
    88 end;
    89 
    90 signature CODE_DATA =
    91 sig
    92   type T
    93   val change: theory option -> (T -> T) -> T
    94   val change_yield: theory option -> (T -> 'a * T) -> 'a * T
    95 end;
    96 
    97 signature PRIVATE_CODE =
    98 sig
    99   include CODE
   100   val declare_data: Object.T -> serial
   101   val change_yield_data: serial * ('a -> Object.T) * (Object.T -> 'a)
   102     -> theory -> ('a -> 'b * 'a) -> 'b * 'a
   103 end;
   104 
   105 structure Code : PRIVATE_CODE =
   106 struct
   107 
   108 (** auxiliary **)
   109 
   110 (* printing *)
   111 
   112 fun string_of_typ thy =
   113   Syntax.string_of_typ (Config.put show_sorts true (Syntax.init_pretty_global thy));
   114 
   115 fun string_of_const thy c =
   116   let val ctxt = Proof_Context.init_global thy in
   117     case AxClass.inst_of_param thy c of
   118       SOME (c, tyco) =>
   119         Proof_Context.extern_const ctxt c ^ " " ^ enclose "[" "]"
   120           (Proof_Context.extern_type ctxt tyco)
   121     | NONE => Proof_Context.extern_const ctxt c
   122   end;
   123 
   124 
   125 (* constants *)
   126 
   127 fun typ_equiv tys = Type.raw_instance tys andalso Type.raw_instance (swap tys);
   128 
   129 fun check_bare_const thy t = case try dest_Const t
   130  of SOME c_ty => c_ty
   131   | NONE => error ("Not a constant: " ^ Syntax.string_of_term_global thy t);
   132 
   133 fun check_unoverload thy (c, ty) =
   134   let
   135     val c' = AxClass.unoverload_const thy (c, ty);
   136     val ty_decl = Sign.the_const_type thy c';
   137   in if Sign.typ_equiv thy
   138       (Type.strip_sorts ty_decl, Type.strip_sorts (Logic.varifyT_global ty)) then c'
   139     else error ("Type\n" ^ string_of_typ thy ty
   140       ^ "\nof constant " ^ quote c
   141       ^ "\nis too specific compared to declared type\n"
   142       ^ string_of_typ thy ty_decl)
   143   end; 
   144 
   145 fun check_const thy = check_unoverload thy o check_bare_const thy;
   146 
   147 fun read_bare_const thy = check_bare_const thy o Syntax.read_term_global thy;
   148 
   149 fun read_const thy = check_unoverload thy o read_bare_const thy;
   150 
   151 
   152 (** data store **)
   153 
   154 (* datatypes *)
   155 
   156 datatype typ_spec = Constructors of (string * ((string * sort) list * typ list)) list
   157   | Abstractor of (string * ((string * sort) list * typ)) * (string * thm);
   158 
   159 fun constructors_of (Constructors cos) = (cos, false)
   160   | constructors_of (Abstractor ((co, (vs, ty)), _)) = ([(co, (vs, [ty]))], true);
   161 
   162 
   163 (* functions *)
   164 
   165 datatype fun_spec = Default of (thm * bool) list * (thm * bool) list lazy
   166   | Eqns of (thm * bool) list
   167   | Proj of term * string
   168   | Abstr of thm * string;
   169 
   170 val empty_fun_spec = Default ([], Lazy.value []);
   171 
   172 fun is_default (Default _) = true
   173   | is_default _ = false;
   174 
   175 fun associated_abstype (Abstr (_, tyco)) = SOME tyco
   176   | associated_abstype _ = NONE;
   177 
   178 
   179 (* executable code data *)
   180 
   181 datatype spec = Spec of {
   182   history_concluded: bool,
   183   signatures: int Symtab.table * typ Symtab.table,
   184   functions: ((bool * fun_spec) * (serial * fun_spec) list) Symtab.table
   185     (*with explicit history*),
   186   types: ((serial * ((string * sort) list * typ_spec)) list) Symtab.table
   187     (*with explicit history*),
   188   cases: ((int * (int * string list)) * thm) Symtab.table * unit Symtab.table
   189 };
   190 
   191 fun make_spec (history_concluded, ((signatures, functions), (types, cases))) =
   192   Spec { history_concluded = history_concluded,
   193     signatures = signatures, functions = functions, types = types, cases = cases };
   194 fun map_spec f (Spec { history_concluded = history_concluded, signatures = signatures,
   195   functions = functions, types = types, cases = cases }) =
   196   make_spec (f (history_concluded, ((signatures, functions), (types, cases))));
   197 fun merge_spec (Spec { history_concluded = _, signatures = (tycos1, sigs1), functions = functions1,
   198     types = types1, cases = (cases1, undefs1) },
   199   Spec { history_concluded = _, signatures = (tycos2, sigs2), functions = functions2,
   200     types = types2, cases = (cases2, undefs2) }) =
   201   let
   202     val signatures = (Symtab.merge (op =) (tycos1, tycos2),
   203       Symtab.merge typ_equiv (sigs1, sigs2));
   204     val types = Symtab.join (K (AList.merge (op =) (K true))) (types1, types2);
   205     fun merge_functions ((_, history1), (_, history2)) =
   206       let
   207         val raw_history = AList.merge (op = : serial * serial -> bool)
   208           (K true) (history1, history2);
   209         val filtered_history = filter_out (is_default o snd) raw_history;
   210         val history = if null filtered_history
   211           then raw_history else filtered_history;
   212       in ((false, (snd o hd) history), history) end;
   213     val all_constructors =
   214       maps (map fst o fst o constructors_of o snd o snd o hd o snd) (Symtab.dest types);
   215     val functions = Symtab.join (K merge_functions) (functions1, functions2)
   216       |> fold (fn c => Symtab.map_entry c (apfst (K (true, empty_fun_spec)))) all_constructors;
   217     val cases = (Symtab.merge (K true) (cases1, cases2),
   218       Symtab.merge (K true) (undefs1, undefs2));
   219   in make_spec (false, ((signatures, functions), (types, cases))) end;
   220 
   221 fun history_concluded (Spec { history_concluded, ... }) = history_concluded;
   222 fun the_signatures (Spec { signatures, ... }) = signatures;
   223 fun the_functions (Spec { functions, ... }) = functions;
   224 fun the_types (Spec { types, ... }) = types;
   225 fun the_cases (Spec { cases, ... }) = cases;
   226 val map_history_concluded = map_spec o apfst;
   227 val map_signatures = map_spec o apsnd o apfst o apfst;
   228 val map_functions = map_spec o apsnd o apfst o apsnd;
   229 val map_typs = map_spec o apsnd o apsnd o apfst;
   230 val map_cases = map_spec o apsnd o apsnd o apsnd;
   231 
   232 
   233 (* data slots dependent on executable code *)
   234 
   235 (*private copy avoids potential conflict of table exceptions*)
   236 structure Datatab = Table(type key = int val ord = int_ord);
   237 
   238 local
   239 
   240 type kind = { empty: Object.T };
   241 
   242 val kinds = Unsynchronized.ref (Datatab.empty: kind Datatab.table);
   243 
   244 fun invoke f k = case Datatab.lookup (! kinds) k
   245  of SOME kind => f kind
   246   | NONE => raise Fail "Invalid code data identifier";
   247 
   248 in
   249 
   250 fun declare_data empty =
   251   let
   252     val k = serial ();
   253     val kind = { empty = empty };
   254     val _ = CRITICAL (fn () => Unsynchronized.change kinds (Datatab.update (k, kind)));
   255   in k end;
   256 
   257 fun invoke_init k = invoke (fn kind => #empty kind) k;
   258 
   259 end; (*local*)
   260 
   261 
   262 (* theory store *)
   263 
   264 local
   265 
   266 type data = Object.T Datatab.table;
   267 fun empty_dataref () = Synchronized.var "code data" (NONE : (data * theory_ref) option);
   268 
   269 structure Code_Data = Theory_Data
   270 (
   271   type T = spec * (data * theory_ref) option Synchronized.var;
   272   val empty = (make_spec (false, (((Symtab.empty, Symtab.empty), Symtab.empty),
   273     (Symtab.empty, (Symtab.empty, Symtab.empty)))), empty_dataref ());
   274   val extend = I  (* FIXME empty_dataref!?! *)
   275   fun merge ((spec1, _), (spec2, _)) =
   276     (merge_spec (spec1, spec2), empty_dataref ());
   277 );
   278 
   279 in
   280 
   281 
   282 (* access to executable code *)
   283 
   284 val the_exec = fst o Code_Data.get;
   285 
   286 fun map_exec_purge f = Code_Data.map (fn (exec, _) => (f exec, empty_dataref ()));
   287 
   288 fun change_fun_spec delete c f = (map_exec_purge o map_functions
   289   o (if delete then Symtab.map_entry c else Symtab.map_default (c, ((false, empty_fun_spec), [])))
   290     o apfst) (fn (_, spec) => (true, f spec));
   291 
   292 
   293 (* tackling equation history *)
   294 
   295 fun continue_history thy = if (history_concluded o the_exec) thy
   296   then thy
   297     |> (Code_Data.map o apfst o map_history_concluded) (K false)
   298     |> SOME
   299   else NONE;
   300 
   301 fun conclude_history thy = if (history_concluded o the_exec) thy
   302   then NONE
   303   else thy
   304     |> (Code_Data.map o apfst)
   305         ((map_functions o Symtab.map) (fn _ => fn ((changed, current), history) =>
   306           ((false, current),
   307             if changed then (serial (), current) :: history else history))
   308         #> map_history_concluded (K true))
   309     |> SOME;
   310 
   311 val _ = Context.>> (Context.map_theory (Theory.at_begin continue_history #> Theory.at_end conclude_history));
   312 
   313 
   314 (* access to data dependent on abstract executable code *)
   315 
   316 fun change_yield_data (kind, mk, dest) theory f =
   317   let
   318     val dataref = (snd o Code_Data.get) theory;
   319     val (datatab, thy_ref) = case Synchronized.value dataref
   320      of SOME (datatab, thy_ref) => if Theory.eq_thy (theory, Theory.deref thy_ref)
   321           then (datatab, thy_ref)
   322           else (Datatab.empty, Theory.check_thy theory)
   323       | NONE => (Datatab.empty, Theory.check_thy theory)
   324     val data = case Datatab.lookup datatab kind
   325      of SOME data => data
   326       | NONE => invoke_init kind;
   327     val result as (_, data') = f (dest data);
   328     val _ = Synchronized.change dataref
   329       ((K o SOME) (Datatab.update (kind, mk data') datatab, thy_ref));
   330   in result end;
   331 
   332 end; (*local*)
   333 
   334 
   335 (** foundation **)
   336 
   337 (* constants *)
   338 
   339 fun arity_number thy tyco = case Symtab.lookup ((fst o the_signatures o the_exec) thy) tyco
   340  of SOME n => n
   341   | NONE => Sign.arity_number thy tyco;
   342 
   343 fun build_tsig thy =
   344   let
   345     val ctxt = Syntax.init_pretty_global thy;
   346     val (tycos, _) = the_signatures (the_exec thy);
   347     val decls = #types (Type.rep_tsig (Sign.tsig_of thy))
   348       |> snd 
   349       |> Symtab.fold (fn (tyco, n) =>
   350           Symtab.update (tyco, Type.LogicalType n)) tycos;
   351   in
   352     Type.empty_tsig
   353     |> Symtab.fold (fn (tyco, Type.LogicalType n) => Type.add_type ctxt Name_Space.default_naming
   354         (Binding.qualified_name tyco, n) | _ => I) decls
   355   end;
   356 
   357 fun cert_signature thy =
   358   Logic.varifyT_global o Type.cert_typ (build_tsig thy) o Type.no_tvars;
   359 
   360 fun read_signature thy =
   361   cert_signature thy o Type.strip_sorts o Syntax.parse_typ (Proof_Context.init_global thy);
   362 
   363 fun expand_signature thy = Type.cert_typ_mode Type.mode_syntax (Sign.tsig_of thy);
   364 
   365 fun lookup_typ thy = Symtab.lookup ((snd o the_signatures o the_exec) thy);
   366 
   367 fun const_typ thy c = case lookup_typ thy c
   368  of SOME ty => ty
   369   | NONE => (Type.strip_sorts o Sign.the_const_type thy) c;
   370 
   371 fun args_number thy = length o binder_types o const_typ thy;
   372 
   373 fun subst_signature thy c ty =
   374   let
   375     fun mk_subst (Type (_, tys1)) (Type (_, tys2)) =
   376           fold2 mk_subst tys1 tys2
   377       | mk_subst ty (TVar (v, _)) = Vartab.update (v, ([], ty))
   378   in case lookup_typ thy c
   379    of SOME ty' => Envir.subst_type (mk_subst ty (expand_signature thy ty') Vartab.empty) ty'
   380     | NONE => ty
   381   end;
   382 
   383 fun subst_signatures thy = map_aterms (fn Const (c, ty) => Const (c, subst_signature thy c ty) | t => t);
   384 
   385 fun logical_typscheme thy (c, ty) =
   386   (map dest_TFree (Sign.const_typargs thy (c, ty)), Type.strip_sorts ty);
   387 
   388 fun typscheme thy (c, ty) = logical_typscheme thy (c, subst_signature thy c ty);
   389 
   390 
   391 (* datatypes *)
   392 
   393 fun no_constr thy s (c, ty) = error ("Not a datatype constructor:\n" ^ string_of_const thy c
   394   ^ " :: " ^ string_of_typ thy ty ^ "\n" ^ enclose "(" ")" s);
   395 
   396 fun analyze_constructor thy (c, raw_ty) =
   397   let
   398     val _ = Thm.cterm_of thy (Const (c, raw_ty));
   399     val ty = subst_signature thy c raw_ty;
   400     val ty_decl = (Logic.unvarifyT_global o const_typ thy) c;
   401     fun last_typ c_ty ty =
   402       let
   403         val tfrees = Term.add_tfreesT ty [];
   404         val (tyco, vs) = (apsnd o map) dest_TFree (dest_Type (body_type ty))
   405           handle TYPE _ => no_constr thy "bad type" c_ty
   406         val _ = if tyco = "fun" then no_constr thy "bad type" c_ty else ();
   407         val _ = if has_duplicates (eq_fst (op =)) vs
   408           then no_constr thy "duplicate type variables in datatype" c_ty else ();
   409         val _ = if length tfrees <> length vs
   410           then no_constr thy "type variables missing in datatype" c_ty else ();
   411       in (tyco, vs) end;
   412     val (tyco, _) = last_typ (c, ty) ty_decl;
   413     val (_, vs) = last_typ (c, ty) ty;
   414   in ((tyco, map snd vs), (c, (map fst vs, ty))) end;
   415 
   416 fun constrset_of_consts thy cs =
   417   let
   418     val _ = map (fn (c, _) => if (is_some o AxClass.class_of_param thy) c
   419       then error ("Is a class parameter: " ^ string_of_const thy c) else ()) cs;
   420     fun add ((tyco', sorts'), c) ((tyco, sorts), cs) =
   421       let
   422         val _ = if (tyco' : string) <> tyco
   423           then error "Different type constructors in constructor set"
   424           else ();
   425         val sorts'' =
   426           map2 (curry (Sorts.inter_sort (Sign.classes_of thy))) sorts' sorts
   427       in ((tyco, sorts''), c :: cs) end;
   428     fun inst vs' (c, (vs, ty)) =
   429       let
   430         val the_v = the o AList.lookup (op =) (vs ~~ vs');
   431         val ty' = map_type_tfree (fn (v, _) => TFree (the_v v)) ty;
   432         val (vs'', _) = logical_typscheme thy (c, ty');
   433       in (c, (vs'', binder_types ty')) end;
   434     val c' :: cs' = map (analyze_constructor thy) cs;
   435     val ((tyco, sorts), cs'') = fold add cs' (apsnd single c');
   436     val vs = Name.names Name.context Name.aT sorts;
   437     val cs''' = map (inst vs) cs'';
   438   in (tyco, (vs, rev cs''')) end;
   439 
   440 fun get_type_entry thy tyco = case these (Symtab.lookup ((the_types o the_exec) thy) tyco)
   441  of (_, entry) :: _ => SOME entry
   442   | _ => NONE;
   443 
   444 fun get_type thy tyco = case get_type_entry thy tyco
   445  of SOME (vs, spec) => apfst (pair vs) (constructors_of spec)
   446   | NONE => arity_number thy tyco
   447       |> Name.invents Name.context Name.aT
   448       |> map (rpair [])
   449       |> rpair []
   450       |> rpair false;
   451 
   452 fun get_abstype_spec thy tyco = case get_type_entry thy tyco
   453  of SOME (vs, Abstractor spec) => (vs, spec)
   454   | _ => error ("Not an abstract type: " ^ tyco);
   455  
   456 fun get_type_of_constr_or_abstr thy c =
   457   case (body_type o const_typ thy) c
   458    of Type (tyco, _) => let val ((_, cos), abstract) = get_type thy tyco
   459         in if member (op =) (map fst cos) c then SOME (tyco, abstract) else NONE end
   460     | _ => NONE;
   461 
   462 fun is_constr thy c = case get_type_of_constr_or_abstr thy c
   463  of SOME (_, false) => true
   464    | _ => false;
   465 
   466 fun is_abstr thy c = case get_type_of_constr_or_abstr thy c
   467  of SOME (_, true) => true
   468    | _ => false;
   469 
   470 
   471 (* bare code equations *)
   472 
   473 (* convention for variables:
   474     ?x ?'a   for free-floating theorems (e.g. in the data store)
   475     ?x  'a   for certificates
   476      x  'a   for final representation of equations
   477 *)
   478 
   479 exception BAD_THM of string;
   480 fun bad_thm msg = raise BAD_THM msg;
   481 fun error_thm f thm = f thm handle BAD_THM msg => error msg;
   482 fun warning_thm f thm = SOME (f thm) handle BAD_THM msg => (warning msg; NONE)
   483 fun try_thm f thm = SOME (f thm) handle BAD_THM _ => NONE;
   484 
   485 fun is_linear thm =
   486   let val (_, args) = (strip_comb o fst o Logic.dest_equals o Thm.plain_prop_of) thm
   487   in not (has_duplicates (op =) ((fold o fold_aterms)
   488     (fn Var (v, _) => cons v | _ => I) args [])) end;
   489 
   490 fun check_decl_ty thy (c, ty) =
   491   let
   492     val ty_decl = Sign.the_const_type thy c;
   493   in if Sign.typ_equiv thy (Type.strip_sorts ty_decl, Type.strip_sorts ty) then ()
   494     else bad_thm ("Type\n" ^ string_of_typ thy ty
   495       ^ "\nof constant " ^ quote c
   496       ^ "\nis too specific compared to declared type\n"
   497       ^ string_of_typ thy ty_decl)
   498   end; 
   499 
   500 fun check_eqn thy { allow_nonlinear, allow_consts, allow_pats } thm (lhs, rhs) =
   501   let
   502     fun bad s = bad_thm (s ^ ":\n" ^ Display.string_of_thm_global thy thm);
   503     fun vars_of t = fold_aterms (fn Var (v, _) => insert (op =) v
   504       | Free _ => bad "Illegal free variable in equation"
   505       | _ => I) t [];
   506     fun tvars_of t = fold_term_types (fn _ =>
   507       fold_atyps (fn TVar (v, _) => insert (op =) v
   508         | TFree _ => bad "Illegal free type variable in equation")) t [];
   509     val lhs_vs = vars_of lhs;
   510     val rhs_vs = vars_of rhs;
   511     val lhs_tvs = tvars_of lhs;
   512     val rhs_tvs = tvars_of rhs;
   513     val _ = if null (subtract (op =) lhs_vs rhs_vs)
   514       then ()
   515       else bad "Free variables on right hand side of equation";
   516     val _ = if null (subtract (op =) lhs_tvs rhs_tvs)
   517       then ()
   518       else bad "Free type variables on right hand side of equation";
   519     val (head, args) = strip_comb lhs;
   520     val (c, ty) = case head
   521      of Const (c_ty as (_, ty)) => (AxClass.unoverload_const thy c_ty, ty)
   522       | _ => bad "Equation not headed by constant";
   523     fun check _ (Abs _) = bad "Abstraction on left hand side of equation"
   524       | check 0 (Var _) = ()
   525       | check _ (Var _) = bad "Variable with application on left hand side of equation"
   526       | check n (t1 $ t2) = (check (n+1) t1; check 0 t2)
   527       | check n (Const (c_ty as (c, ty))) =
   528           if allow_pats then let
   529             val c' = AxClass.unoverload_const thy c_ty
   530           in if n = (length o binder_types o subst_signature thy c') ty
   531             then if allow_consts orelse is_constr thy c'
   532               then ()
   533               else bad (quote c ^ " is not a constructor, on left hand side of equation")
   534             else bad ("Partially applied constant " ^ quote c ^ " on left hand side of equation")
   535           end else bad ("Pattern not allowed here, but constant " ^ quote c ^ " encountered on left hand side")
   536     val _ = map (check 0) args;
   537     val _ = if allow_nonlinear orelse is_linear thm then ()
   538       else bad "Duplicate variables on left hand side of equation";
   539     val _ = if (is_none o AxClass.class_of_param thy) c then ()
   540       else bad "Overloaded constant as head in equation";
   541     val _ = if not (is_constr thy c) then ()
   542       else bad "Constructor as head in equation";
   543     val _ = if not (is_abstr thy c) then ()
   544       else bad "Abstractor as head in equation";
   545     val _ = check_decl_ty thy (c, ty);
   546   in () end;
   547 
   548 fun gen_assert_eqn thy check_patterns (thm, proper) =
   549   let
   550     fun bad s = bad_thm (s ^ ":\n" ^ Display.string_of_thm_global thy thm);
   551     val (lhs, rhs) = (Logic.dest_equals o Thm.plain_prop_of) thm
   552       handle TERM _ => bad "Not an equation"
   553            | THM _ => bad "Not a proper equation";
   554     val _ = check_eqn thy { allow_nonlinear = not proper,
   555       allow_consts = not (proper andalso check_patterns), allow_pats = true } thm (lhs, rhs);
   556   in (thm, proper) end;
   557 
   558 fun assert_abs_eqn thy some_tyco thm =
   559   let
   560     fun bad s = bad_thm (s ^ ":\n" ^ Display.string_of_thm_global thy thm);
   561     val (full_lhs, rhs) = (Logic.dest_equals o Thm.plain_prop_of) thm
   562       handle TERM _ => bad "Not an equation"
   563            | THM _ => bad "Not a proper equation";
   564     val (rep, lhs) = dest_comb full_lhs
   565       handle TERM _ => bad "Not an abstract equation";
   566     val (rep_const, ty) = dest_Const rep;
   567     val (tyco, Ts) = (dest_Type o domain_type) ty
   568       handle TERM _ => bad "Not an abstract equation"
   569            | TYPE _ => bad "Not an abstract equation";
   570     val _ = case some_tyco of SOME tyco' => if tyco = tyco' then ()
   571           else bad ("Abstract type mismatch:" ^ quote tyco ^ " vs. " ^ quote tyco')
   572       | NONE => ();
   573     val (vs', (_, (rep', _))) = get_abstype_spec thy tyco;
   574     val _ = if rep_const = rep' then ()
   575       else bad ("Projection mismatch: " ^ quote rep_const ^ " vs. " ^ quote rep');
   576     val _ = check_eqn thy { allow_nonlinear = false,
   577       allow_consts = false, allow_pats = false } thm (lhs, rhs);
   578     val _ = if forall2 (fn T => fn (_, sort) => Sign.of_sort thy (T, sort)) Ts vs' then ()
   579       else error ("Type arguments do not satisfy sort constraints of abstype certificate.");
   580   in (thm, tyco) end;
   581 
   582 fun assert_eqn thy = error_thm (gen_assert_eqn thy true);
   583 
   584 fun meta_rewrite thy = Local_Defs.meta_rewrite_rule (Proof_Context.init_global thy);
   585 
   586 fun mk_eqn thy = error_thm (gen_assert_eqn thy false) o
   587   apfst (meta_rewrite thy);
   588 
   589 fun mk_eqn_warning thy = Option.map (fn (thm, _) => (thm, is_linear thm))
   590   o warning_thm (gen_assert_eqn thy false) o rpair false o meta_rewrite thy;
   591 
   592 fun mk_eqn_liberal thy = Option.map (fn (thm, _) => (thm, is_linear thm))
   593   o try_thm (gen_assert_eqn thy false) o rpair false o meta_rewrite thy;
   594 
   595 fun mk_abs_eqn thy = error_thm (assert_abs_eqn thy NONE) o meta_rewrite thy;
   596 
   597 val head_eqn = dest_Const o fst o strip_comb o fst o Logic.dest_equals o Thm.plain_prop_of;
   598 
   599 fun const_typ_eqn thy thm =
   600   let
   601     val (c, ty) = head_eqn thm;
   602     val c' = AxClass.unoverload_const thy (c, ty);
   603       (*permissive wrt. to overloaded constants!*)
   604   in (c', ty) end;
   605 
   606 fun const_eqn thy = fst o const_typ_eqn thy;
   607 
   608 fun const_abs_eqn thy = AxClass.unoverload_const thy o dest_Const o fst o strip_comb o snd
   609   o dest_comb o fst o Logic.dest_equals o Thm.plain_prop_of;
   610 
   611 fun mk_proj tyco vs ty abs rep =
   612   let
   613     val ty_abs = Type (tyco, map TFree vs);
   614     val xarg = Var (("x", 0), ty);
   615   in Logic.mk_equals (Const (rep, ty_abs --> ty) $ (Const (abs, ty --> ty_abs) $ xarg), xarg) end;
   616 
   617 
   618 (* technical transformations of code equations *)
   619 
   620 fun expand_eta thy k thm =
   621   let
   622     val (lhs, rhs) = (Logic.dest_equals o Thm.plain_prop_of) thm;
   623     val (_, args) = strip_comb lhs;
   624     val l = if k = ~1
   625       then (length o fst o strip_abs) rhs
   626       else Int.max (0, k - length args);
   627     val (raw_vars, _) = Term.strip_abs_eta l rhs;
   628     val vars = burrow_fst (Name.variant_list (map (fst o fst) (Term.add_vars lhs [])))
   629       raw_vars;
   630     fun expand (v, ty) thm = Drule.fun_cong_rule thm
   631       (Thm.cterm_of thy (Var ((v, 0), ty)));
   632   in
   633     thm
   634     |> fold expand vars
   635     |> Conv.fconv_rule Drule.beta_eta_conversion
   636   end;
   637 
   638 fun same_arity thy thms =
   639   let
   640     val num_args_of = length o snd o strip_comb o fst o Logic.dest_equals;
   641     val k = fold (Integer.max o num_args_of o Thm.prop_of) thms 0;
   642   in map (expand_eta thy k) thms end;
   643 
   644 fun mk_desymbolization pre post mk vs =
   645   let
   646     val names = map (pre o fst o fst) vs
   647       |> map (Name.desymbolize false)
   648       |> Name.variant_list []
   649       |> map post;
   650   in map_filter (fn (((v, i), x), v') =>
   651     if v = v' andalso i = 0 then NONE
   652     else SOME (((v, i), x), mk ((v', 0), x))) (vs ~~ names)
   653   end;
   654 
   655 fun desymbolize_tvars thms =
   656   let
   657     val tvs = fold (Term.add_tvars o Thm.prop_of) thms [];
   658     val tvar_subst = mk_desymbolization (unprefix "'") (prefix "'") TVar tvs;
   659   in map (Thm.certify_instantiate (tvar_subst, [])) thms end;
   660 
   661 fun desymbolize_vars thm =
   662   let
   663     val vs = Term.add_vars (Thm.prop_of thm) [];
   664     val var_subst = mk_desymbolization I I Var vs;
   665   in Thm.certify_instantiate ([], var_subst) thm end;
   666 
   667 fun canonize_thms thy = desymbolize_tvars #> same_arity thy #> map desymbolize_vars;
   668 
   669 
   670 (* abstype certificates *)
   671 
   672 fun check_abstype_cert thy proto_thm =
   673   let
   674     val thm = (AxClass.unoverload thy o meta_rewrite thy) proto_thm;
   675     fun bad s = bad_thm (s ^ ":\n" ^ Display.string_of_thm_global thy thm);
   676     val (lhs, rhs) = Logic.dest_equals (Thm.plain_prop_of thm)
   677       handle TERM _ => bad "Not an equation"
   678            | THM _ => bad "Not a proper equation";
   679     val ((abs, raw_ty), ((rep, rep_ty), param)) = (apsnd (apfst dest_Const o dest_comb)
   680         o apfst dest_Const o dest_comb) lhs
   681       handle TERM _ => bad "Not an abstype certificate";
   682     val _ = pairself (fn c => if (is_some o AxClass.class_of_param thy) c
   683       then error ("Is a class parameter: " ^ string_of_const thy c) else ()) (abs, rep);
   684     val _ = check_decl_ty thy (abs, raw_ty);
   685     val _ = check_decl_ty thy (rep, rep_ty);
   686     val _ = (fst o dest_Var) param
   687       handle TERM _ => bad "Not an abstype certificate";
   688     val _ = if param = rhs then () else bad "Not an abstype certificate";
   689     val ((tyco, sorts), (abs, (vs, ty'))) = analyze_constructor thy (abs, Logic.unvarifyT_global raw_ty);
   690     val ty = domain_type ty';
   691     val (vs', _) = logical_typscheme thy (abs, ty');
   692   in (tyco, (vs ~~ sorts, ((abs, (vs', ty)), (rep, thm)))) end;
   693 
   694 
   695 (* code equation certificates *)
   696 
   697 fun build_head thy (c, ty) =
   698   Thm.cterm_of thy (Logic.mk_equals (Free ("HEAD", ty), Const (c, ty)));
   699 
   700 fun get_head thy cert_thm =
   701   let
   702     val [head] = (#hyps o Thm.crep_thm) cert_thm;
   703     val (_, Const (c, ty)) = (Logic.dest_equals o Thm.term_of) head;
   704   in (typscheme thy (c, ty), head) end;
   705 
   706 fun typscheme_projection thy =
   707   typscheme thy o dest_Const o fst o dest_comb o fst o Logic.dest_equals;
   708 
   709 fun typscheme_abs thy =
   710   typscheme thy o dest_Const o fst o strip_comb o snd o dest_comb o fst o Logic.dest_equals o Thm.prop_of;
   711 
   712 fun constrain_thm thy vs sorts thm =
   713   let
   714     val mapping = map2 (fn (v, sort) => fn sort' =>
   715       (v, Sorts.inter_sort (Sign.classes_of thy) (sort, sort'))) vs sorts;
   716     val inst = map2 (fn (v, sort) => fn (_, sort') =>
   717       (((v, 0), sort), TFree (v, sort'))) vs mapping;
   718     val subst = (map_types o map_type_tfree)
   719       (fn (v, _) => TFree (v, the (AList.lookup (op =) mapping v)));
   720   in
   721     thm
   722     |> Thm.varifyT_global
   723     |> Thm.certify_instantiate (inst, [])
   724     |> pair subst
   725   end;
   726 
   727 fun concretify_abs thy tyco abs_thm =
   728   let
   729     val (_, ((c, _), (_, cert))) = get_abstype_spec thy tyco;
   730     val lhs = (fst o Logic.dest_equals o Thm.prop_of) abs_thm
   731     val ty = fastype_of lhs;
   732     val ty_abs = (fastype_of o snd o dest_comb) lhs;
   733     val abs = Thm.cterm_of thy (Const (c, ty --> ty_abs));
   734     val raw_concrete_thm = Drule.transitive_thm OF [Thm.symmetric cert, Thm.combination (Thm.reflexive abs) abs_thm];
   735   in (c, (Thm.varifyT_global o zero_var_indexes) raw_concrete_thm) end;
   736 
   737 fun add_rhss_of_eqn thy t =
   738   let
   739     val (args, rhs) = (apfst (snd o strip_comb) o Logic.dest_equals o subst_signatures thy) t;
   740     fun add_const (Const (c, ty)) = insert (op =) (c, Sign.const_typargs thy (c, ty))
   741       | add_const _ = I
   742     val add_consts = fold_aterms add_const
   743   in add_consts rhs o fold add_consts args end;
   744 
   745 fun dest_eqn thy =
   746   apfst (snd o strip_comb) o Logic.dest_equals o subst_signatures thy o Logic.unvarify_global;
   747 
   748 abstype cert = Equations of thm * bool list
   749   | Projection of term * string
   750   | Abstract of thm * string
   751 with
   752 
   753 fun empty_cert thy c = 
   754   let
   755     val raw_ty = Logic.unvarifyT_global (const_typ thy c);
   756     val (vs, _) = logical_typscheme thy (c, raw_ty);
   757     val sortargs = case AxClass.class_of_param thy c
   758      of SOME class => [[class]]
   759       | NONE => (case get_type_of_constr_or_abstr thy c
   760          of SOME (tyco, _) => (map snd o fst o the)
   761               (AList.lookup (op =) ((snd o fst o get_type thy) tyco) c)
   762           | NONE => replicate (length vs) []);
   763     val the_sort = the o AList.lookup (op =) (map fst vs ~~ sortargs);
   764     val ty = map_type_tfree (fn (v, _) => TFree (v, the_sort v)) raw_ty
   765     val chead = build_head thy (c, ty);
   766   in Equations (Thm.weaken chead Drule.dummy_thm, []) end;
   767 
   768 fun cert_of_eqns thy c [] = empty_cert thy c
   769   | cert_of_eqns thy c raw_eqns = 
   770       let
   771         val eqns = burrow_fst (canonize_thms thy) raw_eqns;
   772         val _ = map (assert_eqn thy) eqns;
   773         val (thms, propers) = split_list eqns;
   774         val _ = map (fn thm => if c = const_eqn thy thm then ()
   775           else error ("Wrong head of code equation,\nexpected constant "
   776             ^ string_of_const thy c ^ "\n" ^ Display.string_of_thm_global thy thm)) thms;
   777         fun tvars_of T = rev (Term.add_tvarsT T []);
   778         val vss = map (tvars_of o snd o head_eqn) thms;
   779         fun inter_sorts vs =
   780           fold (curry (Sorts.inter_sort (Sign.classes_of thy)) o snd) vs [];
   781         val sorts = map_transpose inter_sorts vss;
   782         val vts = Name.names Name.context Name.aT sorts;
   783         val thms' =
   784           map2 (fn vs => Thm.certify_instantiate (vs ~~ map TFree vts, [])) vss thms;
   785         val head_thm = Thm.symmetric (Thm.assume (build_head thy (head_eqn (hd thms'))));
   786         fun head_conv ct = if can Thm.dest_comb ct
   787           then Conv.fun_conv head_conv ct
   788           else Conv.rewr_conv head_thm ct;
   789         val rewrite_head = Conv.fconv_rule (Conv.arg1_conv head_conv);
   790         val cert_thm = Conjunction.intr_balanced (map rewrite_head thms');
   791       in Equations (cert_thm, propers) end;
   792 
   793 fun cert_of_proj thy c tyco =
   794   let
   795     val (vs, ((abs, (_, ty)), (rep, _))) = get_abstype_spec thy tyco;
   796     val _ = if c = rep then () else
   797       error ("Wrong head of projection,\nexpected constant " ^ string_of_const thy rep);
   798   in Projection (mk_proj tyco vs ty abs rep, tyco) end;
   799 
   800 fun cert_of_abs thy tyco c raw_abs_thm =
   801   let
   802     val abs_thm = singleton (canonize_thms thy) raw_abs_thm;
   803     val _ = assert_abs_eqn thy (SOME tyco) abs_thm;
   804     val _ = if c = const_abs_eqn thy abs_thm then ()
   805       else error ("Wrong head of abstract code equation,\nexpected constant "
   806         ^ string_of_const thy c ^ "\n" ^ Display.string_of_thm_global thy abs_thm);
   807   in Abstract (Thm.legacy_freezeT abs_thm, tyco) end;
   808 
   809 fun constrain_cert thy sorts (Equations (cert_thm, propers)) =
   810       let
   811         val ((vs, _), head) = get_head thy cert_thm;
   812         val (subst, cert_thm') = cert_thm
   813           |> Thm.implies_intr head
   814           |> constrain_thm thy vs sorts;
   815         val head' = Thm.term_of head
   816           |> subst
   817           |> Thm.cterm_of thy;
   818         val cert_thm'' = cert_thm'
   819           |> Thm.elim_implies (Thm.assume head');
   820       in Equations (cert_thm'', propers) end
   821   | constrain_cert thy _ (cert as Projection _) =
   822       cert
   823   | constrain_cert thy sorts (Abstract (abs_thm, tyco)) =
   824       Abstract (snd (constrain_thm thy (fst (typscheme_abs thy abs_thm)) sorts abs_thm), tyco);
   825 
   826 fun typscheme_of_cert thy (Equations (cert_thm, _)) =
   827       fst (get_head thy cert_thm)
   828   | typscheme_of_cert thy (Projection (proj, _)) =
   829       typscheme_projection thy proj
   830   | typscheme_of_cert thy (Abstract (abs_thm, _)) =
   831       typscheme_abs thy abs_thm;
   832 
   833 fun typargs_deps_of_cert thy (Equations (cert_thm, propers)) =
   834       let
   835         val vs = (fst o fst) (get_head thy cert_thm);
   836         val equations = if null propers then [] else
   837           Thm.prop_of cert_thm
   838           |> Logic.dest_conjunction_balanced (length propers);
   839       in (vs, fold (add_rhss_of_eqn thy) equations []) end
   840   | typargs_deps_of_cert thy (Projection (t, _)) =
   841       (fst (typscheme_projection thy t), add_rhss_of_eqn thy t [])
   842   | typargs_deps_of_cert thy (Abstract (abs_thm, tyco)) =
   843       let
   844         val vs = fst (typscheme_abs thy abs_thm);
   845         val (_, concrete_thm) = concretify_abs thy tyco abs_thm;
   846       in (vs, add_rhss_of_eqn thy (map_types Logic.unvarifyT_global (Thm.prop_of concrete_thm)) []) end;
   847 
   848 fun equations_of_cert thy (cert as Equations (cert_thm, propers)) =
   849       let
   850         val tyscm = typscheme_of_cert thy cert;
   851         val thms = if null propers then [] else
   852           cert_thm
   853           |> Local_Defs.expand [snd (get_head thy cert_thm)]
   854           |> Thm.varifyT_global
   855           |> Conjunction.elim_balanced (length propers);
   856         fun abstractions (args, rhs) = (map (rpair NONE) args, (rhs, NONE));
   857       in (tyscm, map (abstractions o dest_eqn thy o Thm.prop_of) thms ~~ (map SOME thms ~~ propers)) end
   858   | equations_of_cert thy (Projection (t, tyco)) =
   859       let
   860         val (_, ((abs, _), _)) = get_abstype_spec thy tyco;
   861         val tyscm = typscheme_projection thy t;
   862         val t' = map_types Logic.varifyT_global t;
   863         fun abstractions (args, rhs) = (map (rpair (SOME abs)) args, (rhs, NONE));
   864       in (tyscm, [((abstractions o dest_eqn thy) t', (NONE, true))]) end
   865   | equations_of_cert thy (Abstract (abs_thm, tyco)) =
   866       let
   867         val tyscm = typscheme_abs thy abs_thm;
   868         val (abs, concrete_thm) = concretify_abs thy tyco abs_thm;
   869         fun abstractions (args, rhs) = (map (rpair NONE) args, (rhs, (SOME abs)));
   870       in
   871         (tyscm, [((abstractions o dest_eqn thy o Thm.prop_of) concrete_thm,
   872           (SOME (Thm.varifyT_global abs_thm), true))])
   873       end;
   874 
   875 fun pretty_cert thy (cert as Equations _) =
   876       (map_filter (Option.map (Display.pretty_thm_global thy o AxClass.overload thy) o fst o snd)
   877          o snd o equations_of_cert thy) cert
   878   | pretty_cert thy (Projection (t, _)) =
   879       [Syntax.pretty_term_global thy (map_types Logic.varifyT_global t)]
   880   | pretty_cert thy (Abstract (abs_thm, _)) =
   881       [(Display.pretty_thm_global thy o AxClass.overload thy o Thm.varifyT_global) abs_thm];
   882 
   883 fun bare_thms_of_cert thy (cert as Equations _) =
   884       (map_filter (fn (_, (some_thm, proper)) => if proper then some_thm else NONE)
   885         o snd o equations_of_cert thy) cert
   886   | bare_thms_of_cert thy (Projection _) = []
   887   | bare_thms_of_cert thy (Abstract (abs_thm, tyco)) =
   888       [Thm.varifyT_global (snd (concretify_abs thy tyco abs_thm))];
   889 
   890 end;
   891 
   892 
   893 (* code certificate access *)
   894 
   895 fun retrieve_raw thy c =
   896   Symtab.lookup ((the_functions o the_exec) thy) c
   897   |> Option.map (snd o fst)
   898   |> the_default empty_fun_spec
   899 
   900 fun get_cert thy f c = case retrieve_raw thy c
   901  of Default (_, eqns_lazy) => Lazy.force eqns_lazy
   902       |> (map o apfst) (Thm.transfer thy)
   903       |> f
   904       |> (map o apfst) (AxClass.unoverload thy)
   905       |> cert_of_eqns thy c
   906   | Eqns eqns => eqns
   907       |> (map o apfst) (Thm.transfer thy)
   908       |> f
   909       |> (map o apfst) (AxClass.unoverload thy)
   910       |> cert_of_eqns thy c
   911   | Proj (_, tyco) =>
   912       cert_of_proj thy c tyco
   913   | Abstr (abs_thm, tyco) => abs_thm
   914       |> Thm.transfer thy
   915       |> AxClass.unoverload thy
   916       |> cert_of_abs thy tyco c;
   917 
   918 
   919 (* cases *)
   920 
   921 fun case_certificate thm =
   922   let
   923     val ((head, raw_case_expr), cases) = (apfst Logic.dest_equals
   924       o apsnd Logic.dest_conjunctions o Logic.dest_implies o Thm.plain_prop_of) thm;
   925     val _ = case head of Free _ => true
   926       | Var _ => true
   927       | _ => raise TERM ("case_cert", []);
   928     val ([(case_var, _)], case_expr) = Term.strip_abs_eta 1 raw_case_expr;
   929     val (Const (case_const, _), raw_params) = strip_comb case_expr;
   930     val n = find_index (fn Free (v, _) => v = case_var | _ => false) raw_params;
   931     val _ = if n = ~1 then raise TERM ("case_cert", []) else ();
   932     val params = map (fst o dest_Var) (nth_drop n raw_params);
   933     fun dest_case t =
   934       let
   935         val (head' $ t_co, rhs) = Logic.dest_equals t;
   936         val _ = if head' = head then () else raise TERM ("case_cert", []);
   937         val (Const (co, _), args) = strip_comb t_co;
   938         val (Var (param, _), args') = strip_comb rhs;
   939         val _ = if args' = args then () else raise TERM ("case_cert", []);
   940       in (param, co) end;
   941     fun analyze_cases cases =
   942       let
   943         val co_list = fold (AList.update (op =) o dest_case) cases [];
   944       in map (the o AList.lookup (op =) co_list) params end;
   945     fun analyze_let t =
   946       let
   947         val (head' $ arg, Var (param', _) $ arg') = Logic.dest_equals t;
   948         val _ = if head' = head then () else raise TERM ("case_cert", []);
   949         val _ = if arg' = arg then () else raise TERM ("case_cert", []);
   950         val _ = if [param'] = params then () else raise TERM ("case_cert", []);
   951       in [] end;
   952     fun analyze (cases as [let_case]) =
   953           (analyze_cases cases handle Bind => analyze_let let_case)
   954       | analyze cases = analyze_cases cases;
   955   in (case_const, (n, analyze cases)) end;
   956 
   957 fun case_cert thm = case_certificate thm
   958   handle Bind => error "bad case certificate"
   959        | TERM _ => error "bad case certificate";
   960 
   961 fun get_case_scheme thy = Option.map fst o Symtab.lookup ((fst o the_cases o the_exec) thy);
   962 fun get_case_cong thy = Option.map snd o Symtab.lookup ((fst o the_cases o the_exec) thy);
   963 
   964 val undefineds = Symtab.keys o snd o the_cases o the_exec;
   965 
   966 
   967 (* diagnostic *)
   968 
   969 fun print_codesetup thy =
   970   let
   971     val ctxt = Proof_Context.init_global thy;
   972     val exec = the_exec thy;
   973     fun pretty_equations const thms =
   974       (Pretty.block o Pretty.fbreaks) (
   975         Pretty.str (string_of_const thy const) :: map (Display.pretty_thm ctxt) thms
   976       );
   977     fun pretty_function (const, Default (_, eqns_lazy)) = pretty_equations const (map fst (Lazy.force eqns_lazy))
   978       | pretty_function (const, Eqns eqns) = pretty_equations const (map fst eqns)
   979       | pretty_function (const, Proj (proj, _)) = Pretty.block
   980           [Pretty.str (string_of_const thy const), Pretty.fbrk, Syntax.pretty_term ctxt proj]
   981       | pretty_function (const, Abstr (thm, _)) = pretty_equations const [thm];
   982     fun pretty_typ (tyco, vs) = Pretty.str
   983       (string_of_typ thy (Type (tyco, map TFree vs)));
   984     fun pretty_typspec (typ, (cos, abstract)) = if null cos
   985       then pretty_typ typ
   986       else (Pretty.block o Pretty.breaks) (
   987         pretty_typ typ
   988         :: Pretty.str "="
   989         :: (if abstract then [Pretty.str "(abstract)"] else [])
   990         @ separate (Pretty.str "|") (map (fn (c, (_, [])) => Pretty.str (string_of_const thy c)
   991              | (c, (_, tys)) =>
   992                  (Pretty.block o Pretty.breaks)
   993                     (Pretty.str (string_of_const thy c)
   994                       :: Pretty.str "of"
   995                       :: map (Pretty.quote o Syntax.pretty_typ_global thy) tys)) cos)
   996       );
   997     fun pretty_case (const, ((_, (_, [])), _)) = Pretty.str (string_of_const thy const)
   998       | pretty_case (const, ((_, (_, cos)), _)) = (Pretty.block o Pretty.breaks) [
   999           Pretty.str (string_of_const thy const), Pretty.str "with",
  1000           (Pretty.block o Pretty.commas o map (Pretty.str o string_of_const thy)) cos];
  1001     val functions = the_functions exec
  1002       |> Symtab.dest
  1003       |> (map o apsnd) (snd o fst)
  1004       |> sort (string_ord o pairself fst);
  1005     val datatypes = the_types exec
  1006       |> Symtab.dest
  1007       |> map (fn (tyco, (_, (vs, spec)) :: _) =>
  1008           ((tyco, vs), constructors_of spec))
  1009       |> sort (string_ord o pairself (fst o fst));
  1010     val cases = Symtab.dest ((fst o the_cases o the_exec) thy);
  1011     val undefineds = Symtab.keys ((snd o the_cases o the_exec) thy);
  1012   in
  1013     (Pretty.writeln o Pretty.chunks) [
  1014       Pretty.block (
  1015         Pretty.str "code equations:" :: Pretty.fbrk
  1016         :: (Pretty.fbreaks o map pretty_function) functions
  1017       ),
  1018       Pretty.block (
  1019         Pretty.str "datatypes:" :: Pretty.fbrk
  1020         :: (Pretty.fbreaks o map pretty_typspec) datatypes
  1021       ),
  1022       Pretty.block (
  1023         Pretty.str "cases:" :: Pretty.fbrk
  1024         :: (Pretty.fbreaks o map pretty_case) cases
  1025       ),
  1026       Pretty.block (
  1027         Pretty.str "undefined:" :: Pretty.fbrk
  1028         :: (Pretty.commas o map (Pretty.str o string_of_const thy)) undefineds
  1029       )
  1030     ]
  1031   end;
  1032 
  1033 
  1034 (** declaring executable ingredients **)
  1035 
  1036 (* constant signatures *)
  1037 
  1038 fun add_type tyco thy =
  1039   case Symtab.lookup ((snd o #types o Type.rep_tsig o Sign.tsig_of) thy) tyco
  1040    of SOME (Type.Abbreviation (vs, _, _)) =>
  1041           (map_exec_purge o map_signatures o apfst)
  1042             (Symtab.update (tyco, length vs)) thy
  1043     | _ => error ("No such type abbreviation: " ^ quote tyco);
  1044 
  1045 fun add_type_cmd s thy = add_type (Sign.intern_type thy s) thy;
  1046 
  1047 fun gen_add_signature prep_const prep_signature (raw_c, raw_ty) thy =
  1048   let
  1049     val c = prep_const thy raw_c;
  1050     val ty = prep_signature thy raw_ty;
  1051     val ty' = expand_signature thy ty;
  1052     val ty'' = Sign.the_const_type thy c;
  1053     val _ = if typ_equiv (ty', ty'') then () else
  1054       error ("Illegal constant signature: " ^ Syntax.string_of_typ_global thy ty);
  1055   in
  1056     thy
  1057     |> (map_exec_purge o map_signatures o apsnd) (Symtab.update (c, ty))
  1058   end;
  1059 
  1060 val add_signature = gen_add_signature (K I) cert_signature;
  1061 val add_signature_cmd = gen_add_signature read_const read_signature;
  1062 
  1063 
  1064 (* code equations *)
  1065 
  1066 fun gen_add_eqn default (raw_thm, proper) thy =
  1067   let
  1068     val thm = Thm.close_derivation raw_thm;
  1069     val c = const_eqn thy thm;
  1070     fun update_subsume thy (thm, proper) eqns = 
  1071       let
  1072         val args_of = snd o chop_while is_Var o rev o snd o strip_comb
  1073           o map_types Type.strip_sorts o fst o Logic.dest_equals o Thm.plain_prop_of;
  1074         val args = args_of thm;
  1075         val incr_idx = Logic.incr_indexes ([], Thm.maxidx_of thm + 1);
  1076         fun matches_args args' =
  1077           let
  1078             val k = length args' - length args
  1079           in if k >= 0
  1080             then Pattern.matchess thy (args, (map incr_idx o drop k) args')
  1081             else false
  1082           end;
  1083         fun drop (thm', proper') = if (proper orelse not proper')
  1084           andalso matches_args (args_of thm') then 
  1085             (warning ("Code generator: dropping subsumed code equation\n" ^
  1086                 Display.string_of_thm_global thy thm'); true)
  1087           else false;
  1088       in (thm, proper) :: filter_out drop eqns end;
  1089     fun natural_order thy_ref eqns =
  1090       (eqns, Lazy.lazy (fn () => fold (update_subsume (Theory.deref thy_ref)) eqns []))
  1091     fun add_eqn' true (Default (eqns, _)) =
  1092           Default (natural_order (Theory.check_thy thy) ((thm, proper) :: eqns))
  1093           (*this restores the natural order and drops syntactic redundancies*)
  1094       | add_eqn' true fun_spec = fun_spec
  1095       | add_eqn' false (Eqns eqns) = Eqns (update_subsume thy (thm, proper) eqns)
  1096       | add_eqn' false _ = Eqns [(thm, proper)];
  1097   in change_fun_spec false c (add_eqn' default) thy end;
  1098 
  1099 fun add_eqn thm thy =
  1100   gen_add_eqn false (mk_eqn thy (thm, true)) thy;
  1101 
  1102 fun add_warning_eqn thm thy =
  1103   case mk_eqn_warning thy thm
  1104    of SOME eqn => gen_add_eqn false eqn thy
  1105     | NONE => thy;
  1106 
  1107 fun add_nbe_eqn thm thy =
  1108   gen_add_eqn false (mk_eqn thy (thm, false)) thy;
  1109 
  1110 fun add_default_eqn thm thy =
  1111   case mk_eqn_liberal thy thm
  1112    of SOME eqn => gen_add_eqn true eqn thy
  1113     | NONE => thy;
  1114 
  1115 val add_default_eqn_attribute = Thm.declaration_attribute
  1116   (fn thm => Context.mapping (add_default_eqn thm) I);
  1117 val add_default_eqn_attrib = Attrib.internal (K add_default_eqn_attribute);
  1118 
  1119 fun add_nbe_default_eqn thm thy =
  1120   gen_add_eqn true (mk_eqn thy (thm, false)) thy;
  1121 
  1122 val add_nbe_default_eqn_attribute = Thm.declaration_attribute
  1123   (fn thm => Context.mapping (add_nbe_default_eqn thm) I);
  1124 val add_nbe_default_eqn_attrib = Attrib.internal (K add_nbe_default_eqn_attribute);
  1125 
  1126 fun add_abs_eqn raw_thm thy =
  1127   let
  1128     val (abs_thm, tyco) = (apfst Thm.close_derivation o mk_abs_eqn thy) raw_thm;
  1129     val c = const_abs_eqn thy abs_thm;
  1130   in change_fun_spec false c (K (Abstr (abs_thm, tyco))) thy end;
  1131 
  1132 fun del_eqn thm thy = case mk_eqn_liberal thy thm
  1133  of SOME (thm, _) => let
  1134         fun del_eqn' (Default _) = empty_fun_spec
  1135           | del_eqn' (Eqns eqns) =
  1136               Eqns (filter_out (fn (thm', _) => Thm.eq_thm_prop (thm, thm')) eqns)
  1137           | del_eqn' spec = spec
  1138       in change_fun_spec true (const_eqn thy thm) del_eqn' thy end
  1139   | NONE => thy;
  1140 
  1141 fun del_eqns c = change_fun_spec true c (K empty_fun_spec);
  1142 
  1143 
  1144 (* cases *)
  1145 
  1146 fun case_cong thy case_const (num_args, (pos, _)) =
  1147   let
  1148     val ([x, y], ctxt) = Name.variants ["A", "A'"] Name.context;
  1149     val (zs, _) = Name.variants (replicate (num_args - 1) "") ctxt;
  1150     val (ws, vs) = chop pos zs;
  1151     val T = Logic.unvarifyT_global (Sign.the_const_type thy case_const);
  1152     val Ts = binder_types T;
  1153     val T_cong = nth Ts pos;
  1154     fun mk_prem z = Free (z, T_cong);
  1155     fun mk_concl z = list_comb (Const (case_const, T), map2 (curry Free) (ws @ z :: vs) Ts);
  1156     val (prem, concl) = pairself Logic.mk_equals (pairself mk_prem (x, y), pairself mk_concl (x, y));
  1157     fun tac { context, prems } = Simplifier.rewrite_goals_tac prems
  1158       THEN ALLGOALS (Proof_Context.fact_tac [Drule.reflexive_thm]);
  1159   in Skip_Proof.prove_global thy (x :: y :: zs) [prem] concl tac end;
  1160 
  1161 fun add_case thm thy =
  1162   let
  1163     val (case_const, (k, case_pats)) = case_cert thm;
  1164     val _ = case filter_out (is_constr thy) case_pats
  1165      of [] => ()
  1166       | cs => error ("Non-constructor(s) in case certificate: " ^ commas (map quote cs));
  1167     val entry = (1 + Int.max (1, length case_pats), (k, case_pats));
  1168   in
  1169     thy
  1170     |> Theory.checkpoint
  1171     |> `(fn thy => case_cong thy case_const entry)
  1172     |-> (fn cong => (map_exec_purge o map_cases o apfst) (Symtab.update (case_const, (entry, cong))))
  1173   end;
  1174 
  1175 fun add_undefined c thy =
  1176   (map_exec_purge o map_cases o apsnd) (Symtab.update (c, ())) thy;
  1177 
  1178 
  1179 (* types *)
  1180 
  1181 fun register_type (tyco, vs_spec) thy =
  1182   let
  1183     val (old_constrs, some_old_proj) =
  1184       case these (Symtab.lookup ((the_types o the_exec) thy) tyco)
  1185        of (_, (_, Constructors cos)) :: _ => (map fst cos, NONE)
  1186         | (_, (_, Abstractor ((co, _), (proj, _)))) :: _ => ([co], SOME proj)
  1187         | [] => ([], NONE)
  1188     val outdated_funs = case some_old_proj
  1189      of NONE => old_constrs
  1190       | SOME old_proj => Symtab.fold
  1191           (fn (c, ((_, spec), _)) =>
  1192             if member (op =) (the_list (associated_abstype spec)) tyco
  1193             then insert (op =) c else I)
  1194             ((the_functions o the_exec) thy) (old_proj :: old_constrs);
  1195     fun drop_outdated_cases cases = fold Symtab.delete_safe
  1196       (Symtab.fold (fn (c, ((_, (_, cos)), _)) =>
  1197         if exists (member (op =) old_constrs) cos
  1198           then insert (op =) c else I) cases []) cases;
  1199   in
  1200     thy
  1201     |> fold del_eqns outdated_funs
  1202     |> map_exec_purge
  1203         ((map_typs o Symtab.map_default (tyco, [])) (cons (serial (), vs_spec))
  1204         #> (map_cases o apfst) drop_outdated_cases)
  1205   end;
  1206 
  1207 fun unoverload_const_typ thy (c, ty) = (AxClass.unoverload_const thy (c, ty), ty);
  1208 
  1209 structure Datatype_Interpretation =
  1210   Interpretation(type T = string * serial val eq = eq_snd (op =) : T * T -> bool);
  1211 
  1212 fun datatype_interpretation f = Datatype_Interpretation.interpretation
  1213   (fn (tyco, _) => fn thy => f (tyco, fst (get_type thy tyco)) thy);
  1214 
  1215 fun add_datatype proto_constrs thy =
  1216   let
  1217     val constrs = map (unoverload_const_typ thy) proto_constrs;
  1218     val (tyco, (vs, cos)) = constrset_of_consts thy constrs;
  1219   in
  1220     thy
  1221     |> fold (del_eqns o fst) constrs
  1222     |> register_type (tyco, (vs, Constructors cos))
  1223     |> Datatype_Interpretation.data (tyco, serial ())
  1224   end;
  1225 
  1226 fun add_datatype_cmd raw_constrs thy =
  1227   add_datatype (map (read_bare_const thy) raw_constrs) thy;
  1228 
  1229 structure Abstype_Interpretation =
  1230   Interpretation(type T = string * serial val eq = eq_snd (op =) : T * T -> bool);
  1231 
  1232 fun abstype_interpretation f = Abstype_Interpretation.interpretation
  1233   (fn (tyco, _) => fn thy => f (tyco, get_abstype_spec thy tyco) thy);
  1234 
  1235 fun add_abstype proto_thm thy =
  1236   let
  1237     val (tyco, (vs, (abs_ty as (abs, (_, ty)), (rep, cert)))) =
  1238       error_thm (check_abstype_cert thy) proto_thm;
  1239   in
  1240     thy
  1241     |> del_eqns abs
  1242     |> register_type (tyco, (vs, Abstractor (abs_ty, (rep, cert))))
  1243     |> change_fun_spec false rep ((K o Proj)
  1244         (map_types Logic.varifyT_global (mk_proj tyco vs ty abs rep), tyco))
  1245     |> Abstype_Interpretation.data (tyco, serial ())
  1246   end;
  1247 
  1248 
  1249 (** infrastructure **)
  1250 
  1251 (* cf. src/HOL/Tools/recfun_codegen.ML *)
  1252 
  1253 structure Code_Target_Attr = Theory_Data
  1254 (
  1255   type T = (string -> thm -> theory -> theory) option;
  1256   val empty = NONE;
  1257   val extend = I;
  1258   val merge = merge_options;
  1259 );
  1260 
  1261 fun set_code_target_attr f = Code_Target_Attr.map (K (SOME f));
  1262 
  1263 fun code_target_attr prefix thm thy =
  1264   let
  1265     val attr = the_default ((K o K) I) (Code_Target_Attr.get thy);
  1266   in thy |> add_warning_eqn thm |> attr prefix thm end;
  1267 
  1268 
  1269 (* setup *)
  1270 
  1271 val _ = Context.>> (Context.map_theory
  1272   (let
  1273     fun mk_attribute f = Thm.declaration_attribute (fn thm => Context.mapping (f thm) I);
  1274     val code_attribute_parser =
  1275       Args.del |-- Scan.succeed (mk_attribute del_eqn)
  1276       || Args.$$$ "nbe" |-- Scan.succeed (mk_attribute add_nbe_eqn)
  1277       || Args.$$$ "abstype" |-- Scan.succeed (mk_attribute add_abstype)
  1278       || Args.$$$ "abstract" |-- Scan.succeed (mk_attribute add_abs_eqn)
  1279       || (Args.$$$ "target" |-- Args.colon |-- Args.name >>
  1280            (mk_attribute o code_target_attr))
  1281       || Scan.succeed (mk_attribute add_warning_eqn);
  1282   in
  1283     Datatype_Interpretation.init
  1284     #> Attrib.setup (Binding.name "code") (Scan.lift code_attribute_parser)
  1285         "declare theorems for code generation"
  1286   end));
  1287 
  1288 end; (*struct*)
  1289 
  1290 
  1291 (* type-safe interfaces for data dependent on executable code *)
  1292 
  1293 functor Code_Data(Data: CODE_DATA_ARGS): CODE_DATA =
  1294 struct
  1295 
  1296 type T = Data.T;
  1297 exception Data of T;
  1298 fun dest (Data x) = x
  1299 
  1300 val kind = Code.declare_data (Data Data.empty);
  1301 
  1302 val data_op = (kind, Data, dest);
  1303 
  1304 fun change_yield (SOME thy) f = Code.change_yield_data data_op thy f
  1305   | change_yield NONE f = f Data.empty
  1306 
  1307 fun change some_thy f = snd (change_yield some_thy (pair () o f));
  1308 
  1309 end;
  1310 
  1311 structure Code : CODE = struct open Code; end;