src/Pure/Isar/obtain.ML
author wenzelm
Fri Apr 27 22:47:30 2012 +0200 (2012-04-27 ago)
changeset 47815 43f677b3ae91
parent 46728 85f8e3932712
child 49660 de49d9b4d7bc
permissions -rw-r--r--
clarified signature;
     1 (*  Title:      Pure/Isar/obtain.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 The 'obtain' and 'guess' language elements -- generalized existence at
     5 the level of proof texts: 'obtain' involves a proof that certain
     6 fixes/assumes may be introduced into the present context; 'guess' is
     7 similar, but derives these elements from the course of reasoning!
     8 
     9   <chain_facts>
    10   obtain x where "A x" <proof> ==
    11 
    12   have "!!thesis. (!!x. A x ==> thesis) ==> thesis"
    13   proof succeed
    14     fix thesis
    15     assume that [intro?]: "!!x. A x ==> thesis"
    16     <chain_facts>
    17     show thesis
    18       apply (insert that)
    19       <proof>
    20   qed
    21   fix x assm <<obtain_export>> "A x"
    22 
    23 
    24   <chain_facts>
    25   guess x <proof body> <proof end> ==
    26 
    27   {
    28     fix thesis
    29     <chain_facts> have "PROP ?guess"
    30       apply magic      -- {* turns goal into "thesis ==> #thesis" *}
    31       <proof body>
    32       apply_end magic  -- {* turns final "(!!x. P x ==> thesis) ==> #thesis" into
    33         "#((!!x. A x ==> thesis) ==> thesis)" which is a finished goal state *}
    34       <proof end>
    35   }
    36   fix x assm <<obtain_export>> "A x"
    37 *)
    38 
    39 signature OBTAIN =
    40 sig
    41   val thatN: string
    42   val obtain: string -> (binding * typ option * mixfix) list ->
    43     (Thm.binding * (term * term list) list) list -> bool -> Proof.state -> Proof.state
    44   val obtain_cmd: string -> (binding * string option * mixfix) list ->
    45     (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    46   val result: (Proof.context -> tactic) -> thm list -> Proof.context ->
    47     ((string * cterm) list * thm list) * Proof.context
    48   val guess: (binding * typ option * mixfix) list -> bool -> Proof.state -> Proof.state
    49   val guess_cmd: (binding * string option * mixfix) list -> bool -> Proof.state -> Proof.state
    50 end;
    51 
    52 structure Obtain: OBTAIN =
    53 struct
    54 
    55 (** obtain_export **)
    56 
    57 (*
    58   [x, A x]
    59      :
    60      B
    61   --------
    62      B
    63 *)
    64 fun eliminate_term ctxt xs tm =
    65   let
    66     val vs = map (dest_Free o Thm.term_of) xs;
    67     val bads = Term.fold_aterms (fn t as Free v =>
    68       if member (op =) vs v then insert (op aconv) t else I | _ => I) tm [];
    69     val _ = null bads orelse
    70       error ("Result contains obtained parameters: " ^
    71         space_implode " " (map (Syntax.string_of_term ctxt) bads));
    72   in tm end;
    73 
    74 fun eliminate fix_ctxt rule xs As thm =
    75   let
    76     val thy = Proof_Context.theory_of fix_ctxt;
    77 
    78     val _ = eliminate_term fix_ctxt xs (Thm.full_prop_of thm);
    79     val _ = Object_Logic.is_judgment thy (Thm.concl_of thm) orelse
    80       error "Conclusion in obtained context must be object-logic judgment";
    81 
    82     val ((_, [thm']), ctxt') = Variable.import true [thm] fix_ctxt;
    83     val prems = Drule.strip_imp_prems (#prop (Thm.crep_thm thm'));
    84   in
    85     ((Drule.implies_elim_list thm' (map Thm.assume prems)
    86         |> Drule.implies_intr_list (map Drule.norm_hhf_cterm As)
    87         |> Drule.forall_intr_list xs)
    88       COMP rule)
    89     |> Drule.implies_intr_list prems
    90     |> singleton (Variable.export ctxt' fix_ctxt)
    91   end;
    92 
    93 fun obtain_export ctxt rule xs _ As =
    94   (eliminate ctxt rule xs As, eliminate_term ctxt xs);
    95 
    96 
    97 
    98 (** obtain **)
    99 
   100 fun bind_judgment ctxt name =
   101   let
   102     val thy = Proof_Context.theory_of ctxt;
   103     val ([x], ctxt') = Proof_Context.add_fixes [(Binding.name name, NONE, NoSyn)] ctxt;
   104     val (t as _ $ Free v) = Object_Logic.fixed_judgment thy x;
   105   in ((v, t), ctxt') end;
   106 
   107 val thatN = "that";
   108 
   109 local
   110 
   111 fun gen_obtain prep_att prep_vars prep_propp
   112     name raw_vars raw_asms int state =
   113   let
   114     val _ = Proof.assert_forward_or_chain state;
   115     val thy = Proof.theory_of state;
   116     val cert = Thm.cterm_of thy;
   117     val ctxt = Proof.context_of state;
   118     val chain_facts = if can Proof.assert_chain state then Proof.the_facts state else [];
   119 
   120     (*obtain vars*)
   121     val (vars, vars_ctxt) = prep_vars raw_vars ctxt;
   122     val (xs', fix_ctxt) = vars_ctxt |> Proof_Context.add_fixes vars;
   123     val xs = map (Variable.check_name o #1) vars;
   124 
   125     (*obtain asms*)
   126     val (proppss, asms_ctxt) = prep_propp (map snd raw_asms) fix_ctxt;
   127     val ((_, bind_ctxt), _) = Proof_Context.bind_propp_i proppss asms_ctxt;
   128     val asm_props = maps (map fst) proppss;
   129     val asms = map fst (Attrib.map_specs (map (prep_att ctxt)) raw_asms) ~~ proppss;
   130 
   131     (*obtain parms*)
   132     val (Ts, parms_ctxt) = fold_map Proof_Context.inferred_param xs' asms_ctxt;
   133     val parms = map Free (xs' ~~ Ts);
   134     val _ = Variable.warn_extra_tfrees fix_ctxt parms_ctxt;
   135 
   136     (*obtain statements*)
   137     val thesisN = singleton (Name.variant_list xs) Auto_Bind.thesisN;
   138     val (thesis_var, thesis) = #1 (bind_judgment fix_ctxt thesisN);
   139 
   140     val that_name = if name = "" then thatN else name;
   141     val that_prop =
   142       Logic.list_rename_params xs
   143         (fold_rev Logic.all parms (Logic.list_implies (asm_props, thesis)));
   144     val obtain_prop =
   145       Logic.list_rename_params [Auto_Bind.thesisN]
   146         (Logic.all (Free thesis_var) (Logic.mk_implies (that_prop, thesis)));
   147 
   148     fun after_qed _ =
   149       Proof.local_qed (NONE, false)
   150       #> `Proof.the_fact #-> (fn rule =>
   151         Proof.fix vars
   152         #> Proof.assm (obtain_export fix_ctxt rule (map cert parms)) asms);
   153   in
   154     state
   155     |> Proof.enter_forward
   156     |> Proof.have NONE (K I) [(Thm.empty_binding, [(obtain_prop, [])])] int
   157     |> Proof.map_context bind_ctxt
   158     |> Proof.proof (SOME Method.succeed_text) |> Seq.hd
   159     |> Proof.fix [(Binding.name thesisN, NONE, NoSyn)]
   160     |> Proof.assume
   161       [((Binding.name that_name, [Context_Rules.intro_query NONE]), [(that_prop, [])])]
   162     |> `Proof.the_facts
   163     ||> Proof.chain_facts chain_facts
   164     ||> Proof.show NONE after_qed [(Thm.empty_binding, [(thesis, [])])] false
   165     |-> Proof.refine_insert
   166   end;
   167 
   168 in
   169 
   170 val obtain = gen_obtain (K I) Proof_Context.cert_vars Proof_Context.cert_propp;
   171 val obtain_cmd = gen_obtain Attrib.attribute_cmd Proof_Context.read_vars Proof_Context.read_propp;
   172 
   173 end;
   174 
   175 
   176 
   177 (** tactical result **)
   178 
   179 fun check_result ctxt thesis th =
   180   (case Thm.prems_of th of
   181     [prem] =>
   182       if Thm.concl_of th aconv thesis andalso
   183         Logic.strip_assums_concl prem aconv thesis then th
   184       else error ("Guessed a different clause:\n" ^ Display.string_of_thm ctxt th)
   185   | [] => error "Goal solved -- nothing guessed"
   186   | _ => error ("Guess split into several cases:\n" ^ Display.string_of_thm ctxt th));
   187 
   188 fun result tac facts ctxt =
   189   let
   190     val thy = Proof_Context.theory_of ctxt;
   191     val cert = Thm.cterm_of thy;
   192 
   193     val ((thesis_var, thesis), thesis_ctxt) = bind_judgment ctxt Auto_Bind.thesisN;
   194     val rule =
   195       (case SINGLE (Method.insert_tac facts 1 THEN tac thesis_ctxt) (Goal.init (cert thesis)) of
   196         NONE => raise THM ("Obtain.result: tactic failed", 0, facts)
   197       | SOME th => check_result ctxt thesis (Raw_Simplifier.norm_hhf (Goal.conclude th)));
   198 
   199     val closed_rule = Thm.forall_intr (cert (Free thesis_var)) rule;
   200     val ((_, [rule']), ctxt') = Variable.import false [closed_rule] ctxt;
   201     val obtain_rule = Thm.forall_elim (cert (Logic.varify_global (Free thesis_var))) rule';
   202     val ((params, stmt), fix_ctxt) = Variable.focus_cterm (Thm.cprem_of obtain_rule 1) ctxt';
   203     val (prems, ctxt'') =
   204       Assumption.add_assms (obtain_export fix_ctxt obtain_rule (map #2 params))
   205         (Drule.strip_imp_prems stmt) fix_ctxt;
   206   in ((params, prems), ctxt'') end;
   207 
   208 
   209 
   210 (** guess **)
   211 
   212 local
   213 
   214 fun unify_params vars thesis_var raw_rule ctxt =
   215   let
   216     val thy = Proof_Context.theory_of ctxt;
   217     val certT = Thm.ctyp_of thy;
   218     val cert = Thm.cterm_of thy;
   219     val string_of_term = Syntax.string_of_term (Config.put show_types true ctxt);
   220 
   221     fun err msg th = error (msg ^ ":\n" ^ Display.string_of_thm ctxt th);
   222 
   223     val maxidx = fold (Term.maxidx_typ o snd o fst) vars ~1;
   224     val rule = Thm.incr_indexes (maxidx + 1) raw_rule;
   225 
   226     val params = Rule_Cases.strip_params (Logic.nth_prem (1, Thm.prop_of rule));
   227     val m = length vars;
   228     val n = length params;
   229     val _ = m <= n orelse err "More variables than parameters in obtained rule" rule;
   230 
   231     fun unify ((x, T), (y, U)) (tyenv, max) = Sign.typ_unify thy (T, U) (tyenv, max)
   232       handle Type.TUNIFY =>
   233         err ("Failed to unify variable " ^
   234           string_of_term (Free (x, Envir.norm_type tyenv T)) ^ " against parameter " ^
   235           string_of_term (Syntax_Trans.mark_boundT (y, Envir.norm_type tyenv U)) ^ " in") rule;
   236     val (tyenv, _) = fold unify (map #1 vars ~~ take m params)
   237       (Vartab.empty, Int.max (maxidx, Thm.maxidx_of rule));
   238     val norm_type = Envir.norm_type tyenv;
   239 
   240     val xs = map (apsnd norm_type o fst) vars;
   241     val ys = map (apsnd norm_type) (drop m params);
   242     val ys' = map Name.internal (Name.variant_list (map fst xs) (map fst ys)) ~~ map #2 ys;
   243     val terms = map (Drule.mk_term o cert o Free) (xs @ ys');
   244 
   245     val instT =
   246       fold (Term.add_tvarsT o #2) params []
   247       |> map (TVar #> (fn T => (certT T, certT (norm_type T))));
   248     val closed_rule = rule
   249       |> Thm.forall_intr (cert (Free thesis_var))
   250       |> Thm.instantiate (instT, []);
   251 
   252     val ((_, rule' :: terms'), ctxt') = Variable.import false (closed_rule :: terms) ctxt;
   253     val vars' =
   254       map (dest_Free o Thm.term_of o Drule.dest_term) terms' ~~
   255       (map snd vars @ replicate (length ys) NoSyn);
   256     val rule'' = Thm.forall_elim (cert (Logic.varify_global (Free thesis_var))) rule';
   257   in ((vars', rule''), ctxt') end;
   258 
   259 fun inferred_type (binding, _, mx) ctxt =
   260   let
   261     val x = Variable.check_name binding;
   262     val (T, ctxt') = Proof_Context.inferred_param x ctxt
   263   in ((x, T, mx), ctxt') end;
   264 
   265 fun polymorphic ctxt vars =
   266   let val Ts = map Logic.dest_type (Variable.polymorphic ctxt (map (Logic.mk_type o #2) vars))
   267   in map2 (fn (x, _, mx) => fn T => ((x, T), mx)) vars Ts end;
   268 
   269 fun gen_guess prep_vars raw_vars int state =
   270   let
   271     val _ = Proof.assert_forward_or_chain state;
   272     val thy = Proof.theory_of state;
   273     val cert = Thm.cterm_of thy;
   274     val ctxt = Proof.context_of state;
   275     val chain_facts = if can Proof.assert_chain state then Proof.the_facts state else [];
   276 
   277     val (thesis_var, thesis) = #1 (bind_judgment ctxt Auto_Bind.thesisN);
   278     val vars = ctxt |> prep_vars raw_vars |-> fold_map inferred_type |> fst |> polymorphic ctxt;
   279 
   280     fun guess_context raw_rule state' =
   281       let
   282         val ((parms, rule), ctxt') =
   283           unify_params vars thesis_var raw_rule (Proof.context_of state');
   284         val (xs, _) = Variable.add_fixes (map (#1 o #1) parms) ctxt';
   285         val ps = xs ~~ map (#2 o #1) parms;
   286         val ts = map Free ps;
   287         val asms =
   288           Logic.strip_assums_hyp (Logic.nth_prem (1, Thm.prop_of rule))
   289           |> map (fn asm => (Term.betapplys (fold_rev Term.abs ps asm, ts), []));
   290         val _ = not (null asms) orelse error "Trivial result -- nothing guessed";
   291       in
   292         state'
   293         |> Proof.map_context (K ctxt')
   294         |> Proof.fix (map (fn ((x, T), mx) => (Binding.name x, SOME T, mx)) parms)
   295         |> `Proof.context_of |-> (fn fix_ctxt => Proof.assm
   296           (obtain_export fix_ctxt rule (map cert ts)) [(Thm.empty_binding, asms)])
   297         |> Proof.bind_terms Auto_Bind.no_facts
   298       end;
   299 
   300     val goal = Var (("guess", 0), propT);
   301     fun print_result ctxt' (k, [(s, [_, th])]) =
   302       Proof_Display.print_results Isabelle_Markup.state int ctxt' (k, [(s, [th])]);
   303     val before_qed = SOME (Method.primitive_text (Goal.conclude #> Raw_Simplifier.norm_hhf #>
   304         (fn th => Goal.protect (Conjunction.intr (Drule.mk_term (Thm.cprop_of th)) th))));
   305     fun after_qed [[_, res]] =
   306       Proof.end_block #> guess_context (check_result ctxt thesis res);
   307   in
   308     state
   309     |> Proof.enter_forward
   310     |> Proof.begin_block
   311     |> Proof.fix [(Binding.name Auto_Bind.thesisN, NONE, NoSyn)]
   312     |> Proof.chain_facts chain_facts
   313     |> Proof.local_goal print_result (K I) (pair o rpair I)
   314       "guess" before_qed after_qed [(Thm.empty_binding, [Logic.mk_term goal, goal])]
   315     |> Proof.refine (Method.primitive_text (K (Goal.init (cert thesis)))) |> Seq.hd
   316   end;
   317 
   318 in
   319 
   320 val guess = gen_guess Proof_Context.cert_vars;
   321 val guess_cmd = gen_guess Proof_Context.read_vars;
   322 
   323 end;
   324 
   325 end;