src/Pure/Isar/isar_cmd.ML
author wenzelm
Sun Mar 09 17:08:31 2014 +0100 (2014-03-09 ago)
changeset 56005 4f4fc80b0613
parent 55828 42ac3cfb89f6
child 56006 6a4dcaf53664
permissions -rw-r--r--
simplified / modernized hide commands: proper outer parsers and PIDE markup via check;
     1 (*  Title:      Pure/Isar/isar_cmd.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Miscellaneous Isar commands.
     5 *)
     6 
     7 signature ISAR_CMD =
     8 sig
     9   val global_setup: Symbol_Pos.source -> theory -> theory
    10   val local_setup: Symbol_Pos.source -> Proof.context -> Proof.context
    11   val parse_ast_translation: Symbol_Pos.source -> theory -> theory
    12   val parse_translation: Symbol_Pos.source -> theory -> theory
    13   val print_translation: Symbol_Pos.source -> theory -> theory
    14   val typed_print_translation: Symbol_Pos.source -> theory -> theory
    15   val print_ast_translation: Symbol_Pos.source -> theory -> theory
    16   val translations: (xstring * string) Syntax.trrule list -> theory -> theory
    17   val no_translations: (xstring * string) Syntax.trrule list -> theory -> theory
    18   val oracle: bstring * Position.T -> Symbol_Pos.source -> theory -> theory
    19   val add_defs: (bool * bool) * ((binding * string) * Attrib.src list) list -> theory -> theory
    20   val declaration: {syntax: bool, pervasive: bool} ->
    21     Symbol_Pos.source -> local_theory -> local_theory
    22   val simproc_setup: string * Position.T -> string list -> Symbol_Pos.source ->
    23     string list -> local_theory -> local_theory
    24   val have: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    25   val hence: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    26   val show: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    27   val thus: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    28   val qed: Method.text_range option -> Toplevel.transition -> Toplevel.transition
    29   val terminal_proof: Method.text_range * Method.text_range option ->
    30     Toplevel.transition -> Toplevel.transition
    31   val default_proof: Toplevel.transition -> Toplevel.transition
    32   val immediate_proof: Toplevel.transition -> Toplevel.transition
    33   val done_proof: Toplevel.transition -> Toplevel.transition
    34   val skip_proof: Toplevel.transition -> Toplevel.transition
    35   val ml_diag: bool -> Symbol_Pos.source -> Toplevel.transition -> Toplevel.transition
    36   val diag_state: Proof.context -> Toplevel.state
    37   val diag_goal: Proof.context -> {context: Proof.context, facts: thm list, goal: thm}
    38   val print_theorems: bool -> Toplevel.transition -> Toplevel.transition
    39   val thy_deps: Toplevel.transition -> Toplevel.transition
    40   val locale_deps: Toplevel.transition -> Toplevel.transition
    41   val class_deps: Toplevel.transition -> Toplevel.transition
    42   val thm_deps: (Facts.ref * Attrib.src list) list -> Toplevel.transition -> Toplevel.transition
    43   val unused_thms: (string list * string list option) option ->
    44     Toplevel.transition -> Toplevel.transition
    45   val print_stmts: string list * (Facts.ref * Attrib.src list) list
    46     -> Toplevel.transition -> Toplevel.transition
    47   val print_thms: string list * (Facts.ref * Attrib.src list) list
    48     -> Toplevel.transition -> Toplevel.transition
    49   val print_prfs: bool -> string list * (Facts.ref * Attrib.src list) list option
    50     -> Toplevel.transition -> Toplevel.transition
    51   val print_prop: (string list * string) -> Toplevel.transition -> Toplevel.transition
    52   val print_term: (string list * string) -> Toplevel.transition -> Toplevel.transition
    53   val print_type: (string list * (string * string option)) ->
    54     Toplevel.transition -> Toplevel.transition
    55   val header_markup: Symbol_Pos.source -> Toplevel.transition -> Toplevel.transition
    56   val local_theory_markup: (xstring * Position.T) option * (Symbol_Pos.source) ->
    57     Toplevel.transition -> Toplevel.transition
    58   val proof_markup: Symbol_Pos.source -> Toplevel.transition -> Toplevel.transition
    59 end;
    60 
    61 structure Isar_Cmd: ISAR_CMD =
    62 struct
    63 
    64 
    65 (** theory declarations **)
    66 
    67 (* generic setup *)
    68 
    69 fun global_setup source =
    70   ML_Lex.read_source source
    71   |> ML_Context.expression (#pos source) "val setup: theory -> theory" "Context.map_theory setup"
    72   |> Context.theory_map;
    73 
    74 fun local_setup source =
    75   ML_Lex.read_source source
    76   |> ML_Context.expression (#pos source) "val setup: local_theory -> local_theory" "Context.map_proof setup"
    77   |> Context.proof_map;
    78 
    79 
    80 (* translation functions *)
    81 
    82 fun parse_ast_translation source =
    83   ML_Lex.read_source source
    84   |> ML_Context.expression (#pos source)
    85     "val parse_ast_translation: (string * (Proof.context -> Ast.ast list -> Ast.ast)) list"
    86     "Context.map_theory (Sign.parse_ast_translation parse_ast_translation)"
    87   |> Context.theory_map;
    88 
    89 fun parse_translation source =
    90   ML_Lex.read_source source
    91   |> ML_Context.expression (#pos source)
    92     "val parse_translation: (string * (Proof.context -> term list -> term)) list"
    93     "Context.map_theory (Sign.parse_translation parse_translation)"
    94   |> Context.theory_map;
    95 
    96 fun print_translation source =
    97   ML_Lex.read_source source
    98   |> ML_Context.expression (#pos source)
    99     "val print_translation: (string * (Proof.context -> term list -> term)) list"
   100     "Context.map_theory (Sign.print_translation print_translation)"
   101   |> Context.theory_map;
   102 
   103 fun typed_print_translation source =
   104   ML_Lex.read_source source
   105   |> ML_Context.expression (#pos source)
   106     "val typed_print_translation: (string * (Proof.context -> typ -> term list -> term)) list"
   107     "Context.map_theory (Sign.typed_print_translation typed_print_translation)"
   108   |> Context.theory_map;
   109 
   110 fun print_ast_translation source =
   111   ML_Lex.read_source source
   112   |> ML_Context.expression (#pos source)
   113     "val print_ast_translation: (string * (Proof.context -> Ast.ast list -> Ast.ast)) list"
   114     "Context.map_theory (Sign.print_ast_translation print_ast_translation)"
   115   |> Context.theory_map;
   116 
   117 
   118 (* translation rules *)
   119 
   120 fun read_trrules thy raw_rules =
   121   let
   122     val ctxt = Proof_Context.init_global thy;
   123   in
   124     raw_rules |> map (Syntax.map_trrule (fn (r, s) =>
   125       Syntax_Phases.parse_ast_pattern ctxt (Proof_Context.intern_type ctxt r, s)))
   126   end;
   127 
   128 fun translations args thy = Sign.add_trrules (read_trrules thy args) thy;
   129 fun no_translations args thy = Sign.del_trrules (read_trrules thy args) thy;
   130 
   131 
   132 (* oracles *)
   133 
   134 fun oracle (name, pos) source =
   135   let
   136     val body = ML_Lex.read_source source;
   137     val ants =
   138       ML_Lex.read Position.none
   139        ("local\n\
   140         \  val binding = " ^ ML_Syntax.make_binding (name, pos) ^ ";\n\
   141         \  val body = ") @ body @ ML_Lex.read Position.none (";\n\
   142         \in\n\
   143         \  val " ^ name ^
   144         " = snd (Context.>>> (Context.map_theory_result (Thm.add_oracle (binding, body))));\n\
   145         \end;\n");
   146   in Context.theory_map (ML_Context.exec (fn () => ML_Context.eval false (#pos source) ants)) end;
   147 
   148 
   149 (* old-style defs *)
   150 
   151 fun add_defs ((unchecked, overloaded), args) thy =
   152   thy |>
   153     (if unchecked then Global_Theory.add_defs_unchecked_cmd else Global_Theory.add_defs_cmd)
   154       overloaded
   155       (map (fn ((b, ax), srcs) => ((b, ax), map (Attrib.attribute_cmd_global thy) srcs)) args)
   156   |> snd;
   157 
   158 
   159 (* declarations *)
   160 
   161 fun declaration {syntax, pervasive} source =
   162   ML_Lex.read_source source
   163   |> ML_Context.expression (#pos source)
   164     "val declaration: Morphism.declaration"
   165     ("Context.map_proof (Local_Theory.declaration {syntax = " ^ Bool.toString syntax ^ ", \
   166       \pervasive = " ^ Bool.toString pervasive ^ "} declaration)")
   167   |> Context.proof_map;
   168 
   169 
   170 (* simprocs *)
   171 
   172 fun simproc_setup name lhss source identifier =
   173   ML_Lex.read_source source
   174   |> ML_Context.expression (#pos source)
   175     "val proc: Morphism.morphism -> Proof.context -> cterm -> thm option"
   176     ("Context.map_proof (Simplifier.def_simproc_cmd {name = " ^ ML_Syntax.make_binding name ^ ", \
   177       \lhss = " ^ ML_Syntax.print_strings lhss ^ ", proc = proc, \
   178       \identifier = Library.maps ML_Context.thms " ^ ML_Syntax.print_strings identifier ^ "})")
   179   |> Context.proof_map;
   180 
   181 
   182 (* goals *)
   183 
   184 fun goal opt_chain goal stmt int =
   185   opt_chain #> goal NONE (K I) stmt int;
   186 
   187 val have = goal I Proof.have_cmd;
   188 val hence = goal Proof.chain Proof.have_cmd;
   189 val show = goal I Proof.show_cmd;
   190 val thus = goal Proof.chain Proof.show_cmd;
   191 
   192 
   193 (* local endings *)
   194 
   195 fun local_qed m = Toplevel.proof (Proof.local_qed (m, true));
   196 val local_terminal_proof = Toplevel.proof' o Proof.local_future_terminal_proof;
   197 val local_default_proof = Toplevel.proof Proof.local_default_proof;
   198 val local_immediate_proof = Toplevel.proof Proof.local_immediate_proof;
   199 val local_done_proof = Toplevel.proof Proof.local_done_proof;
   200 val local_skip_proof = Toplevel.proof' Proof.local_skip_proof;
   201 
   202 val skip_local_qed = Toplevel.skip_proof (fn i => if i > 1 then i - 1 else raise Toplevel.UNDEF);
   203 
   204 
   205 (* global endings *)
   206 
   207 fun global_qed m = Toplevel.end_proof (K (Proof.global_qed (m, true)));
   208 val global_terminal_proof = Toplevel.end_proof o Proof.global_future_terminal_proof;
   209 val global_default_proof = Toplevel.end_proof (K Proof.global_default_proof);
   210 val global_immediate_proof = Toplevel.end_proof (K Proof.global_immediate_proof);
   211 val global_skip_proof = Toplevel.end_proof Proof.global_skip_proof;
   212 val global_done_proof = Toplevel.end_proof (K Proof.global_done_proof);
   213 
   214 val skip_global_qed = Toplevel.skip_proof_to_theory (fn n => n = 1);
   215 
   216 
   217 (* common endings *)
   218 
   219 fun qed m = local_qed m o global_qed m o skip_local_qed o skip_global_qed;
   220 fun terminal_proof m = local_terminal_proof m o global_terminal_proof m;
   221 val default_proof = local_default_proof o global_default_proof;
   222 val immediate_proof = local_immediate_proof o global_immediate_proof;
   223 val done_proof = local_done_proof o global_done_proof;
   224 val skip_proof = local_skip_proof o global_skip_proof;
   225 
   226 
   227 (* diagnostic ML evaluation *)
   228 
   229 structure Diag_State = Proof_Data
   230 (
   231   type T = Toplevel.state;
   232   fun init _ = Toplevel.toplevel;
   233 );
   234 
   235 fun ml_diag verbose source = Toplevel.keep (fn state =>
   236   let val opt_ctxt =
   237     try Toplevel.generic_theory_of state
   238     |> Option.map (Context.proof_of #> Diag_State.put state)
   239   in ML_Context.eval_source_in opt_ctxt verbose source end);
   240 
   241 val diag_state = Diag_State.get;
   242 
   243 fun diag_goal ctxt =
   244   Proof.goal (Toplevel.proof_of (diag_state ctxt))
   245     handle Toplevel.UNDEF => error "No goal present";
   246 
   247 val _ = Theory.setup
   248   (ML_Antiquote.value (Binding.qualify true "Isar" (Binding.name "state"))
   249     (Scan.succeed "Isar_Cmd.diag_state ML_context") #>
   250    ML_Antiquote.value (Binding.qualify true "Isar" (Binding.name "goal"))
   251     (Scan.succeed "Isar_Cmd.diag_goal ML_context"));
   252 
   253 
   254 (* print theorems *)
   255 
   256 val print_theorems_proof =
   257   Toplevel.keep (Proof_Context.print_lthms o Proof.context_of o Toplevel.proof_of);
   258 
   259 fun print_theorems_theory verbose = Toplevel.keep (fn state =>
   260   Toplevel.theory_of state |>
   261   (case Toplevel.previous_context_of state of
   262     SOME prev => Proof_Display.print_theorems_diff verbose (Proof_Context.theory_of prev)
   263   | NONE => Proof_Display.print_theorems verbose));
   264 
   265 fun print_theorems verbose =
   266   Toplevel.unknown_context o print_theorems_theory verbose o print_theorems_proof;
   267 
   268 
   269 (* display dependencies *)
   270 
   271 val thy_deps = Toplevel.unknown_theory o Toplevel.keep (fn state =>
   272   let
   273     val thy = Toplevel.theory_of state;
   274     val thy_session = Present.session_name thy;
   275 
   276     val gr = rev (Theory.nodes_of thy) |> map (fn node =>
   277       let
   278         val name = Context.theory_name node;
   279         val parents = map Context.theory_name (Theory.parents_of node);
   280         val session = Present.session_name node;
   281         val unfold = (session = thy_session);
   282       in
   283        {name = name, ID = name, parents = parents, dir = session,
   284         unfold = unfold, path = "", content = []}
   285       end);
   286   in Graph_Display.display_graph gr end);
   287 
   288 val locale_deps = Toplevel.unknown_theory o Toplevel.keep (fn state =>
   289   let
   290     val thy = Toplevel.theory_of state;
   291     val gr = Locale.pretty_locale_deps thy |> map (fn {name, parents, body} =>
   292      {name = Locale.extern thy name, ID = name, parents = parents,
   293       dir = "", unfold = true, path = "", content = [body]});
   294   in Graph_Display.display_graph gr end);
   295 
   296 val class_deps = Toplevel.unknown_theory o Toplevel.keep (fn state =>
   297   let
   298     val ctxt = Toplevel.context_of state;
   299     val {classes = (space, algebra), ...} = Type.rep_tsig (Proof_Context.tsig_of ctxt);
   300     val classes = Sorts.classes_of algebra;
   301     fun entry (c, (i, (_, cs))) =
   302       (i, {name = Name_Space.extern ctxt space c, ID = c, parents = Graph.Keys.dest cs,
   303             dir = "", unfold = true, path = "", content = []});
   304     val gr =
   305       Graph.fold (cons o entry) classes []
   306       |> sort (int_ord o pairself #1) |> map #2;
   307   in Graph_Display.display_graph gr end);
   308 
   309 fun thm_deps args = Toplevel.unknown_theory o Toplevel.keep (fn state =>
   310   Thm_Deps.thm_deps (Toplevel.theory_of state)
   311     (Attrib.eval_thms (Toplevel.context_of state) args));
   312 
   313 
   314 (* find unused theorems *)
   315 
   316 fun unused_thms opt_range = Toplevel.keep (fn state =>
   317   let
   318     val thy = Toplevel.theory_of state;
   319     val ctxt = Toplevel.context_of state;
   320     fun pretty_thm (a, th) = Proof_Context.pretty_fact ctxt (a, [th]);
   321     val get_theory = Context.get_theory thy;
   322   in
   323     Thm_Deps.unused_thms
   324       (case opt_range of
   325         NONE => (Theory.parents_of thy, [thy])
   326       | SOME (xs, NONE) => (map get_theory xs, [thy])
   327       | SOME (xs, SOME ys) => (map get_theory xs, map get_theory ys))
   328     |> map pretty_thm |> Pretty.chunks |> Pretty.writeln
   329   end);
   330 
   331 
   332 (* print theorems, terms, types etc. *)
   333 
   334 local
   335 
   336 fun string_of_stmts ctxt args =
   337   Attrib.eval_thms ctxt args
   338   |> map (Element.pretty_statement ctxt Thm.theoremK)
   339   |> Pretty.chunks2 |> Pretty.string_of;
   340 
   341 fun string_of_thms ctxt args =
   342   Pretty.string_of (Proof_Context.pretty_fact ctxt ("", Attrib.eval_thms ctxt args));
   343 
   344 fun string_of_prfs full state arg =
   345   Pretty.string_of
   346     (case arg of
   347       NONE =>
   348         let
   349           val {context = ctxt, goal = thm} = Proof.simple_goal (Toplevel.proof_of state);
   350           val thy = Proof_Context.theory_of ctxt;
   351           val prf = Thm.proof_of thm;
   352           val prop = Thm.full_prop_of thm;
   353           val prf' = Proofterm.rewrite_proof_notypes ([], []) prf;
   354         in
   355           Proof_Syntax.pretty_proof ctxt
   356             (if full then Reconstruct.reconstruct_proof thy prop prf' else prf')
   357         end
   358     | SOME srcs =>
   359         let val ctxt = Toplevel.context_of state
   360         in map (Proof_Syntax.pretty_proof_of ctxt full) (Attrib.eval_thms ctxt srcs) end
   361         |> Pretty.chunks);
   362 
   363 fun string_of_prop ctxt s =
   364   let
   365     val prop = Syntax.read_prop ctxt s;
   366     val ctxt' = Variable.auto_fixes prop ctxt;
   367   in Pretty.string_of (Pretty.quote (Syntax.pretty_term ctxt' prop)) end;
   368 
   369 fun string_of_term ctxt s =
   370   let
   371     val t = Syntax.read_term ctxt s;
   372     val T = Term.type_of t;
   373     val ctxt' = Variable.auto_fixes t ctxt;
   374   in
   375     Pretty.string_of
   376       (Pretty.block [Pretty.quote (Syntax.pretty_term ctxt' t), Pretty.fbrk,
   377         Pretty.str "::", Pretty.brk 1, Pretty.quote (Syntax.pretty_typ ctxt' T)])
   378   end;
   379 
   380 fun string_of_type ctxt (s, NONE) =
   381       let val T = Syntax.read_typ ctxt s
   382       in Pretty.string_of (Pretty.quote (Syntax.pretty_typ ctxt T)) end
   383   | string_of_type ctxt (s1, SOME s2) =
   384       let
   385         val ctxt' = Config.put show_sorts true ctxt;
   386         val raw_T = Syntax.parse_typ ctxt' s1;
   387         val S = Syntax.read_sort ctxt' s2;
   388         val T =
   389           Syntax.check_term ctxt'
   390             (Logic.mk_type raw_T |> Type.constraint (Term.itselfT (Type_Infer.anyT S)))
   391           |> Logic.dest_type;
   392       in Pretty.string_of (Pretty.quote (Syntax.pretty_typ ctxt' T)) end;
   393 
   394 fun print_item string_of (modes, arg) = Toplevel.keep (fn state =>
   395   Print_Mode.with_modes modes (fn () => writeln (string_of state arg)) ());
   396 
   397 in
   398 
   399 val print_stmts = print_item (string_of_stmts o Toplevel.context_of);
   400 val print_thms = print_item (string_of_thms o Toplevel.context_of);
   401 val print_prfs = print_item o string_of_prfs;
   402 val print_prop = print_item (string_of_prop o Toplevel.context_of);
   403 val print_term = print_item (string_of_term o Toplevel.context_of);
   404 val print_type = print_item (string_of_type o Toplevel.context_of);
   405 
   406 end;
   407 
   408 
   409 (* markup commands *)
   410 
   411 fun header_markup txt = Toplevel.keep (fn state =>
   412   if Toplevel.is_toplevel state then Thy_Output.check_text txt state
   413   else raise Toplevel.UNDEF);
   414 
   415 fun local_theory_markup (loc, txt) = Toplevel.present_local_theory loc (Thy_Output.check_text txt);
   416 val proof_markup = Toplevel.present_proof o Thy_Output.check_text;
   417 
   418 end;