src/Pure/axclass.ML
author wenzelm
Tue Mar 03 14:07:43 2009 +0100 (2009-03-03 ago)
changeset 30211 556d1810cdad
parent 29579 cb520b766e00
child 30244 48543b307e99
permissions -rw-r--r--
Thm.binding;
     1 (*  Title:      Pure/axclass.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Type classes defined as predicates, associated with a record of
     5 parameters.
     6 *)
     7 
     8 signature AX_CLASS =
     9 sig
    10   val define_class: bstring * class list -> string list ->
    11     (Thm.binding * term list) list -> theory -> class * theory
    12   val add_classrel: thm -> theory -> theory
    13   val add_arity: thm -> theory -> theory
    14   val prove_classrel: class * class -> tactic -> theory -> theory
    15   val prove_arity: string * sort list * sort -> tactic -> theory -> theory
    16   val get_info: theory -> class ->
    17     {def: thm, intro: thm, axioms: thm list, params: (string * typ) list}
    18   val class_intros: theory -> thm list
    19   val class_of_param: theory -> string -> class option
    20   val cert_classrel: theory -> class * class -> class * class
    21   val read_classrel: theory -> xstring * xstring -> class * class
    22   val axiomatize_class: bstring * class list -> theory -> theory
    23   val axiomatize_class_cmd: bstring * xstring list -> theory -> theory
    24   val axiomatize_classrel: (class * class) list -> theory -> theory
    25   val axiomatize_classrel_cmd: (xstring * xstring) list -> theory -> theory
    26   val axiomatize_arity: arity -> theory -> theory
    27   val axiomatize_arity_cmd: xstring * string list * string -> theory -> theory
    28   val instance_name: string * class -> string
    29   val declare_overloaded: string * typ -> theory -> term * theory
    30   val define_overloaded: string -> string * term -> theory -> thm * theory
    31   val inst_tyco_of: theory -> string * typ -> string option
    32   val unoverload: theory -> thm -> thm
    33   val overload: theory -> thm -> thm
    34   val unoverload_conv: theory -> conv
    35   val overload_conv: theory -> conv
    36   val unoverload_const: theory -> string * typ -> string
    37   val param_of_inst: theory -> string * string -> string
    38   val inst_of_param: theory -> string -> (string * string) option
    39   val arity_property: theory -> class * string -> string -> string list
    40   type cache
    41   val of_sort: theory -> typ * sort -> cache -> thm list * cache  (*exception Sorts.CLASS_ERROR*)
    42   val cache: cache
    43   val introN: string
    44   val axiomsN: string
    45 end;
    46 
    47 structure AxClass: AX_CLASS =
    48 struct
    49 
    50 (** theory data **)
    51 
    52 (* class parameters (canonical order) *)
    53 
    54 type param = string * class;
    55 
    56 fun add_param pp ((x, c): param) params =
    57   (case AList.lookup (op =) params x of
    58     NONE => (x, c) :: params
    59   | SOME c' => error ("Duplicate class parameter " ^ quote x ^
    60       " for " ^ Pretty.string_of_sort pp [c] ^
    61       (if c = c' then "" else " and " ^ Pretty.string_of_sort pp [c'])));
    62 
    63 fun merge_params _ ([], qs) = qs
    64   | merge_params pp (ps, qs) =
    65       fold_rev (fn q => if member (op =) ps q then I else add_param pp q) qs ps;
    66 
    67 
    68 (* axclasses *)
    69 
    70 val introN = "intro";
    71 val superN = "super";
    72 val axiomsN = "axioms";
    73 
    74 datatype axclass = AxClass of
    75  {def: thm,
    76   intro: thm,
    77   axioms: thm list,
    78   params: (string * typ) list};
    79 
    80 type axclasses = axclass Symtab.table * param list;
    81 
    82 fun make_axclass ((def, intro, axioms), params) = AxClass
    83   {def = def, intro = intro, axioms = axioms, params = params};
    84 
    85 fun merge_axclasses pp ((tab1, params1), (tab2, params2)) : axclasses =
    86   (Symtab.merge (K true) (tab1, tab2), merge_params pp (params1, params2));
    87 
    88 
    89 (* instances *)
    90 
    91 val classrel_prefix = "classrel_";
    92 val arity_prefix = "arity_";
    93 
    94 type instances =
    95   ((class * class) * thm) list *
    96   ((class * sort list) * thm) list Symtab.table;
    97 
    98 fun merge_instances ((classrel1, arities1): instances, (classrel2, arities2)) =
    99  (merge (eq_fst op =) (classrel1, classrel2),
   100   Symtab.join (K (merge (eq_fst op =))) (arities1, arities2));
   101 
   102 
   103 (* instance parameters *)
   104 
   105 type inst_params =
   106   (string * thm) Symtab.table Symtab.table
   107     (*constant name ~> type constructor ~> (constant name, equation)*)
   108   * (string * string) Symtab.table; (*constant name ~> (constant name, type constructor)*)
   109 
   110 fun merge_inst_params ((const_param1, param_const1), (const_param2, param_const2)) =
   111   (Symtab.join  (K (Symtab.merge (K true))) (const_param1, const_param2),
   112     Symtab.merge (K true) (param_const1, param_const2));
   113 
   114 
   115 (* setup data *)
   116 
   117 structure AxClassData = TheoryDataFun
   118 (
   119   type T = axclasses * (instances * inst_params);
   120   val empty = ((Symtab.empty, []), (([], Symtab.empty), (Symtab.empty, Symtab.empty)));
   121   val copy = I;
   122   val extend = I;
   123   fun merge pp ((axclasses1, (instances1, inst_params1)), (axclasses2, (instances2, inst_params2))) =
   124     (merge_axclasses pp (axclasses1, axclasses2),
   125       (merge_instances (instances1, instances2), merge_inst_params (inst_params1, inst_params2)));
   126 );
   127 
   128 
   129 (* maintain axclasses *)
   130 
   131 val get_axclasses = #1 o AxClassData.get;
   132 val map_axclasses = AxClassData.map o apfst;
   133 
   134 val lookup_def = Symtab.lookup o #1 o get_axclasses;
   135 
   136 fun get_info thy c =
   137   (case lookup_def thy c of
   138     SOME (AxClass info) => info
   139   | NONE => error ("No such axclass: " ^ quote c));
   140 
   141 fun class_intros thy =
   142   let
   143     fun add_intro c =
   144       (case lookup_def thy c of SOME (AxClass {intro, ...}) => cons intro | _ => I);
   145     val classes = Sign.all_classes thy;
   146   in map (Thm.class_triv thy) classes @ fold add_intro classes [] end;
   147 
   148 
   149 fun get_params thy pred =
   150   let val params = #2 (get_axclasses thy);
   151   in fold (fn (x, c) => if pred c then cons x else I) params [] end;
   152 
   153 fun params_of thy c = get_params thy (fn c' => c' = c);
   154 fun all_params_of thy S = get_params thy (fn c => Sign.subsort thy (S, [c]));
   155 
   156 fun class_of_param thy = AList.lookup (op =) (#2 (get_axclasses thy));
   157 
   158 
   159 (* maintain instances *)
   160 
   161 fun instance_name (a, c) = NameSpace.base c ^ "_" ^ NameSpace.base a;
   162 
   163 val get_instances = #1 o #2 o AxClassData.get;
   164 val map_instances = AxClassData.map o apsnd o apfst;
   165 
   166 
   167 fun the_classrel thy (c1, c2) =
   168   (case AList.lookup (op =) (#1 (get_instances thy)) (c1, c2) of
   169     SOME th => Thm.transfer thy th
   170   | NONE => error ("Unproven class relation " ^
   171       Syntax.string_of_classrel (ProofContext.init thy) [c1, c2]));
   172 
   173 fun put_classrel arg = map_instances (fn (classrel, arities) =>
   174   (insert (eq_fst op =) arg classrel, arities));
   175 
   176 
   177 fun the_arity thy a (c, Ss) =
   178   (case AList.lookup (op =) (Symtab.lookup_list (#2 (get_instances thy)) a) (c, Ss) of
   179     SOME th => Thm.transfer thy th
   180   | NONE => error ("Unproven type arity " ^
   181       Syntax.string_of_arity (ProofContext.init thy) (a, Ss, [c])));
   182 
   183 fun arity_property thy (c, a) x =
   184   Symtab.lookup_list (snd (get_instances thy)) a
   185   |> map_filter (fn ((c', _), th) => if c = c'
   186       then AList.lookup (op =) (Thm.get_tags th) x else NONE)
   187   |> rev;
   188 
   189 fun insert_arity_completions thy (t, ((c, Ss), th)) arities =
   190   let
   191     val algebra = Sign.classes_of thy;
   192     val super_class_completions = Sign.super_classes thy c
   193       |> filter_out (fn c1 => exists (fn ((c2, Ss2), _) => c1 = c2
   194           andalso Sorts.sorts_le algebra (Ss2, Ss)) (Symtab.lookup_list arities t))
   195     val tags = Thm.get_tags th;
   196     val completions = map (fn c1 => (Sorts.weaken algebra
   197       (fn (th, c2) => fn c3 => th RS the_classrel thy (c2, c3)) (th, c) c1
   198         |> Thm.map_tags (K tags) |> Thm.close_derivation, c1)) super_class_completions;
   199     val arities' = fold (fn (th1, c1) => Symtab.cons_list (t, ((c1, Ss), th1)))
   200       completions arities;
   201   in (completions, arities') end;
   202 
   203 fun put_arity ((t, Ss, c), th) thy =
   204   let
   205     val th' = (Thm.map_tags o AList.default (op =))
   206       (Markup.theory_nameN, Context.theory_name thy) th;
   207     val arity' = (t, ((c, Ss), th'));
   208   in
   209     thy
   210     |> map_instances (fn (classrel, arities) => (classrel,
   211       arities
   212       |> Symtab.insert_list (eq_fst op =) arity'
   213       |> insert_arity_completions thy arity'
   214       |> snd))
   215   end;
   216 
   217 fun complete_arities thy = 
   218   let
   219     val arities = snd (get_instances thy);
   220     val (completions, arities') = arities
   221       |> fold_map (insert_arity_completions thy) (Symtab.dest_list arities)
   222       |>> flat;
   223   in if null completions
   224     then NONE
   225     else SOME (thy |> map_instances (fn (classrel, _) => (classrel, arities')))
   226   end;
   227 
   228 val _ = Context.>> (Context.map_theory (Theory.at_begin complete_arities));
   229 
   230 
   231 (* maintain instance parameters *)
   232 
   233 val get_inst_params = #2 o #2 o AxClassData.get;
   234 val map_inst_params = AxClassData.map o apsnd o apsnd;
   235 
   236 fun get_inst_param thy (c, tyco) =
   237   (the o Symtab.lookup ((the o Symtab.lookup (fst (get_inst_params thy))) c)) tyco;
   238 
   239 fun add_inst_param (c, tyco) inst = (map_inst_params o apfst
   240       o Symtab.map_default (c, Symtab.empty)) (Symtab.update_new (tyco, inst))
   241   #> (map_inst_params o apsnd) (Symtab.update_new (fst inst, (c, tyco)));
   242 
   243 val inst_of_param = Symtab.lookup o snd o get_inst_params;
   244 val param_of_inst = fst oo get_inst_param;
   245 
   246 fun inst_thms thy = (Symtab.fold (Symtab.fold (cons o snd o snd) o snd) o fst)
   247   (get_inst_params thy) [];
   248 
   249 fun inst_tyco_of thy = try (fst o dest_Type o the_single o Sign.const_typargs thy);
   250 
   251 fun unoverload thy = MetaSimplifier.simplify true (inst_thms thy);
   252 fun overload thy = MetaSimplifier.simplify true (map Thm.symmetric (inst_thms thy));
   253 
   254 fun unoverload_conv thy = MetaSimplifier.rewrite true (inst_thms thy);
   255 fun overload_conv thy = MetaSimplifier.rewrite true (map Thm.symmetric (inst_thms thy));
   256 
   257 fun unoverload_const thy (c_ty as (c, _)) =
   258   case class_of_param thy c
   259    of SOME class => (case inst_tyco_of thy c_ty
   260        of SOME tyco => try (param_of_inst thy) (c, tyco) |> the_default c
   261         | NONE => c)
   262     | NONE => c;
   263 
   264 
   265 (** instances **)
   266 
   267 (* class relations *)
   268 
   269 fun cert_classrel thy raw_rel =
   270   let
   271     val string_of_sort = Syntax.string_of_sort_global thy;
   272     val (c1, c2) = pairself (Sign.certify_class thy) raw_rel;
   273     val _ = Sign.primitive_classrel (c1, c2) (Theory.copy thy);
   274     val _ =
   275       (case subtract (op =) (all_params_of thy [c1]) (all_params_of thy [c2]) of
   276         [] => ()
   277       | xs => raise TYPE ("Class " ^ string_of_sort [c1] ^ " lacks parameter(s) " ^
   278           commas_quote xs ^ " of " ^ string_of_sort [c2], [], []));
   279   in (c1, c2) end;
   280 
   281 fun read_classrel thy raw_rel =
   282   cert_classrel thy (pairself (Sign.read_class thy) raw_rel)
   283     handle TYPE (msg, _, _) => error msg;
   284 
   285 
   286 (* primitive rules *)
   287 
   288 fun add_classrel th thy =
   289   let
   290     fun err () = raise THM ("add_classrel: malformed class relation", 0, [th]);
   291     val prop = Thm.plain_prop_of (Thm.transfer thy th);
   292     val rel = Logic.dest_classrel prop handle TERM _ => err ();
   293     val (c1, c2) = cert_classrel thy rel handle TYPE _ => err ();
   294   in
   295     thy
   296     |> Sign.primitive_classrel (c1, c2)
   297     |> put_classrel ((c1, c2), Thm.close_derivation (Drule.unconstrainTs th))
   298     |> perhaps complete_arities
   299   end;
   300 
   301 fun add_arity th thy =
   302   let
   303     fun err () = raise THM ("add_arity: malformed type arity", 0, [th]);
   304     val prop = Thm.plain_prop_of (Thm.transfer thy th);
   305     val (t, Ss, c) = Logic.dest_arity prop handle TERM _ => err ();
   306     val _ = map (Sign.certify_sort thy) Ss = Ss orelse err ();
   307     val _ = case filter_out (fn c => can (get_inst_param thy) (c, t)) (params_of thy c)
   308      of [] => ()
   309       | cs => Output.legacy_feature
   310           ("Missing specifications for overloaded parameters " ^ commas_quote cs)
   311     val th' = Drule.unconstrainTs th;
   312   in
   313     thy
   314     |> Sign.primitive_arity (t, Ss, [c])
   315     |> put_arity ((t, Ss, c), th')
   316   end;
   317 
   318 
   319 (* tactical proofs *)
   320 
   321 fun prove_classrel raw_rel tac thy =
   322   let
   323     val ctxt = ProofContext.init thy;
   324     val (c1, c2) = cert_classrel thy raw_rel;
   325     val th = Goal.prove ctxt [] []
   326         (Logic.mk_classrel (c1, c2)) (fn _ => tac) handle ERROR msg =>
   327       cat_error msg ("The error(s) above occurred while trying to prove class relation " ^
   328         quote (Syntax.string_of_classrel ctxt [c1, c2]));
   329   in
   330     thy
   331     |> PureThy.add_thms [((Binding.name
   332         (prefix classrel_prefix (Logic.name_classrel (c1, c2))), th), [])]
   333     |-> (fn [th'] => add_classrel th')
   334   end;
   335 
   336 fun prove_arity raw_arity tac thy =
   337   let
   338     val ctxt = ProofContext.init thy;
   339     val arity = Sign.cert_arity thy raw_arity;
   340     val names = map (prefix arity_prefix) (Logic.name_arities arity);
   341     val props = Logic.mk_arities arity;
   342     val ths = Goal.prove_multi ctxt [] [] props
   343       (fn _ => Goal.precise_conjunction_tac (length props) 1 THEN tac) handle ERROR msg =>
   344         cat_error msg ("The error(s) above occurred while trying to prove type arity " ^
   345           quote (Syntax.string_of_arity ctxt arity));
   346   in
   347     thy
   348     |> PureThy.add_thms (map (rpair []) (map Binding.name names ~~ ths))
   349     |-> fold add_arity
   350   end;
   351 
   352 
   353 (* instance parameters and overloaded definitions *)
   354 
   355 (* declaration and definition of instances of overloaded constants *)
   356 
   357 fun declare_overloaded (c, T) thy =
   358   let
   359     val class = case class_of_param thy c
   360      of SOME class => class
   361       | NONE => error ("Not a class parameter: " ^ quote c);
   362     val tyco = case inst_tyco_of thy (c, T)
   363      of SOME tyco => tyco
   364       | NONE => error ("Illegal type for instantiation of class parameter: "
   365         ^ quote (c ^ " :: " ^ Syntax.string_of_typ_global thy T));
   366     val name_inst = instance_name (tyco, class) ^ "_inst";
   367     val c' = NameSpace.base c ^ "_" ^ NameSpace.base tyco;
   368     val T' = Type.strip_sorts T;
   369   in
   370     thy
   371     |> Sign.sticky_prefix name_inst
   372     |> Sign.no_base_names
   373     |> Sign.declare_const [] ((Binding.name c', T'), NoSyn)
   374     |-> (fn const' as Const (c'', _) => Thm.add_def false true
   375           (Binding.name (Thm.def_name c'), Logic.mk_equals (Const (c, T'), const'))
   376     #>> Thm.varifyT
   377     #-> (fn thm => add_inst_param (c, tyco) (c'', thm)
   378     #> PureThy.add_thm ((Binding.name c', thm), [Thm.kind_internal])
   379     #> snd
   380     #> Sign.restore_naming thy
   381     #> pair (Const (c, T))))
   382   end;
   383 
   384 fun define_overloaded name (c, t) thy =
   385   let
   386     val T = Term.fastype_of t;
   387     val SOME tyco = inst_tyco_of thy (c, T);
   388     val (c', eq) = get_inst_param thy (c, tyco);
   389     val prop = Logic.mk_equals (Const (c', T), t);
   390     val name' = Thm.def_name_optional
   391       (NameSpace.base c ^ "_" ^ NameSpace.base tyco) name;
   392   in
   393     thy
   394     |> Thm.add_def false false (Binding.name name', prop)
   395     |>> (fn thm =>  Drule.transitive_thm OF [eq, thm])
   396   end;
   397 
   398 
   399 
   400 (** class definitions **)
   401 
   402 fun split_defined n eq =
   403   let
   404     val intro =
   405       (eq RS Drule.equal_elim_rule2)
   406       |> Conjunction.curry_balanced n
   407       |> n = 0 ? Thm.eq_assumption 1;
   408     val dests =
   409       if n = 0 then []
   410       else
   411         (eq RS Drule.equal_elim_rule1)
   412         |> BalancedTree.dest (fn th =>
   413           (th RS Conjunction.conjunctionD1, th RS Conjunction.conjunctionD2)) n;
   414   in (intro, dests) end;
   415 
   416 fun define_class (bclass, raw_super) raw_params raw_specs thy =
   417   let
   418     val ctxt = ProofContext.init thy;
   419     val pp = Syntax.pp ctxt;
   420 
   421 
   422     (* class *)
   423 
   424     val bconst = Logic.const_of_class bclass;
   425     val class = Sign.full_bname thy bclass;
   426     val super = Sign.minimize_sort thy (Sign.certify_sort thy raw_super);
   427 
   428     fun check_constraint (a, S) =
   429       if Sign.subsort thy (super, S) then ()
   430       else error ("Sort constraint of type variable " ^
   431         setmp show_sorts true (Pretty.string_of_typ pp) (TFree (a, S)) ^
   432         " needs to be weaker than " ^ Pretty.string_of_sort pp super);
   433 
   434 
   435     (* params *)
   436 
   437     val params = raw_params |> map (fn p =>
   438       let
   439         val T = Sign.the_const_type thy p;
   440         val _ =
   441           (case Term.add_tvarsT T [] of
   442             [((a, _), S)] => check_constraint (a, S)
   443           | _ => error ("Exactly one type variable expected in class parameter " ^ quote p));
   444         val T' = Term.map_type_tvar (fn _ => TFree (Name.aT, [class])) T;
   445       in (p, T') end);
   446 
   447 
   448     (* axioms *)
   449 
   450     fun prep_axiom t =
   451       (case Term.add_tfrees t [] of
   452         [(a, S)] => check_constraint (a, S)
   453       | [] => ()
   454       | _ => error ("Multiple type variables in class axiom:\n" ^ Pretty.string_of_term pp t);
   455       t
   456       |> Term.map_types (Term.map_atyps (fn TFree _ => Term.aT [] | U => U))
   457       |> Logic.close_form);
   458 
   459     val axiomss = map (map (prep_axiom o Sign.cert_prop thy) o snd) raw_specs;
   460     val name_atts = map fst raw_specs;
   461 
   462 
   463     (* definition *)
   464 
   465     val conjs = map (curry Logic.mk_inclass (Term.aT [])) super @ flat axiomss;
   466     val class_eq =
   467       Logic.mk_equals (Logic.mk_inclass (Term.aT [], class), Logic.mk_conjunction_balanced conjs);
   468 
   469     val ([def], def_thy) =
   470       thy
   471       |> Sign.primitive_class (bclass, super)
   472       |> PureThy.add_defs false [((Binding.name (Thm.def_name bconst), class_eq), [])];
   473     val (raw_intro, (raw_classrel, raw_axioms)) =
   474       split_defined (length conjs) def ||> chop (length super);
   475 
   476 
   477     (* facts *)
   478 
   479     val class_triv = Thm.class_triv def_thy class;
   480     val ([(_, [intro]), (_, classrel), (_, axioms)], facts_thy) =
   481       def_thy
   482       |> Sign.add_path bconst
   483       |> Sign.no_base_names
   484       |> PureThy.note_thmss ""
   485         [((Binding.name introN, []), [([Drule.standard raw_intro], [])]),
   486          ((Binding.name superN, []), [(map Drule.standard raw_classrel, [])]),
   487          ((Binding.name axiomsN, []),
   488            [(map (fn th => Drule.standard (class_triv RS th)) raw_axioms, [])])]
   489       ||> Sign.restore_naming def_thy;
   490 
   491 
   492     (* result *)
   493 
   494     val axclass = make_axclass ((def, intro, axioms), params);
   495     val result_thy =
   496       facts_thy
   497       |> fold put_classrel (map (pair class) super ~~ classrel)
   498       |> Sign.add_path bconst
   499       |> PureThy.note_thmss "" (name_atts ~~ map Thm.simple_fact (unflat axiomss axioms)) |> snd
   500       |> Sign.restore_naming facts_thy
   501       |> map_axclasses (fn (axclasses, parameters) =>
   502         (Symtab.update (class, axclass) axclasses,
   503           fold (fn (x, _) => add_param pp (x, class)) params parameters));
   504 
   505   in (class, result_thy) end;
   506 
   507 
   508 
   509 (** axiomatizations **)
   510 
   511 local
   512 
   513 fun axiomatize prep mk name add raw_args thy =
   514   let
   515     val args = prep thy raw_args;
   516     val specs = mk args;
   517     val names = name args;
   518   in
   519     thy
   520     |> PureThy.add_axioms (map (rpair []) (map Binding.name names ~~ specs))
   521     |-> fold add
   522   end;
   523 
   524 fun ax_classrel prep =
   525   axiomatize (map o prep) (map Logic.mk_classrel)
   526     (map (prefix classrel_prefix o Logic.name_classrel)) add_classrel;
   527 
   528 fun ax_arity prep =
   529   axiomatize prep Logic.mk_arities
   530     (map (prefix arity_prefix) o Logic.name_arities) add_arity;
   531 
   532 fun class_const c =
   533   (Logic.const_of_class c, Term.itselfT (Term.aT []) --> propT);
   534 
   535 fun ax_class prep_class prep_classrel (bclass, raw_super) thy =
   536   let
   537     val class = Sign.full_bname thy bclass;
   538     val super = map (prep_class thy) raw_super |> Sign.minimize_sort thy;
   539   in
   540     thy
   541     |> Sign.primitive_class (bclass, super)
   542     |> ax_classrel prep_classrel (map (fn c => (class, c)) super)
   543     |> Theory.add_deps "" (class_const class) (map class_const super)
   544   end;
   545 
   546 in
   547 
   548 val axiomatize_class = ax_class Sign.certify_class cert_classrel;
   549 val axiomatize_class_cmd = ax_class Sign.read_class read_classrel;
   550 val axiomatize_classrel = ax_classrel cert_classrel;
   551 val axiomatize_classrel_cmd = ax_classrel read_classrel;
   552 val axiomatize_arity = ax_arity Sign.cert_arity;
   553 val axiomatize_arity_cmd = ax_arity Sign.read_arity;
   554 
   555 end;
   556 
   557 
   558 
   559 (** explicit derivations -- cached **)
   560 
   561 datatype cache = Types of (class * thm) list Typtab.table;
   562 
   563 local
   564 
   565 fun lookup_type (Types cache) = AList.lookup (op =) o Typtab.lookup_list cache;
   566 fun insert_type T der (Types cache) = Types (Typtab.insert_list (eq_fst op =) (T, der) cache);
   567 
   568 fun derive_type _ (_, []) = []
   569   | derive_type thy (typ, sort) =
   570       let
   571         val vars = Term.fold_atyps
   572             (fn T as TFree (_, S) => insert (eq_fst op =) (T, S)
   573               | T as TVar (_, S) => insert (eq_fst op =) (T, S)
   574               | _ => I) typ [];
   575         val hyps = vars
   576           |> map (fn (T, S) => (T, Drule.sort_triv thy (T, S) ~~ S));
   577         val ths = (typ, sort)
   578           |> Sorts.of_sort_derivation (Syntax.pp_global thy) (Sign.classes_of thy)
   579            {class_relation =
   580               fn (th, c1) => fn c2 => th RS the_classrel thy (c1, c2),
   581             type_constructor =
   582               fn a => fn dom => fn c =>
   583                 let val Ss = map (map snd) dom and ths = maps (map fst) dom
   584                 in ths MRS the_arity thy a (c, Ss) end,
   585             type_variable =
   586               the_default [] o AList.lookup (op =) hyps};
   587       in ths end;
   588 
   589 in
   590 
   591 fun of_sort thy (typ, sort) cache =
   592   let
   593     val sort' = filter (is_none o lookup_type cache typ) sort;
   594     val ths' = derive_type thy (typ, sort')
   595       handle ERROR msg => cat_error msg ("The error(s) above occurred for sort derivation: " ^
   596         Syntax.string_of_typ_global thy typ ^ " :: " ^ Syntax.string_of_sort_global thy sort');
   597     val cache' = cache |> fold (insert_type typ) (sort' ~~ ths');
   598     val ths =
   599       sort |> map (fn c =>
   600         Goal.finish (the (lookup_type cache' typ c) RS
   601           Goal.init (Thm.cterm_of thy (Logic.mk_inclass (typ, c))))
   602         |> Thm.adjust_maxidx_thm ~1);
   603   in (ths, cache') end;
   604 
   605 end;
   606 
   607 val cache = Types Typtab.empty;
   608 
   609 end;