src/Pure/axclass.ML
author wenzelm
Thu Mar 25 21:14:15 2010 +0100 (2010-03-25 ago)
changeset 35960 536c07a2a0bc
parent 35896 487b267433b1
child 35961 00e48e1d9afd
permissions -rw-r--r--
removed unused AxClass.of_sort derivation;
     1 (*  Title:      Pure/axclass.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Type classes defined as predicates, associated with a record of
     5 parameters.
     6 *)
     7 
     8 signature AX_CLASS =
     9 sig
    10   val define_class: binding * class list -> string list ->
    11     (Thm.binding * term list) list -> theory -> class * theory
    12   val add_classrel: thm -> theory -> theory
    13   val add_arity: thm -> theory -> theory
    14   val prove_classrel: class * class -> tactic -> theory -> theory
    15   val prove_arity: string * sort list * sort -> tactic -> theory -> theory
    16   val get_info: theory -> class ->
    17     {def: thm, intro: thm, axioms: thm list, params: (string * typ) list}
    18   val class_intros: theory -> thm list
    19   val class_of_param: theory -> string -> class option
    20   val cert_classrel: theory -> class * class -> class * class
    21   val read_classrel: theory -> xstring * xstring -> class * class
    22   val axiomatize_class: binding * class list -> theory -> theory
    23   val axiomatize_class_cmd: binding * xstring list -> theory -> theory
    24   val axiomatize_classrel: (class * class) list -> theory -> theory
    25   val axiomatize_classrel_cmd: (xstring * xstring) list -> theory -> theory
    26   val axiomatize_arity: arity -> theory -> theory
    27   val axiomatize_arity_cmd: xstring * string list * string -> theory -> theory
    28   val instance_name: string * class -> string
    29   val declare_overloaded: string * typ -> theory -> term * theory
    30   val define_overloaded: binding -> string * term -> theory -> thm * theory
    31   val unoverload: theory -> thm -> thm
    32   val overload: theory -> thm -> thm
    33   val unoverload_conv: theory -> conv
    34   val overload_conv: theory -> conv
    35   val unoverload_const: theory -> string * typ -> string
    36   val lookup_inst_param: Consts.T -> ((string * string) * 'a) list -> string * typ -> 'a option
    37   val param_of_inst: theory -> string * string -> string
    38   val inst_of_param: theory -> string -> (string * string) option
    39   val thynames_of_arity: theory -> class * string -> string list
    40   val introN: string
    41   val axiomsN: string
    42 end;
    43 
    44 structure AxClass: AX_CLASS =
    45 struct
    46 
    47 (** theory data **)
    48 
    49 (* class parameters (canonical order) *)
    50 
    51 type param = string * class;
    52 
    53 fun add_param pp ((x, c): param) params =
    54   (case AList.lookup (op =) params x of
    55     NONE => (x, c) :: params
    56   | SOME c' => error ("Duplicate class parameter " ^ quote x ^
    57       " for " ^ Pretty.string_of_sort pp [c] ^
    58       (if c = c' then "" else " and " ^ Pretty.string_of_sort pp [c'])));
    59 
    60 fun merge_params _ ([], qs) = qs
    61   | merge_params pp (ps, qs) =
    62       fold_rev (fn q => if member (op =) ps q then I else add_param pp q) qs ps;
    63 
    64 
    65 (* axclasses *)
    66 
    67 val introN = "intro";
    68 val superN = "super";
    69 val axiomsN = "axioms";
    70 
    71 datatype axclass = AxClass of
    72  {def: thm,
    73   intro: thm,
    74   axioms: thm list,
    75   params: (string * typ) list};
    76 
    77 type axclasses = axclass Symtab.table * param list;
    78 
    79 fun make_axclass ((def, intro, axioms), params) = AxClass
    80   {def = def, intro = intro, axioms = axioms, params = params};
    81 
    82 fun merge_axclasses pp ((tab1, params1), (tab2, params2)) : axclasses =
    83   (Symtab.merge (K true) (tab1, tab2), merge_params pp (params1, params2));
    84 
    85 
    86 (* instances *)
    87 
    88 val classrel_prefix = "classrel_";
    89 val arity_prefix = "arity_";
    90 
    91 type instances =
    92   ((class * class) * thm) list *  (*classrel theorems*)
    93   ((class * sort list) * (thm * string)) list Symtab.table;  (*arity theorems with theory name*)
    94 
    95 fun merge_instances ((classrel1, arities1): instances, (classrel2, arities2)) =
    96  (merge (eq_fst op =) (classrel1, classrel2),
    97   Symtab.join (K (merge (eq_fst op =))) (arities1, arities2));
    98 
    99 
   100 (* instance parameters *)
   101 
   102 type inst_params =
   103   (string * thm) Symtab.table Symtab.table
   104     (*constant name ~> type constructor ~> (constant name, equation)*)
   105   * (string * string) Symtab.table; (*constant name ~> (constant name, type constructor)*)
   106 
   107 fun merge_inst_params ((const_param1, param_const1), (const_param2, param_const2)) =
   108   (Symtab.join  (K (Symtab.merge (K true))) (const_param1, const_param2),
   109     Symtab.merge (K true) (param_const1, param_const2));
   110 
   111 
   112 (* setup data *)
   113 
   114 structure AxClassData = Theory_Data_PP
   115 (
   116   type T = axclasses * (instances * inst_params);
   117   val empty = ((Symtab.empty, []), (([], Symtab.empty), (Symtab.empty, Symtab.empty)));
   118   val extend = I;
   119   fun merge pp ((axclasses1, (instances1, inst_params1)), (axclasses2, (instances2, inst_params2))) =
   120     (merge_axclasses pp (axclasses1, axclasses2),
   121       (merge_instances (instances1, instances2), merge_inst_params (inst_params1, inst_params2)));
   122 );
   123 
   124 
   125 (* maintain axclasses *)
   126 
   127 val get_axclasses = #1 o AxClassData.get;
   128 val map_axclasses = AxClassData.map o apfst;
   129 
   130 val lookup_def = Symtab.lookup o #1 o get_axclasses;
   131 
   132 fun get_info thy c =
   133   (case lookup_def thy c of
   134     SOME (AxClass info) => info
   135   | NONE => error ("No such axclass: " ^ quote c));
   136 
   137 fun class_intros thy =
   138   let
   139     fun add_intro c =
   140       (case lookup_def thy c of SOME (AxClass {intro, ...}) => cons intro | _ => I);
   141     val classes = Sign.all_classes thy;
   142   in map (Thm.class_triv thy) classes @ fold add_intro classes [] end;
   143 
   144 
   145 fun get_params thy pred =
   146   let val params = #2 (get_axclasses thy);
   147   in fold (fn (x, c) => if pred c then cons x else I) params [] end;
   148 
   149 fun all_params_of thy S = get_params thy (fn c => Sign.subsort thy (S, [c]));
   150 
   151 fun class_of_param thy = AList.lookup (op =) (#2 (get_axclasses thy));
   152 
   153 
   154 (* maintain instances *)
   155 
   156 fun instance_name (a, c) = Long_Name.base_name c ^ "_" ^ Long_Name.base_name a;
   157 
   158 val get_instances = #1 o #2 o AxClassData.get;
   159 val map_instances = AxClassData.map o apsnd o apfst;
   160 
   161 
   162 fun the_classrel thy (c1, c2) =
   163   (case AList.lookup (op =) (#1 (get_instances thy)) (c1, c2) of
   164     SOME th => Thm.transfer thy th
   165   | NONE => error ("Unproven class relation " ^
   166       Syntax.string_of_classrel (ProofContext.init thy) [c1, c2]));
   167 
   168 fun put_classrel arg = map_instances (fn (classrel, arities) =>
   169   (insert (eq_fst op =) arg classrel, arities));
   170 
   171 
   172 fun the_arity thy a (c, Ss) =
   173   (case AList.lookup (op =) (Symtab.lookup_list (#2 (get_instances thy)) a) (c, Ss) of
   174     SOME (th, _) => Thm.transfer thy th
   175   | NONE => error ("Unproven type arity " ^
   176       Syntax.string_of_arity (ProofContext.init thy) (a, Ss, [c])));
   177 
   178 fun thynames_of_arity thy (c, a) =
   179   Symtab.lookup_list (#2 (get_instances thy)) a
   180   |> map_filter (fn ((c', _), (_, name)) => if c = c' then SOME name else NONE)
   181   |> rev;
   182 
   183 fun insert_arity_completions thy (t, ((c, Ss), (th, thy_name))) arities =
   184   let
   185     val algebra = Sign.classes_of thy;
   186     val super_class_completions =
   187       Sign.super_classes thy c
   188       |> filter_out (fn c1 => exists (fn ((c2, Ss2), _) => c1 = c2
   189           andalso Sorts.sorts_le algebra (Ss2, Ss)) (Symtab.lookup_list arities t));
   190     val completions = map (fn c1 => (Sorts.weaken algebra
   191       (fn (th, c2) => fn c3 => th RS the_classrel thy (c2, c3)) (th, c) c1
   192         |> Thm.close_derivation, c1)) super_class_completions;
   193     val arities' = fold (fn (th1, c1) => Symtab.cons_list (t, ((c1, Ss), (th1, thy_name))))
   194       completions arities;
   195   in (null completions, arities') end;
   196 
   197 fun put_arity ((t, Ss, c), th) thy =
   198   let
   199     val arity' = (t, ((c, Ss), (th, Context.theory_name thy)));
   200   in
   201     thy
   202     |> map_instances (fn (classrel, arities) => (classrel,
   203       arities
   204       |> Symtab.insert_list (eq_fst op =) arity'
   205       |> insert_arity_completions thy arity'
   206       |> snd))
   207   end;
   208 
   209 fun complete_arities thy =
   210   let
   211     val arities = snd (get_instances thy);
   212     val (finished, arities') = arities
   213       |> fold_map (insert_arity_completions thy) (Symtab.dest_list arities);
   214   in
   215     if forall I finished then NONE
   216     else SOME (thy |> map_instances (fn (classrel, _) => (classrel, arities')))
   217   end;
   218 
   219 val _ = Context.>> (Context.map_theory (Theory.at_begin complete_arities));
   220 
   221 
   222 (* maintain instance parameters *)
   223 
   224 val get_inst_params = #2 o #2 o AxClassData.get;
   225 val map_inst_params = AxClassData.map o apsnd o apsnd;
   226 
   227 fun get_inst_param thy (c, tyco) =
   228   case Symtab.lookup ((the_default Symtab.empty o Symtab.lookup (fst (get_inst_params thy))) c) tyco
   229    of SOME c' => c'
   230     | NONE => error ("No instance parameter for constant " ^ quote c
   231         ^ " on type constructor " ^ quote tyco);
   232 
   233 fun add_inst_param (c, tyco) inst = (map_inst_params o apfst
   234       o Symtab.map_default (c, Symtab.empty)) (Symtab.update_new (tyco, inst))
   235   #> (map_inst_params o apsnd) (Symtab.update_new (fst inst, (c, tyco)));
   236 
   237 val inst_of_param = Symtab.lookup o snd o get_inst_params;
   238 val param_of_inst = fst oo get_inst_param;
   239 
   240 fun inst_thms thy = (Symtab.fold (Symtab.fold (cons o snd o snd) o snd) o fst)
   241   (get_inst_params thy) [];
   242 
   243 fun get_inst_tyco consts = try (fst o dest_Type o the_single o Consts.typargs consts);
   244 
   245 fun unoverload thy = MetaSimplifier.simplify true (inst_thms thy);
   246 fun overload thy = MetaSimplifier.simplify true (map Thm.symmetric (inst_thms thy));
   247 
   248 fun unoverload_conv thy = MetaSimplifier.rewrite true (inst_thms thy);
   249 fun overload_conv thy = MetaSimplifier.rewrite true (map Thm.symmetric (inst_thms thy));
   250 
   251 fun lookup_inst_param consts params (c, T) = case get_inst_tyco consts (c, T)
   252  of SOME tyco => AList.lookup (op =) params (c, tyco)
   253   | NONE => NONE;
   254 
   255 fun unoverload_const thy (c_ty as (c, _)) =
   256   if is_some (class_of_param thy c)
   257   then case get_inst_tyco (Sign.consts_of thy) c_ty
   258    of SOME tyco => try (param_of_inst thy) (c, tyco) |> the_default c
   259     | NONE => c
   260   else c;
   261 
   262 
   263 (** instances **)
   264 
   265 (* class relations *)
   266 
   267 fun cert_classrel thy raw_rel =
   268   let
   269     val string_of_sort = Syntax.string_of_sort_global thy;
   270     val (c1, c2) = pairself (Sign.certify_class thy) raw_rel;
   271     val _ = Sign.primitive_classrel (c1, c2) (Theory.copy thy);
   272     val _ =
   273       (case subtract (op =) (all_params_of thy [c1]) (all_params_of thy [c2]) of
   274         [] => ()
   275       | xs => raise TYPE ("Class " ^ string_of_sort [c1] ^ " lacks parameter(s) " ^
   276           commas_quote xs ^ " of " ^ string_of_sort [c2], [], []));
   277   in (c1, c2) end;
   278 
   279 fun read_classrel thy raw_rel =
   280   cert_classrel thy (pairself (ProofContext.read_class (ProofContext.init thy)) raw_rel)
   281     handle TYPE (msg, _, _) => error msg;
   282 
   283 
   284 (* declaration and definition of instances of overloaded constants *)
   285 
   286 fun inst_tyco_of thy (c, T) =
   287   (case get_inst_tyco (Sign.consts_of thy) (c, T) of
   288     SOME tyco => tyco
   289   | NONE => error ("Illegal type for instantiation of class parameter: " ^
   290       quote (c ^ " :: " ^ Syntax.string_of_typ_global thy T)));
   291 
   292 fun declare_overloaded (c, T) thy =
   293   let
   294     val class =
   295       (case class_of_param thy c of
   296         SOME class => class
   297       | NONE => error ("Not a class parameter: " ^ quote c));
   298     val tyco = inst_tyco_of thy (c, T);
   299     val name_inst = instance_name (tyco, class) ^ "_inst";
   300     val c' = Long_Name.base_name c ^ "_" ^ Long_Name.base_name tyco;
   301     val T' = Type.strip_sorts T;
   302   in
   303     thy
   304     |> Sign.qualified_path true (Binding.name name_inst)
   305     |> Sign.declare_const ((Binding.name c', T'), NoSyn)
   306     |-> (fn const' as Const (c'', _) =>
   307       Thm.add_def false true
   308         (Binding.name (Thm.def_name c'), Logic.mk_equals (Const (c, T'), const'))
   309       #>> Thm.varifyT_global
   310       #-> (fn thm => add_inst_param (c, tyco) (c'', thm)
   311       #> PureThy.add_thm ((Binding.conceal (Binding.name c'), thm), [])
   312       #> snd
   313       #> pair (Const (c, T))))
   314     ||> Sign.restore_naming thy
   315   end;
   316 
   317 fun define_overloaded b (c, t) thy =
   318   let
   319     val T = Term.fastype_of t;
   320     val tyco = inst_tyco_of thy (c, T);
   321     val (c', eq) = get_inst_param thy (c, tyco);
   322     val prop = Logic.mk_equals (Const (c', T), t);
   323     val b' = Thm.def_binding_optional
   324       (Binding.name (Long_Name.base_name c ^ "_" ^ Long_Name.base_name tyco)) b;
   325   in
   326     thy
   327     |> Thm.add_def false false (b', prop)
   328     |>> (fn thm =>  Drule.transitive_thm OF [eq, thm])
   329   end;
   330 
   331 
   332 (* primitive rules *)
   333 
   334 fun add_classrel raw_th thy =
   335   let
   336     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   337     val prop = Thm.plain_prop_of th;
   338     fun err () = raise THM ("add_classrel: malformed class relation", 0, [th]);
   339     val rel = Logic.dest_classrel prop handle TERM _ => err ();
   340     val (c1, c2) = cert_classrel thy rel handle TYPE _ => err ();
   341   in
   342     thy
   343     |> Sign.primitive_classrel (c1, c2)
   344     |> put_classrel ((c1, c2), Thm.close_derivation (Drule.unconstrainTs th))
   345     |> perhaps complete_arities
   346   end;
   347 
   348 fun add_arity raw_th thy =
   349   let
   350     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   351     val prop = Thm.plain_prop_of th;
   352     fun err () = raise THM ("add_arity: malformed type arity", 0, [th]);
   353     val (t, Ss, c) = Logic.dest_arity prop handle TERM _ => err ();
   354     val T = Type (t, map TFree (Name.names Name.context Name.aT Ss));
   355     val missing_params = Sign.complete_sort thy [c]
   356       |> maps (these o Option.map #params o try (get_info thy))
   357       |> filter_out (fn (const, _) => can (get_inst_param thy) (const, t))
   358       |> (map o apsnd o map_atyps) (K T);
   359     val _ = map (Sign.certify_sort thy) Ss = Ss orelse err ();
   360   in
   361     thy
   362     |> fold (snd oo declare_overloaded) missing_params
   363     |> Sign.primitive_arity (t, Ss, [c])
   364     |> put_arity ((t, Ss, c), Thm.close_derivation (Drule.unconstrainTs th))
   365   end;
   366 
   367 
   368 (* tactical proofs *)
   369 
   370 fun prove_classrel raw_rel tac thy =
   371   let
   372     val ctxt = ProofContext.init thy;
   373     val (c1, c2) = cert_classrel thy raw_rel;
   374     val th = Goal.prove ctxt [] [] (Logic.mk_classrel (c1, c2)) (K tac) handle ERROR msg =>
   375       cat_error msg ("The error(s) above occurred while trying to prove class relation " ^
   376         quote (Syntax.string_of_classrel ctxt [c1, c2]));
   377   in
   378     thy
   379     |> PureThy.add_thms [((Binding.name
   380         (prefix classrel_prefix (Logic.name_classrel (c1, c2))), th), [])]
   381     |-> (fn [th'] => add_classrel th')
   382   end;
   383 
   384 fun prove_arity raw_arity tac thy =
   385   let
   386     val ctxt = ProofContext.init thy;
   387     val arity = ProofContext.cert_arity ctxt raw_arity;
   388     val names = map (prefix arity_prefix) (Logic.name_arities arity);
   389     val props = Logic.mk_arities arity;
   390     val ths = Goal.prove_multi ctxt [] [] props
   391       (fn _ => Goal.precise_conjunction_tac (length props) 1 THEN tac) handle ERROR msg =>
   392         cat_error msg ("The error(s) above occurred while trying to prove type arity " ^
   393           quote (Syntax.string_of_arity ctxt arity));
   394   in
   395     thy
   396     |> PureThy.add_thms (map (rpair []) (map Binding.name names ~~ ths))
   397     |-> fold add_arity
   398   end;
   399 
   400 
   401 
   402 (** class definitions **)
   403 
   404 fun split_defined n eq =
   405   let
   406     val intro =
   407       (eq RS Drule.equal_elim_rule2)
   408       |> Conjunction.curry_balanced n
   409       |> n = 0 ? Thm.eq_assumption 1;
   410     val dests =
   411       if n = 0 then []
   412       else
   413         (eq RS Drule.equal_elim_rule1)
   414         |> Balanced_Tree.dest (fn th =>
   415           (th RS Conjunction.conjunctionD1, th RS Conjunction.conjunctionD2)) n;
   416   in (intro, dests) end;
   417 
   418 fun define_class (bclass, raw_super) raw_params raw_specs thy =
   419   let
   420     val ctxt = ProofContext.init thy;
   421     val pp = Syntax.pp ctxt;
   422 
   423 
   424     (* class *)
   425 
   426     val bconst = Binding.map_name Logic.const_of_class bclass;
   427     val class = Sign.full_name thy bclass;
   428     val super = Sign.minimize_sort thy (Sign.certify_sort thy raw_super);
   429 
   430     fun check_constraint (a, S) =
   431       if Sign.subsort thy (super, S) then ()
   432       else error ("Sort constraint of type variable " ^
   433         setmp_CRITICAL show_sorts true (Pretty.string_of_typ pp) (TFree (a, S)) ^
   434         " needs to be weaker than " ^ Pretty.string_of_sort pp super);
   435 
   436 
   437     (* params *)
   438 
   439     val params = raw_params |> map (fn p =>
   440       let
   441         val T = Sign.the_const_type thy p;
   442         val _ =
   443           (case Term.add_tvarsT T [] of
   444             [((a, _), S)] => check_constraint (a, S)
   445           | _ => error ("Exactly one type variable expected in class parameter " ^ quote p));
   446         val T' = Term.map_type_tvar (fn _ => TFree (Name.aT, [class])) T;
   447       in (p, T') end);
   448 
   449 
   450     (* axioms *)
   451 
   452     fun prep_axiom t =
   453       (case Term.add_tfrees t [] of
   454         [(a, S)] => check_constraint (a, S)
   455       | [] => ()
   456       | _ => error ("Multiple type variables in class axiom:\n" ^ Pretty.string_of_term pp t);
   457       t
   458       |> Term.map_types (Term.map_atyps (fn TFree _ => Term.aT [] | U => U))
   459       |> Logic.close_form);
   460 
   461     val axiomss = map (map (prep_axiom o Sign.cert_prop thy) o snd) raw_specs;
   462     val name_atts = map fst raw_specs;
   463 
   464 
   465     (* definition *)
   466 
   467     val conjs = Logic.mk_of_sort (Term.aT [], super) @ flat axiomss;
   468     val class_eq =
   469       Logic.mk_equals (Logic.mk_of_class (Term.aT [], class), Logic.mk_conjunction_balanced conjs);
   470 
   471     val ([def], def_thy) =
   472       thy
   473       |> Sign.primitive_class (bclass, super)
   474       |> PureThy.add_defs false [((Thm.def_binding bconst, class_eq), [])];
   475     val (raw_intro, (raw_classrel, raw_axioms)) =
   476       split_defined (length conjs) def ||> chop (length super);
   477 
   478 
   479     (* facts *)
   480 
   481     val class_triv = Thm.class_triv def_thy class;
   482     val ([(_, [intro]), (_, classrel), (_, axioms)], facts_thy) =
   483       def_thy
   484       |> Sign.qualified_path true bconst
   485       |> PureThy.note_thmss ""
   486         [((Binding.name introN, []), [([Drule.export_without_context raw_intro], [])]),
   487          ((Binding.name superN, []), [(map Drule.export_without_context raw_classrel, [])]),
   488          ((Binding.name axiomsN, []),
   489            [(map (fn th => Drule.export_without_context (class_triv RS th)) raw_axioms, [])])]
   490       ||> Sign.restore_naming def_thy;
   491 
   492 
   493     (* result *)
   494 
   495     val axclass = make_axclass ((def, intro, axioms), params);
   496     val result_thy =
   497       facts_thy
   498       |> fold put_classrel (map (pair class) super ~~ classrel)
   499       |> Sign.qualified_path false bconst
   500       |> PureThy.note_thmss "" (name_atts ~~ map Thm.simple_fact (unflat axiomss axioms)) |> snd
   501       |> Sign.restore_naming facts_thy
   502       |> map_axclasses (fn (axclasses, parameters) =>
   503         (Symtab.update (class, axclass) axclasses,
   504           fold (fn (x, _) => add_param pp (x, class)) params parameters));
   505 
   506   in (class, result_thy) end;
   507 
   508 
   509 
   510 (** axiomatizations **)
   511 
   512 local
   513 
   514 (* old-style axioms *)
   515 
   516 fun add_axiom (b, prop) =
   517   Thm.add_axiom (b, prop) #->
   518   (fn thm => PureThy.add_thm ((b, Drule.export_without_context thm), []));
   519 
   520 fun axiomatize prep mk name add raw_args thy =
   521   let
   522     val args = prep thy raw_args;
   523     val specs = mk args;
   524     val names = name args;
   525   in
   526     thy
   527     |> fold_map add_axiom (map Binding.name names ~~ specs)
   528     |-> fold add
   529   end;
   530 
   531 fun ax_classrel prep =
   532   axiomatize (map o prep) (map Logic.mk_classrel)
   533     (map (prefix classrel_prefix o Logic.name_classrel)) add_classrel;
   534 
   535 fun ax_arity prep =
   536   axiomatize (prep o ProofContext.init) Logic.mk_arities
   537     (map (prefix arity_prefix) o Logic.name_arities) add_arity;
   538 
   539 fun class_const c =
   540   (Logic.const_of_class c, Term.itselfT (Term.aT []) --> propT);
   541 
   542 fun ax_class prep_class prep_classrel (bclass, raw_super) thy =
   543   let
   544     val class = Sign.full_name thy bclass;
   545     val super = map (prep_class thy) raw_super |> Sign.minimize_sort thy;
   546   in
   547     thy
   548     |> Sign.primitive_class (bclass, super)
   549     |> ax_classrel prep_classrel (map (fn c => (class, c)) super)
   550     |> Theory.add_deps "" (class_const class) (map class_const super)
   551   end;
   552 
   553 in
   554 
   555 val axiomatize_class = ax_class Sign.certify_class cert_classrel;
   556 val axiomatize_class_cmd = ax_class (ProofContext.read_class o ProofContext.init) read_classrel;
   557 val axiomatize_classrel = ax_classrel cert_classrel;
   558 val axiomatize_classrel_cmd = ax_classrel read_classrel;
   559 val axiomatize_arity = ax_arity ProofContext.cert_arity;
   560 val axiomatize_arity_cmd = ax_arity ProofContext.read_arity;
   561 
   562 end;
   563 
   564 end;