src/Pure/Isar/proof_context.ML
author wenzelm
Fri Sep 12 12:04:20 2008 +0200 (2008-09-12 ago)
changeset 28212 44831b583999
parent 28209 02f3222a392d
child 28396 72695dd4395d
permissions -rw-r--r--
added extern_fact (local or global);
more procise printing of fact names;
     1 (*  Title:      Pure/Isar/proof_context.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 The key concept of Isar proof contexts: elevates primitive local
     6 reasoning Gamma |- phi to a structured concept, with generic context
     7 elements.  See also structure Variable and Assumption.
     8 *)
     9 
    10 signature PROOF_CONTEXT =
    11 sig
    12   val theory_of: Proof.context -> theory
    13   val init: theory -> Proof.context
    14   type mode
    15   val mode_default: mode
    16   val mode_stmt: mode
    17   val mode_pattern: mode
    18   val mode_schematic: mode
    19   val mode_abbrev: mode
    20   val set_mode: mode -> Proof.context -> Proof.context
    21   val get_mode: Proof.context -> mode
    22   val restore_mode: Proof.context -> Proof.context -> Proof.context
    23   val abbrev_mode: Proof.context -> bool
    24   val set_stmt: bool -> Proof.context -> Proof.context
    25   val naming_of: Proof.context -> NameSpace.naming
    26   val full_name: Proof.context -> bstring -> string
    27   val consts_of: Proof.context -> Consts.T
    28   val const_syntax_name: Proof.context -> string -> string
    29   val the_const_constraint: Proof.context -> string -> typ
    30   val mk_const: Proof.context -> string * typ list -> term
    31   val set_syntax_mode: Syntax.mode -> Proof.context -> Proof.context
    32   val restore_syntax_mode: Proof.context -> Proof.context -> Proof.context
    33   val facts_of: Proof.context -> Facts.T
    34   val transfer_syntax: theory -> Proof.context -> Proof.context
    35   val transfer: theory -> Proof.context -> Proof.context
    36   val theory: (theory -> theory) -> Proof.context -> Proof.context
    37   val theory_result: (theory -> 'a * theory) -> Proof.context -> 'a * Proof.context
    38   val extern_fact: Proof.context -> string -> xstring
    39   val pretty_term_abbrev: Proof.context -> term -> Pretty.T
    40   val pretty_thm_legacy: thm -> Pretty.T
    41   val pretty_thm: Proof.context -> thm -> Pretty.T
    42   val pretty_thms: Proof.context -> thm list -> Pretty.T
    43   val pretty_fact: Proof.context -> string * thm list -> Pretty.T
    44   val string_of_thm: Proof.context -> thm -> string
    45   val read_typ: Proof.context -> string -> typ
    46   val read_typ_syntax: Proof.context -> string -> typ
    47   val read_typ_abbrev: Proof.context -> string -> typ
    48   val cert_typ: Proof.context -> typ -> typ
    49   val cert_typ_syntax: Proof.context -> typ -> typ
    50   val cert_typ_abbrev: Proof.context -> typ -> typ
    51   val get_skolem: Proof.context -> string -> string
    52   val revert_skolem: Proof.context -> string -> string
    53   val infer_type: Proof.context -> string -> typ
    54   val inferred_param: string -> Proof.context -> typ * Proof.context
    55   val inferred_fixes: Proof.context -> (string * typ) list * Proof.context
    56   val read_tyname: Proof.context -> string -> typ
    57   val read_const_proper: Proof.context -> string -> term
    58   val read_const: Proof.context -> string -> term
    59   val allow_dummies: Proof.context -> Proof.context
    60   val decode_term: Proof.context -> term -> term
    61   val standard_infer_types: Proof.context -> term list -> term list
    62   val read_term_pattern: Proof.context -> string -> term
    63   val read_term_schematic: Proof.context -> string -> term
    64   val read_term_abbrev: Proof.context -> string -> term
    65   val expand_abbrevs: Proof.context -> term -> term
    66   val cert_term: Proof.context -> term -> term
    67   val cert_prop: Proof.context -> term -> term
    68   val goal_export: Proof.context -> Proof.context -> thm list -> thm list
    69   val export: Proof.context -> Proof.context -> thm list -> thm list
    70   val export_morphism: Proof.context -> Proof.context -> morphism
    71   val add_binds: (indexname * string option) list -> Proof.context -> Proof.context
    72   val add_binds_i: (indexname * term option) list -> Proof.context -> Proof.context
    73   val auto_bind_goal: term list -> Proof.context -> Proof.context
    74   val auto_bind_facts: term list -> Proof.context -> Proof.context
    75   val match_bind: bool -> (string list * string) list -> Proof.context -> term list * Proof.context
    76   val match_bind_i: bool -> (term list * term) list -> Proof.context -> term list * Proof.context
    77   val read_propp: Proof.context * (string * string list) list list
    78     -> Proof.context * (term * term list) list list
    79   val cert_propp: Proof.context * (term * term list) list list
    80     -> Proof.context * (term * term list) list list
    81   val read_propp_schematic: Proof.context * (string * string list) list list
    82     -> Proof.context * (term * term list) list list
    83   val cert_propp_schematic: Proof.context * (term * term list) list list
    84     -> Proof.context * (term * term list) list list
    85   val bind_propp: Proof.context * (string * string list) list list
    86     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    87   val bind_propp_i: Proof.context * (term * term list) list list
    88     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    89   val bind_propp_schematic: Proof.context * (string * string list) list list
    90     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    91   val bind_propp_schematic_i: Proof.context * (term * term list) list list
    92     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    93   val fact_tac: thm list -> int -> tactic
    94   val some_fact_tac: Proof.context -> int -> tactic
    95   val get_fact: Proof.context -> Facts.ref -> thm list
    96   val get_fact_single: Proof.context -> Facts.ref -> thm
    97   val get_thms: Proof.context -> xstring -> thm list
    98   val get_thm: Proof.context -> xstring -> thm
    99   val add_path: string -> Proof.context -> Proof.context
   100   val no_base_names: Proof.context -> Proof.context
   101   val qualified_names: Proof.context -> Proof.context
   102   val sticky_prefix: string -> Proof.context -> Proof.context
   103   val restore_naming: Proof.context -> Proof.context -> Proof.context
   104   val reset_naming: Proof.context -> Proof.context
   105   val note_thmss: string ->
   106     ((Name.binding * attribute list) * (Facts.ref * attribute list) list) list ->
   107       Proof.context -> (string * thm list) list * Proof.context
   108   val note_thmss_i: string ->
   109     ((Name.binding * attribute list) * (thm list * attribute list) list) list ->
   110       Proof.context -> (string * thm list) list * Proof.context
   111   val put_thms: bool -> string * thm list option -> Proof.context -> Proof.context
   112   val read_vars: (Name.binding * string option * mixfix) list -> Proof.context ->
   113     (Name.binding * typ option * mixfix) list * Proof.context
   114   val cert_vars: (Name.binding * typ option * mixfix) list -> Proof.context ->
   115     (Name.binding * typ option * mixfix) list * Proof.context
   116   val add_fixes: (Name.binding * string option * mixfix) list ->
   117     Proof.context -> string list * Proof.context
   118   val add_fixes_i: (Name.binding * typ option * mixfix) list ->
   119     Proof.context -> string list * Proof.context
   120   val auto_fixes: Proof.context * (term list list * 'a) -> Proof.context * (term list list * 'a)
   121   val bind_fixes: string list -> Proof.context -> (term -> term) * Proof.context
   122   val add_assms: Assumption.export ->
   123     ((Name.binding * attribute list) * (string * string list) list) list ->
   124     Proof.context -> (string * thm list) list * Proof.context
   125   val add_assms_i: Assumption.export ->
   126     ((Name.binding * attribute list) * (term * term list) list) list ->
   127     Proof.context -> (string * thm list) list * Proof.context
   128   val add_cases: bool -> (string * RuleCases.T option) list -> Proof.context -> Proof.context
   129   val apply_case: RuleCases.T -> Proof.context -> (string * term list) list * Proof.context
   130   val get_case: Proof.context -> string -> string option list -> RuleCases.T
   131   val notation: bool -> Syntax.mode -> (term * mixfix) list -> Proof.context -> Proof.context
   132   val target_notation: bool -> Syntax.mode -> (term * mixfix) list -> morphism ->
   133     Context.generic -> Context.generic
   134   val add_const_constraint: string * typ option -> Proof.context -> Proof.context
   135   val add_abbrev: string -> Properties.T ->
   136     bstring * term -> Proof.context -> (term * term) * Proof.context
   137   val revert_abbrev: string -> string -> Proof.context -> Proof.context
   138   val verbose: bool ref
   139   val setmp_verbose: ('a -> 'b) -> 'a -> 'b
   140   val print_syntax: Proof.context -> unit
   141   val print_abbrevs: Proof.context -> unit
   142   val print_binds: Proof.context -> unit
   143   val print_lthms: Proof.context -> unit
   144   val print_cases: Proof.context -> unit
   145   val debug: bool ref
   146   val prems_limit: int ref
   147   val pretty_ctxt: Proof.context -> Pretty.T list
   148   val pretty_context: Proof.context -> Pretty.T list
   149   val query_type: Proof.context -> string -> Properties.T
   150   val query_const: Proof.context -> string -> Properties.T
   151   val query_class: Proof.context -> string -> Properties.T
   152 end;
   153 
   154 structure ProofContext: PROOF_CONTEXT =
   155 struct
   156 
   157 val theory_of = Context.theory_of_proof;
   158 val init = Context.init_proof;
   159 
   160 
   161 (** inner syntax mode **)
   162 
   163 datatype mode =
   164   Mode of
   165    {stmt: bool,                (*inner statement mode*)
   166     pattern: bool,             (*pattern binding schematic variables*)
   167     schematic: bool,           (*term referencing loose schematic variables*)
   168     abbrev: bool};             (*abbrev mode -- no normalization*)
   169 
   170 fun make_mode (stmt, pattern, schematic, abbrev) =
   171   Mode {stmt = stmt, pattern = pattern, schematic = schematic, abbrev = abbrev};
   172 
   173 val mode_default   = make_mode (false, false, false, false);
   174 val mode_stmt      = make_mode (true, false, false, false);
   175 val mode_pattern   = make_mode (false, true, false, false);
   176 val mode_schematic = make_mode (false, false, true, false);
   177 val mode_abbrev    = make_mode (false, false, false, true);
   178 
   179 
   180 
   181 (** Isar proof context information **)
   182 
   183 datatype ctxt =
   184   Ctxt of
   185    {mode: mode,                                       (*inner syntax mode*)
   186     naming: NameSpace.naming,                         (*local naming conventions*)
   187     syntax: LocalSyntax.T,                            (*local syntax*)
   188     consts: Consts.T * Consts.T,                      (*local/global consts*)
   189     facts: Facts.T,                                   (*local facts*)
   190     cases: (string * (RuleCases.T * bool)) list};     (*named case contexts*)
   191 
   192 fun make_ctxt (mode, naming, syntax, consts, facts, cases) =
   193   Ctxt {mode = mode, naming = naming, syntax = syntax,
   194     consts = consts, facts = facts, cases = cases};
   195 
   196 val local_naming = NameSpace.default_naming |> NameSpace.add_path "local";
   197 
   198 structure ContextData = ProofDataFun
   199 (
   200   type T = ctxt;
   201   fun init thy =
   202     make_ctxt (mode_default, local_naming, LocalSyntax.init thy,
   203       (Sign.consts_of thy, Sign.consts_of thy), Facts.empty, []);
   204 );
   205 
   206 fun rep_context ctxt = ContextData.get ctxt |> (fn Ctxt args => args);
   207 
   208 fun map_context f =
   209   ContextData.map (fn Ctxt {mode, naming, syntax, consts, facts, cases} =>
   210     make_ctxt (f (mode, naming, syntax, consts, facts, cases)));
   211 
   212 fun set_mode mode = map_context (fn (_, naming, syntax, consts, facts, cases) =>
   213   (mode, naming, syntax, consts, facts, cases));
   214 
   215 fun map_mode f =
   216   map_context (fn (Mode {stmt, pattern, schematic, abbrev}, naming, syntax, consts, facts, cases) =>
   217     (make_mode (f (stmt, pattern, schematic, abbrev)), naming, syntax, consts, facts, cases));
   218 
   219 fun map_naming f =
   220   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   221     (mode, f naming, syntax, consts, facts, cases));
   222 
   223 fun map_syntax f =
   224   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   225     (mode, naming, f syntax, consts, facts, cases));
   226 
   227 fun map_consts f =
   228   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   229     (mode, naming, syntax, f consts, facts, cases));
   230 
   231 fun map_facts f =
   232   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   233     (mode, naming, syntax, consts, f facts, cases));
   234 
   235 fun map_cases f =
   236   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   237     (mode, naming, syntax, consts, facts, f cases));
   238 
   239 val get_mode = #mode o rep_context;
   240 fun restore_mode ctxt = set_mode (get_mode ctxt);
   241 val abbrev_mode = get_mode #> (fn Mode {abbrev, ...} => abbrev);
   242 
   243 fun set_stmt stmt =
   244   map_mode (fn (_, pattern, schematic, abbrev) => (stmt, pattern, schematic, abbrev));
   245 
   246 val naming_of = #naming o rep_context;
   247 val full_name = NameSpace.full o naming_of;
   248 
   249 val syntax_of = #syntax o rep_context;
   250 val syn_of = LocalSyntax.syn_of o syntax_of;
   251 val set_syntax_mode = map_syntax o LocalSyntax.set_mode;
   252 val restore_syntax_mode = map_syntax o LocalSyntax.restore_mode o syntax_of;
   253 
   254 val consts_of = #1 o #consts o rep_context;
   255 val const_syntax_name = Consts.syntax_name o consts_of;
   256 val the_const_constraint = Consts.the_constraint o consts_of;
   257 
   258 fun mk_const ctxt (c, Ts) = Const (c, Consts.instance (consts_of ctxt) (c, Ts));
   259 
   260 val facts_of = #facts o rep_context;
   261 val cases_of = #cases o rep_context;
   262 
   263 
   264 (* theory transfer *)
   265 
   266 fun transfer_syntax thy =
   267   map_syntax (LocalSyntax.rebuild thy) #>
   268   map_consts (fn consts as (local_consts, global_consts) =>
   269     let val thy_consts = Sign.consts_of thy in
   270       if Consts.eq_consts (thy_consts, global_consts) then consts
   271       else (Consts.merge (local_consts, thy_consts), thy_consts)
   272     end);
   273 
   274 fun transfer thy = Context.transfer_proof thy #> transfer_syntax thy;
   275 
   276 fun theory f ctxt = transfer (f (theory_of ctxt)) ctxt;
   277 
   278 fun theory_result f ctxt =
   279   let val (res, thy') = f (theory_of ctxt)
   280   in (res, ctxt |> transfer thy') end;
   281 
   282 
   283 
   284 (** pretty printing **)
   285 
   286 (* extern *)
   287 
   288 fun extern_fact ctxt name =
   289   let
   290     val local_facts = facts_of ctxt;
   291     val global_facts = PureThy.facts_of (theory_of ctxt);
   292   in
   293     if is_some (Facts.lookup (Context.Proof ctxt) local_facts name)
   294     then Facts.extern local_facts name
   295     else Facts.extern global_facts name
   296   end;
   297 
   298 
   299 (* pretty *)
   300 
   301 fun pretty_term_abbrev ctxt = Syntax.pretty_term (set_mode mode_abbrev ctxt);
   302 
   303 fun pretty_thm_legacy th =
   304   let val thy = Thm.theory_of_thm th
   305   in Display.pretty_thm_aux (Syntax.pp_global thy) true false [] th end;
   306 
   307 fun pretty_thm ctxt th =
   308   let val asms = map Thm.term_of (Assumption.assms_of ctxt)
   309   in Display.pretty_thm_aux (Syntax.pp ctxt) false true asms th end;
   310 
   311 fun pretty_thms ctxt [th] = pretty_thm ctxt th
   312   | pretty_thms ctxt ths = Pretty.blk (0, Pretty.fbreaks (map (pretty_thm ctxt) ths));
   313 
   314 fun pretty_fact_name ctxt a = Pretty.block
   315   [Pretty.markup (Markup.fact a) [Pretty.str (extern_fact ctxt a)], Pretty.str ":"];
   316 
   317 fun pretty_fact ctxt ("", ths) = pretty_thms ctxt ths
   318   | pretty_fact ctxt (a, [th]) = Pretty.block
   319       [pretty_fact_name ctxt a, Pretty.brk 1, pretty_thm ctxt th]
   320   | pretty_fact ctxt (a, ths) = Pretty.block
   321       (Pretty.fbreaks (pretty_fact_name ctxt a :: map (pretty_thm ctxt) ths));
   322 
   323 val string_of_thm = Pretty.string_of oo pretty_thm;
   324 
   325 
   326 
   327 (** prepare types **)
   328 
   329 (* read_typ *)
   330 
   331 fun read_typ_mode mode ctxt s =
   332   Syntax.read_typ (Type.set_mode mode ctxt) s;
   333 
   334 val read_typ        = read_typ_mode Type.mode_default;
   335 val read_typ_syntax = read_typ_mode Type.mode_syntax;
   336 val read_typ_abbrev = read_typ_mode Type.mode_abbrev;
   337 
   338 
   339 (* cert_typ *)
   340 
   341 fun cert_typ_mode mode ctxt T =
   342   Sign.certify_typ_mode mode (theory_of ctxt) T
   343     handle TYPE (msg, _, _) => error msg;
   344 
   345 val cert_typ        = cert_typ_mode Type.mode_default;
   346 val cert_typ_syntax = cert_typ_mode Type.mode_syntax;
   347 val cert_typ_abbrev = cert_typ_mode Type.mode_abbrev;
   348 
   349 
   350 
   351 (** prepare variables **)
   352 
   353 (* internalize Skolem constants *)
   354 
   355 val lookup_skolem = AList.lookup (op =) o Variable.fixes_of;
   356 fun get_skolem ctxt x = the_default x (lookup_skolem ctxt x);
   357 
   358 fun no_skolem internal x =
   359   if can Name.dest_skolem x then
   360     error ("Illegal reference to internal Skolem constant: " ^ quote x)
   361   else if not internal andalso can Name.dest_internal x then
   362     error ("Illegal reference to internal variable: " ^ quote x)
   363   else x;
   364 
   365 
   366 (* revert Skolem constants -- if possible *)
   367 
   368 fun revert_skolem ctxt x =
   369   (case find_first (fn (_, y) => y = x) (Variable.fixes_of ctxt) of
   370     SOME (x', _) => if lookup_skolem ctxt x' = SOME x then x' else x
   371   | NONE => x);
   372 
   373 
   374 (* default token translations *)
   375 
   376 local
   377 
   378 fun free_or_skolem ctxt x =
   379   (if can Name.dest_skolem x then Pretty.mark Markup.skolem (Pretty.str (revert_skolem ctxt x))
   380    else Pretty.mark Markup.free (Pretty.str x))
   381   |> Pretty.mark
   382     (if Variable.is_fixed ctxt x orelse Syntax.is_pretty_global ctxt then Markup.fixed x
   383      else Markup.hilite);
   384 
   385 fun var_or_skolem _ s =
   386   (case Lexicon.read_variable s of
   387     SOME (x, i) =>
   388       (case try Name.dest_skolem x of
   389         NONE => Pretty.mark Markup.var (Pretty.str s)
   390       | SOME x' => Pretty.mark Markup.skolem
   391           (Pretty.str (setmp show_question_marks true Term.string_of_vname (x', i))))
   392   | NONE => Pretty.mark Markup.var (Pretty.str s));
   393 
   394 fun class_markup _ c =    (* FIXME authentic name *)
   395   Pretty.mark (Markup.tclassN, []) (Pretty.str c);
   396 
   397 fun plain_markup m _ s = Pretty.mark m (Pretty.str s);
   398 
   399 val token_trans =
   400  Syntax.tokentrans_mode ""
   401   [("class", class_markup),
   402    ("tfree", plain_markup Markup.tfree),
   403    ("tvar", plain_markup Markup.tvar),
   404    ("free", free_or_skolem),
   405    ("bound", plain_markup Markup.bound),
   406    ("var", var_or_skolem),
   407    ("num", plain_markup Markup.num),
   408    ("xnum", plain_markup Markup.xnum),
   409    ("xstr", plain_markup Markup.xstr)];
   410 
   411 in val _ = Context.>> (Context.map_theory (Sign.add_tokentrfuns token_trans)) end;
   412 
   413 
   414 
   415 (** prepare terms and propositions **)
   416 
   417 (* inferred types of parameters *)
   418 
   419 fun infer_type ctxt x =
   420   Term.fastype_of (singleton (Syntax.check_terms (set_mode mode_schematic ctxt))
   421     (Free (x, dummyT)));
   422 
   423 fun inferred_param x ctxt =
   424   let val T = infer_type ctxt x
   425   in (T, ctxt |> Variable.declare_term (Free (x, T))) end;
   426 
   427 fun inferred_fixes ctxt =
   428   let
   429     val xs = rev (map #2 (Variable.fixes_of ctxt));
   430     val (Ts, ctxt') = fold_map inferred_param xs ctxt;
   431   in (xs ~~ Ts, ctxt') end;
   432 
   433 
   434 (* type and constant names *)
   435 
   436 local
   437 
   438 val token_content = Syntax.read_token #>> SymbolPos.content;
   439 
   440 fun prep_const_proper ctxt (c, pos) =
   441   let val t as (Const (d, _)) =
   442     (case Variable.lookup_const ctxt c of
   443       SOME d => Const (d, Consts.type_scheme (consts_of ctxt) d handle TYPE (msg, _, _) => error msg)
   444     | NONE => Consts.read_const (consts_of ctxt) c)
   445   in Position.report (Markup.const d) pos; t end;
   446 
   447 in
   448 
   449 fun read_tyname ctxt str =
   450   let
   451     val thy = theory_of ctxt;
   452     val (c, pos) = token_content str;
   453   in
   454     if Syntax.is_tid c then
   455      (Position.report Markup.tfree pos;
   456       TFree (c, the_default (Sign.defaultS thy) (Variable.def_sort ctxt (c, ~1))))
   457     else
   458       let
   459         val d = Sign.intern_type thy c;
   460         val _ = Position.report (Markup.tycon d) pos;
   461       in Type (d, replicate (Sign.arity_number thy d) dummyT) end
   462   end;
   463 
   464 fun read_const_proper ctxt = prep_const_proper ctxt o token_content;
   465 
   466 fun read_const ctxt str =
   467   let val (c, pos) = token_content str in
   468     (case (lookup_skolem ctxt c, Variable.is_const ctxt c) of
   469       (SOME x, false) =>
   470         (Position.report (Markup.name x
   471             (if can Name.dest_skolem x then Markup.skolem else Markup.free)) pos;
   472           Free (x, infer_type ctxt x))
   473     | _ => prep_const_proper ctxt (c, pos))
   474   end;
   475 
   476 end;
   477 
   478 
   479 (* read_term *)
   480 
   481 fun read_term_mode mode ctxt = Syntax.read_term (set_mode mode ctxt);
   482 
   483 val read_term_pattern   = read_term_mode mode_pattern;
   484 val read_term_schematic = read_term_mode mode_schematic;
   485 val read_term_abbrev    = read_term_mode mode_abbrev;
   486 
   487 
   488 (* local abbreviations *)
   489 
   490 val tsig_of = Sign.tsig_of o ProofContext.theory_of;
   491 
   492 local
   493 
   494 fun certify_consts ctxt = Consts.certify (Syntax.pp ctxt) (tsig_of ctxt)
   495   (not (abbrev_mode ctxt)) (consts_of ctxt);
   496 
   497 fun reject_schematic (Var (xi, _)) =
   498       error ("Unbound schematic variable: " ^ Term.string_of_vname xi)
   499   | reject_schematic (Abs (_, _, t)) = reject_schematic t
   500   | reject_schematic (t $ u) = (reject_schematic t; reject_schematic u)
   501   | reject_schematic _ = ();
   502 
   503 fun expand_binds ctxt =
   504   let val Mode {pattern, schematic, ...} = get_mode ctxt in
   505     if pattern then I
   506     else Variable.expand_binds ctxt #> (if schematic then I else tap reject_schematic)
   507   end;
   508 
   509 in
   510 
   511 fun expand_abbrevs ctxt = certify_consts ctxt #> expand_binds ctxt;
   512 
   513 end;
   514 
   515 
   516 fun contract_abbrevs ctxt t =
   517   let
   518     val thy = theory_of ctxt;
   519     val consts = consts_of ctxt;
   520     val Mode {abbrev, ...} = get_mode ctxt;
   521   in
   522     if abbrev orelse print_mode_active "no_abbrevs" orelse not (can Term.type_of t) then t
   523     else t |> Pattern.rewrite_term thy (Consts.abbrevs_of consts (print_mode_value () @ [""])) []
   524   end;
   525 
   526 
   527 (* patterns *)
   528 
   529 fun prepare_patternT ctxt =
   530   let val Mode {pattern, schematic, ...} = get_mode ctxt in
   531     if pattern orelse schematic then I
   532     else Term.map_atyps
   533       (fn T as TVar (xi, _) =>
   534             if not (TypeInfer.is_param xi)
   535             then error ("Illegal schematic type variable: " ^ Term.string_of_vname xi)
   536             else T
   537         | T => T)
   538   end;
   539 
   540 
   541 local
   542 
   543 structure AllowDummies = ProofDataFun(type T = bool fun init _ = false);
   544 
   545 fun check_dummies ctxt t =
   546   if AllowDummies.get ctxt then t
   547   else Term.no_dummy_patterns t handle TERM _ => error "Illegal dummy pattern(s) in term";
   548 
   549 fun prepare_dummies ts = #1 (fold_map Term.replace_dummy_patterns ts 1);
   550 
   551 in
   552 
   553 val allow_dummies = AllowDummies.put true;
   554 
   555 fun prepare_patterns ctxt =
   556   let val Mode {pattern, ...} = get_mode ctxt in
   557     TypeInfer.fixate_params (Variable.names_of ctxt) #>
   558     pattern ? Variable.polymorphic ctxt #>
   559     (map o Term.map_types) (prepare_patternT ctxt) #>
   560     (if pattern then prepare_dummies else map (check_dummies ctxt))
   561   end;
   562 
   563 end;
   564 
   565 
   566 (* decoding raw terms (syntax trees) *)
   567 
   568 (* types *)
   569 
   570 fun get_sort thy def_sort raw_env =
   571   let
   572     val tsig = Sign.tsig_of thy;
   573 
   574     fun eq ((xi, S), (xi', S')) =
   575       Term.eq_ix (xi, xi') andalso Type.eq_sort tsig (S, S');
   576     val env = distinct eq raw_env;
   577     val _ = (case duplicates (eq_fst (op =)) env of [] => ()
   578       | dups => error ("Inconsistent sort constraints for type variable(s) "
   579           ^ commas_quote (map (Term.string_of_vname' o fst) dups)));
   580 
   581     fun get xi =
   582       (case (AList.lookup (op =) env xi, def_sort xi) of
   583         (NONE, NONE) => Type.defaultS tsig
   584       | (NONE, SOME S) => S
   585       | (SOME S, NONE) => S
   586       | (SOME S, SOME S') =>
   587           if Type.eq_sort tsig (S, S') then S'
   588           else error ("Sort constraint inconsistent with default for type variable " ^
   589             quote (Term.string_of_vname' xi)));
   590   in get end;
   591 
   592 local
   593 
   594 fun intern_skolem ctxt def_type x =
   595   let
   596     val _ = no_skolem false x;
   597     val sko = lookup_skolem ctxt x;
   598     val is_const = can (read_const_proper ctxt) x orelse NameSpace.is_qualified x;
   599     val is_declared = is_some (def_type (x, ~1));
   600   in
   601     if Variable.is_const ctxt x then NONE
   602     else if is_some sko then sko
   603     else if not is_const orelse is_declared then SOME x
   604     else NONE
   605   end;
   606 
   607 in
   608 
   609 fun term_context ctxt =
   610   let val thy = theory_of ctxt in
   611    {get_sort = get_sort thy (Variable.def_sort ctxt),
   612     map_const = fn a => ((true, #1 (Term.dest_Const (read_const_proper ctxt a)))
   613       handle ERROR _ => (false, Consts.intern (consts_of ctxt) a)),
   614     map_free = intern_skolem ctxt (Variable.def_type ctxt false),
   615     map_type = Sign.intern_tycons thy,
   616     map_sort = Sign.intern_sort thy}
   617   end;
   618 
   619 fun decode_term ctxt =
   620   let val {get_sort, map_const, map_free, map_type, map_sort} = term_context ctxt
   621   in Syntax.decode_term get_sort map_const map_free map_type map_sort end;
   622 
   623 end;
   624 
   625 
   626 (* certify terms *)
   627 
   628 local
   629 
   630 fun gen_cert prop ctxt t =
   631   t
   632   |> expand_abbrevs ctxt
   633   |> (fn t' => #1 (Sign.certify' prop (Syntax.pp ctxt) false (consts_of ctxt) (theory_of ctxt) t')
   634     handle TYPE (msg, _, _) => error msg
   635       | TERM (msg, _) => error msg);
   636 
   637 in
   638 
   639 val cert_term = gen_cert false;
   640 val cert_prop = gen_cert true;
   641 
   642 end;
   643 
   644 
   645 (* type checking/inference *)
   646 
   647 fun standard_infer_types ctxt ts =
   648   let val Mode {pattern, ...} = get_mode ctxt in
   649     TypeInfer.infer_types (Syntax.pp ctxt) (tsig_of ctxt) (Syntax.check_typs ctxt)
   650       (try (Consts.the_constraint (consts_of ctxt))) (Variable.def_type ctxt pattern)
   651       (Variable.names_of ctxt) (Variable.maxidx_of ctxt) ts
   652     handle TYPE (msg, _, _) => error msg
   653   end;
   654 
   655 local
   656 
   657 fun standard_typ_check ctxt =
   658   map (cert_typ_mode (Type.get_mode ctxt) ctxt) #>
   659   map (prepare_patternT ctxt);
   660 
   661 fun standard_term_check ctxt =
   662   standard_infer_types ctxt #>
   663   map (expand_abbrevs ctxt);
   664 
   665 fun standard_term_uncheck ctxt =
   666   map (contract_abbrevs ctxt);
   667 
   668 fun add eq what f = Context.>> (what (fn xs => fn ctxt =>
   669   let val xs' = f ctxt xs in if eq_list eq (xs, xs') then NONE else SOME (xs', ctxt) end));
   670 
   671 in
   672 
   673 val _ = add (op =) (Syntax.add_typ_check 0 "standard") standard_typ_check;
   674 val _ = add (op aconv) (Syntax.add_term_check 0 "standard") standard_term_check;
   675 val _ = add (op aconv) (Syntax.add_term_check 100 "fixate") prepare_patterns;
   676 
   677 val _ = add (op aconv) (Syntax.add_term_uncheck 0 "standard") standard_term_uncheck;
   678 
   679 end;
   680 
   681 
   682 
   683 (** inner syntax operations **)
   684 
   685 local
   686 
   687 fun parse_sort ctxt text =
   688   let
   689     val (syms, pos) = Syntax.parse_token Markup.sort text;
   690     val S = Syntax.standard_parse_sort ctxt (syn_of ctxt)
   691         (Sign.intern_sort (theory_of ctxt)) (syms, pos)
   692       handle ERROR msg => cat_error msg  ("Failed to parse sort" ^ Position.str_of pos)
   693   in S end;
   694 
   695 fun parse_typ ctxt text =
   696   let
   697     val thy = ProofContext.theory_of ctxt;
   698     val get_sort = get_sort thy (Variable.def_sort ctxt);
   699 
   700     val (syms, pos) = Syntax.parse_token Markup.typ text;
   701     val T = Sign.intern_tycons thy
   702         (Syntax.standard_parse_typ ctxt (syn_of ctxt) get_sort (Sign.intern_sort thy) (syms, pos))
   703       handle ERROR msg => cat_error msg  ("Failed to parse type" ^ Position.str_of pos);
   704   in T end;
   705 
   706 fun parse_term T ctxt text =
   707   let
   708     val thy = theory_of ctxt;
   709     val {get_sort, map_const, map_free, map_type, map_sort} = term_context ctxt;
   710 
   711     val (T', _) = TypeInfer.paramify_dummies T 0;
   712     val (markup, kind) = if T' = propT then (Markup.prop, "proposition") else (Markup.term, "term");
   713     val (syms, pos) = Syntax.parse_token markup text;
   714 
   715     fun check t = (Syntax.check_term ctxt (TypeInfer.constrain T' t); NONE)
   716       handle ERROR msg => SOME msg;
   717     val t = Syntax.standard_parse_term (Syntax.pp ctxt) check get_sort map_const map_free
   718         map_type map_sort ctxt (Sign.is_logtype thy) (syn_of ctxt) T' (syms, pos)
   719       handle ERROR msg => cat_error msg  ("Failed to parse " ^ kind ^ Position.str_of pos);
   720   in t end;
   721 
   722 
   723 fun unparse_sort ctxt S =
   724   Syntax.standard_unparse_sort ctxt (syn_of ctxt) (Sign.extern_sort (theory_of ctxt) S);
   725 
   726 fun unparse_typ ctxt T =
   727   Syntax.standard_unparse_typ ctxt (syn_of ctxt) (Sign.extern_typ (theory_of ctxt) T);
   728 
   729 fun unparse_term ctxt t =
   730   let
   731     val thy = theory_of ctxt;
   732     val syntax = syntax_of ctxt;
   733     val consts = consts_of ctxt;
   734   in
   735     t
   736     |> Sign.extern_term (Consts.extern_early consts) thy
   737     |> LocalSyntax.extern_term syntax
   738     |> Syntax.standard_unparse_term (Consts.extern consts) ctxt (LocalSyntax.syn_of syntax)
   739         (not (PureThy.old_appl_syntax thy))
   740   end;
   741 
   742 in
   743 
   744 val _ = Syntax.install_operations
   745   {parse_sort = parse_sort,
   746    parse_typ = parse_typ,
   747    parse_term = parse_term dummyT,
   748    parse_prop = parse_term propT,
   749    unparse_sort = unparse_sort,
   750    unparse_typ = unparse_typ,
   751    unparse_term = unparse_term};
   752 
   753 end;
   754 
   755 
   756 
   757 (** export results **)
   758 
   759 fun common_export is_goal inner outer =
   760   map (Assumption.export is_goal inner outer) #>
   761   Variable.export inner outer;
   762 
   763 val goal_export = common_export true;
   764 val export = common_export false;
   765 
   766 fun export_morphism inner outer =
   767   Assumption.export_morphism inner outer $>
   768   Variable.export_morphism inner outer;
   769 
   770 
   771 
   772 (** bindings **)
   773 
   774 (* simult_matches *)
   775 
   776 fun simult_matches ctxt (t, pats) =
   777   (case Seq.pull (Unify.matchers (theory_of ctxt) (map (rpair t) pats)) of
   778     NONE => error "Pattern match failed!"
   779   | SOME (env, _) => map (apsnd snd) (Envir.alist_of env));
   780 
   781 
   782 (* add_binds(_i) *)
   783 
   784 local
   785 
   786 fun gen_bind prep (xi as (x, _), raw_t) ctxt =
   787   ctxt
   788   |> Variable.add_binds [(xi, Option.map (prep (set_mode mode_default ctxt)) raw_t)];
   789 
   790 in
   791 
   792 fun drop_schematic (b as (xi, SOME t)) = if Term.exists_subterm is_Var t then (xi, NONE) else b
   793   | drop_schematic b = b;
   794 
   795 val add_binds = fold (gen_bind Syntax.read_term);
   796 val add_binds_i = fold (gen_bind cert_term);
   797 
   798 fun auto_bind f ts ctxt = ctxt |> add_binds_i (map drop_schematic (f (theory_of ctxt) ts));
   799 val auto_bind_goal = auto_bind AutoBind.goal;
   800 val auto_bind_facts = auto_bind AutoBind.facts;
   801 
   802 end;
   803 
   804 
   805 (* match_bind(_i) *)
   806 
   807 local
   808 
   809 fun gen_bind prep_terms gen raw_binds ctxt =
   810   let
   811     fun prep_bind (raw_pats, t) ctxt1 =
   812       let
   813         val T = Term.fastype_of t;
   814         val ctxt2 = Variable.declare_term t ctxt1;
   815         val pats = prep_terms (set_mode mode_pattern ctxt2) T raw_pats;
   816         val binds = simult_matches ctxt2 (t, pats);
   817       in (binds, ctxt2) end;
   818 
   819     val ts = prep_terms ctxt dummyT (map snd raw_binds);
   820     val (binds, ctxt') = apfst flat (fold_map prep_bind (map fst raw_binds ~~ ts) ctxt);
   821     val binds' =
   822       if gen then map #1 binds ~~ Variable.exportT_terms ctxt' ctxt (map #2 binds)
   823       else binds;
   824     val binds'' = map (apsnd SOME) binds';
   825     val ctxt'' =
   826       tap (Variable.warn_extra_tfrees ctxt)
   827        (if gen then
   828           ctxt (*sic!*) |> fold Variable.declare_term (map #2 binds') |> add_binds_i binds''
   829         else ctxt' |> add_binds_i binds'');
   830   in (ts, ctxt'') end;
   831 
   832 in
   833 
   834 fun read_terms ctxt T =
   835   map (Syntax.parse_term ctxt #> TypeInfer.constrain T) #> Syntax.check_terms ctxt;
   836 
   837 val match_bind = gen_bind read_terms;
   838 val match_bind_i = gen_bind (fn ctxt => fn _ => map (cert_term ctxt));
   839 
   840 end;
   841 
   842 
   843 (* propositions with patterns *)
   844 
   845 local
   846 
   847 fun prep_propp mode prep_props (context, args) =
   848   let
   849     fun prep (_, raw_pats) (ctxt, prop :: props) =
   850       let val ctxt' = Variable.declare_term prop ctxt
   851       in ((prop, prep_props (set_mode mode_pattern ctxt') raw_pats), (ctxt', props)) end;
   852 
   853     val (propp, (context', _)) = (fold_map o fold_map) prep args
   854       (context, prep_props (set_mode mode context) (maps (map fst) args));
   855   in (context', propp) end;
   856 
   857 fun gen_bind_propp mode parse_prop (ctxt, raw_args) =
   858   let
   859     val (ctxt', args) = prep_propp mode parse_prop (ctxt, raw_args);
   860     val binds = flat (flat (map (map (simult_matches ctxt')) args));
   861     val propss = map (map #1) args;
   862 
   863     (*generalize result: context evaluated now, binds added later*)
   864     val gen = Variable.exportT_terms ctxt' ctxt;
   865     fun gen_binds c = c |> add_binds_i (map #1 binds ~~ map SOME (gen (map #2 binds)));
   866   in (ctxt' |> add_binds_i (map (apsnd SOME) binds), (propss, gen_binds)) end;
   867 
   868 in
   869 
   870 val read_propp           = prep_propp mode_default Syntax.read_props;
   871 val cert_propp           = prep_propp mode_default (map o cert_prop);
   872 val read_propp_schematic = prep_propp mode_schematic Syntax.read_props;
   873 val cert_propp_schematic = prep_propp mode_schematic (map o cert_prop);
   874 
   875 val bind_propp             = gen_bind_propp mode_default Syntax.read_props;
   876 val bind_propp_i           = gen_bind_propp mode_default (map o cert_prop);
   877 val bind_propp_schematic   = gen_bind_propp mode_schematic Syntax.read_props;
   878 val bind_propp_schematic_i = gen_bind_propp mode_schematic (map o cert_prop);
   879 
   880 end;
   881 
   882 
   883 
   884 (** theorems **)
   885 
   886 (* fact_tac *)
   887 
   888 fun comp_incr_tac [] _ = no_tac
   889   | comp_incr_tac (th :: ths) i =
   890       (fn st => Goal.compose_hhf_tac (Drule.incr_indexes st th) i st) APPEND comp_incr_tac ths i;
   891 
   892 fun fact_tac facts = Goal.norm_hhf_tac THEN' comp_incr_tac facts;
   893 
   894 fun potential_facts ctxt prop =
   895   Facts.could_unify (facts_of ctxt) (Term.strip_all_body prop);
   896 
   897 fun some_fact_tac ctxt = SUBGOAL (fn (goal, i) => fact_tac (potential_facts ctxt goal) i);
   898 
   899 
   900 (* get_thm(s) *)
   901 
   902 local
   903 
   904 fun retrieve_thms pick ctxt (Facts.Fact s) =
   905       let
   906         val (_, pos) = Syntax.read_token s;
   907         val prop = Syntax.read_prop (set_mode mode_default ctxt) s
   908           |> singleton (Variable.polymorphic ctxt);
   909 
   910         fun prove_fact th =
   911           Goal.prove ctxt [] [] prop (K (ALLGOALS (fact_tac [th])))
   912           |> Thm.default_position_of th;
   913         val res =
   914           (case get_first (try prove_fact) (potential_facts ctxt prop) of
   915             SOME res => res
   916           | NONE => error ("Failed to retrieve literal fact" ^ Position.str_of pos ^ ":\n" ^
   917               Syntax.string_of_term ctxt prop))
   918       in pick "" [res] end
   919   | retrieve_thms pick ctxt xthmref =
   920       let
   921         val thy = theory_of ctxt;
   922         val local_facts = facts_of ctxt;
   923         val thmref = Facts.map_name_of_ref (Facts.intern local_facts) xthmref;
   924         val name = Facts.name_of_ref thmref;
   925         val pos = Facts.pos_of_ref xthmref;
   926         val thms =
   927           if name = "" then [Thm.transfer thy Drule.dummy_thm]
   928           else
   929             (case Facts.lookup (Context.Proof ctxt) local_facts name of
   930               SOME (_, ths) => (Position.report (Markup.local_fact name) pos;
   931                 map (Thm.transfer thy) (Facts.select thmref ths))
   932             | NONE => PureThy.get_fact (Context.Proof ctxt) thy xthmref);
   933       in pick name thms end;
   934 
   935 in
   936 
   937 val get_fact = retrieve_thms (K I);
   938 val get_fact_single = retrieve_thms Facts.the_single;
   939 
   940 fun get_thms ctxt = get_fact ctxt o Facts.named;
   941 fun get_thm ctxt = get_fact_single ctxt o Facts.named;
   942 
   943 end;
   944 
   945 
   946 (* name space operations *)
   947 
   948 val add_path        = map_naming o NameSpace.add_path;
   949 val no_base_names   = map_naming NameSpace.no_base_names;
   950 val qualified_names = map_naming NameSpace.qualified_names;
   951 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   952 val restore_naming  = map_naming o K o naming_of;
   953 val reset_naming    = map_naming (K local_naming);
   954 
   955 
   956 (* facts *)
   957 
   958 local
   959 
   960 fun update_thms _ (bname, NONE) ctxt = ctxt |> map_facts (Facts.del (full_name ctxt bname))
   961   | update_thms do_props (bname, SOME ths) ctxt = ctxt |> map_facts
   962       (Facts.add_local do_props (naming_of ctxt) (full_name ctxt bname, ths));
   963 
   964 fun gen_note_thmss get k = fold_map (fn ((binding, more_attrs), raw_facts) => fn ctxt =>
   965   let
   966     val bname = Name.name_of binding;
   967     val pos = Name.pos_of binding;
   968     val name = full_name ctxt bname;
   969     val _ = Position.report (Markup.local_fact_decl name) pos;
   970 
   971     val facts = PureThy.name_thmss false pos name (map (apfst (get ctxt)) raw_facts);
   972     fun app (th, attrs) x =
   973       swap (foldl_map (Thm.proof_attributes (surround (Thm.kind k) (attrs @ more_attrs))) (x, th));
   974     val (res, ctxt') = fold_map app facts ctxt;
   975     val thms = PureThy.name_thms false false pos name (flat res);
   976     val Mode {stmt, ...} = get_mode ctxt;
   977   in ((name, thms), ctxt' |> update_thms stmt (bname, SOME thms)) end);
   978 
   979 in
   980 
   981 fun note_thmss k = gen_note_thmss get_fact k;
   982 fun note_thmss_i k = gen_note_thmss (K I) k;
   983 
   984 fun put_thms do_props thms ctxt =
   985   ctxt |> map_naming (K local_naming) |> update_thms do_props thms |> restore_naming ctxt;
   986 
   987 end;
   988 
   989 
   990 
   991 (** parameters **)
   992 
   993 (* variables *)
   994 
   995 fun declare_var (x, opt_T, mx) ctxt =
   996   let val T = (case opt_T of SOME T => T | NONE => Syntax.mixfixT mx)
   997   in ((x, T, mx), ctxt |> Variable.declare_constraints (Free (x, T))) end;
   998 
   999 local
  1000 
  1001 fun prep_vars prep_typ internal =
  1002   fold_map (fn (raw_binding, raw_T, raw_mx) => fn ctxt =>
  1003     let
  1004       val raw_x = Name.name_of raw_binding;
  1005       val (x, mx) = Syntax.const_mixfix raw_x raw_mx;
  1006       val _ = Syntax.is_identifier (no_skolem internal x) orelse
  1007         error ("Illegal variable name: " ^ quote x);
  1008 
  1009       fun cond_tvars T =
  1010         if internal then T
  1011         else Type.no_tvars T handle TYPE (msg, _, _) => error msg;
  1012       val opt_T = Option.map (cond_tvars o cert_typ ctxt o prep_typ ctxt) raw_T;
  1013       val var = (Name.map_name (K x) raw_binding, opt_T, mx);
  1014     in (var, ctxt |> declare_var (x, opt_T, mx) |> #2) end);
  1015 
  1016 in
  1017 
  1018 val read_vars = prep_vars Syntax.parse_typ false;
  1019 val cert_vars = prep_vars (K I) true;
  1020 
  1021 end;
  1022 
  1023 
  1024 (* authentic constants *)
  1025 
  1026 local
  1027 
  1028 fun const_ast_tr intern ctxt [Syntax.Variable c] =
  1029       let
  1030         val Const (c', _) = read_const_proper ctxt c;
  1031         val d = if intern then const_syntax_name ctxt c' else c;
  1032       in Syntax.Constant d end
  1033   | const_ast_tr _ _ asts = raise Syntax.AST ("const_ast_tr", asts);
  1034 
  1035 in
  1036 
  1037 val _ = Context.>> (Context.map_theory
  1038  (Sign.add_syntax
  1039    [("_context_const", "id => 'a", Delimfix "CONST _"),
  1040     ("_context_const", "longid => 'a", Delimfix "CONST _"),
  1041     ("_context_xconst", "id => 'a", Delimfix "XCONST _"),
  1042     ("_context_xconst", "longid => 'a", Delimfix "XCONST _")] #>
  1043   Sign.add_advanced_trfuns
  1044     ([("_context_const", const_ast_tr true), ("_context_xconst", const_ast_tr false)], [], [], [])));
  1045 
  1046 end;
  1047 
  1048 
  1049 (* notation *)
  1050 
  1051 local
  1052 
  1053 fun const_syntax ctxt (Free (x, T), mx) = SOME (true, (x, T, mx))
  1054   | const_syntax ctxt (Const (c, _), mx) =
  1055       Option.map (pair false) (try (Consts.syntax (consts_of ctxt)) (c, mx))
  1056   | const_syntax _ _ = NONE;
  1057 
  1058 in
  1059 
  1060 fun notation add mode args ctxt =
  1061   ctxt |> map_syntax
  1062     (LocalSyntax.update_modesyntax (theory_of ctxt) add mode (map_filter (const_syntax ctxt) args));
  1063 
  1064 fun target_notation add mode args phi =
  1065   let val args' = filter (fn (t, _) => Type.similar_types (t, Morphism.term phi t)) args;
  1066   in Context.mapping (Sign.notation add mode args') (notation add mode args') end;
  1067 
  1068 end;
  1069 
  1070 
  1071 (* local constants *)
  1072 
  1073 fun add_const_constraint (c, opt_T) ctxt =
  1074   let
  1075     fun prepT raw_T =
  1076       let val T = cert_typ ctxt raw_T
  1077       in cert_term ctxt (Const (c, T)); T end;
  1078   in ctxt |> (map_consts o apfst) (Consts.constrain (c, Option.map prepT opt_T)) end;
  1079 
  1080 fun add_abbrev mode tags (c, raw_t) ctxt =
  1081   let
  1082     val t0 = cert_term (ctxt |> set_mode mode_abbrev) raw_t
  1083       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
  1084     val [t] = Variable.exportT_terms (Variable.declare_term t0 ctxt) ctxt [t0];
  1085     val ((lhs, rhs), consts') = consts_of ctxt
  1086       |> Consts.abbreviate (Syntax.pp ctxt) (tsig_of ctxt) (naming_of ctxt) mode tags (c, t);
  1087   in
  1088     ctxt
  1089     |> (map_consts o apfst) (K consts')
  1090     |> Variable.declare_term rhs
  1091     |> pair (lhs, rhs)
  1092   end;
  1093 
  1094 fun revert_abbrev mode c = (map_consts o apfst) (Consts.revert_abbrev mode c);
  1095 
  1096 
  1097 (* fixes *)
  1098 
  1099 local
  1100 
  1101 fun prep_mixfix (x, T, mx) =
  1102   if mx <> NoSyn andalso mx <> Structure andalso
  1103       (can Name.dest_internal x orelse can Name.dest_skolem x) then
  1104     error ("Illegal mixfix syntax for internal/skolem constant " ^ quote x)
  1105   else (true, (x, T, mx));
  1106 
  1107 fun gen_fixes prep raw_vars ctxt =
  1108   let
  1109     val (vars, _) = prep raw_vars ctxt;
  1110     val (xs', ctxt') = Variable.add_fixes (map (Name.name_of o #1) vars) ctxt;
  1111     val ctxt'' =
  1112       ctxt'
  1113       |> fold_map declare_var (map2 (fn x' => fn (_, T, mx) => (x', T, mx)) xs' vars)
  1114       |-> (map_syntax o LocalSyntax.add_syntax (theory_of ctxt) o map prep_mixfix);
  1115     val _ = (vars ~~ xs') |> List.app (fn ((binding, _, _), x') =>
  1116       Position.report (Markup.fixed_decl x') (Name.pos_of binding));
  1117   in (xs', ctxt'') end;
  1118 
  1119 in
  1120 
  1121 val add_fixes = gen_fixes read_vars;
  1122 val add_fixes_i = gen_fixes cert_vars;
  1123 
  1124 end;
  1125 
  1126 
  1127 (* fixes vs. frees *)
  1128 
  1129 fun auto_fixes (arg as (ctxt, (propss, x))) =
  1130   ((fold o fold) Variable.auto_fixes propss ctxt, (propss, x));
  1131 
  1132 fun bind_fixes xs ctxt =
  1133   let
  1134     val (_, ctxt') = ctxt |> add_fixes_i (map (fn x => (Name.binding x, NONE, NoSyn)) xs);
  1135     fun bind (t as Free (x, T)) =
  1136           if member (op =) xs x then
  1137             (case lookup_skolem ctxt' x of SOME x' => Free (x', T) | NONE => t)
  1138           else t
  1139       | bind (t $ u) = bind t $ bind u
  1140       | bind (Abs (x, T, t)) = Abs (x, T, bind t)
  1141       | bind a = a;
  1142   in (bind, ctxt') end;
  1143 
  1144 
  1145 
  1146 (** assumptions **)
  1147 
  1148 local
  1149 
  1150 fun gen_assms prepp exp args ctxt =
  1151   let
  1152     val cert = Thm.cterm_of (theory_of ctxt);
  1153     val (propss, ctxt1) = swap (prepp (ctxt, map snd args));
  1154     val _ = Variable.warn_extra_tfrees ctxt ctxt1;
  1155     val (premss, ctxt2) = fold_burrow (Assumption.add_assms exp o map cert) propss ctxt1;
  1156   in
  1157     ctxt2
  1158     |> auto_bind_facts (flat propss)
  1159     |> note_thmss_i Thm.assumptionK (map fst args ~~ map (map (fn th => ([th], []))) premss)
  1160   end;
  1161 
  1162 in
  1163 
  1164 val add_assms = gen_assms (apsnd #1 o bind_propp);
  1165 val add_assms_i = gen_assms (apsnd #1 o bind_propp_i);
  1166 
  1167 end;
  1168 
  1169 
  1170 
  1171 (** cases **)
  1172 
  1173 local
  1174 
  1175 fun rem_case name = remove (fn (x: string, (y, _)) => x = y) name;
  1176 
  1177 fun add_case _ ("", _) cases = cases
  1178   | add_case _ (name, NONE) cases = rem_case name cases
  1179   | add_case is_proper (name, SOME c) cases = (name, (c, is_proper)) :: rem_case name cases;
  1180 
  1181 fun prep_case name fxs c =
  1182   let
  1183     fun replace (opt_x :: xs) ((y, T) :: ys) = (the_default y opt_x, T) :: replace xs ys
  1184       | replace [] ys = ys
  1185       | replace (_ :: _) [] = error ("Too many parameters for case " ^ quote name);
  1186     val RuleCases.Case {fixes, assumes, binds, cases} = c;
  1187     val fixes' = replace fxs fixes;
  1188     val binds' = map drop_schematic binds;
  1189   in
  1190     if null (fold (Term.add_tvarsT o snd) fixes []) andalso
  1191       null (fold (fold Term.add_vars o snd) assumes []) then
  1192         RuleCases.Case {fixes = fixes', assumes = assumes, binds = binds', cases = cases}
  1193     else error ("Illegal schematic variable(s) in case " ^ quote name)
  1194   end;
  1195 
  1196 fun fix (x, T) ctxt =
  1197   let
  1198     val (bind, ctxt') = bind_fixes [x] ctxt;
  1199     val t = bind (Free (x, T));
  1200   in (t, ctxt' |> Variable.declare_constraints t) end;
  1201 
  1202 in
  1203 
  1204 fun add_cases is_proper = map_cases o fold (add_case is_proper);
  1205 
  1206 fun case_result c ctxt =
  1207   let
  1208     val RuleCases.Case {fixes, ...} = c;
  1209     val (ts, ctxt') = ctxt |> fold_map fix fixes;
  1210     val RuleCases.Case {assumes, binds, cases, ...} = RuleCases.apply ts c;
  1211   in
  1212     ctxt'
  1213     |> add_binds_i (map drop_schematic binds)
  1214     |> add_cases true (map (apsnd SOME) cases)
  1215     |> pair (assumes, (binds, cases))
  1216   end;
  1217 
  1218 val apply_case = apfst fst oo case_result;
  1219 
  1220 fun get_case ctxt name xs =
  1221   (case AList.lookup (op =) (cases_of ctxt) name of
  1222     NONE => error ("Unknown case: " ^ quote name)
  1223   | SOME (c, _) => prep_case name xs c);
  1224 
  1225 end;
  1226 
  1227 
  1228 
  1229 (** print context information **)
  1230 
  1231 val debug = ref false;
  1232 
  1233 val verbose = ref false;
  1234 fun verb f x = if ! verbose then f (x ()) else [];
  1235 
  1236 fun setmp_verbose f x = Library.setmp verbose true f x;
  1237 
  1238 
  1239 (* local syntax *)
  1240 
  1241 val print_syntax = Syntax.print_syntax o syn_of;
  1242 
  1243 
  1244 (* abbreviations *)
  1245 
  1246 fun pretty_abbrevs show_globals ctxt =
  1247   let
  1248     val ((space, consts), (_, globals)) =
  1249       pairself (#constants o Consts.dest) (#consts (rep_context ctxt));
  1250     fun add_abbr (_, (_, NONE)) = I
  1251       | add_abbr (c, (T, SOME t)) =
  1252           if not show_globals andalso Symtab.defined globals c then I
  1253           else cons (c, Logic.mk_equals (Const (c, T), t));
  1254     val abbrevs = NameSpace.extern_table (space, Symtab.make (Symtab.fold add_abbr consts []));
  1255   in
  1256     if null abbrevs andalso not (! verbose) then []
  1257     else [Pretty.big_list "abbreviations:" (map (pretty_term_abbrev ctxt o #2) abbrevs)]
  1258   end;
  1259 
  1260 val print_abbrevs = Pretty.writeln o Pretty.chunks o pretty_abbrevs true;
  1261 
  1262 
  1263 (* term bindings *)
  1264 
  1265 fun pretty_binds ctxt =
  1266   let
  1267     val binds = Variable.binds_of ctxt;
  1268     fun prt_bind (xi, (T, t)) = pretty_term_abbrev ctxt (Logic.mk_equals (Var (xi, T), t));
  1269   in
  1270     if Vartab.is_empty binds andalso not (! verbose) then []
  1271     else [Pretty.big_list "term bindings:" (map prt_bind (Vartab.dest binds))]
  1272   end;
  1273 
  1274 val print_binds = Pretty.writeln o Pretty.chunks o pretty_binds;
  1275 
  1276 
  1277 (* local theorems *)
  1278 
  1279 fun pretty_lthms ctxt =
  1280   let
  1281     val local_facts = facts_of ctxt;
  1282     val props = Facts.props local_facts;
  1283     val facts =
  1284       (if null props then [] else [("unnamed", props)]) @
  1285       Facts.dest_static [] local_facts;
  1286   in
  1287     if null facts andalso not (! verbose) then []
  1288     else [Pretty.big_list "facts:" (map #1 (sort_wrt (#1 o #2) (map (`(pretty_fact ctxt)) facts)))]
  1289   end;
  1290 
  1291 val print_lthms = Pretty.writeln o Pretty.chunks o pretty_lthms;
  1292 
  1293 
  1294 (* local contexts *)
  1295 
  1296 local
  1297 
  1298 fun pretty_case (name, (fixes, ((asms, (lets, cs)), ctxt))) =
  1299   let
  1300     val prt_term = Syntax.pretty_term ctxt;
  1301 
  1302     fun prt_let (xi, t) = Pretty.block
  1303       [Pretty.quote (prt_term (Var (xi, Term.fastype_of t))), Pretty.str " =", Pretty.brk 1,
  1304         Pretty.quote (prt_term t)];
  1305 
  1306     fun prt_asm (a, ts) = Pretty.block (Pretty.breaks
  1307       ((if a = "" then [] else [Pretty.str (a ^ ":")]) @ map (Pretty.quote o prt_term) ts));
  1308 
  1309     fun prt_sect _ _ _ [] = []
  1310       | prt_sect s sep prt xs = [Pretty.block (Pretty.breaks (Pretty.str s ::
  1311             flat (Library.separate sep (map (Library.single o prt) xs))))];
  1312   in
  1313     Pretty.block (Pretty.fbreaks
  1314       (Pretty.str (name ^ ":") ::
  1315         prt_sect "fix" [] (Pretty.str o fst) fixes @
  1316         prt_sect "let" [Pretty.str "and"] prt_let
  1317           (map_filter (fn (xi, SOME t) => SOME (xi, t) | _ => NONE) lets) @
  1318         (if forall (null o #2) asms then []
  1319           else prt_sect "assume" [Pretty.str "and"] prt_asm asms) @
  1320         prt_sect "subcases:" [] (Pretty.str o fst) cs))
  1321   end;
  1322 
  1323 in
  1324 
  1325 fun pretty_cases ctxt =
  1326   let
  1327     fun add_case (_, (_, false)) = I
  1328       | add_case (name, (c as RuleCases.Case {fixes, ...}, true)) =
  1329           cons (name, (fixes, case_result c ctxt));
  1330     val cases = fold add_case (cases_of ctxt) [];
  1331   in
  1332     if null cases andalso not (! verbose) then []
  1333     else [Pretty.big_list "cases:" (map pretty_case cases)]
  1334   end;
  1335 
  1336 val print_cases = Pretty.writeln o Pretty.chunks o pretty_cases;
  1337 
  1338 end;
  1339 
  1340 
  1341 (* core context *)
  1342 
  1343 val prems_limit = ref ~1;
  1344 
  1345 fun pretty_ctxt ctxt =
  1346   if ! prems_limit < 0 andalso not (! debug) then []
  1347   else
  1348     let
  1349       val prt_term = Syntax.pretty_term ctxt;
  1350 
  1351       (*structures*)
  1352       val structs = LocalSyntax.structs_of (syntax_of ctxt);
  1353       val prt_structs = if null structs then []
  1354         else [Pretty.block (Pretty.str "structures:" :: Pretty.brk 1 ::
  1355           Pretty.commas (map Pretty.str structs))];
  1356 
  1357       (*fixes*)
  1358       fun prt_fix (x, x') =
  1359         if x = x' then Pretty.str x
  1360         else Pretty.block [Pretty.str x, Pretty.str " =", Pretty.brk 1, prt_term (Syntax.free x')];
  1361       val fixes =
  1362         rev (filter_out ((can Name.dest_internal orf member (op =) structs) o #1)
  1363           (Variable.fixes_of ctxt));
  1364       val prt_fixes = if null fixes then []
  1365         else [Pretty.block (Pretty.str "fixed variables:" :: Pretty.brk 1 ::
  1366           Pretty.commas (map prt_fix fixes))];
  1367 
  1368       (*prems*)
  1369       val prems = Assumption.prems_of ctxt;
  1370       val len = length prems;
  1371       val suppressed = len - ! prems_limit;
  1372       val prt_prems = if null prems then []
  1373         else [Pretty.big_list "prems:" ((if suppressed <= 0 then [] else [Pretty.str "..."]) @
  1374           map (pretty_thm ctxt) (Library.drop (suppressed, prems)))];
  1375     in prt_structs @ prt_fixes @ prt_prems end;
  1376 
  1377 
  1378 (* main context *)
  1379 
  1380 fun pretty_context ctxt =
  1381   let
  1382     val prt_term = Syntax.pretty_term ctxt;
  1383     val prt_typ = Syntax.pretty_typ ctxt;
  1384     val prt_sort = Syntax.pretty_sort ctxt;
  1385 
  1386     (*theory*)
  1387     val pretty_thy = Pretty.block
  1388       [Pretty.str "theory:", Pretty.brk 1, Context.pretty_thy (theory_of ctxt)];
  1389 
  1390     (*defaults*)
  1391     fun prt_atom prt prtT (x, X) = Pretty.block
  1392       [prt x, Pretty.str " ::", Pretty.brk 1, prtT X];
  1393 
  1394     fun prt_var (x, ~1) = prt_term (Syntax.free x)
  1395       | prt_var xi = prt_term (Syntax.var xi);
  1396 
  1397     fun prt_varT (x, ~1) = prt_typ (TFree (x, []))
  1398       | prt_varT xi = prt_typ (TVar (xi, []));
  1399 
  1400     val prt_defT = prt_atom prt_var prt_typ;
  1401     val prt_defS = prt_atom prt_varT prt_sort;
  1402 
  1403     val (types, sorts) = Variable.constraints_of ctxt;
  1404   in
  1405     verb single (K pretty_thy) @
  1406     pretty_ctxt ctxt @
  1407     verb (pretty_abbrevs false) (K ctxt) @
  1408     verb pretty_binds (K ctxt) @
  1409     verb pretty_lthms (K ctxt) @
  1410     verb pretty_cases (K ctxt) @
  1411     verb single (fn () => Pretty.big_list "type constraints:" (map prt_defT (Vartab.dest types))) @
  1412     verb single (fn () => Pretty.big_list "default sorts:" (map prt_defS (Vartab.dest sorts)))
  1413   end;
  1414 
  1415 
  1416 (* query meta data *)
  1417 
  1418 val query_type = Type.the_tags o tsig_of;
  1419 
  1420 fun query_const ctxt name =
  1421   Consts.the_tags (consts_of ctxt) name handle TYPE (msg, _, _) => error msg;
  1422 
  1423 fun query_class ctxt name = query_const ctxt (Logic.const_of_class name);
  1424 
  1425 end;