src/Pure/drule.ML
author wenzelm
Tue Jul 11 12:17:02 2006 +0200 (2006-07-11 ago)
changeset 20077 4fc9a4fef219
parent 19999 9592df0c3176
child 20227 435601e8e53d
permissions -rw-r--r--
replaced Term.variant(list) by Name.variant(_list);
Name.clean;
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems.
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL OF COMP;
    10 
    11 signature BASIC_DRULE =
    12 sig
    13   val mk_implies: cterm * cterm -> cterm
    14   val list_implies: cterm list * cterm -> cterm
    15   val dest_implies: cterm -> cterm * cterm
    16   val dest_equals: cterm -> cterm * cterm
    17   val strip_imp_prems: cterm -> cterm list
    18   val strip_imp_concl: cterm -> cterm
    19   val cprems_of: thm -> cterm list
    20   val cterm_fun: (term -> term) -> (cterm -> cterm)
    21   val ctyp_fun: (typ -> typ) -> (ctyp -> ctyp)
    22   val read_insts: theory -> (indexname -> typ option) * (indexname -> sort option) ->
    23     (indexname -> typ option) * (indexname -> sort option) -> string list ->
    24     (indexname * string) list -> (ctyp * ctyp) list * (cterm * cterm) list
    25   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    26   val strip_shyps_warning: thm -> thm
    27   val forall_intr_list: cterm list -> thm -> thm
    28   val forall_intr_frees: thm -> thm
    29   val forall_intr_vars: thm -> thm
    30   val forall_elim_list: cterm list -> thm -> thm
    31   val forall_elim_var: int -> thm -> thm
    32   val forall_elim_vars: int -> thm -> thm
    33   val gen_all: thm -> thm
    34   val lift_all: cterm -> thm -> thm
    35   val freeze_thaw: thm -> thm * (thm -> thm)
    36   val freeze_thaw_robust: thm -> thm * (int -> thm -> thm)
    37   val implies_elim_list: thm -> thm list -> thm
    38   val implies_intr_list: cterm list -> thm -> thm
    39   val instantiate: (ctyp * ctyp) list * (cterm * cterm) list -> thm -> thm
    40   val zero_var_indexes: thm -> thm
    41   val implies_intr_hyps: thm -> thm
    42   val standard: thm -> thm
    43   val standard': thm -> thm
    44   val rotate_prems: int -> thm -> thm
    45   val rearrange_prems: int list -> thm -> thm
    46   val RSN: thm * (int * thm) -> thm
    47   val RS: thm * thm -> thm
    48   val RLN: thm list * (int * thm list) -> thm list
    49   val RL: thm list * thm list -> thm list
    50   val MRS: thm list * thm -> thm
    51   val MRL: thm list list * thm list -> thm list
    52   val OF: thm * thm list -> thm
    53   val compose: thm * int * thm -> thm list
    54   val COMP: thm * thm -> thm
    55   val read_instantiate_sg: theory -> (string*string)list -> thm -> thm
    56   val read_instantiate: (string*string)list -> thm -> thm
    57   val cterm_instantiate: (cterm*cterm)list -> thm -> thm
    58   val eq_thm_thy: thm * thm -> bool
    59   val eq_thm_prop: thm * thm -> bool
    60   val equiv_thm: thm * thm -> bool
    61   val size_of_thm: thm -> int
    62   val reflexive_thm: thm
    63   val symmetric_thm: thm
    64   val transitive_thm: thm
    65   val symmetric_fun: thm -> thm
    66   val extensional: thm -> thm
    67   val equals_cong: thm
    68   val imp_cong: thm
    69   val swap_prems_eq: thm
    70   val equal_abs_elim: cterm  -> thm -> thm
    71   val equal_abs_elim_list: cterm list -> thm -> thm
    72   val asm_rl: thm
    73   val cut_rl: thm
    74   val revcut_rl: thm
    75   val thin_rl: thm
    76   val triv_forall_equality: thm
    77   val distinct_prems_rl: thm
    78   val swap_prems_rl: thm
    79   val equal_intr_rule: thm
    80   val equal_elim_rule1: thm
    81   val equal_elim_rule2: thm
    82   val inst: string -> string -> thm -> thm
    83   val instantiate': ctyp option list -> cterm option list -> thm -> thm
    84 end;
    85 
    86 signature DRULE =
    87 sig
    88   include BASIC_DRULE
    89   val generalize: string list * string list -> thm -> thm
    90   val dest_binop: cterm -> cterm * cterm
    91   val list_comb: cterm * cterm list -> cterm
    92   val strip_comb: cterm -> cterm * cterm list
    93   val strip_type: ctyp -> ctyp list * ctyp
    94   val beta_conv: cterm -> cterm -> cterm
    95   val plain_prop_of: thm -> term
    96   val add_used: thm -> string list -> string list
    97   val flexflex_unique: thm -> thm
    98   val close_derivation: thm -> thm
    99   val local_standard: thm -> thm
   100   val store_thm: bstring -> thm -> thm
   101   val store_standard_thm: bstring -> thm -> thm
   102   val store_thm_open: bstring -> thm -> thm
   103   val store_standard_thm_open: bstring -> thm -> thm
   104   val compose_single: thm * int * thm -> thm
   105   val add_rule: thm -> thm list -> thm list
   106   val del_rule: thm -> thm list -> thm list
   107   val merge_rules: thm list * thm list -> thm list
   108   val imp_cong_rule: thm -> thm -> thm
   109   val beta_eta_conversion: cterm -> thm
   110   val eta_long_conversion: cterm -> thm
   111   val forall_conv: int -> (cterm -> thm) -> cterm -> thm
   112   val concl_conv: int -> (cterm -> thm) -> cterm -> thm
   113   val prems_conv: int -> (int -> cterm -> thm) -> cterm -> thm
   114   val goals_conv: (int -> bool) -> (cterm -> thm) -> cterm -> thm
   115   val fconv_rule: (cterm -> thm) -> thm -> thm
   116   val norm_hhf_eq: thm
   117   val is_norm_hhf: term -> bool
   118   val norm_hhf: theory -> term -> term
   119   val unvarify: thm -> thm
   120   val protect: cterm -> cterm
   121   val protectI: thm
   122   val protectD: thm
   123   val protect_cong: thm
   124   val implies_intr_protected: cterm list -> thm -> thm
   125   val termI: thm
   126   val mk_term: cterm -> thm
   127   val dest_term: thm -> cterm
   128   val freeze_all: thm -> thm
   129   val tvars_of_terms: term list -> (indexname * sort) list
   130   val vars_of_terms: term list -> (indexname * typ) list
   131   val tvars_of: thm -> (indexname * sort) list
   132   val vars_of: thm -> (indexname * typ) list
   133   val tfrees_of: thm -> (string * sort) list
   134   val frees_of: thm -> (string * typ) list
   135   val sort_triv: theory -> typ * sort -> thm list
   136   val unconstrainTs: thm -> thm
   137   val fold_terms: (term -> 'a -> 'a) -> thm -> 'a -> 'a
   138   val rename_bvars: (string * string) list -> thm -> thm
   139   val rename_bvars': string option list -> thm -> thm
   140   val incr_indexes: thm -> thm -> thm
   141   val incr_indexes2: thm -> thm -> thm -> thm
   142   val remdups_rl: thm
   143   val multi_resolve: thm list -> thm -> thm Seq.seq
   144   val multi_resolves: thm list -> thm list -> thm Seq.seq
   145   val abs_def: thm -> thm
   146   val read_instantiate_sg': theory -> (indexname * string) list -> thm -> thm
   147   val read_instantiate': (indexname * string) list -> thm -> thm
   148 end;
   149 
   150 structure Drule: DRULE =
   151 struct
   152 
   153 
   154 (** some cterm->cterm operations: faster than calling cterm_of! **)
   155 
   156 fun dest_binop ct =
   157   let val (ct1, ct2) = Thm.dest_comb ct
   158   in (#2 (Thm.dest_comb ct1), ct2) end;
   159 
   160 fun dest_implies ct =
   161   (case Thm.term_of ct of
   162     (Const ("==>", _) $ _ $ _) => dest_binop ct
   163   | _ => raise TERM ("dest_implies", [term_of ct]));
   164 
   165 fun dest_equals ct =
   166   (case Thm.term_of ct of
   167     (Const ("==", _) $ _ $ _) => dest_binop ct
   168     | _ => raise TERM ("dest_equals", [term_of ct]));
   169 
   170 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   171 fun strip_imp_prems ct =
   172     let val (cA,cB) = dest_implies ct
   173     in  cA :: strip_imp_prems cB  end
   174     handle TERM _ => [];
   175 
   176 (* A1==>...An==>B  goes to B, where B is not an implication *)
   177 fun strip_imp_concl ct =
   178     case term_of ct of (Const("==>", _) $ _ $ _) =>
   179         strip_imp_concl (#2 (Thm.dest_comb ct))
   180   | _ => ct;
   181 
   182 (*The premises of a theorem, as a cterm list*)
   183 val cprems_of = strip_imp_prems o cprop_of;
   184 
   185 fun cterm_fun f ct =
   186   let val {t, thy, ...} = Thm.rep_cterm ct
   187   in Thm.cterm_of thy (f t) end;
   188 
   189 fun ctyp_fun f cT =
   190   let val {T, thy, ...} = Thm.rep_ctyp cT
   191   in Thm.ctyp_of thy (f T) end;
   192 
   193 val cert = cterm_of ProtoPure.thy;
   194 
   195 val implies = cert Term.implies;
   196 fun mk_implies (A, B) = Thm.capply (Thm.capply implies A) B;
   197 
   198 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   199 fun list_implies([], B) = B
   200   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   201 
   202 (*cterm version of list_comb: maps  (f, [t1,...,tn])  to  f(t1,...,tn) *)
   203 fun list_comb (f, []) = f
   204   | list_comb (f, t::ts) = list_comb (Thm.capply f t, ts);
   205 
   206 (*cterm version of strip_comb: maps  f(t1,...,tn)  to  (f, [t1,...,tn]) *)
   207 fun strip_comb ct =
   208   let
   209     fun stripc (p as (ct, cts)) =
   210       let val (ct1, ct2) = Thm.dest_comb ct
   211       in stripc (ct1, ct2 :: cts) end handle CTERM _ => p
   212   in stripc (ct, []) end;
   213 
   214 (* cterm version of strip_type: maps  [T1,...,Tn]--->T  to   ([T1,T2,...,Tn], T) *)
   215 fun strip_type cT = (case Thm.typ_of cT of
   216     Type ("fun", _) =>
   217       let
   218         val [cT1, cT2] = Thm.dest_ctyp cT;
   219         val (cTs, cT') = strip_type cT2
   220       in (cT1 :: cTs, cT') end
   221   | _ => ([], cT));
   222 
   223 (*Beta-conversion for cterms, where x is an abstraction. Simply returns the rhs
   224   of the meta-equality returned by the beta_conversion rule.*)
   225 fun beta_conv x y =
   226     #2 (Thm.dest_comb (cprop_of (Thm.beta_conversion false (Thm.capply x y))));
   227 
   228 fun plain_prop_of raw_thm =
   229   let
   230     val thm = Thm.strip_shyps raw_thm;
   231     fun err msg = raise THM ("plain_prop_of: " ^ msg, 0, [thm]);
   232     val {hyps, prop, tpairs, ...} = Thm.rep_thm thm;
   233   in
   234     if not (null hyps) then
   235       err "theorem may not contain hypotheses"
   236     else if not (null (Thm.extra_shyps thm)) then
   237       err "theorem may not contain sort hypotheses"
   238     else if not (null tpairs) then
   239       err "theorem may not contain flex-flex pairs"
   240     else prop
   241   end;
   242 
   243 
   244 
   245 (** reading of instantiations **)
   246 
   247 fun absent ixn =
   248   error("No such variable in term: " ^ Syntax.string_of_vname ixn);
   249 
   250 fun inst_failure ixn =
   251   error("Instantiation of " ^ Syntax.string_of_vname ixn ^ " fails");
   252 
   253 fun read_insts thy (rtypes,rsorts) (types,sorts) used insts =
   254 let
   255     fun is_tv ((a, _), _) =
   256       (case Symbol.explode a of "'" :: _ => true | _ => false);
   257     val (tvs, vs) = List.partition is_tv insts;
   258     fun sort_of ixn = case rsorts ixn of SOME S => S | NONE => absent ixn;
   259     fun readT (ixn, st) =
   260         let val S = sort_of ixn;
   261             val T = Sign.read_typ (thy,sorts) st;
   262         in if Sign.typ_instance thy (T, TVar(ixn,S)) then (ixn,T)
   263            else inst_failure ixn
   264         end
   265     val tye = map readT tvs;
   266     fun mkty(ixn,st) = (case rtypes ixn of
   267                           SOME T => (ixn,(st,typ_subst_TVars tye T))
   268                         | NONE => absent ixn);
   269     val ixnsTs = map mkty vs;
   270     val ixns = map fst ixnsTs
   271     and sTs  = map snd ixnsTs
   272     val (cts,tye2) = read_def_cterms(thy,types,sorts) used false sTs;
   273     fun mkcVar(ixn,T) =
   274         let val U = typ_subst_TVars tye2 T
   275         in cterm_of thy (Var(ixn,U)) end
   276     val ixnTs = ListPair.zip(ixns, map snd sTs)
   277 in (map (fn (ixn, T) => (ctyp_of thy (TVar (ixn, sort_of ixn)),
   278       ctyp_of thy T)) (tye2 @ tye),
   279     ListPair.zip(map mkcVar ixnTs,cts))
   280 end;
   281 
   282 
   283 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   284      Used for establishing default types (of variables) and sorts (of
   285      type variables) when reading another term.
   286      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   287 ***)
   288 
   289 fun types_sorts thm =
   290     let val {prop, hyps, tpairs, ...} = Thm.rep_thm thm;
   291         (* bogus term! *)
   292         val big = Term.list_comb
   293                     (Term.list_comb (prop, hyps), Thm.terms_of_tpairs tpairs);
   294         val vars = map dest_Var (term_vars big);
   295         val frees = map dest_Free (term_frees big);
   296         val tvars = term_tvars big;
   297         val tfrees = term_tfrees big;
   298         fun typ(a,i) = if i<0 then AList.lookup (op =) frees a else AList.lookup (op =) vars (a,i);
   299         fun sort(a,i) = if i<0 then AList.lookup (op =) tfrees a else AList.lookup (op =) tvars (a,i);
   300     in (typ,sort) end;
   301 
   302 fun add_used thm used =
   303   let val {prop, hyps, tpairs, ...} = Thm.rep_thm thm in
   304     add_term_tvarnames (prop, used)
   305     |> fold (curry add_term_tvarnames) hyps
   306     |> fold (curry add_term_tvarnames) (Thm.terms_of_tpairs tpairs)
   307   end;
   308 
   309 
   310 
   311 (** Standardization of rules **)
   312 
   313 (*vars in left-to-right order*)
   314 fun tvars_of_terms ts = rev (fold Term.add_tvars ts []);
   315 fun vars_of_terms ts = rev (fold Term.add_vars ts []);
   316 fun tvars_of thm = tvars_of_terms [Thm.full_prop_of thm];
   317 fun vars_of thm = vars_of_terms [Thm.full_prop_of thm];
   318 
   319 fun fold_terms f th =
   320   let val {hyps, tpairs, prop, ...} = Thm.rep_thm th
   321   in f prop #> fold (fn (t, u) => f t #> f u) tpairs #> fold f hyps end;
   322 
   323 fun tfrees_of th = rev (fold_terms Term.add_tfrees th []);
   324 fun frees_of th = rev (fold_terms Term.add_frees th []);
   325 
   326 
   327 (* type classes and sorts *)
   328 
   329 fun sort_triv thy (T, S) =
   330   let
   331     val certT = Thm.ctyp_of thy;
   332     val cT = certT T;
   333     fun class_triv c =
   334       Thm.class_triv thy c
   335       |> Thm.instantiate ([(certT (TVar (("'a", 0), [c])), cT)], []);
   336   in map class_triv S end;
   337 
   338 fun unconstrainTs th =
   339   fold_rev (Thm.unconstrainT o Thm.ctyp_of (Thm.theory_of_thm th) o TVar) (tvars_of th) th;
   340 
   341 fun strip_shyps_warning thm =
   342   let
   343     val str_of_sort = Pretty.str_of o Sign.pretty_sort (Thm.theory_of_thm thm);
   344     val thm' = Thm.strip_shyps thm;
   345     val xshyps = Thm.extra_shyps thm';
   346   in
   347     if null xshyps then ()
   348     else warning ("Pending sort hypotheses: " ^ commas (map str_of_sort xshyps));
   349     thm'
   350   end;
   351 
   352 (*Generalization over a list of variables*)
   353 val forall_intr_list = fold_rev forall_intr;
   354 
   355 (*Generalization over all suitable Free variables*)
   356 fun forall_intr_frees th =
   357     let
   358       val {prop, hyps, tpairs, thy,...} = rep_thm th;
   359       val fixed = fold Term.add_frees (Thm.terms_of_tpairs tpairs @ hyps) [];
   360       val frees = Term.fold_aterms (fn Free v =>
   361         if member (op =) fixed v then I else insert (op =) v | _ => I) prop [];
   362     in fold (forall_intr o cterm_of thy o Free) frees th end;
   363 
   364 (*Generalization over Vars -- canonical order*)
   365 fun forall_intr_vars th =
   366   let val cert = Thm.cterm_of (Thm.theory_of_thm th)
   367   in forall_intr_list (map (cert o Var) (vars_of th)) th end;
   368 
   369 val forall_elim_var = PureThy.forall_elim_var;
   370 val forall_elim_vars = PureThy.forall_elim_vars;
   371 
   372 fun outer_params t =
   373   let val vs = Term.strip_all_vars t
   374   in Name.variant_list [] (map (Name.clean o #1) vs) ~~ map #2 vs end;
   375 
   376 (*generalize outermost parameters*)
   377 fun gen_all th =
   378   let
   379     val {thy, prop, maxidx, ...} = Thm.rep_thm th;
   380     val cert = Thm.cterm_of thy;
   381     fun elim (x, T) = Thm.forall_elim (cert (Var ((x, maxidx + 1), T)));
   382   in fold elim (outer_params prop) th end;
   383 
   384 (*lift vars wrt. outermost goal parameters
   385   -- reverses the effect of gen_all modulo higher-order unification*)
   386 fun lift_all goal th =
   387   let
   388     val thy = Theory.merge (Thm.theory_of_cterm goal, Thm.theory_of_thm th);
   389     val cert = Thm.cterm_of thy;
   390     val maxidx = Thm.maxidx_of th;
   391     val ps = outer_params (Thm.term_of goal)
   392       |> map (fn (x, T) => Var ((x, maxidx + 1), Logic.incr_tvar (maxidx + 1) T));
   393     val Ts = map Term.fastype_of ps;
   394     val inst = vars_of th |> map (fn (xi, T) =>
   395       (cert (Var (xi, T)), cert (Term.list_comb (Var (xi, Ts ---> T), ps))));
   396   in
   397     th |> Thm.instantiate ([], inst)
   398     |> fold_rev (Thm.forall_intr o cert) ps
   399   end;
   400 
   401 (*direct generalization*)
   402 fun generalize names th = Thm.generalize names (Thm.maxidx_of th + 1) th;
   403 
   404 (*specialization over a list of cterms*)
   405 val forall_elim_list = fold forall_elim;
   406 
   407 (*maps A1,...,An |- B  to  [| A1;...;An |] ==> B*)
   408 val implies_intr_list = fold_rev implies_intr;
   409 
   410 (*maps [| A1;...;An |] ==> B and [A1,...,An]  to  B*)
   411 fun implies_elim_list impth ths = Library.foldl (uncurry implies_elim) (impth,ths);
   412 
   413 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   414 fun zero_var_indexes th =
   415   let
   416     val thy = Thm.theory_of_thm th;
   417     val certT = Thm.ctyp_of thy and cert = Thm.cterm_of thy;
   418     val (instT, inst) = Term.zero_var_indexes_inst (Thm.full_prop_of th);
   419     val cinstT = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   420     val cinst = map (fn (v, t) => (cert (Var v), cert t)) inst;
   421   in Thm.adjust_maxidx_thm (Thm.instantiate (cinstT, cinst) th) end;
   422 
   423 
   424 (** Standard form of object-rule: no hypotheses, flexflex constraints,
   425     Frees, or outer quantifiers; all generality expressed by Vars of index 0.**)
   426 
   427 (*Discharge all hypotheses.*)
   428 fun implies_intr_hyps th =
   429   fold Thm.implies_intr (#hyps (Thm.crep_thm th)) th;
   430 
   431 (*Squash a theorem's flexflex constraints provided it can be done uniquely.
   432   This step can lose information.*)
   433 fun flexflex_unique th =
   434   if null (tpairs_of th) then th else
   435     case Seq.chop 2 (flexflex_rule th) of
   436       ([th],_) => th
   437     | ([],_)   => raise THM("flexflex_unique: impossible constraints", 0, [th])
   438     |      _   => raise THM("flexflex_unique: multiple unifiers", 0, [th]);
   439 
   440 fun close_derivation thm =
   441   if Thm.get_name_tags thm = ("", []) then Thm.name_thm ("", thm)
   442   else thm;
   443 
   444 val standard' =
   445   implies_intr_hyps
   446   #> forall_intr_frees
   447   #> `Thm.maxidx_of
   448   #-> (fn maxidx =>
   449     forall_elim_vars (maxidx + 1)
   450     #> strip_shyps_warning
   451     #> zero_var_indexes
   452     #> Thm.varifyT
   453     #> Thm.compress);
   454 
   455 val standard =
   456   flexflex_unique
   457   #> standard'
   458   #> close_derivation;
   459 
   460 val local_standard =
   461   strip_shyps
   462   #> zero_var_indexes
   463   #> Thm.compress
   464   #> close_derivation;
   465 
   466 
   467 (*Convert all Vars in a theorem to Frees.  Also return a function for
   468   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   469   Similar code in type/freeze_thaw*)
   470 
   471 fun freeze_thaw_robust th =
   472  let val fth = Thm.freezeT th
   473      val {prop, tpairs, thy, ...} = rep_thm fth
   474  in
   475    case foldr add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   476        [] => (fth, fn i => fn x => x)   (*No vars: nothing to do!*)
   477      | vars =>
   478          let fun newName (Var(ix,_)) = (ix, gensym (string_of_indexname ix))
   479              val alist = map newName vars
   480              fun mk_inst (Var(v,T)) =
   481                  (cterm_of thy (Var(v,T)),
   482                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   483              val insts = map mk_inst vars
   484              fun thaw i th' = (*i is non-negative increment for Var indexes*)
   485                  th' |> forall_intr_list (map #2 insts)
   486                      |> forall_elim_list (map (Thm.cterm_incr_indexes i o #1) insts)
   487          in  (Thm.instantiate ([],insts) fth, thaw)  end
   488  end;
   489 
   490 (*Basic version of the function above. No option to rename Vars apart in thaw.
   491   The Frees created from Vars have nice names. FIXME: does not check for
   492   clashes with variables in the assumptions, so delete and use freeze_thaw_robust instead?*)
   493 fun freeze_thaw th =
   494  let val fth = Thm.freezeT th
   495      val {prop, tpairs, thy, ...} = rep_thm fth
   496  in
   497    case foldr add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   498        [] => (fth, fn x => x)
   499      | vars =>
   500          let fun newName (Var(ix,_), (pairs,used)) =
   501                    let val v = Name.variant used (string_of_indexname ix)
   502                    in  ((ix,v)::pairs, v::used)  end;
   503              val (alist, _) = foldr newName ([], Library.foldr add_term_names
   504                (prop :: Thm.terms_of_tpairs tpairs, [])) vars
   505              fun mk_inst (Var(v,T)) =
   506                  (cterm_of thy (Var(v,T)),
   507                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   508              val insts = map mk_inst vars
   509              fun thaw th' =
   510                  th' |> forall_intr_list (map #2 insts)
   511                      |> forall_elim_list (map #1 insts)
   512          in  (Thm.instantiate ([],insts) fth, thaw)  end
   513  end;
   514 
   515 (*Rotates a rule's premises to the left by k*)
   516 val rotate_prems = permute_prems 0;
   517 
   518 (* permute prems, where the i-th position in the argument list (counting from 0)
   519    gives the position within the original thm to be transferred to position i.
   520    Any remaining trailing positions are left unchanged. *)
   521 val rearrange_prems = let
   522   fun rearr new []      thm = thm
   523   |   rearr new (p::ps) thm = rearr (new+1)
   524      (map (fn q => if new<=q andalso q<p then q+1 else q) ps)
   525      (permute_prems (new+1) (new-p) (permute_prems new (p-new) thm))
   526   in rearr 0 end;
   527 
   528 (*Resolution: exactly one resolvent must be produced.*)
   529 fun tha RSN (i,thb) =
   530   case Seq.chop 2 (biresolution false [(false,tha)] i thb) of
   531       ([th],_) => th
   532     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   533     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   534 
   535 (*resolution: P==>Q, Q==>R gives P==>R. *)
   536 fun tha RS thb = tha RSN (1,thb);
   537 
   538 (*For joining lists of rules*)
   539 fun thas RLN (i,thbs) =
   540   let val resolve = biresolution false (map (pair false) thas) i
   541       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   542   in maps resb thbs end;
   543 
   544 fun thas RL thbs = thas RLN (1,thbs);
   545 
   546 (*Resolve a list of rules against bottom_rl from right to left;
   547   makes proof trees*)
   548 fun rls MRS bottom_rl =
   549   let fun rs_aux i [] = bottom_rl
   550         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   551   in  rs_aux 1 rls  end;
   552 
   553 (*As above, but for rule lists*)
   554 fun rlss MRL bottom_rls =
   555   let fun rs_aux i [] = bottom_rls
   556         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   557   in  rs_aux 1 rlss  end;
   558 
   559 (*A version of MRS with more appropriate argument order*)
   560 fun bottom_rl OF rls = rls MRS bottom_rl;
   561 
   562 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   563   with no lifting or renaming!  Q may contain ==> or meta-quants
   564   ALWAYS deletes premise i *)
   565 fun compose(tha,i,thb) =
   566     Seq.list_of (bicompose false (false,tha,0) i thb);
   567 
   568 fun compose_single (tha,i,thb) =
   569   (case compose (tha,i,thb) of
   570     [th] => th
   571   | _ => raise THM ("compose: unique result expected", i, [tha,thb]));
   572 
   573 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   574 fun tha COMP thb =
   575     case compose(tha,1,thb) of
   576         [th] => th
   577       | _ =>   raise THM("COMP", 1, [tha,thb]);
   578 
   579 
   580 (** theorem equality **)
   581 
   582 (*True if the two theorems have the same theory.*)
   583 val eq_thm_thy = eq_thy o pairself Thm.theory_of_thm;
   584 
   585 (*True if the two theorems have the same prop field, ignoring hyps, der, etc.*)
   586 val eq_thm_prop = op aconv o pairself Thm.full_prop_of;
   587 
   588 (*Useful "distance" function for BEST_FIRST*)
   589 val size_of_thm = size_of_term o Thm.full_prop_of;
   590 
   591 (*maintain lists of theorems --- preserving canonical order*)
   592 val del_rule = remove eq_thm_prop;
   593 fun add_rule th = cons th o del_rule th;
   594 val merge_rules = Library.merge eq_thm_prop;
   595 
   596 (*pattern equivalence*)
   597 fun equiv_thm ths =
   598   Pattern.equiv (Theory.merge (pairself Thm.theory_of_thm ths)) (pairself Thm.full_prop_of ths);
   599 
   600 
   601 (*** Meta-Rewriting Rules ***)
   602 
   603 fun read_prop s = read_cterm ProtoPure.thy (s, propT);
   604 
   605 fun store_thm name thm = hd (PureThy.smart_store_thms (name, [thm]));
   606 fun store_standard_thm name thm = store_thm name (standard thm);
   607 fun store_thm_open name thm = hd (PureThy.smart_store_thms_open (name, [thm]));
   608 fun store_standard_thm_open name thm = store_thm_open name (standard' thm);
   609 
   610 val reflexive_thm =
   611   let val cx = cert (Var(("x",0),TVar(("'a",0),[])))
   612   in store_standard_thm_open "reflexive" (Thm.reflexive cx) end;
   613 
   614 val symmetric_thm =
   615   let val xy = read_prop "x == y"
   616   in store_standard_thm_open "symmetric" (Thm.implies_intr xy (Thm.symmetric (Thm.assume xy))) end;
   617 
   618 val transitive_thm =
   619   let val xy = read_prop "x == y"
   620       val yz = read_prop "y == z"
   621       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   622   in store_standard_thm_open "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   623 
   624 fun symmetric_fun thm = thm RS symmetric_thm;
   625 
   626 fun extensional eq =
   627   let val eq' =
   628     abstract_rule "x" (snd (Thm.dest_comb (fst (dest_equals (cprop_of eq))))) eq
   629   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   630 
   631 val equals_cong =
   632   store_standard_thm_open "equals_cong" (Thm.reflexive (read_prop "x == y"));
   633 
   634 val imp_cong =
   635   let
   636     val ABC = read_prop "PROP A ==> PROP B == PROP C"
   637     val AB = read_prop "PROP A ==> PROP B"
   638     val AC = read_prop "PROP A ==> PROP C"
   639     val A = read_prop "PROP A"
   640   in
   641     store_standard_thm_open "imp_cong" (implies_intr ABC (equal_intr
   642       (implies_intr AB (implies_intr A
   643         (equal_elim (implies_elim (assume ABC) (assume A))
   644           (implies_elim (assume AB) (assume A)))))
   645       (implies_intr AC (implies_intr A
   646         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   647           (implies_elim (assume AC) (assume A)))))))
   648   end;
   649 
   650 val swap_prems_eq =
   651   let
   652     val ABC = read_prop "PROP A ==> PROP B ==> PROP C"
   653     val BAC = read_prop "PROP B ==> PROP A ==> PROP C"
   654     val A = read_prop "PROP A"
   655     val B = read_prop "PROP B"
   656   in
   657     store_standard_thm_open "swap_prems_eq" (equal_intr
   658       (implies_intr ABC (implies_intr B (implies_intr A
   659         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   660       (implies_intr BAC (implies_intr A (implies_intr B
   661         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   662   end;
   663 
   664 val imp_cong_rule = combination o combination (reflexive implies);
   665 
   666 local
   667   val dest_eq = dest_equals o cprop_of
   668   val rhs_of = snd o dest_eq
   669 in
   670 fun beta_eta_conversion t =
   671   let val thm = beta_conversion true t
   672   in transitive thm (eta_conversion (rhs_of thm)) end
   673 end;
   674 
   675 fun eta_long_conversion ct = transitive (beta_eta_conversion ct)
   676   (symmetric (beta_eta_conversion (cterm_fun (Pattern.eta_long []) ct)));
   677 
   678 val abs_def =
   679   let
   680     fun contract_lhs th =
   681       Thm.transitive (Thm.symmetric (beta_eta_conversion (fst (dest_equals (cprop_of th))))) th;
   682     fun abstract cx th = Thm.abstract_rule
   683         (case Thm.term_of cx of Var ((x, _), _) => x | Free (x, _) => x | _ => "x") cx th
   684       handle THM _ => raise THM ("Malformed definitional equation", 0, [th]);
   685   in
   686     contract_lhs
   687     #> `(snd o strip_comb o fst o dest_equals o cprop_of)
   688     #-> fold_rev abstract
   689     #> contract_lhs
   690   end;
   691 
   692 (*rewrite B in !!x1 ... xn. B*)
   693 fun forall_conv 0 cv ct = cv ct
   694   | forall_conv n cv ct =
   695       (case try Thm.dest_comb ct of
   696         NONE => cv ct
   697       | SOME (A, B) =>
   698           (case (term_of A, term_of B) of
   699             (Const ("all", _), Abs (x, _, _)) =>
   700               let val (v, B') = Thm.dest_abs (SOME (gensym "all_")) B in
   701                 Thm.combination (Thm.reflexive A)
   702                   (Thm.abstract_rule x v (forall_conv (n - 1) cv B'))
   703               end
   704           | _ => cv ct));
   705 
   706 (*rewrite B in A1 ==> ... ==> An ==> B*)
   707 fun concl_conv 0 cv ct = cv ct
   708   | concl_conv n cv ct =
   709       (case try dest_implies ct of
   710         NONE => cv ct
   711       | SOME (A, B) => imp_cong_rule (reflexive A) (concl_conv (n - 1) cv B));
   712 
   713 (*rewrite the A's in A1 ==> ... ==> An ==> B*)
   714 fun prems_conv 0 _ = reflexive
   715   | prems_conv n cv =
   716       let
   717         fun conv i ct =
   718           if i = n + 1 then reflexive ct
   719           else
   720             (case try dest_implies ct of
   721               NONE => reflexive ct
   722             | SOME (A, B) => imp_cong_rule (cv i A) (conv (i + 1) B));
   723   in conv 1 end;
   724 
   725 fun goals_conv pred cv = prems_conv ~1 (fn i => if pred i then cv else reflexive);
   726 fun fconv_rule cv th = equal_elim (cv (cprop_of th)) th;
   727 
   728 
   729 (*** Some useful meta-theorems ***)
   730 
   731 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   732 val asm_rl = store_standard_thm_open "asm_rl" (Thm.trivial (read_prop "PROP ?psi"));
   733 val _ = store_thm "_" asm_rl;
   734 
   735 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   736 val cut_rl =
   737   store_standard_thm_open "cut_rl"
   738     (Thm.trivial (read_prop "PROP ?psi ==> PROP ?theta"));
   739 
   740 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   741      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   742 val revcut_rl =
   743   let val V = read_prop "PROP V"
   744       and VW = read_prop "PROP V ==> PROP W";
   745   in
   746     store_standard_thm_open "revcut_rl"
   747       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   748   end;
   749 
   750 (*for deleting an unwanted assumption*)
   751 val thin_rl =
   752   let val V = read_prop "PROP V"
   753       and W = read_prop "PROP W";
   754   in store_standard_thm_open "thin_rl" (implies_intr V (implies_intr W (assume W))) end;
   755 
   756 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   757 val triv_forall_equality =
   758   let val V  = read_prop "PROP V"
   759       and QV = read_prop "!!x::'a. PROP V"
   760       and x  = cert (Free ("x", Term.aT []));
   761   in
   762     store_standard_thm_open "triv_forall_equality"
   763       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   764         (implies_intr V  (forall_intr x (assume V))))
   765   end;
   766 
   767 (* (PROP ?Phi ==> PROP ?Phi ==> PROP ?Psi) ==>
   768    (PROP ?Phi ==> PROP ?Psi)
   769 *)
   770 val distinct_prems_rl =
   771   let
   772     val AAB = read_prop "PROP Phi ==> PROP Phi ==> PROP Psi"
   773     val A = read_prop "PROP Phi";
   774   in
   775     store_standard_thm_open "distinct_prems_rl"
   776       (implies_intr_list [AAB, A] (implies_elim_list (assume AAB) [assume A, assume A]))
   777   end;
   778 
   779 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   780    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   781    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   782 *)
   783 val swap_prems_rl =
   784   let val cmajor = read_prop "PROP PhiA ==> PROP PhiB ==> PROP Psi";
   785       val major = assume cmajor;
   786       val cminor1 = read_prop "PROP PhiA";
   787       val minor1 = assume cminor1;
   788       val cminor2 = read_prop "PROP PhiB";
   789       val minor2 = assume cminor2;
   790   in store_standard_thm_open "swap_prems_rl"
   791        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   792          (implies_elim (implies_elim major minor1) minor2))))
   793   end;
   794 
   795 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   796    ==> PROP ?phi == PROP ?psi
   797    Introduction rule for == as a meta-theorem.
   798 *)
   799 val equal_intr_rule =
   800   let val PQ = read_prop "PROP phi ==> PROP psi"
   801       and QP = read_prop "PROP psi ==> PROP phi"
   802   in
   803     store_standard_thm_open "equal_intr_rule"
   804       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   805   end;
   806 
   807 (* PROP ?phi == PROP ?psi ==> PROP ?phi ==> PROP ?psi *)
   808 val equal_elim_rule1 =
   809   let val eq = read_prop "PROP phi == PROP psi"
   810       and P = read_prop "PROP phi"
   811   in store_standard_thm_open "equal_elim_rule1"
   812     (Thm.equal_elim (assume eq) (assume P) |> implies_intr_list [eq, P])
   813   end;
   814 
   815 (* PROP ?psi == PROP ?phi ==> PROP ?phi ==> PROP ?psi *)
   816 val equal_elim_rule2 =
   817   store_standard_thm_open "equal_elim_rule2" (symmetric_thm RS equal_elim_rule1);
   818 
   819 (* "[| PROP ?phi; PROP ?phi; PROP ?psi |] ==> PROP ?psi" *)
   820 val remdups_rl =
   821   let val P = read_prop "PROP phi" and Q = read_prop "PROP psi";
   822   in store_standard_thm_open "remdups_rl" (implies_intr_list [P, P, Q] (Thm.assume Q)) end;
   823 
   824 
   825 (*(PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x))
   826   Rewrite rule for HHF normalization.*)
   827 
   828 val norm_hhf_eq =
   829   let
   830     val aT = TFree ("'a", []);
   831     val all = Term.all aT;
   832     val x = Free ("x", aT);
   833     val phi = Free ("phi", propT);
   834     val psi = Free ("psi", aT --> propT);
   835 
   836     val cx = cert x;
   837     val cphi = cert phi;
   838     val lhs = cert (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   839     val rhs = cert (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   840   in
   841     Thm.equal_intr
   842       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   843         |> Thm.forall_elim cx
   844         |> Thm.implies_intr cphi
   845         |> Thm.forall_intr cx
   846         |> Thm.implies_intr lhs)
   847       (Thm.implies_elim
   848           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   849         |> Thm.forall_intr cx
   850         |> Thm.implies_intr cphi
   851         |> Thm.implies_intr rhs)
   852     |> store_standard_thm_open "norm_hhf_eq"
   853   end;
   854 
   855 val norm_hhf_prop = Logic.dest_equals (Thm.prop_of norm_hhf_eq);
   856 
   857 fun is_norm_hhf tm =
   858   let
   859     fun is_norm (Const ("==>", _) $ _ $ (Const ("all", _) $ _)) = false
   860       | is_norm (t $ u) = is_norm t andalso is_norm u
   861       | is_norm (Abs (_, _, t)) = is_norm t
   862       | is_norm _ = true;
   863   in is_norm (Envir.beta_eta_contract tm) end;
   864 
   865 fun norm_hhf thy t =
   866   if is_norm_hhf t then t
   867   else Pattern.rewrite_term thy [norm_hhf_prop] [] t;
   868 
   869 
   870 
   871 (*** Instantiate theorem th, reading instantiations in theory thy ****)
   872 
   873 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   874 fun instantiate instpair th = Thm.instantiate instpair th  COMP   asm_rl;
   875 
   876 fun read_instantiate_sg' thy sinsts th =
   877     let val ts = types_sorts th;
   878         val used = add_used th [];
   879     in  instantiate (read_insts thy ts ts used sinsts) th  end;
   880 
   881 fun read_instantiate_sg thy sinsts th =
   882   read_instantiate_sg' thy (map (apfst Syntax.indexname) sinsts) th;
   883 
   884 (*Instantiate theorem th, reading instantiations under theory of th*)
   885 fun read_instantiate sinsts th =
   886     read_instantiate_sg (Thm.theory_of_thm th) sinsts th;
   887 
   888 fun read_instantiate' sinsts th =
   889     read_instantiate_sg' (Thm.theory_of_thm th) sinsts th;
   890 
   891 
   892 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   893   Instantiates distinct Vars by terms, inferring type instantiations. *)
   894 local
   895   fun add_types ((ct,cu), (thy,tye,maxidx)) =
   896     let val {thy=thyt, t=t, T= T, maxidx=maxt,...} = rep_cterm ct
   897         and {thy=thyu, t=u, T= U, maxidx=maxu,...} = rep_cterm cu;
   898         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   899         val thy' = Theory.merge(thy, Theory.merge(thyt, thyu))
   900         val (tye',maxi') = Sign.typ_unify thy' (T, U) (tye, maxi)
   901           handle Type.TUNIFY => raise TYPE("Ill-typed instantiation", [T,U], [t,u])
   902     in  (thy', tye', maxi')  end;
   903 in
   904 fun cterm_instantiate ctpairs0 th =
   905   let val (thy,tye,_) = foldr add_types (Thm.theory_of_thm th, Vartab.empty, 0) ctpairs0
   906       fun instT(ct,cu) =
   907         let val inst = cterm_of thy o Envir.subst_TVars tye o term_of
   908         in (inst ct, inst cu) end
   909       fun ctyp2 (ixn, (S, T)) = (ctyp_of thy (TVar (ixn, S)), ctyp_of thy T)
   910   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   911   handle TERM _ =>
   912            raise THM("cterm_instantiate: incompatible theories",0,[th])
   913        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   914 end;
   915 
   916 
   917 (** Derived rules mainly for METAHYPS **)
   918 
   919 (*Given the term "a", takes (%x.t)==(%x.u) to t[a/x]==u[a/x]*)
   920 fun equal_abs_elim ca eqth =
   921   let val {thy=thya, t=a, ...} = rep_cterm ca
   922       and combth = combination eqth (reflexive ca)
   923       val {thy,prop,...} = rep_thm eqth
   924       val (abst,absu) = Logic.dest_equals prop
   925       val cert = cterm_of (Theory.merge (thy,thya))
   926   in  transitive (symmetric (beta_conversion false (cert (abst$a))))
   927            (transitive combth (beta_conversion false (cert (absu$a))))
   928   end
   929   handle THM _ => raise THM("equal_abs_elim", 0, [eqth]);
   930 
   931 (*Calling equal_abs_elim with multiple terms*)
   932 fun equal_abs_elim_list cts th = foldr (uncurry equal_abs_elim) th (rev cts);
   933 
   934 
   935 (* global schematic variables *)
   936 
   937 fun unvarify th =
   938   let
   939     val thy = Thm.theory_of_thm th;
   940     val cert = Thm.cterm_of thy;
   941     val certT = Thm.ctyp_of thy;
   942 
   943     val prop = Thm.full_prop_of th;
   944     val _ = map Logic.unvarify (prop :: Thm.hyps_of th)
   945       handle TERM (msg, _) => raise THM (msg, 0, [th]);
   946 
   947     val instT0 = rev (Term.add_tvars prop []) |> map (fn v as ((a, _), S) => (v, TFree (a, S)));
   948     val instT = map (fn (v, T) => (certT (TVar v), certT T)) instT0;
   949     val inst = rev (Term.add_vars prop []) |> map (fn ((a, i), T) =>
   950       let val T' = Term.instantiateT instT0 T
   951       in (cert (Var ((a, i), T')), cert (Free ((a, T')))) end);
   952   in Thm.instantiate (instT, inst) th end;
   953 
   954 
   955 (** protected propositions and embedded terms **)
   956 
   957 local
   958   val A = cert (Free ("A", propT));
   959   val prop_def = unvarify ProtoPure.prop_def;
   960   val term_def = unvarify ProtoPure.term_def;
   961 in
   962   val protect = Thm.capply (cert Logic.protectC);
   963   val protectI = store_thm "protectI" (PureThy.kind_rule PureThy.internalK (standard
   964       (Thm.equal_elim (Thm.symmetric prop_def) (Thm.assume A))));
   965   val protectD = store_thm "protectD" (PureThy.kind_rule PureThy.internalK (standard
   966       (Thm.equal_elim prop_def (Thm.assume (protect A)))));
   967   val protect_cong = store_standard_thm_open "protect_cong" (Thm.reflexive (protect A));
   968 
   969   val termI = store_thm "termI" (PureThy.kind_rule PureThy.internalK (standard
   970       (Thm.equal_elim (Thm.symmetric term_def) (Thm.forall_intr A (Thm.trivial A)))));
   971 end;
   972 
   973 fun implies_intr_protected asms th =
   974   let val asms' = map protect asms in
   975     implies_elim_list
   976       (implies_intr_list asms th)
   977       (map (fn asm' => Thm.assume asm' RS protectD) asms')
   978     |> implies_intr_list asms'
   979   end;
   980 
   981 fun mk_term ct =
   982   let
   983     val {thy, T, ...} = Thm.rep_cterm ct;
   984     val cert = Thm.cterm_of thy;
   985     val certT = Thm.ctyp_of thy;
   986     val a = certT (TVar (("'a", 0), []));
   987     val x = cert (Var (("x", 0), T));
   988   in Thm.instantiate ([(a, certT T)], [(x, ct)]) termI end;
   989 
   990 fun dest_term th =
   991   let val cprop = Thm.cprop_of th in
   992     if can Logic.dest_term (Thm.term_of cprop) then
   993       #2 (Thm.dest_comb cprop)
   994     else raise THM ("dest_term", 0, [th])
   995   end;
   996 
   997 
   998 
   999 (** variations on instantiate **)
  1000 
  1001 (*shorthand for instantiating just one variable in the current theory*)
  1002 fun inst x t = read_instantiate_sg (the_context()) [(x,t)];
  1003 
  1004 
  1005 (* instantiate by left-to-right occurrence of variables *)
  1006 
  1007 fun instantiate' cTs cts thm =
  1008   let
  1009     fun err msg =
  1010       raise TYPE ("instantiate': " ^ msg,
  1011         map_filter (Option.map Thm.typ_of) cTs,
  1012         map_filter (Option.map Thm.term_of) cts);
  1013 
  1014     fun inst_of (v, ct) =
  1015       (Thm.cterm_of (Thm.theory_of_cterm ct) (Var v), ct)
  1016         handle TYPE (msg, _, _) => err msg;
  1017 
  1018     fun tyinst_of (v, cT) =
  1019       (Thm.ctyp_of (Thm.theory_of_ctyp cT) (TVar v), cT)
  1020         handle TYPE (msg, _, _) => err msg;
  1021 
  1022     fun zip_vars _ [] = []
  1023       | zip_vars (_ :: vs) (NONE :: opt_ts) = zip_vars vs opt_ts
  1024       | zip_vars (v :: vs) (SOME t :: opt_ts) = (v, t) :: zip_vars vs opt_ts
  1025       | zip_vars [] _ = err "more instantiations than variables in thm";
  1026 
  1027     (*instantiate types first!*)
  1028     val thm' =
  1029       if forall is_none cTs then thm
  1030       else Thm.instantiate (map tyinst_of (zip_vars (tvars_of thm) cTs), []) thm;
  1031     in
  1032       if forall is_none cts then thm'
  1033       else Thm.instantiate ([], map inst_of (zip_vars (vars_of thm') cts)) thm'
  1034     end;
  1035 
  1036 
  1037 
  1038 (** renaming of bound variables **)
  1039 
  1040 (* replace bound variables x_i in thm by y_i *)
  1041 (* where vs = [(x_1, y_1), ..., (x_n, y_n)]  *)
  1042 
  1043 fun rename_bvars [] thm = thm
  1044   | rename_bvars vs thm =
  1045     let
  1046       val {thy, prop, ...} = rep_thm thm;
  1047       fun ren (Abs (x, T, t)) = Abs (AList.lookup (op =) vs x |> the_default x, T, ren t)
  1048         | ren (t $ u) = ren t $ ren u
  1049         | ren t = t;
  1050     in equal_elim (reflexive (cterm_of thy (ren prop))) thm end;
  1051 
  1052 
  1053 (* renaming in left-to-right order *)
  1054 
  1055 fun rename_bvars' xs thm =
  1056   let
  1057     val {thy, prop, ...} = rep_thm thm;
  1058     fun rename [] t = ([], t)
  1059       | rename (x' :: xs) (Abs (x, T, t)) =
  1060           let val (xs', t') = rename xs t
  1061           in (xs', Abs (the_default x x', T, t')) end
  1062       | rename xs (t $ u) =
  1063           let
  1064             val (xs', t') = rename xs t;
  1065             val (xs'', u') = rename xs' u
  1066           in (xs'', t' $ u') end
  1067       | rename xs t = (xs, t);
  1068   in case rename xs prop of
  1069       ([], prop') => equal_elim (reflexive (cterm_of thy prop')) thm
  1070     | _ => error "More names than abstractions in theorem"
  1071   end;
  1072 
  1073 
  1074 (* var indexes *)
  1075 
  1076 fun incr_indexes th = Thm.incr_indexes (Thm.maxidx_of th + 1);
  1077 
  1078 fun incr_indexes2 th1 th2 =
  1079   Thm.incr_indexes (Int.max (Thm.maxidx_of th1, Thm.maxidx_of th2) + 1);
  1080 
  1081 
  1082 (* freeze_all *)
  1083 
  1084 (*freeze all (T)Vars; assumes thm in standard form*)
  1085 
  1086 fun freeze_all_TVars thm =
  1087   (case tvars_of thm of
  1088     [] => thm
  1089   | tvars =>
  1090       let val cert = Thm.ctyp_of (Thm.theory_of_thm thm)
  1091       in instantiate' (map (fn ((x, _), S) => SOME (cert (TFree (x, S)))) tvars) [] thm end);
  1092 
  1093 fun freeze_all_Vars thm =
  1094   (case vars_of thm of
  1095     [] => thm
  1096   | vars =>
  1097       let val cert = Thm.cterm_of (Thm.theory_of_thm thm)
  1098       in instantiate' [] (map (fn ((x, _), T) => SOME (cert (Free (x, T)))) vars) thm end);
  1099 
  1100 val freeze_all = freeze_all_Vars o freeze_all_TVars;
  1101 
  1102 
  1103 
  1104 (** multi_resolve **)
  1105 
  1106 local
  1107 
  1108 fun res th i rule =
  1109   Thm.biresolution false [(false, th)] i rule handle THM _ => Seq.empty;
  1110 
  1111 fun multi_res _ [] rule = Seq.single rule
  1112   | multi_res i (th :: ths) rule = Seq.maps (res th i) (multi_res (i + 1) ths rule);
  1113 
  1114 in
  1115 
  1116 val multi_resolve = multi_res 1;
  1117 fun multi_resolves facts rules = Seq.maps (multi_resolve facts) (Seq.of_list rules);
  1118 
  1119 end;
  1120 
  1121 end;
  1122 
  1123 structure BasicDrule: BASIC_DRULE = Drule;
  1124 open BasicDrule;