src/Pure/pure_thy.ML
author ballarin
Thu Mar 24 17:03:37 2005 +0100 (2005-03-24 ago)
changeset 15624 484178635bd8
parent 15570 8d8c70b41bab
child 15696 1da4ce092c0b
permissions -rw-r--r--
Further work on interpretation commands. New command `interpret' for
interpretation in proof contexts.
     1 (*  Title:      Pure/pure_thy.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Theorem database, derived theory operations, and the ProtoPure theory.
     6 *)
     7 
     8 signature BASIC_PURE_THY =
     9 sig
    10   type thmref
    11   val print_theorems: theory -> unit
    12   val print_theory: theory -> unit
    13   val get_thm: theory -> thmref -> thm
    14   val get_thms: theory -> thmref -> thm list
    15   val get_thmss: theory -> thmref list -> thm list
    16   val thms_of: theory -> (string * thm) list
    17   structure ProtoPure:
    18     sig
    19       val thy: theory
    20       val Goal_def: thm
    21     end
    22 end;
    23 
    24 signature PURE_THY =
    25 sig
    26   include BASIC_PURE_THY
    27   val get_thm_closure: theory -> thmref -> thm
    28   val get_thms_closure: theory -> thmref -> thm list
    29   val single_thm: string -> thm list -> thm
    30   val select_thm: thmref -> thm list -> thm list
    31   val cond_extern_thm_sg: Sign.sg -> string -> xstring
    32   val thms_containing: theory -> string list * string list -> (string * thm list) list
    33   val thms_containing_consts: theory -> string list -> (string * thm) list
    34   val find_matching_thms: (thm -> thm list) * (term -> term)
    35         -> theory -> term -> (string * thm) list
    36   val find_intros: theory -> term -> (string * thm) list
    37   val find_intros_goal : theory -> thm -> int -> (string * thm) list
    38   val find_elims : theory -> term -> (string * thm) list
    39   val hide_thms: bool -> string list -> theory -> theory
    40   val store_thm: (bstring * thm) * theory attribute list -> theory -> theory * thm
    41   val smart_store_thms: (bstring * thm list) -> thm list
    42   val smart_store_thms_open: (bstring * thm list) -> thm list
    43   val forall_elim_var: int -> thm -> thm
    44   val forall_elim_vars: int -> thm -> thm
    45   val add_thms: ((bstring * thm) * theory attribute list) list -> theory -> theory * thm list
    46   val add_thmss: ((bstring * thm list) * theory attribute list) list -> theory
    47     -> theory * thm list list
    48   val note_thmss:
    49     theory attribute -> ((bstring * theory attribute list) *
    50     (thmref * theory attribute list) list) list -> theory ->
    51     theory * (bstring * thm list) list
    52   val note_thmss_i:
    53     theory attribute -> ((bstring * theory attribute list) *
    54     (thm list * theory attribute list) list) list -> theory ->
    55     theory * (bstring * thm list) list
    56   val note_thmss_qualified:
    57     (string -> string list) ->
    58     theory attribute -> ((bstring * theory attribute list) *
    59     (thmref * theory attribute list) list) list -> theory ->
    60     theory * (bstring * thm list) list
    61   val note_thmss_qualified_i:
    62     (string -> string list) ->
    63     theory attribute -> ((bstring * theory attribute list) *
    64     (thm list * theory attribute list) list) list -> theory ->
    65     theory * (bstring * thm list) list
    66   val add_axioms: ((bstring * string) * theory attribute list) list -> theory -> theory * thm list
    67   val add_axioms_i: ((bstring * term) * theory attribute list) list -> theory -> theory * thm list
    68   val add_axiomss: ((bstring * string list) * theory attribute list) list -> theory
    69     -> theory * thm list list
    70   val add_axiomss_i: ((bstring * term list) * theory attribute list) list -> theory
    71     -> theory * thm list list
    72   val add_defs: bool -> ((bstring * string) * theory attribute list) list
    73     -> theory -> theory * thm list
    74   val add_defs_i: bool -> ((bstring * term) * theory attribute list) list
    75     -> theory -> theory * thm list
    76   val add_defss: bool -> ((bstring * string list) * theory attribute list) list
    77     -> theory -> theory * thm list list
    78   val add_defss_i: bool -> ((bstring * term list) * theory attribute list) list
    79     -> theory -> theory * thm list list
    80   val get_name: theory -> string
    81   val put_name: string -> theory -> theory
    82   val global_path: theory -> theory
    83   val local_path: theory -> theory
    84   val begin_theory: string -> theory list -> theory
    85   val end_theory: theory -> theory
    86   val checkpoint: theory -> theory
    87   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    88 end;
    89 
    90 structure PureThy: PURE_THY =
    91 struct
    92 
    93 
    94 (*** theorem database ***)
    95 
    96 (** data kind 'Pure/theorems' **)
    97 
    98 structure TheoremsDataArgs =
    99 struct
   100   val name = "Pure/theorems";
   101 
   102   type T =
   103     {space: NameSpace.T,
   104       thms_tab: thm list Symtab.table,
   105       index: FactIndex.T} ref;
   106 
   107   fun mk_empty _ =
   108     ref {space = NameSpace.empty, thms_tab = Symtab.empty, index = FactIndex.empty}: T;
   109 
   110   val empty = mk_empty ();
   111   fun copy (ref x) = ref x;
   112   val prep_ext = mk_empty;
   113   val merge = mk_empty;
   114 
   115   fun pretty sg (ref {space, thms_tab, index = _}) =
   116     let
   117       val prt_thm = Display.pretty_thm_sg sg;
   118       fun prt_thms (name, [th]) =
   119             Pretty.block [Pretty.str (name ^ ":"), Pretty.brk 1, prt_thm th]
   120         | prt_thms (name, ths) = Pretty.big_list (name ^ ":") (map prt_thm ths);
   121 
   122       val thmss = NameSpace.cond_extern_table space thms_tab;
   123     in Pretty.big_list "theorems:" (map prt_thms thmss) end;
   124 
   125   fun print sg data = Pretty.writeln (pretty sg data);
   126 end;
   127 
   128 structure TheoremsData = TheoryDataFun(TheoremsDataArgs);
   129 val get_theorems_sg = TheoremsData.get_sg;
   130 val get_theorems = TheoremsData.get;
   131 
   132 val cond_extern_thm_sg = NameSpace.cond_extern o #space o ! o get_theorems_sg;
   133 
   134 
   135 (* print theory *)
   136 
   137 val print_theorems = TheoremsData.print;
   138 
   139 fun print_theory thy =
   140   Display.pretty_full_theory thy @
   141   [TheoremsDataArgs.pretty (Theory.sign_of thy) (get_theorems thy)]
   142   |> Pretty.chunks |> Pretty.writeln;
   143 
   144 
   145 
   146 (** retrieve theorems **)
   147 
   148 type thmref = xstring * int list option;
   149 
   150 (* selections *)
   151 
   152 fun the_thms _ (SOME thms) = thms
   153   | the_thms name NONE = error ("Unknown theorem(s) " ^ quote name);
   154 
   155 fun single_thm _ [thm] = thm
   156   | single_thm name _ = error ("Single theorem expected " ^ quote name);
   157 
   158 fun select_thm (s, NONE) xs = xs
   159   | select_thm (s, SOME is) xs = map
   160       (fn i => (if i < 1 then raise Subscript else List.nth (xs, i-1)) handle Subscript =>
   161          error ("Bad subscript " ^ string_of_int i ^ " for " ^ quote s)) is;
   162 
   163 
   164 (* get_thm(s)_closure -- statically scoped versions *)
   165 
   166 (*beware of proper order of evaluation!*)
   167 
   168 fun lookup_thms thy =
   169   let
   170     val sg_ref = Sign.self_ref (Theory.sign_of thy);
   171     val ref {space, thms_tab, ...} = get_theorems thy;
   172   in
   173     fn name =>
   174       Option.map (map (Thm.transfer_sg (Sign.deref sg_ref)))        (*semi-dynamic identity*)
   175       (Symtab.lookup (thms_tab, NameSpace.intern space name))   (*static content*)
   176   end;
   177 
   178 fun get_thms_closure thy =
   179   let val closures = map lookup_thms (thy :: Theory.ancestors_of thy)
   180   in fn namei as (name, _) => select_thm namei
   181     (the_thms name (get_first (fn f => f name) closures))
   182   end;
   183 
   184 fun get_thm_closure thy =
   185   let val get = get_thms_closure thy
   186   in fn namei as (name, _) => single_thm name (get namei) end;
   187 
   188 
   189 (* get_thm etc. *)
   190 
   191 fun get_thms theory (namei as (name, _)) =
   192   get_first (fn thy => lookup_thms thy name) (theory :: Theory.ancestors_of theory)
   193   |> the_thms name |> select_thm namei |> map (Thm.transfer theory);
   194 
   195 fun get_thmss thy names = List.concat (map (get_thms thy) names);
   196 fun get_thm thy (namei as (name, _)) = single_thm name (get_thms thy namei);
   197 
   198 
   199 (* thms_of *)
   200 
   201 fun thms_of thy =
   202   let val ref {thms_tab, ...} = get_theorems thy in
   203     map (fn th => (Thm.name_of_thm th, th)) (List.concat (map snd (Symtab.dest thms_tab)))
   204   end;
   205 
   206 
   207 (* thms_containing *)
   208 
   209 fun thms_containing thy idx =
   210   let
   211     fun valid (name, ths) =
   212       (case try (transform_error (get_thms thy)) (name, NONE) of
   213         NONE => false
   214       | SOME ths' => Library.equal_lists Thm.eq_thm (ths, ths'));
   215   in
   216     (thy :: Theory.ancestors_of thy)
   217     |> map (gen_distinct eq_fst o List.filter valid o FactIndex.find idx o #index o ! o get_theorems)
   218     |> List.concat
   219   end;
   220 
   221 fun thms_containing_consts thy consts =
   222   thms_containing thy (consts, []) |> map #2 |> List.concat
   223   |> map (fn th => (Thm.name_of_thm th, th))
   224 
   225 (* intro/elim theorems *)
   226 
   227 (* intro: given a goal state, find a suitable intro rule for some subgoal *)
   228 (* elim: given a theorem thm,
   229          find a theorem whose major premise eliminates the conclusion of thm *)
   230 
   231 fun top_const t = (case head_of t of Const (c, _) => SOME c | _ => NONE);
   232 
   233 (* This is a hack to remove the Trueprop constant that most logics use *)
   234 fun rem_top (_ $ t) = t
   235   | rem_top _ = Bound 0 (* does not match anything *)
   236 
   237 (*returns all those named_thms whose subterm extracted by extract can be
   238   instantiated to obj; the list is sorted according to the number of premises
   239   and the size of the required substitution.*)
   240 fun select_match(c,obj, signobj, named_thms, (extract_thms,extract_term)) =
   241   let val tsig = Sign.tsig_of signobj
   242       fun matches prop =
   243         let val pat = extract_term prop
   244         in case head_of pat of
   245              Const(d,_) => c=d andalso Pattern.matches tsig (pat,obj)
   246            | _ => false
   247         end
   248 
   249       fun substsize prop =
   250             let val pat = extract_term prop
   251                 val (_,subst) = Pattern.match tsig (pat,obj)
   252             in Library.foldl op+ (0, map (size_of_term o snd) subst) end
   253 
   254       fun thm_ord ((p0,s0,_),(p1,s1,_)) =
   255             prod_ord (int_ord o pairself (fn 0 => 0 | x => 1)) int_ord ((p0,s0),(p1,s1));
   256 
   257       fun select((p as (_,thm))::named_thms, sels) =
   258             let
   259               fun sel(thm::thms,sels) =     
   260                     let val {prop, ...} = rep_thm thm
   261                     in if matches prop
   262                        then (nprems_of thm,substsize prop,p)::sels
   263                        else sel(thms,sels)
   264                     end
   265                 | sel([],sels) = sels
   266              val {sign, ...} = rep_thm thm
   267            in select(named_thms,if Sign.subsig(sign, signobj)
   268                                 then sel(extract_thms thm,sels)
   269                                 else sels)
   270            end
   271         | select([],sels) = sels
   272 
   273   in map (fn (_,_,t) => t) (sort thm_ord (select(named_thms, []))) end;
   274 
   275 fun find_matching_thms extract thy prop =
   276   (case top_const prop of NONE => []
   277    | SOME c => let val thms = thms_containing_consts thy [c]
   278                in select_match(c,prop,Theory.sign_of thy,thms,extract) end)
   279 
   280 val find_intros =
   281   find_matching_thms (single, rem_top o Logic.strip_imp_concl)
   282 
   283 fun find_intros_goal thy st i =
   284   find_intros thy (rem_top(Logic.concl_of_goal (prop_of st) i));
   285 
   286 val find_elims = find_matching_thms
   287   (fn thm => if Thm.no_prems thm then [] else [thm],
   288    rem_top o hd o Logic.strip_imp_prems)
   289 
   290 
   291 (** store theorems **)                    (*DESTRUCTIVE*)
   292 
   293 (* hiding -- affects current theory node only! *)
   294 
   295 fun hide_thms fully names thy =
   296   let
   297     val r as ref {space, thms_tab, index} = get_theorems thy;
   298     val space' = NameSpace.hide fully (space, names);
   299   in r := {space = space', thms_tab = thms_tab, index = index}; thy end;
   300 
   301 
   302 (* naming *)
   303 
   304 fun gen_names j len name =
   305   map (fn i => name ^ "_" ^ string_of_int i) (j+1 upto j+len);
   306 
   307 fun name_multi name xs = gen_names 0 (length xs) name ~~ xs;
   308 
   309 fun name_thm pre (p as (_, thm)) =
   310   if Thm.name_of_thm thm <> "" andalso pre then thm else Thm.name_thm p;
   311 
   312 fun name_thms pre name [x] = [name_thm pre (name, x)]
   313   | name_thms pre name xs = map (name_thm pre) (name_multi name xs);
   314 
   315 fun name_thmss name xs = (case filter_out (null o fst) xs of
   316     [([x], z)] => [([name_thm true (name, x)], z)]
   317   | _ => snd (foldl_map (fn (i, (ys, z)) => (i + length ys,
   318   (map (name_thm true) (gen_names i (length ys) name ~~ ys), z))) (0, xs)));
   319 
   320 
   321 (* enter_thms *)
   322 
   323 fun warn_overwrite name = warning ("Replaced old copy of theorems " ^ quote name);
   324 fun warn_same name = warning ("Theorem database already contains a copy of " ^ quote name);
   325 
   326 fun gen_enter_thms _ _ _ _ _ app_att thy ("", thms) = app_att (thy, thms)
   327   | gen_enter_thms full acc sg pre_name post_name app_att thy (bname, thms) =
   328       let
   329         val name = full sg bname;
   330         val (thy', thms') = app_att (thy, pre_name name thms);
   331         val named_thms = post_name name thms';
   332 
   333         val r as ref {space, thms_tab, index} = get_theorems_sg sg;
   334         val space' = NameSpace.extend' acc (space, [name]);
   335         val thms_tab' = Symtab.update ((name, named_thms), thms_tab);
   336         val index' = FactIndex.add (K false) (index, (name, named_thms));
   337       in
   338         (case Symtab.lookup (thms_tab, name) of
   339           NONE => ()
   340         | SOME thms' =>
   341             if Library.equal_lists Thm.eq_thm (thms', named_thms) then warn_same name
   342             else warn_overwrite name);
   343         r := {space = space', thms_tab = thms_tab', index = index'};
   344         (thy', named_thms)
   345       end;
   346 
   347 fun enter_thms sg = gen_enter_thms Sign.full_name NameSpace.accesses sg;
   348 
   349 (* add_thms(s) *)
   350 
   351 fun add_thms_atts pre_name ((bname, thms), atts) thy =
   352   enter_thms (Theory.sign_of thy) pre_name (name_thms false)
   353     (Thm.applys_attributes o rpair atts) thy (bname, thms);
   354 
   355 fun gen_add_thmss pre_name args theory =
   356   foldl_map (fn (thy, arg) => add_thms_atts pre_name arg thy) (theory, args);
   357 
   358 fun gen_add_thms pre_name args =
   359   apsnd (map hd) o gen_add_thmss pre_name (map (apfst (apsnd single)) args);
   360 
   361 val add_thmss = gen_add_thmss (name_thms true);
   362 val add_thms = gen_add_thms (name_thms true);
   363 
   364 
   365 (* note_thmss(_i) *)
   366 
   367 local
   368 
   369 fun gen_note_thss enter get kind_att (thy, ((bname, more_atts), ths_atts)) =
   370   let
   371     fun app (x, (ths, atts)) = Thm.applys_attributes ((x, ths), atts);
   372     val (thy', thms) = enter (Theory.sign_of thy)
   373       name_thmss (name_thms false) (apsnd List.concat o foldl_map app) thy
   374       (bname, map (fn (ths, atts) => (get thy ths, atts @ more_atts @ [kind_att])) ths_atts);
   375   in (thy', (bname, thms)) end;
   376 
   377 fun gen_note_thmss enter get kind_att args thy =
   378   foldl_map (gen_note_thss enter get kind_att) (thy, args);
   379 
   380 in
   381 
   382 (* if path is set, only permit unqualified names *)
   383 
   384 val note_thmss = gen_note_thmss enter_thms get_thms;
   385 val note_thmss_i = gen_note_thmss enter_thms (K I);
   386 
   387 (* always permit qualified names,
   388    clients may specify non-standard access policy *)
   389 
   390 fun note_thmss_qualified acc =
   391   gen_note_thmss (gen_enter_thms Sign.full_name' acc) get_thms;
   392 fun note_thmss_qualified_i acc =
   393   gen_note_thmss (gen_enter_thms Sign.full_name' acc) (K I);
   394 
   395 end;
   396 
   397 
   398 (* store_thm *)
   399 
   400 fun store_thm ((bname, thm), atts) thy =
   401   let val (thy', [th']) = add_thms_atts (name_thms true) ((bname, [thm]), atts) thy
   402   in (thy', th') end;
   403 
   404 
   405 (* smart_store_thms *)
   406 
   407 fun gen_smart_store_thms _ (name, []) =
   408       error ("Cannot store empty list of theorems: " ^ quote name)
   409   | gen_smart_store_thms name_thm (name, [thm]) =
   410       snd (enter_thms (Thm.sign_of_thm thm) (name_thm true) (name_thm false)
   411         I () (name, [thm]))
   412   | gen_smart_store_thms name_thm (name, thms) =
   413       let
   414         val merge_sg = Sign.merge_refs o apsnd (Sign.self_ref o Thm.sign_of_thm);
   415         val sg_ref = Library.foldl merge_sg (Sign.self_ref (Thm.sign_of_thm (hd thms)), tl thms);
   416       in snd (enter_thms (Sign.deref sg_ref) (name_thm true) (name_thm false)
   417         I () (name, thms))
   418       end;
   419 
   420 val smart_store_thms = gen_smart_store_thms name_thms;
   421 val smart_store_thms_open = gen_smart_store_thms (K (K I));
   422 
   423 
   424 (* forall_elim_vars (belongs to drule.ML) *)
   425 
   426 (*Replace outermost quantified variable by Var of given index.*)
   427 fun forall_elim_var i th =
   428     let val {prop,sign,...} = rep_thm th
   429     in case prop of
   430         Const ("all", _) $ Abs (a, T, _) =>
   431           let val used = map (fst o fst)
   432             (List.filter (equal i o snd o fst) (Term.add_vars ([], prop)))
   433           in forall_elim (cterm_of sign (Var ((variant used a, i), T))) th end
   434       | _ => raise THM ("forall_elim_var", i, [th])
   435     end;
   436 
   437 (*Repeat forall_elim_var until all outer quantifiers are removed*)
   438 fun forall_elim_vars i th =
   439     forall_elim_vars i (forall_elim_var i th)
   440         handle THM _ => th;
   441 
   442 
   443 (* store axioms as theorems *)
   444 
   445 local
   446   fun get_axs thy named_axs =
   447     map (forall_elim_vars 0 o Thm.get_axiom thy o fst) named_axs;
   448 
   449   fun add_single add (thy, ((name, ax), atts)) =
   450     let
   451       val named_ax = [(name, ax)];
   452       val thy' = add named_ax thy;
   453       val thm = hd (get_axs thy' named_ax);
   454     in apsnd hd (gen_add_thms (K I) [((name, thm), atts)] thy') end;
   455 
   456   fun add_multi add (thy, ((name, axs), atts)) =
   457     let
   458       val named_axs = name_multi name axs;
   459       val thy' = add named_axs thy;
   460       val thms = get_axs thy' named_axs;
   461     in apsnd hd (gen_add_thmss (K I) [((name, thms), atts)] thy') end;
   462 
   463   fun add_singles add args thy = foldl_map (add_single add) (thy, args);
   464   fun add_multis add args thy = foldl_map (add_multi add) (thy, args);
   465 in
   466   val add_axioms    = add_singles Theory.add_axioms;
   467   val add_axioms_i  = add_singles Theory.add_axioms_i;
   468   val add_axiomss   = add_multis Theory.add_axioms;
   469   val add_axiomss_i = add_multis Theory.add_axioms_i;
   470   val add_defs      = add_singles o Theory.add_defs;
   471   val add_defs_i    = add_singles o Theory.add_defs_i;
   472   val add_defss     = add_multis o Theory.add_defs;
   473   val add_defss_i   = add_multis o Theory.add_defs_i;
   474 end;
   475 
   476 
   477 
   478 (*** derived theory operations ***)
   479 
   480 (** theory management **)
   481 
   482 (* data kind 'Pure/theory_management' *)
   483 
   484 structure TheoryManagementDataArgs =
   485 struct
   486   val name = "Pure/theory_management";
   487   type T = {name: string, version: int};
   488 
   489   val empty = {name = "", version = 0};
   490   val copy = I;
   491   val prep_ext  = I;
   492   fun merge _ = empty;
   493   fun print _ _ = ();
   494 end;
   495 
   496 structure TheoryManagementData = TheoryDataFun(TheoryManagementDataArgs);
   497 val get_info = TheoryManagementData.get;
   498 val put_info = TheoryManagementData.put;
   499 
   500 
   501 (* get / put name *)
   502 
   503 val get_name = #name o get_info;
   504 fun put_name name = put_info {name = name, version = 0};
   505 
   506 
   507 (* control prefixing of theory name *)
   508 
   509 val global_path = Theory.root_path;
   510 
   511 fun local_path thy =
   512   thy |> Theory.root_path |> Theory.add_path (get_name thy);
   513 
   514 
   515 (* begin / end theory *)
   516 
   517 fun begin_theory name thys =
   518   Theory.prep_ext_merge thys
   519   |> put_name name
   520   |> local_path;
   521 
   522 fun end_theory thy =
   523   thy
   524   |> Theory.add_name (get_name thy);
   525 
   526 fun checkpoint thy =
   527   if is_draft thy then
   528     let val {name, version} = get_info thy in
   529       thy
   530       |> Theory.add_name (name ^ ":" ^ string_of_int version)
   531       |> put_info {name = name, version = version + 1}
   532     end
   533   else thy;
   534 
   535 
   536 
   537 (** add logical types **)
   538 
   539 fun add_typedecls decls thy =
   540   let
   541     val full = Sign.full_name (Theory.sign_of thy);
   542 
   543     fun type_of (raw_name, vs, mx) =
   544       if null (duplicates vs) then (raw_name, length vs, mx)
   545       else error ("Duplicate parameters in type declaration: " ^ quote raw_name);
   546   in thy |> Theory.add_types (map type_of decls) end;
   547 
   548 
   549 
   550 (*** the ProtoPure theory ***)
   551 
   552 
   553 (*It might make sense to restrict the polymorphism of the constant "==" to
   554   sort logic, instead of the universal sort, {}.  Unfortunately, this change
   555   causes HOL/Import/shuffler.ML to fail.*)
   556 
   557 val proto_pure =
   558   Theory.pre_pure
   559   |> Library.apply [TheoremsData.init, TheoryManagementData.init, Proofterm.init]
   560   |> put_name "ProtoPure"
   561   |> global_path
   562   |> Theory.add_types
   563    [("fun", 2, NoSyn),
   564     ("prop", 0, NoSyn),
   565     ("itself", 1, NoSyn),
   566     ("dummy", 0, NoSyn)]
   567   |> Theory.add_nonterminals Syntax.pure_nonterms
   568   |> Theory.add_syntax Syntax.pure_syntax
   569   |> Theory.add_modesyntax (Symbol.xsymbolsN, true) Syntax.pure_xsym_syntax
   570   |> Theory.add_syntax
   571    [("==>", "[prop, prop] => prop", Delimfix "op ==>"),
   572     (Term.dummy_patternN, "aprop", Delimfix "'_")]
   573   |> Theory.add_consts
   574    [("==", "['a, 'a] => prop", InfixrName ("==", 2)),
   575     ("==>", "[prop, prop] => prop", Mixfix ("(_/ ==> _)", [2, 1], 1)),
   576     ("all", "('a => prop) => prop", Binder ("!!", 0, 0)),
   577     ("Goal", "prop => prop", NoSyn),
   578     ("TYPE", "'a itself", NoSyn),
   579     (Term.dummy_patternN, "'a", Delimfix "'_")]
   580   |> Theory.add_finals_i false
   581     [Const("==", [TFree ("'a", []), TFree ("'a", [])] ---> propT),
   582      Const("==>", [propT, propT] ---> propT),
   583      Const("all", (TFree("'a", []) --> propT) --> propT),
   584      Const("TYPE", a_itselfT)]
   585   |> Theory.add_modesyntax ("", false)
   586     (Syntax.pure_syntax_output @ Syntax.pure_appl_syntax)
   587   |> Theory.add_trfuns Syntax.pure_trfuns
   588   |> Theory.add_trfunsT Syntax.pure_trfunsT
   589   |> local_path
   590   |> (#1 oo (add_defs_i false o map Thm.no_attributes))
   591    [("Goal_def", let val A = Free ("A", propT) in Logic.mk_equals (Logic.mk_goal A, A) end)]
   592   |> (#1 o add_thmss [(("nothing", []), [])])
   593   |> Theory.add_axioms_i Proofterm.equality_axms
   594   |> end_theory;
   595 
   596 structure ProtoPure =
   597 struct
   598   val thy = proto_pure;
   599   val Goal_def = get_axiom thy "Goal_def";
   600 end;
   601 
   602 
   603 end;
   604 
   605 
   606 structure BasicPureThy: BASIC_PURE_THY = PureThy;
   607 open BasicPureThy;