src/Provers/clasimp.ML
author wenzelm
Thu Jan 19 21:22:08 2006 +0100 (2006-01-19 ago)
changeset 18708 4b3dadb4fe33
parent 18688 abf0f018b5ec
child 18728 6790126ab5f6
permissions -rw-r--r--
setup: theory -> theory;
     1 (*  Title:      Provers/clasimp.ML
     2     ID:         $Id$
     3     Author:     David von Oheimb, TU Muenchen
     4 
     5 Combination of classical reasoner and simplifier (depends on
     6 splitter.ML, classical.ML, blast.ML).
     7 *)
     8 
     9 infix 4 addSIs2 addSEs2 addSDs2 addIs2 addEs2 addDs2 addsimps2 delsimps2
    10   addSss addss addss' addIffs delIffs;
    11 
    12 signature CLASIMP_DATA =
    13 sig
    14   structure Splitter: SPLITTER
    15   structure Classical: CLASSICAL
    16   structure Blast: BLAST
    17   sharing type Classical.claset = Blast.claset
    18   val notE: thm
    19   val iffD1: thm
    20   val iffD2: thm
    21 end
    22 
    23 signature CLASIMP =
    24 sig
    25   include CLASIMP_DATA
    26   type claset
    27   type clasimpset
    28   val change_clasimpset: (clasimpset -> clasimpset) -> unit
    29   val clasimpset: unit -> clasimpset
    30   val addSIs2: clasimpset * thm list -> clasimpset
    31   val addSEs2: clasimpset * thm list -> clasimpset
    32   val addSDs2: clasimpset * thm list -> clasimpset
    33   val addIs2: clasimpset * thm list -> clasimpset
    34   val addEs2: clasimpset * thm list -> clasimpset
    35   val addDs2: clasimpset * thm list -> clasimpset
    36   val addsimps2: clasimpset * thm list -> clasimpset
    37   val delsimps2: clasimpset * thm list -> clasimpset
    38   val addSss: claset * simpset -> claset
    39   val addss: claset * simpset -> claset
    40   val addss': claset * simpset -> claset
    41   val addIffs: clasimpset * thm list -> clasimpset
    42   val delIffs: clasimpset * thm list -> clasimpset
    43   val AddIffs: thm list -> unit
    44   val DelIffs: thm list -> unit
    45   val CLASIMPSET: (clasimpset -> tactic) -> tactic
    46   val CLASIMPSET': (clasimpset -> 'a -> tactic) -> 'a -> tactic
    47   val clarsimp_tac: clasimpset -> int -> tactic
    48   val Clarsimp_tac: int -> tactic
    49   val mk_auto_tac: clasimpset -> int -> int -> tactic
    50   val auto_tac: clasimpset -> tactic
    51   val Auto_tac: tactic
    52   val auto: unit -> unit
    53   val force_tac: clasimpset  -> int -> tactic
    54   val Force_tac: int -> tactic
    55   val force: int -> unit
    56   val fast_simp_tac: clasimpset -> int -> tactic
    57   val slow_simp_tac: clasimpset -> int -> tactic
    58   val best_simp_tac: clasimpset -> int -> tactic
    59   val attrib: (clasimpset * thm list -> clasimpset) -> Context.generic attribute
    60   val get_local_clasimpset: Proof.context -> clasimpset
    61   val local_clasimpset_of: Proof.context -> clasimpset
    62   val iff_add: Context.generic attribute
    63   val iff_add': Context.generic attribute
    64   val iff_del: Context.generic attribute
    65   val iff_modifiers: (Args.T list -> (Method.modifier * Args.T list)) list
    66   val clasimp_modifiers: (Args.T list -> (Method.modifier * Args.T list)) list
    67   val setup: theory -> theory
    68 end;
    69 
    70 functor ClasimpFun(Data: CLASIMP_DATA): CLASIMP =
    71 struct
    72 
    73 open Data;
    74 
    75 type claset = Classical.claset;
    76 type clasimpset = claset * simpset;
    77 
    78 fun change_clasimpset_of thy f =
    79   let val (cs', ss') = f (Classical.get_claset thy, Simplifier.get_simpset thy) in
    80     Classical.change_claset_of thy (fn _ => cs');
    81     Simplifier.change_simpset_of thy (fn _ => ss')
    82   end;
    83 
    84 fun change_clasimpset f = change_clasimpset_of (Context.the_context ()) f;
    85 fun clasimpset () = (Classical.claset (), Simplifier.simpset ());
    86 
    87 
    88 (* clasimpset operations *)
    89 
    90 (*this interface for updating a clasimpset is rudimentary and just for
    91   convenience for the most common cases*)
    92 
    93 fun pair_upd1 f ((a,b),x) = (f(a,x), b);
    94 fun pair_upd2 f ((a,b),x) = (a, f(b,x));
    95 
    96 fun op addSIs2   arg = pair_upd1 Classical.addSIs arg;
    97 fun op addSEs2   arg = pair_upd1 Classical.addSEs arg;
    98 fun op addSDs2   arg = pair_upd1 Classical.addSDs arg;
    99 fun op addIs2    arg = pair_upd1 Classical.addIs arg;
   100 fun op addEs2    arg = pair_upd1 Classical.addEs arg;
   101 fun op addDs2    arg = pair_upd1 Classical.addDs arg;
   102 fun op addsimps2 arg = pair_upd2 Simplifier.addsimps arg;
   103 fun op delsimps2 arg = pair_upd2 Simplifier.delsimps arg;
   104 
   105 (*not totally safe: may instantiate unknowns that appear also in other subgoals*)
   106 val safe_asm_full_simp_tac = Simplifier.generic_simp_tac true (true,true,true);
   107 
   108 (*Add a simpset to a classical set!*)
   109 (*Caution: only one simpset added can be added by each of addSss and addss*)
   110 fun cs addSss ss = Classical.addSafter (cs, ("safe_asm_full_simp_tac",
   111                             CHANGED o safe_asm_full_simp_tac ss));
   112 fun cs addss  ss = Classical.addbefore  (cs, ("asm_full_simp_tac",
   113                             CHANGED o Simplifier.asm_full_simp_tac ss));
   114 fun cs addss' ss = Classical.addbefore  (cs, ("asm_full_simp_tac",
   115                             CHANGED o Simplifier.asm_lr_simp_tac ss));
   116 
   117 (*Attach a suffix, provided we have a name to start with.*)
   118 fun suffix_thm "" _ th = th
   119   | suffix_thm a b th = Thm.name_thm (a^b, th);
   120 
   121 (* iffs: addition of rules to simpsets and clasets simultaneously *)
   122 
   123 (*Takes (possibly conditional) theorems of the form A<->B to
   124         the Safe Intr     rule B==>A and
   125         the Safe Destruct rule A==>B.
   126   Also ~A goes to the Safe Elim rule A ==> ?R
   127   Failing other cases, A is added as a Safe Intr rule*)
   128 local
   129 
   130 fun addIff decls1 decls2 simp ((cs, ss), th) =
   131   let
   132     val name = Thm.name_of_thm th;
   133     val n = nprems_of th;
   134     val (elim, intro) = if n = 0 then decls1 else decls2;
   135     val zero_rotate = zero_var_indexes o rotate_prems n;
   136   in
   137     (elim (intro (cs, [suffix_thm name "_iff2" (zero_rotate (th RS iffD2))]),
   138            [suffix_thm name "_iff1" (Tactic.make_elim (zero_rotate (th RS iffD1)))])
   139       handle THM _ => (elim (cs, [suffix_thm name "_iff1" (zero_rotate (th RS notE))])
   140         handle THM _ => intro (cs, [th])),
   141      simp (ss, [th]))
   142   end;
   143 
   144 fun delIff delcs delss ((cs, ss), th) =
   145   let val zero_rotate = zero_var_indexes o rotate_prems (nprems_of th) in
   146     (delcs (cs, [zero_rotate (th RS iffD2),
   147         Tactic.make_elim (zero_rotate (th RS iffD1))])
   148       handle THM _ => (delcs (cs, [zero_rotate (th RS notE)])
   149         handle THM _ => delcs (cs, [th])),
   150      delss (ss, [th]))
   151   end;
   152 
   153 fun modifier att (x, ths) =
   154   fst (Thm.applys_attributes [att] (x, rev ths));
   155 
   156 val addXIs = modifier (ContextRules.intro_query NONE);
   157 val addXEs = modifier (ContextRules.elim_query NONE);
   158 val addXDs = modifier (ContextRules.dest_query NONE);
   159 val delXs = modifier ContextRules.rule_del;
   160 
   161 in
   162 
   163 val op addIffs =
   164   Library.foldl 
   165       (addIff (Classical.addSEs, Classical.addSIs)
   166               (Classical.addEs, Classical.addIs) 
   167               Simplifier.addsimps);
   168 val op delIffs = Library.foldl (delIff Classical.delrules Simplifier.delsimps);
   169 
   170 fun AddIffs thms = change_clasimpset (fn css => css addIffs thms);
   171 fun DelIffs thms = change_clasimpset (fn css => css delIffs thms);
   172 
   173 fun addIffs_generic (x, ths) =
   174   Library.foldl (addIff (addXEs, addXIs) (addXEs, addXIs) #1) ((x, ()), ths) |> #1;
   175 
   176 fun delIffs_generic (x, ths) =
   177   Library.foldl (delIff delXs #1) ((x, ()), ths) |> #1;
   178 
   179 end;
   180 
   181 
   182 (* tacticals *)
   183 
   184 fun CLASIMPSET tacf state =
   185   Classical.CLASET (fn cs => Simplifier.SIMPSET (fn ss => tacf (cs, ss))) state;
   186 
   187 fun CLASIMPSET' tacf i state =
   188   Classical.CLASET (fn cs => Simplifier.SIMPSET (fn ss => tacf (cs, ss) i)) state;
   189 
   190 
   191 fun clarsimp_tac (cs, ss) =
   192   safe_asm_full_simp_tac ss THEN_ALL_NEW
   193   Classical.clarify_tac (cs addSss ss);
   194 
   195 fun Clarsimp_tac i = clarsimp_tac (clasimpset ()) i;
   196 
   197 
   198 (* auto_tac *)
   199 
   200 fun blast_depth_tac cs m i thm =
   201     Blast.depth_tac cs m i thm
   202       handle Blast.TRANS s => (warning ("Blast_tac: " ^ s); Seq.empty);
   203 
   204 (* a variant of depth_tac that avoids interference of the simplifier
   205    with dup_step_tac when they are combined by auto_tac *)
   206 local
   207 fun slow_step_tac' cs = Classical.appWrappers cs
   208         (Classical.instp_step_tac cs APPEND' Classical.haz_step_tac cs);
   209 in fun nodup_depth_tac cs m i state = SELECT_GOAL
   210    (Classical.safe_steps_tac cs 1 THEN_ELSE
   211         (DEPTH_SOLVE (nodup_depth_tac cs m 1),
   212          Classical.inst0_step_tac cs 1 APPEND COND (K (m=0)) no_tac
   213              (slow_step_tac' cs 1 THEN DEPTH_SOLVE (nodup_depth_tac cs (m-1) 1))
   214         )) i state;
   215 end;
   216 
   217 (*Designed to be idempotent, except if blast_depth_tac instantiates variables
   218   in some of the subgoals*)
   219 fun mk_auto_tac (cs, ss) m n =
   220     let val cs' = cs addss ss
   221         val maintac =
   222           blast_depth_tac cs m               (* fast but can't use wrappers *)
   223           ORELSE'
   224           (CHANGED o nodup_depth_tac cs' n); (* slower but more general *)
   225     in  EVERY [ALLGOALS (Simplifier.asm_full_simp_tac ss),
   226                TRY (Classical.safe_tac cs),
   227                REPEAT (FIRSTGOAL maintac),
   228                TRY (Classical.safe_tac (cs addSss ss)),
   229                prune_params_tac]
   230     end;
   231 
   232 fun auto_tac css = mk_auto_tac css 4 2;
   233 fun Auto_tac st = auto_tac (clasimpset ()) st;
   234 fun auto () = by Auto_tac;
   235 
   236 
   237 (* force_tac *)
   238 
   239 (* aimed to solve the given subgoal totally, using whatever tools possible *)
   240 fun force_tac (cs,ss) = let val cs' = cs addss ss in SELECT_GOAL (EVERY [
   241         Classical.clarify_tac cs' 1,
   242         IF_UNSOLVED (Simplifier.asm_full_simp_tac ss 1),
   243         ALLGOALS (Classical.first_best_tac cs')]) end;
   244 fun Force_tac i = force_tac (clasimpset ()) i;
   245 fun force i = by (Force_tac i);
   246 
   247 
   248 (* basic combinations *)
   249 
   250 fun ADDSS tac (cs, ss) = let val cs' = cs addss ss in tac cs' end;
   251 
   252 val fast_simp_tac = ADDSS Classical.fast_tac;
   253 val slow_simp_tac = ADDSS Classical.slow_tac;
   254 val best_simp_tac = ADDSS Classical.best_tac;
   255 
   256 
   257 (* access clasimpset *)
   258 
   259 fun get_local_clasimpset ctxt =
   260   (Classical.get_local_claset ctxt, Simplifier.get_local_simpset ctxt);
   261 
   262 fun local_clasimpset_of ctxt =
   263   (Classical.local_claset_of ctxt, Simplifier.local_simpset_of ctxt);
   264 
   265 
   266 (* attributes *)
   267 
   268 fun attrib f = Attrib.declaration (fn th =>
   269  fn Context.Theory thy => (change_clasimpset_of thy (fn css => f (css, [th])); Context.Theory thy)
   270   | Context.Proof ctxt =>
   271       let
   272         val cs = Classical.get_local_claset ctxt;
   273         val ss = Simplifier.get_local_simpset ctxt;
   274         val (cs', ss') = f ((cs, ss), [th]);
   275         val ctxt' =
   276           ctxt
   277           |> Classical.put_local_claset cs'
   278           |> Simplifier.put_local_simpset ss';
   279       in Context.Proof ctxt' end);
   280 
   281 fun attrib' f (x, th) = (f (x, [th]), th);
   282 
   283 val iff_add = attrib (op addIffs);
   284 val iff_add' = attrib' addIffs_generic;
   285 val iff_del = attrib (op delIffs) o attrib' delIffs_generic;
   286 
   287 val iff_att = Attrib.syntax (Scan.lift
   288  (Args.del >> K iff_del ||
   289   Scan.option Args.add -- Args.query >> K iff_add' ||
   290   Scan.option Args.add >> K iff_add));
   291 
   292 
   293 (* method modifiers *)
   294 
   295 val iffN = "iff";
   296 
   297 val iff_modifiers =
   298  [Args.$$$ iffN -- Scan.option Args.add -- Args.colon
   299     >> K ((I, Attrib.context iff_add): Method.modifier),
   300   Args.$$$ iffN -- Scan.option Args.add -- Args.query_colon >> K (I, Attrib.context iff_add'),
   301   Args.$$$ iffN -- Args.del -- Args.colon >> K (I, Attrib.context iff_del)];
   302 
   303 val clasimp_modifiers =
   304   Simplifier.simp_modifiers @ Splitter.split_modifiers @
   305   Classical.cla_modifiers @ iff_modifiers;
   306 
   307 
   308 (* methods *)
   309 
   310 fun clasimp_meth tac prems ctxt = Method.METHOD (fn facts =>
   311   ALLGOALS (Method.insert_tac (prems @ facts)) THEN tac (local_clasimpset_of ctxt));
   312 
   313 fun clasimp_meth' tac prems ctxt = Method.METHOD (fn facts =>
   314   HEADGOAL (Method.insert_tac (prems @ facts) THEN' tac (local_clasimpset_of ctxt)));
   315 
   316 val clasimp_method = Method.bang_sectioned_args clasimp_modifiers o clasimp_meth;
   317 val clasimp_method' = Method.bang_sectioned_args clasimp_modifiers o clasimp_meth';
   318 
   319 
   320 fun auto_args m =
   321   Method.bang_sectioned_args' clasimp_modifiers (Scan.lift (Scan.option (Args.nat -- Args.nat))) m;
   322 
   323 fun auto_meth NONE = clasimp_meth (CHANGED_PROP o auto_tac)
   324   | auto_meth (SOME (m, n)) = clasimp_meth (CHANGED_PROP o (fn css => mk_auto_tac css m n));
   325 
   326 
   327 (* theory setup *)
   328 
   329 val setup =
   330  (Attrib.add_attributes
   331    [("iff", Attrib.common iff_att, "declaration of Simplifier / Classical rules")] #>
   332   Method.add_methods
   333    [("fastsimp", clasimp_method' fast_simp_tac, "combined fast and simp"),
   334     ("slowsimp", clasimp_method' slow_simp_tac, "combined slow and simp"),
   335     ("bestsimp", clasimp_method' best_simp_tac, "combined best and simp"),
   336     ("force", clasimp_method' force_tac, "force"),
   337     ("auto", auto_args auto_meth, "auto"),
   338     ("clarsimp", clasimp_method' (CHANGED_PROP oo clarsimp_tac), "clarify simplified goal")]);
   339 
   340 end;