src/Pure/Isar/isar_cmd.ML
author haftmann
Sun Sep 07 17:51:28 2014 +0200 (2014-09-07 ago)
changeset 58201 5bf56c758e02
parent 58011 bc6bced136e5
child 58868 c5e1cce7ace3
permissions -rw-r--r--
separated class_deps command into separate file
     1 (*  Title:      Pure/Isar/isar_cmd.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Miscellaneous Isar commands.
     5 *)
     6 
     7 signature ISAR_CMD =
     8 sig
     9   val global_setup: Symbol_Pos.source -> theory -> theory
    10   val local_setup: Symbol_Pos.source -> Proof.context -> Proof.context
    11   val parse_ast_translation: Symbol_Pos.source -> theory -> theory
    12   val parse_translation: Symbol_Pos.source -> theory -> theory
    13   val print_translation: Symbol_Pos.source -> theory -> theory
    14   val typed_print_translation: Symbol_Pos.source -> theory -> theory
    15   val print_ast_translation: Symbol_Pos.source -> theory -> theory
    16   val translations: (xstring * string) Syntax.trrule list -> theory -> theory
    17   val no_translations: (xstring * string) Syntax.trrule list -> theory -> theory
    18   val oracle: bstring * Position.T -> Symbol_Pos.source -> theory -> theory
    19   val add_defs: (bool * bool) * ((binding * string) * Token.src list) list -> theory -> theory
    20   val declaration: {syntax: bool, pervasive: bool} ->
    21     Symbol_Pos.source -> local_theory -> local_theory
    22   val simproc_setup: string * Position.T -> string list -> Symbol_Pos.source ->
    23     string list -> local_theory -> local_theory
    24   val have: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    25   val hence: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    26   val show: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    27   val thus: (Attrib.binding * (string * string list) list) list -> bool -> Proof.state -> Proof.state
    28   val qed: Method.text_range option -> Toplevel.transition -> Toplevel.transition
    29   val terminal_proof: Method.text_range * Method.text_range option ->
    30     Toplevel.transition -> Toplevel.transition
    31   val default_proof: Toplevel.transition -> Toplevel.transition
    32   val immediate_proof: Toplevel.transition -> Toplevel.transition
    33   val done_proof: Toplevel.transition -> Toplevel.transition
    34   val skip_proof: Toplevel.transition -> Toplevel.transition
    35   val ml_diag: bool -> Symbol_Pos.source -> Toplevel.transition -> Toplevel.transition
    36   val diag_state: Proof.context -> Toplevel.state
    37   val diag_goal: Proof.context -> {context: Proof.context, facts: thm list, goal: thm}
    38   val pretty_theorems: bool -> Toplevel.state -> Pretty.T list
    39   val thy_deps: Toplevel.transition -> Toplevel.transition
    40   val locale_deps: Toplevel.transition -> Toplevel.transition
    41   val print_stmts: string list * (Facts.ref * Token.src list) list
    42     -> Toplevel.transition -> Toplevel.transition
    43   val print_thms: string list * (Facts.ref * Token.src list) list
    44     -> Toplevel.transition -> Toplevel.transition
    45   val print_prfs: bool -> string list * (Facts.ref * Token.src list) list option
    46     -> Toplevel.transition -> Toplevel.transition
    47   val print_prop: (string list * string) -> Toplevel.transition -> Toplevel.transition
    48   val print_term: (string list * string) -> Toplevel.transition -> Toplevel.transition
    49   val print_type: (string list * (string * string option)) ->
    50     Toplevel.transition -> Toplevel.transition
    51   val header_markup: Symbol_Pos.source -> Toplevel.transition -> Toplevel.transition
    52   val local_theory_markup: (xstring * Position.T) option * (Symbol_Pos.source) ->
    53     Toplevel.transition -> Toplevel.transition
    54   val proof_markup: Symbol_Pos.source -> Toplevel.transition -> Toplevel.transition
    55 end;
    56 
    57 structure Isar_Cmd: ISAR_CMD =
    58 struct
    59 
    60 
    61 (** theory declarations **)
    62 
    63 (* generic setup *)
    64 
    65 fun global_setup source =
    66   ML_Lex.read_source false source
    67   |> ML_Context.expression (#pos source) "val setup: theory -> theory" "Context.map_theory setup"
    68   |> Context.theory_map;
    69 
    70 fun local_setup source =
    71   ML_Lex.read_source false source
    72   |> ML_Context.expression (#pos source) "val setup: local_theory -> local_theory" "Context.map_proof setup"
    73   |> Context.proof_map;
    74 
    75 
    76 (* translation functions *)
    77 
    78 fun parse_ast_translation source =
    79   ML_Lex.read_source false source
    80   |> ML_Context.expression (#pos source)
    81     "val parse_ast_translation: (string * (Proof.context -> Ast.ast list -> Ast.ast)) list"
    82     "Context.map_theory (Sign.parse_ast_translation parse_ast_translation)"
    83   |> Context.theory_map;
    84 
    85 fun parse_translation source =
    86   ML_Lex.read_source false source
    87   |> ML_Context.expression (#pos source)
    88     "val parse_translation: (string * (Proof.context -> term list -> term)) list"
    89     "Context.map_theory (Sign.parse_translation parse_translation)"
    90   |> Context.theory_map;
    91 
    92 fun print_translation source =
    93   ML_Lex.read_source false source
    94   |> ML_Context.expression (#pos source)
    95     "val print_translation: (string * (Proof.context -> term list -> term)) list"
    96     "Context.map_theory (Sign.print_translation print_translation)"
    97   |> Context.theory_map;
    98 
    99 fun typed_print_translation source =
   100   ML_Lex.read_source false source
   101   |> ML_Context.expression (#pos source)
   102     "val typed_print_translation: (string * (Proof.context -> typ -> term list -> term)) list"
   103     "Context.map_theory (Sign.typed_print_translation typed_print_translation)"
   104   |> Context.theory_map;
   105 
   106 fun print_ast_translation source =
   107   ML_Lex.read_source false source
   108   |> ML_Context.expression (#pos source)
   109     "val print_ast_translation: (string * (Proof.context -> Ast.ast list -> Ast.ast)) list"
   110     "Context.map_theory (Sign.print_ast_translation print_ast_translation)"
   111   |> Context.theory_map;
   112 
   113 
   114 (* translation rules *)
   115 
   116 fun read_trrules thy raw_rules =
   117   let
   118     val ctxt = Proof_Context.init_global thy;
   119     val read_root =
   120       #1 o dest_Type o Proof_Context.read_type_name {proper = true, strict = false} ctxt;
   121   in
   122     raw_rules
   123     |> map (Syntax.map_trrule (fn (r, s) => Syntax_Phases.parse_ast_pattern ctxt (read_root r, s)))
   124   end;
   125 
   126 fun translations args thy = Sign.add_trrules (read_trrules thy args) thy;
   127 fun no_translations args thy = Sign.del_trrules (read_trrules thy args) thy;
   128 
   129 
   130 (* oracles *)
   131 
   132 fun oracle (name, pos) source =
   133   let
   134     val body = ML_Lex.read_source false source;
   135     val ants =
   136       ML_Lex.read Position.none
   137        ("local\n\
   138         \  val binding = " ^ ML_Syntax.make_binding (name, pos) ^ ";\n\
   139         \  val body = ") @ body @ ML_Lex.read Position.none (";\n\
   140         \in\n\
   141         \  val " ^ name ^
   142         " = snd (Context.>>> (Context.map_theory_result (Thm.add_oracle (binding, body))));\n\
   143         \end;\n");
   144   in
   145     Context.theory_map
   146       (ML_Context.exec (fn () => ML_Context.eval ML_Compiler.flags (#pos source) ants))
   147   end;
   148 
   149 
   150 (* old-style defs *)
   151 
   152 fun add_defs ((unchecked, overloaded), args) thy =
   153  (legacy_feature "Old 'defs' command -- use 'definition' (with 'overloading') instead";
   154   thy |>
   155     (if unchecked then Global_Theory.add_defs_unchecked_cmd else Global_Theory.add_defs_cmd)
   156       overloaded
   157       (map (fn ((b, ax), srcs) => ((b, ax), map (Attrib.attribute_cmd_global thy) srcs)) args)
   158   |> snd);
   159 
   160 
   161 (* declarations *)
   162 
   163 fun declaration {syntax, pervasive} source =
   164   ML_Lex.read_source false source
   165   |> ML_Context.expression (#pos source)
   166     "val declaration: Morphism.declaration"
   167     ("Context.map_proof (Local_Theory.declaration {syntax = " ^ Bool.toString syntax ^ ", \
   168       \pervasive = " ^ Bool.toString pervasive ^ "} declaration)")
   169   |> Context.proof_map;
   170 
   171 
   172 (* simprocs *)
   173 
   174 fun simproc_setup name lhss source identifier =
   175   ML_Lex.read_source false source
   176   |> ML_Context.expression (#pos source)
   177     "val proc: Morphism.morphism -> Proof.context -> cterm -> thm option"
   178     ("Context.map_proof (Simplifier.def_simproc_cmd {name = " ^ ML_Syntax.make_binding name ^ ", \
   179       \lhss = " ^ ML_Syntax.print_strings lhss ^ ", proc = proc, \
   180       \identifier = Library.maps ML_Context.thms " ^ ML_Syntax.print_strings identifier ^ "})")
   181   |> Context.proof_map;
   182 
   183 
   184 (* goals *)
   185 
   186 fun goal opt_chain goal stmt int =
   187   opt_chain #> goal NONE (K I) stmt int;
   188 
   189 val have = goal I Proof.have_cmd;
   190 val hence = goal Proof.chain Proof.have_cmd;
   191 val show = goal I Proof.show_cmd;
   192 val thus = goal Proof.chain Proof.show_cmd;
   193 
   194 
   195 (* local endings *)
   196 
   197 fun local_qed m = Toplevel.proof (Proof.local_qed (m, true));
   198 val local_terminal_proof = Toplevel.proof' o Proof.local_future_terminal_proof;
   199 val local_default_proof = Toplevel.proof Proof.local_default_proof;
   200 val local_immediate_proof = Toplevel.proof Proof.local_immediate_proof;
   201 val local_done_proof = Toplevel.proof Proof.local_done_proof;
   202 val local_skip_proof = Toplevel.proof' Proof.local_skip_proof;
   203 
   204 val skip_local_qed = Toplevel.skip_proof (fn i => if i > 1 then i - 1 else raise Toplevel.UNDEF);
   205 
   206 
   207 (* global endings *)
   208 
   209 fun global_qed m = Toplevel.end_proof (K (Proof.global_qed (m, true)));
   210 val global_terminal_proof = Toplevel.end_proof o Proof.global_future_terminal_proof;
   211 val global_default_proof = Toplevel.end_proof (K Proof.global_default_proof);
   212 val global_immediate_proof = Toplevel.end_proof (K Proof.global_immediate_proof);
   213 val global_skip_proof = Toplevel.end_proof Proof.global_skip_proof;
   214 val global_done_proof = Toplevel.end_proof (K Proof.global_done_proof);
   215 
   216 val skip_global_qed = Toplevel.skip_proof_to_theory (fn n => n = 1);
   217 
   218 
   219 (* common endings *)
   220 
   221 fun qed m = local_qed m o global_qed m o skip_local_qed o skip_global_qed;
   222 fun terminal_proof m = local_terminal_proof m o global_terminal_proof m;
   223 val default_proof = local_default_proof o global_default_proof;
   224 val immediate_proof = local_immediate_proof o global_immediate_proof;
   225 val done_proof = local_done_proof o global_done_proof;
   226 val skip_proof = local_skip_proof o global_skip_proof;
   227 
   228 
   229 (* diagnostic ML evaluation *)
   230 
   231 structure Diag_State = Proof_Data
   232 (
   233   type T = Toplevel.state;
   234   fun init _ = Toplevel.toplevel;
   235 );
   236 
   237 fun ml_diag verbose source = Toplevel.keep (fn state =>
   238   let
   239     val opt_ctxt =
   240       try Toplevel.generic_theory_of state
   241       |> Option.map (Context.proof_of #> Diag_State.put state);
   242     val flags = ML_Compiler.verbose verbose ML_Compiler.flags;
   243   in ML_Context.eval_source_in opt_ctxt flags source end);
   244 
   245 val diag_state = Diag_State.get;
   246 
   247 fun diag_goal ctxt =
   248   Proof.goal (Toplevel.proof_of (diag_state ctxt))
   249     handle Toplevel.UNDEF => error "No goal present";
   250 
   251 val _ = Theory.setup
   252   (ML_Antiquotation.value (Binding.qualify true "Isar" @{binding state})
   253     (Scan.succeed "Isar_Cmd.diag_state ML_context") #>
   254    ML_Antiquotation.value (Binding.qualify true "Isar" @{binding goal})
   255     (Scan.succeed "Isar_Cmd.diag_goal ML_context"));
   256 
   257 
   258 (* theorems of theory or proof context *)
   259 
   260 fun pretty_theorems verbose st =
   261   if Toplevel.is_proof st then
   262     Proof_Context.pretty_local_facts (Toplevel.context_of st) verbose
   263   else
   264     let
   265       val thy = Toplevel.theory_of st;
   266       val prev_thys =
   267         (case Toplevel.previous_context_of st of
   268           SOME prev => [Proof_Context.theory_of prev]
   269         | NONE => Theory.parents_of thy);
   270     in Proof_Display.pretty_theorems_diff verbose prev_thys thy end;
   271 
   272 
   273 (* display dependencies *)
   274 
   275 val thy_deps = Toplevel.unknown_theory o Toplevel.keep (fn state =>
   276   let
   277     val thy = Toplevel.theory_of state;
   278     val thy_session = Present.session_name thy;
   279 
   280     val gr = rev (Theory.nodes_of thy) |> map (fn node =>
   281       let
   282         val name = Context.theory_name node;
   283         val parents = map Context.theory_name (Theory.parents_of node);
   284         val session = Present.session_name node;
   285         val unfold = (session = thy_session);
   286       in
   287        {name = name, ID = name, parents = parents, dir = session,
   288         unfold = unfold, path = "", content = []}
   289       end);
   290   in Graph_Display.display_graph gr end);
   291 
   292 val locale_deps = Toplevel.unknown_theory o Toplevel.keep (fn state =>
   293   let
   294     val thy = Toplevel.theory_of state;
   295     val gr = Locale.pretty_locale_deps thy |> map (fn {name, parents, body} =>
   296      {name = Locale.extern thy name, ID = name, parents = parents,
   297       dir = "", unfold = true, path = "", content = [body]});
   298   in Graph_Display.display_graph gr end);
   299 
   300 
   301 (* print theorems, terms, types etc. *)
   302 
   303 local
   304 
   305 fun string_of_stmts ctxt args =
   306   Attrib.eval_thms ctxt args
   307   |> map (Element.pretty_statement ctxt Thm.theoremK)
   308   |> Pretty.chunks2 |> Pretty.string_of;
   309 
   310 fun string_of_thms ctxt args =
   311   Pretty.string_of (Proof_Context.pretty_fact ctxt ("", Attrib.eval_thms ctxt args));
   312 
   313 fun string_of_prfs full state arg =
   314   Pretty.string_of
   315     (case arg of
   316       NONE =>
   317         let
   318           val {context = ctxt, goal = thm} = Proof.simple_goal (Toplevel.proof_of state);
   319           val thy = Proof_Context.theory_of ctxt;
   320           val prf = Thm.proof_of thm;
   321           val prop = Thm.full_prop_of thm;
   322           val prf' = Proofterm.rewrite_proof_notypes ([], []) prf;
   323         in
   324           Proof_Syntax.pretty_proof ctxt
   325             (if full then Reconstruct.reconstruct_proof thy prop prf' else prf')
   326         end
   327     | SOME srcs =>
   328         let val ctxt = Toplevel.context_of state
   329         in map (Proof_Syntax.pretty_proof_of ctxt full) (Attrib.eval_thms ctxt srcs) end
   330         |> Pretty.chunks);
   331 
   332 fun string_of_prop ctxt s =
   333   let
   334     val prop = Syntax.read_prop ctxt s;
   335     val ctxt' = Variable.auto_fixes prop ctxt;
   336   in Pretty.string_of (Pretty.quote (Syntax.pretty_term ctxt' prop)) end;
   337 
   338 fun string_of_term ctxt s =
   339   let
   340     val t = Syntax.read_term ctxt s;
   341     val T = Term.type_of t;
   342     val ctxt' = Variable.auto_fixes t ctxt;
   343   in
   344     Pretty.string_of
   345       (Pretty.block [Pretty.quote (Syntax.pretty_term ctxt' t), Pretty.fbrk,
   346         Pretty.str "::", Pretty.brk 1, Pretty.quote (Syntax.pretty_typ ctxt' T)])
   347   end;
   348 
   349 fun string_of_type ctxt (s, NONE) =
   350       let val T = Syntax.read_typ ctxt s
   351       in Pretty.string_of (Pretty.quote (Syntax.pretty_typ ctxt T)) end
   352   | string_of_type ctxt (s1, SOME s2) =
   353       let
   354         val ctxt' = Config.put show_sorts true ctxt;
   355         val raw_T = Syntax.parse_typ ctxt' s1;
   356         val S = Syntax.read_sort ctxt' s2;
   357         val T =
   358           Syntax.check_term ctxt'
   359             (Logic.mk_type raw_T |> Type.constraint (Term.itselfT (Type_Infer.anyT S)))
   360           |> Logic.dest_type;
   361       in Pretty.string_of (Pretty.quote (Syntax.pretty_typ ctxt' T)) end;
   362 
   363 fun print_item string_of (modes, arg) = Toplevel.keep (fn state =>
   364   Print_Mode.with_modes modes (fn () => writeln (string_of state arg)) ());
   365 
   366 in
   367 
   368 val print_stmts = print_item (string_of_stmts o Toplevel.context_of);
   369 val print_thms = print_item (string_of_thms o Toplevel.context_of);
   370 val print_prfs = print_item o string_of_prfs;
   371 val print_prop = print_item (string_of_prop o Toplevel.context_of);
   372 val print_term = print_item (string_of_term o Toplevel.context_of);
   373 val print_type = print_item (string_of_type o Toplevel.context_of);
   374 
   375 end;
   376 
   377 
   378 (* markup commands *)
   379 
   380 fun header_markup txt = Toplevel.keep (fn state =>
   381   if Toplevel.is_toplevel state then Thy_Output.check_text txt state
   382   else raise Toplevel.UNDEF);
   383 
   384 fun local_theory_markup (loc, txt) = Toplevel.present_local_theory loc (Thy_Output.check_text txt);
   385 val proof_markup = Toplevel.present_proof o Thy_Output.check_text;
   386 
   387 end;