src/Pure/PIDE/resources.ML
author wenzelm
Thu Sep 28 15:11:32 2017 +0200 (2017-09-28 ago)
changeset 66712 4c98c929a12a
parent 66711 80fa1401cf76
child 66771 925d10a7a610
permissions -rw-r--r--
session-qualified theory names are mandatory;
     1 (*  Title:      Pure/PIDE/resources.ML
     2     Author:     Makarius
     3 
     4 Resources for theories and auxiliary files.
     5 *)
     6 
     7 signature RESOURCES =
     8 sig
     9   val default_qualifier: string
    10   val init_session_base:
    11     {global_theories: (string * string) list,
    12      loaded_theories: string list,
    13      known_theories: (string * string) list} -> unit
    14   val finish_session_base: unit -> unit
    15   val global_theory: string -> string option
    16   val loaded_theory: string -> bool
    17   val known_theory: string -> Path.T option
    18   val master_directory: theory -> Path.T
    19   val imports_of: theory -> (string * Position.T) list
    20   val begin_theory: Path.T -> Thy_Header.header -> theory list -> theory
    21   val thy_path: Path.T -> Path.T
    22   val theory_qualifier: string -> string
    23   val import_name: string -> Path.T -> string -> {master_dir: Path.T, theory_name: string}
    24   val check_thy: Path.T -> string ->
    25    {master: Path.T * SHA1.digest, text: string, theory_pos: Position.T,
    26     imports: (string * Position.T) list, keywords: Thy_Header.keywords}
    27   val parse_files: string -> (theory -> Token.file list) parser
    28   val provide: Path.T * SHA1.digest -> theory -> theory
    29   val provide_parse_files: string -> (theory -> Token.file list * theory) parser
    30   val loaded_files_current: theory -> bool
    31 end;
    32 
    33 structure Resources: RESOURCES =
    34 struct
    35 
    36 (* session base *)
    37 
    38 val default_qualifier = "Draft";
    39 
    40 val empty_session_base =
    41   {global_theories = Symtab.empty: string Symtab.table,
    42    loaded_theories = Symtab.empty: unit Symtab.table,
    43    known_theories = Symtab.empty: Path.T Symtab.table};
    44 
    45 val global_session_base =
    46   Synchronized.var "Sessions.base" empty_session_base;
    47 
    48 fun init_session_base {global_theories, loaded_theories, known_theories} =
    49   Synchronized.change global_session_base
    50     (fn _ =>
    51       {global_theories = Symtab.make global_theories,
    52        loaded_theories = Symtab.make_set loaded_theories,
    53        known_theories = Symtab.make (map (apsnd Path.explode) known_theories)});
    54 
    55 fun finish_session_base () =
    56   Synchronized.change global_session_base
    57     (fn {global_theories, loaded_theories, ...} =>
    58       {global_theories = global_theories,
    59        loaded_theories = loaded_theories,
    60        known_theories = #known_theories empty_session_base});
    61 
    62 fun get_session_base f = f (Synchronized.value global_session_base);
    63 
    64 fun global_theory a = Symtab.lookup (get_session_base #global_theories) a;
    65 fun loaded_theory a = Symtab.defined (get_session_base #loaded_theories) a;
    66 fun known_theory a = Symtab.lookup (get_session_base #known_theories) a;
    67 
    68 
    69 (* manage source files *)
    70 
    71 type files =
    72  {master_dir: Path.T,  (*master directory of theory source*)
    73   imports: (string * Position.T) list,  (*source specification of imports*)
    74   provided: (Path.T * SHA1.digest) list};  (*source path, digest*)
    75 
    76 fun make_files (master_dir, imports, provided): files =
    77  {master_dir = master_dir, imports = imports, provided = provided};
    78 
    79 structure Files = Theory_Data
    80 (
    81   type T = files;
    82   val empty = make_files (Path.current, [], []);
    83   fun extend _ = empty;
    84   fun merge _ = empty;
    85 );
    86 
    87 fun map_files f =
    88   Files.map (fn {master_dir, imports, provided} =>
    89     make_files (f (master_dir, imports, provided)));
    90 
    91 
    92 val master_directory = #master_dir o Files.get;
    93 val imports_of = #imports o Files.get;
    94 
    95 fun begin_theory master_dir {name, imports, keywords} parents =
    96   Theory.begin_theory name parents
    97   |> map_files (fn _ => (master_dir, imports, []))
    98   |> Thy_Header.add_keywords keywords;
    99 
   100 
   101 (* theory files *)
   102 
   103 val thy_path = Path.ext "thy";
   104 
   105 fun theory_qualifier theory =
   106   (case global_theory theory of
   107     SOME qualifier => qualifier
   108   | NONE => Long_Name.qualifier theory);
   109 
   110 fun theory_name qualifier theory =
   111   if loaded_theory theory then (true, theory)
   112   else
   113     let val theory' =
   114       if Long_Name.is_qualified theory orelse is_some (global_theory theory)
   115       then theory
   116       else Long_Name.qualify qualifier theory
   117     in (false, theory') end;
   118 
   119 fun import_name qualifier dir s =
   120   (case theory_name qualifier (Thy_Header.import_name s) of
   121     (true, theory) => {master_dir = Path.current, theory_name = theory}
   122   | (false, theory) =>
   123       let val node_name =
   124         (case known_theory theory of
   125           SOME node_name => node_name
   126         | NONE => File.full_path dir (thy_path (Path.expand (Path.explode s))))
   127       in {master_dir = Path.dir node_name, theory_name = theory} end);
   128 
   129 fun check_file dir file = File.check_file (File.full_path dir file);
   130 
   131 fun check_thy dir thy_name =
   132   let
   133     val thy_base_name = Long_Name.base_name thy_name;
   134     val master_file =
   135       (case known_theory thy_name of
   136         SOME known_path => check_file Path.current known_path
   137       | NONE => check_file dir (thy_path (Path.basic thy_base_name)));
   138     val text = File.read master_file;
   139 
   140     val {name = (name, pos), imports, keywords} =
   141       Thy_Header.read (Path.position master_file) text;
   142     val _ =
   143       thy_base_name <> name andalso
   144         error ("Bad theory name " ^ quote name ^
   145           " for file " ^ Path.print (Path.base master_file) ^ Position.here pos);
   146   in
   147    {master = (master_file, SHA1.digest text), text = text, theory_pos = pos,
   148     imports = imports, keywords = keywords}
   149   end;
   150 
   151 
   152 (* load files *)
   153 
   154 fun parse_files cmd =
   155   Scan.ahead Parse.not_eof -- Parse.path >> (fn (tok, name) => fn thy =>
   156     (case Token.get_files tok of
   157       [] =>
   158         let
   159           val keywords = Thy_Header.get_keywords thy;
   160           val master_dir = master_directory thy;
   161           val pos = Token.pos_of tok;
   162           val src_paths = Keyword.command_files keywords cmd (Path.explode name);
   163         in map (Command.read_file master_dir pos) src_paths end
   164     | files => map Exn.release files));
   165 
   166 fun provide (src_path, id) =
   167   map_files (fn (master_dir, imports, provided) =>
   168     if AList.defined (op =) provided src_path then
   169       error ("Duplicate use of source file: " ^ Path.print src_path)
   170     else (master_dir, imports, (src_path, id) :: provided));
   171 
   172 fun provide_parse_files cmd =
   173   parse_files cmd >> (fn files => fn thy =>
   174     let
   175       val fs = files thy;
   176       val thy' = fold (fn {src_path, digest, ...} => provide (src_path, digest)) fs thy;
   177     in (fs, thy') end);
   178 
   179 fun load_file thy src_path =
   180   let
   181     val full_path = check_file (master_directory thy) src_path;
   182     val text = File.read full_path;
   183     val id = SHA1.digest text;
   184   in ((full_path, id), text) end;
   185 
   186 fun loaded_files_current thy =
   187   #provided (Files.get thy) |>
   188     forall (fn (src_path, id) =>
   189       (case try (load_file thy) src_path of
   190         NONE => false
   191       | SOME ((_, id'), _) => id = id'));
   192 
   193 
   194 (* antiquotations *)
   195 
   196 local
   197 
   198 fun err msg pos = error (msg ^ Position.here pos);
   199 
   200 fun check_path check_file ctxt dir (name, pos) =
   201   let
   202     val _ = Context_Position.report ctxt pos Markup.language_path;
   203 
   204     val path = Path.append dir (Path.explode name) handle ERROR msg => err msg pos;
   205     val _ = Path.expand path handle ERROR msg => err msg pos;
   206     val _ = Context_Position.report ctxt pos (Markup.path (Path.smart_implode path));
   207     val _ =
   208       (case check_file of
   209         NONE => path
   210       | SOME check => (check path handle ERROR msg => err msg pos));
   211   in path end;
   212 
   213 fun document_antiq check_file ctxt (name, pos) =
   214   let
   215     val dir = master_directory (Proof_Context.theory_of ctxt);
   216     val _ = check_path check_file ctxt dir (name, pos);
   217   in
   218     space_explode "/" name
   219     |> map Latex.output_ascii
   220     |> space_implode (Latex.output_ascii "/" ^ "\\discretionary{}{}{}")
   221     |> enclose "\\isatt{" "}"
   222   end;
   223 
   224 fun ML_antiq check_file ctxt (name, pos) =
   225   let val path = check_path check_file ctxt Path.current (name, pos);
   226   in "Path.explode " ^ ML_Syntax.print_string (Path.implode path) end;
   227 
   228 in
   229 
   230 val _ = Theory.setup
   231  (Thy_Output.antiquotation @{binding path} (Scan.lift (Parse.position Parse.path))
   232     (document_antiq NONE o #context) #>
   233   Thy_Output.antiquotation @{binding file} (Scan.lift (Parse.position Parse.path))
   234     (document_antiq (SOME File.check_file) o #context) #>
   235   Thy_Output.antiquotation @{binding dir} (Scan.lift (Parse.position Parse.path))
   236     (document_antiq (SOME File.check_dir) o #context) #>
   237   ML_Antiquotation.value @{binding path}
   238     (Args.context -- Scan.lift (Parse.position Parse.path)
   239       >> uncurry (ML_antiq NONE)) #>
   240   ML_Antiquotation.value @{binding file}
   241     (Args.context -- Scan.lift (Parse.position Parse.path)
   242       >> uncurry (ML_antiq (SOME File.check_file))) #>
   243   ML_Antiquotation.value @{binding dir}
   244     (Args.context -- Scan.lift (Parse.position Parse.path)
   245       >> uncurry (ML_antiq (SOME File.check_dir))));
   246 
   247 end;
   248 
   249 end;