src/Pure/axclass.ML
author wenzelm
Mon Apr 26 14:44:41 2010 +0200 (2010-04-26 ago)
changeset 36346 5518de23101d
parent 36330 0584e203960e
child 36417 54bc1a44967d
permissions -rw-r--r--
removed unused AxClass.class_intros;
     1 (*  Title:      Pure/axclass.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Type classes defined as predicates, associated with a record of
     5 parameters.
     6 *)
     7 
     8 signature AX_CLASS =
     9 sig
    10   val define_class: binding * class list -> string list ->
    11     (Thm.binding * term list) list -> theory -> class * theory
    12   val add_classrel: thm -> theory -> theory
    13   val add_arity: thm -> theory -> theory
    14   val prove_classrel: class * class -> tactic -> theory -> theory
    15   val prove_arity: string * sort list * sort -> tactic -> theory -> theory
    16   type info = {def: thm, intro: thm, axioms: thm list, params: (string * typ) list}
    17   val get_info: theory -> class -> info
    18   val class_of_param: theory -> string -> class option
    19   val cert_classrel: theory -> class * class -> class * class
    20   val read_classrel: theory -> xstring * xstring -> class * class
    21   val axiomatize_class: binding * class list -> theory -> theory
    22   val axiomatize_class_cmd: binding * xstring list -> theory -> theory
    23   val axiomatize_classrel: (class * class) list -> theory -> theory
    24   val axiomatize_classrel_cmd: (xstring * xstring) list -> theory -> theory
    25   val axiomatize_arity: arity -> theory -> theory
    26   val axiomatize_arity_cmd: xstring * string list * string -> theory -> theory
    27   val instance_name: string * class -> string
    28   val declare_overloaded: string * typ -> theory -> term * theory
    29   val define_overloaded: binding -> string * term -> theory -> thm * theory
    30   val unoverload: theory -> thm -> thm
    31   val overload: theory -> thm -> thm
    32   val unoverload_conv: theory -> conv
    33   val overload_conv: theory -> conv
    34   val unoverload_const: theory -> string * typ -> string
    35   val lookup_inst_param: Consts.T -> ((string * string) * 'a) list -> string * typ -> 'a option
    36   val param_of_inst: theory -> string * string -> string
    37   val inst_of_param: theory -> string -> (string * string) option
    38   val thynames_of_arity: theory -> class * string -> string list
    39 end;
    40 
    41 structure AxClass: AX_CLASS =
    42 struct
    43 
    44 (** theory data **)
    45 
    46 (* axclass info *)
    47 
    48 type info =
    49  {def: thm,
    50   intro: thm,
    51   axioms: thm list,
    52   params: (string * typ) list};
    53 
    54 fun make_axclass (def, intro, axioms, params): info =
    55   {def = def, intro = intro, axioms = axioms, params = params};
    56 
    57 
    58 (* class parameters (canonical order) *)
    59 
    60 type param = string * class;
    61 
    62 fun add_param pp ((x, c): param) params =
    63   (case AList.lookup (op =) params x of
    64     NONE => (x, c) :: params
    65   | SOME c' => error ("Duplicate class parameter " ^ quote x ^
    66       " for " ^ Pretty.string_of_sort pp [c] ^
    67       (if c = c' then "" else " and " ^ Pretty.string_of_sort pp [c'])));
    68 
    69 
    70 (* setup data *)
    71 
    72 datatype data = Data of
    73  {axclasses: info Symtab.table,
    74   params: param list,
    75   proven_classrels: (thm * proof) Symreltab.table,
    76   proven_arities: ((class * sort list) * ((thm * string) * proof)) list Symtab.table,
    77     (*arity theorems with theory name*)
    78   inst_params:
    79     (string * thm) Symtab.table Symtab.table *
    80       (*constant name ~> type constructor ~> (constant name, equation)*)
    81     (string * string) Symtab.table (*constant name ~> (constant name, type constructor)*),
    82   diff_merge_classrels: (class * class) list};
    83 
    84 fun make_data
    85     (axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels) =
    86   Data {axclasses = axclasses, params = params, proven_classrels = proven_classrels,
    87     proven_arities = proven_arities, inst_params = inst_params,
    88     diff_merge_classrels = diff_merge_classrels};
    89 
    90 structure Data = Theory_Data_PP
    91 (
    92   type T = data;
    93   val empty =
    94     make_data (Symtab.empty, [], Symreltab.empty, Symtab.empty, (Symtab.empty, Symtab.empty), []);
    95   val extend = I;
    96   fun merge pp
    97       (Data {axclasses = axclasses1, params = params1, proven_classrels = proven_classrels1,
    98         proven_arities = proven_arities1, inst_params = inst_params1,
    99         diff_merge_classrels = diff_merge_classrels1},
   100        Data {axclasses = axclasses2, params = params2, proven_classrels = proven_classrels2,
   101         proven_arities = proven_arities2, inst_params = inst_params2,
   102         diff_merge_classrels = diff_merge_classrels2}) =
   103     let
   104       val axclasses' = Symtab.merge (K true) (axclasses1, axclasses2);
   105       val params' =
   106         if null params1 then params2
   107         else fold_rev (fn q => if member (op =) params1 q then I else add_param pp q) params2 params1;
   108 
   109       (*transitive closure of classrels and arity completion is done in Theory.at_begin hook*)
   110       val proven_classrels' = Symreltab.join (K #1) (proven_classrels1, proven_classrels2);
   111       val proven_arities' =
   112         Symtab.join (K (Library.merge (eq_fst op =))) (proven_arities1, proven_arities2);
   113 
   114       val classrels1 = Symreltab.keys proven_classrels1;
   115       val classrels2 = Symreltab.keys proven_classrels2;
   116       val diff_merge_classrels' =
   117         subtract (op =) classrels1 classrels2 @
   118         subtract (op =) classrels2 classrels1 @
   119         diff_merge_classrels1 @ diff_merge_classrels2;
   120 
   121       val inst_params' =
   122         (Symtab.join (K (Symtab.merge (K true))) (#1 inst_params1, #1 inst_params2),
   123           Symtab.merge (K true) (#2 inst_params1, #2 inst_params2));
   124     in
   125       make_data (axclasses', params', proven_classrels', proven_arities', inst_params',
   126         diff_merge_classrels')
   127     end;
   128 );
   129 
   130 fun map_data f =
   131   Data.map (fn Data {axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels} =>
   132     make_data (f (axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels)));
   133 
   134 fun map_axclasses f =
   135   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels) =>
   136     (f axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels));
   137 
   138 fun map_params f =
   139   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels) =>
   140     (axclasses, f params, proven_classrels, proven_arities, inst_params, diff_merge_classrels));
   141 
   142 fun map_proven_classrels f =
   143   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels) =>
   144     (axclasses, params, f proven_classrels, proven_arities, inst_params, diff_merge_classrels));
   145 
   146 fun map_proven_arities f =
   147   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels) =>
   148     (axclasses, params, proven_classrels, f proven_arities, inst_params, diff_merge_classrels));
   149 
   150 fun map_inst_params f =
   151   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, diff_merge_classrels) =>
   152     (axclasses, params, proven_classrels, proven_arities, f inst_params, diff_merge_classrels));
   153 
   154 val clear_diff_merge_classrels =
   155   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params, _) =>
   156     (axclasses, params, proven_classrels, proven_arities, inst_params, []));
   157 
   158 val rep_data = Data.get #> (fn Data args => args);
   159 
   160 val axclasses_of = #axclasses o rep_data;
   161 val params_of = #params o rep_data;
   162 val proven_classrels_of = #proven_classrels o rep_data;
   163 val proven_arities_of = #proven_arities o rep_data;
   164 val inst_params_of = #inst_params o rep_data;
   165 val diff_merge_classrels_of = #diff_merge_classrels o rep_data;
   166 
   167 
   168 (* axclasses with parameters *)
   169 
   170 fun get_info thy c =
   171   (case Symtab.lookup (axclasses_of thy) c of
   172     SOME info => info
   173   | NONE => error ("No such axclass: " ^ quote c));
   174 
   175 fun all_params_of thy S =
   176   let val params = params_of thy;
   177   in fold (fn (x, c) => if Sign.subsort thy (S, [c]) then cons x else I) params [] end;
   178 
   179 fun class_of_param thy = AList.lookup (op =) (params_of thy);
   180 
   181 
   182 (* maintain instances *)
   183 
   184 val classrel_prefix = "classrel_";
   185 val arity_prefix = "arity_";
   186 
   187 fun instance_name (a, c) = Long_Name.base_name c ^ "_" ^ Long_Name.base_name a;
   188 
   189 
   190 fun the_classrel thy (c1, c2) =
   191   (case Symreltab.lookup (proven_classrels_of thy) (c1, c2) of
   192     SOME classrel => classrel
   193   | NONE => error ("Unproven class relation " ^
   194       Syntax.string_of_classrel (ProofContext.init thy) [c1, c2]));
   195 
   196 fun the_classrel_thm thy = Thm.transfer thy o #1 o the_classrel thy;
   197 fun the_classrel_prf thy = #2 o the_classrel thy;
   198 
   199 fun put_trancl_classrel ((c1, c2), th) thy =
   200   let
   201     val cert = Thm.cterm_of thy;
   202     val certT = Thm.ctyp_of thy;
   203 
   204     val classes = Sorts.classes_of (Sign.classes_of thy);
   205     val classrels = proven_classrels_of thy;
   206 
   207     fun reflcl_classrel (c1', c2') =
   208       if c1' = c2'
   209       then Thm.trivial (cert (Logic.mk_of_class (TVar ((Name.aT, 0), []), c1')))
   210       else the_classrel_thm thy (c1', c2');
   211     fun gen_classrel (c1_pred, c2_succ) =
   212       let
   213         val th' = ((reflcl_classrel (c1_pred, c1) RS th) RS reflcl_classrel (c2, c2_succ))
   214           |> Drule.instantiate' [SOME (certT (TVar ((Name.aT, 0), [])))] []
   215           |> Thm.close_derivation;
   216         val prf' = Thm.proof_of th';
   217       in ((c1_pred, c2_succ), (th', prf')) end;
   218 
   219     val new_classrels =
   220       Library.map_product pair (c1 :: Graph.imm_preds classes c1) (c2 :: Graph.imm_succs classes c2)
   221       |> filter_out (Symreltab.defined classrels)
   222       |> map gen_classrel;
   223     val needed = not (null new_classrels);
   224   in
   225     (needed,
   226       if needed then map_proven_classrels (fold Symreltab.update new_classrels) thy
   227       else thy)
   228   end;
   229 
   230 fun complete_classrels thy =
   231   let
   232     val classrels = proven_classrels_of thy;
   233     val diff_merge_classrels = diff_merge_classrels_of thy;
   234     val (needed, thy') = (false, thy) |>
   235       fold (fn c12 => fn (needed, thy) =>
   236           put_trancl_classrel (c12, Symreltab.lookup classrels c12 |> the |> #1) thy
   237           |>> (fn b => needed orelse b))
   238         diff_merge_classrels;
   239   in
   240     if null diff_merge_classrels then NONE
   241     else SOME (clear_diff_merge_classrels thy')
   242   end;
   243 
   244 
   245 fun the_arity thy a (c, Ss) =
   246   (case AList.lookup (op =) (Symtab.lookup_list (proven_arities_of thy) a) (c, Ss) of
   247     SOME arity => arity
   248   | NONE => error ("Unproven type arity " ^
   249       Syntax.string_of_arity (ProofContext.init thy) (a, Ss, [c])));
   250 
   251 fun the_arity_thm thy a c_Ss = the_arity thy a c_Ss |> #1 |> #1 |> Thm.transfer thy;
   252 fun the_arity_prf thy a c_Ss = the_arity thy a c_Ss |> #2;
   253 
   254 fun thynames_of_arity thy (c, a) =
   255   Symtab.lookup_list (proven_arities_of thy) a
   256   |> map_filter (fn ((c', _), ((_, name),_)) => if c = c' then SOME name else NONE)
   257   |> rev;
   258 
   259 fun insert_arity_completions thy (t, ((c, Ss), ((th, thy_name), _))) arities =
   260   let
   261     val algebra = Sign.classes_of thy;
   262     val super_class_completions =
   263       Sign.super_classes thy c
   264       |> filter_out (fn c1 => exists (fn ((c2, Ss2), _) => c1 = c2
   265           andalso Sorts.sorts_le algebra (Ss2, Ss)) (Symtab.lookup_list arities t));
   266     val names_and_Ss = Name.names Name.context Name.aT (map (K []) Ss);
   267     val completions = super_class_completions |> map (fn c1 =>
   268       let
   269         val th1 = (th RS the_classrel_thm thy (c, c1))
   270           |> Drule.instantiate' (map (SOME o ctyp_of thy o TVar o apfst (rpair 0)) names_and_Ss) []
   271           |> Thm.close_derivation;
   272         val prf1 = Thm.proof_of th1;
   273       in (((th1, thy_name), prf1), c1) end);
   274     val arities' = fold (fn (th_thy_prf1, c1) => Symtab.cons_list (t, ((c1, Ss), th_thy_prf1)))
   275       completions arities;
   276   in (null completions, arities') end;
   277 
   278 fun put_arity ((t, Ss, c), th) thy =
   279   let
   280     val arity' = (t, ((c, Ss), ((th, Context.theory_name thy), Thm.proof_of th)));
   281   in
   282     thy
   283     |> map_proven_arities
   284       (Symtab.insert_list (eq_fst op =) arity' #>
   285         insert_arity_completions thy arity' #> snd)
   286   end;
   287 
   288 fun complete_arities thy =
   289   let
   290     val arities = proven_arities_of thy;
   291     val (finished, arities') = arities
   292       |> fold_map (insert_arity_completions thy) (Symtab.dest_list arities);
   293   in
   294     if forall I finished
   295     then NONE
   296     else SOME (map_proven_arities (K arities') thy)
   297   end;
   298 
   299 val _ = Context.>> (Context.map_theory
   300   (Theory.at_begin complete_classrels #> Theory.at_begin complete_arities));
   301 
   302 
   303 (* maintain instance parameters *)
   304 
   305 fun get_inst_param thy (c, tyco) =
   306   (case Symtab.lookup (the_default Symtab.empty (Symtab.lookup (#1 (inst_params_of thy)) c)) tyco of
   307     SOME c' => c'
   308   | NONE => error ("No instance parameter for constant " ^ quote c ^ " on type " ^ quote tyco));
   309 
   310 fun add_inst_param (c, tyco) inst =
   311   (map_inst_params o apfst o Symtab.map_default (c, Symtab.empty)) (Symtab.update_new (tyco, inst))
   312   #> (map_inst_params o apsnd) (Symtab.update_new (fst inst, (c, tyco)));
   313 
   314 val inst_of_param = Symtab.lookup o #2 o inst_params_of;
   315 val param_of_inst = fst oo get_inst_param;
   316 
   317 fun inst_thms thy =
   318   Symtab.fold (Symtab.fold (cons o #2 o #2) o #2) (#1 (inst_params_of thy)) [];
   319 
   320 fun get_inst_tyco consts = try (fst o dest_Type o the_single o Consts.typargs consts);
   321 
   322 fun unoverload thy = MetaSimplifier.simplify true (inst_thms thy);
   323 fun overload thy = MetaSimplifier.simplify true (map Thm.symmetric (inst_thms thy));
   324 
   325 fun unoverload_conv thy = MetaSimplifier.rewrite true (inst_thms thy);
   326 fun overload_conv thy = MetaSimplifier.rewrite true (map Thm.symmetric (inst_thms thy));
   327 
   328 fun lookup_inst_param consts params (c, T) =
   329   (case get_inst_tyco consts (c, T) of
   330     SOME tyco => AList.lookup (op =) params (c, tyco)
   331   | NONE => NONE);
   332 
   333 fun unoverload_const thy (c_ty as (c, _)) =
   334   if is_some (class_of_param thy c) then
   335     (case get_inst_tyco (Sign.consts_of thy) c_ty of
   336       SOME tyco => try (param_of_inst thy) (c, tyco) |> the_default c
   337     | NONE => c)
   338   else c;
   339 
   340 
   341 
   342 (** instances **)
   343 
   344 (* class relations *)
   345 
   346 fun cert_classrel thy raw_rel =
   347   let
   348     val string_of_sort = Syntax.string_of_sort_global thy;
   349     val (c1, c2) = pairself (Sign.certify_class thy) raw_rel;
   350     val _ = Sign.primitive_classrel (c1, c2) (Theory.copy thy);
   351     val _ =
   352       (case subtract (op =) (all_params_of thy [c1]) (all_params_of thy [c2]) of
   353         [] => ()
   354       | xs => raise TYPE ("Class " ^ string_of_sort [c1] ^ " lacks parameter(s) " ^
   355           commas_quote xs ^ " of " ^ string_of_sort [c2], [], []));
   356   in (c1, c2) end;
   357 
   358 fun read_classrel thy raw_rel =
   359   cert_classrel thy (pairself (ProofContext.read_class (ProofContext.init thy)) raw_rel)
   360     handle TYPE (msg, _, _) => error msg;
   361 
   362 
   363 (* declaration and definition of instances of overloaded constants *)
   364 
   365 fun inst_tyco_of thy (c, T) =
   366   (case get_inst_tyco (Sign.consts_of thy) (c, T) of
   367     SOME tyco => tyco
   368   | NONE => error ("Illegal type for instantiation of class parameter: " ^
   369       quote (c ^ " :: " ^ Syntax.string_of_typ_global thy T)));
   370 
   371 fun declare_overloaded (c, T) thy =
   372   let
   373     val class =
   374       (case class_of_param thy c of
   375         SOME class => class
   376       | NONE => error ("Not a class parameter: " ^ quote c));
   377     val tyco = inst_tyco_of thy (c, T);
   378     val name_inst = instance_name (tyco, class) ^ "_inst";
   379     val c' = Long_Name.base_name c ^ "_" ^ Long_Name.base_name tyco;
   380     val T' = Type.strip_sorts T;
   381   in
   382     thy
   383     |> Sign.qualified_path true (Binding.name name_inst)
   384     |> Sign.declare_const ((Binding.name c', T'), NoSyn)
   385     |-> (fn const' as Const (c'', _) =>
   386       Thm.add_def false true
   387         (Binding.name (Thm.def_name c'), Logic.mk_equals (Const (c, T'), const'))
   388       #>> apsnd Thm.varifyT_global
   389       #-> (fn (_, thm) => add_inst_param (c, tyco) (c'', thm)
   390         #> PureThy.add_thm ((Binding.conceal (Binding.name c'), thm), [])
   391         #> snd
   392         #> pair (Const (c, T))))
   393     ||> Sign.restore_naming thy
   394   end;
   395 
   396 fun define_overloaded b (c, t) thy =
   397   let
   398     val T = Term.fastype_of t;
   399     val tyco = inst_tyco_of thy (c, T);
   400     val (c', eq) = get_inst_param thy (c, tyco);
   401     val prop = Logic.mk_equals (Const (c', T), t);
   402     val b' = Thm.def_binding_optional
   403       (Binding.name (Long_Name.base_name c ^ "_" ^ Long_Name.base_name tyco)) b;
   404   in
   405     thy
   406     |> Thm.add_def false false (b', prop)
   407     |>> (fn (_, thm) =>  Drule.transitive_thm OF [eq, thm])
   408   end;
   409 
   410 
   411 (* primitive rules *)
   412 
   413 val shyps_topped = forall null o #shyps o Thm.rep_thm;
   414 
   415 fun add_classrel raw_th thy =
   416   let
   417     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   418     val prop = Thm.plain_prop_of th;
   419     fun err () = raise THM ("add_classrel: malformed class relation", 0, [th]);
   420     val rel = Logic.dest_classrel prop handle TERM _ => err ();
   421     val (c1, c2) = cert_classrel thy rel handle TYPE _ => err ();
   422     val th' = th
   423       |> Drule.instantiate' [SOME (ctyp_of thy (TVar ((Name.aT, 0), [c1])))] []
   424       |> Thm.unconstrain_allTs;
   425     val _ = shyps_topped th' orelse raise Fail "add_classrel: nontop shyps after unconstrain";
   426   in
   427     thy
   428     |> Sign.primitive_classrel (c1, c2)
   429     |> (snd oo put_trancl_classrel) ((c1, c2), th')
   430     |> perhaps complete_arities
   431   end;
   432 
   433 fun add_arity raw_th thy =
   434   let
   435     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   436     val prop = Thm.plain_prop_of th;
   437     fun err () = raise THM ("add_arity: malformed type arity", 0, [th]);
   438     val (t, Ss, c) = Logic.dest_arity prop handle TERM _ => err ();
   439     val names = Name.names Name.context Name.aT Ss;
   440     val T = Type (t, map TFree names);
   441     val missing_params = Sign.complete_sort thy [c]
   442       |> maps (these o Option.map #params o try (get_info thy))
   443       |> filter_out (fn (const, _) => can (get_inst_param thy) (const, t))
   444       |> (map o apsnd o map_atyps) (K T);
   445     val _ = map (Sign.certify_sort thy) Ss = Ss orelse err ();
   446     val th' = th
   447       |> Drule.instantiate' (map (SOME o ctyp_of thy o TVar o apfst (rpair 0)) names) []
   448       |> Thm.unconstrain_allTs;
   449     val _ = shyps_topped th' orelse raise Fail "add_arity: nontop shyps after unconstrain";
   450   in
   451     thy
   452     |> fold (snd oo declare_overloaded) missing_params
   453     |> Sign.primitive_arity (t, Ss, [c])
   454     |> put_arity ((t, Ss, c), th')
   455   end;
   456 
   457 
   458 (* tactical proofs *)
   459 
   460 fun prove_classrel raw_rel tac thy =
   461   let
   462     val ctxt = ProofContext.init thy;
   463     val (c1, c2) = cert_classrel thy raw_rel;
   464     val th = Goal.prove ctxt [] [] (Logic.mk_classrel (c1, c2)) (K tac) handle ERROR msg =>
   465       cat_error msg ("The error(s) above occurred while trying to prove class relation " ^
   466         quote (Syntax.string_of_classrel ctxt [c1, c2]));
   467   in
   468     thy
   469     |> PureThy.add_thms [((Binding.name
   470         (prefix classrel_prefix (Logic.name_classrel (c1, c2))), th), [])]
   471     |-> (fn [th'] => add_classrel th')
   472   end;
   473 
   474 fun prove_arity raw_arity tac thy =
   475   let
   476     val ctxt = ProofContext.init thy;
   477     val arity = ProofContext.cert_arity ctxt raw_arity;
   478     val names = map (prefix arity_prefix) (Logic.name_arities arity);
   479     val props = Logic.mk_arities arity;
   480     val ths = Goal.prove_multi ctxt [] [] props
   481       (fn _ => Goal.precise_conjunction_tac (length props) 1 THEN tac) handle ERROR msg =>
   482         cat_error msg ("The error(s) above occurred while trying to prove type arity " ^
   483           quote (Syntax.string_of_arity ctxt arity));
   484   in
   485     thy
   486     |> PureThy.add_thms (map (rpair []) (map Binding.name names ~~ ths))
   487     |-> fold add_arity
   488   end;
   489 
   490 
   491 
   492 (** class definitions **)
   493 
   494 fun split_defined n eq =
   495   let
   496     val intro =
   497       (eq RS Drule.equal_elim_rule2)
   498       |> Conjunction.curry_balanced n
   499       |> n = 0 ? Thm.eq_assumption 1;
   500     val dests =
   501       if n = 0 then []
   502       else
   503         (eq RS Drule.equal_elim_rule1)
   504         |> Balanced_Tree.dest (fn th =>
   505           (th RS Conjunction.conjunctionD1, th RS Conjunction.conjunctionD2)) n;
   506   in (intro, dests) end;
   507 
   508 fun define_class (bclass, raw_super) raw_params raw_specs thy =
   509   let
   510     val ctxt = ProofContext.init thy;
   511     val pp = Syntax.pp ctxt;
   512 
   513 
   514     (* class *)
   515 
   516     val bconst = Binding.map_name Logic.const_of_class bclass;
   517     val class = Sign.full_name thy bclass;
   518     val super = Sign.minimize_sort thy (Sign.certify_sort thy raw_super);
   519 
   520     fun check_constraint (a, S) =
   521       if Sign.subsort thy (super, S) then ()
   522       else error ("Sort constraint of type variable " ^
   523         setmp_CRITICAL show_sorts true (Pretty.string_of_typ pp) (TFree (a, S)) ^
   524         " needs to be weaker than " ^ Pretty.string_of_sort pp super);
   525 
   526 
   527     (* params *)
   528 
   529     val params = raw_params |> map (fn p =>
   530       let
   531         val T = Sign.the_const_type thy p;
   532         val _ =
   533           (case Term.add_tvarsT T [] of
   534             [((a, _), S)] => check_constraint (a, S)
   535           | _ => error ("Exactly one type variable expected in class parameter " ^ quote p));
   536         val T' = Term.map_type_tvar (fn _ => TFree (Name.aT, [class])) T;
   537       in (p, T') end);
   538 
   539 
   540     (* axioms *)
   541 
   542     fun prep_axiom t =
   543       (case Term.add_tfrees t [] of
   544         [(a, S)] => check_constraint (a, S)
   545       | [] => ()
   546       | _ => error ("Multiple type variables in class axiom:\n" ^ Pretty.string_of_term pp t);
   547       t
   548       |> Term.map_types (Term.map_atyps (fn TFree _ => Term.aT [] | U => U))
   549       |> Logic.close_form);
   550 
   551     val axiomss = map (map (prep_axiom o Sign.cert_prop thy) o snd) raw_specs;
   552     val name_atts = map fst raw_specs;
   553 
   554 
   555     (* definition *)
   556 
   557     val conjs = Logic.mk_of_sort (Term.aT [], super) @ flat axiomss;
   558     val class_eq =
   559       Logic.mk_equals (Logic.mk_of_class (Term.aT [], class), Logic.mk_conjunction_balanced conjs);
   560 
   561     val ([def], def_thy) =
   562       thy
   563       |> Sign.primitive_class (bclass, super)
   564       |> PureThy.add_defs false [((Thm.def_binding bconst, class_eq), [])];
   565     val (raw_intro, (raw_classrel, raw_axioms)) =
   566       split_defined (length conjs) def ||> chop (length super);
   567 
   568 
   569     (* facts *)
   570 
   571     val class_triv = Thm.class_triv def_thy class;
   572     val ([(_, [intro]), (_, classrel), (_, axioms)], facts_thy) =
   573       def_thy
   574       |> Sign.qualified_path true bconst
   575       |> PureThy.note_thmss ""
   576         [((Binding.name "intro", []), [([Drule.export_without_context raw_intro], [])]),
   577          ((Binding.name "super", []), [(map Drule.export_without_context raw_classrel, [])]),
   578          ((Binding.name "axioms", []),
   579            [(map (fn th => Drule.export_without_context (class_triv RS th)) raw_axioms, [])])]
   580       ||> Sign.restore_naming def_thy;
   581 
   582 
   583     (* result *)
   584 
   585     val axclass = make_axclass (def, intro, axioms, params);
   586     val result_thy =
   587       facts_thy
   588       |> fold (snd oo put_trancl_classrel) (map (pair class) super ~~ classrel)
   589       |> Sign.qualified_path false bconst
   590       |> PureThy.note_thmss "" (name_atts ~~ map Thm.simple_fact (unflat axiomss axioms)) |> snd
   591       |> Sign.restore_naming facts_thy
   592       |> map_axclasses (Symtab.update (class, axclass))
   593       |> map_params (fold (fn (x, _) => add_param pp (x, class)) params);
   594 
   595   in (class, result_thy) end;
   596 
   597 
   598 
   599 (** axiomatizations **)
   600 
   601 local
   602 
   603 (* old-style axioms *)
   604 
   605 fun add_axiom (b, prop) =
   606   Thm.add_axiom (b, prop) #->
   607   (fn (_, thm) => PureThy.add_thm ((b, Drule.export_without_context thm), []));
   608 
   609 fun axiomatize prep mk name add raw_args thy =
   610   let
   611     val args = prep thy raw_args;
   612     val specs = mk args;
   613     val names = name args;
   614   in
   615     thy
   616     |> fold_map add_axiom (map Binding.name names ~~ specs)
   617     |-> fold add
   618   end;
   619 
   620 fun ax_classrel prep =
   621   axiomatize (map o prep) (map Logic.mk_classrel)
   622     (map (prefix classrel_prefix o Logic.name_classrel)) add_classrel;
   623 
   624 fun ax_arity prep =
   625   axiomatize (prep o ProofContext.init) Logic.mk_arities
   626     (map (prefix arity_prefix) o Logic.name_arities) add_arity;
   627 
   628 fun class_const c =
   629   (Logic.const_of_class c, Term.itselfT (Term.aT []) --> propT);
   630 
   631 fun ax_class prep_class prep_classrel (bclass, raw_super) thy =
   632   let
   633     val class = Sign.full_name thy bclass;
   634     val super = map (prep_class thy) raw_super |> Sign.minimize_sort thy;
   635   in
   636     thy
   637     |> Sign.primitive_class (bclass, super)
   638     |> ax_classrel prep_classrel (map (fn c => (class, c)) super)
   639     |> Theory.add_deps "" (class_const class) (map class_const super)
   640   end;
   641 
   642 in
   643 
   644 val axiomatize_class = ax_class Sign.certify_class cert_classrel;
   645 val axiomatize_class_cmd = ax_class (ProofContext.read_class o ProofContext.init) read_classrel;
   646 val axiomatize_classrel = ax_classrel cert_classrel;
   647 val axiomatize_classrel_cmd = ax_classrel read_classrel;
   648 val axiomatize_arity = ax_arity ProofContext.cert_arity;
   649 val axiomatize_arity_cmd = ax_arity ProofContext.read_arity;
   650 
   651 end;
   652 
   653 end;