src/HOL/Tools/inductive.ML
author haftmann
Wed May 05 18:25:34 2010 +0200 (2010-05-05 ago)
changeset 36692 54b64d4ad524
parent 36642 084470c3cea2
child 36954 ef698bd61057
permissions -rw-r--r--
farewell to old-style mem infixes -- type inference in situations with mem_int and mem_string should provide enough information to resolve the type of (op =)
     1 (*  Title:      HOL/Tools/inductive.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Stefan Berghofer and Markus Wenzel, TU Muenchen
     4 
     5 (Co)Inductive Definition module for HOL.
     6 
     7 Features:
     8   * least or greatest fixedpoints
     9   * mutually recursive definitions
    10   * definitions involving arbitrary monotone operators
    11   * automatically proves introduction and elimination rules
    12 
    13   Introduction rules have the form
    14   [| M Pj ti, ..., Q x, ... |] ==> Pk t
    15   where M is some monotone operator (usually the identity)
    16   Q x is any side condition on the free variables
    17   ti, t are any terms
    18   Pj, Pk are two of the predicates being defined in mutual recursion
    19 *)
    20 
    21 signature BASIC_INDUCTIVE =
    22 sig
    23   type inductive_result =
    24     {preds: term list, elims: thm list, raw_induct: thm,
    25      induct: thm, inducts: thm list, intrs: thm list}
    26   val morph_result: morphism -> inductive_result -> inductive_result
    27   type inductive_info = {names: string list, coind: bool} * inductive_result
    28   val the_inductive: Proof.context -> string -> inductive_info
    29   val print_inductives: Proof.context -> unit
    30   val mono_add: attribute
    31   val mono_del: attribute
    32   val get_monos: Proof.context -> thm list
    33   val mk_cases: Proof.context -> term -> thm
    34   val inductive_forall_name: string
    35   val inductive_forall_def: thm
    36   val rulify: thm -> thm
    37   val inductive_cases: (Attrib.binding * string list) list -> local_theory ->
    38     thm list list * local_theory
    39   val inductive_cases_i: (Attrib.binding * term list) list -> local_theory ->
    40     thm list list * local_theory
    41   type inductive_flags =
    42     {quiet_mode: bool, verbose: bool, alt_name: binding, coind: bool,
    43       no_elim: bool, no_ind: bool, skip_mono: bool, fork_mono: bool}
    44   val add_inductive_i:
    45     inductive_flags -> ((binding * typ) * mixfix) list ->
    46     (string * typ) list -> (Attrib.binding * term) list -> thm list -> local_theory ->
    47     inductive_result * local_theory
    48   val add_inductive: bool -> bool ->
    49     (binding * string option * mixfix) list ->
    50     (binding * string option * mixfix) list ->
    51     (Attrib.binding * string) list ->
    52     (Facts.ref * Attrib.src list) list ->
    53     bool -> local_theory -> inductive_result * local_theory
    54   val add_inductive_global: inductive_flags ->
    55     ((binding * typ) * mixfix) list -> (string * typ) list -> (Attrib.binding * term) list ->
    56     thm list -> theory -> inductive_result * theory
    57   val arities_of: thm -> (string * int) list
    58   val params_of: thm -> term list
    59   val partition_rules: thm -> thm list -> (string * thm list) list
    60   val partition_rules': thm -> (thm * 'a) list -> (string * (thm * 'a) list) list
    61   val unpartition_rules: thm list -> (string * 'a list) list -> 'a list
    62   val infer_intro_vars: thm -> int -> thm list -> term list list
    63   val setup: theory -> theory
    64 end;
    65 
    66 signature INDUCTIVE =
    67 sig
    68   include BASIC_INDUCTIVE
    69   type add_ind_def =
    70     inductive_flags ->
    71     term list -> (Attrib.binding * term) list -> thm list ->
    72     term list -> (binding * mixfix) list ->
    73     local_theory -> inductive_result * local_theory
    74   val declare_rules: binding -> bool -> bool -> string list -> term list ->
    75     thm list -> binding list -> Attrib.src list list -> (thm * string list * int) list ->
    76     thm -> local_theory -> thm list * thm list * thm * thm list * local_theory
    77   val add_ind_def: add_ind_def
    78   val gen_add_inductive_i: add_ind_def -> inductive_flags ->
    79     ((binding * typ) * mixfix) list -> (string * typ) list -> (Attrib.binding * term) list ->
    80     thm list -> local_theory -> inductive_result * local_theory
    81   val gen_add_inductive: add_ind_def -> bool -> bool ->
    82     (binding * string option * mixfix) list ->
    83     (binding * string option * mixfix) list ->
    84     (Attrib.binding * string) list -> (Facts.ref * Attrib.src list) list ->
    85     bool -> local_theory -> inductive_result * local_theory
    86   val gen_ind_decl: add_ind_def -> bool ->
    87     OuterParse.token list -> (bool -> local_theory -> local_theory) * OuterParse.token list
    88 end;
    89 
    90 structure Inductive: INDUCTIVE =
    91 struct
    92 
    93 
    94 (** theory context references **)
    95 
    96 val inductive_forall_name = "HOL.induct_forall";
    97 val inductive_forall_def = @{thm induct_forall_def};
    98 val inductive_conj_name = "HOL.induct_conj";
    99 val inductive_conj_def = @{thm induct_conj_def};
   100 val inductive_conj = @{thms induct_conj};
   101 val inductive_atomize = @{thms induct_atomize};
   102 val inductive_rulify = @{thms induct_rulify};
   103 val inductive_rulify_fallback = @{thms induct_rulify_fallback};
   104 
   105 val notTrueE = TrueI RSN (2, notE);
   106 val notFalseI = Seq.hd (atac 1 notI);
   107 
   108 val simp_thms' = map mk_meta_eq
   109   @{lemma "(~True) = False" "(~False) = True"
   110       "(True --> P) = P" "(False --> P) = True"
   111       "(P & True) = P" "(True & P) = P"
   112     by (fact simp_thms)+};
   113 
   114 val simp_thms'' = map mk_meta_eq [@{thm inf_fun_eq}, @{thm inf_bool_eq}] @ simp_thms';
   115 
   116 val simp_thms''' = map mk_meta_eq
   117   [@{thm le_fun_def}, @{thm le_bool_def}, @{thm sup_fun_eq}, @{thm sup_bool_eq}];
   118 
   119 
   120 (** context data **)
   121 
   122 type inductive_result =
   123   {preds: term list, elims: thm list, raw_induct: thm,
   124    induct: thm, inducts: thm list, intrs: thm list};
   125 
   126 fun morph_result phi {preds, elims, raw_induct: thm, induct, inducts, intrs} =
   127   let
   128     val term = Morphism.term phi;
   129     val thm = Morphism.thm phi;
   130     val fact = Morphism.fact phi;
   131   in
   132    {preds = map term preds, elims = fact elims, raw_induct = thm raw_induct,
   133     induct = thm induct, inducts = fact inducts, intrs = fact intrs}
   134   end;
   135 
   136 type inductive_info =
   137   {names: string list, coind: bool} * inductive_result;
   138 
   139 structure InductiveData = Generic_Data
   140 (
   141   type T = inductive_info Symtab.table * thm list;
   142   val empty = (Symtab.empty, []);
   143   val extend = I;
   144   fun merge ((tab1, monos1), (tab2, monos2)) : T =
   145     (Symtab.merge (K true) (tab1, tab2), Thm.merge_thms (monos1, monos2));
   146 );
   147 
   148 val get_inductives = InductiveData.get o Context.Proof;
   149 
   150 fun print_inductives ctxt =
   151   let
   152     val (tab, monos) = get_inductives ctxt;
   153     val space = Consts.space_of (ProofContext.consts_of ctxt);
   154   in
   155     [Pretty.strs ("(co)inductives:" :: map #1 (Name_Space.extern_table (space, tab))),
   156      Pretty.big_list "monotonicity rules:" (map (Display.pretty_thm ctxt) monos)]
   157     |> Pretty.chunks |> Pretty.writeln
   158   end;
   159 
   160 
   161 (* get and put data *)
   162 
   163 fun the_inductive ctxt name =
   164   (case Symtab.lookup (#1 (get_inductives ctxt)) name of
   165     NONE => error ("Unknown (co)inductive predicate " ^ quote name)
   166   | SOME info => info);
   167 
   168 fun put_inductives names info = InductiveData.map
   169   (apfst (fold (fn name => Symtab.update (name, info)) names));
   170 
   171 
   172 
   173 (** monotonicity rules **)
   174 
   175 val get_monos = #2 o get_inductives;
   176 val map_monos = InductiveData.map o apsnd;
   177 
   178 fun mk_mono thm =
   179   let
   180     fun eq2mono thm' = thm' RS (thm' RS eq_to_mono);
   181     fun dest_less_concl thm = dest_less_concl (thm RS @{thm le_funD})
   182       handle THM _ => thm RS @{thm le_boolD}
   183   in
   184     case concl_of thm of
   185       Const ("==", _) $ _ $ _ => eq2mono (thm RS meta_eq_to_obj_eq)
   186     | _ $ (Const (@{const_name "op ="}, _) $ _ $ _) => eq2mono thm
   187     | _ $ (Const (@{const_name Orderings.less_eq}, _) $ _ $ _) =>
   188       dest_less_concl (Seq.hd (REPEAT (FIRSTGOAL
   189         (resolve_tac [@{thm le_funI}, @{thm le_boolI'}])) thm))
   190     | _ => thm
   191   end handle THM _ =>
   192     error ("Bad monotonicity theorem:\n" ^ Display.string_of_thm_without_context thm);
   193 
   194 val mono_add = Thm.declaration_attribute (map_monos o Thm.add_thm o mk_mono);
   195 val mono_del = Thm.declaration_attribute (map_monos o Thm.del_thm o mk_mono);
   196 
   197 
   198 
   199 (** misc utilities **)
   200 
   201 fun message quiet_mode s = if quiet_mode then () else writeln s;
   202 fun clean_message quiet_mode s = if ! quick_and_dirty then () else message quiet_mode s;
   203 
   204 fun coind_prefix true = "co"
   205   | coind_prefix false = "";
   206 
   207 fun log (b:int) m n = if m >= n then 0 else 1 + log b (b * m) n;
   208 
   209 fun make_bool_args f g [] i = []
   210   | make_bool_args f g (x :: xs) i =
   211       (if i mod 2 = 0 then f x else g x) :: make_bool_args f g xs (i div 2);
   212 
   213 fun make_bool_args' xs =
   214   make_bool_args (K HOLogic.false_const) (K HOLogic.true_const) xs;
   215 
   216 fun arg_types_of k c = drop k (binder_types (fastype_of c));
   217 
   218 fun find_arg T x [] = sys_error "find_arg"
   219   | find_arg T x ((p as (_, (SOME _, _))) :: ps) =
   220       apsnd (cons p) (find_arg T x ps)
   221   | find_arg T x ((p as (U, (NONE, y))) :: ps) =
   222       if (T: typ) = U then (y, (U, (SOME x, y)) :: ps)
   223       else apsnd (cons p) (find_arg T x ps);
   224 
   225 fun make_args Ts xs =
   226   map (fn (T, (NONE, ())) => Const (@{const_name undefined}, T) | (_, (SOME t, ())) => t)
   227     (fold (fn (t, T) => snd o find_arg T t) xs (map (rpair (NONE, ())) Ts));
   228 
   229 fun make_args' Ts xs Us =
   230   fst (fold_map (fn T => find_arg T ()) Us (Ts ~~ map (pair NONE) xs));
   231 
   232 fun dest_predicate cs params t =
   233   let
   234     val k = length params;
   235     val (c, ts) = strip_comb t;
   236     val (xs, ys) = chop k ts;
   237     val i = find_index (fn c' => c' = c) cs;
   238   in
   239     if xs = params andalso i >= 0 then
   240       SOME (c, i, ys, chop (length ys) (arg_types_of k c))
   241     else NONE
   242   end;
   243 
   244 fun mk_names a 0 = []
   245   | mk_names a 1 = [a]
   246   | mk_names a n = map (fn i => a ^ string_of_int i) (1 upto n);
   247 
   248 
   249 
   250 (** process rules **)
   251 
   252 local
   253 
   254 fun err_in_rule ctxt name t msg =
   255   error (cat_lines ["Ill-formed introduction rule " ^ quote name,
   256     Syntax.string_of_term ctxt t, msg]);
   257 
   258 fun err_in_prem ctxt name t p msg =
   259   error (cat_lines ["Ill-formed premise", Syntax.string_of_term ctxt p,
   260     "in introduction rule " ^ quote name, Syntax.string_of_term ctxt t, msg]);
   261 
   262 val bad_concl = "Conclusion of introduction rule must be an inductive predicate";
   263 
   264 val bad_ind_occ = "Inductive predicate occurs in argument of inductive predicate";
   265 
   266 val bad_app = "Inductive predicate must be applied to parameter(s) ";
   267 
   268 fun atomize_term thy = MetaSimplifier.rewrite_term thy inductive_atomize [];
   269 
   270 in
   271 
   272 fun check_rule ctxt cs params ((binding, att), rule) =
   273   let
   274     val err_name = Binding.str_of binding;
   275     val params' = Term.variant_frees rule (Logic.strip_params rule);
   276     val frees = rev (map Free params');
   277     val concl = subst_bounds (frees, Logic.strip_assums_concl rule);
   278     val prems = map (curry subst_bounds frees) (Logic.strip_assums_hyp rule);
   279     val rule' = Logic.list_implies (prems, concl);
   280     val aprems = map (atomize_term (ProofContext.theory_of ctxt)) prems;
   281     val arule = list_all_free (params', Logic.list_implies (aprems, concl));
   282 
   283     fun check_ind err t = case dest_predicate cs params t of
   284         NONE => err (bad_app ^
   285           commas (map (Syntax.string_of_term ctxt) params))
   286       | SOME (_, _, ys, _) =>
   287           if exists (fn c => exists (fn t => Logic.occs (c, t)) ys) cs
   288           then err bad_ind_occ else ();
   289 
   290     fun check_prem' prem t =
   291       if member (op =) cs (head_of t) then
   292         check_ind (err_in_prem ctxt err_name rule prem) t
   293       else (case t of
   294           Abs (_, _, t) => check_prem' prem t
   295         | t $ u => (check_prem' prem t; check_prem' prem u)
   296         | _ => ());
   297 
   298     fun check_prem (prem, aprem) =
   299       if can HOLogic.dest_Trueprop aprem then check_prem' prem prem
   300       else err_in_prem ctxt err_name rule prem "Non-atomic premise";
   301   in
   302     (case concl of
   303        Const (@{const_name Trueprop}, _) $ t =>
   304          if member (op =) cs (head_of t) then
   305            (check_ind (err_in_rule ctxt err_name rule') t;
   306             List.app check_prem (prems ~~ aprems))
   307          else err_in_rule ctxt err_name rule' bad_concl
   308      | _ => err_in_rule ctxt err_name rule' bad_concl);
   309     ((binding, att), arule)
   310   end;
   311 
   312 val rulify =
   313   hol_simplify inductive_conj
   314   #> hol_simplify inductive_rulify
   315   #> hol_simplify inductive_rulify_fallback
   316   #> Simplifier.norm_hhf;
   317 
   318 end;
   319 
   320 
   321 
   322 (** proofs for (co)inductive predicates **)
   323 
   324 (* prove monotonicity *)
   325 
   326 fun prove_mono quiet_mode skip_mono fork_mono predT fp_fun monos ctxt =
   327  (message (quiet_mode orelse skip_mono andalso !quick_and_dirty orelse fork_mono)
   328     "  Proving monotonicity ...";
   329   (if skip_mono then Skip_Proof.prove else if fork_mono then Goal.prove_future else Goal.prove) ctxt
   330     [] []
   331     (HOLogic.mk_Trueprop
   332       (Const (@{const_name Orderings.mono}, (predT --> predT) --> HOLogic.boolT) $ fp_fun))
   333     (fn _ => EVERY [rtac @{thm monoI} 1,
   334       REPEAT (resolve_tac [@{thm le_funI}, @{thm le_boolI'}] 1),
   335       REPEAT (FIRST
   336         [atac 1,
   337          resolve_tac (map mk_mono monos @ get_monos ctxt) 1,
   338          etac @{thm le_funE} 1, dtac @{thm le_boolD} 1])]));
   339 
   340 
   341 (* prove introduction rules *)
   342 
   343 fun prove_intrs quiet_mode coind mono fp_def k intr_ts rec_preds_defs ctxt ctxt' =
   344   let
   345     val _ = clean_message quiet_mode "  Proving the introduction rules ...";
   346 
   347     val unfold = funpow k (fn th => th RS fun_cong)
   348       (mono RS (fp_def RS
   349         (if coind then @{thm def_gfp_unfold} else @{thm def_lfp_unfold})));
   350 
   351     fun select_disj 1 1 = []
   352       | select_disj _ 1 = [rtac disjI1]
   353       | select_disj n i = (rtac disjI2)::(select_disj (n - 1) (i - 1));
   354 
   355     val rules = [refl, TrueI, notFalseI, exI, conjI];
   356 
   357     val intrs = map_index (fn (i, intr) =>
   358       Skip_Proof.prove ctxt [] [] intr (fn _ => EVERY
   359        [rewrite_goals_tac rec_preds_defs,
   360         rtac (unfold RS iffD2) 1,
   361         EVERY1 (select_disj (length intr_ts) (i + 1)),
   362         (*Not ares_tac, since refl must be tried before any equality assumptions;
   363           backtracking may occur if the premises have extra variables!*)
   364         DEPTH_SOLVE_1 (resolve_tac rules 1 APPEND assume_tac 1)])
   365        |> rulify
   366        |> singleton (ProofContext.export ctxt ctxt')) intr_ts
   367 
   368   in (intrs, unfold) end;
   369 
   370 
   371 (* prove elimination rules *)
   372 
   373 fun prove_elims quiet_mode cs params intr_ts intr_names unfold rec_preds_defs ctxt ctxt''' =
   374   let
   375     val _ = clean_message quiet_mode "  Proving the elimination rules ...";
   376 
   377     val ([pname], ctxt') = Variable.variant_fixes ["P"] ctxt;
   378     val P = HOLogic.mk_Trueprop (Free (pname, HOLogic.boolT));
   379 
   380     fun dest_intr r =
   381       (the (dest_predicate cs params (HOLogic.dest_Trueprop (Logic.strip_assums_concl r))),
   382        Logic.strip_assums_hyp r, Logic.strip_params r);
   383 
   384     val intrs = map dest_intr intr_ts ~~ intr_names;
   385 
   386     val rules1 = [disjE, exE, FalseE];
   387     val rules2 = [conjE, FalseE, notTrueE];
   388 
   389     fun prove_elim c =
   390       let
   391         val Ts = arg_types_of (length params) c;
   392         val (anames, ctxt'') = Variable.variant_fixes (mk_names "a" (length Ts)) ctxt';
   393         val frees = map Free (anames ~~ Ts);
   394 
   395         fun mk_elim_prem ((_, _, us, _), ts, params') =
   396           list_all (params',
   397             Logic.list_implies (map (HOLogic.mk_Trueprop o HOLogic.mk_eq)
   398               (frees ~~ us) @ ts, P));
   399         val c_intrs = filter (equal c o #1 o #1 o #1) intrs;
   400         val prems = HOLogic.mk_Trueprop (list_comb (c, params @ frees)) ::
   401            map mk_elim_prem (map #1 c_intrs)
   402       in
   403         (Skip_Proof.prove ctxt'' [] prems P
   404           (fn {prems, ...} => EVERY
   405             [cut_facts_tac [hd prems] 1,
   406              rewrite_goals_tac rec_preds_defs,
   407              dtac (unfold RS iffD1) 1,
   408              REPEAT (FIRSTGOAL (eresolve_tac rules1)),
   409              REPEAT (FIRSTGOAL (eresolve_tac rules2)),
   410              EVERY (map (fn prem =>
   411                DEPTH_SOLVE_1 (ares_tac [rewrite_rule rec_preds_defs prem, conjI] 1)) (tl prems))])
   412           |> rulify
   413           |> singleton (ProofContext.export ctxt'' ctxt'''),
   414          map #2 c_intrs, length Ts)
   415       end
   416 
   417    in map prove_elim cs end;
   418 
   419 
   420 (* derivation of simplified elimination rules *)
   421 
   422 local
   423 
   424 (*delete needless equality assumptions*)
   425 val refl_thin = Goal.prove_global @{theory HOL} [] [] @{prop "!!P. a = a ==> P ==> P"}
   426   (fn _ => assume_tac 1);
   427 val elim_rls = [asm_rl, FalseE, refl_thin, conjE, exE];
   428 val elim_tac = REPEAT o Tactic.eresolve_tac elim_rls;
   429 
   430 fun simp_case_tac ss i =
   431   EVERY' [elim_tac, asm_full_simp_tac ss, elim_tac, REPEAT o bound_hyp_subst_tac] i;
   432 
   433 in
   434 
   435 fun mk_cases ctxt prop =
   436   let
   437     val thy = ProofContext.theory_of ctxt;
   438     val ss = simpset_of ctxt;
   439 
   440     fun err msg =
   441       error (Pretty.string_of (Pretty.block
   442         [Pretty.str msg, Pretty.fbrk, Syntax.pretty_term ctxt prop]));
   443 
   444     val elims = Induct.find_casesP ctxt prop;
   445 
   446     val cprop = Thm.cterm_of thy prop;
   447     val tac = ALLGOALS (simp_case_tac ss) THEN prune_params_tac;
   448     fun mk_elim rl =
   449       Thm.implies_intr cprop (Tactic.rule_by_tactic ctxt tac (Thm.assume cprop RS rl))
   450       |> singleton (Variable.export (Variable.auto_fixes prop ctxt) ctxt);
   451   in
   452     (case get_first (try mk_elim) elims of
   453       SOME r => r
   454     | NONE => err "Proposition not an inductive predicate:")
   455   end;
   456 
   457 end;
   458 
   459 
   460 (* inductive_cases *)
   461 
   462 fun gen_inductive_cases prep_att prep_prop args lthy =
   463   let
   464     val thy = ProofContext.theory_of lthy;
   465     val facts = args |> map (fn ((a, atts), props) =>
   466       ((a, map (prep_att thy) atts),
   467         map (Thm.no_attributes o single o mk_cases lthy o prep_prop lthy) props));
   468   in lthy |> Local_Theory.notes facts |>> map snd end;
   469 
   470 val inductive_cases = gen_inductive_cases Attrib.intern_src Syntax.read_prop;
   471 val inductive_cases_i = gen_inductive_cases (K I) Syntax.check_prop;
   472 
   473 
   474 val ind_cases_setup =
   475   Method.setup @{binding ind_cases}
   476     (Scan.lift (Scan.repeat1 Args.name_source --
   477       Scan.optional (Args.$$$ "for" |-- Scan.repeat1 Args.name) []) >>
   478       (fn (raw_props, fixes) => fn ctxt =>
   479         let
   480           val (_, ctxt') = Variable.add_fixes fixes ctxt;
   481           val props = Syntax.read_props ctxt' raw_props;
   482           val ctxt'' = fold Variable.declare_term props ctxt';
   483           val rules = ProofContext.export ctxt'' ctxt (map (mk_cases ctxt'') props)
   484         in Method.erule 0 rules end))
   485     "dynamic case analysis on predicates";
   486 
   487 
   488 (* prove induction rule *)
   489 
   490 fun prove_indrule quiet_mode cs argTs bs xs rec_const params intr_ts mono
   491     fp_def rec_preds_defs ctxt ctxt''' =
   492   let
   493     val _ = clean_message quiet_mode "  Proving the induction rule ...";
   494     val thy = ProofContext.theory_of ctxt;
   495 
   496     (* predicates for induction rule *)
   497 
   498     val (pnames, ctxt') = Variable.variant_fixes (mk_names "P" (length cs)) ctxt;
   499     val preds = map2 (curry Free) pnames
   500       (map (fn c => arg_types_of (length params) c ---> HOLogic.boolT) cs);
   501 
   502     (* transform an introduction rule into a premise for induction rule *)
   503 
   504     fun mk_ind_prem r =
   505       let
   506         fun subst s =
   507           (case dest_predicate cs params s of
   508             SOME (_, i, ys, (_, Ts)) =>
   509               let
   510                 val k = length Ts;
   511                 val bs = map Bound (k - 1 downto 0);
   512                 val P = list_comb (List.nth (preds, i),
   513                   map (incr_boundvars k) ys @ bs);
   514                 val Q = list_abs (mk_names "x" k ~~ Ts,
   515                   HOLogic.mk_binop inductive_conj_name
   516                     (list_comb (incr_boundvars k s, bs), P))
   517               in (Q, case Ts of [] => SOME (s, P) | _ => NONE) end
   518           | NONE =>
   519               (case s of
   520                 (t $ u) => (fst (subst t) $ fst (subst u), NONE)
   521               | (Abs (a, T, t)) => (Abs (a, T, fst (subst t)), NONE)
   522               | _ => (s, NONE)));
   523 
   524         fun mk_prem s prems =
   525           (case subst s of
   526             (_, SOME (t, u)) => t :: u :: prems
   527           | (t, _) => t :: prems);
   528 
   529         val SOME (_, i, ys, _) = dest_predicate cs params
   530           (HOLogic.dest_Trueprop (Logic.strip_assums_concl r))
   531 
   532       in list_all_free (Logic.strip_params r,
   533         Logic.list_implies (map HOLogic.mk_Trueprop (fold_rev mk_prem
   534           (map HOLogic.dest_Trueprop (Logic.strip_assums_hyp r)) []),
   535             HOLogic.mk_Trueprop (list_comb (List.nth (preds, i), ys))))
   536       end;
   537 
   538     val ind_prems = map mk_ind_prem intr_ts;
   539 
   540 
   541     (* make conclusions for induction rules *)
   542 
   543     val Tss = map (binder_types o fastype_of) preds;
   544     val (xnames, ctxt'') =
   545       Variable.variant_fixes (mk_names "x" (length (flat Tss))) ctxt';
   546     val mutual_ind_concl = HOLogic.mk_Trueprop (foldr1 HOLogic.mk_conj
   547         (map (fn (((xnames, Ts), c), P) =>
   548            let val frees = map Free (xnames ~~ Ts)
   549            in HOLogic.mk_imp
   550              (list_comb (c, params @ frees), list_comb (P, frees))
   551            end) (unflat Tss xnames ~~ Tss ~~ cs ~~ preds)));
   552 
   553 
   554     (* make predicate for instantiation of abstract induction rule *)
   555 
   556     val ind_pred = fold_rev lambda (bs @ xs) (foldr1 HOLogic.mk_conj
   557       (map_index (fn (i, P) => fold_rev (curry HOLogic.mk_imp)
   558          (make_bool_args HOLogic.mk_not I bs i)
   559          (list_comb (P, make_args' argTs xs (binder_types (fastype_of P))))) preds));
   560 
   561     val ind_concl = HOLogic.mk_Trueprop
   562       (HOLogic.mk_binrel @{const_name Orderings.less_eq} (rec_const, ind_pred));
   563 
   564     val raw_fp_induct = (mono RS (fp_def RS @{thm def_lfp_induct}));
   565 
   566     val induct = Skip_Proof.prove ctxt'' [] ind_prems ind_concl
   567       (fn {prems, ...} => EVERY
   568         [rewrite_goals_tac [inductive_conj_def],
   569          DETERM (rtac raw_fp_induct 1),
   570          REPEAT (resolve_tac [@{thm le_funI}, @{thm le_boolI}] 1),
   571          rewrite_goals_tac simp_thms'',
   572          (*This disjE separates out the introduction rules*)
   573          REPEAT (FIRSTGOAL (eresolve_tac [disjE, exE, FalseE])),
   574          (*Now break down the individual cases.  No disjE here in case
   575            some premise involves disjunction.*)
   576          REPEAT (FIRSTGOAL (etac conjE ORELSE' bound_hyp_subst_tac)),
   577          REPEAT (FIRSTGOAL
   578            (resolve_tac [conjI, impI] ORELSE' (etac notE THEN' atac))),
   579          EVERY (map (fn prem => DEPTH_SOLVE_1 (ares_tac [rewrite_rule
   580              (inductive_conj_def :: rec_preds_defs @ simp_thms'') prem,
   581            conjI, refl] 1)) prems)]);
   582 
   583     val lemma = Skip_Proof.prove ctxt'' [] []
   584       (Logic.mk_implies (ind_concl, mutual_ind_concl)) (fn _ => EVERY
   585         [rewrite_goals_tac rec_preds_defs,
   586          REPEAT (EVERY
   587            [REPEAT (resolve_tac [conjI, impI] 1),
   588             REPEAT (eresolve_tac [@{thm le_funE}, @{thm le_boolE}] 1),
   589             atac 1,
   590             rewrite_goals_tac simp_thms',
   591             atac 1])])
   592 
   593   in singleton (ProofContext.export ctxt'' ctxt''') (induct RS lemma) end;
   594 
   595 
   596 
   597 (** specification of (co)inductive predicates **)
   598 
   599 fun mk_ind_def quiet_mode skip_mono fork_mono alt_name coind
   600     cs intr_ts monos params cnames_syn lthy =
   601   let
   602     val fp_name = if coind then @{const_name Inductive.gfp} else @{const_name Inductive.lfp};
   603 
   604     val argTs = fold (combine (op =) o arg_types_of (length params)) cs [];
   605     val k = log 2 1 (length cs);
   606     val predT = replicate k HOLogic.boolT ---> argTs ---> HOLogic.boolT;
   607     val p :: xs = map Free (Variable.variant_frees lthy intr_ts
   608       (("p", predT) :: (mk_names "x" (length argTs) ~~ argTs)));
   609     val bs = map Free (Variable.variant_frees lthy (p :: xs @ intr_ts)
   610       (map (rpair HOLogic.boolT) (mk_names "b" k)));
   611 
   612     fun subst t =
   613       (case dest_predicate cs params t of
   614         SOME (_, i, ts, (Ts, Us)) =>
   615           let
   616             val l = length Us;
   617             val zs = map Bound (l - 1 downto 0);
   618           in
   619             list_abs (map (pair "z") Us, list_comb (p,
   620               make_bool_args' bs i @ make_args argTs
   621                 ((map (incr_boundvars l) ts ~~ Ts) @ (zs ~~ Us))))
   622           end
   623       | NONE =>
   624           (case t of
   625             t1 $ t2 => subst t1 $ subst t2
   626           | Abs (x, T, u) => Abs (x, T, subst u)
   627           | _ => t));
   628 
   629     (* transform an introduction rule into a conjunction  *)
   630     (*   [| p_i t; ... |] ==> p_j u                       *)
   631     (* is transformed into                                *)
   632     (*   b_j & x_j = u & p b_j t & ...                    *)
   633 
   634     fun transform_rule r =
   635       let
   636         val SOME (_, i, ts, (Ts, _)) = dest_predicate cs params
   637           (HOLogic.dest_Trueprop (Logic.strip_assums_concl r));
   638         val ps = make_bool_args HOLogic.mk_not I bs i @
   639           map HOLogic.mk_eq (make_args' argTs xs Ts ~~ ts) @
   640           map (subst o HOLogic.dest_Trueprop)
   641             (Logic.strip_assums_hyp r)
   642       in
   643         fold_rev (fn (x, T) => fn P => HOLogic.exists_const T $ Abs (x, T, P))
   644           (Logic.strip_params r)
   645           (if null ps then HOLogic.true_const else foldr1 HOLogic.mk_conj ps)
   646       end
   647 
   648     (* make a disjunction of all introduction rules *)
   649 
   650     val fp_fun = fold_rev lambda (p :: bs @ xs)
   651       (if null intr_ts then HOLogic.false_const
   652        else foldr1 HOLogic.mk_disj (map transform_rule intr_ts));
   653 
   654     (* add definiton of recursive predicates to theory *)
   655 
   656     val rec_name =
   657       if Binding.is_empty alt_name then
   658         Binding.name (space_implode "_" (map (Binding.name_of o fst) cnames_syn))
   659       else alt_name;
   660 
   661     val ((rec_const, (_, fp_def)), lthy') = lthy
   662       |> Local_Theory.conceal
   663       |> Local_Theory.define
   664         ((rec_name, case cnames_syn of [(_, syn)] => syn | _ => NoSyn),
   665          ((Binding.empty, [Attrib.internal (K Nitpick_Defs.add)]),
   666          fold_rev lambda params
   667            (Const (fp_name, (predT --> predT) --> predT) $ fp_fun)))
   668       ||> Local_Theory.restore_naming lthy;
   669     val fp_def' = Simplifier.rewrite (HOL_basic_ss addsimps [fp_def])
   670       (cterm_of (ProofContext.theory_of lthy') (list_comb (rec_const, params)));
   671     val specs =
   672       if length cs < 2 then []
   673       else
   674         map_index (fn (i, (name_mx, c)) =>
   675           let
   676             val Ts = arg_types_of (length params) c;
   677             val xs = map Free (Variable.variant_frees lthy intr_ts
   678               (mk_names "x" (length Ts) ~~ Ts))
   679           in
   680             (name_mx, (Attrib.empty_binding, fold_rev lambda (params @ xs)
   681               (list_comb (rec_const, params @ make_bool_args' bs i @
   682                 make_args argTs (xs ~~ Ts)))))
   683           end) (cnames_syn ~~ cs);
   684     val (consts_defs, lthy'') = lthy'
   685       |> Local_Theory.conceal
   686       |> fold_map Local_Theory.define specs
   687       ||> Local_Theory.restore_naming lthy';
   688     val preds = (case cs of [_] => [rec_const] | _ => map #1 consts_defs);
   689 
   690     val (_, lthy''') = Variable.add_fixes (map (fst o dest_Free) params) lthy'';
   691     val mono = prove_mono quiet_mode skip_mono fork_mono predT fp_fun monos lthy''';
   692     val (_, lthy'''') =
   693       Local_Theory.note (apfst Binding.conceal Attrib.empty_binding,
   694         ProofContext.export lthy''' lthy'' [mono]) lthy'';
   695 
   696   in (lthy'''', lthy''', rec_name, mono, fp_def', map (#2 o #2) consts_defs,
   697     list_comb (rec_const, params), preds, argTs, bs, xs)
   698   end;
   699 
   700 fun declare_rules rec_binding coind no_ind cnames
   701     preds intrs intr_bindings intr_atts elims raw_induct lthy =
   702   let
   703     val rec_name = Binding.name_of rec_binding;
   704     fun rec_qualified qualified = Binding.qualify qualified rec_name;
   705     val intr_names = map Binding.name_of intr_bindings;
   706     val ind_case_names = Rule_Cases.case_names intr_names;
   707     val induct =
   708       if coind then
   709         (raw_induct, [Rule_Cases.case_names [rec_name],
   710           Rule_Cases.case_conclusion (rec_name, intr_names),
   711           Rule_Cases.consumes 1, Induct.coinduct_pred (hd cnames)])
   712       else if no_ind orelse length cnames > 1 then
   713         (raw_induct, [ind_case_names, Rule_Cases.consumes 0])
   714       else (raw_induct RSN (2, rev_mp), [ind_case_names, Rule_Cases.consumes 1]);
   715 
   716     val (intrs', lthy1) =
   717       lthy |>
   718       Spec_Rules.add
   719         (if coind then Spec_Rules.Co_Inductive else Spec_Rules.Inductive) (preds, intrs) |>
   720       Local_Theory.notes
   721         (map (rec_qualified false) intr_bindings ~~ intr_atts ~~
   722           map (fn th => [([th],
   723            [Attrib.internal (K (Context_Rules.intro_query NONE)),
   724             Attrib.internal (K Nitpick_Intros.add)])]) intrs) |>>
   725       map (hd o snd);
   726     val (((_, elims'), (_, [induct'])), lthy2) =
   727       lthy1 |>
   728       Local_Theory.note ((rec_qualified true (Binding.name "intros"), []), intrs') ||>>
   729       fold_map (fn (name, (elim, cases, k)) =>
   730         Local_Theory.note
   731           ((Binding.qualify true (Long_Name.base_name name) (Binding.name "cases"),
   732             [Attrib.internal (K (Rule_Cases.case_names cases)),
   733              Attrib.internal (K (Rule_Cases.consumes 1)),
   734              Attrib.internal (K (Rule_Cases.constraints k)),
   735              Attrib.internal (K (Induct.cases_pred name)),
   736              Attrib.internal (K (Context_Rules.elim_query NONE))]), [elim]) #>
   737         apfst (hd o snd)) (if null elims then [] else cnames ~~ elims) ||>>
   738       Local_Theory.note
   739         ((rec_qualified true (Binding.name (coind_prefix coind ^ "induct")),
   740           map (Attrib.internal o K) (#2 induct)), [rulify (#1 induct)]);
   741 
   742     val (inducts, lthy3) =
   743       if no_ind orelse coind then ([], lthy2)
   744       else
   745         let val inducts = cnames ~~ Project_Rule.projects lthy2 (1 upto length cnames) induct' in
   746           lthy2 |>
   747           Local_Theory.notes [((rec_qualified true (Binding.name "inducts"), []),
   748             inducts |> map (fn (name, th) => ([th],
   749               [Attrib.internal (K ind_case_names),
   750                Attrib.internal (K (Rule_Cases.consumes 1)),
   751                Attrib.internal (K (Induct.induct_pred name))])))] |>> snd o hd
   752         end;
   753   in (intrs', elims', induct', inducts, lthy3) end;
   754 
   755 type inductive_flags =
   756   {quiet_mode: bool, verbose: bool, alt_name: binding, coind: bool,
   757     no_elim: bool, no_ind: bool, skip_mono: bool, fork_mono: bool};
   758 
   759 type add_ind_def =
   760   inductive_flags ->
   761   term list -> (Attrib.binding * term) list -> thm list ->
   762   term list -> (binding * mixfix) list ->
   763   local_theory -> inductive_result * local_theory;
   764 
   765 fun add_ind_def {quiet_mode, verbose, alt_name, coind, no_elim, no_ind, skip_mono, fork_mono}
   766     cs intros monos params cnames_syn lthy =
   767   let
   768     val _ = null cnames_syn andalso error "No inductive predicates given";
   769     val names = map (Binding.name_of o fst) cnames_syn;
   770     val _ = message (quiet_mode andalso not verbose)
   771       ("Proofs for " ^ coind_prefix coind ^ "inductive predicate(s) " ^ commas_quote names);
   772 
   773     val cnames = map (Local_Theory.full_name lthy o #1) cnames_syn;  (* FIXME *)
   774     val ((intr_names, intr_atts), intr_ts) =
   775       apfst split_list (split_list (map (check_rule lthy cs params) intros));
   776 
   777     val (lthy1, lthy2, rec_name, mono, fp_def, rec_preds_defs, rec_const, preds,
   778       argTs, bs, xs) = mk_ind_def quiet_mode skip_mono fork_mono alt_name coind cs intr_ts
   779         monos params cnames_syn lthy;
   780 
   781     val (intrs, unfold) = prove_intrs quiet_mode coind mono fp_def (length bs + length xs)
   782       intr_ts rec_preds_defs lthy2 lthy1;
   783     val elims =
   784       if no_elim then []
   785       else
   786         prove_elims quiet_mode cs params intr_ts (map Binding.name_of intr_names)
   787           unfold rec_preds_defs lthy2 lthy1;
   788     val raw_induct = zero_var_indexes
   789       (if no_ind then Drule.asm_rl
   790        else if coind then
   791          singleton (ProofContext.export lthy2 lthy1)
   792            (rotate_prems ~1 (Object_Logic.rulify
   793              (fold_rule rec_preds_defs
   794                (rewrite_rule simp_thms'''
   795                 (mono RS (fp_def RS @{thm def_coinduct}))))))
   796        else
   797          prove_indrule quiet_mode cs argTs bs xs rec_const params intr_ts mono fp_def
   798            rec_preds_defs lthy2 lthy1);
   799 
   800     val (intrs', elims', induct, inducts, lthy3) = declare_rules rec_name coind no_ind
   801       cnames preds intrs intr_names intr_atts elims raw_induct lthy1;
   802 
   803     val result =
   804       {preds = preds,
   805        intrs = intrs',
   806        elims = elims',
   807        raw_induct = rulify raw_induct,
   808        induct = induct,
   809        inducts = inducts};
   810 
   811     val lthy4 = lthy3
   812       |> Local_Theory.declaration false (fn phi =>
   813         let val result' = morph_result phi result;
   814         in put_inductives cnames (*global names!?*) ({names = cnames, coind = coind}, result') end);
   815   in (result, lthy4) end;
   816 
   817 
   818 (* external interfaces *)
   819 
   820 fun gen_add_inductive_i mk_def
   821     (flags as {quiet_mode, verbose, alt_name, coind, no_elim, no_ind, skip_mono, fork_mono})
   822     cnames_syn pnames spec monos lthy =
   823   let
   824     val thy = ProofContext.theory_of lthy;
   825     val _ = Theory.requires thy "Inductive" (coind_prefix coind ^ "inductive definitions");
   826 
   827 
   828     (* abbrevs *)
   829 
   830     val (_, ctxt1) = Variable.add_fixes (map (Binding.name_of o fst o fst) cnames_syn) lthy;
   831 
   832     fun get_abbrev ((name, atts), t) =
   833       if can (Logic.strip_assums_concl #> Logic.dest_equals) t then
   834         let
   835           val _ = Binding.is_empty name andalso null atts orelse
   836             error "Abbreviations may not have names or attributes";
   837           val ((x, T), rhs) = Local_Defs.abs_def (snd (Local_Defs.cert_def ctxt1 t));
   838           val var =
   839             (case find_first (fn ((c, _), _) => Binding.name_of c = x) cnames_syn of
   840               NONE => error ("Undeclared head of abbreviation " ^ quote x)
   841             | SOME ((b, T'), mx) =>
   842                 if T <> T' then error ("Bad type specification for abbreviation " ^ quote x)
   843                 else (b, mx));
   844         in SOME (var, rhs) end
   845       else NONE;
   846 
   847     val abbrevs = map_filter get_abbrev spec;
   848     val bs = map (Binding.name_of o fst o fst) abbrevs;
   849 
   850 
   851     (* predicates *)
   852 
   853     val pre_intros = filter_out (is_some o get_abbrev) spec;
   854     val cnames_syn' = filter_out (member (op =) bs o Binding.name_of o fst o fst) cnames_syn;
   855     val cs = map (Free o apfst Binding.name_of o fst) cnames_syn';
   856     val ps = map Free pnames;
   857 
   858     val (_, ctxt2) = lthy |> Variable.add_fixes (map (Binding.name_of o fst o fst) cnames_syn');
   859     val _ = map (fn abbr => Local_Defs.fixed_abbrev abbr ctxt2) abbrevs;
   860     val ctxt3 = ctxt2 |> fold (snd oo Local_Defs.fixed_abbrev) abbrevs;
   861     val expand = Assumption.export_term ctxt3 lthy #> ProofContext.cert_term lthy;
   862 
   863     fun close_rule r = list_all_free (rev (fold_aterms
   864       (fn t as Free (v as (s, _)) =>
   865           if Variable.is_fixed ctxt1 s orelse
   866             member (op =) ps t then I else insert (op =) v
   867         | _ => I) r []), r);
   868 
   869     val intros = map (apsnd (Syntax.check_term lthy #> close_rule #> expand)) pre_intros;
   870     val preds = map (fn ((c, _), mx) => (c, mx)) cnames_syn';
   871   in
   872     lthy
   873     |> mk_def flags cs intros monos ps preds
   874     ||> fold (snd oo Local_Theory.abbrev Syntax.mode_default) abbrevs
   875   end;
   876 
   877 fun gen_add_inductive mk_def verbose coind cnames_syn pnames_syn intro_srcs raw_monos int lthy =
   878   let
   879     val ((vars, intrs), _) = lthy
   880       |> ProofContext.set_mode ProofContext.mode_abbrev
   881       |> Specification.read_spec (cnames_syn @ pnames_syn) intro_srcs;
   882     val (cs, ps) = chop (length cnames_syn) vars;
   883     val monos = Attrib.eval_thms lthy raw_monos;
   884     val flags = {quiet_mode = false, verbose = verbose, alt_name = Binding.empty,
   885       coind = coind, no_elim = false, no_ind = false, skip_mono = false, fork_mono = not int};
   886   in
   887     lthy
   888     |> gen_add_inductive_i mk_def flags cs (map (apfst Binding.name_of o fst) ps) intrs monos
   889   end;
   890 
   891 val add_inductive_i = gen_add_inductive_i add_ind_def;
   892 val add_inductive = gen_add_inductive add_ind_def;
   893 
   894 fun add_inductive_global flags cnames_syn pnames pre_intros monos thy =
   895   let
   896     val name = Sign.full_name thy (fst (fst (hd cnames_syn)));
   897     val ctxt' = thy
   898       |> Theory_Target.init NONE
   899       |> add_inductive_i flags cnames_syn pnames pre_intros monos |> snd
   900       |> Local_Theory.exit;
   901     val info = #2 (the_inductive ctxt' name);
   902   in (info, ProofContext.theory_of ctxt') end;
   903 
   904 
   905 (* read off arities of inductive predicates from raw induction rule *)
   906 fun arities_of induct =
   907   map (fn (_ $ t $ u) =>
   908       (fst (dest_Const (head_of t)), length (snd (strip_comb u))))
   909     (HOLogic.dest_conj (HOLogic.dest_Trueprop (concl_of induct)));
   910 
   911 (* read off parameters of inductive predicate from raw induction rule *)
   912 fun params_of induct =
   913   let
   914     val (_ $ t $ u :: _) =
   915       HOLogic.dest_conj (HOLogic.dest_Trueprop (concl_of induct));
   916     val (_, ts) = strip_comb t;
   917     val (_, us) = strip_comb u
   918   in
   919     List.take (ts, length ts - length us)
   920   end;
   921 
   922 val pname_of_intr =
   923   concl_of #> HOLogic.dest_Trueprop #> head_of #> dest_Const #> fst;
   924 
   925 (* partition introduction rules according to predicate name *)
   926 fun gen_partition_rules f induct intros =
   927   fold_rev (fn r => AList.map_entry op = (pname_of_intr (f r)) (cons r)) intros
   928     (map (rpair [] o fst) (arities_of induct));
   929 
   930 val partition_rules = gen_partition_rules I;
   931 fun partition_rules' induct = gen_partition_rules fst induct;
   932 
   933 fun unpartition_rules intros xs =
   934   fold_map (fn r => AList.map_entry_yield op = (pname_of_intr r)
   935     (fn x :: xs => (x, xs)) #>> the) intros xs |> fst;
   936 
   937 (* infer order of variables in intro rules from order of quantifiers in elim rule *)
   938 fun infer_intro_vars elim arity intros =
   939   let
   940     val thy = theory_of_thm elim;
   941     val _ :: cases = prems_of elim;
   942     val used = map (fst o fst) (Term.add_vars (prop_of elim) []);
   943     fun mtch (t, u) =
   944       let
   945         val params = Logic.strip_params t;
   946         val vars = map (Var o apfst (rpair 0))
   947           (Name.variant_list used (map fst params) ~~ map snd params);
   948         val ts = map (curry subst_bounds (rev vars))
   949           (List.drop (Logic.strip_assums_hyp t, arity));
   950         val us = Logic.strip_imp_prems u;
   951         val tab = fold (Pattern.first_order_match thy) (ts ~~ us)
   952           (Vartab.empty, Vartab.empty);
   953       in
   954         map (Envir.subst_term tab) vars
   955       end
   956   in
   957     map (mtch o apsnd prop_of) (cases ~~ intros)
   958   end;
   959 
   960 
   961 
   962 (** package setup **)
   963 
   964 (* setup theory *)
   965 
   966 val setup =
   967   ind_cases_setup #>
   968   Attrib.setup @{binding mono} (Attrib.add_del mono_add mono_del)
   969     "declaration of monotonicity rule";
   970 
   971 
   972 (* outer syntax *)
   973 
   974 local structure P = OuterParse and K = OuterKeyword in
   975 
   976 val _ = OuterKeyword.keyword "monos";
   977 
   978 fun gen_ind_decl mk_def coind =
   979   P.fixes -- P.for_fixes --
   980   Scan.optional SpecParse.where_alt_specs [] --
   981   Scan.optional (P.$$$ "monos" |-- P.!!! SpecParse.xthms1) []
   982   >> (fn (((preds, params), specs), monos) =>
   983       (snd oo gen_add_inductive mk_def true coind preds params specs monos));
   984 
   985 val ind_decl = gen_ind_decl add_ind_def;
   986 
   987 val _ =
   988   OuterSyntax.local_theory' "inductive" "define inductive predicates" K.thy_decl
   989     (ind_decl false);
   990 
   991 val _ =
   992   OuterSyntax.local_theory' "coinductive" "define coinductive predicates" K.thy_decl
   993     (ind_decl true);
   994 
   995 val _ =
   996   OuterSyntax.local_theory "inductive_cases"
   997     "create simplified instances of elimination rules (improper)" K.thy_script
   998     (P.and_list1 SpecParse.specs >> (snd oo inductive_cases));
   999 
  1000 end;
  1001 
  1002 end;