src/HOL/Product_Type.thy
author wenzelm
Thu Jan 19 21:22:08 2006 +0100 (2006-01-19 ago)
changeset 18708 4b3dadb4fe33
parent 18706 1e7562c7afe6
child 18757 f0d901bc0686
permissions -rw-r--r--
setup: theory -> theory;
     1 (*  Title:      HOL/Product_Type.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1992  University of Cambridge
     5 *)
     6 
     7 header {* Cartesian products *}
     8 
     9 theory Product_Type
    10 imports Fun
    11 uses ("Tools/split_rule.ML")
    12 begin
    13 
    14 subsection {* Unit *}
    15 
    16 typedef unit = "{True}"
    17 proof
    18   show "True : ?unit" by blast
    19 qed
    20 
    21 constdefs
    22   Unity :: unit    ("'(')")
    23   "() == Abs_unit True"
    24 
    25 lemma unit_eq: "u = ()"
    26   by (induct u) (simp add: unit_def Unity_def)
    27 
    28 text {*
    29   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    30   this rule directly --- it loops!
    31 *}
    32 
    33 ML_setup {*
    34   val unit_eq_proc =
    35     let val unit_meta_eq = mk_meta_eq (thm "unit_eq") in
    36       Simplifier.simproc (Theory.sign_of (the_context ())) "unit_eq" ["x::unit"]
    37       (fn _ => fn _ => fn t => if HOLogic.is_unit t then NONE else SOME unit_meta_eq)
    38     end;
    39 
    40   Addsimprocs [unit_eq_proc];
    41 *}
    42 
    43 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    44   by simp
    45 
    46 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    47   by (rule triv_forall_equality)
    48 
    49 lemma unit_induct [induct type: unit]: "P () ==> P x"
    50   by simp
    51 
    52 text {*
    53   This rewrite counters the effect of @{text unit_eq_proc} on @{term
    54   [source] "%u::unit. f u"}, replacing it by @{term [source]
    55   f} rather than by @{term [source] "%u. f ()"}.
    56 *}
    57 
    58 lemma unit_abs_eta_conv [simp]: "(%u::unit. f ()) = f"
    59   by (rule ext) simp
    60 
    61 
    62 subsection {* Pairs *}
    63 
    64 subsubsection {* Type definition *}
    65 
    66 constdefs
    67   Pair_Rep :: "['a, 'b] => ['a, 'b] => bool"
    68   "Pair_Rep == (%a b. %x y. x=a & y=b)"
    69 
    70 global
    71 
    72 typedef (Prod)
    73   ('a, 'b) "*"    (infixr 20)
    74     = "{f. EX a b. f = Pair_Rep (a::'a) (b::'b)}"
    75 proof
    76   fix a b show "Pair_Rep a b : ?Prod"
    77     by blast
    78 qed
    79 
    80 syntax (xsymbols)
    81   "*"      :: "[type, type] => type"         ("(_ \<times>/ _)" [21, 20] 20)
    82 syntax (HTML output)
    83   "*"      :: "[type, type] => type"         ("(_ \<times>/ _)" [21, 20] 20)
    84 
    85 local
    86 
    87 
    88 subsubsection {* Abstract constants and syntax *}
    89 
    90 global
    91 
    92 consts
    93   fst      :: "'a * 'b => 'a"
    94   snd      :: "'a * 'b => 'b"
    95   split    :: "[['a, 'b] => 'c, 'a * 'b] => 'c"
    96   curry    :: "['a * 'b => 'c, 'a, 'b] => 'c"
    97   prod_fun :: "['a => 'b, 'c => 'd, 'a * 'c] => 'b * 'd"
    98   Pair     :: "['a, 'b] => 'a * 'b"
    99   Sigma    :: "['a set, 'a => 'b set] => ('a * 'b) set"
   100 
   101 local
   102 
   103 text {*
   104   Patterns -- extends pre-defined type @{typ pttrn} used in
   105   abstractions.
   106 *}
   107 
   108 nonterminals
   109   tuple_args patterns
   110 
   111 syntax
   112   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   113   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   114   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   115   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   116   ""            :: "pttrn => patterns"                  ("_")
   117   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   118   "@Sigma" ::"[pttrn, 'a set, 'b set] => ('a * 'b) set" ("(3SIGMA _:_./ _)" 10)
   119   "@Times" ::"['a set,  'a => 'b set] => ('a * 'b) set" (infixr "<*>" 80)
   120 
   121 translations
   122   "(x, y)"       == "Pair x y"
   123   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   124   "%(x,y,zs).b"  == "split(%x (y,zs).b)"
   125   "%(x,y).b"     == "split(%x y. b)"
   126   "_abs (Pair x y) t" => "%(x,y).t"
   127   (* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   128      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *)
   129 
   130   "SIGMA x:A. B" => "Sigma A (%x. B)"
   131   "A <*> B"      => "Sigma A (%_. B)"
   132 
   133 (* reconstructs pattern from (nested) splits, avoiding eta-contraction of body*)
   134 (* works best with enclosing "let", if "let" does not avoid eta-contraction   *)
   135 print_translation {*
   136 let fun split_tr' [Abs (x,T,t as (Abs abs))] =
   137       (* split (%x y. t) => %(x,y) t *)
   138       let val (y,t') = atomic_abs_tr' abs;
   139           val (x',t'') = atomic_abs_tr' (x,T,t');
   140     
   141       in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end
   142     | split_tr' [Abs (x,T,(s as Const ("split",_)$t))] =
   143        (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   144        let val (Const ("_abs",_)$(Const ("_pattern",_)$y$z)$t') = split_tr' [t];
   145            val (x',t'') = atomic_abs_tr' (x,T,t');
   146        in Syntax.const "_abs"$ 
   147            (Syntax.const "_pattern"$x'$(Syntax.const "_patterns"$y$z))$t'' end
   148     | split_tr' [Const ("split",_)$t] =
   149        (* split (split (%x y z. t)) => %((x,y),z). t *)   
   150        split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   151     | split_tr' [Const ("_abs",_)$x_y$(Abs abs)] =
   152        (* split (%pttrn z. t) => %(pttrn,z). t *)
   153        let val (z,t) = atomic_abs_tr' abs;
   154        in Syntax.const "_abs" $ (Syntax.const "_pattern" $x_y$z) $ t end
   155     | split_tr' _ =  raise Match;
   156 in [("split", split_tr')]
   157 end
   158 *}
   159 
   160 
   161 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   162 typed_print_translation {*
   163 let
   164   fun split_guess_names_tr' _ T [Abs (x,_,Abs _)] = raise Match
   165     | split_guess_names_tr' _ T  [Abs (x,xT,t)] =
   166         (case (head_of t) of
   167            Const ("split",_) => raise Match
   168          | _ => let 
   169                   val (_::yT::_) = binder_types (domain_type T) handle Bind => raise Match;
   170                   val (y,t') = atomic_abs_tr' ("y",yT,(incr_boundvars 1 t)$Bound 0); 
   171                   val (x',t'') = atomic_abs_tr' (x,xT,t');
   172                 in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end)
   173     | split_guess_names_tr' _ T [t] =
   174        (case (head_of t) of
   175            Const ("split",_) => raise Match 
   176          | _ => let 
   177                   val (xT::yT::_) = binder_types (domain_type T) handle Bind => raise Match;
   178                   val (y,t') = 
   179                         atomic_abs_tr' ("y",yT,(incr_boundvars 2 t)$Bound 1$Bound 0); 
   180                   val (x',t'') = atomic_abs_tr' ("x",xT,t');
   181                 in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end)
   182     | split_guess_names_tr' _ _ _ = raise Match;
   183 in [("split", split_guess_names_tr')]
   184 end 
   185 *}
   186 
   187 text{*Deleted x-symbol and html support using @{text"\<Sigma>"} (Sigma) because of the danger of confusion with Sum.*}
   188 
   189 syntax (xsymbols)
   190   "@Times" :: "['a set,  'a => 'b set] => ('a * 'b) set"  ("_ \<times> _" [81, 80] 80)
   191 
   192 syntax (HTML output)
   193   "@Times" :: "['a set,  'a => 'b set] => ('a * 'b) set"  ("_ \<times> _" [81, 80] 80)
   194 
   195 print_translation {* [("Sigma", dependent_tr' ("@Sigma", "@Times"))] *}
   196 
   197 
   198 subsubsection {* Definitions *}
   199 
   200 defs
   201   Pair_def:     "Pair a b == Abs_Prod(Pair_Rep a b)"
   202   fst_def:      "fst p == THE a. EX b. p = (a, b)"
   203   snd_def:      "snd p == THE b. EX a. p = (a, b)"
   204   split_def:    "split == (%c p. c (fst p) (snd p))"
   205   curry_def:    "curry == (%c x y. c (x,y))"
   206   prod_fun_def: "prod_fun f g == split(%x y.(f(x), g(y)))"
   207   Sigma_def:    "Sigma A B == UN x:A. UN y:B(x). {(x, y)}"
   208 
   209 
   210 subsubsection {* Lemmas and proof tool setup *}
   211 
   212 lemma ProdI: "Pair_Rep a b : Prod"
   213   by (unfold Prod_def) blast
   214 
   215 lemma Pair_Rep_inject: "Pair_Rep a b = Pair_Rep a' b' ==> a = a' & b = b'"
   216   apply (unfold Pair_Rep_def)
   217   apply (drule fun_cong [THEN fun_cong], blast)
   218   done
   219 
   220 lemma inj_on_Abs_Prod: "inj_on Abs_Prod Prod"
   221   apply (rule inj_on_inverseI)
   222   apply (erule Abs_Prod_inverse)
   223   done
   224 
   225 lemma Pair_inject:
   226   assumes "(a, b) = (a', b')"
   227     and "a = a' ==> b = b' ==> R"
   228   shows R
   229   apply (insert prems [unfolded Pair_def])
   230   apply (rule inj_on_Abs_Prod [THEN inj_onD, THEN Pair_Rep_inject, THEN conjE])
   231   apply (assumption | rule ProdI)+
   232   done
   233 
   234 lemma Pair_eq [iff]: "((a, b) = (a', b')) = (a = a' & b = b')"
   235   by (blast elim!: Pair_inject)
   236 
   237 lemma fst_conv [simp]: "fst (a, b) = a"
   238   by (unfold fst_def) blast
   239 
   240 lemma snd_conv [simp]: "snd (a, b) = b"
   241   by (unfold snd_def) blast
   242 
   243 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   244   by simp
   245 
   246 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   247   by simp
   248 
   249 lemma PairE_lemma: "EX x y. p = (x, y)"
   250   apply (unfold Pair_def)
   251   apply (rule Rep_Prod [unfolded Prod_def, THEN CollectE])
   252   apply (erule exE, erule exE, rule exI, rule exI)
   253   apply (rule Rep_Prod_inverse [symmetric, THEN trans])
   254   apply (erule arg_cong)
   255   done
   256 
   257 lemma PairE [cases type: *]: "(!!x y. p = (x, y) ==> Q) ==> Q"
   258   by (insert PairE_lemma [of p]) blast
   259 
   260 ML {*
   261   local val PairE = thm "PairE" in
   262     fun pair_tac s =
   263       EVERY' [res_inst_tac [("p", s)] PairE, hyp_subst_tac, K prune_params_tac];
   264   end;
   265 *}
   266 
   267 lemma surjective_pairing: "p = (fst p, snd p)"
   268   -- {* Do not add as rewrite rule: invalidates some proofs in IMP *}
   269   by (cases p) simp
   270 
   271 lemmas pair_collapse = surjective_pairing [symmetric]
   272 declare pair_collapse [simp]
   273 
   274 lemma surj_pair [simp]: "EX x y. z = (x, y)"
   275   apply (rule exI)
   276   apply (rule exI)
   277   apply (rule surjective_pairing)
   278   done
   279 
   280 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   281 proof
   282   fix a b
   283   assume "!!x. PROP P x"
   284   thus "PROP P (a, b)" .
   285 next
   286   fix x
   287   assume "!!a b. PROP P (a, b)"
   288   hence "PROP P (fst x, snd x)" .
   289   thus "PROP P x" by simp
   290 qed
   291 
   292 lemmas split_tupled_all = split_paired_all unit_all_eq2
   293 
   294 text {*
   295   The rule @{thm [source] split_paired_all} does not work with the
   296   Simplifier because it also affects premises in congrence rules,
   297   where this can lead to premises of the form @{text "!!a b. ... =
   298   ?P(a, b)"} which cannot be solved by reflexivity.
   299 *}
   300 
   301 ML_setup {*
   302   (* replace parameters of product type by individual component parameters *)
   303   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   304   local (* filtering with exists_paired_all is an essential optimization *)
   305     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   306           can HOLogic.dest_prodT T orelse exists_paired_all t
   307       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   308       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   309       | exists_paired_all _ = false;
   310     val ss = HOL_basic_ss
   311       addsimps [thm "split_paired_all", thm "unit_all_eq2", thm "unit_abs_eta_conv"]
   312       addsimprocs [unit_eq_proc];
   313   in
   314     val split_all_tac = SUBGOAL (fn (t, i) =>
   315       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   316     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   317       if exists_paired_all t then full_simp_tac ss i else no_tac);
   318     fun split_all th =
   319    if exists_paired_all (#prop (Thm.rep_thm th)) then full_simplify ss th else th;
   320   end;
   321 
   322 change_claset (fn cs => cs addSbefore ("split_all_tac", split_all_tac));
   323 *}
   324 
   325 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   326   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   327   by fast
   328 
   329 lemma curry_split [simp]: "curry (split f) = f"
   330   by (simp add: curry_def split_def)
   331 
   332 lemma split_curry [simp]: "split (curry f) = f"
   333   by (simp add: curry_def split_def)
   334 
   335 lemma curryI [intro!]: "f (a,b) ==> curry f a b"
   336   by (simp add: curry_def)
   337 
   338 lemma curryD [dest!]: "curry f a b ==> f (a,b)"
   339   by (simp add: curry_def)
   340 
   341 lemma curryE: "[| curry f a b ; f (a,b) ==> Q |] ==> Q"
   342   by (simp add: curry_def)
   343 
   344 lemma curry_conv [simp]: "curry f a b = f (a,b)"
   345   by (simp add: curry_def)
   346 
   347 lemma prod_induct [induct type: *]: "!!x. (!!a b. P (a, b)) ==> P x"
   348   by fast
   349 
   350 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   351   by fast
   352 
   353 lemma split_conv [simp]: "split c (a, b) = c a b"
   354   by (simp add: split_def)
   355 
   356 lemmas split = split_conv  -- {* for backwards compatibility *}
   357 
   358 lemmas splitI = split_conv [THEN iffD2, standard]
   359 lemmas splitD = split_conv [THEN iffD1, standard]
   360 
   361 lemma split_Pair_apply: "split (%x y. f (x, y)) = f"
   362   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   363   apply (rule ext)
   364   apply (tactic {* pair_tac "x" 1 *}, simp)
   365   done
   366 
   367 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   368   -- {* Can't be added to simpset: loops! *}
   369   by (simp add: split_Pair_apply)
   370 
   371 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   372   by (simp add: split_def)
   373 
   374 lemma Pair_fst_snd_eq: "!!s t. (s = t) = (fst s = fst t & snd s = snd t)"
   375 by (simp only: split_tupled_all, simp)
   376 
   377 lemma prod_eqI [intro?]: "fst p = fst q ==> snd p = snd q ==> p = q"
   378   by (simp add: Pair_fst_snd_eq)
   379 
   380 lemma split_weak_cong: "p = q ==> split c p = split c q"
   381   -- {* Prevents simplification of @{term c}: much faster *}
   382   by (erule arg_cong)
   383 
   384 lemma split_eta: "(%(x, y). f (x, y)) = f"
   385   apply (rule ext)
   386   apply (simp only: split_tupled_all)
   387   apply (rule split_conv)
   388   done
   389 
   390 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   391   by (simp add: split_eta)
   392 
   393 text {*
   394   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   395   @{thm [source] split_eta} as a rewrite rule is not general enough,
   396   and using @{thm [source] cond_split_eta} directly would render some
   397   existing proofs very inefficient; similarly for @{text
   398   split_beta}. *}
   399 
   400 ML_setup {*
   401 
   402 local
   403   val cond_split_eta_ss = HOL_basic_ss addsimps [thm "cond_split_eta"]
   404   fun  Pair_pat k 0 (Bound m) = (m = k)
   405   |    Pair_pat k i (Const ("Pair",  _) $ Bound m $ t) = i > 0 andalso
   406                         m = k+i andalso Pair_pat k (i-1) t
   407   |    Pair_pat _ _ _ = false;
   408   fun no_args k i (Abs (_, _, t)) = no_args (k+1) i t
   409   |   no_args k i (t $ u) = no_args k i t andalso no_args k i u
   410   |   no_args k i (Bound m) = m < k orelse m > k+i
   411   |   no_args _ _ _ = true;
   412   fun split_pat tp i (Abs  (_,_,t)) = if tp 0 i t then SOME (i,t) else NONE
   413   |   split_pat tp i (Const ("split", _) $ Abs (_, _, t)) = split_pat tp (i+1) t
   414   |   split_pat tp i _ = NONE;
   415   fun metaeq thy ss lhs rhs = mk_meta_eq (Goal.prove thy [] []
   416         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs,rhs)))
   417         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   418 
   419   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k+1) i t
   420   |   beta_term_pat k i (t $ u) = Pair_pat k i (t $ u) orelse
   421                         (beta_term_pat k i t andalso beta_term_pat k i u)
   422   |   beta_term_pat k i t = no_args k i t;
   423   fun  eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   424   |    eta_term_pat _ _ _ = false;
   425   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   426   |   subst arg k i (t $ u) = if Pair_pat k i (t $ u) then incr_boundvars k arg
   427                               else (subst arg k i t $ subst arg k i u)
   428   |   subst arg k i t = t;
   429   fun beta_proc thy ss (s as Const ("split", _) $ Abs (_, _, t) $ arg) =
   430         (case split_pat beta_term_pat 1 t of
   431         SOME (i,f) => SOME (metaeq thy ss s (subst arg 0 i f))
   432         | NONE => NONE)
   433   |   beta_proc _ _ _ = NONE;
   434   fun eta_proc thy ss (s as Const ("split", _) $ Abs (_, _, t)) =
   435         (case split_pat eta_term_pat 1 t of
   436           SOME (_,ft) => SOME (metaeq thy ss s (let val (f $ arg) = ft in f end))
   437         | NONE => NONE)
   438   |   eta_proc _ _ _ = NONE;
   439 in
   440   val split_beta_proc = Simplifier.simproc (Theory.sign_of (the_context ()))
   441     "split_beta" ["split f z"] beta_proc;
   442   val split_eta_proc = Simplifier.simproc (Theory.sign_of (the_context ()))
   443     "split_eta" ["split f"] eta_proc;
   444 end;
   445 
   446 Addsimprocs [split_beta_proc, split_eta_proc];
   447 *}
   448 
   449 lemma split_beta: "(%(x, y). P x y) z = P (fst z) (snd z)"
   450   by (subst surjective_pairing, rule split_conv)
   451 
   452 lemma split_split: "R (split c p) = (ALL x y. p = (x, y) --> R (c x y))"
   453   -- {* For use with @{text split} and the Simplifier. *}
   454   by (insert surj_pair [of p], clarify, simp)
   455 
   456 text {*
   457   @{thm [source] split_split} could be declared as @{text "[split]"}
   458   done after the Splitter has been speeded up significantly;
   459   precompute the constants involved and don't do anything unless the
   460   current goal contains one of those constants.
   461 *}
   462 
   463 lemma split_split_asm: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   464 by (subst split_split, simp)
   465 
   466 
   467 text {*
   468   \medskip @{term split} used as a logical connective or set former.
   469 
   470   \medskip These rules are for use with @{text blast}; could instead
   471   call @{text simp} using @{thm [source] split} as rewrite. *}
   472 
   473 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   474   apply (simp only: split_tupled_all)
   475   apply (simp (no_asm_simp))
   476   done
   477 
   478 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   479   apply (simp only: split_tupled_all)
   480   apply (simp (no_asm_simp))
   481   done
   482 
   483 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   484   by (induct p) (auto simp add: split_def)
   485 
   486 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   487   by (induct p) (auto simp add: split_def)
   488 
   489 lemma splitE2:
   490   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   491 proof -
   492   assume q: "Q (split P z)"
   493   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   494   show R
   495     apply (rule r surjective_pairing)+
   496     apply (rule split_beta [THEN subst], rule q)
   497     done
   498 qed
   499 
   500 lemma splitD': "split R (a,b) c ==> R a b c"
   501   by simp
   502 
   503 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   504   by simp
   505 
   506 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   507 by (simp only: split_tupled_all, simp)
   508 
   509 lemma mem_splitE:
   510   assumes major: "z: split c p"
   511     and cases: "!!x y. [| p = (x,y); z: c x y |] ==> Q"
   512   shows Q
   513   by (rule major [unfolded split_def] cases surjective_pairing)+
   514 
   515 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   516 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   517 
   518 ML_setup {*
   519 local (* filtering with exists_p_split is an essential optimization *)
   520   fun exists_p_split (Const ("split",_) $ _ $ (Const ("Pair",_)$_$_)) = true
   521     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   522     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   523     | exists_p_split _ = false;
   524   val ss = HOL_basic_ss addsimps [thm "split_conv"];
   525 in
   526 val split_conv_tac = SUBGOAL (fn (t, i) =>
   527     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   528 end;
   529 (* This prevents applications of splitE for already splitted arguments leading
   530    to quite time-consuming computations (in particular for nested tuples) *)
   531 change_claset (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac));
   532 *}
   533 
   534 lemma split_eta_SetCompr [simp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   535   by (rule ext) fast
   536 
   537 lemma split_eta_SetCompr2 [simp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   538   by (rule ext) fast
   539 
   540 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   541   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   542   by (rule ext) blast
   543 
   544 (* Do NOT make this a simp rule as it
   545    a) only helps in special situations
   546    b) can lead to nontermination in the presence of split_def
   547 *)
   548 lemma split_comp_eq: 
   549 "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   550   by (rule ext) auto
   551 
   552 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   553   by blast
   554 
   555 (*
   556 the following  would be slightly more general,
   557 but cannot be used as rewrite rule:
   558 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   559 ### ?y = .x
   560 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   561 by (rtac some_equality 1)
   562 by ( Simp_tac 1)
   563 by (split_all_tac 1)
   564 by (Asm_full_simp_tac 1)
   565 qed "The_split_eq";
   566 *)
   567 
   568 lemma injective_fst_snd: "!!x y. [|fst x = fst y; snd x = snd y|] ==> x = y"
   569   by auto
   570 
   571 
   572 text {*
   573   \bigskip @{term prod_fun} --- action of the product functor upon
   574   functions.
   575 *}
   576 
   577 lemma prod_fun [simp]: "prod_fun f g (a, b) = (f a, g b)"
   578   by (simp add: prod_fun_def)
   579 
   580 lemma prod_fun_compose: "prod_fun (f1 o f2) (g1 o g2) = (prod_fun f1 g1 o prod_fun f2 g2)"
   581   apply (rule ext)
   582   apply (tactic {* pair_tac "x" 1 *}, simp)
   583   done
   584 
   585 lemma prod_fun_ident [simp]: "prod_fun (%x. x) (%y. y) = (%z. z)"
   586   apply (rule ext)
   587   apply (tactic {* pair_tac "z" 1 *}, simp)
   588   done
   589 
   590 lemma prod_fun_imageI [intro]: "(a, b) : r ==> (f a, g b) : prod_fun f g ` r"
   591   apply (rule image_eqI)
   592   apply (rule prod_fun [symmetric], assumption)
   593   done
   594 
   595 lemma prod_fun_imageE [elim!]:
   596   assumes major: "c: (prod_fun f g)`r"
   597     and cases: "!!x y. [| c=(f(x),g(y));  (x,y):r |] ==> P"
   598   shows P
   599   apply (rule major [THEN imageE])
   600   apply (rule_tac p = x in PairE)
   601   apply (rule cases)
   602    apply (blast intro: prod_fun)
   603   apply blast
   604   done
   605 
   606 
   607 constdefs
   608   upd_fst :: "('a => 'c) => 'a * 'b => 'c * 'b"
   609  "upd_fst f == prod_fun f id"
   610 
   611   upd_snd :: "('b => 'c) => 'a * 'b => 'a * 'c"
   612  "upd_snd f == prod_fun id f"
   613 
   614 lemma upd_fst_conv [simp]: "upd_fst f (x,y) = (f x,y)" 
   615   by (simp add: upd_fst_def)
   616 
   617 lemma upd_snd_conv [simp]: "upd_snd f (x,y) = (x,f y)" 
   618   by (simp add: upd_snd_def)
   619 
   620 text {*
   621   \bigskip Disjoint union of a family of sets -- Sigma.
   622 *}
   623 
   624 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   625   by (unfold Sigma_def) blast
   626 
   627 lemma SigmaE [elim!]:
   628     "[| c: Sigma A B;
   629         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   630      |] ==> P"
   631   -- {* The general elimination rule. *}
   632   by (unfold Sigma_def) blast
   633 
   634 text {*
   635   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   636   eigenvariables.
   637 *}
   638 
   639 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
   640   by blast
   641 
   642 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
   643   by blast
   644 
   645 lemma SigmaE2:
   646     "[| (a, b) : Sigma A B;
   647         [| a:A;  b:B(a) |] ==> P
   648      |] ==> P"
   649   by blast
   650 
   651 lemma Sigma_cong:
   652      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
   653       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
   654   by auto
   655 
   656 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
   657   by blast
   658 
   659 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
   660   by blast
   661 
   662 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
   663   by blast
   664 
   665 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
   666   by auto
   667 
   668 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
   669   by auto
   670 
   671 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
   672   by auto
   673 
   674 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
   675   by blast
   676 
   677 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
   678   by blast
   679 
   680 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
   681   by (blast elim: equalityE)
   682 
   683 lemma SetCompr_Sigma_eq:
   684     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
   685   by blast
   686 
   687 text {*
   688   \bigskip Complex rules for Sigma.
   689 *}
   690 
   691 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
   692   by blast
   693 
   694 lemma UN_Times_distrib:
   695   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
   696   -- {* Suggested by Pierre Chartier *}
   697   by blast
   698 
   699 lemma split_paired_Ball_Sigma [simp]:
   700     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
   701   by blast
   702 
   703 lemma split_paired_Bex_Sigma [simp]:
   704     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
   705   by blast
   706 
   707 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
   708   by blast
   709 
   710 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
   711   by blast
   712 
   713 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
   714   by blast
   715 
   716 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
   717   by blast
   718 
   719 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
   720   by blast
   721 
   722 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
   723   by blast
   724 
   725 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
   726   by blast
   727 
   728 text {*
   729   Non-dependent versions are needed to avoid the need for higher-order
   730   matching, especially when the rules are re-oriented.
   731 *}
   732 
   733 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
   734   by blast
   735 
   736 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
   737   by blast
   738 
   739 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
   740   by blast
   741 
   742 
   743 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   744   apply (rule_tac x = "(a, b)" in image_eqI)
   745    apply auto
   746   done
   747 
   748 
   749 text {*
   750   Setup of internal @{text split_rule}.
   751 *}
   752 
   753 constdefs
   754   internal_split :: "('a => 'b => 'c) => 'a * 'b => 'c"
   755   "internal_split == split"
   756 
   757 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   758   by (simp only: internal_split_def split_conv)
   759 
   760 hide const internal_split
   761 
   762 use "Tools/split_rule.ML"
   763 setup SplitRule.setup
   764 
   765 
   766 subsection {* Code generator setup *}
   767 
   768 types_code
   769   "*"     ("(_ */ _)")
   770 attach (term_of) {*
   771 fun term_of_id_42 f T g U (x, y) = HOLogic.pair_const T U $ f x $ g y;
   772 *}
   773 attach (test) {*
   774 fun gen_id_42 aG bG i = (aG i, bG i);
   775 *}
   776 
   777 consts_code
   778   "Pair"    ("(_,/ _)")
   779   "fst"     ("fst")
   780   "snd"     ("snd")
   781 
   782 code_alias
   783   "*" "Product_Type.*"
   784   "Pair" "Product_Type.Pair"
   785   "fst" "Product_Type.fst"
   786   "snd" "Product_Type.snd"
   787 
   788 code_primconst fst
   789 ml {*
   790 fun fst (x, y) = x;
   791 *}
   792 
   793 code_primconst snd
   794 ml {*
   795 fun snd (x, y) = y;
   796 *}
   797 
   798 code_syntax_tyco
   799   *
   800     ml (infix 2 "*")
   801     haskell (atom "(__,/ __)")
   802 
   803 code_syntax_const
   804   fst
   805     haskell (atom "fst")
   806   snd
   807     haskell (atom "snd")
   808 
   809 ML {*
   810 
   811 signature PRODUCT_TYPE_CODEGEN =
   812 sig
   813   val strip_abs: int -> term -> term list * term;
   814 end;
   815 
   816 structure ProductTypeCodegen : PRODUCT_TYPE_CODEGEN =
   817 struct
   818 
   819 fun strip_abs 0 t = ([], t)
   820   | strip_abs i (Abs (s, T, t)) =
   821       let
   822         val s' = Codegen.new_name t s;
   823         val v = Free (s', T)
   824       in apfst (cons v) (strip_abs (i-1) (subst_bound (v, t))) end
   825   | strip_abs i (u as Const ("split", _) $ t) = (case strip_abs (i+1) t of
   826         (v :: v' :: vs, u) => (HOLogic.mk_prod (v, v') :: vs, u)
   827       | _ => ([], u))
   828   | strip_abs i t = ([], t);
   829 
   830 end;
   831 
   832 local
   833 
   834 open ProductTypeCodegen;
   835 
   836 fun let_codegen thy defs gr dep thyname brack t = (case strip_comb t of
   837     (t1 as Const ("Let", _), t2 :: t3 :: ts) =>
   838     let
   839       fun dest_let (l as Const ("Let", _) $ t $ u) =
   840           (case strip_abs 1 u of
   841              ([p], u') => apfst (cons (p, t)) (dest_let u')
   842            | _ => ([], l))
   843         | dest_let t = ([], t);
   844       fun mk_code (gr, (l, r)) =
   845         let
   846           val (gr1, pl) = Codegen.invoke_codegen thy defs dep thyname false (gr, l);
   847           val (gr2, pr) = Codegen.invoke_codegen thy defs dep thyname false (gr1, r);
   848         in (gr2, (pl, pr)) end
   849     in case dest_let (t1 $ t2 $ t3) of
   850         ([], _) => NONE
   851       | (ps, u) =>
   852           let
   853             val (gr1, qs) = foldl_map mk_code (gr, ps);
   854             val (gr2, pu) = Codegen.invoke_codegen thy defs dep thyname false (gr1, u);
   855             val (gr3, pargs) = foldl_map
   856               (Codegen.invoke_codegen thy defs dep thyname true) (gr2, ts)
   857           in
   858             SOME (gr3, Codegen.mk_app brack
   859               (Pretty.blk (0, [Pretty.str "let ", Pretty.blk (0, List.concat
   860                   (separate [Pretty.str ";", Pretty.brk 1] (map (fn (pl, pr) =>
   861                     [Pretty.block [Pretty.str "val ", pl, Pretty.str " =",
   862                        Pretty.brk 1, pr]]) qs))),
   863                 Pretty.brk 1, Pretty.str "in ", pu,
   864                 Pretty.brk 1, Pretty.str "end"])) pargs)
   865           end
   866     end
   867   | _ => NONE);
   868 
   869 fun split_codegen thy defs gr dep thyname brack t = (case strip_comb t of
   870     (t1 as Const ("split", _), t2 :: ts) =>
   871       (case strip_abs 1 (t1 $ t2) of
   872          ([p], u) =>
   873            let
   874              val (gr1, q) = Codegen.invoke_codegen thy defs dep thyname false (gr, p);
   875              val (gr2, pu) = Codegen.invoke_codegen thy defs dep thyname false (gr1, u);
   876              val (gr3, pargs) = foldl_map
   877                (Codegen.invoke_codegen thy defs dep thyname true) (gr2, ts)
   878            in
   879              SOME (gr2, Codegen.mk_app brack
   880                (Pretty.block [Pretty.str "(fn ", q, Pretty.str " =>",
   881                  Pretty.brk 1, pu, Pretty.str ")"]) pargs)
   882            end
   883        | _ => NONE)
   884   | _ => NONE);
   885 
   886 in
   887 
   888 val prod_codegen_setup =
   889   Codegen.add_codegen "let_codegen" let_codegen #>
   890   Codegen.add_codegen "split_codegen" split_codegen #>
   891   CodegenPackage.add_appconst
   892     ("Let", ((2, 2), CodegenPackage.appgen_let strip_abs)) #>
   893   CodegenPackage.add_appconst
   894     ("split", ((1, 1), CodegenPackage.appgen_split strip_abs));
   895 
   896 end;
   897 *}
   898 
   899 setup prod_codegen_setup
   900 
   901 ML
   902 {*
   903 val Collect_split = thm "Collect_split";
   904 val Compl_Times_UNIV1 = thm "Compl_Times_UNIV1";
   905 val Compl_Times_UNIV2 = thm "Compl_Times_UNIV2";
   906 val PairE = thm "PairE";
   907 val PairE_lemma = thm "PairE_lemma";
   908 val Pair_Rep_inject = thm "Pair_Rep_inject";
   909 val Pair_def = thm "Pair_def";
   910 val Pair_eq = thm "Pair_eq";
   911 val Pair_fst_snd_eq = thm "Pair_fst_snd_eq";
   912 val Pair_inject = thm "Pair_inject";
   913 val ProdI = thm "ProdI";
   914 val SetCompr_Sigma_eq = thm "SetCompr_Sigma_eq";
   915 val SigmaD1 = thm "SigmaD1";
   916 val SigmaD2 = thm "SigmaD2";
   917 val SigmaE = thm "SigmaE";
   918 val SigmaE2 = thm "SigmaE2";
   919 val SigmaI = thm "SigmaI";
   920 val Sigma_Diff_distrib1 = thm "Sigma_Diff_distrib1";
   921 val Sigma_Diff_distrib2 = thm "Sigma_Diff_distrib2";
   922 val Sigma_Int_distrib1 = thm "Sigma_Int_distrib1";
   923 val Sigma_Int_distrib2 = thm "Sigma_Int_distrib2";
   924 val Sigma_Un_distrib1 = thm "Sigma_Un_distrib1";
   925 val Sigma_Un_distrib2 = thm "Sigma_Un_distrib2";
   926 val Sigma_Union = thm "Sigma_Union";
   927 val Sigma_def = thm "Sigma_def";
   928 val Sigma_empty1 = thm "Sigma_empty1";
   929 val Sigma_empty2 = thm "Sigma_empty2";
   930 val Sigma_mono = thm "Sigma_mono";
   931 val The_split = thm "The_split";
   932 val The_split_eq = thm "The_split_eq";
   933 val The_split_eq = thm "The_split_eq";
   934 val Times_Diff_distrib1 = thm "Times_Diff_distrib1";
   935 val Times_Int_distrib1 = thm "Times_Int_distrib1";
   936 val Times_Un_distrib1 = thm "Times_Un_distrib1";
   937 val Times_eq_cancel2 = thm "Times_eq_cancel2";
   938 val Times_subset_cancel2 = thm "Times_subset_cancel2";
   939 val UNIV_Times_UNIV = thm "UNIV_Times_UNIV";
   940 val UN_Times_distrib = thm "UN_Times_distrib";
   941 val Unity_def = thm "Unity_def";
   942 val cond_split_eta = thm "cond_split_eta";
   943 val fst_conv = thm "fst_conv";
   944 val fst_def = thm "fst_def";
   945 val fst_eqD = thm "fst_eqD";
   946 val inj_on_Abs_Prod = thm "inj_on_Abs_Prod";
   947 val injective_fst_snd = thm "injective_fst_snd";
   948 val mem_Sigma_iff = thm "mem_Sigma_iff";
   949 val mem_splitE = thm "mem_splitE";
   950 val mem_splitI = thm "mem_splitI";
   951 val mem_splitI2 = thm "mem_splitI2";
   952 val prod_eqI = thm "prod_eqI";
   953 val prod_fun = thm "prod_fun";
   954 val prod_fun_compose = thm "prod_fun_compose";
   955 val prod_fun_def = thm "prod_fun_def";
   956 val prod_fun_ident = thm "prod_fun_ident";
   957 val prod_fun_imageE = thm "prod_fun_imageE";
   958 val prod_fun_imageI = thm "prod_fun_imageI";
   959 val prod_induct = thm "prod_induct";
   960 val snd_conv = thm "snd_conv";
   961 val snd_def = thm "snd_def";
   962 val snd_eqD = thm "snd_eqD";
   963 val split = thm "split";
   964 val splitD = thm "splitD";
   965 val splitD' = thm "splitD'";
   966 val splitE = thm "splitE";
   967 val splitE' = thm "splitE'";
   968 val splitE2 = thm "splitE2";
   969 val splitI = thm "splitI";
   970 val splitI2 = thm "splitI2";
   971 val splitI2' = thm "splitI2'";
   972 val split_Pair_apply = thm "split_Pair_apply";
   973 val split_beta = thm "split_beta";
   974 val split_conv = thm "split_conv";
   975 val split_def = thm "split_def";
   976 val split_eta = thm "split_eta";
   977 val split_eta_SetCompr = thm "split_eta_SetCompr";
   978 val split_eta_SetCompr2 = thm "split_eta_SetCompr2";
   979 val split_paired_All = thm "split_paired_All";
   980 val split_paired_Ball_Sigma = thm "split_paired_Ball_Sigma";
   981 val split_paired_Bex_Sigma = thm "split_paired_Bex_Sigma";
   982 val split_paired_Ex = thm "split_paired_Ex";
   983 val split_paired_The = thm "split_paired_The";
   984 val split_paired_all = thm "split_paired_all";
   985 val split_part = thm "split_part";
   986 val split_split = thm "split_split";
   987 val split_split_asm = thm "split_split_asm";
   988 val split_tupled_all = thms "split_tupled_all";
   989 val split_weak_cong = thm "split_weak_cong";
   990 val surj_pair = thm "surj_pair";
   991 val surjective_pairing = thm "surjective_pairing";
   992 val unit_abs_eta_conv = thm "unit_abs_eta_conv";
   993 val unit_all_eq1 = thm "unit_all_eq1";
   994 val unit_all_eq2 = thm "unit_all_eq2";
   995 val unit_eq = thm "unit_eq";
   996 val unit_induct = thm "unit_induct";
   997 *}
   998 
   999 end