src/Pure/PIDE/command.ML
author wenzelm
Sat Jul 13 18:33:33 2013 +0200 (2013-07-13 ago)
changeset 52651 5adb5c69af97
parent 52647 45ce95b8bf69
child 52656 9437f440ef3f
permissions -rw-r--r--
initial delay for automatically tried tools;
     1 (*  Title:      Pure/PIDE/command.ML
     2     Author:     Makarius
     3 
     4 Prover command execution: read -- eval -- print.
     5 *)
     6 
     7 signature COMMAND =
     8 sig
     9   val read: (unit -> theory) -> Token.T list -> Toplevel.transition
    10   type eval
    11   val eval_eq: eval * eval -> bool
    12   val eval_result_state: eval -> Toplevel.state
    13   val eval_stable: eval -> bool
    14   val eval: (unit -> theory) -> Token.T list -> eval -> eval
    15   type print
    16   val print: bool -> string -> eval -> print list -> print list option
    17   type print_fn = Toplevel.transition -> Toplevel.state -> unit
    18   val print_function: string ->
    19     ({command_name: string} ->
    20       {delay: Time.time, pri: int, persistent: bool, print_fn: print_fn} option) -> unit
    21   val no_print_function: string -> unit
    22   type exec = eval * print list
    23   val no_exec: exec
    24   val exec_ids: exec option -> Document_ID.exec list
    25   val exec: Document_ID.execution -> exec -> unit
    26 end;
    27 
    28 structure Command: COMMAND =
    29 struct
    30 
    31 (** memo results -- including physical interrupts! **)
    32 
    33 datatype 'a expr =
    34   Expr of Document_ID.exec * (unit -> 'a) |
    35   Result of 'a Exn.result;
    36 
    37 abstype 'a memo = Memo of 'a expr Synchronized.var
    38 with
    39 
    40 fun memo exec_id e = Memo (Synchronized.var "Command.memo" (Expr (exec_id, e)));
    41 fun memo_value a = Memo (Synchronized.var "Command.memo" (Result (Exn.Res a)));
    42 
    43 fun memo_result (Memo v) =
    44   (case Synchronized.value v of
    45     Expr (exec_id, _) => error ("Unfinished execution result: " ^ Document_ID.print exec_id)
    46   | Result res => Exn.release res);
    47 
    48 fun memo_stable (Memo v) =
    49   (case Synchronized.value v of
    50    Expr _ => true
    51  | Result res => not (Exn.is_interrupt_exn res));
    52 
    53 fun memo_exec execution_id (Memo v) =
    54   Synchronized.guarded_access v
    55     (fn expr =>
    56       (case expr of
    57         Result res => SOME (res, expr)
    58       | Expr (exec_id, e) =>
    59           uninterruptible (fn restore_attributes => fn () =>
    60             if Execution.running execution_id exec_id then
    61               let
    62                 val res = Exn.capture (restore_attributes e) ();
    63                 val _ = Execution.finished exec_id;
    64               in SOME (res, Result res) end
    65             else SOME (Exn.interrupt_exn, expr)) ()))
    66   |> Exn.release |> ignore;
    67 
    68 fun memo_fork params execution_id (Memo v) =
    69   (case Synchronized.value v of
    70     Result _ => ()
    71   | _ => ignore ((singleton o Future.forks) params (fn () => memo_exec execution_id (Memo v))));
    72 
    73 end;
    74 
    75 
    76 
    77 (** main phases of execution **)
    78 
    79 (* read *)
    80 
    81 fun read init span =
    82   let
    83     val outer_syntax = #2 (Outer_Syntax.get_syntax ());
    84     val command_reports = Outer_Syntax.command_reports outer_syntax;
    85 
    86     val proper_range =
    87       Position.set_range (Token.position_range_of (#1 (take_suffix Token.is_improper span)));
    88     val pos =
    89       (case find_first Token.is_command span of
    90         SOME tok => Token.position_of tok
    91       | NONE => proper_range);
    92 
    93     val (is_malformed, token_reports) = Thy_Syntax.reports_of_tokens span;
    94     val _ = Position.reports_text (token_reports @ maps command_reports span);
    95   in
    96     if is_malformed then Toplevel.malformed pos "Malformed command syntax"
    97     else
    98       (case Outer_Syntax.read_spans outer_syntax span of
    99         [tr] =>
   100           if Keyword.is_control (Toplevel.name_of tr) then
   101             Toplevel.malformed pos "Illegal control command"
   102           else Toplevel.modify_init init tr
   103       | [] => Toplevel.ignored (Position.set_range (Token.position_range_of span))
   104       | _ => Toplevel.malformed proper_range "Exactly one command expected")
   105       handle ERROR msg => Toplevel.malformed proper_range msg
   106   end;
   107 
   108 
   109 (* eval *)
   110 
   111 type eval_state =
   112   {failed: bool, malformed: bool, command: Toplevel.transition, state: Toplevel.state};
   113 val init_eval_state =
   114   {failed = false, malformed = false, command = Toplevel.empty, state = Toplevel.toplevel};
   115 
   116 datatype eval = Eval of {exec_id: Document_ID.exec, eval_process: eval_state memo};
   117 
   118 fun eval_eq (Eval {exec_id, ...}, Eval {exec_id = exec_id', ...}) = exec_id = exec_id';
   119 
   120 fun eval_result (Eval {eval_process, ...}) = memo_result eval_process;
   121 val eval_result_state = #state o eval_result;
   122 
   123 fun eval_stable (Eval {exec_id, eval_process}) =
   124   Goal.stable_futures exec_id andalso memo_stable eval_process;
   125 
   126 local
   127 
   128 fun run int tr st =
   129   if Goal.future_enabled () andalso Keyword.is_diag (Toplevel.name_of tr) then
   130     (Goal.fork_params {name = "Toplevel.diag", pos = Toplevel.pos_of tr, pri = ~1}
   131       (fn () => Toplevel.command_exception int tr st); ([], SOME st))
   132   else Toplevel.command_errors int tr st;
   133 
   134 fun check_cmts span tr st' =
   135   Toplevel.setmp_thread_position tr
   136     (fn () =>
   137       Outer_Syntax.side_comments span |> maps (fn cmt =>
   138         (Thy_Output.check_text (Token.source_position_of cmt) st'; [])
   139           handle exn =>
   140             if Exn.is_interrupt exn then reraise exn
   141             else ML_Compiler.exn_messages_ids exn)) ();
   142 
   143 fun proof_status tr st =
   144   (case try Toplevel.proof_of st of
   145     SOME prf => Toplevel.status tr (Proof.status_markup prf)
   146   | NONE => ());
   147 
   148 fun eval_state span tr ({malformed, state = st, ...}: eval_state) =
   149   if malformed then
   150     {failed = true, malformed = malformed, command = tr, state = Toplevel.toplevel}
   151   else
   152     let
   153       val malformed' = Toplevel.is_malformed tr;
   154       val is_init = Toplevel.is_init tr;
   155       val is_proof = Keyword.is_proof (Toplevel.name_of tr);
   156 
   157       val _ = Multithreading.interrupted ();
   158       val _ = Toplevel.status tr Markup.running;
   159       val (errs1, result) = run (is_init orelse is_proof) (Toplevel.set_print false tr) st;
   160       val errs2 = (case result of NONE => [] | SOME st' => check_cmts span tr st');
   161       val errs = errs1 @ errs2;
   162       val _ = Toplevel.status tr Markup.finished;
   163       val _ = List.app (Future.error_msg (Toplevel.pos_of tr)) errs;
   164     in
   165       (case result of
   166         NONE =>
   167           let
   168             val _ = if null errs then Exn.interrupt () else ();
   169             val _ = Toplevel.status tr Markup.failed;
   170           in {failed = true, malformed = malformed', command = tr, state = st} end
   171       | SOME st' =>
   172           let
   173             val _ = proof_status tr st';
   174           in {failed = false, malformed = malformed', command = tr, state = st'} end)
   175     end;
   176 
   177 in
   178 
   179 fun eval init span eval0 =
   180   let
   181     val exec_id = Document_ID.make ();
   182     fun process () =
   183       let
   184         val tr =
   185           Position.setmp_thread_data (Position.id_only (Document_ID.print exec_id))
   186             (fn () => read init span |> Toplevel.exec_id exec_id) ();
   187       in eval_state span tr (eval_result eval0) end;
   188   in Eval {exec_id = exec_id, eval_process = memo exec_id process} end;
   189 
   190 end;
   191 
   192 
   193 (* print *)
   194 
   195 datatype print = Print of
   196  {name: string, delay: Time.time, pri: int, persistent: bool,
   197   exec_id: Document_ID.exec, print_process: unit memo};
   198 
   199 type print_fn = Toplevel.transition -> Toplevel.state -> unit;
   200 
   201 type print_function =
   202   {command_name: string} ->
   203     {delay: Time.time, pri: int, persistent: bool, print_fn: print_fn} option;
   204 
   205 local
   206 
   207 val print_functions =
   208   Synchronized.var "Command.print_functions" ([]: (string * print_function) list);
   209 
   210 fun print_error tr e =
   211   (Toplevel.setmp_thread_position tr o Runtime.controlled_execution) e ()
   212     handle exn =>
   213       if Exn.is_interrupt exn then reraise exn
   214       else List.app (Future.error_msg (Toplevel.pos_of tr)) (ML_Compiler.exn_messages_ids exn);
   215 
   216 fun print_eq (Print {exec_id, ...}, Print {exec_id = exec_id', ...}) = exec_id = exec_id';
   217 
   218 fun print_stable (Print {exec_id, print_process, ...}) =
   219   Goal.stable_futures exec_id andalso memo_stable print_process;
   220 
   221 fun print_persistent (Print {persistent, ...}) = persistent;
   222 
   223 in
   224 
   225 fun print command_visible command_name eval old_prints =
   226   let
   227     fun new_print (name, get_pr) =
   228       let
   229         fun make_print strict {delay, pri, persistent, print_fn} =
   230           let
   231             val exec_id = Document_ID.make ();
   232             fun process () =
   233               let
   234                 val {failed, command, state = st', ...} = eval_result eval;
   235                 val tr = Toplevel.exec_id exec_id command;
   236               in
   237                 if failed andalso not strict then ()
   238                 else print_error tr (fn () => print_fn tr st')
   239               end;
   240           in
   241            Print {
   242              name = name, delay = delay, pri = pri, persistent = persistent,
   243              exec_id = exec_id, print_process = memo exec_id process}
   244           end;
   245       in
   246         (case Exn.capture (Runtime.controlled_execution get_pr) {command_name = command_name} of
   247           Exn.Res NONE => NONE
   248         | Exn.Res (SOME pr) => SOME (make_print false pr)
   249         | Exn.Exn exn =>
   250             SOME (make_print true
   251               {delay = Time.zeroTime, pri = 0, persistent = false,
   252                 print_fn = fn _ => fn _ => reraise exn}))
   253       end;
   254 
   255     val new_prints =
   256       if command_visible then
   257         rev (Synchronized.value print_functions) |> map_filter (fn pr =>
   258           (case find_first (fn Print {name, ...} => name = fst pr) old_prints of
   259             SOME print => if print_stable print then SOME print else new_print pr
   260           | NONE => new_print pr))
   261       else filter (fn print => print_persistent print andalso print_stable print) old_prints;
   262   in
   263     if eq_list print_eq (old_prints, new_prints) then NONE else SOME new_prints
   264   end;
   265 
   266 fun print_function name f =
   267   Synchronized.change print_functions (fn funs =>
   268    (if not (AList.defined (op =) funs name) then ()
   269     else warning ("Redefining command print function: " ^ quote name);
   270     AList.update (op =) (name, f) funs));
   271 
   272 fun no_print_function name =
   273   Synchronized.change print_functions (filter_out (equal name o #1));
   274 
   275 end;
   276 
   277 val _ =
   278   print_function "print_state"
   279     (fn {command_name} =>
   280       SOME {delay = Time.zeroTime, pri = 0, persistent = true,
   281         print_fn = fn tr => fn st' =>
   282           let
   283             val is_init = Keyword.is_theory_begin command_name;
   284             val is_proof = Keyword.is_proof command_name;
   285             val do_print =
   286               not is_init andalso
   287                 (Toplevel.print_of tr orelse (is_proof andalso Toplevel.is_proof st'));
   288           in if do_print then Toplevel.print_state false st' else () end});
   289 
   290 
   291 (* combined execution *)
   292 
   293 type exec = eval * print list;
   294 val no_exec: exec =
   295   (Eval {exec_id = Document_ID.none, eval_process = memo_value init_eval_state}, []);
   296 
   297 fun exec_ids NONE = []
   298   | exec_ids (SOME (Eval {exec_id, ...}, prints)) =
   299       exec_id :: map (fn Print {exec_id, ...} => exec_id) prints;
   300 
   301 local
   302 
   303 fun run_print execution_id (Print {name, delay, pri, print_process, ...}) =
   304   if Multithreading.enabled () then
   305     let
   306       val group = Future.worker_subgroup ();
   307       fun fork () =
   308         memo_fork {name = name, group = SOME group, deps = [], pri = pri, interrupts = true}
   309           execution_id print_process;
   310     in
   311       if delay = Time.zeroTime then fork ()
   312       else ignore (Event_Timer.request (Time.+ (Time.now (), delay)) fork)
   313     end
   314   else memo_exec execution_id print_process;
   315 
   316 in
   317 
   318 fun exec execution_id (Eval {eval_process, ...}, prints) =
   319   (memo_exec execution_id eval_process; List.app (run_print execution_id) prints);
   320 
   321 end;
   322 
   323 end;
   324